source: NEMO/trunk/src/OCE/TRA/traldf_triad.F90 @ 13237

Last change on this file since 13237 was 13237, checked in by smasson, 3 months ago

trunk: Mid-year merge, merge back KERNEL-06_techene_e3

  • Property svn:keywords set to Id
File size: 21.3 KB
Line 
1MODULE traldf_triad
2   !!======================================================================
3   !!                   ***  MODULE  traldf_triad  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!======================================================================
6   !! History :  3.3  ! 2010-10  (G. Nurser, C. Harris, G. Madec)  Griffies operator (original code)
7   !!            3.7  ! 2013-12  (F. Lemarie, G. Madec)  triad operator (Griffies) + Method of Stabilizing Correction
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   tra_ldf_triad : update the tracer trend with the iso-neutral laplacian triad-operator
12   !!----------------------------------------------------------------------
13   USE oce            ! ocean dynamics and active tracers
14   USE dom_oce        ! ocean space and time domain
15   USE phycst         ! physical constants
16   USE trc_oce        ! share passive tracers/Ocean variables
17   USE zdf_oce        ! ocean vertical physics
18   USE ldftra         ! lateral physics: eddy diffusivity
19   USE ldfslp         ! lateral physics: iso-neutral slopes
20   USE traldf_iso     ! lateral diffusion (Madec operator)         (tra_ldf_iso routine)
21   USE diaptr         ! poleward transport diagnostics
22   USE diaar5         ! AR5 diagnostics
23   USE zpshde         ! partial step: hor. derivative     (zps_hde routine)
24   !
25   USE in_out_manager ! I/O manager
26   USE iom            ! I/O library
27   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
28   USE lib_mpp        ! MPP library
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   tra_ldf_triad   ! routine called by traldf.F90
34
35   REAL(wp), DIMENSION(:,:,:), ALLOCATABLE, SAVE ::   zdkt3d   !: vertical tracer gradient at 2 levels
36
37   LOGICAL  ::   l_ptr   ! flag to compute poleward transport
38   LOGICAL  ::   l_hst   ! flag to compute heat transport
39
40
41   !! * Substitutions
42#  include "do_loop_substitute.h90"
43#  include "domzgr_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
46   !! $Id$
47   !! Software governed by the CeCILL license (see ./LICENSE)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51  SUBROUTINE tra_ldf_triad( kt, Kmm, kit000, cdtype, pahu, pahv,               &
52      &                                              pgu , pgv  , pgui, pgvi , &
53      &                                         pt , pt2, pt_rhs, kjpt, kpass )
54      !!----------------------------------------------------------------------
55      !!                  ***  ROUTINE tra_ldf_triad  ***
56      !!
57      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
58      !!      trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and
59      !!      add it to the general trend of tracer equation.
60      !!
61      !! ** Method  :   The horizontal component of the lateral diffusive trends
62      !!      is provided by a 2nd order operator rotated along neural or geopo-
63      !!      tential surfaces to which an eddy induced advection can be added
64      !!      It is computed using before fields (forward in time) and isopyc-
65      !!      nal or geopotential slopes computed in routine ldfslp.
66      !!
67      !!      see documentation for the desciption
68      !!
69      !! ** Action :   pt_rhs   updated with the before rotated diffusion
70      !!               ah_wslp2 ....
71      !!               akz   stabilizing vertical diffusivity coefficient (used in trazdf_imp)
72      !!----------------------------------------------------------------------
73      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
74      INTEGER                              , INTENT(in   ) ::   kit000     ! first time step index
75      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
76      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
77      INTEGER                              , INTENT(in   ) ::   kpass      ! =1/2 first or second passage
78      INTEGER                              , INTENT(in)    ::   Kmm        ! ocean time level indices
79      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(in   ) ::   pahu, pahv ! eddy diffusivity at u- and v-points  [m2/s]
80      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu , pgv  ! tracer gradient at pstep levels
81      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(in   ) ::   pgui, pgvi ! tracer gradient at top   levels
82      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   pt         ! tracer (kpass=1) or laplacian of tracer (kpass=2)
83      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   pt2        ! tracer (only used in kpass=2)
84      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pt_rhs     ! tracer trend
85      !
86      INTEGER  ::  ji, jj, jk, jn   ! dummy loop indices
87      INTEGER  ::  ip,jp,kp         ! dummy loop indices
88      INTEGER  ::  ierr            ! local integer
89      REAL(wp) ::  zmsku, zabe1, zcof1, zcoef3    ! local scalars
90      REAL(wp) ::  zmskv, zabe2, zcof2, zcoef4    !   -      -
91      REAL(wp) ::  zcoef0, ze3w_2, zsign          !   -      -
92      !
93      REAL(wp) ::   zslope_skew, zslope_iso, zslope2, zbu, zbv
94      REAL(wp) ::   ze1ur, ze2vr, ze3wr, zdxt, zdyt, zdzt
95      REAL(wp) ::   zah, zah_slp, zaei_slp
96      REAL(wp), DIMENSION(jpi,jpj    ) ::   z2d                                              ! 2D workspace
97      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zdit, zdjt, zftu, zftv, ztfw, zpsi_uw, zpsi_vw   ! 3D     -
98      !!----------------------------------------------------------------------
99      !
100      IF( .NOT.ALLOCATED(zdkt3d) )  THEN
101         ALLOCATE( zdkt3d(jpi,jpj,0:1) , STAT=ierr )
102         CALL mpp_sum ( 'traldf_triad', ierr )
103         IF( ierr > 0 )   CALL ctl_stop('STOP', 'tra_ldf_triad: unable to allocate arrays')
104      ENDIF
105     !
106      IF( kpass == 1 .AND. kt == kit000 )  THEN
107         IF(lwp) WRITE(numout,*)
108         IF(lwp) WRITE(numout,*) 'tra_ldf_triad : rotated laplacian diffusion operator on ', cdtype
109         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~'
110      ENDIF
111      !   
112      l_hst = .FALSE.
113      l_ptr = .FALSE.
114      IF( cdtype == 'TRA' ) THEN
115         IF( iom_use( 'sophtldf' ) .OR. iom_use( 'sopstldf') )      l_ptr = .TRUE. 
116         IF( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR.                   &
117         &   iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  )   l_hst = .TRUE.
118      ENDIF
119      !
120      IF( kpass == 1 ) THEN   ;   zsign =  1._wp      ! bilaplacian operator require a minus sign (eddy diffusivity >0)
121      ELSE                    ;   zsign = -1._wp
122      ENDIF
123      !   
124      !!----------------------------------------------------------------------
125      !!   0 - calculate  ah_wslp2, akz, and optionally zpsi_uw, zpsi_vw
126      !!----------------------------------------------------------------------
127      !
128      IF( kpass == 1 ) THEN         !==  first pass only  and whatever the tracer is  ==!
129         !
130         akz     (:,:,:) = 0._wp     
131         ah_wslp2(:,:,:) = 0._wp
132         IF( ln_ldfeiv_dia ) THEN
133            zpsi_uw(:,:,:) = 0._wp
134            zpsi_vw(:,:,:) = 0._wp
135         ENDIF
136         !
137         DO ip = 0, 1                            ! i-k triads
138            DO kp = 0, 1
139               DO_3D_10_10( 1, jpkm1 )
140                  ze3wr = 1._wp / e3w(ji+ip,jj,jk+kp,Kmm)
141                  zbu   = e1e2u(ji,jj) * e3u(ji,jj,jk,Kmm)
142                  zah   = 0.25_wp * pahu(ji,jj,jk)
143                  zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp)
144                  ! Subtract s-coordinate slope at t-points to give slope rel to s-surfaces (do this by *adding* gradient of depth)
145                  zslope2 = zslope_skew + ( gdept(ji+1,jj,jk,Kmm) - gdept(ji,jj,jk,Kmm) ) * r1_e1u(ji,jj) * umask(ji,jj,jk+kp)
146                  zslope2 = zslope2 *zslope2
147                  ah_wslp2(ji+ip,jj,jk+kp) = ah_wslp2(ji+ip,jj,jk+kp) + zah * zbu * ze3wr * r1_e1e2t(ji+ip,jj) * zslope2
148                  akz     (ji+ip,jj,jk+kp) = akz     (ji+ip,jj,jk+kp) + zah * r1_e1u(ji,jj)       &
149                     &                                                      * r1_e1u(ji,jj) * umask(ji,jj,jk+kp)
150                     !
151                 IF( ln_ldfeiv_dia )   zpsi_uw(ji,jj,jk+kp) = zpsi_uw(ji,jj,jk+kp)   &
152                     &                                       + 0.25_wp * aeiu(ji,jj,jk) * e2u(ji,jj) * zslope_skew
153               END_3D
154            END DO
155         END DO
156         !
157         DO jp = 0, 1                            ! j-k triads
158            DO kp = 0, 1
159               DO_3D_10_10( 1, jpkm1 )
160                  ze3wr = 1.0_wp / e3w(ji,jj+jp,jk+kp,Kmm)
161                  zbv   = e1e2v(ji,jj) * e3v(ji,jj,jk,Kmm)
162                  zah   = 0.25_wp * pahv(ji,jj,jk)
163                  zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp)
164                  ! Subtract s-coordinate slope at t-points to give slope rel to s surfaces
165                  !    (do this by *adding* gradient of depth)
166                  zslope2 = zslope_skew + ( gdept(ji,jj+1,jk,Kmm) - gdept(ji,jj,jk,Kmm) ) * r1_e2v(ji,jj) * vmask(ji,jj,jk+kp)
167                  zslope2 = zslope2 * zslope2
168                  ah_wslp2(ji,jj+jp,jk+kp) = ah_wslp2(ji,jj+jp,jk+kp) + zah * zbv * ze3wr * r1_e1e2t(ji,jj+jp) * zslope2
169                  akz     (ji,jj+jp,jk+kp) = akz     (ji,jj+jp,jk+kp) + zah * r1_e2v(ji,jj)     &
170                     &                                                      * r1_e2v(ji,jj) * vmask(ji,jj,jk+kp)
171                  !
172                  IF( ln_ldfeiv_dia )   zpsi_vw(ji,jj,jk+kp) = zpsi_vw(ji,jj,jk+kp)   &
173                     &                                       + 0.25 * aeiv(ji,jj,jk) * e1v(ji,jj) * zslope_skew
174               END_3D
175            END DO
176         END DO
177         !
178         IF( ln_traldf_msc ) THEN                ! stabilizing vertical diffusivity coefficient
179            !
180            IF( ln_traldf_blp ) THEN                ! bilaplacian operator
181               DO_3D_10_10( 2, jpkm1 )
182                  akz(ji,jj,jk) = 16._wp           &
183                     &   * ah_wslp2   (ji,jj,jk)   &
184                     &   * (  akz     (ji,jj,jk)   &
185                     &      + ah_wslp2(ji,jj,jk)   &
186                     &        / ( e3w (ji,jj,jk,Kmm) * e3w(ji,jj,jk,Kmm) )  )
187               END_3D
188            ELSEIF( ln_traldf_lap ) THEN              ! laplacian operator
189               DO_3D_10_10( 2, jpkm1 )
190                  ze3w_2 = e3w(ji,jj,jk,Kmm) * e3w(ji,jj,jk,Kmm)
191                  zcoef0 = rDt * (  akz(ji,jj,jk) + ah_wslp2(ji,jj,jk) / ze3w_2  )
192                  akz(ji,jj,jk) = MAX( zcoef0 - 0.5_wp , 0._wp ) * ze3w_2 * r1_Dt
193               END_3D
194           ENDIF
195           !
196         ELSE                                    ! 33 flux set to zero with akz=ah_wslp2 ==>> computed in full implicit
197            akz(:,:,:) = ah_wslp2(:,:,:)     
198         ENDIF
199         !
200         IF( ln_ldfeiv_dia .AND. cdtype == 'TRA' )   CALL ldf_eiv_dia( zpsi_uw, zpsi_vw, Kmm )
201         !
202      ENDIF                                  !==  end 1st pass only  ==!
203      !
204      !                                                           ! ===========
205      DO jn = 1, kjpt                                             ! tracer loop
206         !                                                        ! ===========
207         ! Zero fluxes for each tracer
208!!gm  this should probably be done outside the jn loop
209         ztfw(:,:,:) = 0._wp
210         zftu(:,:,:) = 0._wp
211         zftv(:,:,:) = 0._wp
212         !
213         DO_3D_10_10( 1, jpkm1 )
214            zdit(ji,jj,jk) = ( pt(ji+1,jj  ,jk,jn) - pt(ji,jj,jk,jn) ) * umask(ji,jj,jk)
215            zdjt(ji,jj,jk) = ( pt(ji  ,jj+1,jk,jn) - pt(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
216         END_3D
217         IF( ln_zps .AND. l_grad_zps ) THEN    ! partial steps: correction at top/bottom ocean level
218            DO_2D_10_10
219               zdit(ji,jj,mbku(ji,jj)) = pgu(ji,jj,jn)
220               zdjt(ji,jj,mbkv(ji,jj)) = pgv(ji,jj,jn)
221            END_2D
222            IF( ln_isfcav ) THEN                   ! top level (ocean cavities only)
223               DO_2D_10_10
224                  IF( miku(ji,jj)  > 1 )   zdit(ji,jj,miku(ji,jj) ) = pgui(ji,jj,jn) 
225                  IF( mikv(ji,jj)  > 1 )   zdjt(ji,jj,mikv(ji,jj) ) = pgvi(ji,jj,jn) 
226               END_2D
227            ENDIF
228         ENDIF
229         !
230         !!----------------------------------------------------------------------
231         !!   II - horizontal trend  (full)
232         !!----------------------------------------------------------------------
233         !
234         DO jk = 1, jpkm1
235            !                    !==  Vertical tracer gradient at level jk and jk+1
236            zdkt3d(:,:,1) = ( pt(:,:,jk,jn) - pt(:,:,jk+1,jn) ) * tmask(:,:,jk+1)
237            !
238            !                    ! surface boundary condition: zdkt3d(jk=0)=zdkt3d(jk=1)
239            IF( jk == 1 ) THEN   ;   zdkt3d(:,:,0) = zdkt3d(:,:,1)
240            ELSE                 ;   zdkt3d(:,:,0) = ( pt(:,:,jk-1,jn) - pt(:,:,jk,jn) ) * tmask(:,:,jk)
241            ENDIF
242            !
243            zaei_slp = 0._wp
244            !
245            IF( ln_botmix_triad ) THEN
246               DO ip = 0, 1              !==  Horizontal & vertical fluxes
247                  DO kp = 0, 1
248                     DO_2D_10_10
249                        ze1ur = r1_e1u(ji,jj)
250                        zdxt  = zdit(ji,jj,jk) * ze1ur
251                        ze3wr = 1._wp / e3w(ji+ip,jj,jk+kp,Kmm)
252                        zdzt  = zdkt3d(ji+ip,jj,kp) * ze3wr
253                        zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp)
254                        zslope_iso  = triadi  (ji+ip,jj,jk,1-ip,kp)
255                        !
256                        zbu = 0.25_wp * e1e2u(ji,jj) * e3u(ji,jj,jk,Kmm)
257                        ! ln_botmix_triad is .T. don't mask zah for bottom half cells    !!gm ?????   ahu is masked....
258                        zah = pahu(ji,jj,jk)
259                        zah_slp  = zah * zslope_iso
260                        IF( ln_ldfeiv )   zaei_slp = aeiu(ji,jj,jk) * zslope_skew
261                        zftu(ji   ,jj,jk   ) = zftu(ji   ,jj,jk   ) - ( zah * zdxt + (zah_slp - zaei_slp) * zdzt ) * zbu * ze1ur
262                        ztfw(ji+ip,jj,jk+kp) = ztfw(ji+ip,jj,jk+kp) - ( zah_slp + zaei_slp) * zdxt                 * zbu * ze3wr
263                     END_2D
264                  END DO
265               END DO
266               !
267               DO jp = 0, 1
268                  DO kp = 0, 1
269                     DO_2D_10_10
270                        ze2vr = r1_e2v(ji,jj)
271                        zdyt  = zdjt(ji,jj,jk) * ze2vr
272                        ze3wr = 1._wp / e3w(ji,jj+jp,jk+kp,Kmm)
273                        zdzt  = zdkt3d(ji,jj+jp,kp) * ze3wr
274                        zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp)
275                        zslope_iso  = triadj(ji,jj+jp,jk,1-jp,kp)
276                        zbv = 0.25_wp * e1e2v(ji,jj) * e3v(ji,jj,jk,Kmm)
277                        ! ln_botmix_triad is .T. don't mask zah for bottom half cells    !!gm ?????  ahv is masked...
278                        zah = pahv(ji,jj,jk)
279                        zah_slp = zah * zslope_iso
280                        IF( ln_ldfeiv )   zaei_slp = aeiv(ji,jj,jk) * zslope_skew
281                        zftv(ji,jj   ,jk   ) = zftv(ji,jj   ,jk   ) - ( zah * zdyt + (zah_slp - zaei_slp) * zdzt ) * zbv * ze2vr
282                        ztfw(ji,jj+jp,jk+kp) = ztfw(ji,jj+jp,jk+kp) - ( zah_slp + zaei_slp ) * zdyt                * zbv * ze3wr
283                     END_2D
284                  END DO
285               END DO
286               !
287            ELSE
288               !
289               DO ip = 0, 1               !==  Horizontal & vertical fluxes
290                  DO kp = 0, 1
291                     DO_2D_10_10
292                        ze1ur = r1_e1u(ji,jj)
293                        zdxt  = zdit(ji,jj,jk) * ze1ur
294                        ze3wr = 1._wp / e3w(ji+ip,jj,jk+kp,Kmm)
295                        zdzt  = zdkt3d(ji+ip,jj,kp) * ze3wr
296                        zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp)
297                        zslope_iso  = triadi(ji+ip,jj,jk,1-ip,kp)
298                        !
299                        zbu = 0.25_wp * e1e2u(ji,jj) * e3u(ji,jj,jk,Kmm)
300                        ! ln_botmix_triad is .F. mask zah for bottom half cells
301                        zah = pahu(ji,jj,jk) * umask(ji,jj,jk+kp)         ! pahu(ji+ip,jj,jk)   ===>>  ????
302                        zah_slp  = zah * zslope_iso
303                        IF( ln_ldfeiv )   zaei_slp = aeiu(ji,jj,jk) * zslope_skew        ! aeit(ji+ip,jj,jk)*zslope_skew
304                        zftu(ji   ,jj,jk   ) = zftu(ji   ,jj,jk   ) - ( zah * zdxt + (zah_slp - zaei_slp) * zdzt ) * zbu * ze1ur
305                        ztfw(ji+ip,jj,jk+kp) = ztfw(ji+ip,jj,jk+kp) - (zah_slp + zaei_slp) * zdxt * zbu * ze3wr
306                     END_2D
307                  END DO
308               END DO
309               !
310               DO jp = 0, 1
311                  DO kp = 0, 1
312                     DO_2D_10_10
313                        ze2vr = r1_e2v(ji,jj)
314                        zdyt  = zdjt(ji,jj,jk) * ze2vr
315                        ze3wr = 1._wp / e3w(ji,jj+jp,jk+kp,Kmm)
316                        zdzt  = zdkt3d(ji,jj+jp,kp) * ze3wr
317                        zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp)
318                        zslope_iso  = triadj(ji,jj+jp,jk,1-jp,kp)
319                        zbv = 0.25_wp * e1e2v(ji,jj) * e3v(ji,jj,jk,Kmm)
320                        ! ln_botmix_triad is .F. mask zah for bottom half cells
321                        zah = pahv(ji,jj,jk) * vmask(ji,jj,jk+kp)         ! pahv(ji,jj+jp,jk)  ????
322                        zah_slp = zah * zslope_iso
323                        IF( ln_ldfeiv )   zaei_slp = aeiv(ji,jj,jk) * zslope_skew        ! aeit(ji,jj+jp,jk)*zslope_skew
324                        zftv(ji,jj,jk) = zftv(ji,jj,jk) - ( zah * zdyt + (zah_slp - zaei_slp) * zdzt ) * zbv * ze2vr
325                        ztfw(ji,jj+jp,jk+kp) = ztfw(ji,jj+jp,jk+kp) - (zah_slp + zaei_slp) * zdyt * zbv * ze3wr
326                     END_2D
327                  END DO
328               END DO
329            ENDIF
330            !                             !==  horizontal divergence and add to the general trend  ==!
331            DO_2D_00_00
332               pt_rhs(ji,jj,jk,jn) = pt_rhs(ji,jj,jk,jn)    &
333                  &                       + zsign * (  zftu(ji-1,jj  ,jk) - zftu(ji,jj,jk)       &
334                  &                                           + zftv(ji,jj-1,jk) - zftv(ji,jj,jk)   )   &
335                  &                                        / (  e1e2t(ji,jj) * e3t(ji,jj,jk,Kmm)  )
336            END_2D
337            !
338         END DO
339         !
340         !                                !==  add the vertical 33 flux  ==!
341         IF( ln_traldf_lap ) THEN               ! laplacian case: eddy coef = ah_wslp2 - akz
342            DO_3D_10_00( 2, jpkm1 )
343               ztfw(ji,jj,jk) = ztfw(ji,jj,jk) - e1e2t(ji,jj) / e3w(ji,jj,jk,Kmm) * tmask(ji,jj,jk)   &
344                  &                            * ( ah_wslp2(ji,jj,jk) - akz(ji,jj,jk) )             &
345                  &                            * (  pt(ji,jj,jk-1,jn) - pt(ji,jj,jk,jn) )
346            END_3D
347         ELSE                                   ! bilaplacian
348            SELECT CASE( kpass )
349            CASE(  1  )                            ! 1st pass : eddy coef = ah_wslp2
350               DO_3D_10_00( 2, jpkm1 )
351                  ztfw(ji,jj,jk) = ztfw(ji,jj,jk) - e1e2t(ji,jj) / e3w(ji,jj,jk,Kmm) * tmask(ji,jj,jk)             &
352                     &                            * ah_wslp2(ji,jj,jk) * ( pt(ji,jj,jk-1,jn) - pt(ji,jj,jk,jn) )
353               END_3D
354            CASE(  2  )                            ! 2nd pass : eddy flux = ah_wslp2 and akz applied on pt  and pt2 gradients, resp.
355               DO_3D_10_00( 2, jpkm1 )
356                  ztfw(ji,jj,jk) = ztfw(ji,jj,jk) - e1e2t(ji,jj) / e3w(ji,jj,jk,Kmm) * tmask(ji,jj,jk)                      &
357                     &                            * (  ah_wslp2(ji,jj,jk) * ( pt (ji,jj,jk-1,jn) - pt (ji,jj,jk,jn) )   &
358                     &                               + akz     (ji,jj,jk) * ( pt2(ji,jj,jk-1,jn) - pt2(ji,jj,jk,jn) )   )
359               END_3D
360            END SELECT
361         ENDIF
362         !
363         DO_3D_00_00( 1, jpkm1 )
364            pt_rhs(ji,jj,jk,jn) = pt_rhs(ji,jj,jk,jn)    &
365            &                                  + zsign * (  ztfw(ji,jj,jk+1) - ztfw(ji,jj,jk)  )   &
366               &                                              / ( e1e2t(ji,jj) * e3t(ji,jj,jk,Kmm) )
367         END_3D
368         !
369         IF( ( kpass == 1 .AND. ln_traldf_lap ) .OR.  &     !==  first pass only (  laplacian)  ==!
370             ( kpass == 2 .AND. ln_traldf_blp ) ) THEN      !==  2nd   pass      (bilaplacian)  ==!
371            !
372            !                          ! "Poleward" diffusive heat or salt transports (T-S case only)
373            IF( l_ptr )  CALL dia_ptr_hst( jn, 'ldf', zftv(:,:,:)  )
374            !                          ! Diffusive heat transports
375            IF( l_hst )  CALL dia_ar5_hst( jn, 'ldf', zftu(:,:,:), zftv(:,:,:) )
376            !
377         ENDIF                                                    !== end pass selection  ==!
378         !
379         !                                                        ! ===============
380      END DO                                                      ! end tracer loop
381      !                                                           ! ===============
382   END SUBROUTINE tra_ldf_triad
383
384   !!==============================================================================
385END MODULE traldf_triad
Note: See TracBrowser for help on using the repository browser.