source: NEMO/trunk/src/OCE/OBS/obs_read_surf.F90

Last change on this file was 13226, checked in by orioltp, 5 months ago

Merging dev_r12512_HPC-04_mcastril_Mixed_Precision_implementation into the trunk

  • Property svn:keywords set to Id
File size: 18.7 KB
Line 
1MODULE obs_read_surf
2   !!======================================================================
3   !!                       ***  MODULE obs_read_surf  ***
4   !! Observation diagnostics: Read the surface data from feedback files
5   !!======================================================================
6
7   !!----------------------------------------------------------------------
8   !!   obs_rea_surf : Driver for reading surface data from feedback files
9   !!----------------------------------------------------------------------
10
11   !! * Modules used
12   USE par_kind                 ! Precision variables
13   USE in_out_manager           ! I/O manager
14   USE dom_oce                  ! Ocean space and time domain variables
15   USE obs_mpp                  ! MPP support routines for observation diagnostics
16   USE julian                   ! Julian date routines
17   USE obs_utils                ! Observation operator utility functions
18   USE obs_grid                 ! Grid search
19   USE obs_sort                 ! Sorting observation arrays
20   USE obs_surf_def             ! Surface observation definitions
21   USE obs_types                ! Observation type definitions
22   USE obs_fbm                  ! Feedback routines
23   USE netcdf                   ! NetCDF library
24
25   IMPLICIT NONE
26
27   !! * Routine accessibility
28   PRIVATE
29
30   PUBLIC obs_rea_surf      ! Read the surface observations from the point data
31
32   !!----------------------------------------------------------------------
33   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
34   !! $Id$
35   !! Software governed by the CeCILL license (see ./LICENSE)
36   !!----------------------------------------------------------------------
37
38CONTAINS
39
40   SUBROUTINE obs_rea_surf( surfdata, knumfiles, cdfilenames, &
41      &                     kvars, kextr, kstp, ddobsini, ddobsend, &
42      &                     ldignmis, ldmod, ldnightav )
43      !!---------------------------------------------------------------------
44      !!
45      !!                   *** ROUTINE obs_rea_surf ***
46      !!
47      !! ** Purpose : Read from file the surface data
48      !!
49      !! ** Method  : Read in the data from feedback format files and
50      !!              put into the NEMO internal surface data structure
51      !!
52      !! ** Action  :
53      !!
54      !!
55      !! History : 
56      !!      ! :  2009-01 (K. Mogensen) Initial version based on old versions
57      !!      ! :  2015-02 (M. Martin)   Unify the different surface data type reading.
58      !!----------------------------------------------------------------------
59      !! * Modules used
60
61      !! * Arguments
62      TYPE(obs_surf), INTENT(INOUT) :: &
63         & surfdata                     ! Surface data to be read
64      INTEGER, INTENT(IN) :: knumfiles  ! Number of corio format files to read
65      CHARACTER(LEN=128), INTENT(IN) :: &
66         & cdfilenames(knumfiles)       ! File names to read in
67      INTEGER, INTENT(IN) :: kvars      ! Number of variables in surfdata
68      INTEGER, INTENT(IN) :: kextr      ! Number of extra fields for each var
69      INTEGER, INTENT(IN) :: kstp       ! Ocean time-step index
70      LOGICAL, INTENT(IN) :: ldignmis   ! Ignore missing files
71      LOGICAL, INTENT(IN) :: ldmod      ! Initialize model from input data
72      LOGICAL, INTENT(IN) :: ldnightav  ! Observations represent a night-time average
73      REAL(dp), INTENT(IN) :: ddobsini   ! Obs. ini time in YYYYMMDD.HHMMSS
74      REAL(dp), INTENT(IN) :: ddobsend   ! Obs. end time in YYYYMMDD.HHMMSS
75
76      !! * Local declarations
77      CHARACTER(LEN=11), PARAMETER :: cpname='obs_rea_surf'
78      CHARACTER(len=8) :: clrefdate
79      CHARACTER(len=8), DIMENSION(:), ALLOCATABLE :: clvars
80      INTEGER :: ji
81      INTEGER :: jj
82      INTEGER :: jk
83      INTEGER :: iflag
84      INTEGER :: inobf
85      INTEGER :: i_file_id
86      INTEGER :: inowin
87      INTEGER :: iyea
88      INTEGER :: imon
89      INTEGER :: iday
90      INTEGER :: ihou
91      INTEGER :: imin
92      INTEGER :: isec
93      INTEGER :: itype
94      INTEGER :: iobsmpp
95      INTEGER :: iobs
96      INTEGER :: iobstot
97      INTEGER :: ios
98      INTEGER :: ioserrcount
99      INTEGER, PARAMETER :: jpsurfmaxtype = 1024
100      INTEGER, DIMENSION(knumfiles) :: irefdate
101      INTEGER, DIMENSION(jpsurfmaxtype+1) :: &
102         & ityp, &
103         & itypmpp
104      INTEGER, DIMENSION(:), ALLOCATABLE :: &
105         & iobsi,    &
106         & iobsj,    &
107         & iproc,    &
108         & iindx,    &
109         & ifileidx, &
110         & isurfidx
111      REAL(wp), DIMENSION(:), ALLOCATABLE :: &
112         & zphi, &
113         & zlam
114      REAL(dp), DIMENSION(:), ALLOCATABLE :: &
115         & zdat
116      REAL(dp), DIMENSION(knumfiles) :: &
117         & djulini, &
118         & djulend
119      LOGICAL :: llvalprof
120      TYPE(obfbdata), POINTER, DIMENSION(:) :: &
121         & inpfiles
122
123      ! Local initialization
124      iobs = 0
125
126      !-----------------------------------------------------------------------
127      ! Count the number of files needed and allocate the obfbdata type
128      !-----------------------------------------------------------------------
129
130      inobf = knumfiles
131
132      ALLOCATE( inpfiles(inobf) )
133
134      surf_files : DO jj = 1, inobf
135
136         !---------------------------------------------------------------------
137         ! Prints
138         !---------------------------------------------------------------------
139         IF(lwp) THEN
140            WRITE(numout,*)
141            WRITE(numout,*) ' obs_rea_surf : Reading from file = ', &
142               & TRIM( TRIM( cdfilenames(jj) ) )
143            WRITE(numout,*) ' ~~~~~~~~~~~'
144            WRITE(numout,*)
145         ENDIF
146
147         !---------------------------------------------------------------------
148         !  Initialization: Open file and get dimensions only
149         !---------------------------------------------------------------------
150
151         iflag = nf90_open( TRIM( TRIM( cdfilenames(jj) ) ), nf90_nowrite, &
152            &                      i_file_id )
153
154         IF ( iflag /= nf90_noerr ) THEN
155
156            IF ( ldignmis ) THEN
157               inpfiles(jj)%nobs = 0
158               CALL ctl_warn( 'File ' // TRIM( TRIM( cdfilenames(jj) ) ) // &
159                  &           ' not found' )
160            ELSE
161               CALL ctl_stop( 'File ' // TRIM( TRIM( cdfilenames(jj) ) ) // &
162                  &           ' not found' )
163            ENDIF
164
165         ELSE 
166
167            !------------------------------------------------------------------
168            !  Close the file since it is opened in read_obfbdata
169            !------------------------------------------------------------------
170
171            iflag = nf90_close( i_file_id )
172
173            !------------------------------------------------------------------
174            !  Read the surface file into inpfiles
175            !------------------------------------------------------------------
176            CALL init_obfbdata( inpfiles(jj) )
177            CALL read_obfbdata( TRIM( cdfilenames(jj) ), inpfiles(jj), &
178               &                ldgrid = .TRUE. )
179
180            IF ( ldmod .AND. ( inpfiles(jj)%nadd == 0 ) ) THEN
181               CALL ctl_stop( 'Model not in input data' )
182               RETURN
183            ENDIF
184
185            IF ( jj == 1 ) THEN
186               ALLOCATE( clvars( inpfiles(jj)%nvar ) )
187               DO ji = 1, inpfiles(jj)%nvar
188                 clvars(ji) = inpfiles(jj)%cname(ji)
189               END DO
190            ELSE
191               DO ji = 1, inpfiles(jj)%nvar
192                  IF ( inpfiles(jj)%cname(ji) /= clvars(ji) ) THEN
193                     CALL ctl_stop( 'Feedback file variables not consistent', &
194                        &           ' with previous files for this type' )
195                  ENDIF
196               END DO
197            ENDIF
198
199            IF (lwp) WRITE(numout,*)'Observation file contains ',inpfiles(jj)%nobs,' observations'
200
201            !------------------------------------------------------------------
202            !  Change longitude (-180,180)
203            !------------------------------------------------------------------
204
205            DO ji = 1, inpfiles(jj)%nobs
206
207               IF ( inpfiles(jj)%plam(ji) < -180. ) &
208                  &   inpfiles(jj)%plam(ji) = inpfiles(jj)%plam(ji) + 360.
209
210               IF ( inpfiles(jj)%plam(ji) >  180. ) &
211                  &   inpfiles(jj)%plam(ji) = inpfiles(jj)%plam(ji) - 360.
212
213            END DO
214
215            !------------------------------------------------------------------
216            !  Calculate the date  (change eventually)
217            !------------------------------------------------------------------
218            clrefdate=inpfiles(jj)%cdjuldref(1:8)
219            READ(clrefdate,'(I8)') irefdate(jj)
220
221            CALL ddatetoymdhms( ddobsini, iyea, imon, iday, ihou, imin, isec )
222            CALL greg2jul( isec, imin, ihou, iday, imon, iyea, djulini(jj), &
223               &           krefdate = irefdate(jj) )
224            CALL ddatetoymdhms( ddobsend, iyea, imon, iday, ihou, imin, isec )
225            CALL greg2jul( isec, imin, ihou, iday, imon, iyea, djulend(jj), &
226               &           krefdate = irefdate(jj) )
227
228            IF ( ldnightav ) THEN
229
230               IF ( lwp ) THEN
231                  WRITE(numout,*)'Resetting time of night-time averaged observations', &
232                     &             ' to the end of the day'
233               ENDIF
234
235               DO ji = 1, inpfiles(jj)%nobs
236                  !  for night-time averaged data force the time
237                  !  to be the last time-step of the day, but still within the day.
238                  IF ( inpfiles(jj)%ptim(ji) >= 0. ) THEN
239                     inpfiles(jj)%ptim(ji) = &
240                        & INT(inpfiles(jj)%ptim(ji)) + 0.9999
241                  ELSE
242                     inpfiles(jj)%ptim(ji) = &
243                        & INT(inpfiles(jj)%ptim(ji)) - 0.0001
244                  ENDIF
245               END DO
246            ENDIF
247
248            IF ( inpfiles(jj)%nobs > 0 ) THEN
249               inpfiles(jj)%iproc = -1
250               inpfiles(jj)%iobsi = -1
251               inpfiles(jj)%iobsj = -1
252            ENDIF
253            inowin = 0
254            DO ji = 1, inpfiles(jj)%nobs
255               IF ( ( inpfiles(jj)%ptim(ji) >  djulini(jj) ) .AND. &
256                  & ( inpfiles(jj)%ptim(ji) <= djulend(jj) )       ) THEN
257                  inowin = inowin + 1
258               ENDIF
259            END DO
260            ALLOCATE( zlam(inowin)  )
261            ALLOCATE( zphi(inowin)  )
262            ALLOCATE( iobsi(inowin) )
263            ALLOCATE( iobsj(inowin) )
264            ALLOCATE( iproc(inowin) )
265            inowin = 0
266            DO ji = 1, inpfiles(jj)%nobs
267               IF ( ( inpfiles(jj)%ptim(ji) >  djulini(jj) ) .AND. &
268                  & ( inpfiles(jj)%ptim(ji) <= djulend(jj) )       ) THEN
269                  inowin = inowin + 1
270                  zlam(inowin) = inpfiles(jj)%plam(ji)
271                  zphi(inowin) = inpfiles(jj)%pphi(ji)
272               ENDIF
273            END DO
274
275            CALL obs_grid_search( inowin, zlam, zphi, iobsi, iobsj, iproc, 'T' )
276
277            inowin = 0
278            DO ji = 1, inpfiles(jj)%nobs
279               IF ( ( inpfiles(jj)%ptim(ji) >  djulini(jj) ) .AND. &
280                  & ( inpfiles(jj)%ptim(ji) <= djulend(jj) )       ) THEN
281                  inowin = inowin + 1
282                  inpfiles(jj)%iproc(ji,1) = iproc(inowin)
283                  inpfiles(jj)%iobsi(ji,1) = iobsi(inowin)
284                  inpfiles(jj)%iobsj(ji,1) = iobsj(inowin)
285               ENDIF
286            END DO
287            DEALLOCATE( zlam, zphi, iobsi, iobsj, iproc )
288
289            DO ji = 1, inpfiles(jj)%nobs
290               IF ( ( inpfiles(jj)%ptim(ji) >  djulini(jj) ) .AND. &
291                  & ( inpfiles(jj)%ptim(ji) <= djulend(jj) )       ) THEN
292                  IF ( nproc == 0 ) THEN
293                     IF ( inpfiles(jj)%iproc(ji,1) >  nproc ) CYCLE
294                  ELSE
295                     IF ( inpfiles(jj)%iproc(ji,1) /= nproc ) CYCLE
296                  ENDIF
297                  llvalprof = .FALSE.
298                  IF ( .NOT. BTEST(inpfiles(jj)%ivlqc(1,ji,1),2) ) THEN
299                     iobs = iobs + 1
300                  ENDIF
301               ENDIF
302            END DO
303
304         ENDIF
305
306      END DO surf_files
307
308      !-----------------------------------------------------------------------
309      ! Get the time ordered indices of the input data
310      !-----------------------------------------------------------------------
311
312      !---------------------------------------------------------------------
313      !  Loop over input data files to count total number of profiles
314      !---------------------------------------------------------------------
315      iobstot = 0
316      DO jj = 1, inobf
317         DO ji = 1, inpfiles(jj)%nobs
318            IF ( ( inpfiles(jj)%ptim(ji) >  djulini(jj) ) .AND. &
319               & ( inpfiles(jj)%ptim(ji) <= djulend(jj) )       ) THEN
320               iobstot = iobstot + 1
321            ENDIF
322         END DO
323      END DO
324
325      ALLOCATE( iindx(iobstot), ifileidx(iobstot), &
326         &      isurfidx(iobstot), zdat(iobstot) )
327      jk = 0
328      DO jj = 1, inobf
329         DO ji = 1, inpfiles(jj)%nobs
330            IF ( ( inpfiles(jj)%ptim(ji) >  djulini(jj) ) .AND. &
331               & ( inpfiles(jj)%ptim(ji) <= djulend(jj) )       ) THEN
332               jk = jk + 1
333               ifileidx(jk) = jj
334               isurfidx(jk) = ji
335               zdat(jk)     = inpfiles(jj)%ptim(ji)
336            ENDIF
337         END DO
338      END DO
339      CALL sort_dp_indx( iobstot, &
340         &               zdat,     &
341         &               iindx   )
342
343      CALL obs_surf_alloc( surfdata, iobs, kvars, kextr, kstp, jpi, jpj )
344
345      ! Read obs/positions, QC, all variable and assign to surfdata
346
347      iobs = 0
348
349      surfdata%cvars(:)  = clvars(:)
350
351      ityp   (:) = 0
352      itypmpp(:) = 0
353
354      ioserrcount = 0
355
356      DO jk = 1, iobstot
357
358         jj = ifileidx(iindx(jk))
359         ji = isurfidx(iindx(jk))
360         IF ( ( inpfiles(jj)%ptim(ji) >  djulini(jj) ) .AND.  &
361            & ( inpfiles(jj)%ptim(ji) <= djulend(jj) ) ) THEN
362
363            IF ( nproc == 0 ) THEN
364               IF ( inpfiles(jj)%iproc(ji,1) >  nproc ) CYCLE
365            ELSE
366               IF ( inpfiles(jj)%iproc(ji,1) /= nproc ) CYCLE
367            ENDIF
368
369            ! Set observation information
370
371            IF ( .NOT. BTEST(inpfiles(jj)%ivlqc(1,ji,1),2) ) THEN
372
373               iobs = iobs + 1
374
375               CALL jul2greg( isec,                   &
376                  &           imin,                   &
377                  &           ihou,                   &
378                  &           iday,                   &
379                  &           imon,                   &
380                  &           iyea,                   &
381                  &           inpfiles(jj)%ptim(ji), &
382                  &           irefdate(jj) )
383
384
385               ! Surface time coordinates
386               surfdata%nyea(iobs) = iyea
387               surfdata%nmon(iobs) = imon
388               surfdata%nday(iobs) = iday
389               surfdata%nhou(iobs) = ihou
390               surfdata%nmin(iobs) = imin
391
392               ! Surface space coordinates
393               surfdata%rlam(iobs) = inpfiles(jj)%plam(ji)
394               surfdata%rphi(iobs) = inpfiles(jj)%pphi(ji)
395
396               ! Coordinate search parameters
397               surfdata%mi  (iobs) = inpfiles(jj)%iobsi(ji,1)
398               surfdata%mj  (iobs) = inpfiles(jj)%iobsj(ji,1)
399
400               ! WMO number
401               surfdata%cwmo(iobs) = inpfiles(jj)%cdwmo(ji)
402
403               ! Instrument type
404               READ( inpfiles(jj)%cdtyp(ji), '(I4)', IOSTAT = ios, ERR = 901 ) itype
405901            IF ( ios /= 0 ) THEN
406                  IF (ioserrcount == 0) THEN
407                     CALL ctl_warn ( 'Problem converting an instrument type ', &
408                        &            'to integer. Setting type to zero' )
409                  ENDIF
410                  ioserrcount = ioserrcount + 1
411                  itype = 0
412               ENDIF
413               surfdata%ntyp(iobs) = itype
414               IF ( itype < jpsurfmaxtype + 1 ) THEN
415                  ityp(itype+1) = ityp(itype+1) + 1
416               ELSE
417                  IF(lwp)WRITE(numout,*)'WARNING:Increase jpsurfmaxtype in ',&
418                     &                  cpname
419               ENDIF
420
421               ! Bookkeeping data to match observations
422               surfdata%nsidx(iobs) = iobs
423               surfdata%nsfil(iobs) = iindx(jk)
424
425               ! QC flags
426               surfdata%nqc(iobs) = inpfiles(jj)%ivqc(ji,1)
427
428               ! Observed value
429               surfdata%robs(iobs,1) = inpfiles(jj)%pob(1,ji,1)
430
431
432               ! Model and MDT is set to fbrmdi unless read from file
433               IF ( ldmod ) THEN
434                  surfdata%rmod(iobs,1) = inpfiles(jj)%padd(1,ji,1,1)
435                  IF ( TRIM(surfdata%cvars(1)) == 'SLA' ) THEN
436                     surfdata%rext(iobs,1) = inpfiles(jj)%padd(1,ji,2,1)
437                     surfdata%rext(iobs,2) = inpfiles(jj)%pext(1,ji,1)
438                  ENDIF
439                ELSE
440                  surfdata%rmod(iobs,1) = fbrmdi
441                  IF ( TRIM(surfdata%cvars(1)) == 'SLA' ) surfdata%rext(iobs,:) = fbrmdi
442               ENDIF
443            ENDIF
444         ENDIF
445
446      END DO
447
448      !-----------------------------------------------------------------------
449      ! Sum up over processors
450      !-----------------------------------------------------------------------
451
452      CALL obs_mpp_sum_integer( iobs, iobsmpp )
453      CALL obs_mpp_sum_integers( ityp, itypmpp, jpsurfmaxtype + 1 )
454
455      !-----------------------------------------------------------------------
456      ! Output number of observations.
457      !-----------------------------------------------------------------------
458      IF (lwp) THEN
459
460         WRITE(numout,*)
461         WRITE(numout,'(1X,A)')TRIM( surfdata%cvars(1) )//' data'
462         WRITE(numout,'(1X,A)')'--------------'
463         DO jj = 1,8
464            IF ( itypmpp(jj) > 0 ) THEN
465               WRITE(numout,'(1X,A4,I4,A3,I10)')'Type ', jj,' = ',itypmpp(jj)
466            ENDIF
467         END DO
468         WRITE(numout,'(1X,A)') &
469            & '---------------------------------------------------------------'
470         WRITE(numout,'(1X,A,I8)') &
471            & 'Total data for variable '//TRIM( surfdata%cvars(1) )// &
472            & '           = ', iobsmpp
473         WRITE(numout,'(1X,A)') &
474            & '---------------------------------------------------------------'
475         WRITE(numout,*)
476
477      ENDIF
478
479      !-----------------------------------------------------------------------
480      ! Deallocate temporary data
481      !-----------------------------------------------------------------------
482      DEALLOCATE( ifileidx, isurfidx, zdat, clvars )
483
484      !-----------------------------------------------------------------------
485      ! Deallocate input data
486      !-----------------------------------------------------------------------
487      DO jj = 1, inobf
488         IF ( inpfiles(jj)%lalloc ) THEN
489            CALL dealloc_obfbdata( inpfiles(jj) )
490         ENDIF
491      END DO
492      DEALLOCATE( inpfiles )
493
494   END SUBROUTINE obs_rea_surf
495
496END MODULE obs_read_surf
Note: See TracBrowser for help on using the repository browser.