source: NEMO/trunk/src/OCE/TRA/trazdf.F90 @ 14010

Last change on this file since 14010 was 14010, checked in by gsamson, 5 months ago

merge dev_r2052_ENHANCE-09_rbourdal_massfluxconvection into trunk

  • Property svn:keywords set to Id
File size: 13.8 KB
Line 
1MODULE trazdf
2   !!==============================================================================
3   !!                 ***  MODULE  trazdf  ***
4   !! Ocean active tracers:  vertical component of the tracer mixing trend
5   !!==============================================================================
6   !! History :  1.0  !  2005-11  (G. Madec)  Original code
7   !!            3.0  !  2008-01  (C. Ethe, G. Madec)  merge TRC-TRA
8   !!            4.0  !  2017-06  (G. Madec)  remove explict time-stepping option
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   tra_zdf       : Update the tracer trend with the vertical diffusion
13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers variables
15   USE dom_oce        ! ocean space and time domain variables
16   USE domvvl         ! variable volume
17   USE phycst         ! physical constant
18   USE zdf_oce        ! ocean vertical physics variables
19   USE zdfmfc         ! Mass FLux Convection
20   USE sbc_oce        ! surface boundary condition: ocean
21   USE ldftra         ! lateral diffusion: eddy diffusivity
22   USE ldfslp         ! lateral diffusion: iso-neutral slope
23   USE trd_oce        ! trends: ocean variables
24   USE trdtra         ! trends: tracer trend manager
25   !
26   USE in_out_manager ! I/O manager
27   USE prtctl         ! Print control
28   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
29   USE lib_mpp        ! MPP library
30   USE timing         ! Timing
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   tra_zdf       ! called by step.F90
36   PUBLIC   tra_zdf_imp   ! called by trczdf.F90
37
38   !! * Substitutions
39#  include "do_loop_substitute.h90"
40#  include "domzgr_substitute.h90"
41   !!----------------------------------------------------------------------
42   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
43   !! $Id$
44   !! Software governed by the CeCILL license (see ./LICENSE)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   SUBROUTINE tra_zdf( kt, Kbb, Kmm, Krhs, pts, Kaa )
49      !!----------------------------------------------------------------------
50      !!                  ***  ROUTINE tra_zdf  ***
51      !!
52      !! ** Purpose :   compute the vertical ocean tracer physics.
53      !!---------------------------------------------------------------------
54      INTEGER                                  , INTENT(in)    :: kt                  ! ocean time-step index
55      INTEGER                                  , INTENT(in)    :: Kbb, Kmm, Krhs, Kaa ! time level indices
56      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts,jpt), INTENT(inout) :: pts                 ! active tracers and RHS of tracer equation
57      !
58      INTEGER  ::   ji, jj, jk   ! Dummy loop indices
59      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrdt, ztrds   ! 3D workspace
60      !!---------------------------------------------------------------------
61      !
62      IF( ln_timing )   CALL timing_start('tra_zdf')
63      !
64      IF( kt == nit000 )  THEN
65         IF( ntile == 0 .OR. ntile == 1 )  THEN                   ! Do only on the first tile
66            IF(lwp)WRITE(numout,*)
67            IF(lwp)WRITE(numout,*) 'tra_zdf : implicit vertical mixing on T & S'
68            IF(lwp)WRITE(numout,*) '~~~~~~~ '
69         ENDIF
70      ENDIF
71      !
72      IF( l_trdtra )   THEN                  !* Save ta and sa trends
73         ALLOCATE( ztrdt(jpi,jpj,jpk), ztrds(jpi,jpj,jpk) )
74         ztrdt(:,:,:) = pts(:,:,:,jp_tem,Kaa)
75         ztrds(:,:,:) = pts(:,:,:,jp_sal,Kaa)
76      ENDIF
77      !
78      !                                      !* compute lateral mixing trend and add it to the general trend
79      CALL tra_zdf_imp( kt, nit000, 'TRA', rDt, Kbb, Kmm, Krhs, pts, Kaa, jpts ) 
80
81!!gm WHY here !   and I don't like that !
82      ! DRAKKAR SSS control {
83      ! JMM avoid negative salinities near river outlet ! Ugly fix
84      ! JMM : restore negative salinities to small salinities:
85      WHERE( pts(A2D(0),:,jp_sal,Kaa) < 0._wp )   pts(A2D(0),:,jp_sal,Kaa) = 0.1_wp
86!!gm
87
88      IF( l_trdtra )   THEN                      ! save the vertical diffusive trends for further diagnostics
89         DO jk = 1, jpk
90            ztrdt(:,:,jk) = (   (  pts(:,:,jk,jp_tem,Kaa)*e3t(:,:,jk,Kaa)     &
91               &                 - pts(:,:,jk,jp_tem,Kbb)*e3t(:,:,jk,Kbb)  )  &
92               &              / (  e3t(:,:,jk,Kmm)*rDt  )   )                 &
93               &          - ztrdt(:,:,jk)
94            ztrds(:,:,jk) = (   (  pts(:,:,jk,jp_sal,Kaa)*e3t(:,:,jk,Kaa)     &
95               &                 - pts(:,:,jk,jp_sal,Kbb)*e3t(:,:,jk,Kbb)  )  &
96               &             / (   e3t(:,:,jk,Kmm)*rDt  )   )                 &
97               &          - ztrds(:,:,jk)
98         END DO
99         ! NOTE: [tiling-comms-merge] The diagnostic results change along the north fold if this is removed
100!!gm this should be moved in trdtra.F90 and done on all trends
101         CALL lbc_lnk_multi( 'trazdf', ztrdt, 'T', 1.0_wp , ztrds, 'T', 1.0_wp )
102!!gm
103         CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_tem, jptra_zdf, ztrdt )
104         CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_sal, jptra_zdf, ztrds )
105         DEALLOCATE( ztrdt , ztrds )
106      ENDIF
107      !                                          ! print mean trends (used for debugging)
108      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=pts(:,:,:,jp_tem,Kaa), clinfo1=' zdf  - Ta: ', mask1=tmask,               &
109         &                                  tab3d_2=pts(:,:,:,jp_sal,Kaa), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
110      !
111      IF( ln_timing )   CALL timing_stop('tra_zdf')
112      !
113   END SUBROUTINE tra_zdf
114
115 
116   SUBROUTINE tra_zdf_imp( kt, kit000, cdtype, p2dt, Kbb, Kmm, Krhs, pt, Kaa, kjpt ) 
117      !!----------------------------------------------------------------------
118      !!                  ***  ROUTINE tra_zdf_imp  ***
119      !!
120      !! ** Purpose :   Compute the after tracer through a implicit computation
121      !!     of the vertical tracer diffusion (including the vertical component
122      !!     of lateral mixing (only for 2nd order operator, for fourth order
123      !!     it is already computed and add to the general trend in traldf)
124      !!
125      !! ** Method  :  The vertical diffusion of a tracer ,t , is given by:
126      !!          difft = dz( avt dz(t) ) = 1/e3t dk+1( avt/e3w dk(t) )
127      !!      It is computed using a backward time scheme (t=after field)
128      !!      which provide directly the after tracer field.
129      !!      If ln_zdfddm=T, use avs for salinity or for passive tracers
130      !!      Surface and bottom boundary conditions: no diffusive flux on
131      !!      both tracers (bottom, applied through the masked field avt).
132      !!      If iso-neutral mixing, add to avt the contribution due to lateral mixing.
133      !!
134      !! ** Action  : - pt(:,:,:,:,Kaa)  becomes the after tracer
135      !!---------------------------------------------------------------------
136      INTEGER                                  , INTENT(in   ) ::   kt       ! ocean time-step index
137      INTEGER                                  , INTENT(in   ) ::   Kbb, Kmm, Krhs, Kaa  ! ocean time level indices
138      INTEGER                                  , INTENT(in   ) ::   kit000   ! first time step index
139      CHARACTER(len=3)                         , INTENT(in   ) ::   cdtype   ! =TRA or TRC (tracer indicator)
140      INTEGER                                  , INTENT(in   ) ::   kjpt     ! number of tracers
141      REAL(wp)                                 , INTENT(in   ) ::   p2dt     ! tracer time-step
142      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::   pt       ! tracers and RHS of tracer equation
143      !
144      INTEGER  ::  ji, jj, jk, jn   ! dummy loop indices
145      REAL(wp) ::  zrhs, zzwi, zzws ! local scalars
146      REAL(wp), DIMENSION(A2D(nn_hls),jpk) ::  zwi, zwt, zwd, zws
147      !!---------------------------------------------------------------------
148      !
149      !                                               ! ============= !
150      DO jn = 1, kjpt                                 !  tracer loop  !
151         !                                            ! ============= !
152         !  Matrix construction
153         ! --------------------
154         ! Build matrix if temperature or salinity (only in double diffusion case) or first passive tracer
155         !
156         IF(  ( cdtype == 'TRA' .AND. ( jn == jp_tem .OR. ( jn == jp_sal .AND. ln_zdfddm ) ) ) .OR.   &
157            & ( cdtype == 'TRC' .AND. jn == 1 )  )  THEN
158            !
159            ! vertical mixing coef.: avt for temperature, avs for salinity and passive tracers
160            IF( cdtype == 'TRA' .AND. jn == jp_tem ) THEN
161               DO_3D( 1, 1, 1, 1, 2, jpk )
162                  zwt(ji,jj,jk) = avt(ji,jj,jk)
163               END_3D
164            ELSE
165               DO_3D( 1, 1, 1, 1, 2, jpk )
166                  zwt(ji,jj,jk) = avs(ji,jj,jk)
167               END_3D
168            ENDIF
169            zwt(:,:,1) = 0._wp
170            !
171            IF( l_ldfslp ) THEN            ! isoneutral diffusion: add the contribution
172               IF( ln_traldf_msc  ) THEN     ! MSC iso-neutral operator
173                  DO_3D( 0, 0, 0, 0, 2, jpkm1 )
174                     zwt(ji,jj,jk) = zwt(ji,jj,jk) + akz(ji,jj,jk) 
175                  END_3D
176               ELSE                          ! standard or triad iso-neutral operator
177                  DO_3D( 0, 0, 0, 0, 2, jpkm1 )
178                     zwt(ji,jj,jk) = zwt(ji,jj,jk) + ah_wslp2(ji,jj,jk)
179                  END_3D
180               ENDIF
181            ENDIF
182            !
183            ! Diagonal, lower (i), upper (s)  (including the bottom boundary condition since avt is masked)
184            IF( ln_zad_Aimp ) THEN         ! Adaptive implicit vertical advection
185               DO_3D( 0, 0, 0, 0, 1, jpkm1 )
186                  zzwi = - p2dt * zwt(ji,jj,jk  ) / e3w(ji,jj,jk  ,Kmm)
187                  zzws = - p2dt * zwt(ji,jj,jk+1) / e3w(ji,jj,jk+1,Kmm)
188                  zwd(ji,jj,jk) = e3t(ji,jj,jk,Kaa) - zzwi - zzws   &
189                     &                 + p2dt * ( MAX( wi(ji,jj,jk  ) , 0._wp ) - MIN( wi(ji,jj,jk+1) , 0._wp ) )
190                  zwi(ji,jj,jk) = zzwi + p2dt *   MIN( wi(ji,jj,jk  ) , 0._wp )
191                  zws(ji,jj,jk) = zzws - p2dt *   MAX( wi(ji,jj,jk+1) , 0._wp )
192               END_3D
193            ELSE
194               DO_3D( 0, 0, 0, 0, 1, jpkm1 )
195                  zwi(ji,jj,jk) = - p2dt * zwt(ji,jj,jk  ) / e3w(ji,jj,jk,Kmm)
196                  zws(ji,jj,jk) = - p2dt * zwt(ji,jj,jk+1) / e3w(ji,jj,jk+1,Kmm)
197                  zwd(ji,jj,jk) = e3t(ji,jj,jk,Kaa) - zwi(ji,jj,jk) - zws(ji,jj,jk)
198               END_3D
199            ENDIF
200            !
201            ! Modification of diagonal to add MF scheme
202            IF ( ln_zdfmfc ) THEN
203               CALL diag_mfc( zwi, zwd, zws, p2dt, Kaa )
204            END IF
205            !
206            !! Matrix inversion from the first level
207            !!----------------------------------------------------------------------
208            !   solve m.x = y  where m is a tri diagonal matrix ( jpk*jpk )
209            !
210            !        ( zwd1 zws1   0    0    0  )( zwx1 ) ( zwy1 )
211            !        ( zwi2 zwd2 zws2   0    0  )( zwx2 ) ( zwy2 )
212            !        (  0   zwi3 zwd3 zws3   0  )( zwx3 )=( zwy3 )
213            !        (        ...               )( ...  ) ( ...  )
214            !        (  0    0    0   zwik zwdk )( zwxk ) ( zwyk )
215            !
216            !   m is decomposed in the product of an upper and lower triangular matrix.
217            !   The 3 diagonal terms are in 3d arrays: zwd, zws, zwi.
218            !   Suffices i,s and d indicate "inferior" (below diagonal), diagonal
219            !   and "superior" (above diagonal) components of the tridiagonal system.
220            !   The solution will be in the 4d array pta.
221            !   The 3d array zwt is used as a work space array.
222            !   En route to the solution pt(:,:,:,:,Kaa) is used a to evaluate the rhs and then
223            !   used as a work space array: its value is modified.
224            !
225            DO_2D( 0, 0, 0, 0 )      !* 1st recurrence:   Tk = Dk - Ik Sk-1 / Tk-1   (increasing k) ! done one for all passive tracers (so included in the IF instruction)
226               zwt(ji,jj,1) = zwd(ji,jj,1)
227            END_2D
228            DO_3D( 0, 0, 0, 0, 2, jpkm1 )
229               zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) / zwt(ji,jj,jk-1)
230            END_3D
231            !
232         ENDIF 
233         !         
234         ! Modification of rhs to add MF scheme
235         IF ( ln_zdfmfc ) THEN
236            CALL rhs_mfc( pt(:,:,:,jn,Krhs), jn )
237         END IF
238         !
239         DO_2D( 0, 0, 0, 0 )         !* 2nd recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
240            pt(ji,jj,1,jn,Kaa) =        e3t(ji,jj,1,Kbb) * pt(ji,jj,1,jn,Kbb)    &
241               &               + p2dt * e3t(ji,jj,1,Kmm) * pt(ji,jj,1,jn,Krhs) 
242         END_2D
243         DO_3D( 0, 0, 0, 0, 2, jpkm1 )
244            zrhs =        e3t(ji,jj,jk,Kbb) * pt(ji,jj,jk,jn,Kbb)    &
245               & + p2dt * e3t(ji,jj,jk,Kmm) * pt(ji,jj,jk,jn,Krhs)   ! zrhs=right hand side
246            pt(ji,jj,jk,jn,Kaa) = zrhs - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) * pt(ji,jj,jk-1,jn,Kaa)
247         END_3D
248         !
249         DO_2D( 0, 0, 0, 0 )         !* 3d recurrence:    Xk = (Zk - Sk Xk+1 ) / Tk   (result is the after tracer)
250            pt(ji,jj,jpkm1,jn,Kaa) = pt(ji,jj,jpkm1,jn,Kaa) / zwt(ji,jj,jpkm1) * tmask(ji,jj,jpkm1)
251         END_2D
252         DO_3DS( 0, 0, 0, 0, jpk-2, 1, -1 )
253            pt(ji,jj,jk,jn,Kaa) = ( pt(ji,jj,jk,jn,Kaa) - zws(ji,jj,jk) * pt(ji,jj,jk+1,jn,Kaa) )   &
254               &             / zwt(ji,jj,jk) * tmask(ji,jj,jk)
255         END_3D
256         !                                            ! ================= !
257      END DO                                          !  end tracer loop  !
258      !                                               ! ================= !
259   END SUBROUTINE tra_zdf_imp
260
261   !!==============================================================================
262END MODULE trazdf
Note: See TracBrowser for help on using the repository browser.