source: NEMO/trunk/src/OCE/TRA/traadv_fct.F90 @ 13226

Last change on this file since 13226 was 13226, checked in by orioltp, 3 months ago

Merging dev_r12512_HPC-04_mcastril_Mixed_Precision_implementation into the trunk

  • Property svn:keywords set to Id
File size: 32.8 KB
Line 
1MODULE traadv_fct
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_fct  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend (2nd/4th order Flux Corrected Transport method)
5   !!==============================================================================
6   !! History :  3.7  !  2015-09  (L. Debreu, G. Madec)  original code (inspired from traadv_tvd.F90)
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!  tra_adv_fct    : update the tracer trend with a 3D advective trends using a 2nd or 4th order FCT scheme
11   !!                   with sub-time-stepping in the vertical direction
12   !!  nonosc         : compute monotonic tracer fluxes by a non-oscillatory algorithm
13   !!  interp_4th_cpt : 4th order compact scheme for the vertical component of the advection
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and active tracers
16   USE dom_oce        ! ocean space and time domain
17   USE trc_oce        ! share passive tracers/Ocean variables
18   USE trd_oce        ! trends: ocean variables
19   USE trdtra         ! tracers trends
20   USE diaptr         ! poleward transport diagnostics
21   USE diaar5         ! AR5 diagnostics
22   USE phycst  , ONLY : rho0_rcp
23   USE zdf_oce , ONLY : ln_zad_Aimp
24   !
25   USE in_out_manager ! I/O manager
26   USE iom            !
27   USE lib_mpp        ! MPP library
28   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
29   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   tra_adv_fct        ! called by traadv.F90
35   PUBLIC   interp_4th_cpt     ! called by traadv_cen.F90
36
37   LOGICAL  ::   l_trd   ! flag to compute trends
38   LOGICAL  ::   l_ptr   ! flag to compute poleward transport
39   LOGICAL  ::   l_hst   ! flag to compute heat/salt transport
40   REAL(wp) ::   r1_6 = 1._wp / 6._wp   ! =1/6
41
42   !                                        ! tridiag solver associated indices:
43   INTEGER, PARAMETER ::   np_NH   = 0   ! Neumann homogeneous boundary condition
44   INTEGER, PARAMETER ::   np_CEN2 = 1   ! 2nd order centered  boundary condition
45
46   !! * Substitutions
47#  include "do_loop_substitute.h90"
48   !!----------------------------------------------------------------------
49   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
50   !! $Id$
51   !! Software governed by the CeCILL license (see ./LICENSE)
52   !!----------------------------------------------------------------------
53CONTAINS
54
55   SUBROUTINE tra_adv_fct( kt, kit000, cdtype, p2dt, pU, pV, pW,       &
56      &                    Kbb, Kmm, pt, kjpt, Krhs, kn_fct_h, kn_fct_v )
57      !!----------------------------------------------------------------------
58      !!                  ***  ROUTINE tra_adv_fct  ***
59      !!
60      !! **  Purpose :   Compute the now trend due to total advection of tracers
61      !!               and add it to the general trend of tracer equations
62      !!
63      !! **  Method  : - 2nd or 4th FCT scheme on the horizontal direction
64      !!               (choice through the value of kn_fct)
65      !!               - on the vertical the 4th order is a compact scheme
66      !!               - corrected flux (monotonic correction)
67      !!
68      !! ** Action : - update pt(:,:,:,:,Krhs)  with the now advective tracer trends
69      !!             - send trends to trdtra module for further diagnostics (l_trdtra=T)
70      !!             - poleward advective heat and salt transport (ln_diaptr=T)
71      !!----------------------------------------------------------------------
72      INTEGER                                  , INTENT(in   ) ::   kt              ! ocean time-step index
73      INTEGER                                  , INTENT(in   ) ::   Kbb, Kmm, Krhs  ! ocean time level indices
74      INTEGER                                  , INTENT(in   ) ::   kit000          ! first time step index
75      CHARACTER(len=3)                         , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
76      INTEGER                                  , INTENT(in   ) ::   kjpt            ! number of tracers
77      INTEGER                                  , INTENT(in   ) ::   kn_fct_h        ! order of the FCT scheme (=2 or 4)
78      INTEGER                                  , INTENT(in   ) ::   kn_fct_v        ! order of the FCT scheme (=2 or 4)
79      REAL(wp)                                 , INTENT(in   ) ::   p2dt            ! tracer time-step
80      REAL(wp), DIMENSION(jpi,jpj,jpk         ), INTENT(in   ) ::   pU, pV, pW      ! 3 ocean volume flux components
81      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::   pt              ! tracers and RHS of tracer equation
82      !
83      INTEGER  ::   ji, jj, jk, jn                           ! dummy loop indices 
84      REAL(wp) ::   ztra                                     ! local scalar
85      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk, zC2t_u, zC4t_u   !   -      -
86      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk, zC2t_v, zC4t_v   !   -      -
87      REAL(wp), DIMENSION(jpi,jpj,jpk)        ::   zwi, zwx, zwy, zwz, ztu, ztv, zltu, zltv, ztw
88      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrdx, ztrdy, ztrdz, zptry
89      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   zwinf, zwdia, zwsup
90      LOGICAL  ::   ll_zAimp                                 ! flag to apply adaptive implicit vertical advection
91      !!----------------------------------------------------------------------
92      !
93      IF( kt == kit000 )  THEN
94         IF(lwp) WRITE(numout,*)
95         IF(lwp) WRITE(numout,*) 'tra_adv_fct : FCT advection scheme on ', cdtype
96         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
97      ENDIF
98      !! -- init to 0
99      zwi(:,:,:) = 0._wp
100      zwx(:,:,:) = 0._wp
101      zwy(:,:,:) = 0._wp
102      zwz(:,:,:) = 0._wp
103      ztu(:,:,:) = 0._wp
104      ztv(:,:,:) = 0._wp
105      zltu(:,:,:) = 0._wp
106      zltv(:,:,:) = 0._wp
107      ztw(:,:,:) = 0._wp
108      !
109      l_trd = .FALSE.            ! set local switches
110      l_hst = .FALSE.
111      l_ptr = .FALSE.
112      ll_zAimp = .FALSE.
113      IF( ( cdtype == 'TRA' .AND. l_trdtra  ) .OR. ( cdtype =='TRC' .AND. l_trdtrc ) )      l_trd = .TRUE.
114      IF(   cdtype == 'TRA' .AND. ( iom_use( 'sophtadv' ) .OR. iom_use( 'sophtadv' ) ) )    l_ptr = .TRUE. 
115      IF(   cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR.  &
116         &                         iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) )  l_hst = .TRUE.
117      !
118      IF( l_trd .OR. l_hst )  THEN
119         ALLOCATE( ztrdx(jpi,jpj,jpk), ztrdy(jpi,jpj,jpk), ztrdz(jpi,jpj,jpk) )
120         ztrdx(:,:,:) = 0._wp   ;    ztrdy(:,:,:) = 0._wp   ;   ztrdz(:,:,:) = 0._wp
121      ENDIF
122      !
123      IF( l_ptr ) THEN 
124         ALLOCATE( zptry(jpi,jpj,jpk) )
125         zptry(:,:,:) = 0._wp
126      ENDIF
127      !                          ! surface & bottom value : flux set to zero one for all
128      zwz(:,:, 1 ) = 0._wp           
129      zwx(:,:,jpk) = 0._wp   ;   zwy(:,:,jpk) = 0._wp    ;    zwz(:,:,jpk) = 0._wp
130      !
131      zwi(:,:,:) = 0._wp       
132      !
133      ! If adaptive vertical advection, check if it is needed on this PE at this time
134      IF( ln_zad_Aimp ) THEN
135         IF( MAXVAL( ABS( wi(:,:,:) ) ) > 0._wp ) ll_zAimp = .TRUE.
136      END IF
137      ! If active adaptive vertical advection, build tridiagonal matrix
138      IF( ll_zAimp ) THEN
139         ALLOCATE(zwdia(jpi,jpj,jpk), zwinf(jpi,jpj,jpk),zwsup(jpi,jpj,jpk))
140         DO_3D_00_00( 1, jpkm1 )
141            zwdia(ji,jj,jk) =  1._wp + p2dt * ( MAX( wi(ji,jj,jk  ) , 0._wp ) - MIN( wi(ji,jj,jk+1) , 0._wp ) ) / e3t(ji,jj,jk,Krhs)
142            zwinf(ji,jj,jk) =  p2dt * MIN( wi(ji,jj,jk  ) , 0._wp ) / e3t(ji,jj,jk,Krhs)
143            zwsup(ji,jj,jk) = -p2dt * MAX( wi(ji,jj,jk+1) , 0._wp ) / e3t(ji,jj,jk,Krhs)
144         END_3D
145      END IF
146      !
147      DO jn = 1, kjpt            !==  loop over the tracers  ==!
148         !
149         !        !==  upstream advection with initial mass fluxes & intermediate update  ==!
150         !                    !* upstream tracer flux in the i and j direction
151         DO_3D_10_10( 1, jpkm1 )
152            ! upstream scheme
153            zfp_ui = pU(ji,jj,jk) + ABS( pU(ji,jj,jk) )
154            zfm_ui = pU(ji,jj,jk) - ABS( pU(ji,jj,jk) )
155            zfp_vj = pV(ji,jj,jk) + ABS( pV(ji,jj,jk) )
156            zfm_vj = pV(ji,jj,jk) - ABS( pV(ji,jj,jk) )
157            zwx(ji,jj,jk) = 0.5 * ( zfp_ui * pt(ji,jj,jk,jn,Kbb) + zfm_ui * pt(ji+1,jj  ,jk,jn,Kbb) )
158            zwy(ji,jj,jk) = 0.5 * ( zfp_vj * pt(ji,jj,jk,jn,Kbb) + zfm_vj * pt(ji  ,jj+1,jk,jn,Kbb) )
159         END_3D
160         !                    !* upstream tracer flux in the k direction *!
161         DO_3D_11_11( 2, jpkm1 )
162            zfp_wk = pW(ji,jj,jk) + ABS( pW(ji,jj,jk) )
163            zfm_wk = pW(ji,jj,jk) - ABS( pW(ji,jj,jk) )
164            zwz(ji,jj,jk) = 0.5 * ( zfp_wk * pt(ji,jj,jk,jn,Kbb) + zfm_wk * pt(ji,jj,jk-1,jn,Kbb) ) * wmask(ji,jj,jk)
165         END_3D
166         IF( ln_linssh ) THEN    ! top ocean value (only in linear free surface as zwz has been w-masked)
167            IF( ln_isfcav ) THEN             ! top of the ice-shelf cavities and at the ocean surface
168               DO_2D_11_11
169                  zwz(ji,jj, mikt(ji,jj) ) = pW(ji,jj,mikt(ji,jj)) * pt(ji,jj,mikt(ji,jj),jn,Kbb)   ! linear free surface
170               END_2D
171            ELSE                             ! no cavities: only at the ocean surface
172               zwz(:,:,1) = pW(:,:,1) * pt(:,:,1,jn,Kbb)
173            ENDIF
174         ENDIF
175         !               
176         DO_3D_00_00( 1, jpkm1 )
177            !                             ! total intermediate advective trends
178            ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
179               &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
180               &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
181            !                             ! update and guess with monotonic sheme
182            pt(ji,jj,jk,jn,Krhs) =                     pt(ji,jj,jk,jn,Krhs) +        ztra   / e3t(ji,jj,jk,Kmm) * tmask(ji,jj,jk)
183            zwi(ji,jj,jk)    = ( e3t(ji,jj,jk,Kbb) * pt(ji,jj,jk,jn,Kbb) + p2dt * ztra ) / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
184         END_3D
185         
186         IF ( ll_zAimp ) THEN
187            CALL tridia_solver( zwdia, zwsup, zwinf, zwi, zwi , 0 )
188            !
189            ztw(:,:,1) = 0._wp ; ztw(:,:,jpk) = 0._wp ;
190            DO_3D_00_00( 2, jpkm1 )
191               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
192               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
193               ztw(ji,jj,jk) =  0.5 * e1e2t(ji,jj) * ( zfp_wk * zwi(ji,jj,jk) + zfm_wk * zwi(ji,jj,jk-1) ) * wmask(ji,jj,jk)
194               zwz(ji,jj,jk) = zwz(ji,jj,jk) + ztw(ji,jj,jk) ! update vertical fluxes
195            END_3D
196            DO_3D_00_00( 1, jpkm1 )
197               pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) - ( ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) &
198                  &                                        * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
199            END_3D
200            !
201         END IF
202         !               
203         IF( l_trd .OR. l_hst )  THEN             ! trend diagnostics (contribution of upstream fluxes)
204            ztrdx(:,:,:) = zwx(:,:,:)   ;   ztrdy(:,:,:) = zwy(:,:,:)   ;   ztrdz(:,:,:) = zwz(:,:,:)
205         END IF
206         !                             ! "Poleward" heat and salt transports (contribution of upstream fluxes)
207         IF( l_ptr )   zptry(:,:,:) = zwy(:,:,:) 
208         !
209         !        !==  anti-diffusive flux : high order minus low order  ==!
210         !
211         SELECT CASE( kn_fct_h )    !* horizontal anti-diffusive fluxes
212         !
213         CASE(  2  )                   !- 2nd order centered
214            DO_3D_10_10( 1, jpkm1 )
215               zwx(ji,jj,jk) = 0.5_wp * pU(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj,jk,jn,Kmm) ) - zwx(ji,jj,jk)
216               zwy(ji,jj,jk) = 0.5_wp * pV(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji,jj+1,jk,jn,Kmm) ) - zwy(ji,jj,jk)
217            END_3D
218            !
219         CASE(  4  )                   !- 4th order centered
220            zltu(:,:,jpk) = 0._wp            ! Bottom value : flux set to zero
221            zltv(:,:,jpk) = 0._wp
222            DO jk = 1, jpkm1                 ! Laplacian
223               DO_2D_10_10
224                  ztu(ji,jj,jk) = ( pt(ji+1,jj  ,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * umask(ji,jj,jk)
225                  ztv(ji,jj,jk) = ( pt(ji  ,jj+1,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * vmask(ji,jj,jk)
226               END_2D
227               DO_2D_00_00
228                  zltu(ji,jj,jk) = (  ztu(ji,jj,jk) + ztu(ji-1,jj,jk)  ) * r1_6
229                  zltv(ji,jj,jk) = (  ztv(ji,jj,jk) + ztv(ji,jj-1,jk)  ) * r1_6
230               END_2D
231            END DO
232            CALL lbc_lnk_multi( 'traadv_fct', zltu, 'T', 1.0_wp , zltv, 'T', 1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
233            !
234            DO_3D_10_10( 1, jpkm1 )
235               zC2t_u = pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj  ,jk,jn,Kmm)   ! 2 x C2 interpolation of T at u- & v-points
236               zC2t_v = pt(ji,jj,jk,jn,Kmm) + pt(ji  ,jj+1,jk,jn,Kmm)
237               !                                                  ! C4 minus upstream advective fluxes
238               zwx(ji,jj,jk) =  0.5_wp * pU(ji,jj,jk) * ( zC2t_u + zltu(ji,jj,jk) - zltu(ji+1,jj,jk) ) - zwx(ji,jj,jk)
239               zwy(ji,jj,jk) =  0.5_wp * pV(ji,jj,jk) * ( zC2t_v + zltv(ji,jj,jk) - zltv(ji,jj+1,jk) ) - zwy(ji,jj,jk)
240            END_3D
241            !
242         CASE(  41 )                   !- 4th order centered       ==>>   !!gm coding attempt   need to be tested
243            ztu(:,:,jpk) = 0._wp             ! Bottom value : flux set to zero
244            ztv(:,:,jpk) = 0._wp
245            DO_3D_10_10( 1, jpkm1 )
246               ztu(ji,jj,jk) = ( pt(ji+1,jj  ,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * umask(ji,jj,jk)
247               ztv(ji,jj,jk) = ( pt(ji  ,jj+1,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * vmask(ji,jj,jk)
248            END_3D
249            CALL lbc_lnk_multi( 'traadv_fct', ztu, 'U', -1.0_wp , ztv, 'V', -1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
250            !
251            DO_3D_00_00( 1, jpkm1 )
252               zC2t_u = pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj  ,jk,jn,Kmm)   ! 2 x C2 interpolation of T at u- & v-points (x2)
253               zC2t_v = pt(ji,jj,jk,jn,Kmm) + pt(ji  ,jj+1,jk,jn,Kmm)
254               !                                                  ! C4 interpolation of T at u- & v-points (x2)
255               zC4t_u =  zC2t_u + r1_6 * ( ztu(ji-1,jj  ,jk) - ztu(ji+1,jj  ,jk) )
256               zC4t_v =  zC2t_v + r1_6 * ( ztv(ji  ,jj-1,jk) - ztv(ji  ,jj+1,jk) )
257               !                                                  ! C4 minus upstream advective fluxes
258               zwx(ji,jj,jk) =  0.5_wp * pU(ji,jj,jk) * zC4t_u - zwx(ji,jj,jk)
259               zwy(ji,jj,jk) =  0.5_wp * pV(ji,jj,jk) * zC4t_v - zwy(ji,jj,jk)
260            END_3D
261            !
262         END SELECT
263         !                     
264         SELECT CASE( kn_fct_v )    !* vertical anti-diffusive fluxes (w-masked interior values)
265         !
266         CASE(  2  )                   !- 2nd order centered
267            DO_3D_00_00( 2, jpkm1 )
268               zwz(ji,jj,jk) =  (  pW(ji,jj,jk) * 0.5_wp * ( pt(ji,jj,jk,jn,Kmm) + pt(ji,jj,jk-1,jn,Kmm) )   &
269                  &              - zwz(ji,jj,jk)  ) * wmask(ji,jj,jk)
270            END_3D
271            !
272         CASE(  4  )                   !- 4th order COMPACT
273            CALL interp_4th_cpt( pt(:,:,:,jn,Kmm) , ztw )   ! zwt = COMPACT interpolation of T at w-point
274            DO_3D_00_00( 2, jpkm1 )
275               zwz(ji,jj,jk) = ( pW(ji,jj,jk) * ztw(ji,jj,jk) - zwz(ji,jj,jk) ) * wmask(ji,jj,jk)
276            END_3D
277            !
278         END SELECT
279         IF( ln_linssh ) THEN    ! top ocean value: high order = upstream  ==>>  zwz=0
280            zwz(:,:,1) = 0._wp   ! only ocean surface as interior zwz values have been w-masked
281         ENDIF
282         !         
283         IF ( ll_zAimp ) THEN
284            DO_3D_00_00( 1, jpkm1 )
285               !                             ! total intermediate advective trends
286               ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
287                  &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
288                  &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
289               ztw(ji,jj,jk)  = zwi(ji,jj,jk) + p2dt * ztra / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
290            END_3D
291            !
292            CALL tridia_solver( zwdia, zwsup, zwinf, ztw, ztw , 0 )
293            !
294            DO_3D_00_00( 2, jpkm1 )
295               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
296               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
297               zwz(ji,jj,jk) =  zwz(ji,jj,jk) + 0.5 * e1e2t(ji,jj) * ( zfp_wk * ztw(ji,jj,jk) + zfm_wk * ztw(ji,jj,jk-1) ) * wmask(ji,jj,jk)
298            END_3D
299         END IF
300         !
301         CALL lbc_lnk_multi( 'traadv_fct', zwi, 'T', 1.0_wp, zwx, 'U', -1.0_wp , zwy, 'V', -1.0_wp,  zwz, 'W',  1.0_wp )
302         !
303         !        !==  monotonicity algorithm  ==!
304         !
305         CALL nonosc( Kmm, pt(:,:,:,jn,Kbb), zwx, zwy, zwz, zwi, p2dt )
306         !
307         !        !==  final trend with corrected fluxes  ==!
308         !
309         DO_3D_00_00( 1, jpkm1 )
310            ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
311               &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
312               &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
313            pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) + ztra / e3t(ji,jj,jk,Kmm)
314            zwi(ji,jj,jk) = zwi(ji,jj,jk) + p2dt * ztra / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
315         END_3D
316         !
317         IF ( ll_zAimp ) THEN
318            !
319            ztw(:,:,1) = 0._wp ; ztw(:,:,jpk) = 0._wp
320            DO_3D_00_00( 2, jpkm1 )
321               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
322               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
323               ztw(ji,jj,jk) = - 0.5 * e1e2t(ji,jj) * ( zfp_wk * zwi(ji,jj,jk) + zfm_wk * zwi(ji,jj,jk-1) ) * wmask(ji,jj,jk)
324               zwz(ji,jj,jk) = zwz(ji,jj,jk) + ztw(ji,jj,jk) ! Update vertical fluxes for trend diagnostic
325            END_3D
326            DO_3D_00_00( 1, jpkm1 )
327               pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) - ( ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) &
328                  &                                        * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
329            END_3D
330         END IF         
331         !
332         IF( l_trd .OR. l_hst ) THEN   ! trend diagnostics // heat/salt transport
333            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< add anti-diffusive fluxes
334            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  !     to upstream fluxes
335            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  !
336            !
337            IF( l_trd ) THEN              ! trend diagnostics
338               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_xad, ztrdx, pU, pt(:,:,:,jn,Kmm) )
339               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_yad, ztrdy, pV, pt(:,:,:,jn,Kmm) )
340               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_zad, ztrdz, pW, pt(:,:,:,jn,Kmm) )
341            ENDIF
342            !                             ! heat/salt transport
343            IF( l_hst )   CALL dia_ar5_hst( jn, 'adv', ztrdx(:,:,:), ztrdy(:,:,:) )
344            !
345         ENDIF
346         IF( l_ptr ) THEN              ! "Poleward" transports
347            zptry(:,:,:) = zptry(:,:,:) + zwy(:,:,:)  ! <<< add anti-diffusive fluxes
348            CALL dia_ptr_hst( jn, 'adv', zptry(:,:,:) )
349         ENDIF
350         !
351      END DO                     ! end of tracer loop
352      !
353      IF ( ll_zAimp ) THEN
354         DEALLOCATE( zwdia, zwinf, zwsup )
355      ENDIF
356      IF( l_trd .OR. l_hst ) THEN
357         DEALLOCATE( ztrdx, ztrdy, ztrdz )
358      ENDIF
359      IF( l_ptr ) THEN
360         DEALLOCATE( zptry )
361      ENDIF
362      !
363   END SUBROUTINE tra_adv_fct
364
365
366   SUBROUTINE nonosc( Kmm, pbef, paa, pbb, pcc, paft, p2dt )
367      !!---------------------------------------------------------------------
368      !!                    ***  ROUTINE nonosc  ***
369      !!     
370      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
371      !!       scheme and the before field by a nonoscillatory algorithm
372      !!
373      !! **  Method  :   ... ???
374      !!       warning : pbef and paft must be masked, but the boundaries
375      !!       conditions on the fluxes are not necessary zalezak (1979)
376      !!       drange (1995) multi-dimensional forward-in-time and upstream-
377      !!       in-space based differencing for fluid
378      !!----------------------------------------------------------------------
379      INTEGER                          , INTENT(in   ) ::   Kmm             ! time level index
380      REAL(wp)                         , INTENT(in   ) ::   p2dt            ! tracer time-step
381      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(in   ) ::   pbef, paft      ! before & after field
382      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
383      !
384      INTEGER  ::   ji, jj, jk   ! dummy loop indices
385      INTEGER  ::   ikm1         ! local integer
386      REAL(dp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn    ! local scalars
387      REAL(dp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
388      REAL(dp), DIMENSION(jpi,jpj,jpk) :: zbetup, zbetdo, zbup, zbdo
389      !!----------------------------------------------------------------------
390      !
391      zbig  = 1.e+40_dp
392      zrtrn = 1.e-15_dp
393      zbetup(:,:,:) = 0._dp   ;   zbetdo(:,:,:) = 0._dp
394
395      ! Search local extrema
396      ! --------------------
397      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
398      zbup = MAX( pbef * tmask - zbig * ( 1._wp - tmask ),   &
399         &        paft * tmask - zbig * ( 1._wp - tmask )  )
400      zbdo = MIN( pbef * tmask + zbig * ( 1._wp - tmask ),   &
401         &        paft * tmask + zbig * ( 1._wp - tmask )  )
402
403      DO jk = 1, jpkm1
404         ikm1 = MAX(jk-1,1)
405         DO_2D_00_00
406
407            ! search maximum in neighbourhood
408            zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
409               &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
410               &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
411               &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
412
413            ! search minimum in neighbourhood
414            zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
415               &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
416               &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
417               &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
418
419            ! positive part of the flux
420            zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
421               & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
422               & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
423
424            ! negative part of the flux
425            zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
426               & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
427               & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
428
429            ! up & down beta terms
430            zbt = e1e2t(ji,jj) * e3t(ji,jj,jk,Kmm) / p2dt
431            zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
432            zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
433         END_2D
434      END DO
435      CALL lbc_lnk_multi( 'traadv_fct', zbetup, 'T', 1.0_wp , zbetdo, 'T', 1.0_wp )   ! lateral boundary cond. (unchanged sign)
436
437      ! 3. monotonic flux in the i & j direction (paa & pbb)
438      ! ----------------------------------------
439      DO_3D_00_00( 1, jpkm1 )
440         zau = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
441         zbu = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
442         zcu =       ( 0.5  + SIGN( 0.5_wp , paa(ji,jj,jk) ) )
443         paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1._wp - zcu) * zbu )
444
445         zav = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
446         zbv = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
447         zcv =       ( 0.5  + SIGN( 0.5_wp , pbb(ji,jj,jk) ) )
448         pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1._wp - zcv) * zbv )
449
450! monotonic flux in the k direction, i.e. pcc
451! -------------------------------------------
452         za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
453         zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
454         zc =       ( 0.5  + SIGN( 0.5_wp , pcc(ji,jj,jk+1) ) )
455         pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1._wp - zc) * zb )
456      END_3D
457      CALL lbc_lnk_multi( 'traadv_fct', paa, 'U', -1.0_wp , pbb, 'V', -1.0_wp )   ! lateral boundary condition (changed sign)
458      !
459   END SUBROUTINE nonosc
460
461
462   SUBROUTINE interp_4th_cpt_org( pt_in, pt_out )
463      !!----------------------------------------------------------------------
464      !!                  ***  ROUTINE interp_4th_cpt_org  ***
465      !!
466      !! **  Purpose :   Compute the interpolation of tracer at w-point
467      !!
468      !! **  Method  :   4th order compact interpolation
469      !!----------------------------------------------------------------------
470      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! now tracer fields
471      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(  out) ::   pt_out   ! now tracer field interpolated at w-pts
472      !
473      INTEGER :: ji, jj, jk   ! dummy loop integers
474      REAL(wp),DIMENSION(jpi,jpj,jpk) :: zwd, zwi, zws, zwrm, zwt
475      !!----------------------------------------------------------------------
476     
477      DO_3D_11_11( 3, jpkm1 )
478         zwd (ji,jj,jk) = 4._wp
479         zwi (ji,jj,jk) = 1._wp
480         zws (ji,jj,jk) = 1._wp
481         zwrm(ji,jj,jk) = 3._wp * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
482         !
483         IF( tmask(ji,jj,jk+1) == 0._wp) THEN   ! Switch to second order centered at bottom
484            zwd (ji,jj,jk) = 1._wp
485            zwi (ji,jj,jk) = 0._wp
486            zws (ji,jj,jk) = 0._wp
487            zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )   
488         ENDIF
489      END_3D
490      !
491      jk = 2                                          ! Switch to second order centered at top
492      DO_2D_11_11
493         zwd (ji,jj,jk) = 1._wp
494         zwi (ji,jj,jk) = 0._wp
495         zws (ji,jj,jk) = 0._wp
496         zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
497      END_2D
498      !
499      !                       !==  tridiagonal solve  ==!
500      DO_2D_11_11
501         zwt(ji,jj,2) = zwd(ji,jj,2)
502      END_2D
503      DO_3D_11_11( 3, jpkm1 )
504         zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
505      END_3D
506      !
507      DO_2D_11_11
508         pt_out(ji,jj,2) = zwrm(ji,jj,2)
509      END_2D
510      DO_3D_11_11( 3, jpkm1 )
511         pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
512      END_3D
513
514      DO_2D_11_11
515         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
516      END_2D
517      DO_3DS_11_11( jpk-2, 2, -1 )
518         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
519      END_3D
520      !   
521   END SUBROUTINE interp_4th_cpt_org
522   
523
524   SUBROUTINE interp_4th_cpt( pt_in, pt_out )
525      !!----------------------------------------------------------------------
526      !!                  ***  ROUTINE interp_4th_cpt  ***
527      !!
528      !! **  Purpose :   Compute the interpolation of tracer at w-point
529      !!
530      !! **  Method  :   4th order compact interpolation
531      !!----------------------------------------------------------------------
532      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! field at t-point
533      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(  out) ::   pt_out   ! field interpolated at w-point
534      !
535      INTEGER ::   ji, jj, jk   ! dummy loop integers
536      INTEGER ::   ikt, ikb     ! local integers
537      REAL(wp),DIMENSION(jpi,jpj,jpk) :: zwd, zwi, zws, zwrm, zwt
538      !!----------------------------------------------------------------------
539      !
540      !                      !==  build the three diagonal matrix & the RHS  ==!
541      !
542      DO_3D_00_00( 3, jpkm1 )
543         zwd (ji,jj,jk) = 3._wp * wmask(ji,jj,jk) + 1._wp                 !       diagonal
544         zwi (ji,jj,jk) =         wmask(ji,jj,jk)                         ! lower diagonal
545         zws (ji,jj,jk) =         wmask(ji,jj,jk)                         ! upper diagonal
546         zwrm(ji,jj,jk) = 3._wp * wmask(ji,jj,jk)                     &   ! RHS
547            &           *       ( pt_in(ji,jj,jk) + pt_in(ji,jj,jk-1) )
548      END_3D
549      !
550!!gm
551!      SELECT CASE( kbc )               !* boundary condition
552!      CASE( np_NH   )   ! Neumann homogeneous at top & bottom
553!      CASE( np_CEN2 )   ! 2nd order centered  at top & bottom
554!      END SELECT
555!!gm 
556      !
557      IF ( ln_isfcav ) THEN            ! set level two values which may not be set in ISF case
558         zwd(:,:,2) = 1._wp  ;  zwi(:,:,2) = 0._wp  ;  zws(:,:,2) = 0._wp  ;  zwrm(:,:,2) = 0._wp
559      END IF
560      !
561      DO_2D_00_00
562         ikt = mikt(ji,jj) + 1            ! w-point below the 1st  wet point
563         ikb = MAX(mbkt(ji,jj), 2)        !     -   above the last wet point
564         !
565         zwd (ji,jj,ikt) = 1._wp          ! top
566         zwi (ji,jj,ikt) = 0._wp
567         zws (ji,jj,ikt) = 0._wp
568         zwrm(ji,jj,ikt) = 0.5_wp * ( pt_in(ji,jj,ikt-1) + pt_in(ji,jj,ikt) )
569         !
570         zwd (ji,jj,ikb) = 1._wp          ! bottom
571         zwi (ji,jj,ikb) = 0._wp
572         zws (ji,jj,ikb) = 0._wp
573         zwrm(ji,jj,ikb) = 0.5_wp * ( pt_in(ji,jj,ikb-1) + pt_in(ji,jj,ikb) )           
574      END_2D
575      !
576      !                       !==  tridiagonal solver  ==!
577      !
578      DO_2D_00_00
579         zwt(ji,jj,2) = zwd(ji,jj,2)
580      END_2D
581      DO_3D_00_00( 3, jpkm1 )
582         zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
583      END_3D
584      !
585      DO_2D_00_00
586         pt_out(ji,jj,2) = zwrm(ji,jj,2)
587      END_2D
588      DO_3D_00_00( 3, jpkm1 )
589         pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
590      END_3D
591
592      DO_2D_00_00
593         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
594      END_2D
595      DO_3DS_00_00( jpk-2, 2, -1 )
596         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
597      END_3D
598      !   
599   END SUBROUTINE interp_4th_cpt
600
601
602   SUBROUTINE tridia_solver( pD, pU, pL, pRHS, pt_out , klev )
603      !!----------------------------------------------------------------------
604      !!                  ***  ROUTINE tridia_solver  ***
605      !!
606      !! **  Purpose :   solve a symmetric 3diagonal system
607      !!
608      !! **  Method  :   solve M.t_out = RHS(t)  where M is a tri diagonal matrix ( jpk*jpk )
609      !!     
610      !!             ( D_1 U_1  0   0   0  )( t_1 )   ( RHS_1 )
611      !!             ( L_2 D_2 U_2  0   0  )( t_2 )   ( RHS_2 )
612      !!             (  0  L_3 D_3 U_3  0  )( t_3 ) = ( RHS_3 )
613      !!             (        ...          )( ... )   ( ...  )
614      !!             (  0   0   0  L_k D_k )( t_k )   ( RHS_k )
615      !!     
616      !!        M is decomposed in the product of an upper and lower triangular matrix.
617      !!        The tri-diagonals matrix is given as input 3D arrays:   pD, pU, pL
618      !!        (i.e. the Diagonal, the Upper diagonal, and the Lower diagonal).
619      !!        The solution is pta.
620      !!        The 3d array zwt is used as a work space array.
621      !!----------------------------------------------------------------------
622      REAL(wp),DIMENSION(:,:,:), INTENT(in   ) ::   pD, pU, PL    ! 3-diagonal matrix
623      REAL(wp),DIMENSION(:,:,:), INTENT(in   ) ::   pRHS          ! Right-Hand-Side
624      REAL(wp),DIMENSION(:,:,:), INTENT(  out) ::   pt_out        !!gm field at level=F(klev)
625      INTEGER                  , INTENT(in   ) ::   klev          ! =1 pt_out at w-level
626      !                                                           ! =0 pt at t-level
627      INTEGER ::   ji, jj, jk   ! dummy loop integers
628      INTEGER ::   kstart       ! local indices
629      REAL(wp),DIMENSION(jpi,jpj,jpk) ::   zwt   ! 3D work array
630      !!----------------------------------------------------------------------
631      !
632      kstart =  1  + klev
633      !
634      DO_2D_00_00
635         zwt(ji,jj,kstart) = pD(ji,jj,kstart)
636      END_2D
637      DO_3D_00_00( kstart+1, jpkm1 )
638         zwt(ji,jj,jk) = pD(ji,jj,jk) - pL(ji,jj,jk) * pU(ji,jj,jk-1) /zwt(ji,jj,jk-1)
639      END_3D
640      !
641      DO_2D_00_00
642         pt_out(ji,jj,kstart) = pRHS(ji,jj,kstart)
643      END_2D
644      DO_3D_00_00( kstart+1, jpkm1 )
645         pt_out(ji,jj,jk) = pRHS(ji,jj,jk) - pL(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
646      END_3D
647
648      DO_2D_00_00
649         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
650      END_2D
651      DO_3DS_00_00( jpk-2, kstart, -1 )
652         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - pU(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
653      END_3D
654      !
655   END SUBROUTINE tridia_solver
656
657   !!======================================================================
658END MODULE traadv_fct
Note: See TracBrowser for help on using the repository browser.