New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcfwb.F90 in NEMO/trunk/src/OCE/SBC – NEMO

source: NEMO/trunk/src/OCE/SBC/sbcfwb.F90 @ 15004

Last change on this file since 15004 was 15004, checked in by mathiot, 16 months ago

ticket #2960: commit fix to the trunk (WARNING: output convention of isf fluxes changed from oce->isf to isf->oce), no impact on the input file needed for some options

  • Property svn:keywords set to Id
File size: 13.4 KB
Line 
1MODULE sbcfwb
2   !!======================================================================
3   !!                       ***  MODULE  sbcfwb  ***
4   !! Ocean fluxes   : domain averaged freshwater budget
5   !!======================================================================
6   !! History :  OPA  ! 2001-02  (E. Durand)  Original code
7   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
8   !!            3.0  ! 2006-08  (G. Madec)  Surface module
9   !!            3.2  ! 2009-07  (C. Talandier) emp mean s spread over erp area
10   !!            3.6  ! 2014-11  (P. Mathiot  ) add ice shelf melting
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   sbc_fwb       : freshwater budget for global ocean configurations (free surface & forced mode)
15   !!----------------------------------------------------------------------
16   USE oce            ! ocean dynamics and tracers
17   USE dom_oce        ! ocean space and time domain
18   USE sbc_oce        ! surface ocean boundary condition
19   USE isf_oce , ONLY : fwfisf_cav, fwfisf_par                    ! ice shelf melting contribution
20   USE sbc_ice , ONLY : snwice_mass, snwice_mass_b, snwice_fmass
21   USE phycst         ! physical constants
22   USE sbcrnf         ! ocean runoffs
23   USE sbcssr         ! Sea-Surface damping terms
24   !
25   USE in_out_manager ! I/O manager
26   USE iom            ! IOM
27   USE lib_mpp        ! distribued memory computing library
28   USE timing         ! Timing
29   USE lbclnk         ! ocean lateral boundary conditions
30   USE lib_fortran    !
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   sbc_fwb    ! routine called by step
36
37   REAL(wp) ::   rn_fwb0   ! initial freshwater adjustment flux [kg/m2/s] (nn_fwb = 2 only)
38   REAL(wp) ::   a_fwb     ! annual domain averaged freshwater budget from the
39                           ! previous year
40   REAL(wp) ::   area      ! global mean ocean surface (interior domain)
41
42   !!----------------------------------------------------------------------
43   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
44   !! $Id$
45   !! Software governed by the CeCILL license (see ./LICENSE)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   SUBROUTINE sbc_fwb( kt, kn_fwb, kn_fsbc, Kmm )
50      !!---------------------------------------------------------------------
51      !!                  ***  ROUTINE sbc_fwb  ***
52      !!
53      !! ** Purpose :   Control the mean sea surface drift
54      !!
55      !! ** Method  :   several ways  depending on kn_fwb
56      !!                =0 no control
57      !!                =1 global mean of emp set to zero at each nn_fsbc time step
58      !!                =2 annual global mean corrected from previous year
59      !!                =3 global mean of emp set to zero at each nn_fsbc time step
60      !!                   & spread out over erp area depending its sign
61      !! Note: if sea ice is embedded it is taken into account when computing the budget
62      !!----------------------------------------------------------------------
63      INTEGER, INTENT( in ) ::   kt       ! ocean time-step index
64      INTEGER, INTENT( in ) ::   kn_fsbc  !
65      INTEGER, INTENT( in ) ::   kn_fwb   ! ocean time-step index
66      INTEGER, INTENT( in ) ::   Kmm      ! ocean time level index
67      !
68      INTEGER  ::   ios, inum, ikty       ! local integers
69      REAL(wp) ::   z_fwf, z_fwf_nsrf, zsum_fwf, zsum_erp                ! local scalars
70      REAL(wp) ::   zsurf_neg, zsurf_pos, zsurf_tospread, zcoef          !   -      -
71      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   ztmsk_neg, ztmsk_pos, z_wgt ! 2D workspaces
72      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   ztmsk_tospread, zerp_cor    !   -      -
73      REAL(wp)   ,DIMENSION(1) ::   z_fwfprv 
74      COMPLEX(dp),DIMENSION(1) ::   y_fwfnow 
75      !
76      NAMELIST/namsbc_fwb/rn_fwb0
77      !!----------------------------------------------------------------------
78      !
79      IF( kt == nit000 ) THEN
80         READ( numnam_ref, namsbc_fwb, IOSTAT = ios, ERR = 901 )
81901      IF( ios /= 0 ) CALL ctl_nam( ios, 'namsbc_fwb in reference namelist'     )
82         READ( numnam_cfg, namsbc_fwb, IOSTAT = ios, ERR = 902 )
83902      IF( ios >  0 ) CALL ctl_nam( ios, 'namsbc_fwb in configuration namelist' )
84         IF(lwm) WRITE( numond, namsbc_fwb )
85         IF(lwp) THEN
86            WRITE(numout,*)
87            WRITE(numout,*) 'sbc_fwb : FreshWater Budget correction'
88            WRITE(numout,*) '~~~~~~~'
89            IF( kn_fwb == 1 )   WRITE(numout,*) '          instantaneously set to zero'
90            IF( kn_fwb == 3 )   WRITE(numout,*) '          fwf set to zero and spread out over erp area'
91            IF( kn_fwb == 2 ) THEN
92               WRITE(numout,*) '          adjusted from previous year budget'
93               WRITE(numout,*)
94               WRITE(numout,*) '   Namelist namsbc_fwb'
95               WRITE(numout,*) '      Initial freshwater adjustment flux [kg/m2/s] = ', rn_fwb0
96            END IF
97         ENDIF
98         !
99         IF( kn_fwb == 3 .AND. nn_sssr /= 2 )   CALL ctl_stop( 'sbc_fwb: nn_fwb = 3 requires nn_sssr = 2, we stop ' )
100         IF( kn_fwb == 3 .AND. ln_isfcav    )   CALL ctl_stop( 'sbc_fwb: nn_fwb = 3 with ln_isfcav = .TRUE. not working, we stop ' )
101         !
102         area = glob_sum( 'sbcfwb', e1e2t(:,:) * tmask(:,:,1))           ! interior global domain surface
103         ! isf cavities are excluded because it can feedback to the melting with generation of inhibition of plumes
104         ! and in case of no melt, it can generate HSSW.
105         !
106#if ! defined key_si3 && ! defined key_cice
107         snwice_mass_b(:,:) = 0.e0               ! no sea-ice model is being used : no snow+ice mass
108         snwice_mass  (:,:) = 0.e0
109         snwice_fmass (:,:) = 0.e0
110#endif
111         !
112      ENDIF
113
114      SELECT CASE ( kn_fwb )
115      !
116      CASE ( 1 )                             !==  global mean fwf set to zero  ==!
117         !
118         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
119            y_fwfnow(1) = local_sum( e1e2t(:,:) * ( emp(:,:) - rnf(:,:) - fwfisf_cav(:,:) - fwfisf_par(:,:) - snwice_fmass(:,:) ) )
120            CALL mpp_delay_sum( 'sbcfwb', 'fwb', y_fwfnow(:), z_fwfprv(:), kt == nitend - nn_fsbc + 1 )
121            z_fwfprv(1) = z_fwfprv(1) / area
122            zcoef = z_fwfprv(1) * rcp
123            emp(:,:) = emp(:,:) - z_fwfprv(1)        * tmask(:,:,1)
124            qns(:,:) = qns(:,:) + zcoef * sst_m(:,:) * tmask(:,:,1) ! account for change to the heat budget due to fw correction
125            ! outputs
126            IF( iom_use('hflx_fwb_cea') )  CALL iom_put( 'hflx_fwb_cea', zcoef * sst_m(:,:) * tmask(:,:,1) )
127            IF( iom_use('vflx_fwb_cea') )  CALL iom_put( 'vflx_fwb_cea', z_fwfprv(1)        * tmask(:,:,1) )
128         ENDIF
129         !
130      CASE ( 2 )                             !==  fw adjustment based on fw budget at the end of the previous year  ==!
131         !
132         IF( kt == nit000 ) THEN                                                                    ! initialisation
133            !                                                                                       ! set the fw adjustment (a_fwb)
134            IF ( ln_rstart .AND. iom_varid( numror, 'a_fwb',   ldstop = .FALSE. ) > 0 ) THEN        !    as read from restart file
135               IF(lwp) WRITE(numout,*) 'sbc_fwb : reading FW-budget adjustment from restart file'
136               CALL iom_get( numror, 'a_fwb',   a_fwb )
137            ELSE                                                                                    !    as specified in namelist
138               a_fwb = rn_fwb0
139            END IF
140            !
141            IF(lwp)WRITE(numout,*)
142            IF(lwp)WRITE(numout,*)'sbc_fwb : initial freshwater-budget adjustment = ', a_fwb, 'kg/m2/s'
143            !
144         ENDIF   
145         !                                         ! Update a_fwb if new year start
146         ikty = 365 * 86400 / rn_Dt                  !!bug  use of 365 days leap year or 360d year !!!!!!!
147         IF( MOD( kt, ikty ) == 0 ) THEN
148                                                      ! mean sea level taking into account the ice+snow
149                                                      ! sum over the global domain
150            a_fwb   = glob_sum( 'sbcfwb', e1e2t(:,:) * ( ssh(:,:,Kmm) + snwice_mass(:,:) * r1_rho0 ) )
151            a_fwb   = a_fwb * 1.e+3 / ( area * rday * 365. )     ! convert in Kg/m3/s = mm/s
152!!gm        !                                                      !!bug 365d year
153         ENDIF
154         !
155         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN         ! correct the freshwater fluxes
156            zcoef = a_fwb * rcp
157            emp(:,:) = emp(:,:) + a_fwb              * tmask(:,:,1)
158            qns(:,:) = qns(:,:) - zcoef * sst_m(:,:) * tmask(:,:,1) ! account for change to the heat budget due to fw correction
159            ! outputs
160            IF( iom_use('hflx_fwb_cea') )  CALL iom_put( 'hflx_fwb_cea', -zcoef * sst_m(:,:) * tmask(:,:,1) )
161            IF( iom_use('vflx_fwb_cea') )  CALL iom_put( 'vflx_fwb_cea', -a_fwb              * tmask(:,:,1) )
162         ENDIF
163         ! Output restart information
164         IF( lrst_oce ) THEN
165            IF(lwp) WRITE(numout,*)
166            IF(lwp) WRITE(numout,*) 'sbc_fwb : writing FW-budget adjustment to ocean restart file at it = ', kt
167            IF(lwp) WRITE(numout,*) '~~~~'
168            CALL iom_rstput( kt, nitrst, numrow, 'a_fwb',   a_fwb )
169         END IF
170         !
171         IF( kt == nitend .AND. lwp ) WRITE(numout,*) 'sbc_fwb : final freshwater-budget adjustment = ', a_fwb, 'kg/m2/s'
172         !
173      CASE ( 3 )                             !==  global fwf set to zero and spread out over erp area  ==!
174         !
175         ALLOCATE( ztmsk_neg(jpi,jpj) , ztmsk_pos(jpi,jpj) , ztmsk_tospread(jpi,jpj) , z_wgt(jpi,jpj) , zerp_cor(jpi,jpj) )
176         !
177         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
178            ztmsk_pos(:,:) = tmask_i(:,:)                      ! Select <0 and >0 area of erp
179            WHERE( erp < 0._wp )   ztmsk_pos = 0._wp
180            ztmsk_neg(:,:) = tmask_i(:,:) - ztmsk_pos(:,:)
181            !                                                  ! fwf global mean (excluding ocean to ice/snow exchanges)
182            z_fwf     = glob_sum( 'sbcfwb', e1e2t(:,:) * ( emp(:,:) - rnf(:,:) - fwfisf_cav(:,:) - fwfisf_par(:,:) - snwice_fmass(:,:) ) ) / area
183            !           
184            IF( z_fwf < 0._wp ) THEN         ! spread out over >0 erp area to increase evaporation
185               zsurf_pos = glob_sum( 'sbcfwb', e1e2t(:,:)*ztmsk_pos(:,:) )
186               zsurf_tospread      = zsurf_pos
187               ztmsk_tospread(:,:) = ztmsk_pos(:,:)
188            ELSE                             ! spread out over <0 erp area to increase precipitation
189               zsurf_neg = glob_sum( 'sbcfwb', e1e2t(:,:)*ztmsk_neg(:,:) )  ! Area filled by <0 and >0 erp
190               zsurf_tospread      = zsurf_neg
191               ztmsk_tospread(:,:) = ztmsk_neg(:,:)
192            ENDIF
193            !
194            zsum_fwf   = glob_sum( 'sbcfwb', e1e2t(:,:) * z_fwf )         ! fwf global mean over <0 or >0 erp area
195!!gm :  zsum_fwf   = z_fwf * area   ???  it is right?  I think so....
196            z_fwf_nsrf =  zsum_fwf / ( zsurf_tospread + rsmall )
197            !                                                  ! weight to respect erp field 2D structure
198            zsum_erp   = glob_sum( 'sbcfwb', ztmsk_tospread(:,:) * erp(:,:) * e1e2t(:,:) )
199            z_wgt(:,:) = ztmsk_tospread(:,:) * erp(:,:) / ( zsum_erp + rsmall )
200            !                                                  ! final correction term to apply
201            zerp_cor(:,:) = -1. * z_fwf_nsrf * zsurf_tospread * z_wgt(:,:)
202            !
203!!gm   ===>>>>  lbc_lnk should be useless as all the computation is done over the whole domain !
204            CALL lbc_lnk( 'sbcfwb', zerp_cor, 'T', 1.0_wp )
205            !
206            emp(:,:) = emp(:,:) + zerp_cor(:,:)
207            qns(:,:) = qns(:,:) - zerp_cor(:,:) * rcp * sst_m(:,:)  ! account for change to the heat budget due to fw correction
208            erp(:,:) = erp(:,:) + zerp_cor(:,:)
209            ! outputs
210            IF( iom_use('hflx_fwb_cea') )  CALL iom_put( 'hflx_fwb_cea', -zerp_cor(:,:) * rcp * sst_m(:,:) )
211            IF( iom_use('vflx_fwb_cea') )  CALL iom_put( 'vflx_fwb_cea', -zerp_cor(:,:) )
212            !
213            IF( lwp ) THEN                   ! control print
214               IF( z_fwf < 0._wp ) THEN
215                  WRITE(numout,*)'   z_fwf < 0'
216                  WRITE(numout,*)'   SUM(erp+)     = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv'
217               ELSE
218                  WRITE(numout,*)'   z_fwf >= 0'
219                  WRITE(numout,*)'   SUM(erp-)     = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv'
220               ENDIF
221               WRITE(numout,*)'   SUM(empG)     = ', SUM( z_fwf*e1e2t(:,:) )*1.e-9,' Sv'
222               WRITE(numout,*)'   z_fwf         = ', z_fwf      ,' Kg/m2/s'
223               WRITE(numout,*)'   z_fwf_nsrf    = ', z_fwf_nsrf ,' Kg/m2/s'
224               WRITE(numout,*)'   MIN(zerp_cor) = ', MINVAL(zerp_cor) 
225               WRITE(numout,*)'   MAX(zerp_cor) = ', MAXVAL(zerp_cor) 
226            ENDIF
227         ENDIF
228         DEALLOCATE( ztmsk_neg , ztmsk_pos , ztmsk_tospread , z_wgt , zerp_cor )
229         !
230      CASE DEFAULT                           !==  you should never be there  ==!
231         CALL ctl_stop( 'sbc_fwb : wrong nn_fwb value for the FreshWater Budget correction, choose either 1, 2 or 3' )
232         !
233      END SELECT
234      !
235   END SUBROUTINE sbc_fwb
236
237   !!======================================================================
238END MODULE sbcfwb
Note: See TracBrowser for help on using the repository browser.