source: NEMO/trunk/src/OCE/TRA/traadv_fct.F90 @ 11407

Last change on this file since 11407 was 11407, checked in by acc, 18 months ago

Final documentation tweaks to the adaptive-implicit vertical advection section of chap_ZDF.tex and associated code changes. The code changes are mostly cosmetic or to align with the documentation but this does include a modified version of traadv_fct.F90 (thanks to Jerome) which correctly accounts for any implicit component of the vertical velocity when computing anti-diffusive fluxes for flux correction. The changes have null effect when ln_zad_Aimp is .false. and have been SETTE tested with ORCA2_ICE_PISCES with ln_zad_Aimp = .true.

  • Property svn:keywords set to Id
File size: 37.8 KB
Line 
1MODULE traadv_fct
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_fct  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend (2nd/4th order Flux Corrected Transport method)
5   !!==============================================================================
6   !! History :  3.7  !  2015-09  (L. Debreu, G. Madec)  original code (inspired from traadv_tvd.F90)
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!  tra_adv_fct    : update the tracer trend with a 3D advective trends using a 2nd or 4th order FCT scheme
11   !!                   with sub-time-stepping in the vertical direction
12   !!  nonosc         : compute monotonic tracer fluxes by a non-oscillatory algorithm
13   !!  interp_4th_cpt : 4th order compact scheme for the vertical component of the advection
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and active tracers
16   USE dom_oce        ! ocean space and time domain
17   USE trc_oce        ! share passive tracers/Ocean variables
18   USE trd_oce        ! trends: ocean variables
19   USE trdtra         ! tracers trends
20   USE diaptr         ! poleward transport diagnostics
21   USE diaar5         ! AR5 diagnostics
22   USE phycst  , ONLY : rau0_rcp
23   USE zdf_oce , ONLY : ln_zad_Aimp
24   !
25   USE in_out_manager ! I/O manager
26   USE iom            !
27   USE lib_mpp        ! MPP library
28   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
29   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   tra_adv_fct        ! called by traadv.F90
35   PUBLIC   interp_4th_cpt     ! called by traadv_cen.F90
36
37   LOGICAL  ::   l_trd   ! flag to compute trends
38   LOGICAL  ::   l_ptr   ! flag to compute poleward transport
39   LOGICAL  ::   l_hst   ! flag to compute heat/salt transport
40   REAL(wp) ::   r1_6 = 1._wp / 6._wp   ! =1/6
41
42   !                                        ! tridiag solver associated indices:
43   INTEGER, PARAMETER ::   np_NH   = 0   ! Neumann homogeneous boundary condition
44   INTEGER, PARAMETER ::   np_CEN2 = 1   ! 2nd order centered  boundary condition
45
46   !! * Substitutions
47#  include "vectopt_loop_substitute.h90"
48   !!----------------------------------------------------------------------
49   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
50   !! $Id$
51   !! Software governed by the CeCILL license (see ./LICENSE)
52   !!----------------------------------------------------------------------
53CONTAINS
54
55   SUBROUTINE tra_adv_fct( kt, kit000, cdtype, p2dt, pun, pvn, pwn,       &
56      &                                              ptb, ptn, pta, kjpt, kn_fct_h, kn_fct_v )
57      !!----------------------------------------------------------------------
58      !!                  ***  ROUTINE tra_adv_fct  ***
59      !!
60      !! **  Purpose :   Compute the now trend due to total advection of tracers
61      !!               and add it to the general trend of tracer equations
62      !!
63      !! **  Method  : - 2nd or 4th FCT scheme on the horizontal direction
64      !!               (choice through the value of kn_fct)
65      !!               - on the vertical the 4th order is a compact scheme
66      !!               - corrected flux (monotonic correction)
67      !!
68      !! ** Action : - update pta  with the now advective tracer trends
69      !!             - send trends to trdtra module for further diagnostics (l_trdtra=T)
70      !!             - htr_adv, str_adv : poleward advective heat and salt transport (ln_diaptr=T)
71      !!----------------------------------------------------------------------
72      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
73      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
74      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
75      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
76      INTEGER                              , INTENT(in   ) ::   kn_fct_h        ! order of the FCT scheme (=2 or 4)
77      INTEGER                              , INTENT(in   ) ::   kn_fct_v        ! order of the FCT scheme (=2 or 4)
78      REAL(wp)                             , INTENT(in   ) ::   p2dt            ! tracer time-step
79      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
80      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
81      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
82      !
83      INTEGER  ::   ji, jj, jk, jn                           ! dummy loop indices 
84      REAL(wp) ::   ztra                                     ! local scalar
85      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk, zC2t_u, zC4t_u   !   -      -
86      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk, zC2t_v, zC4t_v   !   -      -
87      REAL(wp), DIMENSION(jpi,jpj,jpk)        ::   zwi, zwx, zwy, zwz, ztu, ztv, zltu, zltv, ztw
88      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrdx, ztrdy, ztrdz, zptry
89      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   zwinf, zwdia, zwsup
90      LOGICAL  ::   ll_zAimp                                 ! flag to apply adaptive implicit vertical advection
91      !!----------------------------------------------------------------------
92      !
93      IF( kt == kit000 )  THEN
94         IF(lwp) WRITE(numout,*)
95         IF(lwp) WRITE(numout,*) 'tra_adv_fct : FCT advection scheme on ', cdtype
96         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
97      ENDIF
98      !
99      l_trd = .FALSE.            ! set local switches
100      l_hst = .FALSE.
101      l_ptr = .FALSE.
102      ll_zAimp = .FALSE.
103      IF( ( cdtype =='TRA' .AND. l_trdtra  ) .OR. ( cdtype =='TRC' .AND. l_trdtrc ) )       l_trd = .TRUE.
104      IF(   cdtype =='TRA' .AND. ln_diaptr )                                                l_ptr = .TRUE. 
105      IF(   cdtype =='TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR.  &
106         &                         iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) )  l_hst = .TRUE.
107      !
108      IF( l_trd .OR. l_hst )  THEN
109         ALLOCATE( ztrdx(jpi,jpj,jpk), ztrdy(jpi,jpj,jpk), ztrdz(jpi,jpj,jpk) )
110         ztrdx(:,:,:) = 0._wp   ;    ztrdy(:,:,:) = 0._wp   ;   ztrdz(:,:,:) = 0._wp
111      ENDIF
112      !
113      IF( l_ptr ) THEN 
114         ALLOCATE( zptry(jpi,jpj,jpk) )
115         zptry(:,:,:) = 0._wp
116      ENDIF
117      !                          ! surface & bottom value : flux set to zero one for all
118      zwz(:,:, 1 ) = 0._wp           
119      zwx(:,:,jpk) = 0._wp   ;   zwy(:,:,jpk) = 0._wp    ;    zwz(:,:,jpk) = 0._wp
120      !
121      zwi(:,:,:) = 0._wp       
122      !
123      ! If adaptive vertical advection, check if it is needed on this PE at this time
124      IF( ln_zad_Aimp ) THEN
125         IF( MAXVAL( ABS( wi(:,:,:) ) ) > 0._wp ) ll_zAimp = .TRUE.
126      END IF
127      ! If active adaptive vertical advection, build tridiagonal matrix
128      IF( ll_zAimp ) THEN
129         ALLOCATE(zwdia(jpi,jpj,jpk), zwinf(jpi,jpj,jpk),zwsup(jpi,jpj,jpk))
130         DO jk = 1, jpkm1
131            DO jj = 2, jpjm1
132               DO ji = fs_2, fs_jpim1   ! vector opt. (ensure same order of calculation as below if wi=0.)
133                  zwdia(ji,jj,jk) =  1._wp + p2dt * ( MAX( wi(ji,jj,jk  ) , 0._wp ) - MIN( wi(ji,jj,jk+1) , 0._wp ) ) / e3t_a(ji,jj,jk)
134                  zwinf(ji,jj,jk) =  p2dt * MIN( wi(ji,jj,jk  ) , 0._wp ) / e3t_a(ji,jj,jk)
135                  zwsup(ji,jj,jk) = -p2dt * MAX( wi(ji,jj,jk+1) , 0._wp ) / e3t_a(ji,jj,jk)
136               END DO
137            END DO
138         END DO
139      END IF
140      !
141      DO jn = 1, kjpt            !==  loop over the tracers  ==!
142         !
143         !        !==  upstream advection with initial mass fluxes & intermediate update  ==!
144         !                    !* upstream tracer flux in the i and j direction
145         DO jk = 1, jpkm1
146            DO jj = 1, jpjm1
147               DO ji = 1, fs_jpim1   ! vector opt.
148                  ! upstream scheme
149                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
150                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
151                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
152                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
153                  zwx(ji,jj,jk) = 0.5 * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
154                  zwy(ji,jj,jk) = 0.5 * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
155               END DO
156            END DO
157         END DO
158         !                    !* upstream tracer flux in the k direction *!
159         DO jk = 2, jpkm1        ! Interior value ( multiplied by wmask)
160            DO jj = 1, jpj
161               DO ji = 1, jpi
162                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
163                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
164                  zwz(ji,jj,jk) = 0.5 * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) ) * wmask(ji,jj,jk)
165               END DO
166            END DO
167         END DO
168         IF( ln_linssh ) THEN    ! top ocean value (only in linear free surface as zwz has been w-masked)
169            IF( ln_isfcav ) THEN             ! top of the ice-shelf cavities and at the ocean surface
170               DO jj = 1, jpj
171                  DO ji = 1, jpi
172                     zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)   ! linear free surface
173                  END DO
174               END DO   
175            ELSE                             ! no cavities: only at the ocean surface
176               zwz(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)
177            ENDIF
178         ENDIF
179         !               
180         DO jk = 1, jpkm1     !* trend and after field with monotonic scheme
181            DO jj = 2, jpjm1
182               DO ji = fs_2, fs_jpim1   ! vector opt.
183                  !                             ! total intermediate advective trends
184                  ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
185                     &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
186                     &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
187                  !                             ! update and guess with monotonic sheme
188                  pta(ji,jj,jk,jn) =                     pta(ji,jj,jk,jn) +        ztra   / e3t_n(ji,jj,jk) * tmask(ji,jj,jk)
189                  zwi(ji,jj,jk)    = ( e3t_b(ji,jj,jk) * ptb(ji,jj,jk,jn) + p2dt * ztra ) / e3t_a(ji,jj,jk) * tmask(ji,jj,jk)
190               END DO
191            END DO
192         END DO
193         
194         IF ( ll_zAimp ) THEN
195            CALL tridia_solver( zwdia, zwsup, zwinf, zwi, zwi , 0 )
196            !
197            ztu(:,:,1) = 0._wp; ztu(:,:,jpk) = 0._wp
198            DO jk = 2, jpkm1        ! Interior value ( multiplied by wmask)
199               DO jj = 1, jpj
200                  DO ji = 1, jpi
201                     zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
202                     zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
203                     ztu(ji,jj,jk) =  0.5 * e1e2t(ji,jj) * ( zfp_wk * zwi(ji,jj,jk) + zfm_wk * zwi(ji,jj,jk-1) ) * wmask(ji,jj,jk)
204                  END DO
205               END DO
206            END DO
207            DO jk = 1, jpkm1
208               DO jj = 2, jpjm1
209                  DO ji = fs_2, fs_jpim1   ! vector opt. 
210                     pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) - ( ztu(ji,jj,jk) - ztu(ji  ,jj  ,jk+1) ) &
211                        &                                  * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
212                  END DO
213               END DO
214            END DO
215            zwz(:,:,:) = zwz(:,:,:) + ztu(:,:,:)
216            !
217         END IF
218         !               
219         IF( l_trd .OR. l_hst )  THEN             ! trend diagnostics (contribution of upstream fluxes)
220            ztrdx(:,:,:) = zwx(:,:,:)   ;   ztrdy(:,:,:) = zwy(:,:,:)   ;   ztrdz(:,:,:) = zwz(:,:,:)
221         END IF
222         !                             ! "Poleward" heat and salt transports (contribution of upstream fluxes)
223         IF( l_ptr )   zptry(:,:,:) = zwy(:,:,:) 
224         !
225         !        !==  anti-diffusive flux : high order minus low order  ==!
226         !
227         SELECT CASE( kn_fct_h )    !* horizontal anti-diffusive fluxes
228         !
229         CASE(  2  )                   !- 2nd order centered
230            DO jk = 1, jpkm1
231               DO jj = 1, jpjm1
232                  DO ji = 1, fs_jpim1   ! vector opt.
233                     zwx(ji,jj,jk) = 0.5_wp * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) ) - zwx(ji,jj,jk)
234                     zwy(ji,jj,jk) = 0.5_wp * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) ) - zwy(ji,jj,jk)
235                  END DO
236               END DO
237            END DO
238            !
239         CASE(  4  )                   !- 4th order centered
240            zltu(:,:,jpk) = 0._wp            ! Bottom value : flux set to zero
241            zltv(:,:,jpk) = 0._wp
242            DO jk = 1, jpkm1                 ! Laplacian
243               DO jj = 1, jpjm1                    ! 1st derivative (gradient)
244                  DO ji = 1, fs_jpim1   ! vector opt.
245                     ztu(ji,jj,jk) = ( ptn(ji+1,jj  ,jk,jn) - ptn(ji,jj,jk,jn) ) * umask(ji,jj,jk)
246                     ztv(ji,jj,jk) = ( ptn(ji  ,jj+1,jk,jn) - ptn(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
247                  END DO
248               END DO
249               DO jj = 2, jpjm1                    ! 2nd derivative * 1/ 6
250                  DO ji = fs_2, fs_jpim1   ! vector opt.
251                     zltu(ji,jj,jk) = (  ztu(ji,jj,jk) + ztu(ji-1,jj,jk)  ) * r1_6
252                     zltv(ji,jj,jk) = (  ztv(ji,jj,jk) + ztv(ji,jj-1,jk)  ) * r1_6
253                  END DO
254               END DO
255            END DO
256            CALL lbc_lnk_multi( 'traadv_fct', zltu, 'T', 1. , zltv, 'T', 1. )   ! Lateral boundary cond. (unchanged sgn)
257            !
258            DO jk = 1, jpkm1                 ! Horizontal advective fluxes
259               DO jj = 1, jpjm1
260                  DO ji = 1, fs_jpim1   ! vector opt.
261                     zC2t_u = ptn(ji,jj,jk,jn) + ptn(ji+1,jj  ,jk,jn)   ! 2 x C2 interpolation of T at u- & v-points
262                     zC2t_v = ptn(ji,jj,jk,jn) + ptn(ji  ,jj+1,jk,jn)
263                     !                                                  ! C4 minus upstream advective fluxes
264                     zwx(ji,jj,jk) =  0.5_wp * pun(ji,jj,jk) * ( zC2t_u + zltu(ji,jj,jk) - zltu(ji+1,jj,jk) ) - zwx(ji,jj,jk)
265                     zwy(ji,jj,jk) =  0.5_wp * pvn(ji,jj,jk) * ( zC2t_v + zltv(ji,jj,jk) - zltv(ji,jj+1,jk) ) - zwy(ji,jj,jk)
266                  END DO
267               END DO
268            END DO         
269            !
270         CASE(  41 )                   !- 4th order centered       ==>>   !!gm coding attempt   need to be tested
271            ztu(:,:,jpk) = 0._wp             ! Bottom value : flux set to zero
272            ztv(:,:,jpk) = 0._wp
273            DO jk = 1, jpkm1                 ! 1st derivative (gradient)
274               DO jj = 1, jpjm1
275                  DO ji = 1, fs_jpim1   ! vector opt.
276                     ztu(ji,jj,jk) = ( ptn(ji+1,jj  ,jk,jn) - ptn(ji,jj,jk,jn) ) * umask(ji,jj,jk)
277                     ztv(ji,jj,jk) = ( ptn(ji  ,jj+1,jk,jn) - ptn(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
278                  END DO
279               END DO
280            END DO
281            CALL lbc_lnk_multi( 'traadv_fct', ztu, 'U', -1. , ztv, 'V', -1. )   ! Lateral boundary cond. (unchanged sgn)
282            !
283            DO jk = 1, jpkm1                 ! Horizontal advective fluxes
284               DO jj = 2, jpjm1
285                  DO ji = 2, fs_jpim1   ! vector opt.
286                     zC2t_u = ptn(ji,jj,jk,jn) + ptn(ji+1,jj  ,jk,jn)   ! 2 x C2 interpolation of T at u- & v-points (x2)
287                     zC2t_v = ptn(ji,jj,jk,jn) + ptn(ji  ,jj+1,jk,jn)
288                     !                                                  ! C4 interpolation of T at u- & v-points (x2)
289                     zC4t_u =  zC2t_u + r1_6 * ( ztu(ji-1,jj  ,jk) - ztu(ji+1,jj  ,jk) )
290                     zC4t_v =  zC2t_v + r1_6 * ( ztv(ji  ,jj-1,jk) - ztv(ji  ,jj+1,jk) )
291                     !                                                  ! C4 minus upstream advective fluxes
292                     zwx(ji,jj,jk) =  0.5_wp * pun(ji,jj,jk) * zC4t_u - zwx(ji,jj,jk)
293                     zwy(ji,jj,jk) =  0.5_wp * pvn(ji,jj,jk) * zC4t_v - zwy(ji,jj,jk)
294                  END DO
295               END DO
296            END DO
297            !
298         END SELECT
299         !                     
300         SELECT CASE( kn_fct_v )    !* vertical anti-diffusive fluxes (w-masked interior values)
301         !
302         CASE(  2  )                   !- 2nd order centered
303            DO jk = 2, jpkm1   
304               DO jj = 2, jpjm1
305                  DO ji = fs_2, fs_jpim1
306                     zwz(ji,jj,jk) =  (  pwn(ji,jj,jk) * 0.5_wp * ( ptn(ji,jj,jk,jn) + ptn(ji,jj,jk-1,jn) )   &
307                        &              - zwz(ji,jj,jk)  ) * wmask(ji,jj,jk)
308                  END DO
309               END DO
310            END DO
311            !
312         CASE(  4  )                   !- 4th order COMPACT
313            CALL interp_4th_cpt( ptn(:,:,:,jn) , ztw )   ! zwt = COMPACT interpolation of T at w-point
314            DO jk = 2, jpkm1
315               DO jj = 2, jpjm1
316                  DO ji = fs_2, fs_jpim1
317                     zwz(ji,jj,jk) = ( pwn(ji,jj,jk) * ztw(ji,jj,jk) - zwz(ji,jj,jk) ) * wmask(ji,jj,jk)
318                  END DO
319               END DO
320            END DO
321            !
322         END SELECT
323         IF( ln_linssh ) THEN    ! top ocean value: high order = upstream  ==>>  zwz=0
324            zwz(:,:,1) = 0._wp   ! only ocean surface as interior zwz values have been w-masked
325         ENDIF
326         !
327         CALL lbc_lnk_multi( 'traadv_fct', zwi, 'T', 1., zwx, 'U', -1. , zwy, 'V', -1.,  zwz, 'W',  1. )
328         !
329         !         
330         IF ( ll_zAimp ) THEN
331            DO jk = 1, jpkm1     !* trend and after field with monotonic scheme
332               DO jj = 2, jpjm1
333                  DO ji = fs_2, fs_jpim1   ! vector opt.
334                     !                             ! total intermediate advective trends
335                     ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
336                        &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
337                        &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
338                     ztu(ji,jj,jk)  = zwi(ji,jj,jk) + p2dt * ztra / e3t_a(ji,jj,jk) * tmask(ji,jj,jk)
339                  END DO
340               END DO
341            END DO
342            !
343            CALL tridia_solver( zwdia, zwsup, zwinf, ztu, ztu , 0 )
344            !
345            ztu(:,:,1) = 0._wp
346            DO jk = 2, jpkm1        ! Interior value ( multiplied by wmask)
347               DO jj = 2, jpjm1
348                  DO ji = fs_2, fs_jpim1   ! vector opt.
349                     zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
350                     zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
351                     zwz(ji,jj,jk) =  zwz(ji,jj,jk) + 0.5 * e1e2t(ji,jj) * ( zfp_wk * ztu(ji,jj,jk) + zfm_wk * ztu(ji,jj,jk-1) ) * wmask(ji,jj,jk)
352                  END DO
353               END DO
354            END DO
355         END IF
356         !        !==  monotonicity algorithm  ==!
357         !
358         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
359         !
360         !        !==  final trend with corrected fluxes  ==!
361         !
362         DO jk = 1, jpkm1
363            DO jj = 2, jpjm1
364               DO ji = fs_2, fs_jpim1   ! vector opt. 
365                  ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
366                     &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
367                     &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
368                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra / e3t_n(ji,jj,jk)
369                  zwi(ji,jj,jk) = zwi(ji,jj,jk) + p2dt * ztra / e3t_a(ji,jj,jk) * tmask(ji,jj,jk)
370               END DO
371            END DO
372         END DO
373         !
374         IF ( ll_zAimp ) THEN
375            !
376            DO jk = 2, jpkm1        ! Interior value ( multiplied by wmask)
377               DO jj = 2, jpjm1
378                  DO ji = fs_2, fs_jpim1   ! vector opt.
379                     zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
380                     zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
381                     zwz(ji,jj,jk) = - 0.5 * e1e2t(ji,jj) * ( zfp_wk * zwi(ji,jj,jk) + zfm_wk * zwi(ji,jj,jk-1) ) * wmask(ji,jj,jk)
382                  END DO
383               END DO
384            END DO
385            DO jk = 1, jpkm1
386               DO jj = 2, jpjm1
387                  DO ji = fs_2, fs_jpim1   ! vector opt. 
388                     pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) - ( zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) &
389                        &                                * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
390                  END DO
391               END DO
392            END DO
393         END IF         
394         !
395         IF( l_trd .OR. l_hst ) THEN   ! trend diagnostics // heat/salt transport
396            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< add anti-diffusive fluxes
397            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  !     to upstream fluxes
398            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  !
399            !
400            IF( l_trd ) THEN              ! trend diagnostics
401               CALL trd_tra( kt, cdtype, jn, jptra_xad, ztrdx, pun, ptn(:,:,:,jn) )
402               CALL trd_tra( kt, cdtype, jn, jptra_yad, ztrdy, pvn, ptn(:,:,:,jn) )
403               CALL trd_tra( kt, cdtype, jn, jptra_zad, ztrdz, pwn, ptn(:,:,:,jn) )
404            ENDIF
405            !                             ! heat/salt transport
406            IF( l_hst )   CALL dia_ar5_hst( jn, 'adv', ztrdx(:,:,:), ztrdy(:,:,:) )
407            !
408         ENDIF
409         IF( l_ptr ) THEN              ! "Poleward" transports
410            zptry(:,:,:) = zptry(:,:,:) + zwy(:,:,:)  ! <<< add anti-diffusive fluxes
411            CALL dia_ptr_hst( jn, 'adv', zptry(:,:,:) )
412         ENDIF
413         !
414      END DO                     ! end of tracer loop
415      !
416      IF ( ll_zAimp ) THEN
417         DEALLOCATE( zwdia, zwinf, zwsup )
418      ENDIF
419      IF( l_trd .OR. l_hst ) THEN
420         DEALLOCATE( ztrdx, ztrdy, ztrdz )
421      ENDIF
422      IF( l_ptr ) THEN
423         DEALLOCATE( zptry )
424      ENDIF
425      !
426   END SUBROUTINE tra_adv_fct
427
428
429   SUBROUTINE nonosc( pbef, paa, pbb, pcc, paft, p2dt )
430      !!---------------------------------------------------------------------
431      !!                    ***  ROUTINE nonosc  ***
432      !!     
433      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
434      !!       scheme and the before field by a nonoscillatory algorithm
435      !!
436      !! **  Method  :   ... ???
437      !!       warning : pbef and paft must be masked, but the boundaries
438      !!       conditions on the fluxes are not necessary zalezak (1979)
439      !!       drange (1995) multi-dimensional forward-in-time and upstream-
440      !!       in-space based differencing for fluid
441      !!----------------------------------------------------------------------
442      REAL(wp)                         , INTENT(in   ) ::   p2dt            ! tracer time-step
443      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(in   ) ::   pbef, paft      ! before & after field
444      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
445      !
446      INTEGER  ::   ji, jj, jk   ! dummy loop indices
447      INTEGER  ::   ikm1         ! local integer
448      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn    ! local scalars
449      REAL(wp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
450      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zbetup, zbetdo, zbup, zbdo
451      !!----------------------------------------------------------------------
452      !
453      zbig  = 1.e+40_wp
454      zrtrn = 1.e-15_wp
455      zbetup(:,:,:) = 0._wp   ;   zbetdo(:,:,:) = 0._wp
456
457      ! Search local extrema
458      ! --------------------
459      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
460      zbup = MAX( pbef * tmask - zbig * ( 1._wp - tmask ),   &
461         &        paft * tmask - zbig * ( 1._wp - tmask )  )
462      zbdo = MIN( pbef * tmask + zbig * ( 1._wp - tmask ),   &
463         &        paft * tmask + zbig * ( 1._wp - tmask )  )
464
465      DO jk = 1, jpkm1
466         ikm1 = MAX(jk-1,1)
467         DO jj = 2, jpjm1
468            DO ji = fs_2, fs_jpim1   ! vector opt.
469
470               ! search maximum in neighbourhood
471               zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
472                  &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
473                  &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
474                  &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
475
476               ! search minimum in neighbourhood
477               zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
478                  &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
479                  &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
480                  &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
481
482               ! positive part of the flux
483               zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
484                  & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
485                  & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
486
487               ! negative part of the flux
488               zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
489                  & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
490                  & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
491
492               ! up & down beta terms
493               zbt = e1e2t(ji,jj) * e3t_n(ji,jj,jk) / p2dt
494               zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
495               zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
496            END DO
497         END DO
498      END DO
499      CALL lbc_lnk_multi( 'traadv_fct', zbetup, 'T', 1. , zbetdo, 'T', 1. )   ! lateral boundary cond. (unchanged sign)
500
501      ! 3. monotonic flux in the i & j direction (paa & pbb)
502      ! ----------------------------------------
503      DO jk = 1, jpkm1
504         DO jj = 2, jpjm1
505            DO ji = fs_2, fs_jpim1   ! vector opt.
506               zau = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
507               zbu = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
508               zcu =       ( 0.5  + SIGN( 0.5 , paa(ji,jj,jk) ) )
509               paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1._wp - zcu) * zbu )
510
511               zav = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
512               zbv = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
513               zcv =       ( 0.5  + SIGN( 0.5 , pbb(ji,jj,jk) ) )
514               pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1._wp - zcv) * zbv )
515
516      ! monotonic flux in the k direction, i.e. pcc
517      ! -------------------------------------------
518               za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
519               zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
520               zc =       ( 0.5  + SIGN( 0.5 , pcc(ji,jj,jk+1) ) )
521               pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1._wp - zc) * zb )
522            END DO
523         END DO
524      END DO
525      CALL lbc_lnk_multi( 'traadv_fct', paa, 'U', -1. , pbb, 'V', -1. )   ! lateral boundary condition (changed sign)
526      !
527   END SUBROUTINE nonosc
528
529
530   SUBROUTINE interp_4th_cpt_org( pt_in, pt_out )
531      !!----------------------------------------------------------------------
532      !!                  ***  ROUTINE interp_4th_cpt_org  ***
533      !!
534      !! **  Purpose :   Compute the interpolation of tracer at w-point
535      !!
536      !! **  Method  :   4th order compact interpolation
537      !!----------------------------------------------------------------------
538      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! now tracer fields
539      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(  out) ::   pt_out   ! now tracer field interpolated at w-pts
540      !
541      INTEGER :: ji, jj, jk   ! dummy loop integers
542      REAL(wp),DIMENSION(jpi,jpj,jpk) :: zwd, zwi, zws, zwrm, zwt
543      !!----------------------------------------------------------------------
544     
545      DO jk = 3, jpkm1        !==  build the three diagonal matrix  ==!
546         DO jj = 1, jpj
547            DO ji = 1, jpi
548               zwd (ji,jj,jk) = 4._wp
549               zwi (ji,jj,jk) = 1._wp
550               zws (ji,jj,jk) = 1._wp
551               zwrm(ji,jj,jk) = 3._wp * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
552               !
553               IF( tmask(ji,jj,jk+1) == 0._wp) THEN   ! Switch to second order centered at bottom
554                  zwd (ji,jj,jk) = 1._wp
555                  zwi (ji,jj,jk) = 0._wp
556                  zws (ji,jj,jk) = 0._wp
557                  zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )   
558               ENDIF
559            END DO
560         END DO
561      END DO
562      !
563      jk = 2                                          ! Switch to second order centered at top
564      DO jj = 1, jpj
565         DO ji = 1, jpi
566            zwd (ji,jj,jk) = 1._wp
567            zwi (ji,jj,jk) = 0._wp
568            zws (ji,jj,jk) = 0._wp
569            zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
570         END DO
571      END DO   
572      !
573      !                       !==  tridiagonal solve  ==!
574      DO jj = 1, jpj                ! first recurrence
575         DO ji = 1, jpi
576            zwt(ji,jj,2) = zwd(ji,jj,2)
577         END DO
578      END DO
579      DO jk = 3, jpkm1
580         DO jj = 1, jpj
581            DO ji = 1, jpi
582               zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
583            END DO
584         END DO
585      END DO
586      !
587      DO jj = 1, jpj                ! second recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
588         DO ji = 1, jpi
589            pt_out(ji,jj,2) = zwrm(ji,jj,2)
590         END DO
591      END DO
592      DO jk = 3, jpkm1
593         DO jj = 1, jpj
594            DO ji = 1, jpi
595               pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
596            END DO
597         END DO
598      END DO
599
600      DO jj = 1, jpj                ! third recurrence: Xk = (Zk - Sk Xk+1 ) / Tk
601         DO ji = 1, jpi
602            pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
603         END DO
604      END DO
605      DO jk = jpk-2, 2, -1
606         DO jj = 1, jpj
607            DO ji = 1, jpi
608               pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
609            END DO
610         END DO
611      END DO
612      !   
613   END SUBROUTINE interp_4th_cpt_org
614   
615
616   SUBROUTINE interp_4th_cpt( pt_in, pt_out )
617      !!----------------------------------------------------------------------
618      !!                  ***  ROUTINE interp_4th_cpt  ***
619      !!
620      !! **  Purpose :   Compute the interpolation of tracer at w-point
621      !!
622      !! **  Method  :   4th order compact interpolation
623      !!----------------------------------------------------------------------
624      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! field at t-point
625      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(  out) ::   pt_out   ! field interpolated at w-point
626      !
627      INTEGER ::   ji, jj, jk   ! dummy loop integers
628      INTEGER ::   ikt, ikb     ! local integers
629      REAL(wp),DIMENSION(jpi,jpj,jpk) :: zwd, zwi, zws, zwrm, zwt
630      !!----------------------------------------------------------------------
631      !
632      !                      !==  build the three diagonal matrix & the RHS  ==!
633      !
634      DO jk = 3, jpkm1                 ! interior (from jk=3 to jpk-1)
635         DO jj = 2, jpjm1
636            DO ji = fs_2, fs_jpim1
637               zwd (ji,jj,jk) = 3._wp * wmask(ji,jj,jk) + 1._wp                 !       diagonal
638               zwi (ji,jj,jk) =         wmask(ji,jj,jk)                         ! lower diagonal
639               zws (ji,jj,jk) =         wmask(ji,jj,jk)                         ! upper diagonal
640               zwrm(ji,jj,jk) = 3._wp * wmask(ji,jj,jk)                     &   ! RHS
641                  &           *       ( pt_in(ji,jj,jk) + pt_in(ji,jj,jk-1) )
642            END DO
643         END DO
644      END DO
645      !
646!!gm
647!      SELECT CASE( kbc )               !* boundary condition
648!      CASE( np_NH   )   ! Neumann homogeneous at top & bottom
649!      CASE( np_CEN2 )   ! 2nd order centered  at top & bottom
650!      END SELECT
651!!gm 
652      !
653      IF ( ln_isfcav ) THEN            ! set level two values which may not be set in ISF case
654         zwd(:,:,2) = 1._wp  ;  zwi(:,:,2) = 0._wp  ;  zws(:,:,2) = 0._wp  ;  zwrm(:,:,2) = 0._wp
655      END IF
656      !
657      DO jj = 2, jpjm1                 ! 2nd order centered at top & bottom
658         DO ji = fs_2, fs_jpim1
659            ikt = mikt(ji,jj) + 1            ! w-point below the 1st  wet point
660            ikb = mbkt(ji,jj)                !     -   above the last wet point
661            !
662            zwd (ji,jj,ikt) = 1._wp          ! top
663            zwi (ji,jj,ikt) = 0._wp
664            zws (ji,jj,ikt) = 0._wp
665            zwrm(ji,jj,ikt) = 0.5_wp * ( pt_in(ji,jj,ikt-1) + pt_in(ji,jj,ikt) )
666            !
667            zwd (ji,jj,ikb) = 1._wp          ! bottom
668            zwi (ji,jj,ikb) = 0._wp
669            zws (ji,jj,ikb) = 0._wp
670            zwrm(ji,jj,ikb) = 0.5_wp * ( pt_in(ji,jj,ikb-1) + pt_in(ji,jj,ikb) )           
671         END DO
672      END DO   
673      !
674      !                       !==  tridiagonal solver  ==!
675      !
676      DO jj = 2, jpjm1              !* 1st recurrence:   Tk = Dk - Ik Sk-1 / Tk-1
677         DO ji = fs_2, fs_jpim1
678            zwt(ji,jj,2) = zwd(ji,jj,2)
679         END DO
680      END DO
681      DO jk = 3, jpkm1
682         DO jj = 2, jpjm1
683            DO ji = fs_2, fs_jpim1
684               zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
685            END DO
686         END DO
687      END DO
688      !
689      DO jj = 2, jpjm1              !* 2nd recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
690         DO ji = fs_2, fs_jpim1
691            pt_out(ji,jj,2) = zwrm(ji,jj,2)
692         END DO
693      END DO
694      DO jk = 3, jpkm1
695         DO jj = 2, jpjm1
696            DO ji = fs_2, fs_jpim1
697               pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
698            END DO
699         END DO
700      END DO
701
702      DO jj = 2, jpjm1              !* 3d recurrence:    Xk = (Zk - Sk Xk+1 ) / Tk
703         DO ji = fs_2, fs_jpim1
704            pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
705         END DO
706      END DO
707      DO jk = jpk-2, 2, -1
708         DO jj = 2, jpjm1
709            DO ji = fs_2, fs_jpim1
710               pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
711            END DO
712         END DO
713      END DO
714      !   
715   END SUBROUTINE interp_4th_cpt
716
717
718   SUBROUTINE tridia_solver( pD, pU, pL, pRHS, pt_out , klev )
719      !!----------------------------------------------------------------------
720      !!                  ***  ROUTINE tridia_solver  ***
721      !!
722      !! **  Purpose :   solve a symmetric 3diagonal system
723      !!
724      !! **  Method  :   solve M.t_out = RHS(t)  where M is a tri diagonal matrix ( jpk*jpk )
725      !!     
726      !!             ( D_1 U_1  0   0   0  )( t_1 )   ( RHS_1 )
727      !!             ( L_2 D_2 U_2  0   0  )( t_2 )   ( RHS_2 )
728      !!             (  0  L_3 D_3 U_3  0  )( t_3 ) = ( RHS_3 )
729      !!             (        ...          )( ... )   ( ...  )
730      !!             (  0   0   0  L_k D_k )( t_k )   ( RHS_k )
731      !!     
732      !!        M is decomposed in the product of an upper and lower triangular matrix.
733      !!        The tri-diagonals matrix is given as input 3D arrays:   pD, pU, pL
734      !!        (i.e. the Diagonal, the Upper diagonal, and the Lower diagonal).
735      !!        The solution is pta.
736      !!        The 3d array zwt is used as a work space array.
737      !!----------------------------------------------------------------------
738      REAL(wp),DIMENSION(:,:,:), INTENT(in   ) ::   pD, pU, PL    ! 3-diagonal matrix
739      REAL(wp),DIMENSION(:,:,:), INTENT(in   ) ::   pRHS          ! Right-Hand-Side
740      REAL(wp),DIMENSION(:,:,:), INTENT(  out) ::   pt_out        !!gm field at level=F(klev)
741      INTEGER                  , INTENT(in   ) ::   klev          ! =1 pt_out at w-level
742      !                                                           ! =0 pt at t-level
743      INTEGER ::   ji, jj, jk   ! dummy loop integers
744      INTEGER ::   kstart       ! local indices
745      REAL(wp),DIMENSION(jpi,jpj,jpk) ::   zwt   ! 3D work array
746      !!----------------------------------------------------------------------
747      !
748      kstart =  1  + klev
749      !
750      DO jj = 2, jpjm1              !* 1st recurrence:   Tk = Dk - Ik Sk-1 / Tk-1
751         DO ji = fs_2, fs_jpim1
752            zwt(ji,jj,kstart) = pD(ji,jj,kstart)
753         END DO
754      END DO
755      DO jk = kstart+1, jpkm1
756         DO jj = 2, jpjm1
757            DO ji = fs_2, fs_jpim1
758               zwt(ji,jj,jk) = pD(ji,jj,jk) - pL(ji,jj,jk) * pU(ji,jj,jk-1) /zwt(ji,jj,jk-1)
759            END DO
760         END DO
761      END DO
762      !
763      DO jj = 2, jpjm1              !* 2nd recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
764         DO ji = fs_2, fs_jpim1
765            pt_out(ji,jj,kstart) = pRHS(ji,jj,kstart)
766         END DO
767      END DO
768      DO jk = kstart+1, jpkm1
769         DO jj = 2, jpjm1
770            DO ji = fs_2, fs_jpim1
771               pt_out(ji,jj,jk) = pRHS(ji,jj,jk) - pL(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
772            END DO
773         END DO
774      END DO
775
776      DO jj = 2, jpjm1              !* 3d recurrence:    Xk = (Zk - Sk Xk+1 ) / Tk
777         DO ji = fs_2, fs_jpim1
778            pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
779         END DO
780      END DO
781      DO jk = jpk-2, kstart, -1
782         DO jj = 2, jpjm1
783            DO ji = fs_2, fs_jpim1
784               pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - pU(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
785            END DO
786         END DO
787      END DO
788      !
789   END SUBROUTINE tridia_solver
790
791   !!======================================================================
792END MODULE traadv_fct
Note: See TracBrowser for help on using the repository browser.