source: NEMO/trunk/src/OCE/IOM/iom_nf90.F90 @ 12649

Last change on this file since 12649 was 12649, checked in by smasson, 7 months ago

trunk: clean and unique 3rd dimension in iom_rstput, see #2432

  • Property svn:keywords set to Id
File size: 42.6 KB
Line 
1MODULE iom_nf90
2   !!======================================================================
3   !!                    ***  MODULE  iom_nf90 ***
4   !! Input/Output manager :  Library to read input files with NF90 (only fliocom module)
5   !!======================================================================
6   !! History :  9.0  ! 05 12  (J. Belier) Original code
7   !!            9.0  ! 06 02  (S. Masson) Adaptation to NEMO
8   !!             "   ! 07 07  (D. Storkey) Changes to iom_nf90_gettime
9   !!            3.6  ! 2015-15  (J. Harle) Added procedure to read REAL attributes
10   !!            4.0  ! 2017-11 (M. Andrejczuk) Extend IOM interface to write any 3D fields
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   iom_open       : open a file read only
15   !!   iom_close      : close a file or all files opened by iom
16   !!   iom_get        : read a field (interfaced to several routines)
17   !!   iom_varid      : get the id of a variable in a file
18   !!   iom_rstput     : write a field in a restart file (interfaced to several routines)
19   !!----------------------------------------------------------------------
20   USE dom_oce         ! ocean space and time domain
21   USE sbc_oce, ONLY: ght_abl ! abl vertical level number and height
22   USE lbclnk          ! lateal boundary condition / mpp exchanges
23   USE iom_def         ! iom variables definitions
24   USE netcdf          ! NetCDF library
25   USE in_out_manager  ! I/O manager
26   USE lib_mpp         ! MPP library
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC iom_nf90_open  , iom_nf90_close, iom_nf90_varid, iom_nf90_get, iom_nf90_rstput
32   PUBLIC iom_nf90_chkatt, iom_nf90_getatt, iom_nf90_putatt
33
34   INTERFACE iom_nf90_get
35      MODULE PROCEDURE iom_nf90_g0d, iom_nf90_g123d
36   END INTERFACE
37   INTERFACE iom_nf90_rstput
38      MODULE PROCEDURE iom_nf90_rp0123d
39   END INTERFACE
40
41   !!----------------------------------------------------------------------
42   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
43   !! $Id$
44   !! Software governed by the CeCILL license (see ./LICENSE)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   SUBROUTINE iom_nf90_open( cdname, kiomid, ldwrt, ldok, kdompar, kdlev, cdcomp )
49      !!---------------------------------------------------------------------
50      !!                   ***  SUBROUTINE  iom_open  ***
51      !!
52      !! ** Purpose : open an input file with NF90
53      !!---------------------------------------------------------------------
54      CHARACTER(len=*)       , INTENT(inout)           ::   cdname      ! File name
55      INTEGER                , INTENT(  out)           ::   kiomid      ! nf90 identifier of the opened file
56      LOGICAL                , INTENT(in   )           ::   ldwrt       ! read or write the file?
57      LOGICAL                , INTENT(in   )           ::   ldok        ! check the existence
58      INTEGER, DIMENSION(2,5), INTENT(in   ), OPTIONAL ::   kdompar     ! domain parameters:
59      INTEGER                , INTENT(in   ), OPTIONAL ::   kdlev       ! size of the ice/abl third dimension
60      CHARACTER(len=3)       , INTENT(in   ), OPTIONAL ::   cdcomp      ! name of component calling iom_nf90_open
61
62      CHARACTER(LEN=256) ::   clinfo           ! info character
63      CHARACTER(LEN=256) ::   cltmp            ! temporary character
64      CHARACTER(LEN=3  ) ::   clcomp           ! name of component calling iom_nf90_open
65      INTEGER            ::   iln              ! lengths of character
66      INTEGER            ::   istop            ! temporary storage of nstop
67      INTEGER            ::   if90id           ! nf90 identifier of the opened file
68      INTEGER            ::   idmy             ! dummy variable
69      INTEGER            ::   jl               ! loop variable
70      INTEGER            ::   ichunk           ! temporary storage of nn_chunksz
71      INTEGER            ::   imode            ! creation mode flag: NF90_CLOBBER or NF90_NOCLOBBER or NF90_HDF5
72      INTEGER            ::   ihdf5            ! local variable for retrieval of value for NF90_HDF5
73      LOGICAL            ::   llclobber        ! local definition of ln_clobber
74      !---------------------------------------------------------------------
75      !
76      clinfo = '                    iom_nf90_open ~~~  '
77      istop = nstop     ! store the actual value of nstop
78      !
79      !                 !number of vertical levels
80      IF( PRESENT(cdcomp) )   THEN
81         IF( .NOT. PRESENT(kdlev) ) CALL ctl_stop( 'iom_nf90_open: cdcomp and kdlev must both be present' )
82         clcomp = cdcomp    ! use input value
83      ELSE
84         clcomp = 'OCE'     ! by default
85      ENDIF
86      !
87      IF( nn_chunksz > 0 ) THEN   ;   ichunk = nn_chunksz
88      ELSE                        ;   ichunk = NF90_SIZEHINT_DEFAULT
89      ENDIF
90      !
91      llclobber = ldwrt .AND. ln_clobber
92      IF( ldok .AND. .NOT. llclobber ) THEN      !==  Open existing file ==!
93         !                                       !=========================!
94         IF( ldwrt ) THEN  ! ... in write mode
95            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in WRITE mode'
96            IF( snc4set%luse ) THEN
97               CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_WRITE  , if90id ), clinfo)
98            ELSE
99               CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_WRITE  , if90id, chunksize = ichunk ), clinfo)
100            ENDIF
101            CALL iom_nf90_check(NF90_SET_FILL( if90id, NF90_NOFILL, idmy                          ), clinfo)
102         ELSE              ! ... in read mode
103            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in READ mode'
104            CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_NOWRITE, if90id, chunksize = ichunk ), clinfo)
105         ENDIF
106      ELSE                                       !== the file doesn't exist ==!   (or we overwrite it)
107         !                                       !============================!
108         iln = INDEX( cdname, '.nc' )
109         IF( ldwrt ) THEN              !* the file should be open in write mode so we create it...
110            IF( jpnij > 1 ) THEN
111               WRITE(cltmp,'(a,a,i4.4,a)') cdname(1:iln-1), '_', narea-1, '.nc'
112               cdname = TRIM(cltmp)
113            ENDIF
114            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' create new file: '//TRIM(cdname)//' in WRITE mode'
115
116            IF( llclobber ) THEN   ;   imode = IOR( NF90_64BIT_OFFSET, NF90_CLOBBER   )
117            ELSE                   ;   imode = IOR( NF90_64BIT_OFFSET, NF90_NOCLOBBER ) 
118            ENDIF
119            IF( snc4set%luse ) THEN
120               IF(lwp) WRITE(numout,*) TRIM(clinfo)//' creating file: '//TRIM(cdname)//' in hdf5 (netcdf4) mode'
121               CALL GET_NF90_SYMBOL("NF90_HDF5", ihdf5)
122               IF( llclobber ) THEN   ;   imode = IOR(ihdf5, NF90_CLOBBER)
123               ELSE                   ;   imode = IOR(ihdf5, NF90_NOCLOBBER)
124               ENDIF
125               CALL iom_nf90_check(NF90_CREATE( TRIM(cdname), imode, if90id ), clinfo)
126            ELSE
127               CALL iom_nf90_check(NF90_CREATE( TRIM(cdname), imode, if90id, chunksize = ichunk ), clinfo)
128            ENDIF
129            CALL iom_nf90_check(NF90_SET_FILL( if90id, NF90_NOFILL,                   idmy ), clinfo)
130            ! define dimensions
131                               CALL iom_nf90_check(NF90_DEF_DIM( if90id,            'x',   kdompar(1,1), idmy ), clinfo)
132                               CALL iom_nf90_check(NF90_DEF_DIM( if90id,            'y',   kdompar(2,1), idmy ), clinfo)
133            SELECT CASE (clcomp)
134            CASE ('OCE')   ;   CALL iom_nf90_check(NF90_DEF_DIM( if90id,      'nav_lev',            jpk, idmy ), clinfo)
135            CASE ('ICE')   ;   CALL iom_nf90_check(NF90_DEF_DIM( if90id,       'numcat',          kdlev, idmy ), clinfo)
136            CASE ('ABL')   ;   CALL iom_nf90_check(NF90_DEF_DIM( if90id,      'nav_lev',          kdlev, idmy ), clinfo)
137            CASE ('SED')   ;   CALL iom_nf90_check(NF90_DEF_DIM( if90id,       'numsed',          kdlev, idmy ), clinfo)
138            CASE DEFAULT   ;   CALL ctl_stop( 'iom_nf90_open unknown component type' )
139            END SELECT
140                               CALL iom_nf90_check(NF90_DEF_DIM( if90id, 'time_counter', NF90_UNLIMITED, idmy ), clinfo)
141            ! global attributes
142            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_number_total'   , jpnij              ), clinfo)
143            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_number'         , narea-1            ), clinfo)
144            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_dimensions_ids' , (/1     , 2     /) ), clinfo)
145            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_size_global'    , (/jpiglo, jpjglo/) ), clinfo)
146            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_size_local'     , kdompar(:,1)       ), clinfo)
147            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_position_first' , kdompar(:,2)       ), clinfo)
148            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_position_last'  , kdompar(:,3)       ), clinfo)
149            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_halo_size_start', kdompar(:,4)       ), clinfo)
150            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_halo_size_end'  , kdompar(:,5)       ), clinfo)
151            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_type'           , 'BOX'              ), clinfo)
152         ELSE                          !* the file should be open for read mode so it must exist...
153            CALL ctl_stop( TRIM(clinfo), ' should be impossible case...' )
154         ENDIF
155      ENDIF
156      !
157      ! start to fill file informations
158      ! =============
159      IF( istop == nstop ) THEN   ! no error within this routine
160!does not work with some compilers         kiomid = MINLOC(iom_file(:)%nfid, dim = 1)
161         kiomid = 0
162         DO jl = jpmax_files, 1, -1
163            IF( iom_file(jl)%nfid == 0 )   kiomid = jl
164         ENDDO
165         iom_file(kiomid)%name   = TRIM(cdname)
166         iom_file(kiomid)%comp   = clcomp
167         iom_file(kiomid)%nfid   = if90id
168         iom_file(kiomid)%nvars  = 0
169         iom_file(kiomid)%irec   = -1   ! useless for NetCDF files, used to know if the file is in define mode
170         CALL iom_nf90_check(NF90_Inquire(if90id, unlimitedDimId = iom_file(kiomid)%iduld), clinfo)
171         IF( iom_file(kiomid)%iduld .GE. 0 ) THEN
172            CALL iom_nf90_check(NF90_Inquire_Dimension(if90id, iom_file(kiomid)%iduld,    & 
173               &                                       name = iom_file(kiomid)%uldname,   &
174               &                                       len  = iom_file(kiomid)%lenuld ), clinfo )
175         ENDIF
176         IF(lwp) WRITE(numout,*) '                   ---> '//TRIM(cdname)//' OK'
177      ELSE
178         kiomid = 0               ! return error flag
179      ENDIF
180      !
181   END SUBROUTINE iom_nf90_open
182
183
184   SUBROUTINE iom_nf90_close( kiomid )
185      !!--------------------------------------------------------------------
186      !!                   ***  SUBROUTINE  iom_nf90_close  ***
187      !!
188      !! ** Purpose : close an input file with NF90
189      !!--------------------------------------------------------------------
190      INTEGER, INTENT(in) ::   kiomid   ! iom identifier of the file to be closed
191      CHARACTER(LEN=100)  ::   clinfo   ! info character
192      !---------------------------------------------------------------------
193      clinfo = '      iom_nf90_close    , file: '//TRIM(iom_file(kiomid)%name)
194      CALL iom_nf90_check(NF90_CLOSE(iom_file(kiomid)%nfid), clinfo)
195   END SUBROUTINE iom_nf90_close
196
197
198   FUNCTION iom_nf90_varid ( kiomid, cdvar, kiv, kdimsz, kndims, lduld ) 
199      !!-----------------------------------------------------------------------
200      !!                  ***  FUNCTION  iom_varid  ***
201      !!
202      !! ** Purpose : get the id of a variable in a file with NF90
203      !!-----------------------------------------------------------------------
204      INTEGER              , INTENT(in   )           ::   kiomid   ! file Identifier
205      CHARACTER(len=*)     , INTENT(in   )           ::   cdvar    ! name of the variable
206      INTEGER              , INTENT(in   )           ::   kiv   !
207      INTEGER, DIMENSION(:), INTENT(  out), OPTIONAL ::   kdimsz   ! size of each dimension
208      INTEGER              , INTENT(  out), OPTIONAL ::   kndims   ! number of dimensions
209      LOGICAL              , INTENT(  out), OPTIONAL ::   lduld    ! true if the last dimension is unlimited (time)
210      !
211      INTEGER                        ::   iom_nf90_varid   ! iom variable Id
212      INTEGER                        ::   if90id           ! nf90 file identifier
213      INTEGER                        ::   ji               ! dummy loop index
214      INTEGER                        ::   ivarid           ! NetCDF  variable Id
215      INTEGER                        ::   i_nvd            ! number of dimension of the variable
216      INTEGER, DIMENSION(jpmax_dims) ::   idimid           ! dimension ids of the variable
217      LOGICAL                        ::   llok             ! ok  test
218      CHARACTER(LEN=100)             ::   clinfo           ! info character
219      !!-----------------------------------------------------------------------
220      clinfo = '          iom_nf90_varid, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(cdvar)
221      iom_nf90_varid = 0                    ! default definition
222      IF( PRESENT(kdimsz) ) kdimsz(:) = 0   ! default definition
223      if90id = iom_file(kiomid)%nfid        ! get back NetCDF file id
224      !
225      llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr   ! does the variable exist in the file
226      IF( llok ) THEN
227         iom_nf90_varid = kiv
228         iom_file(kiomid)%nvars       = kiv
229         iom_file(kiomid)%nvid(kiv)   = ivarid
230         iom_file(kiomid)%cn_var(kiv) = TRIM(cdvar)
231         CALL iom_nf90_check(NF90_Inquire_Variable(if90id, ivarid, ndims = i_nvd), clinfo)   ! number of dimensions
232         iom_file(kiomid)%ndims(kiv)  = i_nvd
233         CALL iom_nf90_check(NF90_Inquire_Variable(if90id, ivarid, dimids = idimid(1:i_nvd)), clinfo)   ! dimensions ids
234         iom_file(kiomid)%luld(kiv) = .FALSE.   ! default value
235         iom_file(kiomid)%dimsz(:,kiv) = 0      ! reset dimsz in case previously used
236         DO ji = 1, i_nvd                       ! dimensions size
237            CALL iom_nf90_check(NF90_Inquire_Dimension(if90id, idimid(ji), len = iom_file(kiomid)%dimsz(ji,kiv)), clinfo)   
238            IF( idimid(ji) == iom_file(kiomid)%iduld ) iom_file(kiomid)%luld(kiv) = .TRUE.   ! unlimited dimension?
239         END DO
240         !---------- Deal with scale_factor and add_offset
241         llok = NF90_Inquire_attribute(if90id, ivarid, 'scale_factor') == nf90_noerr
242         IF( llok) THEN
243            CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, 'scale_factor', iom_file(kiomid)%scf(kiv)), clinfo)
244         ELSE
245            iom_file(kiomid)%scf(kiv) = 1.
246         END IF
247         llok = NF90_Inquire_attribute(if90id, ivarid, 'add_offset') == nf90_noerr
248         IF( llok ) THEN
249            CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, 'add_offset', iom_file(kiomid)%ofs(kiv)), clinfo)
250         ELSE
251            iom_file(kiomid)%ofs(kiv) = 0.
252         END IF
253         ! return the simension size
254         IF( PRESENT(kdimsz) ) THEN
255            IF( i_nvd <= SIZE(kdimsz) ) THEN
256               kdimsz(1:i_nvd) = iom_file(kiomid)%dimsz(1:i_nvd,kiv)
257            ELSE
258               WRITE(ctmp1,*) i_nvd, SIZE(kdimsz)
259               CALL ctl_stop( TRIM(clinfo), 'error in kdimsz size'//TRIM(ctmp1) )
260            ENDIF
261         ENDIF
262         IF( PRESENT(kndims) )  kndims = iom_file(kiomid)%ndims(kiv)
263         IF( PRESENT( lduld) )  lduld  = iom_file(kiomid)%luld(kiv)
264      ELSE 
265         iom_nf90_varid = -1   !   variable not found, return error code: -1
266      ENDIF
267      !
268   END FUNCTION iom_nf90_varid
269
270   !!----------------------------------------------------------------------
271   !!                   INTERFACE iom_nf90_get
272   !!----------------------------------------------------------------------
273
274   SUBROUTINE iom_nf90_g0d( kiomid, kvid, pvar, kstart )
275      !!-----------------------------------------------------------------------
276      !!                  ***  ROUTINE  iom_nf90_g0d  ***
277      !!
278      !! ** Purpose : read a scalar with NF90
279      !!-----------------------------------------------------------------------
280      INTEGER ,               INTENT(in   )            ::   kiomid   ! Identifier of the file
281      INTEGER ,               INTENT(in   )            ::   kvid     ! variable id
282      REAL(wp),               INTENT(  out)            ::   pvar     ! read field
283      INTEGER , DIMENSION(1), INTENT(in   ), OPTIONAL  ::   kstart   ! start position of the reading in each axis
284      !
285      CHARACTER(LEN=100)      ::   clinfo   ! info character
286      !---------------------------------------------------------------------
287      clinfo = 'iom_nf90_g0d , file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
288      CALL iom_nf90_check(NF90_GET_VAR(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), pvar, start = kstart), clinfo )
289   END SUBROUTINE iom_nf90_g0d
290
291
292   SUBROUTINE iom_nf90_g123d( kiomid, kvid, knbdim, kstart, kcount, kx1, kx2, ky1, ky2,   &
293         &                    pv_r1d, pv_r2d, pv_r3d )
294      !!-----------------------------------------------------------------------
295      !!                  ***  ROUTINE  iom_nf90_g123d  ***
296      !!
297      !! ** Purpose : read a 1D/2D/3D variable with NF90
298      !!
299      !! ** Method : read ONE record at each CALL
300      !!-----------------------------------------------------------------------
301      INTEGER                    , INTENT(in   )           ::   kiomid    ! iom identifier of the file
302      INTEGER                    , INTENT(in   )           ::   kvid      ! Name of the variable
303      INTEGER                    , INTENT(in   )           ::   knbdim    ! number of dimensions of the variable
304      INTEGER , DIMENSION(:)     , INTENT(in   )           ::   kstart    ! start position of the reading in each axis
305      INTEGER , DIMENSION(:)     , INTENT(in   )           ::   kcount    ! number of points to be read in each axis
306      INTEGER ,                    INTENT(in   )           ::   kx1, kx2, ky1, ky2   ! subdomain indexes
307      REAL(wp), DIMENSION(:)     , INTENT(  out), OPTIONAL ::   pv_r1d    ! read field (1D case)
308      REAL(wp), DIMENSION(:,:)   , INTENT(  out), OPTIONAL ::   pv_r2d    ! read field (2D case)
309      REAL(wp), DIMENSION(:,:,:) , INTENT(  out), OPTIONAL ::   pv_r3d    ! read field (3D case)
310      !
311      CHARACTER(LEN=100) ::   clinfo               ! info character
312      INTEGER            ::   if90id               ! nf90 identifier of the opened file
313      INTEGER            ::   ivid                 ! nf90 variable id
314      !---------------------------------------------------------------------
315      clinfo = 'iom_nf90_g123d , file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
316      if90id = iom_file(kiomid)%nfid         ! get back NetCDF file id
317      ivid   = iom_file(kiomid)%nvid(kvid)   ! get back NetCDF var id
318      !
319      IF(     PRESENT(pv_r1d) ) THEN
320         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r1d(:                ), start = kstart(1:knbdim),   &
321            &                                                                       count = kcount(1:knbdim)), clinfo )
322      ELSEIF( PRESENT(pv_r2d) ) THEN
323         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r2d(kx1:kx2,ky1:ky2  ), start = kstart(1:knbdim),   &
324            &                                                                       count = kcount(1:knbdim)), clinfo )
325      ELSEIF( PRESENT(pv_r3d) ) THEN
326         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r3d(kx1:kx2,ky1:ky2,:), start = kstart(1:knbdim),   &
327            &                                                                       count = kcount(1:knbdim)), clinfo )
328      ENDIF
329      !
330   END SUBROUTINE iom_nf90_g123d
331
332
333   SUBROUTINE iom_nf90_chkatt( kiomid, cdatt, llok, ksize, cdvar )
334      !!-----------------------------------------------------------------------
335      !!                  ***  ROUTINE  iom_nf90_chkatt  ***
336      !!
337      !! ** Purpose : check existence of attribute with NF90
338      !!              (either a global attribute (default) or a variable
339      !!               attribute if optional variable name is supplied (cdvar))
340      !!-----------------------------------------------------------------------
341      INTEGER         , INTENT(in   ) ::   kiomid   ! Identifier of the file
342      CHARACTER(len=*), INTENT(in   ) ::   cdatt    ! attribute name
343      LOGICAL         , INTENT(  out) ::   llok     ! error code
344      INTEGER         , INTENT(  out), OPTIONAL     &
345                      &               ::   ksize    ! attribute size
346      CHARACTER(len=*), INTENT(in   ), OPTIONAL     &
347                      &               ::   cdvar    ! name of the variable
348      !
349      INTEGER                         ::   if90id   ! temporary integer
350      INTEGER                         ::   isize    ! temporary integer
351      INTEGER                         ::   ivarid   ! NetCDF variable Id
352      !---------------------------------------------------------------------
353      !
354      if90id = iom_file(kiomid)%nfid
355      IF( PRESENT(cdvar) ) THEN
356         ! check the variable exists in the file
357         llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr
358         IF( llok ) &
359            ! check the variable has the attribute required
360            llok = NF90_Inquire_attribute(if90id, ivarid, cdatt, len=isize ) == nf90_noerr
361      ELSE
362         llok = NF90_Inquire_attribute(if90id, NF90_GLOBAL, cdatt, len=isize ) == nf90_noerr
363      ENDIF
364      !
365      IF( PRESENT(ksize) ) ksize = isize
366      !
367      IF( .not. llok) &
368         CALL ctl_warn('iom_nf90_chkatt: no attribute '//cdatt//' found')
369      !
370   END SUBROUTINE iom_nf90_chkatt
371
372
373   !!----------------------------------------------------------------------
374   !!                   INTERFACE iom_nf90_getatt
375   !!----------------------------------------------------------------------
376
377   SUBROUTINE iom_nf90_getatt( kiomid, cdatt, katt0d, katt1d, patt0d, patt1d, cdatt0d, cdvar)
378      !!-----------------------------------------------------------------------
379      !!                  ***  ROUTINE  iom_nf90_getatt  ***
380      !!
381      !! ** Purpose : read an attribute with NF90
382      !!              (either a global attribute (default) or a variable
383      !!               attribute if optional variable name is supplied (cdvar))
384      !!-----------------------------------------------------------------------
385      INTEGER               , INTENT(in   )           ::   kiomid   ! Identifier of the file
386      CHARACTER(len=*)      , INTENT(in   )           ::   cdatt    ! attribute name
387      INTEGER               , INTENT(  out), OPTIONAL ::   katt0d   ! read scalar integer
388      INTEGER, DIMENSION(:) , INTENT(  out), OPTIONAL ::   katt1d   ! read 1d array integer
389      REAL(wp)              , INTENT(  out), OPTIONAL ::   patt0d   ! read scalar  real
390      REAL(wp), DIMENSION(:), INTENT(  out), OPTIONAL ::   patt1d   ! read 1d array real
391      CHARACTER(len=*)      , INTENT(  out), OPTIONAL ::   cdatt0d  ! read character
392      CHARACTER(len=*)      , INTENT(in   ), OPTIONAL ::   cdvar    ! name of the variable
393      !
394      INTEGER                         ::   if90id   ! temporary integer
395      INTEGER                         ::   ivarid   ! NetCDF variable Id
396      LOGICAL                         ::   llok     ! temporary logical
397      CHARACTER(LEN=100)              ::   clinfo   ! info character
398      !---------------------------------------------------------------------
399      !
400      if90id = iom_file(kiomid)%nfid
401      IF( PRESENT(cdvar) ) THEN
402         ! check the variable exists in the file
403         llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr
404         IF( llok ) THEN
405            ! check the variable has the attribute required
406            llok = NF90_Inquire_attribute(if90id, ivarid, cdatt) == nf90_noerr
407         ELSE
408            CALL ctl_warn('iom_nf90_getatt: no variable '//TRIM(cdvar)//' found')
409         ENDIF
410      ELSE
411         llok = NF90_Inquire_attribute(if90id, NF90_GLOBAL, cdatt) == nf90_noerr
412         ivarid = NF90_GLOBAL
413      ENDIF
414      !
415      IF( llok) THEN
416         clinfo = 'iom_nf90_getatt, file: '//TRIM(iom_file(kiomid)%name)//', att: '//TRIM(cdatt)
417         IF(PRESENT( katt0d))   CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values =  katt0d), clinfo)
418         IF(PRESENT( katt1d))   CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values =  katt1d), clinfo)
419         IF(PRESENT( patt0d))   CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values =  patt0d), clinfo)
420         IF(PRESENT( patt1d))   CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values =  patt1d), clinfo)
421         IF(PRESENT(cdatt0d))   CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values = cdatt0d), clinfo)
422      ELSE
423         CALL ctl_warn('iom_nf90_getatt: no attribute '//TRIM(cdatt)//' found')
424         IF(PRESENT( katt0d))    katt0d    = -999
425         IF(PRESENT( katt1d))    katt1d(:) = -999
426         IF(PRESENT( patt0d))    patt0d    = -999._wp
427         IF(PRESENT( patt1d))    patt1d(:) = -999._wp
428         IF(PRESENT(cdatt0d))   cdatt0d    = '!'
429      ENDIF
430      !
431   END SUBROUTINE iom_nf90_getatt
432
433
434   SUBROUTINE iom_nf90_putatt( kiomid, cdatt, katt0d, katt1d, patt0d, patt1d, cdatt0d, cdvar)
435      !!-----------------------------------------------------------------------
436      !!                  ***  ROUTINE  iom_nf90_putatt  ***
437      !!
438      !! ** Purpose : write an attribute with NF90
439      !!              (either a global attribute (default) or a variable
440      !!               attribute if optional variable name is supplied (cdvar))
441      !!-----------------------------------------------------------------------
442      INTEGER               , INTENT(in   )           ::   kiomid   ! Identifier of the file
443      CHARACTER(len=*)      , INTENT(in   )           ::   cdatt    ! attribute name
444      INTEGER               , INTENT(in   ), OPTIONAL ::   katt0d   ! read scalar integer
445      INTEGER, DIMENSION(:) , INTENT(in   ), OPTIONAL ::   katt1d   ! read 1d array integer
446      REAL(wp)              , INTENT(in   ), OPTIONAL ::   patt0d   ! read scalar  real
447      REAL(wp), DIMENSION(:), INTENT(in   ), OPTIONAL ::   patt1d   ! read 1d array real
448      CHARACTER(len=*)      , INTENT(in   ), OPTIONAL ::   cdatt0d  ! read character
449      CHARACTER(len=*)      , INTENT(in   ), OPTIONAL ::   cdvar    ! name of the variable
450      !
451      INTEGER                         ::   if90id   ! temporary integer
452      INTEGER                         ::   ivarid   ! NetCDF variable Id
453      INTEGER                         ::   isize    ! Attribute size
454      INTEGER                         ::   itype    ! Attribute type
455      LOGICAL                         ::   llok     ! temporary logical
456      LOGICAL                         ::   llatt     ! temporary logical
457      LOGICAL                         ::   lldata   ! temporary logical
458      CHARACTER(LEN=100)              ::   clinfo   ! info character
459      !---------------------------------------------------------------------
460      !
461      if90id = iom_file(kiomid)%nfid
462      IF( PRESENT(cdvar) ) THEN
463         llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr   ! is the variable in the file?
464         IF( .NOT. llok ) THEN
465            CALL ctl_warn('iom_nf90_putatt: no variable '//TRIM(cdvar)//' found'   &
466               &        , '                 no attribute '//cdatt//' written' )
467            RETURN
468         ENDIF
469      ELSE
470         ivarid = NF90_GLOBAL
471      ENDIF
472      llatt = NF90_Inquire_attribute(if90id, ivarid, cdatt, len = isize, xtype = itype ) == nf90_noerr
473      !
474      ! trick: irec used to know if the file is in define mode or not
475      lldata = iom_file(kiomid)%irec /= -1   ! default: go back in define mode if in data mode
476      IF( lldata .AND. llatt ) THEN          ! attribute already there. Do we really need to go back in define mode?
477         ! do we have the appropriate type?
478         IF(PRESENT( katt0d) .OR. PRESENT( katt1d))   llok = itype == NF90_INT
479         IF(PRESENT( patt0d) .OR. PRESENT( patt1d))   llok = itype == NF90_DOUBLE
480         IF(PRESENT(cdatt0d)                      )   llok = itype == NF90_CHAR
481         ! and do we have the appropriate size?
482         IF(PRESENT( katt0d))   llok = llok .AND. isize == 1
483         IF(PRESENT( katt1d))   llok = llok .AND. isize == SIZE(katt1d)
484         IF(PRESENT( patt0d))   llok = llok .AND. isize == 1
485         IF(PRESENT( patt1d))   llok = llok .AND. isize == SIZE(patt1d)
486         IF(PRESENT(cdatt0d))   llok = llok .AND. isize == LEN_TRIM(cdatt0d)
487         !
488         lldata = .NOT. llok
489      ENDIF
490      !
491      clinfo = 'iom_nf90_putatt, file: '//TRIM(iom_file(kiomid)%name)//', att: '//TRIM(cdatt)
492      IF(lldata)   CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)   ! leave data mode to define mode
493      !
494      IF(PRESENT( katt0d))   CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values =       katt0d) , clinfo)
495      IF(PRESENT( katt1d))   CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values =       katt1d) , clinfo)
496      IF(PRESENT( patt0d))   CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values =       patt0d) , clinfo)
497      IF(PRESENT( patt1d))   CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values =       patt1d) , clinfo)
498      IF(PRESENT(cdatt0d))   CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values = trim(cdatt0d)), clinfo)
499      !
500      IF(lldata)   CALL iom_nf90_check(NF90_ENDDEF( if90id ), clinfo)   ! leave define mode to data mode
501      !
502   END SUBROUTINE iom_nf90_putatt
503
504
505   SUBROUTINE iom_nf90_rp0123d( kt, kwrite, kiomid, cdvar , kvid  , ktype,   &
506         &                                  pv_r0d, pv_r1d, pv_r2d, pv_r3d )
507      !!--------------------------------------------------------------------
508      !!                   ***  SUBROUTINE  iom_nf90_rstput  ***
509      !!
510      !! ** Purpose : read the time axis cdvar in the file
511      !!--------------------------------------------------------------------
512      INTEGER                     , INTENT(in)           ::   kt       ! ocean time-step
513      INTEGER                     , INTENT(in)           ::   kwrite   ! writing time-step
514      INTEGER                     , INTENT(in)           ::   kiomid   ! Identifier of the file
515      CHARACTER(len=*)            , INTENT(in)           ::   cdvar    ! variable name
516      INTEGER                     , INTENT(in)           ::   kvid     ! variable id
517      INTEGER                     , INTENT(in), OPTIONAL ::   ktype    ! variable type (default R8)
518      REAL(wp)                    , INTENT(in), OPTIONAL ::   pv_r0d   ! written Od field
519      REAL(wp), DIMENSION(      :), INTENT(in), OPTIONAL ::   pv_r1d   ! written 1d field
520      REAL(wp), DIMENSION(:, :   ), INTENT(in), OPTIONAL ::   pv_r2d   ! written 2d field
521      REAL(wp), DIMENSION(:, :, :), INTENT(in), OPTIONAL ::   pv_r3d   ! written 3d field
522      !
523      INTEGER               :: idims                ! number of dimension
524      INTEGER               :: idvar                ! variable id
525      INTEGER               :: jd                   ! dimension loop counter   
526      INTEGER               :: ix1, ix2, iy1, iy2   ! subdomain indexes   
527      INTEGER, DIMENSION(4) :: idimsz               ! dimensions size 
528      INTEGER, DIMENSION(4) :: idimid               ! dimensions id
529      CHARACTER(LEN=256)    :: clinfo               ! info character
530      INTEGER               :: if90id               ! nf90 file identifier
531      INTEGER               :: itype                ! variable type
532      INTEGER, DIMENSION(4) :: ichunksz             ! NetCDF4 chunk sizes. Will be computed using
533      !                                             ! nn_nchunks_[i,j,k,t] namelist parameters
534      INTEGER               :: ichunkalg, ishuffle, ideflate, ideflate_level
535      !                                             ! NetCDF4 internally fixed parameters
536      LOGICAL               :: lchunk               ! logical switch to activate chunking and compression
537      !                                             ! when appropriate (currently chunking is applied to 4d fields only)
538      INTEGER               :: idlv                 ! local variable
539      !---------------------------------------------------------------------
540      !
541      clinfo = '          iom_nf90_rp0123d, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(cdvar)
542      if90id = iom_file(kiomid)%nfid
543      !
544      ! define dimension variables if it is not already done
545      ! ==========================
546      IF( iom_file(kiomid)%nvars == 0 ) THEN
547         ! are we in define mode?
548         IF( iom_file(kiomid)%irec /= -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
549            CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = -1
550         ENDIF
551         ! define the dimension variables if it is not already done
552         DO jd = 1, 2
553            CALL iom_nf90_check(NF90_INQUIRE_DIMENSION(if90id,jd,iom_file(kiomid)%cn_var(jd),iom_file(kiomid)%dimsz(jd,jd)),clinfo)
554            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(iom_file(kiomid)%cn_var(jd)), NF90_FLOAT , (/ 1, 2 /),   &
555               &                              iom_file(kiomid)%nvid(jd) ), clinfo)
556         END DO
557         iom_file(kiomid)%dimsz(2,1) = iom_file(kiomid)%dimsz(2,2)   ! second dim of first  variable
558         iom_file(kiomid)%dimsz(1,2) = iom_file(kiomid)%dimsz(1,1)   ! first  dim of second variable
559         DO jd = 3, 4
560            CALL iom_nf90_check(NF90_INQUIRE_DIMENSION(if90id,jd,iom_file(kiomid)%cn_var(jd),iom_file(kiomid)%dimsz(1,jd)), clinfo)
561            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(iom_file(kiomid)%cn_var(jd)), NF90_FLOAT , (/ jd   /),   &
562               &                              iom_file(kiomid)%nvid(jd) ), clinfo)
563         END DO
564         ! update informations structure related the dimension variable we just added...
565         iom_file(kiomid)%nvars       = 4
566         iom_file(kiomid)%luld(1:4)   = (/ .FALSE., .FALSE., .FALSE., .TRUE. /)
567         iom_file(kiomid)%ndims(1:4)  = (/ 2, 2, 1, 1 /)
568         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' define dimension variables done'
569      ENDIF
570      ! define the data if it is not already done
571      ! ===============
572      IF( kvid <= 0 ) THEN
573         !
574         ! NetCDF4 chunking and compression fixed settings
575         ichunkalg = 0
576         ishuffle = 1
577         ideflate = 1
578         ideflate_level = 1
579         !
580         idvar = iom_file(kiomid)%nvars + 1
581         ! are we in define mode?
582         IF( iom_file(kiomid)%irec /= -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
583            CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = -1
584         ENDIF
585         ! variable definition
586         IF(     PRESENT(pv_r0d) ) THEN   ;   idims = 0
587         ELSEIF( PRESENT(pv_r1d) ) THEN
588                                              idims = 2   ;   idimid(1:idims) = (/3,4/)
589         ELSEIF( PRESENT(pv_r2d) ) THEN   ;   idims = 3   ;   idimid(1:idims) = (/1,2,4/)
590         ELSEIF( PRESENT(pv_r3d) ) THEN
591                                              idims = 4   ;   idimid(1:idims) = (/1,2,3,4/)
592         ENDIF
593         IF( PRESENT(ktype) ) THEN   ! variable external type
594            SELECT CASE (ktype)
595            CASE (jp_r8)   ;   itype = NF90_DOUBLE
596            CASE (jp_r4)   ;   itype = NF90_FLOAT
597            CASE (jp_i4)   ;   itype = NF90_INT
598            CASE (jp_i2)   ;   itype = NF90_SHORT
599            CASE (jp_i1)   ;   itype = NF90_BYTE
600            CASE DEFAULT   ;   CALL ctl_stop( TRIM(clinfo)//' unknown variable type' )
601            END SELECT
602         ELSE
603            itype = NF90_DOUBLE
604         ENDIF
605         IF( PRESENT(pv_r0d) ) THEN
606            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cdvar), itype,                    &
607               &                              iom_file(kiomid)%nvid(idvar) ), clinfo )
608         ELSE
609            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cdvar), itype, idimid(1:idims),   &
610               &                              iom_file(kiomid)%nvid(idvar) ), clinfo )
611         ENDIF
612         lchunk = .false.
613         IF( snc4set%luse .AND. idims == 4 )   lchunk = .true.
614         ! update informations structure related the new variable we want to add...
615         iom_file(kiomid)%nvars         = idvar
616         iom_file(kiomid)%cn_var(idvar) = TRIM(cdvar)
617         iom_file(kiomid)%scf(idvar)    = 1.
618         iom_file(kiomid)%ofs(idvar)    = 0.
619         iom_file(kiomid)%ndims(idvar)  = idims
620         IF( .NOT. PRESENT(pv_r0d) ) THEN   ;   iom_file(kiomid)%luld(idvar) = .TRUE.
621         ELSE                               ;   iom_file(kiomid)%luld(idvar) = .FALSE.
622         ENDIF
623         DO jd = 1, idims
624            CALL iom_nf90_check(NF90_INQUIRE_DIMENSION( if90id, idimid(jd), len = iom_file(kiomid)%dimsz(jd,idvar) ), clinfo)
625            IF ( lchunk ) ichunksz(jd) = iom_file(kiomid)%dimsz(jd,idvar)
626         END DO
627         IF ( lchunk ) THEN
628            ! Calculate chunk sizes by partitioning each dimension as requested in namnc4 namelist
629            ! Disallow very small chunk sizes and prevent chunk sizes larger than each individual dimension
630            ichunksz(1) = MIN( ichunksz(1),MAX( (ichunksz(1)-1)/snc4set%ni + 1 ,16 ) ) ! Suggested default nc4set%ni=4
631            ichunksz(2) = MIN( ichunksz(2),MAX( (ichunksz(2)-1)/snc4set%nj + 1 ,16 ) ) ! Suggested default nc4set%nj=2
632            ichunksz(3) = MIN( ichunksz(3),MAX( (ichunksz(3)-1)/snc4set%nk + 1 , 1 ) ) ! Suggested default nc4set%nk=6
633            ichunksz(4) = 1                                                            ! Do not allow chunks to span the
634            !                                                                          ! unlimited dimension
635            CALL iom_nf90_check(SET_NF90_DEF_VAR_CHUNKING(if90id, idvar, ichunkalg, ichunksz), clinfo)
636            CALL iom_nf90_check(SET_NF90_DEF_VAR_DEFLATE(if90id, idvar, ishuffle, ideflate, ideflate_level), clinfo)
637            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' chunked ok. Chunks sizes: ', ichunksz
638         ENDIF
639         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' defined ok'
640      ELSE
641         idvar = kvid
642      ENDIF
643      !
644      ! time step kwrite : write the variable
645      IF( kt == kwrite ) THEN
646         ! are we in write mode?
647         IF( iom_file(kiomid)%irec == -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
648            CALL iom_nf90_check(NF90_ENDDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = 0
649         ENDIF
650         ! on what kind of domain must the data be written?
651         IF( PRESENT(pv_r2d) .OR. PRESENT(pv_r3d) ) THEN
652            idimsz(1:2) = iom_file(kiomid)%dimsz(1:2,idvar)
653            IF(     idimsz(1) == (nlei - nldi + 1) .AND. idimsz(2) == (nlej - nldj + 1) ) THEN
654               ix1 = nldi   ;   ix2 = nlei   ;   iy1 = nldj   ;   iy2 = nlej
655            ELSEIF( idimsz(1) == nlci              .AND. idimsz(2) == nlcj              ) THEN
656               ix1 = 1      ;   ix2 = nlci   ;   iy1 = 1      ;   iy2 = nlcj
657            ELSEIF( idimsz(1) == jpi               .AND. idimsz(2) == jpj               ) THEN
658               ix1 = 1      ;   ix2 = jpi    ;   iy1 = 1      ;   iy2 = jpj
659            ELSE
660               CALL ctl_stop( 'iom_nf90_rp0123d: should have been an impossible case...' )
661            ENDIF
662
663            ! write dimension variables if it is not already done
664            ! =============
665            ! trick: is defined to 0 => dimension variable are defined but not yet written
666            IF( iom_file(kiomid)%dimsz(1, 4) == 0 ) THEN   ! time_counter = 0
667               CALL iom_nf90_check(    NF90_PUT_VAR( if90id, 1,                            glamt(ix1:ix2, iy1:iy2) ), clinfo )
668               CALL iom_nf90_check(    NF90_PUT_VAR( if90id, 2,                            gphit(ix1:ix2, iy1:iy2) ), clinfo )
669               SELECT CASE (iom_file(kiomid)%comp)
670               CASE ('OCE') 
671                  CALL iom_nf90_check( NF90_PUT_VAR( if90id, 3,                                           gdept_1d ), clinfo )
672               CASE ('ABL')
673                  CALL iom_nf90_check( NF90_PUT_VAR( if90id, 3,                                            ght_abl ), clinfo )
674               CASE DEFAULT
675                  CALL iom_nf90_check( NF90_PUT_VAR( if90id, 3, (/ (idlv, idlv = 1,iom_file(kiomid)%dimsz(1,3)) /) ), clinfo )
676               END SELECT
677               ! "wrong" value: to be improved but not really useful...
678               CALL iom_nf90_check(   NF90_PUT_VAR( if90id, 4,                                                  kt ), clinfo )   
679               ! update the size of the variable corresponding to the unlimited dimension
680               iom_file(kiomid)%dimsz(1, 4) = 1   ! so we don't enter this IF case any more...
681               IF(lwp) WRITE(numout,*) TRIM(clinfo)//' write dimension variables done'
682            ENDIF
683         ENDIF
684
685         ! write the data
686         ! =============
687         IF(     PRESENT(pv_r0d) ) THEN
688            CALL iom_nf90_check( NF90_PUT_VAR( if90id, idvar, pv_r0d                    ), clinfo )
689         ELSEIF( PRESENT(pv_r1d) ) THEN
690            CALL iom_nf90_check( NF90_PUT_VAR( if90id, idvar, pv_r1d(:)                 ), clinfo )
691         ELSEIF( PRESENT(pv_r2d) ) THEN
692            CALL iom_nf90_check( NF90_PUT_VAR( if90id, idvar, pv_r2d(ix1:ix2,iy1:iy2)   ), clinfo )
693         ELSEIF( PRESENT(pv_r3d) ) THEN
694            CALL iom_nf90_check( NF90_PUT_VAR( if90id, idvar, pv_r3d(ix1:ix2,iy1:iy2,:) ), clinfo )
695         ENDIF
696         ! add 1 to the size of the temporal dimension (not really useful...)
697         IF( iom_file(kiomid)%luld(idvar) )   iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar)    &
698               &                            = iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar) + 1
699         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' written ok'
700      ENDIF
701      !     
702   END SUBROUTINE iom_nf90_rp0123d
703
704
705   SUBROUTINE iom_nf90_check( kstatus, cdinfo )
706      !!--------------------------------------------------------------------
707      !!                   ***  SUBROUTINE iom_nf90_check  ***
708      !!
709      !! ** Purpose :   check nf90 errors
710      !!--------------------------------------------------------------------
711      INTEGER,          INTENT(in) :: kstatus
712      CHARACTER(LEN=*), INTENT(in) :: cdinfo
713      !---------------------------------------------------------------------
714      IF(kstatus /= nf90_noerr)   CALL ctl_stop( 'iom_nf90_check : '//TRIM(nf90_strerror(kstatus)), TRIM(cdinfo) )
715   END SUBROUTINE iom_nf90_check
716
717   !!======================================================================
718END MODULE iom_nf90
Note: See TracBrowser for help on using the repository browser.