source: NEMO/trunk/src/OCE/SBC/sbcssm.F90 @ 13237

Last change on this file since 13237 was 13237, checked in by smasson, 3 months ago

trunk: Mid-year merge, merge back KERNEL-06_techene_e3

  • Property svn:keywords set to Id
File size: 14.3 KB
Line 
1MODULE sbcssm
2   !!======================================================================
3   !!                       ***  MODULE  sbcssm  ***
4   !! Surface module :  provide time-mean ocean surface variables
5   !!======================================================================
6   !! History :  9.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.3  ! 2010-10  (C. Bricaud, G. Madec)  add the Patm forcing for sea-ice
8   !!            3.7  ! 2015-11  (G. Madec)  non linear free surface by default: e3t_m always computed
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   sbc_ssm       : calculate sea surface mean currents, temperature, 
13   !!                   and salinity over nn_fsbc time-step
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and tracers
16   USE dom_oce        ! ocean space and time domain
17   USE sbc_oce        ! surface boundary condition: ocean fields
18   USE sbcapr         ! surface boundary condition: atmospheric pressure
19   USE eosbn2         ! equation of state and related derivatives
20   USE traqsr, ONLY: ln_traqsr
21   !
22   USE in_out_manager ! I/O manager
23   USE prtctl         ! Print control
24   USE iom            ! IOM library
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   sbc_ssm        ! routine called by step.F90
30   PUBLIC   sbc_ssm_init   ! routine called by sbcmod.F90
31
32   LOGICAL, SAVE ::   l_ssm_mean = .FALSE.   ! keep track of whether means have been read from restart file
33   
34#  include "domzgr_substitute.h90"
35   !!----------------------------------------------------------------------
36   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
37   !! $Id$
38   !! Software governed by the CeCILL license (see ./LICENSE)
39   !!----------------------------------------------------------------------
40CONTAINS
41
42   SUBROUTINE sbc_ssm( kt, Kbb, Kmm )
43      !!---------------------------------------------------------------------
44      !!                     ***  ROUTINE sbc_oce  ***
45      !!                     
46      !! ** Purpose :   provide ocean surface variable to sea-surface boundary
47      !!                condition computation
48      !!               
49      !! ** Method  :   compute mean surface velocity (2 components at U and
50      !!      V-points) [m/s], temperature [Celsius] and salinity [psu] over
51      !!      the periode (kt - nn_fsbc) to kt
52      !!         Note that the inverse barometer ssh (i.e. ssh associated with Patm)
53      !!      is add to ssh_m when ln_apr_dyn = T. Required for sea-ice dynamics.
54      !!---------------------------------------------------------------------
55      INTEGER, INTENT(in) ::   kt   ! ocean time step
56      INTEGER, INTENT(in) ::   Kbb, Kmm   ! ocean time level indices
57      !
58      INTEGER  ::   ji, jj               ! loop index
59      REAL(wp) ::   zcoef, zf_sbc       ! local scalar
60      REAL(wp), DIMENSION(jpi,jpj,jpts) :: zts
61      !!---------------------------------------------------------------------
62      !
63      !                                        !* surface T-, U-, V- ocean level variables (T, S, depth, velocity)
64      zts(:,:,jp_tem) = ts(:,:,1,jp_tem,Kmm)
65      zts(:,:,jp_sal) = ts(:,:,1,jp_sal,Kmm)
66      !
67      IF( nn_fsbc == 1 ) THEN                             !   Instantaneous surface fields        !
68         !                                                ! ---------------------------------------- !
69         ssu_m(:,:) = uu(:,:,1,Kbb)
70         ssv_m(:,:) = vv(:,:,1,Kbb)
71         IF( l_useCT )  THEN    ;   sst_m(:,:) = eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
72         ELSE                   ;   sst_m(:,:) = zts(:,:,jp_tem)
73         ENDIF
74         sss_m(:,:) = zts(:,:,jp_sal)
75         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
76         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = ssh(:,:,Kmm) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
77         ELSE                    ;   ssh_m(:,:) = ssh(:,:,Kmm)
78         ENDIF
79         !
80         e3t_m(:,:) = e3t(:,:,1,Kmm)
81         !
82         frq_m(:,:) = fraqsr_1lev(:,:)
83         !
84      ELSE
85         !                                                ! ----------------------------------------------- !
86         IF( kt == nit000 .AND. .NOT. l_ssm_mean ) THEN   !   Initialisation: 1st time-step, no input means !
87            !                                             ! ----------------------------------------------- !
88            IF(lwp) WRITE(numout,*)
89            IF(lwp) WRITE(numout,*) 'sbc_ssm : mean fields initialised to instantaneous values'
90            IF(lwp) WRITE(numout,*) '~~~~~~~   '
91            zcoef = REAL( nn_fsbc - 1, wp )
92            ssu_m(:,:) = zcoef * uu(:,:,1,Kbb)
93            ssv_m(:,:) = zcoef * vv(:,:,1,Kbb)
94            IF( l_useCT )  THEN    ;   sst_m(:,:) = zcoef * eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
95            ELSE                    ;   sst_m(:,:) = zcoef * zts(:,:,jp_tem)
96            ENDIF
97            sss_m(:,:) = zcoef * zts(:,:,jp_sal)
98            !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
99            IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = zcoef * ( ssh(:,:,Kmm) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) ) )
100            ELSE                    ;   ssh_m(:,:) = zcoef *   ssh(:,:,Kmm)
101            ENDIF
102            !
103            e3t_m(:,:) = zcoef * e3t(:,:,1,Kmm)
104            !
105            frq_m(:,:) = zcoef * fraqsr_1lev(:,:)
106            !                                             ! ---------------------------------------- !
107         ELSEIF( MOD( kt - 2 , nn_fsbc ) == 0 ) THEN      !   Initialisation: New mean computation   !
108            !                                             ! ---------------------------------------- !
109            ssu_m(:,:) = 0._wp     ! reset to zero ocean mean sbc fields
110            ssv_m(:,:) = 0._wp
111            sst_m(:,:) = 0._wp
112            sss_m(:,:) = 0._wp
113            ssh_m(:,:) = 0._wp
114            e3t_m(:,:) = 0._wp
115            frq_m(:,:) = 0._wp
116         ENDIF
117         !                                                ! ---------------------------------------- !
118         !                                                !        Cumulate at each time step        !
119         !                                                ! ---------------------------------------- !
120         ssu_m(:,:) = ssu_m(:,:) + uu(:,:,1,Kbb)
121         ssv_m(:,:) = ssv_m(:,:) + vv(:,:,1,Kbb)
122         IF( l_useCT )  THEN     ;   sst_m(:,:) = sst_m(:,:) + eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
123         ELSE                    ;   sst_m(:,:) = sst_m(:,:) + zts(:,:,jp_tem)
124         ENDIF
125         sss_m(:,:) = sss_m(:,:) + zts(:,:,jp_sal)
126         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
127         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = ssh_m(:,:) + ssh(:,:,Kmm) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
128         ELSE                    ;   ssh_m(:,:) = ssh_m(:,:) + ssh(:,:,Kmm)
129         ENDIF
130         !
131         e3t_m(:,:) = e3t_m(:,:) + e3t(:,:,1,Kmm)
132         !
133         frq_m(:,:) = frq_m(:,:) + fraqsr_1lev(:,:)
134
135         !                                                ! ---------------------------------------- !
136         IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
137            !                                             ! ---------------------------------------- !
138            zcoef = 1. / REAL( nn_fsbc, wp )
139            sst_m(:,:) = sst_m(:,:) * zcoef     ! mean SST             [Celsius]
140            sss_m(:,:) = sss_m(:,:) * zcoef     ! mean SSS             [psu]
141            ssu_m(:,:) = ssu_m(:,:) * zcoef     ! mean suface current  [m/s]
142            ssv_m(:,:) = ssv_m(:,:) * zcoef     !
143            ssh_m(:,:) = ssh_m(:,:) * zcoef     ! mean SSH             [m]
144            e3t_m(:,:) = e3t_m(:,:) * zcoef     ! mean vertical scale factor [m]
145            frq_m(:,:) = frq_m(:,:) * zcoef     ! mean fraction of solar net radiation absorbed in the 1st T level [-]
146            !
147         ENDIF
148         !                                                ! ---------------------------------------- !
149         IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
150            !                                             ! ---------------------------------------- !
151            IF(lwp) WRITE(numout,*)
152            IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields written in ocean restart file ',   &
153               &                    'at it= ', kt,' date= ', ndastp
154            IF(lwp) WRITE(numout,*) '~~~~~~~'
155            zf_sbc = REAL( nn_fsbc, wp )
156            IF( lwxios ) CALL iom_swap(      cwxios_context          )
157            CALL iom_rstput( kt, nitrst, numrow, 'nn_fsbc', zf_sbc, ldxios = lwxios )    ! sbc frequency
158            CALL iom_rstput( kt, nitrst, numrow, 'ssu_m'  , ssu_m, ldxios = lwxios  )    ! sea surface mean fields
159            CALL iom_rstput( kt, nitrst, numrow, 'ssv_m'  , ssv_m, ldxios = lwxios  )
160            CALL iom_rstput( kt, nitrst, numrow, 'sst_m'  , sst_m, ldxios = lwxios  )
161            CALL iom_rstput( kt, nitrst, numrow, 'sss_m'  , sss_m, ldxios = lwxios  )
162            CALL iom_rstput( kt, nitrst, numrow, 'ssh_m'  , ssh_m, ldxios = lwxios  )
163            CALL iom_rstput( kt, nitrst, numrow, 'e3t_m'  , e3t_m, ldxios = lwxios  )
164            CALL iom_rstput( kt, nitrst, numrow, 'frq_m'  , frq_m, ldxios = lwxios  )
165            !
166            IF( lwxios ) CALL iom_swap(      cxios_context          )
167         ENDIF
168         !
169      ENDIF
170      !
171      IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
172         CALL iom_put( 'ssu_m', ssu_m )
173         CALL iom_put( 'ssv_m', ssv_m )
174         CALL iom_put( 'sst_m', sst_m )
175         CALL iom_put( 'sss_m', sss_m )
176         CALL iom_put( 'ssh_m', ssh_m )
177         CALL iom_put( 'e3t_m', e3t_m )
178         CALL iom_put( 'frq_m', frq_m )
179      ENDIF
180      !
181   END SUBROUTINE sbc_ssm
182
183
184   SUBROUTINE sbc_ssm_init( Kbb, Kmm )
185      !!----------------------------------------------------------------------
186      !!                  ***  ROUTINE sbc_ssm_init  ***
187      !!
188      !! ** Purpose :   Initialisation of the sbc data
189      !!
190      !! ** Action  : - read parameters
191      !!----------------------------------------------------------------------
192      INTEGER, INTENT(in) ::   Kbb, Kmm   ! ocean time level indices
193      REAL(wp) ::   zcoef, zf_sbc   ! local scalar
194      !!----------------------------------------------------------------------
195      !
196      IF( nn_fsbc == 1 ) THEN
197         !
198         IF(lwp) WRITE(numout,*)
199         IF(lwp) WRITE(numout,*) 'sbc_ssm_init : sea surface mean fields, nn_fsbc=1 : instantaneous values'
200         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ '
201         !
202      ELSE
203         !               
204         IF(lwp) WRITE(numout,*)
205         IF(lwp) WRITE(numout,*) 'sbc_ssm_init : sea surface mean fields'
206         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~ '
207         !
208         IF( ln_rstart .AND. iom_varid( numror, 'nn_fsbc', ldstop = .FALSE. ) > 0 ) THEN
209            l_ssm_mean = .TRUE.
210            CALL iom_get( numror               , 'nn_fsbc', zf_sbc, ldxios = lrxios )    ! sbc frequency of previous run
211            CALL iom_get( numror, jpdom_autoglo, 'ssu_m'  , ssu_m, ldxios = lrxios  )    ! sea surface mean velocity    (U-point)
212            CALL iom_get( numror, jpdom_autoglo, 'ssv_m'  , ssv_m, ldxios = lrxios  )    !   "         "    velocity    (V-point)
213            CALL iom_get( numror, jpdom_autoglo, 'sst_m'  , sst_m, ldxios = lrxios  )    !   "         "    temperature (T-point)
214            CALL iom_get( numror, jpdom_autoglo, 'sss_m'  , sss_m, ldxios = lrxios  )    !   "         "    salinity    (T-point)
215            CALL iom_get( numror, jpdom_autoglo, 'ssh_m'  , ssh_m, ldxios = lrxios  )    !   "         "    height      (T-point)
216            CALL iom_get( numror, jpdom_autoglo, 'e3t_m'  , e3t_m, ldxios = lrxios  )    ! 1st level thickness          (T-point)
217            ! fraction of solar net radiation absorbed in 1st T level
218            IF( iom_varid( numror, 'frq_m', ldstop = .FALSE. ) > 0 ) THEN
219               CALL iom_get( numror, jpdom_autoglo, 'frq_m'  , frq_m, ldxios = lrxios  )
220            ELSE
221               frq_m(:,:) = 1._wp   ! default definition
222            ENDIF
223            !
224            IF( zf_sbc /= REAL( nn_fsbc, wp ) ) THEN      ! nn_fsbc has changed between 2 runs
225               IF(lwp) WRITE(numout,*) '   restart with a change in the frequency of mean from ', zf_sbc, ' to ', nn_fsbc 
226               zcoef = REAL( nn_fsbc - 1, wp ) / zf_sbc 
227               ssu_m(:,:) = zcoef * ssu_m(:,:) 
228               ssv_m(:,:) = zcoef * ssv_m(:,:)
229               sst_m(:,:) = zcoef * sst_m(:,:)
230               sss_m(:,:) = zcoef * sss_m(:,:)
231               ssh_m(:,:) = zcoef * ssh_m(:,:)
232               e3t_m(:,:) = zcoef * e3t_m(:,:)
233               frq_m(:,:) = zcoef * frq_m(:,:)
234            ELSE
235               IF(lwp) WRITE(numout,*) '   mean fields read in the ocean restart file'
236            ENDIF
237         ENDIF
238      ENDIF
239      !
240      IF( .NOT.l_ssm_mean ) THEN   ! default initialisation. needed by iceistate
241         !
242         IF(lwp) WRITE(numout,*) '   default initialisation of ss._m arrays'
243         ssu_m(:,:) = uu(:,:,1,Kbb)
244         ssv_m(:,:) = vv(:,:,1,Kbb)
245         IF( l_useCT )  THEN    ;   sst_m(:,:) = eos_pt_from_ct( ts(:,:,1,jp_tem,Kmm), ts(:,:,1,jp_sal,Kmm) )
246         ELSE                   ;   sst_m(:,:) = ts(:,:,1,jp_tem,Kmm)
247         ENDIF
248         sss_m(:,:) = ts  (:,:,1,jp_sal,Kmm)
249         ssh_m(:,:) = ssh(:,:,Kmm)
250         e3t_m(:,:) = e3t (:,:,1,Kmm)
251         frq_m(:,:) = 1._wp
252         !
253      ENDIF
254      !
255      IF( .NOT. ln_traqsr )   fraqsr_1lev(:,:) = 1._wp   ! default definition: qsr 100% in the fisrt level
256      !
257      IF( lwxios.AND.nn_fsbc > 1 ) THEN
258         CALL iom_set_rstw_var_active('nn_fsbc')
259         CALL iom_set_rstw_var_active('ssu_m')
260         CALL iom_set_rstw_var_active('ssv_m')
261         CALL iom_set_rstw_var_active('sst_m')
262         CALL iom_set_rstw_var_active('sss_m')
263         CALL iom_set_rstw_var_active('ssh_m')
264         CALL iom_set_rstw_var_active('e3t_m')
265         CALL iom_set_rstw_var_active('frq_m')
266      ENDIF
267
268   END SUBROUTINE sbc_ssm_init
269
270   !!======================================================================
271END MODULE sbcssm
Note: See TracBrowser for help on using the repository browser.