New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynhpg.F90 in NEMO/trunk/src/OCE/DYN – NEMO

source: NEMO/trunk/src/OCE/DYN/dynhpg.F90 @ 14834

Last change on this file since 14834 was 14834, checked in by hadcv, 14 months ago

#2600: Merge in dev_r14273_HPC-02_Daley_Tiling

  • Property svn:keywords set to Id
File size: 75.9 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  OPA  !  1987-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  1991-11  (G. Madec)
8   !!            7.0  !  1996-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  1997-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  2002-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  2002-08  (A. Bozec)  hpg_zps: Original code
12   !!   NEMO     1.0  !  2005-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                 !         Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!             -   !  2005-11  (G. Madec) style & small optimisation
15   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
16   !!            3.4  !  2011-11  (H. Liu) hpg_prj: Original code for s-coordinates
17   !!                 !           (A. Coward) suppression of hel, wdj and rot options
18   !!            3.6  !  2014-11  (P. Mathiot) hpg_isf: original code for ice shelf cavity
19   !!            4.2  !  2020-12  (M. Bell, A. Young) hpg_djc: revised djc scheme
20   !!----------------------------------------------------------------------
21
22   !!----------------------------------------------------------------------
23   !!   dyn_hpg      : update the momentum trend with the now horizontal
24   !!                  gradient of the hydrostatic pressure
25   !!   dyn_hpg_init : initialisation and control of options
26   !!       hpg_zco  : z-coordinate scheme
27   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
28   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
29   !!       hpg_isf  : s-coordinate (sco formulation) adapted to ice shelf
30   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
31   !!       hpg_prj  : s-coordinate (Pressure Jacobian with Cubic polynomial)
32   !!----------------------------------------------------------------------
33   USE oce             ! ocean dynamics and tracers
34   USE isf_oce , ONLY : risfload  ! ice shelf  (risfload variable)
35   USE isfload , ONLY : isf_load  ! ice shelf  (isf_load routine )
36   USE sbc_oce         ! surface variable (only for the flag with ice shelf)
37   USE dom_oce         ! ocean space and time domain
38   USE wet_dry         ! wetting and drying
39   USE phycst          ! physical constants
40   USE trd_oce         ! trends: ocean variables
41   USE trddyn          ! trend manager: dynamics
42   USE zpshde          ! partial step: hor. derivative     (zps_hde routine)
43   !
44   USE in_out_manager  ! I/O manager
45   USE prtctl          ! Print control
46   USE lbclnk          ! lateral boundary condition
47   USE lib_mpp         ! MPP library
48   USE eosbn2          ! compute density
49   USE timing          ! Timing
50   USE iom
51
52   IMPLICIT NONE
53   PRIVATE
54
55   PUBLIC   dyn_hpg        ! routine called by step module
56   PUBLIC   dyn_hpg_init   ! routine called by opa module
57
58   !                                !!* Namelist namdyn_hpg : hydrostatic pressure gradient
59   LOGICAL, PUBLIC ::   ln_hpg_zco   !: z-coordinate - full steps
60   LOGICAL, PUBLIC ::   ln_hpg_zps   !: z-coordinate - partial steps (interpolation)
61   LOGICAL, PUBLIC ::   ln_hpg_sco   !: s-coordinate (standard jacobian formulation)
62   LOGICAL, PUBLIC ::   ln_hpg_djc   !: s-coordinate (Density Jacobian with Cubic polynomial)
63   LOGICAL, PUBLIC ::   ln_hpg_prj   !: s-coordinate (Pressure Jacobian scheme)
64   LOGICAL, PUBLIC ::   ln_hpg_isf   !: s-coordinate similar to sco modify for isf
65
66   !                                !! Flag to control the type of hydrostatic pressure gradient
67   INTEGER, PARAMETER ::   np_ERROR  =-10   ! error in specification of lateral diffusion
68   INTEGER, PARAMETER ::   np_zco    =  0   ! z-coordinate - full steps
69   INTEGER, PARAMETER ::   np_zps    =  1   ! z-coordinate - partial steps (interpolation)
70   INTEGER, PARAMETER ::   np_sco    =  2   ! s-coordinate (standard jacobian formulation)
71   INTEGER, PARAMETER ::   np_djc    =  3   ! s-coordinate (Density Jacobian with Cubic polynomial)
72   INTEGER, PARAMETER ::   np_prj    =  4   ! s-coordinate (Pressure Jacobian scheme)
73   INTEGER, PARAMETER ::   np_isf    =  5   ! s-coordinate similar to sco modify for isf
74   !
75   INTEGER, PUBLIC  ::   nhpg         !: type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
76   !
77   LOGICAL          ::   ln_hpg_djc_vnh, ln_hpg_djc_vnv                 ! flag to specify hpg_djc boundary condition type
78   REAL(wp), PUBLIC ::   aco_bc_hor, bco_bc_hor, aco_bc_vrt, bco_bc_vrt !: coefficients for hpg_djc hor and vert boundary conditions
79
80   !! * Substitutions
81#  include "do_loop_substitute.h90"
82#  include "domzgr_substitute.h90"
83
84   !!----------------------------------------------------------------------
85   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
86   !! $Id$
87   !! Software governed by the CeCILL license (see ./LICENSE)
88   !!----------------------------------------------------------------------
89CONTAINS
90
91   SUBROUTINE dyn_hpg( kt, Kmm, puu, pvv, Krhs )
92      !!---------------------------------------------------------------------
93      !!                  ***  ROUTINE dyn_hpg  ***
94      !!
95      !! ** Method  :   Call the hydrostatic pressure gradient routine
96      !!              using the scheme defined in the namelist
97      !!
98      !! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
99      !!             - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
100      !!----------------------------------------------------------------------
101      INTEGER                             , INTENT( in )  ::  kt          ! ocean time-step index
102      INTEGER                             , INTENT( in )  ::  Kmm, Krhs   ! ocean time level indices
103      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv    ! ocean velocities and RHS of momentum equation
104      !
105      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   ztrdu, ztrdv
106      !!----------------------------------------------------------------------
107      !
108      IF( ln_timing )   CALL timing_start('dyn_hpg')
109      !
110      IF( l_trddyn ) THEN                    ! Temporary saving of puu(:,:,:,Krhs) and pvv(:,:,:,Krhs) trends (l_trddyn)
111         ALLOCATE( ztrdu(jpi,jpj,jpk) , ztrdv(jpi,jpj,jpk) )
112         ztrdu(:,:,:) = puu(:,:,:,Krhs)
113         ztrdv(:,:,:) = pvv(:,:,:,Krhs)
114      ENDIF
115      !
116      SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
117      CASE ( np_zco )   ;   CALL hpg_zco    ( kt, Kmm, puu, pvv, Krhs )  ! z-coordinate
118      CASE ( np_zps )   ;   CALL hpg_zps    ( kt, Kmm, puu, pvv, Krhs )  ! z-coordinate plus partial steps (interpolation)
119      CASE ( np_sco )   ;   CALL hpg_sco    ( kt, Kmm, puu, pvv, Krhs )  ! s-coordinate (standard jacobian formulation)
120      CASE ( np_djc )   ;   CALL hpg_djc    ( kt, Kmm, puu, pvv, Krhs )  ! s-coordinate (Density Jacobian with Cubic polynomial)
121      CASE ( np_prj )   ;   CALL hpg_prj    ( kt, Kmm, puu, pvv, Krhs )  ! s-coordinate (Pressure Jacobian scheme)
122      CASE ( np_isf )   ;   CALL hpg_isf    ( kt, Kmm, puu, pvv, Krhs )  ! s-coordinate similar to sco modify for ice shelf
123      END SELECT
124      !
125      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
126         ztrdu(:,:,:) = puu(:,:,:,Krhs) - ztrdu(:,:,:)
127         ztrdv(:,:,:) = pvv(:,:,:,Krhs) - ztrdv(:,:,:)
128         CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt, Kmm )
129         DEALLOCATE( ztrdu , ztrdv )
130      ENDIF
131      !
132      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=puu(:,:,:,Krhs), clinfo1=' hpg  - Ua: ', mask1=umask,   &
133         &                                  tab3d_2=pvv(:,:,:,Krhs), clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
134      !
135      IF( ln_timing )   CALL timing_stop('dyn_hpg')
136      !
137   END SUBROUTINE dyn_hpg
138
139
140   SUBROUTINE dyn_hpg_init( Kmm )
141      !!----------------------------------------------------------------------
142      !!                 ***  ROUTINE dyn_hpg_init  ***
143      !!
144      !! ** Purpose :   initializations for the hydrostatic pressure gradient
145      !!              computation and consistency control
146      !!
147      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
148      !!      with the type of vertical coordinate used (zco, zps, sco)
149      !!----------------------------------------------------------------------
150      INTEGER, INTENT( in ) :: Kmm   ! ocean time level index
151      !
152      INTEGER ::   ioptio = 0      ! temporary integer
153      INTEGER ::   ios             ! Local integer output status for namelist read
154      !!
155      INTEGER  ::   ji, jj, jk, ikt    ! dummy loop indices      ISF
156      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::  zts_top, zrhd   ! hypothesys on isf density
157      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::  zrhdtop_isf    ! density at bottom of ISF
158      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::  ziceload       ! density at bottom of ISF
159      !!
160      NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco,     &
161         &                 ln_hpg_djc, ln_hpg_prj, ln_hpg_isf,     &
162         &                 ln_hpg_djc_vnh, ln_hpg_djc_vnv
163      !!----------------------------------------------------------------------
164      !
165      READ  ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
166901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist' )
167      !
168      READ  ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
169902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist' )
170      IF(lwm) WRITE ( numond, namdyn_hpg )
171      !
172      IF(lwp) THEN                   ! Control print
173         WRITE(numout,*)
174         WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
175         WRITE(numout,*) '~~~~~~~~~~~~'
176         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
177         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
178         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
179         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
180         WRITE(numout,*) '      s-coord. (standard jacobian formulation) for isf  ln_hpg_isf    = ', ln_hpg_isf
181         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
182         WRITE(numout,*) '      s-coord. (Pressure Jacobian: Cubic polynomial)    ln_hpg_prj    = ', ln_hpg_prj
183      ENDIF
184      !
185      IF( .NOT.ln_linssh .AND. (ln_hpg_zco.OR.ln_hpg_zps) )   &
186         &   CALL ctl_stop( 'dyn_hpg_init : non-linear free surface incompatible with hpg_zco or hpg_zps' )
187      !
188      IF( (.NOT.ln_hpg_isf .AND. ln_isfcav) .OR. (ln_hpg_isf .AND. .NOT.ln_isfcav) )                  &
189         &   CALL ctl_stop( 'dyn_hpg_init : ln_hpg_isf=T requires ln_isfcav=T and vice versa' ) 
190      !
191#if defined key_qco
192      IF( ln_hpg_isf ) THEN
193         CALL ctl_stop( 'dyn_hpg_init : key_qco and ln_hpg_isf not yet compatible' )
194      ENDIF
195#endif
196      !
197      !                               ! Set nhpg from ln_hpg_... flags & consistency check
198      nhpg   = np_ERROR
199      ioptio = 0
200      IF( ln_hpg_zco ) THEN   ;   nhpg = np_zco   ;   ioptio = ioptio +1   ;   ENDIF
201      IF( ln_hpg_zps ) THEN   ;   nhpg = np_zps   ;   ioptio = ioptio +1   ;   ENDIF
202      IF( ln_hpg_sco ) THEN   ;   nhpg = np_sco   ;   ioptio = ioptio +1   ;   ENDIF
203      IF( ln_hpg_djc ) THEN   ;   nhpg = np_djc   ;   ioptio = ioptio +1   ;   ENDIF
204      IF( ln_hpg_prj ) THEN   ;   nhpg = np_prj   ;   ioptio = ioptio +1   ;   ENDIF
205      IF( ln_hpg_isf ) THEN   ;   nhpg = np_isf   ;   ioptio = ioptio +1   ;   ENDIF
206      !
207      IF( ioptio /= 1 )   CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
208      !
209      IF(lwp) THEN
210         WRITE(numout,*)
211         SELECT CASE( nhpg )
212         CASE( np_zco )   ;   WRITE(numout,*) '   ==>>>   z-coord. - full steps '
213         CASE( np_zps )   ;   WRITE(numout,*) '   ==>>>   z-coord. - partial steps (interpolation)'
214         CASE( np_sco )   ;   WRITE(numout,*) '   ==>>>   s-coord. (standard jacobian formulation)'
215         CASE( np_djc )   ;   WRITE(numout,*) '   ==>>>   s-coord. (Density Jacobian: Cubic polynomial)'
216         CASE( np_prj )   ;   WRITE(numout,*) '   ==>>>   s-coord. (Pressure Jacobian: Cubic polynomial)'
217         CASE( np_isf )   ;   WRITE(numout,*) '   ==>>>   s-coord. (standard jacobian formulation) for isf'
218         END SELECT
219         WRITE(numout,*)
220      ENDIF
221      !                         
222      IF ( ln_hpg_djc ) THEN
223         IF (ln_hpg_djc_vnh) THEN ! Von Neumann boundary condition
224           IF(lwp) WRITE(numout,*) '           horizontal bc: von Neumann '
225           aco_bc_hor = 6.0_wp/5.0_wp
226           bco_bc_hor = 7.0_wp/15.0_wp
227         ELSE ! Linear extrapolation
228           IF(lwp) WRITE(numout,*) '           horizontal bc: linear extrapolation'
229           aco_bc_hor = 3.0_wp/2.0_wp
230           bco_bc_hor = 1.0_wp/2.0_wp
231         END IF
232         IF (ln_hpg_djc_vnv) THEN ! Von Neumann boundary condition
233           IF(lwp) WRITE(numout,*) '           vertical bc: von Neumann '
234           aco_bc_vrt = 6.0_wp/5.0_wp
235           bco_bc_vrt = 7.0_wp/15.0_wp
236         ELSE ! Linear extrapolation
237           IF(lwp) WRITE(numout,*) '           vertical bc: linear extrapolation'
238           aco_bc_vrt = 3.0_wp/2.0_wp
239           bco_bc_vrt = 1.0_wp/2.0_wp
240         END IF
241      END IF
242      !
243   END SUBROUTINE dyn_hpg_init
244
245
246   SUBROUTINE hpg_zco( kt, Kmm, puu, pvv, Krhs )
247      !!---------------------------------------------------------------------
248      !!                  ***  ROUTINE hpg_zco  ***
249      !!
250      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
251      !!      The now hydrostatic pressure gradient at a given level, jk,
252      !!      is computed by taking the vertical integral of the in-situ
253      !!      density gradient along the model level from the suface to that
254      !!      level:    zhpi = grav .....
255      !!                zhpj = grav .....
256      !!      add it to the general momentum trend (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)).
257      !!            puu(:,:,:,Krhs) = puu(:,:,:,Krhs) - 1/e1u * zhpi
258      !!            pvv(:,:,:,Krhs) = pvv(:,:,:,Krhs) - 1/e2v * zhpj
259      !!
260      !! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
261      !!----------------------------------------------------------------------
262      INTEGER                             , INTENT( in )  ::  kt          ! ocean time-step index
263      INTEGER                             , INTENT( in )  ::  Kmm, Krhs   ! ocean time level indices
264      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv    ! ocean velocities and RHS of momentum equation
265      !
266      INTEGER  ::   ji, jj, jk       ! dummy loop indices
267      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
268      REAL(wp), DIMENSION(A2D(nn_hls)) ::  zhpi, zhpj
269      !!----------------------------------------------------------------------
270      !
271      IF( .NOT. l_istiled .OR. ntile == 1 )  THEN                       ! Do only on the first tile
272         IF( kt == nit000 ) THEN
273            IF(lwp) WRITE(numout,*)
274            IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
275            IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
276         ENDIF
277      ENDIF
278      !
279      zcoef0 = - grav * 0.5_wp            ! Local constant initialization
280      !
281      DO_2D( 0, 0, 0, 0 )                 ! Surface value
282         zcoef1 = zcoef0 * e3w(ji,jj,1,Kmm)
283         !                                   ! hydrostatic pressure gradient
284         zhpi(ji,jj) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
285         zhpj(ji,jj) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
286         !                                   ! add to the general momentum trend
287         puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj)
288         pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj)
289      END_2D
290      !
291      DO_3D( 0, 0, 0, 0, 2, jpkm1 )        ! interior value (2=<jk=<jpkm1)
292         zcoef1 = zcoef0 * e3w(ji,jj,jk,Kmm)
293         !                                   ! hydrostatic pressure gradient
294         zhpi(ji,jj) = zhpi(ji,jj) + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )  &
295            &                                  - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) * r1_e1u(ji,jj)
296
297         zhpj(ji,jj) = zhpj(ji,jj) + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )  &
298            &                                  - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) * r1_e2v(ji,jj)
299         !                                   ! add to the general momentum trend
300         puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj)
301         pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj)
302      END_3D
303      !
304   END SUBROUTINE hpg_zco
305
306
307   SUBROUTINE hpg_zps( kt, Kmm, puu, pvv, Krhs )
308      !!---------------------------------------------------------------------
309      !!                 ***  ROUTINE hpg_zps  ***
310      !!
311      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
312      !!
313      !! ** Action  : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
314      !!----------------------------------------------------------------------
315      INTEGER                             , INTENT( in )  ::  kt          ! ocean time-step index
316      INTEGER                             , INTENT( in )  ::  Kmm, Krhs   ! ocean time level indices
317      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv    ! ocean velocities and RHS of momentum equation
318      !!
319      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
320      INTEGER  ::   iku, ikv                         ! temporary integers
321      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
322      REAL(wp), DIMENSION(A2D(nn_hls),jpk ) :: zhpi, zhpj
323      REAL(wp), DIMENSION(A2D(nn_hls),jpts) :: zgtsu, zgtsv
324      REAL(wp), DIMENSION(A2D(nn_hls)     ) :: zgru, zgrv
325      !!----------------------------------------------------------------------
326      !
327      IF( .NOT. l_istiled .OR. ntile == 1 )  THEN                       ! Do only on the first tile
328         IF( kt == nit000 ) THEN
329            IF(lwp) WRITE(numout,*)
330            IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
331            IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
332         ENDIF
333      ENDIF
334
335      ! Partial steps: Compute NOW horizontal gradient of t, s, rd at the last ocean level
336      CALL zps_hde( kt, Kmm, jpts, ts(:,:,:,:,Kmm), zgtsu, zgtsv, rhd, zgru , zgrv )
337
338      ! Local constant initialization
339      zcoef0 = - grav * 0.5_wp
340
341      !  Surface value (also valid in partial step case)
342      DO_2D( 0, 0, 0, 0 )
343         zcoef1 = zcoef0 * e3w(ji,jj,1,Kmm)
344         ! hydrostatic pressure gradient
345         zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
346         zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
347         ! add to the general momentum trend
348         puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj,1)
349         pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj,1)
350      END_2D
351
352      ! interior value (2=<jk=<jpkm1)
353      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
354         zcoef1 = zcoef0 * e3w(ji,jj,jk,Kmm)
355         ! hydrostatic pressure gradient
356         zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
357            &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
358            &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) * r1_e1u(ji,jj)
359
360         zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
361            &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
362            &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) * r1_e2v(ji,jj)
363         ! add to the general momentum trend
364         puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj,jk)
365         pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj,jk)
366      END_3D
367
368      ! partial steps correction at the last level  (use zgru & zgrv computed in zpshde.F90)
369      DO_2D( 0, 0, 0, 0 )
370         iku = mbku(ji,jj)
371         ikv = mbkv(ji,jj)
372         zcoef2 = zcoef0 * MIN( e3w(ji,jj,iku,Kmm), e3w(ji+1,jj  ,iku,Kmm) )
373         zcoef3 = zcoef0 * MIN( e3w(ji,jj,ikv,Kmm), e3w(ji  ,jj+1,ikv,Kmm) )
374         IF( iku > 1 ) THEN            ! on i-direction (level 2 or more)
375            puu  (ji,jj,iku,Krhs) = puu(ji,jj,iku,Krhs) - zhpi(ji,jj,iku)         ! subtract old value
376            zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1)                   &   ! compute the new one
377               &            + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + zgru(ji,jj) ) * r1_e1u(ji,jj)
378            puu  (ji,jj,iku,Krhs) = puu(ji,jj,iku,Krhs) + zhpi(ji,jj,iku)         ! add the new one to the general momentum trend
379         ENDIF
380         IF( ikv > 1 ) THEN            ! on j-direction (level 2 or more)
381            pvv  (ji,jj,ikv,Krhs) = pvv(ji,jj,ikv,Krhs) - zhpj(ji,jj,ikv)         ! subtract old value
382            zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1)                   &   ! compute the new one
383               &            + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + zgrv(ji,jj) ) * r1_e2v(ji,jj)
384            pvv  (ji,jj,ikv,Krhs) = pvv(ji,jj,ikv,Krhs) + zhpj(ji,jj,ikv)         ! add the new one to the general momentum trend
385         ENDIF
386      END_2D
387      !
388   END SUBROUTINE hpg_zps
389
390
391   SUBROUTINE hpg_sco( kt, Kmm, puu, pvv, Krhs )
392      !!---------------------------------------------------------------------
393      !!                  ***  ROUTINE hpg_sco  ***
394      !!
395      !! ** Method  :   s-coordinate case. Jacobian scheme.
396      !!      The now hydrostatic pressure gradient at a given level, jk,
397      !!      is computed by taking the vertical integral of the in-situ
398      !!      density gradient along the model level from the suface to that
399      !!      level. s-coordinates (ln_sco): a corrective term is added
400      !!      to the horizontal pressure gradient :
401      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
402      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
403      !!      add it to the general momentum trend (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)).
404      !!         puu(:,:,:,Krhs) = puu(:,:,:,Krhs) - 1/e1u * zhpi
405      !!         pvv(:,:,:,Krhs) = pvv(:,:,:,Krhs) - 1/e2v * zhpj
406      !!
407      !! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
408      !!----------------------------------------------------------------------
409      INTEGER                             , INTENT( in )  ::  kt          ! ocean time-step index
410      INTEGER                             , INTENT( in )  ::  Kmm, Krhs   ! ocean time level indices
411      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv    ! ocean velocities and RHS of momentum equation
412      !!
413      INTEGER  ::   ji, jj, jk, jii, jjj           ! dummy loop indices
414      REAL(wp) ::   zcoef0, zuap, zvap, ztmp       ! local scalars
415      LOGICAL  ::   ll_tmp1, ll_tmp2               ! local logical variables
416      REAL(wp), DIMENSION(A2D(nn_hls),jpk)  ::   zhpi, zhpj
417      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zcpx, zcpy   !W/D pressure filter
418      !!----------------------------------------------------------------------
419      !
420      IF( ln_wd_il ) ALLOCATE(zcpx(A2D(nn_hls)), zcpy(A2D(nn_hls)))
421      !
422      IF( .NOT. l_istiled .OR. ntile == 1 )  THEN                       ! Do only on the first tile
423         IF( kt == nit000 ) THEN
424            IF(lwp) WRITE(numout,*)
425            IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
426            IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OCE original scheme used'
427         ENDIF
428      ENDIF
429      !
430      zcoef0 = - grav * 0.5_wp
431      !
432      IF( ln_wd_il ) THEN
433        DO_2D( 0, 0, 0, 0 )
434          ll_tmp1 = MIN(  ssh(ji,jj,Kmm)               ,  ssh(ji+1,jj,Kmm) ) >                &
435               &    MAX( -ht_0(ji,jj)               , -ht_0(ji+1,jj) ) .AND.            &
436               &    MAX(  ssh(ji,jj,Kmm) +  ht_0(ji,jj),  ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) )  &
437               &                                                       > rn_wdmin1 + rn_wdmin2
438          ll_tmp2 = ( ABS( ssh(ji,jj,Kmm)              -  ssh(ji+1,jj,Kmm) ) > 1.E-12 ) .AND. (       &
439               &    MAX(   ssh(ji,jj,Kmm)              ,  ssh(ji+1,jj,Kmm) ) >                &
440               &    MAX(  -ht_0(ji,jj)              , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
441
442          IF(ll_tmp1) THEN
443            zcpx(ji,jj) = 1.0_wp
444          ELSE IF(ll_tmp2) THEN
445            ! no worries about  ssh(ji+1,jj,Kmm) -  ssh(ji  ,jj,Kmm) = 0, it won't happen ! here
446            zcpx(ji,jj) = ABS( (ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
447                        &    / (ssh(ji+1,jj,Kmm) - ssh(ji  ,jj,Kmm)) )
448          ELSE
449            zcpx(ji,jj) = 0._wp
450          END IF
451   
452          ll_tmp1 = MIN(  ssh(ji,jj,Kmm)              ,  ssh(ji,jj+1,Kmm) ) >                &
453               &    MAX( -ht_0(ji,jj)              , -ht_0(ji,jj+1) ) .AND.            &
454               &    MAX(  ssh(ji,jj,Kmm) + ht_0(ji,jj),  ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) )  &
455               &                                                      > rn_wdmin1 + rn_wdmin2
456          ll_tmp2 = ( ABS( ssh(ji,jj,Kmm)             -  ssh(ji,jj+1,Kmm) ) > 1.E-12 ) .AND. (        &
457               &    MAX(   ssh(ji,jj,Kmm)             ,  ssh(ji,jj+1,Kmm) ) >                &
458               &    MAX(  -ht_0(ji,jj)             , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
459
460          IF(ll_tmp1) THEN
461            zcpy(ji,jj) = 1.0_wp
462          ELSE IF(ll_tmp2) THEN
463            ! no worries about  ssh(ji,jj+1,Kmm) -  ssh(ji,jj  ,Kmm) = 0, it won't happen ! here
464            zcpy(ji,jj) = ABS( (ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
465                        &    / (ssh(ji,jj+1,Kmm) - ssh(ji,jj  ,Kmm)) )
466          ELSE
467            zcpy(ji,jj) = 0._wp
468          END IF
469        END_2D
470      END IF
471      !
472      DO_2D( 0, 0, 0, 0 )              ! Surface value
473         !                                   ! hydrostatic pressure gradient along s-surfaces
474         zhpi(ji,jj,1) = zcoef0 * r1_e1u(ji,jj)                      &
475            &          * (  e3w(ji+1,jj  ,1,Kmm) * rhd(ji+1,jj  ,1)  &
476            &             - e3w(ji  ,jj  ,1,Kmm) * rhd(ji  ,jj  ,1)  )
477         zhpj(ji,jj,1) = zcoef0 * r1_e2v(ji,jj)                      &
478            &          * (  e3w(ji  ,jj+1,1,Kmm) * rhd(ji  ,jj+1,1)  &
479            &             - e3w(ji  ,jj  ,1,Kmm) * rhd(ji  ,jj  ,1)  )
480         !                                   ! s-coordinate pressure gradient correction
481         zuap = -zcoef0 * ( rhd    (ji+1,jj,1) + rhd    (ji,jj,1) )   &
482            &           * ( gde3w(ji+1,jj,1) - gde3w(ji,jj,1) ) * r1_e1u(ji,jj)
483         zvap = -zcoef0 * ( rhd    (ji,jj+1,1) + rhd    (ji,jj,1) )   &
484            &           * ( gde3w(ji,jj+1,1) - gde3w(ji,jj,1) ) * r1_e2v(ji,jj)
485         !
486         IF( ln_wd_il ) THEN
487            zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
488            zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj) 
489            zuap = zuap * zcpx(ji,jj)
490            zvap = zvap * zcpy(ji,jj)
491         ENDIF
492         !                                   ! add to the general momentum trend
493         puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj,1) + zuap
494         pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj,1) + zvap
495      END_2D
496      !
497      DO_3D( 0, 0, 0, 0, 2, jpkm1 )    ! interior value (2=<jk=<jpkm1)
498         !                                   ! hydrostatic pressure gradient along s-surfaces
499         zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 * r1_e1u(ji,jj)                         &
500            &           * (  e3w(ji+1,jj,jk,Kmm) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )  &
501            &              - e3w(ji  ,jj,jk,Kmm) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  )
502         zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 * r1_e2v(ji,jj)                         &
503            &           * (  e3w(ji,jj+1,jk,Kmm) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )  &
504            &              - e3w(ji,jj  ,jk,Kmm) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  )
505         !                                   ! s-coordinate pressure gradient correction
506         zuap = -zcoef0 * ( rhd  (ji+1,jj  ,jk) + rhd  (ji,jj,jk) ) &
507            &           * ( gde3w(ji+1,jj  ,jk) - gde3w(ji,jj,jk) ) * r1_e1u(ji,jj)
508         zvap = -zcoef0 * ( rhd  (ji  ,jj+1,jk) + rhd  (ji,jj,jk) ) &
509            &           * ( gde3w(ji  ,jj+1,jk) - gde3w(ji,jj,jk) ) * r1_e2v(ji,jj)
510         !
511         IF( ln_wd_il ) THEN
512            zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
513            zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj) 
514            zuap = zuap * zcpx(ji,jj)
515            zvap = zvap * zcpy(ji,jj)
516         ENDIF
517         !
518         ! add to the general momentum trend
519         puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj,jk) + zuap
520         pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj,jk) + zvap
521      END_3D
522      !
523      IF( ln_wd_il )  DEALLOCATE( zcpx , zcpy )
524      !
525   END SUBROUTINE hpg_sco
526
527
528   SUBROUTINE hpg_isf( kt, Kmm, puu, pvv, Krhs )
529      !!---------------------------------------------------------------------
530      !!                  ***  ROUTINE hpg_isf  ***
531      !!
532      !! ** Method  :   s-coordinate case. Jacobian scheme.
533      !!      The now hydrostatic pressure gradient at a given level, jk,
534      !!      is computed by taking the vertical integral of the in-situ
535      !!      density gradient along the model level from the suface to that
536      !!      level. s-coordinates (ln_sco): a corrective term is added
537      !!      to the horizontal pressure gradient :
538      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
539      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
540      !!      add it to the general momentum trend (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)).
541      !!         puu(:,:,:,Krhs) = puu(:,:,:,Krhs) - 1/e1u * zhpi
542      !!         pvv(:,:,:,Krhs) = pvv(:,:,:,Krhs) - 1/e2v * zhpj
543      !!      iceload is added
544      !!     
545      !! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
546      !!----------------------------------------------------------------------
547      INTEGER                             , INTENT( in )  ::  kt          ! ocean time-step index
548      INTEGER                             , INTENT( in )  ::  Kmm, Krhs   ! ocean time level indices
549      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv    ! ocean velocities and RHS of momentum equation
550      !!
551      INTEGER  ::   ji, jj, jk             ! dummy loop indices
552      INTEGER  ::   ikt ,  ikti1,  iktj1   ! local integer
553      REAL(wp) ::   ze3w, ze3wi1, ze3wj1   ! local scalars
554      REAL(wp) ::   zcoef0, zuap, zvap     !   -      -
555      REAL(wp), DIMENSION(A2D(nn_hls),jpk ) ::  zhpi, zhpj
556      REAL(wp), DIMENSION(A2D(nn_hls),jpts) ::  zts_top
557      REAL(wp), DIMENSION(A2D(nn_hls))      ::  zrhdtop_oce
558      !!----------------------------------------------------------------------
559      !
560      zcoef0 = - grav * 0.5_wp   ! Local constant initialization
561      !
562      !                          ! iniitialised to 0. zhpi zhpi
563      zhpi(:,:,:) = 0._wp   ;   zhpj(:,:,:) = 0._wp
564
565      ! compute rhd at the ice/oce interface (ocean side)
566      ! usefull to reduce residual current in the test case ISOMIP with no melting
567      DO_2D( nn_hls, nn_hls, nn_hls, nn_hls )
568         ikt = mikt(ji,jj)
569         zts_top(ji,jj,1) = ts(ji,jj,ikt,1,Kmm)
570         zts_top(ji,jj,2) = ts(ji,jj,ikt,2,Kmm)
571      END_2D
572      CALL eos( zts_top, risfdep, zrhdtop_oce )
573
574      !                     !===========================!
575      !                     !=====  surface value  =====!
576      !                     !===========================!
577      DO_2D( 0, 0, 0, 0 )
578         ikt   = mikt(ji  ,jj  )   ;   ze3w   = e3w(ji  ,jj  ,ikt  ,Kmm)
579         ikti1 = mikt(ji+1,jj  )   ;   ze3wi1 = e3w(ji+1,jj  ,ikti1,Kmm)
580         iktj1 = mikt(ji  ,jj+1)   ;   ze3wj1 = e3w(ji  ,jj+1,iktj1,Kmm)
581         !                          ! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
582         !                          ! we assume ISF is in isostatic equilibrium
583         zhpi(ji,jj,1) = zcoef0 * r1_e1u(ji,jj) * (   risfload(ji+1,jj) - risfload(ji,jj)  &
584            &                                       + 0.5_wp * ( ze3wi1 * ( rhd(ji+1,jj,ikti1) + zrhdtop_oce(ji+1,jj) )     &
585            &                                                  - ze3w   * ( rhd(ji  ,jj,ikt  ) + zrhdtop_oce(ji  ,jj) ) )   )
586         zhpj(ji,jj,1) = zcoef0 * r1_e2v(ji,jj) * (   risfload(ji,jj+1) - risfload(ji,jj)  &
587            &                                       + 0.5_wp * ( ze3wj1 * ( rhd(ji,jj+1,iktj1) + zrhdtop_oce(ji,jj+1) )      &
588            &                                                  - ze3w   * ( rhd(ji,jj  ,ikt  ) + zrhdtop_oce(ji,jj  ) ) )   ) 
589         !                          ! s-coordinate pressure gradient correction (=0 if z coordinate)
590         zuap = -zcoef0 * ( rhd    (ji+1,jj,1) + rhd    (ji,jj,1) )   &
591            &           * ( gde3w(ji+1,jj,1) - gde3w(ji,jj,1) ) * r1_e1u(ji,jj)
592         zvap = -zcoef0 * ( rhd    (ji,jj+1,1) + rhd    (ji,jj,1) )   &
593            &           * ( gde3w(ji,jj+1,1) - gde3w(ji,jj,1) ) * r1_e2v(ji,jj)
594         !                          ! add to the general momentum trend
595         puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
596         pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
597      END_2D
598      !   
599      !                     !=============================!
600      !                     !=====  interior values  =====!
601      !                     !=============================!
602      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
603         ze3w   = e3w(ji  ,jj  ,jk,Kmm)
604         ze3wi1 = e3w(ji+1,jj  ,jk,Kmm)
605         ze3wj1 = e3w(ji  ,jj+1,jk,Kmm)
606         !                          ! hydrostatic pressure gradient along s-surfaces
607         zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   &
608            &           * (  ze3wi1 * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) ) * wmask(ji+1,jj,jk)   &
609            &              - ze3w   * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) ) * wmask(ji  ,jj,jk)   )
610         zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
611            &           * (  ze3wj1 * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) ) * wmask(ji,jj+1,jk)   &
612            &              - ze3w   * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) ) * wmask(ji,jj  ,jk)   )
613         !                          ! s-coordinate pressure gradient correction
614         zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) )   &
615            &           * ( gde3w(ji+1,jj  ,jk) - gde3w(ji,jj,jk) ) / e1u(ji,jj)
616         zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) )   &
617            &           * ( gde3w(ji  ,jj+1,jk) - gde3w(ji,jj,jk) ) / e2v(ji,jj)
618         !                          ! add to the general momentum trend
619         puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + (zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
620         pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + (zhpj(ji,jj,jk) + zvap) * vmask(ji,jj,jk)
621      END_3D
622      !
623   END SUBROUTINE hpg_isf
624
625
626   SUBROUTINE hpg_djc( kt, Kmm, puu, pvv, Krhs )
627      !!---------------------------------------------------------------------
628      !!                  ***  ROUTINE hpg_djc  ***
629      !!
630      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
631      !!
632      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
633      !!----------------------------------------------------------------------
634      INTEGER                             , INTENT( in )  ::  kt          ! ocean time-step index
635      INTEGER                             , INTENT( in )  ::  Kmm, Krhs   ! ocean time level indices
636      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv    ! ocean velocities and RHS of momentum equation
637      !!
638      INTEGER  ::   ji, jj, jk          ! dummy loop indices
639      INTEGER  ::   iktb, iktt          ! jk indices at tracer points for top and bottom points
640      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
641      REAL(wp) ::   z_grav_10, z1_12, z1_cff
642      REAL(wp) ::   cffu, cffx          !    "         "
643      REAL(wp) ::   cffv, cffy          !    "         "
644      LOGICAL  ::   ll_tmp1, ll_tmp2    ! local logical variables
645      REAL(wp), DIMENSION(A2D(nn_hls),jpk) ::   zhpi, zhpj
646
647      REAL(wp), DIMENSION(A2D(nn_hls),jpk) ::   zdzx, zdzy, zdzz                          ! Primitive grid differences ('delta_xyz')
648      REAL(wp), DIMENSION(A2D(nn_hls),jpk) ::   zdz_i, zdz_j, zdz_k                       ! Harmonic average of primitive grid differences ('d_xyz')
649      REAL(wp), DIMENSION(A2D(nn_hls),jpk) ::   zdrhox, zdrhoy, zdrhoz                    ! Primitive rho differences ('delta_rho')
650      REAL(wp), DIMENSION(A2D(nn_hls),jpk) ::   zdrho_i, zdrho_j, zdrho_k                 ! Harmonic average of primitive rho differences ('d_rho')
651      REAL(wp), DIMENSION(A2D(nn_hls),jpk) ::   z_rho_i, z_rho_j, z_rho_k                 ! Face intergrals
652      REAL(wp), DIMENSION(A2D(nn_hls))     ::   zz_dz_i, zz_dz_j, zz_drho_i, zz_drho_j    ! temporary arrays
653      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zcpx, zcpy   !W/D pressure filter
654      !!----------------------------------------------------------------------
655      !
656      IF( ln_wd_il ) THEN
657         ALLOCATE( zcpx(A2D(nn_hls)) , zcpy(A2D(nn_hls)) )
658        DO_2D( 0, 0, 0, 0 )
659          ll_tmp1 = MIN(  ssh(ji,jj,Kmm)              ,  ssh(ji+1,jj,Kmm) ) >                &
660               &    MAX( -ht_0(ji,jj)              , -ht_0(ji+1,jj) ) .AND.            &
661               &    MAX(  ssh(ji,jj,Kmm) + ht_0(ji,jj),  ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) )  &
662               &                                                      > rn_wdmin1 + rn_wdmin2
663          ll_tmp2 = ( ABS( ssh(ji,jj,Kmm)             -  ssh(ji+1,jj,Kmm) ) > 1.E-12 ) .AND. (        &
664               &    MAX(   ssh(ji,jj,Kmm)             ,  ssh(ji+1,jj,Kmm) ) >                &
665               &    MAX(  -ht_0(ji,jj)             , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
666          IF(ll_tmp1) THEN
667            zcpx(ji,jj) = 1.0_wp
668          ELSE IF(ll_tmp2) THEN
669            ! no worries about  ssh(ji+1,jj,Kmm) -  ssh(ji  ,jj,Kmm) = 0, it won't happen ! here
670            zcpx(ji,jj) = ABS( (ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
671                        &    / (ssh(ji+1,jj,Kmm) - ssh(ji  ,jj,Kmm)) )
672          ELSE
673            zcpx(ji,jj) = 0._wp
674          END IF
675   
676          ll_tmp1 = MIN(  ssh(ji,jj,Kmm)              ,  ssh(ji,jj+1,Kmm) ) >                &
677               &    MAX( -ht_0(ji,jj)              , -ht_0(ji,jj+1) ) .AND.            &
678               &    MAX(  ssh(ji,jj,Kmm) + ht_0(ji,jj),  ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) )  &
679               &                                                      > rn_wdmin1 + rn_wdmin2
680          ll_tmp2 = ( ABS( ssh(ji,jj,Kmm)             -  ssh(ji,jj+1,Kmm) ) > 1.E-12 ) .AND. (        &
681               &    MAX(   ssh(ji,jj,Kmm)             ,  ssh(ji,jj+1,Kmm) ) >                &
682               &    MAX(  -ht_0(ji,jj)             , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
683
684          IF(ll_tmp1) THEN
685            zcpy(ji,jj) = 1.0_wp
686          ELSE IF(ll_tmp2) THEN
687            ! no worries about  ssh(ji,jj+1,Kmm) -  ssh(ji,jj  ,Kmm) = 0, it won't happen ! here
688            zcpy(ji,jj) = ABS( (ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
689                        &    / (ssh(ji,jj+1,Kmm) - ssh(ji,jj  ,Kmm)) )
690          ELSE
691            zcpy(ji,jj) = 0._wp
692          END IF
693        END_2D
694      END IF
695
696      IF( .NOT. l_istiled .OR. ntile == 1 )  THEN                       ! Do only on the first tile
697         IF( kt == nit000 ) THEN
698            IF(lwp) WRITE(numout,*)
699            IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
700            IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
701         ENDIF
702      ENDIF
703
704      ! Local constant initialization
705      zcoef0 = - grav * 0.5_wp
706      z_grav_10  = grav / 10._wp
707      z1_12  = 1.0_wp / 12._wp
708
709      !----------------------------------------------------------------------------------------
710      !  1. compute and store elementary vertical differences in provisional arrays
711      !----------------------------------------------------------------------------------------
712
713!!bug gm   Not a true bug, but... zdzz=e3w  for zdzx, zdzy verify what it is really
714
715      DO_3D( 1, 1, 1, 1, 2, jpkm1 ) 
716         zdrhoz(ji,jj,jk) =   rhd    (ji  ,jj  ,jk) - rhd    (ji,jj,jk-1)
717         zdzz  (ji,jj,jk) = - gde3w(ji  ,jj  ,jk) + gde3w(ji,jj,jk-1)
718      END_3D
719
720      !-------------------------------------------------------------------------
721      ! 2. compute harmonic averages for vertical differences using eq. 5.18
722      !-------------------------------------------------------------------------
723      zep = 1.e-15
724
725!! mb zdrho_k, zdz_k, zdrho_i, zdz_i, zdrho_j, zdz_j re-centred about the point (ji,jj,jk)
726      zdrho_k(:,:,:) = 0._wp
727      zdz_k  (:,:,:) = 0._wp
728
729      DO_3D( 1, 1, 1, 1, 2, jpk-2 )
730         cffw = MAX( 2._wp * zdrhoz(ji,jj,jk) * zdrhoz(ji,jj,jk+1), 0._wp )
731         z1_cff = zdrhoz(ji,jj,jk) + zdrhoz(ji,jj,jk+1)
732         zdrho_k(ji,jj,jk) = cffw / SIGN( MAX( ABS(z1_cff), zep ), z1_cff )
733         zdz_k(ji,jj,jk) = 2._wp *   zdzz(ji,jj,jk) * zdzz(ji,jj,jk+1)   &
734            &                  / ( zdzz(ji,jj,jk) + zdzz(ji,jj,jk+1) )
735      END_3D
736
737      !----------------------------------------------------------------------------------
738      ! 3. apply boundary conditions at top and bottom using 5.36-5.37
739      !----------------------------------------------------------------------------------
740
741! mb for sea-ice shelves we will need to re-write this upper boundary condition in the same form as the lower boundary condition
742      DO_2D( 1, 1, 1, 1 )
743         zdrho_k(ji,jj,1) = aco_bc_vrt * ( rhd  (ji,jj,2) - rhd  (ji,jj,1) ) - bco_bc_vrt * zdrho_k(ji,jj,2)
744         zdz_k  (ji,jj,1) = aco_bc_vrt * (-gde3w(ji,jj,2) + gde3w(ji,jj,1) ) - bco_bc_vrt * zdz_k  (ji,jj,2)
745      END_2D
746
747      DO_2D( 1, 1, 1, 1 )
748         IF ( mbkt(ji,jj)>1 ) THEN
749            iktb = mbkt(ji,jj)
750            zdrho_k(ji,jj,iktb) = aco_bc_vrt * (     rhd(ji,jj,iktb) -     rhd(ji,jj,iktb-1) ) - bco_bc_vrt * zdrho_k(ji,jj,iktb-1)
751            zdz_k  (ji,jj,iktb) = aco_bc_vrt * (-gde3w(ji,jj,iktb) + gde3w(ji,jj,iktb-1) ) - bco_bc_vrt * zdz_k  (ji,jj,iktb-1) 
752         END IF
753      END_2D
754
755      !--------------------------------------------------------------
756      ! 4. Compute side face integrals
757      !-------------------------------------------------------------
758
759!! ssh replaces e3w_n ; gde3w is a depth; the formulae involve heights 
760!! rho_k stores grav * FX / rho_0 
761
762      !--------------------------------------------------------------
763      ! 4. a) Upper half of top-most grid box, compute and store
764      !-------------------------------------------------------------
765! *** AY note: ssh(ji,jj,Kmm) + gde3w(ji,jj,1) = e3w(ji,jj,1,Kmm)
766      DO_2D( 0, 1, 0, 1)
767         z_rho_k(ji,jj,1) =  grav * ( ssh(ji,jj,Kmm) + gde3w(ji,jj,1) )                        & 
768            &                     * (  rhd(ji,jj,1)                                        &
769            &                     + 0.5_wp * (   rhd    (ji,jj,2) - rhd    (ji,jj,1) ) &
770            &                              * (   ssh   (ji,jj,Kmm) + gde3w(ji,jj,1) )          &
771            &                              / ( - gde3w(ji,jj,2) + gde3w(ji,jj,1) )  )
772      END_2D
773
774      !--------------------------------------------------------------
775      ! 4. b) Interior faces, compute and store
776      !-------------------------------------------------------------
777
778      DO_3D( 0, 1, 0, 1, 2, jpkm1 )
779         z_rho_k(ji,jj,jk) = zcoef0 * (   rhd    (ji,jj,jk) + rhd    (ji,jj,jk-1) )                                   &
780            &                       * ( - gde3w(ji,jj,jk) + gde3w(ji,jj,jk-1) )                                               &
781            &                       + z_grav_10 * (                                                                           &
782            &     (   zdrho_k  (ji,jj,jk) - zdrho_k  (ji,jj,jk-1) )                                                           &
783            &   * ( - gde3w(ji,jj,jk) + gde3w(ji,jj,jk-1) - z1_12 * ( zdz_k  (ji,jj,jk) + zdz_k  (ji,jj,jk-1) ) )             &
784            &   - ( zdz_k    (ji,jj,jk) - zdz_k    (ji,jj,jk-1) )                                                             &
785            &   * ( rhd    (ji,jj,jk) - rhd    (ji,jj,jk-1) - z1_12 * ( zdrho_k(ji,jj,jk) + zdrho_k(ji,jj,jk-1) ) )   &
786            &                             )
787      END_3D
788
789      !----------------------------------------------------------------------------------------
790      !  5. compute and store elementary horizontal differences in provisional arrays
791      !----------------------------------------------------------------------------------------
792      zdrhox(:,:,:) = 0._wp
793      zdzx  (:,:,:) = 0._wp
794      zdrhoy(:,:,:) = 0._wp
795      zdzy  (:,:,:) = 0._wp
796
797      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 )
798         zdrhox(ji,jj,jk) = rhd  (ji+1,jj  ,jk) - rhd  (ji  ,jj  ,jk)
799         zdzx  (ji,jj,jk) = gde3w(ji  ,jj  ,jk) - gde3w(ji+1,jj  ,jk)
800         zdrhoy(ji,jj,jk) = rhd  (ji  ,jj+1,jk) - rhd  (ji  ,jj  ,jk)
801         zdzy  (ji,jj,jk) = gde3w(ji  ,jj  ,jk) - gde3w(ji  ,jj+1,jk)
802      END_3D
803
804      IF( nn_hls == 1 ) CALL lbc_lnk( 'dynhpg', zdrhox, 'U', -1._wp, zdzx, 'U', -1._wp, zdrhoy, 'V', -1._wp, zdzy, 'V', -1._wp )
805
806      !-------------------------------------------------------------------------
807      ! 6. compute harmonic averages using eq. 5.18
808      !-------------------------------------------------------------------------
809
810      DO_3D( 0, 1, 0, 1, 1, jpkm1 )
811         cffu = MAX( 2._wp * zdrhox(ji-1,jj,jk) * zdrhox(ji,jj,jk), 0._wp )
812         z1_cff = zdrhox(ji-1,jj,jk) + zdrhox(ji,jj,jk)
813         zdrho_i(ji,jj,jk) = cffu / SIGN( MAX( ABS(z1_cff), zep ), z1_cff )
814
815         cffx = MAX( 2._wp * zdzx(ji-1,jj,jk)   * zdzx(ji,jj,jk), 0._wp )
816         z1_cff = zdzx(ji-1,jj,jk)   + zdzx(ji,jj,jk)
817         zdz_i(ji,jj,jk)   = cffx / SIGN( MAX( ABS(z1_cff), zep ), z1_cff )
818
819         cffv = MAX( 2._wp * zdrhoy(ji,jj-1,jk) * zdrhoy(ji,jj,jk), 0._wp )
820         z1_cff = zdrhoy(ji,jj-1,jk) + zdrhoy(ji,jj,jk)
821         zdrho_j(ji,jj,jk) = cffv / SIGN( MAX( ABS(z1_cff), zep ), z1_cff )
822
823         cffy = MAX( 2._wp * zdzy(ji,jj-1,jk)   * zdzy(ji,jj,jk), 0._wp )
824         z1_cff = zdzy(ji,jj-1,jk)   + zdzy(ji,jj,jk)
825         zdz_j(ji,jj,jk)   = cffy / SIGN( MAX( ABS(z1_cff), zep ), z1_cff )
826      END_3D
827     
828!!! Note that zdzx, zdzy, zdzz, zdrhox, zdrhoy and zdrhoz should NOT be used beyond this point     
829
830      !----------------------------------------------------------------------------------
831      ! 6B. apply boundary conditions at side boundaries using 5.36-5.37
832      !----------------------------------------------------------------------------------
833
834      DO jk = 1, jpkm1
835         zz_drho_i(:,:) = zdrho_i(:,:,jk)
836         zz_dz_i  (:,:) = zdz_i  (:,:,jk)
837         zz_drho_j(:,:) = zdrho_j(:,:,jk)
838         zz_dz_j  (:,:) = zdz_j  (:,:,jk)
839         ! Walls coming from left: should check from 2 to jpi-1 (and jpj=2-jpj)
840         DO_2D( 0, 0, 0, 1 )
841            IF ( umask(ji,jj,jk) > 0.5_wp .AND. umask(ji-1,jj,jk) < 0.5_wp .AND. umask(ji+1,jj,jk) > 0.5_wp)  THEN
842               zz_drho_i(ji,jj) = aco_bc_hor * ( rhd    (ji+1,jj,jk) - rhd    (ji,jj,jk) ) - bco_bc_hor * zdrho_i(ji+1,jj,jk)
843               zz_dz_i  (ji,jj) = aco_bc_hor * (-gde3w(ji+1,jj,jk) + gde3w(ji,jj,jk) ) - bco_bc_hor * zdz_i  (ji+1,jj,jk)
844            END IF
845         END_2D
846         ! Walls coming from right: should check from 3 to jpi (and jpj=2-jpj)
847         DO_2D( -1, 1, 0, 1 )
848            IF ( umask(ji,jj,jk) < 0.5_wp .AND. umask(ji-1,jj,jk) > 0.5_wp .AND. umask(ji-2,jj,jk) > 0.5_wp) THEN
849               zz_drho_i(ji,jj) = aco_bc_hor * ( rhd    (ji,jj,jk) - rhd    (ji-1,jj,jk) ) - bco_bc_hor * zdrho_i(ji-1,jj,jk)
850               zz_dz_i  (ji,jj) = aco_bc_hor * (-gde3w(ji,jj,jk) + gde3w(ji-1,jj,jk) ) - bco_bc_hor * zdz_i  (ji-1,jj,jk)
851            END IF
852         END_2D
853         ! Walls coming from left: should check from 2 to jpj-1 (and jpi=2-jpi)
854         DO_2D( 0, 1, 0, 0 )
855            IF ( vmask(ji,jj,jk) > 0.5_wp .AND. vmask(ji,jj-1,jk) < 0.5_wp .AND. vmask(ji,jj+1,jk) > 0.5_wp)  THEN
856               zz_drho_j(ji,jj) = aco_bc_hor * ( rhd    (ji,jj+1,jk) - rhd    (ji,jj,jk) ) - bco_bc_hor * zdrho_j(ji,jj+1,jk)
857               zz_dz_j  (ji,jj) = aco_bc_hor * (-gde3w(ji,jj+1,jk) + gde3w(ji,jj,jk) ) - bco_bc_hor * zdz_j  (ji,jj+1,jk)
858            END IF
859         END_2D
860         ! Walls coming from right: should check from 3 to jpj (and jpi=2-jpi)
861         DO_2D( 0, 1, -1, 1 )
862            IF ( vmask(ji,jj,jk) < 0.5_wp .AND. vmask(ji,jj-1,jk) > 0.5_wp .AND. vmask(ji,jj-2,jk) > 0.5_wp) THEN
863               zz_drho_j(ji,jj) = aco_bc_hor * ( rhd    (ji,jj,jk) - rhd    (ji,jj-1,jk) ) - bco_bc_hor * zdrho_j(ji,jj-1,jk)
864               zz_dz_j  (ji,jj) = aco_bc_hor * (-gde3w(ji,jj,jk) + gde3w(ji,jj-1,jk) ) - bco_bc_hor * zdz_j  (ji,jj-1,jk)
865            END IF
866         END_2D
867         zdrho_i(:,:,jk) = zz_drho_i(:,:)
868         zdz_i  (:,:,jk) = zz_dz_i  (:,:)
869         zdrho_j(:,:,jk) = zz_drho_j(:,:)
870         zdz_j  (:,:,jk) = zz_dz_j  (:,:)
871      END DO
872
873      !--------------------------------------------------------------
874      ! 7. Calculate integrals on side faces 
875      !-------------------------------------------------------------
876
877      DO_3D( 0, 0, 0, 0, 1, jpkm1 )
878! two -ve signs cancel in next two lines (within zcoef0 and because gde3w is a depth not a height)
879         z_rho_i(ji,jj,jk) = zcoef0 * ( rhd    (ji+1,jj,jk) + rhd    (ji,jj,jk) )                                       &
880             &                    * ( gde3w(ji+1,jj,jk) - gde3w(ji,jj,jk) )                                   
881         IF ( umask(ji-1, jj, jk) > 0.5 .OR. umask(ji+1, jj, jk) > 0.5 ) THEN
882            z_rho_i(ji,jj,jk) = z_rho_i(ji,jj,jk) - z_grav_10 * (                                                               &
883             &     (   zdrho_i  (ji+1,jj,jk) - zdrho_i  (ji,jj,jk) )                                                            &
884             &   * ( - gde3w(ji+1,jj,jk) + gde3w(ji,jj,jk) - z1_12 * ( zdz_i  (ji+1,jj,jk) + zdz_i  (ji,jj,jk) ) )              &
885             &   - (   zdz_i    (ji+1,jj,jk) - zdz_i    (ji,jj,jk) )                                                            &
886             &   * (   rhd    (ji+1,jj,jk) - rhd    (ji,jj,jk) - z1_12 * ( zdrho_i(ji+1,jj,jk) + zdrho_i(ji,jj,jk) ) )  &
887             &                                               )
888         END IF
889 
890         z_rho_j(ji,jj,jk) = zcoef0 * ( rhd    (ji,jj+1,jk) + rhd    (ji,jj,jk) )                                       &
891             &                    * ( gde3w(ji,jj+1,jk) - gde3w(ji,jj,jk) )                                 
892         IF ( vmask(ji, jj-1, jk) > 0.5 .OR. vmask(ji, jj+1, jk) > 0.5 ) THEN
893            z_rho_j(ji,jj,jk) = z_rho_j(ji,jj,jk) - z_grav_10 * (                                                               &
894             &     (   zdrho_j  (ji,jj+1,jk) - zdrho_j  (ji,jj,jk) )                                                            &
895             &   * ( - gde3w(ji,jj+1,jk) + gde3w(ji,jj,jk) - z1_12 * ( zdz_j  (ji,jj+1,jk) + zdz_j  (ji,jj,jk) ) )              &
896             &   - (   zdz_j    (ji,jj+1,jk) - zdz_j    (ji,jj,jk) )                                                            &
897             &   * (   rhd    (ji,jj+1,jk) - rhd    (ji,jj,jk) - z1_12 * ( zdrho_j(ji,jj+1,jk) + zdrho_j(ji,jj,jk) ) )  &
898             &                                                 )
899         END IF
900      END_3D
901
902      !--------------------------------------------------------------
903      ! 8. Integrate in the vertical   
904      !-------------------------------------------------------------
905      !
906      ! ---------------
907      !  Surface value
908      ! ---------------
909      DO_2D( 0, 0, 0, 0 )
910         zhpi(ji,jj,1) = ( z_rho_k(ji,jj,1) - z_rho_k(ji+1,jj  ,1) - z_rho_i(ji,jj,1) ) * r1_e1u(ji,jj)
911         zhpj(ji,jj,1) = ( z_rho_k(ji,jj,1) - z_rho_k(ji  ,jj+1,1) - z_rho_j(ji,jj,1) ) * r1_e2v(ji,jj)
912         IF( ln_wd_il ) THEN
913           zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
914           zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj) 
915         ENDIF
916         ! add to the general momentum trend
917         puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj,1)
918         pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj,1)
919      END_2D
920
921      ! ----------------
922      !  interior value   (2=<jk=<jpkm1)
923      ! ----------------
924      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
925         ! hydrostatic pressure gradient along s-surfaces
926         zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                                     &
927            &           + (  ( z_rho_k(ji,jj,jk) - z_rho_k(ji+1,jj,jk  ) )                     &
928            &              - ( z_rho_i(ji,jj,jk) - z_rho_i(ji  ,jj,jk-1) )  ) * r1_e1u(ji,jj)
929         zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                                     &
930            &           + (  ( z_rho_k(ji,jj,jk) - z_rho_k(ji,jj+1,jk  ) )                     &
931            &               -( z_rho_j(ji,jj,jk) - z_rho_j(ji,jj  ,jk-1) )  ) * r1_e2v(ji,jj)
932         IF( ln_wd_il ) THEN
933           zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
934           zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj) 
935         ENDIF
936         ! add to the general momentum trend
937         puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj,jk)
938         pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj,jk)
939      END_3D
940      !
941      IF( ln_wd_il )   DEALLOCATE( zcpx, zcpy )
942      !
943   END SUBROUTINE hpg_djc
944
945
946   SUBROUTINE hpg_prj( kt, Kmm, puu, pvv, Krhs )
947      !!---------------------------------------------------------------------
948      !!                  ***  ROUTINE hpg_prj  ***
949      !!
950      !! ** Method  :   s-coordinate case.
951      !!      A Pressure-Jacobian horizontal pressure gradient method
952      !!      based on the constrained cubic-spline interpolation for
953      !!      all vertical coordinate systems
954      !!
955      !! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
956      !!----------------------------------------------------------------------
957      INTEGER, PARAMETER  :: polynomial_type = 1    ! 1: cubic spline, 2: linear
958      INTEGER                             , INTENT( in )  ::  kt          ! ocean time-step index
959      INTEGER                             , INTENT( in )  ::  Kmm, Krhs   ! ocean time level indices
960      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv    ! ocean velocities and RHS of momentum equation
961      !!
962      INTEGER  ::   ji, jj, jk, jkk                 ! dummy loop indices
963      REAL(wp) ::   zcoef0, znad                    ! local scalars
964      !
965      !! The local variables for the correction term
966      INTEGER  :: jk1, jis, jid, jjs, jjd
967      LOGICAL  :: ll_tmp1, ll_tmp2                  ! local logical variables
968      REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
969      REAL(wp) :: zrhdt1
970      REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
971      REAL(wp), DIMENSION(A2D(nn_hls))     ::   zpgu, zpgv   ! 2D workspace
972      REAL(wp), DIMENSION(A2D(nn_hls))     ::   zsshu_n, zsshv_n
973      REAL(wp), DIMENSION(A2D(nn_hls),jpk) ::   zdept, zrhh
974      REAL(wp), DIMENSION(A2D(nn_hls),jpk) ::   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
975      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zcpx, zcpy   !W/D pressure filter
976      !!----------------------------------------------------------------------
977      !
978      IF( .NOT. l_istiled .OR. ntile == 1 )  THEN                       ! Do only on the first tile
979         IF( kt == nit000 ) THEN
980            IF(lwp) WRITE(numout,*)
981            IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
982            IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, cubic spline pressure Jacobian'
983         ENDIF
984      ENDIF
985
986      ! Local constant initialization
987      zcoef0 = - grav
988      znad = 1._wp
989      IF( ln_linssh )   znad = 1._wp
990      !
991      ! ---------------
992      !  Surface pressure gradient to be removed
993      ! ---------------
994      DO_2D( 0, 0, 0, 0 )
995         zpgu(ji,jj) = - grav * ( ssh(ji+1,jj,Kmm) - ssh(ji,jj,Kmm) ) * r1_e1u(ji,jj)
996         zpgv(ji,jj) = - grav * ( ssh(ji,jj+1,Kmm) - ssh(ji,jj,Kmm) ) * r1_e2v(ji,jj)
997      END_2D
998      !
999      IF( ln_wd_il ) THEN
1000         ALLOCATE( zcpx(A2D(nn_hls)) , zcpy(A2D(nn_hls)) )
1001         DO_2D( 0, 0, 0, 0 )
1002            ll_tmp1 = MIN(   ssh(ji,jj,Kmm)              ,   ssh(ji+1,jj,Kmm)                 ) >       &
1003               &      MAX( -ht_0(ji,jj)                  , -ht_0(ji+1,jj)                     ) .AND.   &
1004               &      MAX(   ssh(ji,jj,Kmm) + ht_0(ji,jj),   ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) ) >       &
1005               &      rn_wdmin1 + rn_wdmin2
1006            ll_tmp2 = ( ABS(   ssh(ji,jj,Kmm) -   ssh(ji+1,jj,Kmm) ) > 1.E-12 ) .AND.                   &
1007               &      ( MAX(   ssh(ji,jj,Kmm) ,   ssh(ji+1,jj,Kmm) ) >                                  &
1008               &        MAX( -ht_0(ji,jj)     , -ht_0(ji+1,jj)     ) + rn_wdmin1 + rn_wdmin2 )
1009
1010            IF(ll_tmp1) THEN
1011               zcpx(ji,jj) = 1.0_wp
1012            ELSE IF(ll_tmp2) THEN
1013               ! no worries about  ssh(ji+1,jj,Kmm) -  ssh(ji  ,jj,Kmm) = 0, it won't happen ! here
1014               zcpx(ji,jj) = ABS( (ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
1015                           &    / (ssh(ji+1,jj,Kmm) -  ssh(ji  ,jj,Kmm)) )
1016               zcpx(ji,jj) = MAX(MIN( zcpx(ji,jj) , 1.0_wp),0.0_wp)
1017            ELSE
1018               zcpx(ji,jj) = 0._wp
1019            END IF
1020
1021            ll_tmp1 = MIN(   ssh(ji,jj,Kmm)              ,   ssh(ji,jj+1,Kmm)                 ) >       &
1022               &      MAX( -ht_0(ji,jj)                  , -ht_0(ji,jj+1)                     ) .AND.   &
1023               &      MAX(   ssh(ji,jj,Kmm) + ht_0(ji,jj),   ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) ) >       &
1024               &      rn_wdmin1 + rn_wdmin2
1025            ll_tmp2 = ( ABS(   ssh(ji,jj,Kmm) -   ssh(ji,jj+1,Kmm) ) > 1.E-12 ) .AND.                   &
1026               &      ( MAX(   ssh(ji,jj,Kmm) ,   ssh(ji,jj+1,Kmm) ) >                                  &
1027               &        MAX( -ht_0(ji,jj)     , -ht_0(ji,jj+1)     ) + rn_wdmin1 + rn_wdmin2 )
1028
1029            IF(ll_tmp1) THEN
1030               zcpy(ji,jj) = 1.0_wp
1031            ELSE IF(ll_tmp2) THEN
1032               ! no worries about  ssh(ji,jj+1,Kmm) -  ssh(ji,jj  ,Kmm) = 0, it won't happen ! here
1033               zcpy(ji,jj) = ABS( (ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
1034                           &    / (ssh(ji,jj+1,Kmm) -  ssh(ji,jj  ,Kmm)) )
1035               zcpy(ji,jj) = MAX(MIN( zcpy(ji,jj) , 1.0_wp),0.0_wp)
1036            ELSE
1037               zcpy(ji,jj) = 0._wp
1038            ENDIF
1039         END_2D
1040      ENDIF
1041
1042      ! Clean 3-D work arrays
1043      zhpi(:,:,:) = 0._wp
1044      zrhh(:,:,:) = rhd(A2D(nn_hls),:)
1045
1046      ! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
1047      DO_2D( 1, 1, 1, 1 )
1048         jk = mbkt(ji,jj)
1049         IF(     jk <=  1   ) THEN   ;   zrhh(ji,jj,    :   ) = 0._wp
1050         ELSEIF( jk ==  2   ) THEN   ;   zrhh(ji,jj,jk+1:jpk) = rhd(ji,jj,jk)
1051         ELSEIF( jk < jpkm1 ) THEN
1052            DO jkk = jk+1, jpk
1053               zrhh(ji,jj,jkk) = interp1(gde3w(ji,jj,jkk  ), gde3w(ji,jj,jkk-1),   &
1054                  &                      gde3w(ji,jj,jkk-2), zrhh (ji,jj,jkk-1), zrhh(ji,jj,jkk-2))
1055            END DO
1056         ENDIF
1057      END_2D
1058
1059      ! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
1060      DO_2D( 1, 1, 1, 1 )
1061         zdept(ji,jj,1) = 0.5_wp * e3w(ji,jj,1,Kmm) - ssh(ji,jj,Kmm)
1062      END_2D
1063
1064      DO_3D( 1, 1, 1, 1, 2, jpk )
1065         zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + e3w(ji,jj,jk,Kmm)
1066      END_3D
1067
1068      fsp(:,:,:) = zrhh (:,:,:)
1069      xsp(:,:,:) = zdept(:,:,:)
1070
1071      ! Construct the vertical density profile with the
1072      ! constrained cubic spline interpolation
1073      ! rho(z) = asp + bsp*z + csp*z^2 + dsp*z^3
1074      CALL cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1075
1076      ! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
1077      DO_2D( 0, 1, 0, 1 )
1078         zrhdt1 = zrhh(ji,jj,1) - interp3( zdept(ji,jj,1), asp(ji,jj,1), bsp(ji,jj,1),  &
1079            &                                              csp(ji,jj,1), dsp(ji,jj,1) ) * 0.25_wp * e3w(ji,jj,1,Kmm)
1080
1081         ! assuming linear profile across the top half surface layer
1082         zhpi(ji,jj,1) =  0.5_wp * e3w(ji,jj,1,Kmm) * zrhdt1
1083      END_2D
1084
1085      ! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
1086      DO_3D( 0, 1, 0, 1, 2, jpkm1 )
1087         zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) +                                  &
1088            &             integ_spline( zdept(ji,jj,jk-1), zdept(ji,jj,jk),   &
1089            &                           asp  (ji,jj,jk-1), bsp  (ji,jj,jk-1), &
1090            &                           csp  (ji,jj,jk-1), dsp  (ji,jj,jk-1)  )
1091      END_3D
1092
1093      ! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
1094
1095      ! Prepare zsshu_n and zsshv_n
1096      DO_2D( 0, 0, 0, 0 )
1097!!gm BUG ?    if it is ssh at u- & v-point then it should be:
1098!          zsshu_n(ji,jj) = (e1e2t(ji,jj) * ssh(ji,jj,Kmm) + e1e2t(ji+1,jj) * ssh(ji+1,jj,Kmm)) * &
1099!                         & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp
1100!          zsshv_n(ji,jj) = (e1e2t(ji,jj) * ssh(ji,jj,Kmm) + e1e2t(ji,jj+1) * ssh(ji,jj+1,Kmm)) * &
1101!                         & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp
1102!!gm not this:
1103         zsshu_n(ji,jj) = (e1e2u(ji,jj) * ssh(ji,jj,Kmm) + e1e2u(ji+1, jj) * ssh(ji+1,jj,Kmm)) * &
1104                        & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp
1105         zsshv_n(ji,jj) = (e1e2v(ji,jj) * ssh(ji,jj,Kmm) + e1e2v(ji+1, jj) * ssh(ji,jj+1,Kmm)) * &
1106                        & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp
1107      END_2D
1108
1109      DO_2D( 0, 0, 0, 0 )
1110         zu(ji,jj,1) = - ( e3u(ji,jj,1,Kmm) - zsshu_n(ji,jj) )
1111         zv(ji,jj,1) = - ( e3v(ji,jj,1,Kmm) - zsshv_n(ji,jj) )
1112      END_2D
1113
1114      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
1115         zu(ji,jj,jk) = zu(ji,jj,jk-1) - e3u(ji,jj,jk,Kmm)
1116         zv(ji,jj,jk) = zv(ji,jj,jk-1) - e3v(ji,jj,jk,Kmm)
1117      END_3D
1118
1119      DO_3D( 0, 0, 0, 0, 1, jpkm1 )
1120         zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * e3u(ji,jj,jk,Kmm)
1121         zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * e3v(ji,jj,jk,Kmm)
1122      END_3D
1123
1124      DO_3D( 0, 0, 0, 0, 1, jpkm1 )
1125         zu(ji,jj,jk) = MIN(  zu(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) )  )
1126         zu(ji,jj,jk) = MAX(  zu(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) )  )
1127         zv(ji,jj,jk) = MIN(  zv(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) )  )
1128         zv(ji,jj,jk) = MAX(  zv(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) )  )
1129      END_3D
1130
1131
1132      DO_3D( 0, 0, 0, 0, 1, jpkm1 )
1133         zpwes = 0._wp; zpwed = 0._wp
1134         zpnss = 0._wp; zpnsd = 0._wp
1135         zuijk = zu(ji,jj,jk)
1136         zvijk = zv(ji,jj,jk)
1137
1138         !!!!!     for u equation
1139         IF( jk <= mbku(ji,jj) ) THEN
1140            IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1141              jis = ji + 1; jid = ji
1142            ELSE
1143              jis = ji;     jid = ji +1
1144            ENDIF
1145
1146            ! integrate the pressure on the shallow side
1147            jk1 = jk
1148            DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1149               IF( jk1 == mbku(ji,jj) ) THEN
1150                  zuijk = -zdept(jis,jj,jk1)
1151                  EXIT
1152               ENDIF
1153               zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1154               zpwes = zpwes +                                      &
1155                  integ_spline(zdept(jis,jj,jk1), zdeps,            &
1156                                 asp(jis,jj,jk1), bsp(jis,jj,jk1),  &
1157                                 csp(jis,jj,jk1), dsp(jis,jj,jk1))
1158               jk1 = jk1 + 1
1159            END DO
1160
1161            ! integrate the pressure on the deep side
1162            jk1 = jk
1163            DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1164               IF( jk1 == 1 ) THEN
1165                  zdeps = zdept(jid,jj,1) + MIN(zuijk, ssh(jid,jj,Kmm)*znad)
1166                  zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1167                                                    bsp(jid,jj,1)  , csp(jid,jj,1), &
1168                                                    dsp(jid,jj,1)) * zdeps
1169                  zpwed  = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1170                  EXIT
1171               ENDIF
1172               zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1173               zpwed = zpwed +                                        &
1174                  integ_spline(zdeps,             zdept(jid,jj,jk1),  &
1175                               asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1),  &
1176                               csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1177               jk1 = jk1 - 1
1178            END DO
1179
1180            ! update the momentum trends in u direction
1181            zdpdx1 = zcoef0 * r1_e1u(ji,jj) * ( zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk) )
1182            IF( .NOT.ln_linssh ) THEN
1183               zdpdx2 = zcoef0 * r1_e1u(ji,jj) * &
1184                  &    ( REAL(jis-jid, wp) * (zpwes + zpwed) + (ssh(ji+1,jj,Kmm)-ssh(ji,jj,Kmm)) )
1185            ELSE
1186               zdpdx2 = zcoef0 * r1_e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1187            ENDIF
1188            IF( ln_wd_il ) THEN
1189               zdpdx1 = zdpdx1 * zcpx(ji,jj) * wdrampu(ji,jj)
1190               zdpdx2 = zdpdx2 * zcpx(ji,jj) * wdrampu(ji,jj)
1191            ENDIF
1192            puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + (zdpdx1 + zdpdx2 - zpgu(ji,jj)) * umask(ji,jj,jk)
1193         ENDIF
1194
1195         !!!!!     for v equation
1196         IF( jk <= mbkv(ji,jj) ) THEN
1197            IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1198               jjs = jj + 1; jjd = jj
1199            ELSE
1200               jjs = jj    ; jjd = jj + 1
1201            ENDIF
1202
1203            ! integrate the pressure on the shallow side
1204            jk1 = jk
1205            DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1206               IF( jk1 == mbkv(ji,jj) ) THEN
1207                  zvijk = -zdept(ji,jjs,jk1)
1208                  EXIT
1209               ENDIF
1210               zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1211               zpnss = zpnss +                                       &
1212                  integ_spline(zdept(ji,jjs,jk1), zdeps,             &
1213                               asp(ji,jjs,jk1),   bsp(ji,jjs,jk1),   &
1214                               csp(ji,jjs,jk1),   dsp(ji,jjs,jk1) )
1215              jk1 = jk1 + 1
1216            END DO
1217
1218            ! integrate the pressure on the deep side
1219            jk1 = jk
1220            DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1221               IF( jk1 == 1 ) THEN
1222                  zdeps = zdept(ji,jjd,1) + MIN(zvijk, ssh(ji,jjd,Kmm)*znad)
1223                  zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1224                                                    bsp(ji,jjd,1)  , csp(ji,jjd,1), &
1225                                                    dsp(ji,jjd,1) ) * zdeps
1226                  zpnsd  = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1227                  EXIT
1228               ENDIF
1229               zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1230               zpnsd = zpnsd +                                        &
1231                  integ_spline(zdeps,             zdept(ji,jjd,jk1),  &
1232                               asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1),  &
1233                               csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1234               jk1 = jk1 - 1
1235            END DO
1236
1237            ! update the momentum trends in v direction
1238            zdpdy1 = zcoef0 * r1_e2v(ji,jj) * ( zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk) )
1239            IF( .NOT.ln_linssh ) THEN
1240               zdpdy2 = zcoef0 * r1_e2v(ji,jj) * &
1241                       ( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (ssh(ji,jj+1,Kmm)-ssh(ji,jj,Kmm)) )
1242            ELSE
1243               zdpdy2 = zcoef0 * r1_e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1244            ENDIF
1245            IF( ln_wd_il ) THEN
1246               zdpdy1 = zdpdy1 * zcpy(ji,jj) * wdrampv(ji,jj)
1247               zdpdy2 = zdpdy2 * zcpy(ji,jj) * wdrampv(ji,jj)
1248            ENDIF
1249
1250            pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + (zdpdy1 + zdpdy2 - zpgv(ji,jj)) * vmask(ji,jj,jk)
1251         ENDIF
1252         !
1253      END_3D
1254      !
1255      IF( ln_wd_il )   DEALLOCATE( zcpx, zcpy )
1256      !
1257   END SUBROUTINE hpg_prj
1258
1259
1260   SUBROUTINE cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1261      !!----------------------------------------------------------------------
1262      !!                 ***  ROUTINE cspline  ***
1263      !!
1264      !! ** Purpose :   constrained cubic spline interpolation
1265      !!
1266      !! ** Method  :   f(x) = asp + bsp*x + csp*x^2 + dsp*x^3
1267      !!
1268      !! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1269      !!----------------------------------------------------------------------
1270      REAL(wp), DIMENSION(A2D(nn_hls),jpk), INTENT(in   ) ::   fsp, xsp           ! value and coordinate
1271      REAL(wp), DIMENSION(A2D(nn_hls),jpk), INTENT(  out) ::   asp, bsp, csp, dsp ! coefficients of the interpoated function
1272      INTEGER                             , INTENT(in   ) ::   polynomial_type    ! 1: cubic spline   ;   2: Linear
1273      !
1274      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
1275      REAL(wp) ::   zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1276      REAL(wp) ::   zdxtmp1, zdxtmp2, zalpha
1277      REAL(wp) ::   zdf(jpk)
1278      !!----------------------------------------------------------------------
1279      !
1280      IF (polynomial_type == 1) THEN     ! Constrained Cubic Spline
1281         DO_2D( 1, 1, 1, 1 )
1282            !!Fritsch&Butland's method, 1984 (preferred, but more computation)
1283            !    DO jk = 2, jpkm1-1
1284            !       zdxtmp1 = xsp(ji,jj,jk)   - xsp(ji,jj,jk-1)
1285            !       zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1286            !       zdf1    = ( fsp(ji,jj,jk)   - fsp(ji,jj,jk-1) ) / zdxtmp1
1287            !       zdf2    = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk)   ) / zdxtmp2
1288            !
1289            !       zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1290            !
1291            !       IF(zdf1 * zdf2 <= 0._wp) THEN
1292            !           zdf(jk) = 0._wp
1293            !       ELSE
1294            !         zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1295            !       ENDIF
1296            !    END DO
1297
1298            !!Simply geometric average
1299            DO jk = 2, jpk-2
1300               zdf1 = (fsp(ji,jj,jk  ) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk  ) - xsp(ji,jj,jk-1))
1301               zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk  )) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk  ))
1302
1303               IF(zdf1 * zdf2 <= 0._wp) THEN
1304                  zdf(jk) = 0._wp
1305               ELSE
1306                  zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1307               ENDIF
1308            END DO
1309
1310            zdf(1)     = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1311                       &          ( xsp(ji,jj,2) - xsp(ji,jj,1) )           -  0.5_wp * zdf(2)
1312            zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1313                       &          ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - 0.5_wp * zdf(jpk - 2)
1314
1315            DO jk = 1, jpk-2
1316               zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1317               ztmp1  = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1318               ztmp2  =  6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1319               zddf1  = -2._wp * ztmp1 + ztmp2
1320               ztmp1  = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1321               zddf2  =  2._wp * ztmp1 - ztmp2
1322
1323               dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1324               csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1325               bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1326                             & csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1327                             & dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1328                             &                   xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1329               asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1330                             &                (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1331                             &                 dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1332            END DO
1333         END_2D
1334
1335      ELSEIF ( polynomial_type == 2 ) THEN     ! Linear
1336         DO_3D( 1, 1, 1, 1, 1, jpk-2 )
1337            zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1338            ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1339
1340            dsp(ji,jj,jk) = 0._wp
1341            csp(ji,jj,jk) = 0._wp
1342            bsp(ji,jj,jk) = ztmp1 / zdxtmp
1343            asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1344         END_3D
1345         !
1346      ELSE
1347         CALL ctl_stop( 'invalid polynomial type in cspline' )
1348      ENDIF
1349      !
1350   END SUBROUTINE cspline
1351
1352
1353   FUNCTION interp1(x, xl, xr, fl, fr)  RESULT(f)
1354      !!----------------------------------------------------------------------
1355      !!                 ***  ROUTINE interp1  ***
1356      !!
1357      !! ** Purpose :   1-d linear interpolation
1358      !!
1359      !! ** Method  :   interpolation is straight forward
1360      !!                extrapolation is also permitted (no value limit)
1361      !!----------------------------------------------------------------------
1362      REAL(wp), INTENT(in) ::  x, xl, xr, fl, fr
1363      REAL(wp)             ::  f ! result of the interpolation (extrapolation)
1364      REAL(wp)             ::  zdeltx
1365      !!----------------------------------------------------------------------
1366      !
1367      zdeltx = xr - xl
1368      IF( abs(zdeltx) <= 10._wp * EPSILON(x) ) THEN
1369         f = 0.5_wp * (fl + fr)
1370      ELSE
1371         f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1372      ENDIF
1373      !
1374   END FUNCTION interp1
1375
1376
1377   FUNCTION interp2( x, a, b, c, d )  RESULT(f)
1378      !!----------------------------------------------------------------------
1379      !!                 ***  ROUTINE interp1  ***
1380      !!
1381      !! ** Purpose :   1-d constrained cubic spline interpolation
1382      !!
1383      !! ** Method  :  cubic spline interpolation
1384      !!
1385      !!----------------------------------------------------------------------
1386      REAL(wp), INTENT(in) ::  x, a, b, c, d
1387      REAL(wp)             ::  f ! value from the interpolation
1388      !!----------------------------------------------------------------------
1389      !
1390      f = a + x* ( b + x * ( c + d * x ) )
1391      !
1392   END FUNCTION interp2
1393
1394
1395   FUNCTION interp3( x, a, b, c, d )  RESULT(f)
1396      !!----------------------------------------------------------------------
1397      !!                 ***  ROUTINE interp1  ***
1398      !!
1399      !! ** Purpose :   Calculate the first order of derivative of
1400      !!                a cubic spline function y=a+b*x+c*x^2+d*x^3
1401      !!
1402      !! ** Method  :   f=dy/dx=b+2*c*x+3*d*x^2
1403      !!
1404      !!----------------------------------------------------------------------
1405      REAL(wp), INTENT(in) ::  x, a, b, c, d
1406      REAL(wp)             ::  f ! value from the interpolation
1407      !!----------------------------------------------------------------------
1408      !
1409      f = b + x * ( 2._wp * c + 3._wp * d * x)
1410      !
1411   END FUNCTION interp3
1412
1413
1414   FUNCTION integ_spline( xl, xr, a, b, c, d )  RESULT(f)
1415      !!----------------------------------------------------------------------
1416      !!                 ***  ROUTINE interp1  ***
1417      !!
1418      !! ** Purpose :   1-d constrained cubic spline integration
1419      !!
1420      !! ** Method  :  integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1421      !!
1422      !!----------------------------------------------------------------------
1423      REAL(wp), INTENT(in) ::  xl, xr, a, b, c, d
1424      REAL(wp)             ::  za1, za2, za3
1425      REAL(wp)             ::  f                   ! integration result
1426      !!----------------------------------------------------------------------
1427      !
1428      za1 = 0.5_wp * b
1429      za2 = c / 3.0_wp
1430      za3 = 0.25_wp * d
1431      !
1432      f  = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1433         & xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1434      !
1435   END FUNCTION integ_spline
1436
1437   !!======================================================================
1438END MODULE dynhpg
Note: See TracBrowser for help on using the repository browser.