source: NEMO/trunk/src/OCE/SBC/sbcrnf.F90 @ 13237

Last change on this file since 13237 was 13237, checked in by smasson, 3 months ago

trunk: Mid-year merge, merge back KERNEL-06_techene_e3

  • Property svn:keywords set to Id
File size: 30.0 KB
Line 
1MODULE sbcrnf
2   !!======================================================================
3   !!                       ***  MODULE  sbcrnf  ***
4   !! Ocean forcing:  river runoff
5   !!=====================================================================
6   !! History :  OPA  ! 2000-11  (R. Hordoir, E. Durand)  NetCDF FORMAT
7   !!   NEMO     1.0  ! 2002-09  (G. Madec)  F90: Free form and module
8   !!            3.0  ! 2006-07  (G. Madec)  Surface module
9   !!            3.2  ! 2009-04  (B. Lemaire)  Introduce iom_put
10   !!            3.3  ! 2010-10  (R. Furner, G. Madec) runoff distributed over ocean levels
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   sbc_rnf       : monthly runoffs read in a NetCDF file
15   !!   sbc_rnf_init  : runoffs initialisation
16   !!   rnf_mouth     : set river mouth mask
17   !!----------------------------------------------------------------------
18   USE dom_oce        ! ocean space and time domain
19   USE phycst         ! physical constants
20   USE sbc_oce        ! surface boundary condition variables
21   USE eosbn2         ! Equation Of State
22   USE closea, ONLY: l_clo_rnf, clo_rnf ! closed seas
23   !
24   USE in_out_manager ! I/O manager
25   USE fldread        ! read input field at current time step
26   USE iom            ! I/O module
27   USE lib_mpp        ! MPP library
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   sbc_rnf       ! called in sbcmod module
33   PUBLIC   sbc_rnf_div   ! called in divhor module
34   PUBLIC   sbc_rnf_alloc ! called in sbcmod module
35   PUBLIC   sbc_rnf_init  ! called in sbcmod module
36   
37   !                                                !!* namsbc_rnf namelist *
38   CHARACTER(len=100)         ::   cn_dir            !: Root directory for location of rnf files
39   LOGICAL           , PUBLIC ::   ln_rnf_depth      !: depth       river runoffs attribute specified in a file
40   LOGICAL                    ::      ln_rnf_depth_ini  !: depth       river runoffs  computed at the initialisation
41   REAL(wp)                   ::      rn_rnf_max        !: maximum value of the runoff climatologie (ln_rnf_depth_ini =T)
42   REAL(wp)                   ::      rn_dep_max        !: depth over which runoffs is spread       (ln_rnf_depth_ini =T)
43   INTEGER                    ::      nn_rnf_depth_file !: create (=1) a runoff depth file or not (=0)
44   LOGICAL                    ::   ln_rnf_icb        !: iceberg flux is specified in a file
45   LOGICAL                    ::   ln_rnf_tem        !: temperature river runoffs attribute specified in a file
46   LOGICAL           , PUBLIC ::   ln_rnf_sal        !: salinity    river runoffs attribute specified in a file
47   TYPE(FLD_N)       , PUBLIC ::   sn_rnf            !: information about the runoff file to be read
48   TYPE(FLD_N)                ::   sn_cnf            !: information about the runoff mouth file to be read
49   TYPE(FLD_N)                ::   sn_i_rnf        !: information about the iceberg flux file to be read
50   TYPE(FLD_N)                ::   sn_s_rnf          !: information about the salinities of runoff file to be read
51   TYPE(FLD_N)                ::   sn_t_rnf          !: information about the temperatures of runoff file to be read
52   TYPE(FLD_N)                ::   sn_dep_rnf        !: information about the depth which river inflow affects
53   LOGICAL           , PUBLIC ::   ln_rnf_mouth      !: specific treatment in mouths vicinity
54   REAL(wp)                   ::   rn_hrnf           !: runoffs, depth over which enhanced vertical mixing is used
55   REAL(wp)          , PUBLIC ::   rn_avt_rnf        !: runoffs, value of the additional vertical mixing coef. [m2/s]
56   REAL(wp)          , PUBLIC ::   rn_rfact          !: multiplicative factor for runoff
57
58   LOGICAL , PUBLIC ::   l_rnfcpl = .false.   !: runoffs recieved from oasis
59   INTEGER , PUBLIC ::   nkrnf = 0            !: nb of levels over which Kz is increased at river mouths
60   
61   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   rnfmsk              !: river mouth mask (hori.)
62   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:)     ::   rnfmsk_z            !: river mouth mask (vert.)
63   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   h_rnf               !: depth of runoff in m
64   INTEGER,  PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   nk_rnf              !: depth of runoff in model levels
65   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   rnf_tsc_b, rnf_tsc  !: before and now T & S runoff contents   [K.m/s & PSU.m/s]   
66
67   TYPE(FLD),        ALLOCATABLE, DIMENSION(:) ::   sf_rnf       ! structure: river runoff (file information, fields read)
68   TYPE(FLD),        ALLOCATABLE, DIMENSION(:) ::   sf_i_rnf     ! structure: iceberg flux (file information, fields read)
69   TYPE(FLD),        ALLOCATABLE, DIMENSION(:) ::   sf_s_rnf     ! structure: river runoff salinity (file information, fields read) 
70   TYPE(FLD),        ALLOCATABLE, DIMENSION(:) ::   sf_t_rnf     ! structure: river runoff temperature (file information, fields read) 
71 
72   !! * Substitutions
73#  include "do_loop_substitute.h90"
74#  include "domzgr_substitute.h90"
75   !!----------------------------------------------------------------------
76   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
77   !! $Id$
78   !! Software governed by the CeCILL license (see ./LICENSE)
79   !!----------------------------------------------------------------------
80CONTAINS
81
82   INTEGER FUNCTION sbc_rnf_alloc()
83      !!----------------------------------------------------------------------
84      !!                ***  ROUTINE sbc_rnf_alloc  ***
85      !!----------------------------------------------------------------------
86      ALLOCATE( rnfmsk(jpi,jpj)         , rnfmsk_z(jpk)          ,     &
87         &      h_rnf (jpi,jpj)         , nk_rnf  (jpi,jpj)      ,     &
88         &      rnf_tsc_b(jpi,jpj,jpts) , rnf_tsc (jpi,jpj,jpts) , STAT=sbc_rnf_alloc )
89         !
90      CALL mpp_sum ( 'sbcrnf', sbc_rnf_alloc )
91      IF( sbc_rnf_alloc > 0 )   CALL ctl_warn('sbc_rnf_alloc: allocation of arrays failed')
92   END FUNCTION sbc_rnf_alloc
93
94
95   SUBROUTINE sbc_rnf( kt )
96      !!----------------------------------------------------------------------
97      !!                  ***  ROUTINE sbc_rnf  ***
98      !!
99      !! ** Purpose :   Introduce a climatological run off forcing
100      !!
101      !! ** Method  :   Set each river mouth with a monthly climatology
102      !!                provided from different data.
103      !!                CAUTION : upward water flux, runoff forced to be < 0
104      !!
105      !! ** Action  :   runoff updated runoff field at time-step kt
106      !!----------------------------------------------------------------------
107      INTEGER, INTENT(in) ::   kt          ! ocean time step
108      !
109      INTEGER  ::   ji, jj    ! dummy loop indices
110      INTEGER  ::   z_err = 0 ! dummy integer for error handling
111      !!----------------------------------------------------------------------
112      REAL(wp), DIMENSION(jpi,jpj) ::   ztfrz   ! freezing point used for temperature correction
113      !
114      !
115      !                                            !-------------------!
116      !                                            !   Update runoff   !
117      !                                            !-------------------!
118      !
119      !
120      IF( .NOT. l_rnfcpl )  THEN
121                            CALL fld_read ( kt, nn_fsbc, sf_rnf   )    ! Read Runoffs data and provide it at kt ( runoffs + iceberg )
122         IF( ln_rnf_icb )   CALL fld_read ( kt, nn_fsbc, sf_i_rnf )    ! idem for iceberg flux if required
123      ENDIF
124      IF(   ln_rnf_tem   )   CALL fld_read ( kt, nn_fsbc, sf_t_rnf )    ! idem for runoffs temperature if required
125      IF(   ln_rnf_sal   )   CALL fld_read ( kt, nn_fsbc, sf_s_rnf )    ! idem for runoffs salinity    if required
126      !
127      IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN
128         !
129         IF( .NOT. l_rnfcpl ) THEN
130             rnf(:,:) = rn_rfact * ( sf_rnf(1)%fnow(:,:,1) ) * tmask(:,:,1)  ! updated runoff value at time step kt
131             IF( ln_rnf_icb ) THEN
132                fwficb(:,:) = rn_rfact * ( sf_i_rnf(1)%fnow(:,:,1) ) * tmask(:,:,1)  ! updated runoff value at time step kt
133                CALL iom_put( 'iceberg_cea'  , fwficb(:,:)  )         ! output iceberg flux
134                CALL iom_put( 'hflx_icb_cea' , fwficb(:,:) * rLfus )   ! output Heat Flux into Sea Water due to Iceberg Thermodynamics -->
135             ENDIF
136         ENDIF
137         !
138         !                                                           ! set temperature & salinity content of runoffs
139         IF( ln_rnf_tem ) THEN                                       ! use runoffs temperature data
140            rnf_tsc(:,:,jp_tem) = ( sf_t_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rho0
141            CALL eos_fzp( sss_m(:,:), ztfrz(:,:) )
142            WHERE( sf_t_rnf(1)%fnow(:,:,1) == -999._wp )             ! if missing data value use SST as runoffs temperature
143               rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rho0
144            END WHERE
145         ELSE                                                        ! use SST as runoffs temperature
146            !CEOD River is fresh water so must at least be 0 unless we consider ice
147            rnf_tsc(:,:,jp_tem) = MAX( sst_m(:,:), 0.0_wp ) * rnf(:,:) * r1_rho0
148         ENDIF
149         !                                                           ! use runoffs salinity data
150         IF( ln_rnf_sal )   rnf_tsc(:,:,jp_sal) = ( sf_s_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rho0
151         !                                                           ! else use S=0 for runoffs (done one for all in the init)
152                                         CALL iom_put( 'runoffs'     , rnf(:,:)                         )   ! output runoff mass flux
153         IF( iom_use('hflx_rnf_cea') )   CALL iom_put( 'hflx_rnf_cea', rnf_tsc(:,:,jp_tem) * rho0 * rcp )   ! output runoff sensible heat (W/m2)
154      ENDIF
155      !
156      !                                                ! ---------------------------------------- !
157      IF( kt == nit000 ) THEN                          !   set the forcing field at nit000 - 1    !
158         !                                             ! ---------------------------------------- !
159         IF( ln_rstart .AND.    &                               !* Restart: read in restart file
160            & iom_varid( numror, 'rnf_b', ldstop = .FALSE. ) > 0 ) THEN
161            IF(lwp) WRITE(numout,*) '          nit000-1 runoff forcing fields red in the restart file', lrxios
162            CALL iom_get( numror, jpdom_autoglo, 'rnf_b', rnf_b, ldxios = lrxios )     ! before runoff
163            CALL iom_get( numror, jpdom_autoglo, 'rnf_hc_b', rnf_tsc_b(:,:,jp_tem), ldxios = lrxios )   ! before heat content of runoff
164            CALL iom_get( numror, jpdom_autoglo, 'rnf_sc_b', rnf_tsc_b(:,:,jp_sal), ldxios = lrxios )   ! before salinity content of runoff
165         ELSE                                                   !* no restart: set from nit000 values
166            IF(lwp) WRITE(numout,*) '          nit000-1 runoff forcing fields set to nit000'
167            rnf_b    (:,:  ) = rnf    (:,:  )
168            rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
169         ENDIF
170      ENDIF
171      !                                                ! ---------------------------------------- !
172      IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
173         !                                             ! ---------------------------------------- !
174         IF(lwp) WRITE(numout,*)
175         IF(lwp) WRITE(numout,*) 'sbcrnf : runoff forcing fields written in ocean restart file ',   &
176            &                    'at it= ', kt,' date= ', ndastp
177         IF(lwp) WRITE(numout,*) '~~~~'
178         IF( lwxios ) CALL iom_swap(      cwxios_context          )
179         CALL iom_rstput( kt, nitrst, numrow, 'rnf_b' , rnf, ldxios = lwxios )
180         CALL iom_rstput( kt, nitrst, numrow, 'rnf_hc_b', rnf_tsc(:,:,jp_tem), ldxios = lwxios )
181         CALL iom_rstput( kt, nitrst, numrow, 'rnf_sc_b', rnf_tsc(:,:,jp_sal), ldxios = lwxios )
182         IF( lwxios ) CALL iom_swap(      cxios_context          )
183      ENDIF
184      !
185   END SUBROUTINE sbc_rnf
186
187
188   SUBROUTINE sbc_rnf_div( phdivn, Kmm )
189      !!----------------------------------------------------------------------
190      !!                  ***  ROUTINE sbc_rnf  ***
191      !!
192      !! ** Purpose :   update the horizontal divergence with the runoff inflow
193      !!
194      !! ** Method  :
195      !!                CAUTION : rnf is positive (inflow) decreasing the
196      !!                          divergence and expressed in m/s
197      !!
198      !! ** Action  :   phdivn   decreased by the runoff inflow
199      !!----------------------------------------------------------------------
200      INTEGER                   , INTENT(in   ) ::   Kmm      ! ocean time level index
201      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   phdivn   ! horizontal divergence
202      !!
203      INTEGER  ::   ji, jj, jk   ! dummy loop indices
204      REAL(wp) ::   zfact     ! local scalar
205      !!----------------------------------------------------------------------
206      !
207      zfact = 0.5_wp
208      !
209      IF( ln_rnf_depth .OR. ln_rnf_depth_ini ) THEN      !==   runoff distributed over several levels   ==!
210         IF( ln_linssh ) THEN    !* constant volume case : just apply the runoff input flow
211            DO_2D_11_11
212               DO jk = 1, nk_rnf(ji,jj)
213                  phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rho0 / h_rnf(ji,jj)
214               END DO
215            END_2D
216         ELSE                    !* variable volume case
217            DO_2D_11_11
218               h_rnf(ji,jj) = 0._wp
219               DO jk = 1, nk_rnf(ji,jj)                           ! recalculates h_rnf to be the depth in metres
220                  h_rnf(ji,jj) = h_rnf(ji,jj) + e3t(ji,jj,jk,Kmm)   ! to the bottom of the relevant grid box
221               END DO
222               !                          ! apply the runoff input flow
223               DO jk = 1, nk_rnf(ji,jj)
224                  phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rho0 / h_rnf(ji,jj)
225               END DO
226            END_2D
227         ENDIF
228      ELSE                       !==   runoff put only at the surface   ==!
229         h_rnf (:,:)   = e3t (:,:,1,Kmm)        ! update h_rnf to be depth of top box
230         phdivn(:,:,1) = phdivn(:,:,1) - ( rnf(:,:) + rnf_b(:,:) ) * zfact * r1_rho0 / e3t(:,:,1,Kmm)
231      ENDIF
232      !
233   END SUBROUTINE sbc_rnf_div
234
235
236   SUBROUTINE sbc_rnf_init( Kmm )
237      !!----------------------------------------------------------------------
238      !!                  ***  ROUTINE sbc_rnf_init  ***
239      !!
240      !! ** Purpose :   Initialisation of the runoffs if (ln_rnf=T)
241      !!
242      !! ** Method  : - read the runoff namsbc_rnf namelist
243      !!
244      !! ** Action  : - read parameters
245      !!----------------------------------------------------------------------
246      INTEGER, INTENT(in) :: Kmm           ! ocean time level index
247      CHARACTER(len=32) ::   rn_dep_file   ! runoff file name
248      INTEGER           ::   ji, jj, jk, jm    ! dummy loop indices
249      INTEGER           ::   ierror, inum  ! temporary integer
250      INTEGER           ::   ios           ! Local integer output status for namelist read
251      INTEGER           ::   nbrec         ! temporary integer
252      REAL(wp)          ::   zacoef 
253      REAL(wp), DIMENSION(jpi,jpj,2) :: zrnfcl   
254      !!
255      NAMELIST/namsbc_rnf/ cn_dir            , ln_rnf_depth, ln_rnf_tem, ln_rnf_sal, ln_rnf_icb,   &
256         &                 sn_rnf, sn_cnf    , sn_i_rnf, sn_s_rnf    , sn_t_rnf  , sn_dep_rnf,   &
257         &                 ln_rnf_mouth      , rn_hrnf     , rn_avt_rnf, rn_rfact,     &
258         &                 ln_rnf_depth_ini  , rn_dep_max  , rn_rnf_max, nn_rnf_depth_file
259      !!----------------------------------------------------------------------
260      !
261      !                                         !==  allocate runoff arrays
262      IF( sbc_rnf_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_rnf_alloc : unable to allocate arrays' )
263      !
264      IF( .NOT. ln_rnf ) THEN                      ! no specific treatment in vicinity of river mouths
265         ln_rnf_mouth  = .FALSE.                   ! default definition needed for example by sbc_ssr or by tra_adv_muscl
266         nkrnf         = 0
267         rnf     (:,:) = 0.0_wp
268         rnf_b   (:,:) = 0.0_wp
269         rnfmsk  (:,:) = 0.0_wp
270         rnfmsk_z(:)   = 0.0_wp
271         RETURN
272      ENDIF
273      !
274      !                                   ! ============
275      !                                   !   Namelist
276      !                                   ! ============
277      !
278      READ  ( numnam_ref, namsbc_rnf, IOSTAT = ios, ERR = 901)
279901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namsbc_rnf in reference namelist' )
280
281      READ  ( numnam_cfg, namsbc_rnf, IOSTAT = ios, ERR = 902 )
282902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namsbc_rnf in configuration namelist' )
283      IF(lwm) WRITE ( numond, namsbc_rnf )
284      !
285      !                                         ! Control print
286      IF(lwp) THEN
287         WRITE(numout,*)
288         WRITE(numout,*) 'sbc_rnf_init : runoff '
289         WRITE(numout,*) '~~~~~~~~~~~~ '
290         WRITE(numout,*) '   Namelist namsbc_rnf'
291         WRITE(numout,*) '      specific river mouths treatment            ln_rnf_mouth = ', ln_rnf_mouth
292         WRITE(numout,*) '      river mouth additional Kz                  rn_avt_rnf   = ', rn_avt_rnf
293         WRITE(numout,*) '      depth of river mouth additional mixing     rn_hrnf      = ', rn_hrnf
294         WRITE(numout,*) '      multiplicative factor for runoff           rn_rfact     = ', rn_rfact
295      ENDIF
296      !                                   ! ==================
297      !                                   !   Type of runoff
298      !                                   ! ==================
299      !
300      IF( .NOT. l_rnfcpl ) THEN                   
301         ALLOCATE( sf_rnf(1), STAT=ierror )         ! Create sf_rnf structure (runoff inflow)
302         IF(lwp) WRITE(numout,*)
303         IF(lwp) WRITE(numout,*) '   ==>>>   runoffs inflow read in a file'
304         IF( ierror > 0 ) THEN
305            CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_rnf structure' )   ;   RETURN
306         ENDIF
307         ALLOCATE( sf_rnf(1)%fnow(jpi,jpj,1)   )
308         IF( sn_rnf%ln_tint ) ALLOCATE( sf_rnf(1)%fdta(jpi,jpj,1,2) )
309         CALL fld_fill( sf_rnf, (/ sn_rnf /), cn_dir, 'sbc_rnf_init', 'read runoffs data', 'namsbc_rnf', no_print )
310         !
311         IF( ln_rnf_icb ) THEN                      ! Create (if required) sf_i_rnf structure
312            IF(lwp) WRITE(numout,*)
313            IF(lwp) WRITE(numout,*) '          iceberg flux read in a file'
314            ALLOCATE( sf_i_rnf(1), STAT=ierror  )
315            IF( ierror > 0 ) THEN
316               CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_i_rnf structure' )   ;   RETURN
317            ENDIF
318            ALLOCATE( sf_i_rnf(1)%fnow(jpi,jpj,1)   )
319            IF( sn_i_rnf%ln_tint ) ALLOCATE( sf_i_rnf(1)%fdta(jpi,jpj,1,2) )
320            CALL fld_fill (sf_i_rnf, (/ sn_i_rnf /), cn_dir, 'sbc_rnf_init', 'read iceberg flux data', 'namsbc_rnf' )
321         ELSE
322            fwficb(:,:) = 0._wp
323         ENDIF
324
325      ENDIF
326      !
327      IF( ln_rnf_tem ) THEN                      ! Create (if required) sf_t_rnf structure
328         IF(lwp) WRITE(numout,*)
329         IF(lwp) WRITE(numout,*) '   ==>>>   runoffs temperatures read in a file'
330         ALLOCATE( sf_t_rnf(1), STAT=ierror  )
331         IF( ierror > 0 ) THEN
332            CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_t_rnf structure' )   ;   RETURN
333         ENDIF
334         ALLOCATE( sf_t_rnf(1)%fnow(jpi,jpj,1)   )
335         IF( sn_t_rnf%ln_tint ) ALLOCATE( sf_t_rnf(1)%fdta(jpi,jpj,1,2) )
336         CALL fld_fill (sf_t_rnf, (/ sn_t_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff temperature data', 'namsbc_rnf', no_print )
337      ENDIF
338      !
339      IF( ln_rnf_sal  ) THEN                     ! Create (if required) sf_s_rnf and sf_t_rnf structures
340         IF(lwp) WRITE(numout,*)
341         IF(lwp) WRITE(numout,*) '   ==>>>   runoffs salinities read in a file'
342         ALLOCATE( sf_s_rnf(1), STAT=ierror  )
343         IF( ierror > 0 ) THEN
344            CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_s_rnf structure' )   ;   RETURN
345         ENDIF
346         ALLOCATE( sf_s_rnf(1)%fnow(jpi,jpj,1)   )
347         IF( sn_s_rnf%ln_tint ) ALLOCATE( sf_s_rnf(1)%fdta(jpi,jpj,1,2) )
348         CALL fld_fill (sf_s_rnf, (/ sn_s_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff salinity data', 'namsbc_rnf', no_print )
349      ENDIF
350      !
351      IF( ln_rnf_depth ) THEN                    ! depth of runoffs set from a file
352         IF(lwp) WRITE(numout,*)
353         IF(lwp) WRITE(numout,*) '   ==>>>   runoffs depth read in a file'
354         rn_dep_file = TRIM( cn_dir )//TRIM( sn_dep_rnf%clname )
355         IF( .NOT. sn_dep_rnf%ln_clim ) THEN   ;   WRITE(rn_dep_file, '(a,"_y",i4)' ) TRIM( rn_dep_file ), nyear    ! add year
356            IF( sn_dep_rnf%cltype == 'monthly' )   WRITE(rn_dep_file, '(a,"m",i2)'  ) TRIM( rn_dep_file ), nmonth   ! add month
357         ENDIF
358         CALL iom_open ( rn_dep_file, inum )                           ! open file
359         CALL iom_get  ( inum, jpdom_data, sn_dep_rnf%clvar, h_rnf )   ! read the river mouth array
360         CALL iom_close( inum )                                        ! close file
361         !
362         nk_rnf(:,:) = 0                               ! set the number of level over which river runoffs are applied
363         DO_2D_11_11
364            IF( h_rnf(ji,jj) > 0._wp ) THEN
365               jk = 2
366               DO WHILE ( jk < mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ;  jk = jk + 1
367               END DO
368               nk_rnf(ji,jj) = jk
369            ELSEIF( h_rnf(ji,jj) == -1._wp   ) THEN   ;  nk_rnf(ji,jj) = 1
370            ELSEIF( h_rnf(ji,jj) == -999._wp ) THEN   ;  nk_rnf(ji,jj) = mbkt(ji,jj)
371            ELSE
372               CALL ctl_stop( 'sbc_rnf_init: runoff depth not positive, and not -999 or -1, rnf value in file fort.999'  )
373               WRITE(999,*) 'ji, jj, h_rnf(ji,jj) :', ji, jj, h_rnf(ji,jj)
374            ENDIF
375         END_2D
376         DO_2D_11_11
377            h_rnf(ji,jj) = 0._wp
378            DO jk = 1, nk_rnf(ji,jj)
379               h_rnf(ji,jj) = h_rnf(ji,jj) + e3t(ji,jj,jk,Kmm)
380            END DO
381         END_2D
382         !
383      ELSE IF( ln_rnf_depth_ini ) THEN           ! runoffs applied at the surface
384         !
385         IF(lwp) WRITE(numout,*)
386         IF(lwp) WRITE(numout,*) '   ==>>>   depth of runoff computed once from max value of runoff'
387         IF(lwp) WRITE(numout,*) '        max value of the runoff climatologie (over global domain) rn_rnf_max = ', rn_rnf_max
388         IF(lwp) WRITE(numout,*) '        depth over which runoffs is spread                        rn_dep_max = ', rn_dep_max
389         IF(lwp) WRITE(numout,*) '        create (=1) a runoff depth file or not (=0)      nn_rnf_depth_file  = ', nn_rnf_depth_file
390
391         CALL iom_open( TRIM( sn_rnf%clname ), inum )    !  open runoff file
392         nbrec = iom_getszuld( inum )
393         zrnfcl(:,:,1) = 0._wp                                                          ! init the max to 0. in 1
394         DO jm = 1, nbrec
395            CALL iom_get( inum, jpdom_data, TRIM( sn_rnf%clvar ), zrnfcl(:,:,2), jm )   ! read the value in 2
396            zrnfcl(:,:,1) = MAXVAL( zrnfcl(:,:,:), DIM=3 )                              ! store the maximum value in time in 1
397         END DO
398         CALL iom_close( inum )
399         !
400         h_rnf(:,:) = 1.
401         !
402         zacoef = rn_dep_max / rn_rnf_max            ! coef of linear relation between runoff and its depth (150m for max of runoff)
403         !
404         WHERE( zrnfcl(:,:,1) > 0._wp )  h_rnf(:,:) = zacoef * zrnfcl(:,:,1)   ! compute depth for all runoffs
405         !
406         DO_2D_11_11
407            IF( zrnfcl(ji,jj,1) > 0._wp ) THEN
408               jk = mbkt(ji,jj)
409               h_rnf(ji,jj) = MIN( h_rnf(ji,jj), gdept_0(ji,jj,jk ) )
410            ENDIF
411         END_2D
412         !
413         nk_rnf(:,:) = 0                       ! number of levels on which runoffs are distributed
414         DO_2D_11_11
415            IF( zrnfcl(ji,jj,1) > 0._wp ) THEN
416               jk = 2
417               DO WHILE ( jk < mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ;  jk = jk + 1
418               END DO
419               nk_rnf(ji,jj) = jk
420            ELSE
421               nk_rnf(ji,jj) = 1
422            ENDIF
423         END_2D
424         !
425         DO_2D_11_11
426            h_rnf(ji,jj) = 0._wp
427            DO jk = 1, nk_rnf(ji,jj)
428               h_rnf(ji,jj) = h_rnf(ji,jj) + e3t(ji,jj,jk,Kmm)
429            END DO
430         END_2D
431         !
432         IF( nn_rnf_depth_file == 1 ) THEN      !  save  output nb levels for runoff
433            IF(lwp) WRITE(numout,*) '   ==>>>   create runoff depht file'
434            CALL iom_open  ( TRIM( sn_dep_rnf%clname ), inum, ldwrt = .TRUE. )
435            CALL iom_rstput( 0, 0, inum, 'rodepth', h_rnf )
436            CALL iom_close ( inum )
437         ENDIF
438      ELSE                                       ! runoffs applied at the surface
439         nk_rnf(:,:) = 1
440         h_rnf (:,:) = e3t(:,:,1,Kmm)
441      ENDIF
442      !
443      rnf(:,:) =  0._wp                         ! runoff initialisation
444      rnf_tsc(:,:,:) = 0._wp                    ! runoffs temperature & salinty contents initilisation
445      !
446      !                                   ! ========================
447      !                                   !   River mouth vicinity
448      !                                   ! ========================
449      !
450      IF( ln_rnf_mouth ) THEN                   ! Specific treatment in vicinity of river mouths :
451         !                                      !    - Increase Kz in surface layers ( rn_hrnf > 0 )
452         !                                      !    - set to zero SSS damping (ln_ssr=T)
453         !                                      !    - mixed upstream-centered (ln_traadv_cen2=T)
454         !
455         IF( ln_rnf_depth )   CALL ctl_warn( 'sbc_rnf_init: increased mixing turned on but effects may already',   &
456            &                                              'be spread through depth by ln_rnf_depth'               )
457         !
458         nkrnf = 0                                  ! Number of level over which Kz increase
459         IF( rn_hrnf > 0._wp ) THEN
460            nkrnf = 2
461            DO WHILE( nkrnf /= jpkm1 .AND. gdepw_1d(nkrnf+1) < rn_hrnf )   ;   nkrnf = nkrnf + 1
462            END DO
463            IF( ln_sco )   CALL ctl_warn( 'sbc_rnf_init: number of levels over which Kz is increased is computed for zco...' )
464         ENDIF
465         IF(lwp) WRITE(numout,*)
466         IF(lwp) WRITE(numout,*) '   ==>>>   Specific treatment used in vicinity of river mouths :'
467         IF(lwp) WRITE(numout,*) '             - Increase Kz in surface layers (if rn_hrnf > 0 )'
468         IF(lwp) WRITE(numout,*) '               by ', rn_avt_rnf,' m2/s  over ', nkrnf, ' w-levels'
469         IF(lwp) WRITE(numout,*) '             - set to zero SSS damping       (if ln_ssr=T)'
470         IF(lwp) WRITE(numout,*) '             - mixed upstream-centered       (if ln_traadv_cen2=T)'
471         !
472         CALL rnf_mouth                             ! set river mouth mask
473         !
474      ELSE                                      ! No treatment at river mouths
475         IF(lwp) WRITE(numout,*)
476         IF(lwp) WRITE(numout,*) '   ==>>>   No specific treatment at river mouths'
477         rnfmsk  (:,:) = 0._wp
478         rnfmsk_z(:)   = 0._wp
479         nkrnf = 0
480      ENDIF
481      !
482      IF( lwxios ) THEN
483         CALL iom_set_rstw_var_active('rnf_b')
484         CALL iom_set_rstw_var_active('rnf_hc_b')
485         CALL iom_set_rstw_var_active('rnf_sc_b')
486      ENDIF
487
488   END SUBROUTINE sbc_rnf_init
489
490
491   SUBROUTINE rnf_mouth
492      !!----------------------------------------------------------------------
493      !!                  ***  ROUTINE rnf_mouth  ***
494      !!
495      !! ** Purpose :   define the river mouths mask
496      !!
497      !! ** Method  :   read the river mouth mask (=0/1) in the river runoff
498      !!                climatological file. Defined a given vertical structure.
499      !!                CAUTION, the vertical structure is hard coded on the
500      !!                first 5 levels.
501      !!                This fields can be used to:
502      !!                 - set an upstream advection scheme
503      !!                   (ln_rnf_mouth=T and ln_traadv_cen2=T)
504      !!                 - increase vertical on the top nn_krnf vertical levels
505      !!                   at river runoff input grid point (nn_krnf>=2, see step.F90)
506      !!                 - set to zero SSS restoring flux at river mouth grid points
507      !!
508      !! ** Action  :   rnfmsk   set to 1 at river runoff input, 0 elsewhere
509      !!                rnfmsk_z vertical structure
510      !!----------------------------------------------------------------------
511      INTEGER            ::   inum        ! temporary integers
512      CHARACTER(len=140) ::   cl_rnfile   ! runoff file name
513      !!----------------------------------------------------------------------
514      !
515      IF(lwp) WRITE(numout,*)
516      IF(lwp) WRITE(numout,*) '   rnf_mouth : river mouth mask'
517      IF(lwp) WRITE(numout,*) '   ~~~~~~~~~ '
518      !
519      cl_rnfile = TRIM( cn_dir )//TRIM( sn_cnf%clname )
520      IF( .NOT. sn_cnf%ln_clim ) THEN   ;   WRITE(cl_rnfile, '(a,"_y",i4)' ) TRIM( cl_rnfile ), nyear    ! add year
521         IF( sn_cnf%cltype == 'monthly' )   WRITE(cl_rnfile, '(a,"m",i2)'  ) TRIM( cl_rnfile ), nmonth   ! add month
522      ENDIF
523      !
524      ! horizontal mask (read in NetCDF file)
525      CALL iom_open ( cl_rnfile, inum )                           ! open file
526      CALL iom_get  ( inum, jpdom_data, sn_cnf%clvar, rnfmsk )    ! read the river mouth array
527      CALL iom_close( inum )                                      ! close file
528      !
529      IF( l_clo_rnf )   CALL clo_rnf( rnfmsk )   ! closed sea inflow set as river mouth
530      !
531      rnfmsk_z(:)   = 0._wp                                       ! vertical structure
532      rnfmsk_z(1)   = 1.0
533      rnfmsk_z(2)   = 1.0                                         ! **********
534      rnfmsk_z(3)   = 0.5                                         ! HARD CODED on the 5 first levels
535      rnfmsk_z(4)   = 0.25                                        ! **********
536      rnfmsk_z(5)   = 0.125
537      !
538   END SUBROUTINE rnf_mouth
539
540   !!======================================================================
541END MODULE sbcrnf
Note: See TracBrowser for help on using the repository browser.