source: NEMO/trunk/src/OCE/ZDF/zdfiwm.F90 @ 13295

Last change on this file since 13295 was 13295, checked in by acc, 8 months ago

Replace do-loop macros in the trunk with alternative forms with greater flexibility for extra halo applications. This alters a lot of routines but does not change any behaviour or results. do_loop_substitute.h90 is greatly simplified by this change. SETTE results are identical to those with the previous revision

  • Property svn:keywords set to Id
File size: 28.0 KB
Line 
1MODULE zdfiwm
2   !!========================================================================
3   !!                       ***  MODULE  zdfiwm  ***
4   !! Ocean physics: Internal gravity wave-driven vertical mixing
5   !!========================================================================
6   !! History :  1.0  !  2004-04  (L. Bessieres, G. Madec)  Original code
7   !!             -   !  2006-08  (A. Koch-Larrouy)  Indonesian strait
8   !!            3.3  !  2010-10  (C. Ethe, G. Madec)  reorganisation of initialisation phase
9   !!            3.6  !  2016-03  (C. de Lavergne)  New param: internal wave-driven mixing
10   !!            4.0  !  2017-04  (G. Madec)  renamed module, remove the old param. and the CPP keys
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   zdf_iwm       : global     momentum & tracer Kz with wave induced Kz
15   !!   zdf_iwm_init  : global     momentum & tracer Kz with wave induced Kz
16   !!----------------------------------------------------------------------
17   USE oce            ! ocean dynamics and tracers variables
18   USE dom_oce        ! ocean space and time domain variables
19   USE zdf_oce        ! ocean vertical physics variables
20   USE zdfddm         ! ocean vertical physics: double diffusive mixing
21   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
22   USE eosbn2         ! ocean equation of state
23   USE phycst         ! physical constants
24   !
25   USE fldread        ! field read
26   USE prtctl         ! Print control
27   USE in_out_manager ! I/O manager
28   USE iom            ! I/O Manager
29   USE lib_mpp        ! MPP library
30   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   zdf_iwm        ! called in step module
36   PUBLIC   zdf_iwm_init   ! called in nemogcm module
37
38   !                      !!* Namelist  namzdf_iwm : internal wave-driven mixing *
39   INTEGER ::  nn_zpyc     ! pycnocline-intensified mixing energy proportional to N (=1) or N^2 (=2)
40   LOGICAL ::  ln_mevar    ! variable (=T) or constant (=F) mixing efficiency
41   LOGICAL ::  ln_tsdiff   ! account for differential T/S wave-driven mixing (=T) or not (=F)
42
43   REAL(wp)::  r1_6 = 1._wp / 6._wp
44
45   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   ebot_iwm   ! power available from high-mode wave breaking (W/m2)
46   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   epyc_iwm   ! power available from low-mode, pycnocline-intensified wave breaking (W/m2)
47   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   ecri_iwm   ! power available from low-mode, critical slope wave breaking (W/m2)
48   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   hbot_iwm   ! WKB decay scale for high-mode energy dissipation (m)
49   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   hcri_iwm   ! decay scale for low-mode critical slope dissipation (m)
50
51   !! * Substitutions
52#  include "do_loop_substitute.h90"
53#  include "domzgr_substitute.h90"
54   !!----------------------------------------------------------------------
55   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
56   !! $Id$
57   !! Software governed by the CeCILL license (see ./LICENSE)
58   !!----------------------------------------------------------------------
59CONTAINS
60
61   INTEGER FUNCTION zdf_iwm_alloc()
62      !!----------------------------------------------------------------------
63      !!                ***  FUNCTION zdf_iwm_alloc  ***
64      !!----------------------------------------------------------------------
65      ALLOCATE( ebot_iwm(jpi,jpj),  epyc_iwm(jpi,jpj),  ecri_iwm(jpi,jpj) ,     &
66      &         hbot_iwm(jpi,jpj),  hcri_iwm(jpi,jpj)                     , STAT=zdf_iwm_alloc )
67      !
68      CALL mpp_sum ( 'zdfiwm', zdf_iwm_alloc )
69      IF( zdf_iwm_alloc /= 0 )   CALL ctl_stop( 'STOP', 'zdf_iwm_alloc: failed to allocate arrays' )
70   END FUNCTION zdf_iwm_alloc
71
72
73   SUBROUTINE zdf_iwm( kt, Kmm, p_avm, p_avt, p_avs )
74      !!----------------------------------------------------------------------
75      !!                  ***  ROUTINE zdf_iwm  ***
76      !!                   
77      !! ** Purpose :   add to the vertical mixing coefficients the effect of
78      !!              breaking internal waves.
79      !!
80      !! ** Method  : - internal wave-driven vertical mixing is given by:
81      !!                  Kz_wave = min(  100 cm2/s, f(  Reb = zemx_iwm /( Nu * N^2 )  )
82      !!              where zemx_iwm is the 3D space distribution of the wave-breaking
83      !!              energy and Nu the molecular kinematic viscosity.
84      !!              The function f(Reb) is linear (constant mixing efficiency)
85      !!              if the namelist parameter ln_mevar = F and nonlinear if ln_mevar = T.
86      !!
87      !!              - Compute zemx_iwm, the 3D power density that allows to compute
88      !!              Reb and therefrom the wave-induced vertical diffusivity.
89      !!              This is divided into three components:
90      !!                 1. Bottom-intensified low-mode dissipation at critical slopes
91      !!                     zemx_iwm(z) = ( ecri_iwm / rho0 ) * EXP( -(H-z)/hcri_iwm )
92      !!                                   / ( 1. - EXP( - H/hcri_iwm ) ) * hcri_iwm
93      !!              where hcri_iwm is the characteristic length scale of the bottom
94      !!              intensification, ecri_iwm a map of available power, and H the ocean depth.
95      !!                 2. Pycnocline-intensified low-mode dissipation
96      !!                     zemx_iwm(z) = ( epyc_iwm / rho0 ) * ( sqrt(rn2(z))^nn_zpyc )
97      !!                                   / SUM( sqrt(rn2(z))^nn_zpyc * e3w[z) )
98      !!              where epyc_iwm is a map of available power, and nn_zpyc
99      !!              is the chosen stratification-dependence of the internal wave
100      !!              energy dissipation.
101      !!                 3. WKB-height dependent high mode dissipation
102      !!                     zemx_iwm(z) = ( ebot_iwm / rho0 ) * rn2(z) * EXP(-z_wkb(z)/hbot_iwm)
103      !!                                   / SUM( rn2(z) * EXP(-z_wkb(z)/hbot_iwm) * e3w[z) )
104      !!              where hbot_iwm is the characteristic length scale of the WKB bottom
105      !!              intensification, ebot_iwm is a map of available power, and z_wkb is the
106      !!              WKB-stretched height above bottom defined as
107      !!                    z_wkb(z) = H * SUM( sqrt(rn2(z'>=z)) * e3w[z'>=z) )
108      !!                                 / SUM( sqrt(rn2(z'))    * e3w[z')    )
109      !!
110      !!              - update the model vertical eddy viscosity and diffusivity:
111      !!                     avt  = avt  +    av_wave
112      !!                     avm  = avm  +    av_wave
113      !!
114      !!              - if namelist parameter ln_tsdiff = T, account for differential mixing:
115      !!                     avs  = avt  +    av_wave * diffusivity_ratio(Reb)
116      !!
117      !! ** Action  : - avt, avs, avm, increased by tide internal wave-driven mixing   
118      !!
119      !! References :  de Lavergne et al. 2015, JPO; 2016, in prep.
120      !!----------------------------------------------------------------------
121      INTEGER                    , INTENT(in   ) ::   kt             ! ocean time step
122      INTEGER                    , INTENT(in   ) ::   Kmm            ! time level index
123      REAL(wp), DIMENSION(:,:,:) , INTENT(inout) ::   p_avm          ! momentum Kz (w-points)
124      REAL(wp), DIMENSION(:,:,:) , INTENT(inout) ::   p_avt, p_avs   ! tracer   Kz (w-points)
125      !
126      INTEGER  ::   ji, jj, jk   ! dummy loop indices
127      REAL(wp) ::   zztmp, ztmp1, ztmp2        ! scalar workspace
128      REAL(wp), DIMENSION(jpi,jpj)     ::   zfact       ! Used for vertical structure
129      REAL(wp), DIMENSION(jpi,jpj)     ::   zhdep       ! Ocean depth
130      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zwkb        ! WKB-stretched height above bottom
131      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zweight     ! Weight for high mode vertical distribution
132      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   znu_t       ! Molecular kinematic viscosity (T grid)
133      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   znu_w       ! Molecular kinematic viscosity (W grid)
134      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zReb        ! Turbulence intensity parameter
135      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zemx_iwm    ! local energy density available for mixing (W/kg)
136      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zav_ratio   ! S/T diffusivity ratio (only for ln_tsdiff=T)
137      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zav_wave    ! Internal wave-induced diffusivity
138      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   z3d  ! 3D workspace used for iom_put
139      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::   z2d  ! 2D     -      -    -     -
140      !!----------------------------------------------------------------------
141      !
142      !                       
143      ! Set to zero the 1st and last vertical levels of appropriate variables
144      IF( iom_use("emix_iwm") ) THEN
145         DO_2D( 0, 0, 0, 0 )
146            zemx_iwm (ji,jj,1) = 0._wp   ;   zemx_iwm (ji,jj,jpk) = 0._wp
147         END_2D
148         zemx_iwm (           1:nn_hls,:,:) = 0._wp   ;   zemx_iwm (:,           1:nn_hls,:) = 0._wp
149         zemx_iwm (jpi-nn_hls+1:jpi   ,:,:) = 0._wp   ;   zemx_iwm (:,jpj-nn_hls+1:   jpj,:) = 0._wp
150      ENDIF
151      IF( iom_use("av_ratio") ) THEN
152         DO_2D( 0, 0, 0, 0 )
153            zav_ratio(ji,jj,1) = 0._wp   ;   zav_ratio(ji,jj,jpk) = 0._wp
154         END_2D
155         zav_ratio(           1:nn_hls,:,:) = 0._wp   ;   zav_ratio(:,           1:nn_hls,:) = 0._wp
156         zav_ratio(jpi-nn_hls+1:jpi   ,:,:) = 0._wp   ;   zav_ratio(:,jpj-nn_hls+1:   jpj,:) = 0._wp
157      ENDIF
158      IF( iom_use("av_wave") ) THEN
159         DO_2D( 0, 0, 0, 0 )
160            zav_wave (ji,jj,1) = 0._wp   ;   zav_wave (ji,jj,jpk) = 0._wp
161         END_2D
162         zav_wave(           1:nn_hls,:,:) = 0._wp   ;   zav_wave(:,           1:nn_hls,:) = 0._wp
163         zav_wave(jpi-nn_hls+1:jpi   ,:,:) = 0._wp   ;   zav_wave(:,jpj-nn_hls+1:   jpj,:) = 0._wp
164      ENDIF
165      !
166      !                       ! ----------------------------- !
167      !                       !  Internal wave-driven mixing  !  (compute zav_wave)
168      !                       ! ----------------------------- !
169      !                             
170      !                       !* Critical slope mixing: distribute energy over the time-varying ocean depth,
171      !                                                 using an exponential decay from the seafloor.
172      DO_2D( 0, 0, 0, 0 )
173         zhdep(ji,jj) = gdepw_0(ji,jj,mbkt(ji,jj)+1)       ! depth of the ocean
174         zfact(ji,jj) = rho0 * (  1._wp - EXP( -zhdep(ji,jj) / hcri_iwm(ji,jj) )  )
175         IF( zfact(ji,jj) /= 0._wp )   zfact(ji,jj) = ecri_iwm(ji,jj) / zfact(ji,jj)
176      END_2D
177!!gm gde3w ==>>>  check for ssh taken into account.... seem OK gde3w_n=gdept(:,:,:,Kmm) - ssh(:,:,Kmm)
178      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
179         IF ( zfact(ji,jj) == 0._wp .OR. wmask(ji,jj,jk) == 0._wp ) THEN   ! optimization
180            zemx_iwm(ji,jj,jk) = 0._wp
181         ELSE
182            zemx_iwm(ji,jj,jk) = zfact(ji,jj) * (  EXP( ( gde3w(ji,jj,jk  ) - zhdep(ji,jj) ) / hcri_iwm(ji,jj) )     &
183                 &                               - EXP( ( gde3w(ji,jj,jk-1) - zhdep(ji,jj) ) / hcri_iwm(ji,jj) ) )   &
184                 &                            / ( gde3w(ji,jj,jk) - gde3w(ji,jj,jk-1) )
185         ENDIF
186      END_3D
187!!gm delta(gde3w) = e3t(:,:,:,Kmm)  !!  Please verify the grid-point position w versus t-point
188!!gm it seems to me that only 1/hcri_iwm  is used ==>  compute it one for all
189
190
191      !                        !* Pycnocline-intensified mixing: distribute energy over the time-varying
192      !                        !* ocean depth as proportional to sqrt(rn2)^nn_zpyc
193      !                                          ! (NB: N2 is masked, so no use of wmask here)
194      SELECT CASE ( nn_zpyc )
195      !
196      CASE ( 1 )               ! Dissipation scales as N (recommended)
197         !
198         DO_2D( 0, 0, 0, 0 )
199            zfact(ji,jj) = 0._wp
200         END_2D
201         DO_3D( 0, 0, 0, 0, 2, jpkm1 )       ! part independent of the level
202            zfact(ji,jj) = zfact(ji,jj) + e3w(ji,jj,jk,Kmm) * SQRT(  MAX( 0._wp, rn2(ji,jj,jk) )  ) * wmask(ji,jj,jk)
203         END_3D
204         !
205         DO_2D( 0, 0, 0, 0 )
206            IF( zfact(ji,jj) /= 0 )   zfact(ji,jj) = epyc_iwm(ji,jj) / ( rho0 * zfact(ji,jj) )
207         END_2D
208         !
209         DO_3D( 0, 0, 0, 0, 2, jpkm1 )       ! complete with the level-dependent part
210            zemx_iwm(ji,jj,jk) = zemx_iwm(ji,jj,jk) + zfact(ji,jj) * SQRT(  MAX( 0._wp, rn2(ji,jj,jk) )  ) * wmask(ji,jj,jk)
211         END_3D
212         !
213      CASE ( 2 )               ! Dissipation scales as N^2
214         !
215         DO_2D( 0, 0, 0, 0 )
216            zfact(ji,jj) = 0._wp
217         END_2D
218         DO_3D( 0, 0, 0, 0, 2, jpkm1 )       ! part independent of the level
219            zfact(ji,jj) = zfact(ji,jj) + e3w(ji,jj,jk,Kmm) * MAX( 0._wp, rn2(ji,jj,jk) ) * wmask(ji,jj,jk)
220         END_3D
221         !
222         DO_2D( 0, 0, 0, 0 )
223            IF( zfact(ji,jj) /= 0 )   zfact(ji,jj) = epyc_iwm(ji,jj) / ( rho0 * zfact(ji,jj) )
224         END_2D
225         !
226         DO_3D( 0, 0, 0, 0, 2, jpkm1 )       ! complete with the level-dependent part
227            zemx_iwm(ji,jj,jk) = zemx_iwm(ji,jj,jk) + zfact(ji,jj) * MAX( 0._wp, rn2(ji,jj,jk) ) * wmask(ji,jj,jk)
228         END_3D
229         !
230      END SELECT
231
232      !                        !* WKB-height dependent mixing: distribute energy over the time-varying
233      !                        !* ocean depth as proportional to rn2 * exp(-z_wkb/rn_hbot)
234      !
235      DO_2D( 0, 0, 0, 0 )
236         zwkb(ji,jj,1) = 0._wp
237      END_2D
238      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
239         zwkb(ji,jj,jk) = zwkb(ji,jj,jk-1) + e3w(ji,jj,jk,Kmm) * SQRT(  MAX( 0._wp, rn2(ji,jj,jk) )  ) * wmask(ji,jj,jk)
240      END_3D
241      DO_2D( 0, 0, 0, 0 )
242         zfact(ji,jj) = zwkb(ji,jj,jpkm1)
243      END_2D
244      !
245      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
246         IF( zfact(ji,jj) /= 0 )   zwkb(ji,jj,jk) = zhdep(ji,jj) * ( zfact(ji,jj) - zwkb(ji,jj,jk) )   &
247            &                                     * wmask(ji,jj,jk) / zfact(ji,jj)
248      END_3D
249      DO_2D( 0, 0, 0, 0 )
250         zwkb (ji,jj,1) = zhdep(ji,jj) * wmask(ji,jj,1)
251      END_2D
252      !
253      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
254         IF ( rn2(ji,jj,jk) <= 0._wp .OR. wmask(ji,jj,jk) == 0._wp ) THEN   ! optimization: EXP coast a lot
255            zweight(ji,jj,jk) = 0._wp
256         ELSE
257            zweight(ji,jj,jk) = rn2(ji,jj,jk) * hbot_iwm(ji,jj)    &
258               &   * (  EXP( -zwkb(ji,jj,jk) / hbot_iwm(ji,jj) ) - EXP( -zwkb(ji,jj,jk-1) / hbot_iwm(ji,jj) )  )
259         ENDIF
260      END_3D
261      !
262      DO_2D( 0, 0, 0, 0 )
263         zfact(ji,jj) = 0._wp
264      END_2D
265      DO_3D( 0, 0, 0, 0, 2, jpkm1 )       ! part independent of the level
266         zfact(ji,jj) = zfact(ji,jj) + zweight(ji,jj,jk)
267      END_3D
268      !
269      DO_2D( 0, 0, 0, 0 )
270         IF( zfact(ji,jj) /= 0 )   zfact(ji,jj) = ebot_iwm(ji,jj) / ( rho0 * zfact(ji,jj) )
271      END_2D
272      !
273      DO_3D( 0, 0, 0, 0, 2, jpkm1 )       ! complete with the level-dependent part
274         zemx_iwm(ji,jj,jk) = zemx_iwm(ji,jj,jk) + zweight(ji,jj,jk) * zfact(ji,jj) * wmask(ji,jj,jk)   &
275            &                                                        / ( gde3w(ji,jj,jk) - gde3w(ji,jj,jk-1) )
276!!gm  use of e3t(ji,jj,:,Kmm) just above?
277      END_3D
278      !
279!!gm  this is to be replaced by just a constant value znu=1.e-6 m2/s
280      ! Calculate molecular kinematic viscosity
281      DO_3D( 0, 0, 0, 0, 1, jpkm1 )
282         znu_t(ji,jj,jk) = 1.e-4_wp * (  17.91_wp - 0.53810_wp * ts(ji,jj,jk,jp_tem,Kmm)   &
283            &                                     + 0.00694_wp * ts(ji,jj,jk,jp_tem,Kmm) * ts(ji,jj,jk,jp_tem,Kmm)  &
284            &                                     + 0.02305_wp * ts(ji,jj,jk,jp_sal,Kmm)  ) * tmask(ji,jj,jk) * r1_rho0
285      END_3D
286      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
287         znu_w(ji,jj,jk) = 0.5_wp * ( znu_t(ji,jj,jk-1) + znu_t(ji,jj,jk) ) * wmask(ji,jj,jk)
288      END_3D
289!!gm end
290      !
291      ! Calculate turbulence intensity parameter Reb
292      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
293         zReb(ji,jj,jk) = zemx_iwm(ji,jj,jk) / MAX( 1.e-20_wp, znu_w(ji,jj,jk) * rn2(ji,jj,jk) )
294      END_3D
295      !
296      ! Define internal wave-induced diffusivity
297      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
298         zav_wave(ji,jj,jk) = znu_w(ji,jj,jk) * zReb(ji,jj,jk) * r1_6   ! This corresponds to a constant mixing efficiency of 1/6
299      END_3D
300      !
301      IF( ln_mevar ) THEN              ! Variable mixing efficiency case : modify zav_wave in the
302         DO_3D( 0, 0, 0, 0, 2, jpkm1 )
303            IF( zReb(ji,jj,jk) > 480.00_wp ) THEN
304               zav_wave(ji,jj,jk) = 3.6515_wp * znu_w(ji,jj,jk) * SQRT( zReb(ji,jj,jk) )
305            ELSEIF( zReb(ji,jj,jk) < 10.224_wp ) THEN
306               zav_wave(ji,jj,jk) = 0.052125_wp * znu_w(ji,jj,jk) * zReb(ji,jj,jk) * SQRT( zReb(ji,jj,jk) )
307            ENDIF
308         END_3D
309      ENDIF
310      !
311      DO_3D( 0, 0, 0, 0, 2, jpkm1 )          ! Bound diffusivity by molecular value and 100 cm2/s
312         zav_wave(ji,jj,jk) = MIN(  MAX( 1.4e-7_wp, zav_wave(ji,jj,jk) ), 1.e-2_wp  ) * wmask(ji,jj,jk)
313      END_3D
314      !
315      IF( kt == nit000 ) THEN        !* Control print at first time-step: diagnose the energy consumed by zav_wave
316         zztmp = 0._wp
317!!gm used of glosum 3D....
318         DO_3D( 0, 0, 0, 0, 2, jpkm1 )
319            zztmp = zztmp + e3w(ji,jj,jk,Kmm) * e1e2t(ji,jj)   &
320               &          * MAX( 0._wp, rn2(ji,jj,jk) ) * zav_wave(ji,jj,jk) * wmask(ji,jj,jk) * tmask_i(ji,jj)
321         END_3D
322         CALL mpp_sum( 'zdfiwm', zztmp )
323         zztmp = rho0 * zztmp ! Global integral of rauo * Kz * N^2 = power contributing to mixing
324         !
325         IF(lwp) THEN
326            WRITE(numout,*)
327            WRITE(numout,*) 'zdf_iwm : Internal wave-driven mixing (iwm)'
328            WRITE(numout,*) '~~~~~~~ '
329            WRITE(numout,*)
330            WRITE(numout,*) '      Total power consumption by av_wave =  ', zztmp * 1.e-12_wp, 'TW'
331         ENDIF
332      ENDIF
333
334      !                          ! ----------------------- !
335      !                          !   Update  mixing coefs  !                         
336      !                          ! ----------------------- !
337      !     
338      IF( ln_tsdiff ) THEN          !* Option for differential mixing of salinity and temperature
339         ztmp1 = 0.505_wp + 0.495_wp * TANH( 0.92_wp * ( LOG10( 1.e-20_wp ) - 0.60_wp ) )
340         DO_3D( 0, 0, 0, 0, 2, jpkm1 )
341            ztmp2 = zReb(ji,jj,jk) * 5._wp * r1_6
342            IF ( ztmp2 > 1.e-20_wp .AND. wmask(ji,jj,jk) == 1._wp ) THEN
343               zav_ratio(ji,jj,jk) = 0.505_wp + 0.495_wp * TANH( 0.92_wp * ( LOG10(ztmp2) - 0.60_wp ) )
344            ELSE
345               zav_ratio(ji,jj,jk) = ztmp1 * wmask(ji,jj,jk)
346            ENDIF
347         END_3D
348         CALL iom_put( "av_ratio", zav_ratio )
349         DO_3D( 0, 0, 0, 0, 2, jpkm1 )    !* update momentum & tracer diffusivity with wave-driven mixing
350            p_avs(ji,jj,jk) = p_avs(ji,jj,jk) + zav_wave(ji,jj,jk) * zav_ratio(ji,jj,jk)
351            p_avt(ji,jj,jk) = p_avt(ji,jj,jk) + zav_wave(ji,jj,jk)
352            p_avm(ji,jj,jk) = p_avm(ji,jj,jk) + zav_wave(ji,jj,jk)
353         END_3D
354         !
355      ELSE                          !* update momentum & tracer diffusivity with wave-driven mixing
356         DO_3D( 0, 0, 0, 0, 2, jpkm1 )
357            p_avs(ji,jj,jk) = p_avs(ji,jj,jk) + zav_wave(ji,jj,jk)
358            p_avt(ji,jj,jk) = p_avt(ji,jj,jk) + zav_wave(ji,jj,jk)
359            p_avm(ji,jj,jk) = p_avm(ji,jj,jk) + zav_wave(ji,jj,jk)
360         END_3D
361      ENDIF
362
363      !                             !* output internal wave-driven mixing coefficient
364      CALL iom_put( "av_wave", zav_wave )
365                                    !* output useful diagnostics: Kz*N^2 ,
366!!gm Kz*N2 should take into account the ratio avs/avt if it is used.... (see diaar5)
367                                    !  vertical integral of rho0 * Kz * N^2 , energy density (zemx_iwm)
368      IF( iom_use("bflx_iwm") .OR. iom_use("pcmap_iwm") ) THEN
369         ALLOCATE( z2d(jpi,jpj) , z3d(jpi,jpj,jpk) )
370         ! Initialisation for iom_put
371         DO_2D( 0, 0, 0, 0 )
372            z3d(ji,jj,1) = 0._wp   ;   z3d(ji,jj,jpk) = 0._wp
373         END_2D
374         z3d(           1:nn_hls,:,:) = 0._wp   ;   z3d(:,           1:nn_hls,:) = 0._wp
375         z3d(jpi-nn_hls+1:jpi   ,:,:) = 0._wp   ;   z3d(:,jpj-nn_hls+1:   jpj,:) = 0._wp
376         z2d(           1:nn_hls,:  ) = 0._wp   ;   z2d(:,           1:nn_hls  ) = 0._wp
377         z2d(jpi-nn_hls+1:jpi   ,:  ) = 0._wp   ;   z2d(:,jpj-nn_hls+1:   jpj  ) = 0._wp
378
379         DO_3D( 0, 0, 0, 0, 2, jpkm1 )
380            z3d(ji,jj,jk) = MAX( 0._wp, rn2(ji,jj,jk) ) * zav_wave(ji,jj,jk)
381         END_3D
382         DO_2D( 0, 0, 0, 0 )
383            z2d(ji,jj) = 0._wp
384         END_2D
385         DO_3D( 0, 0, 0, 0, 2, jpkm1 ) 
386            z2d(ji,jj) = z2d(ji,jj) + e3w(ji,jj,jk,Kmm) * z3d(ji,jj,jk) * wmask(ji,jj,jk)
387         END_3D
388         DO_2D( 0, 0, 0, 0 )
389            z2d(ji,jj) = rho0 * z2d(ji,jj)
390         END_2D
391         CALL iom_put(  "bflx_iwm", z3d )
392         CALL iom_put( "pcmap_iwm", z2d )
393         DEALLOCATE( z2d , z3d )
394      ENDIF
395      CALL iom_put( "emix_iwm", zemx_iwm )
396     
397      IF(sn_cfctl%l_prtctl)   CALL prt_ctl(tab3d_1=zav_wave , clinfo1=' iwm - av_wave: ', tab3d_2=avt, clinfo2=' avt: ', kdim=jpk)
398      !
399   END SUBROUTINE zdf_iwm
400
401
402   SUBROUTINE zdf_iwm_init
403      !!----------------------------------------------------------------------
404      !!                  ***  ROUTINE zdf_iwm_init  ***
405      !!                     
406      !! ** Purpose :   Initialization of the wave-driven vertical mixing, reading
407      !!              of input power maps and decay length scales in netcdf files.
408      !!
409      !! ** Method  : - Read the namzdf_iwm namelist and check the parameters
410      !!
411      !!              - Read the input data in NetCDF files :
412      !!              power available from high-mode wave breaking (mixing_power_bot.nc)
413      !!              power available from pycnocline-intensified wave-breaking (mixing_power_pyc.nc)
414      !!              power available from critical slope wave-breaking (mixing_power_cri.nc)
415      !!              WKB decay scale for high-mode wave-breaking (decay_scale_bot.nc)
416      !!              decay scale for critical slope wave-breaking (decay_scale_cri.nc)
417      !!
418      !! ** input   : - Namlist namzdf_iwm
419      !!              - NetCDF files : mixing_power_bot.nc, mixing_power_pyc.nc, mixing_power_cri.nc,
420      !!              decay_scale_bot.nc decay_scale_cri.nc
421      !!
422      !! ** Action  : - Increase by 1 the nstop flag is setting problem encounter
423      !!              - Define ebot_iwm, epyc_iwm, ecri_iwm, hbot_iwm, hcri_iwm
424      !!
425      !! References : de Lavergne et al. JPO, 2015 ; de Lavergne PhD 2016
426      !!              de Lavergne et al. in prep., 2017
427      !!----------------------------------------------------------------------
428      INTEGER  ::   ifpr               ! dummy loop indices
429      INTEGER  ::   inum               ! local integer
430      INTEGER  ::   ios
431      REAL(wp) ::   zbot, zpyc, zcri   ! local scalars
432      !
433      CHARACTER(len=256)            ::   cn_dir                 ! Root directory for location of ssr files
434      INTEGER, PARAMETER            ::   jpiwm  = 5             ! maximum number of files to read
435      INTEGER, PARAMETER            ::   jp_mpb = 1
436      INTEGER, PARAMETER            ::   jp_mpp = 2
437      INTEGER, PARAMETER            ::   jp_mpc = 3
438      INTEGER, PARAMETER            ::   jp_dsb = 4
439      INTEGER, PARAMETER            ::   jp_dsc = 5
440      !
441      TYPE(FLD_N), DIMENSION(jpiwm) ::   slf_iwm                ! array of namelist informations
442      TYPE(FLD_N)                   ::   sn_mpb, sn_mpp, sn_mpc ! informations about Mixing Power field to be read
443      TYPE(FLD_N)                   ::   sn_dsb, sn_dsc         ! informations about Decay Scale field to be read
444      TYPE(FLD  ), DIMENSION(jpiwm) ::   sf_iwm                 ! structure of input fields (file informations, fields read)
445      !
446      NAMELIST/namzdf_iwm/ nn_zpyc, ln_mevar, ln_tsdiff, &
447         &                 cn_dir, sn_mpb, sn_mpp, sn_mpc, sn_dsb, sn_dsc
448      !!----------------------------------------------------------------------
449      !
450      READ  ( numnam_ref, namzdf_iwm, IOSTAT = ios, ERR = 901)
451901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namzdf_iwm in reference namelist' )
452      !
453      READ  ( numnam_cfg, namzdf_iwm, IOSTAT = ios, ERR = 902 )
454902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namzdf_iwm in configuration namelist' )
455      IF(lwm) WRITE ( numond, namzdf_iwm )
456      !
457      IF(lwp) THEN                  ! Control print
458         WRITE(numout,*)
459         WRITE(numout,*) 'zdf_iwm_init : internal wave-driven mixing'
460         WRITE(numout,*) '~~~~~~~~~~~~'
461         WRITE(numout,*) '   Namelist namzdf_iwm : set wave-driven mixing parameters'
462         WRITE(numout,*) '      Pycnocline-intensified diss. scales as N (=1) or N^2 (=2) = ', nn_zpyc
463         WRITE(numout,*) '      Variable (T) or constant (F) mixing efficiency            = ', ln_mevar
464         WRITE(numout,*) '      Differential internal wave-driven mixing (T) or not (F)   = ', ln_tsdiff
465      ENDIF
466     
467      ! The new wave-driven mixing parameterization elevates avt and avm in the interior, and
468      ! ensures that avt remains larger than its molecular value (=1.4e-7). Therefore, avtb should
469      ! be set here to a very small value, and avmb to its (uniform) molecular value (=1.4e-6).
470      avmb(:) = 1.4e-6_wp        ! viscous molecular value
471      avtb(:) = 1.e-10_wp        ! very small diffusive minimum (background avt is specified in zdf_iwm)   
472      avtb_2d(:,:) = 1.e0_wp     ! uniform
473      IF(lwp) THEN                  ! Control print
474         WRITE(numout,*)
475         WRITE(numout,*) '   Force the background value applied to avm & avt in TKE to be everywhere ',   &
476            &               'the viscous molecular value & a very small diffusive value, resp.'
477      ENDIF
478           
479      !                             ! allocate iwm arrays
480      IF( zdf_iwm_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'zdf_iwm_init : unable to allocate iwm arrays' )
481      !
482      ! store namelist information in an array
483      slf_iwm(jp_mpb) = sn_mpb ; slf_iwm(jp_mpp) = sn_mpp ; slf_iwm(jp_mpc) = sn_mpc
484      slf_iwm(jp_dsb) = sn_dsb ; slf_iwm(jp_dsc) = sn_dsc
485      !
486      DO ifpr= 1, jpiwm
487         ALLOCATE( sf_iwm(ifpr)%fnow(jpi,jpj,1)   )
488         IF( slf_iwm(ifpr)%ln_tint )ALLOCATE( sf_iwm(ifpr)%fdta(jpi,jpj,1,2) )
489      END DO
490
491      ! fill sf_iwm with sf_iwm and control print
492      CALL fld_fill( sf_iwm, slf_iwm , cn_dir, 'zdfiwm_init', 'iwm input file', 'namiwm' )
493
494      !                             ! hard-coded default definition (to be defined in namelist ?)
495      sf_iwm(jp_mpb)%fnow(:,:,1) = 1.e-6
496      sf_iwm(jp_mpp)%fnow(:,:,1) = 1.e-6
497      sf_iwm(jp_mpc)%fnow(:,:,1) = 1.e-10
498      sf_iwm(jp_dsb)%fnow(:,:,1) = 100.
499      sf_iwm(jp_dsc)%fnow(:,:,1) = 100.
500
501      !                             ! read necessary fields
502      CALL fld_read( nit000, 1, sf_iwm )
503
504      ebot_iwm(:,:) = sf_iwm(1)%fnow(:,:,1) * ssmask(:,:) ! energy flux for high-mode wave breaking [W/m2]
505      epyc_iwm(:,:) = sf_iwm(2)%fnow(:,:,1) * ssmask(:,:) ! energy flux for pynocline-intensified wave breaking [W/m2]
506      ecri_iwm(:,:) = sf_iwm(3)%fnow(:,:,1) * ssmask(:,:) ! energy flux for critical slope wave breaking [W/m2]
507      hbot_iwm(:,:) = sf_iwm(4)%fnow(:,:,1)               ! spatially variable decay scale for high-mode wave breaking [m]
508      hcri_iwm(:,:) = sf_iwm(5)%fnow(:,:,1)               ! spatially variable decay scale for critical slope wave breaking [m]
509
510      zbot = glob_sum( 'zdfiwm', e1e2t(:,:) * ebot_iwm(:,:) )
511      zpyc = glob_sum( 'zdfiwm', e1e2t(:,:) * epyc_iwm(:,:) )
512      zcri = glob_sum( 'zdfiwm', e1e2t(:,:) * ecri_iwm(:,:) )
513
514      IF(lwp) THEN
515         WRITE(numout,*) '      High-mode wave-breaking energy:             ', zbot * 1.e-12_wp, 'TW'
516         WRITE(numout,*) '      Pycnocline-intensifed wave-breaking energy: ', zpyc * 1.e-12_wp, 'TW'
517         WRITE(numout,*) '      Critical slope wave-breaking energy:        ', zcri * 1.e-12_wp, 'TW'
518      ENDIF
519      !
520   END SUBROUTINE zdf_iwm_init
521
522   !!======================================================================
523END MODULE zdfiwm
Note: See TracBrowser for help on using the repository browser.