source: NEMO/trunk/src/OCE/ZDF/zdfmxl.F90 @ 12489

Last change on this file since 12489 was 12489, checked in by davestorkey, 7 months ago

Preparation for new timestepping scheme #2390.
Main changes:

  1. Initial euler timestep now handled in stp and not in TRA/DYN routines.
  2. Renaming of all timestep parameters. In summary, the namelist parameter is now rn_Dt and the current timestep is rDt (and rDt_ice, rDt_trc etc).
  3. Renaming of a few miscellaneous parameters, eg. atfp → rn_atfp (namelist parameter used everywhere) and rau0 → rho0.

This version gives bit-comparable results to the previous version of the trunk.

  • Property svn:keywords set to Id
File size: 6.9 KB
Line 
1MODULE zdfmxl
2   !!======================================================================
3   !!                       ***  MODULE  zdfmxl  ***
4   !! Ocean physics: mixed layer depth
5   !!======================================================================
6   !! History :  1.0  ! 2003-08  (G. Madec)  original code
7   !!            3.2  ! 2009-07  (S. Masson, G. Madec)  IOM + merge of DO-loop
8   !!            3.7  ! 2012-03  (G. Madec)  make public the density criteria for trdmxl
9   !!             -   ! 2014-02  (F. Roquet)  mixed layer depth calculated using N2 instead of rhop
10   !!----------------------------------------------------------------------
11   !!   zdf_mxl      : Compute the turbocline and mixed layer depths.
12   !!----------------------------------------------------------------------
13   USE oce            ! ocean dynamics and tracers variables
14   USE isf_oce        ! ice shelf
15   USE dom_oce        ! ocean space and time domain variables
16   USE trc_oce  , ONLY: l_offline         ! ocean space and time domain variables
17   USE zdf_oce        ! ocean vertical physics
18   !
19   USE in_out_manager ! I/O manager
20   USE prtctl         ! Print control
21   USE phycst         ! physical constants
22   USE iom            ! I/O library
23   USE lib_mpp        ! MPP library
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   zdf_mxl   ! called by zdfphy.F90
29
30   INTEGER , PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   nmln    !: number of level in the mixed layer (used by LDF, ZDF, TRD, TOP)
31   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   hmld    !: mixing layer depth (turbocline)      [m]   (used by TOP)
32   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   hmlp    !: mixed layer depth  (rho=rho0+zdcrit) [m]   (used by LDF)
33   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   hmlpt   !: depth of the last T-point inside the mixed layer [m] (used by LDF)
34
35   REAL(wp), PUBLIC ::   rho_c = 0.01_wp    !: density criterion for mixed layer depth
36   REAL(wp), PUBLIC ::   avt_c = 5.e-4_wp   ! Kz criterion for the turbocline depth
37
38   !! * Substitutions
39#  include "do_loop_substitute.h90"
40   !!----------------------------------------------------------------------
41   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
42   !! $Id$
43   !! Software governed by the CeCILL license (see ./LICENSE)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   INTEGER FUNCTION zdf_mxl_alloc()
48      !!----------------------------------------------------------------------
49      !!               ***  FUNCTION zdf_mxl_alloc  ***
50      !!----------------------------------------------------------------------
51      zdf_mxl_alloc = 0      ! set to zero if no array to be allocated
52      IF( .NOT. ALLOCATED( nmln ) ) THEN
53         ALLOCATE( nmln(jpi,jpj), hmld(jpi,jpj), hmlp(jpi,jpj), hmlpt(jpi,jpj), STAT= zdf_mxl_alloc )
54         !
55         CALL mpp_sum ( 'zdfmxl', zdf_mxl_alloc )
56         IF( zdf_mxl_alloc /= 0 )   CALL ctl_stop( 'STOP', 'zdf_mxl_alloc: failed to allocate arrays.' )
57         !
58      ENDIF
59   END FUNCTION zdf_mxl_alloc
60
61
62   SUBROUTINE zdf_mxl( kt, Kmm )
63      !!----------------------------------------------------------------------
64      !!                  ***  ROUTINE zdfmxl  ***
65      !!                   
66      !! ** Purpose :   Compute the turbocline depth and the mixed layer depth
67      !!              with density criteria.
68      !!
69      !! ** Method  :   The mixed layer depth is the shallowest W depth with
70      !!      the density of the corresponding T point (just bellow) bellow a
71      !!      given value defined locally as rho(10m) + rho_c
72      !!               The turbocline depth is the depth at which the vertical
73      !!      eddy diffusivity coefficient (resulting from the vertical physics
74      !!      alone, not the isopycnal part, see trazdf.F) fall below a given
75      !!      value defined locally (avt_c here taken equal to 5 cm/s2 by default)
76      !!
77      !! ** Action  :   nmln, hmld, hmlp, hmlpt
78      !!----------------------------------------------------------------------
79      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
80      INTEGER, INTENT(in) ::   Kmm  ! ocean time level index
81      !
82      INTEGER  ::   ji, jj, jk      ! dummy loop indices
83      INTEGER  ::   iikn, iiki, ikt ! local integer
84      REAL(wp) ::   zN2_c           ! local scalar
85      INTEGER, DIMENSION(jpi,jpj) ::   imld   ! 2D workspace
86      !!----------------------------------------------------------------------
87      !
88      IF( kt == nit000 ) THEN
89         IF(lwp) WRITE(numout,*)
90         IF(lwp) WRITE(numout,*) 'zdf_mxl : mixed layer depth'
91         IF(lwp) WRITE(numout,*) '~~~~~~~ '
92         !                             ! allocate zdfmxl arrays
93         IF( zdf_mxl_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'zdf_mxl : unable to allocate arrays' )
94      ENDIF
95      !
96      ! w-level of the mixing and mixed layers
97      nmln(:,:)  = nlb10               ! Initialization to the number of w ocean point
98      hmlp(:,:)  = 0._wp               ! here hmlp used as a dummy variable, integrating vertically N^2
99      zN2_c = grav * rho_c * r1_rho0   ! convert density criteria into N^2 criteria
100      DO_3D_11_11( nlb10, jpkm1 )
101         ikt = mbkt(ji,jj)
102         hmlp(ji,jj) = hmlp(ji,jj) + MAX( rn2b(ji,jj,jk) , 0._wp ) * e3w(ji,jj,jk,Kmm)
103         IF( hmlp(ji,jj) < zN2_c )   nmln(ji,jj) = MIN( jk , ikt ) + 1   ! Mixed layer level
104      END_3D
105      !
106      ! w-level of the turbocline and mixing layer (iom_use)
107      imld(:,:) = mbkt(:,:) + 1        ! Initialization to the number of w ocean point
108      DO_3DS_11_11( jpkm1, nlb10, -1 )
109         IF( avt (ji,jj,jk) < avt_c * wmask(ji,jj,jk) )   imld(ji,jj) = jk      ! Turbocline
110      END_3D
111      ! depth of the mixing and mixed layers
112      DO_2D_11_11
113         iiki = imld(ji,jj)
114         iikn = nmln(ji,jj)
115         hmld (ji,jj) = gdepw(ji,jj,iiki  ,Kmm) * ssmask(ji,jj)    ! Turbocline depth
116         hmlp (ji,jj) = gdepw(ji,jj,iikn  ,Kmm) * ssmask(ji,jj)    ! Mixed layer depth
117         hmlpt(ji,jj) = gdept(ji,jj,iikn-1,Kmm) * ssmask(ji,jj)    ! depth of the last T-point inside the mixed layer
118      END_2D
119      !
120      IF( .NOT.l_offline ) THEN
121         IF( iom_use("mldr10_1") ) THEN
122            IF( ln_isfcav ) THEN  ;  CALL iom_put( "mldr10_1", hmlp - risfdep)   ! mixed layer thickness
123            ELSE                  ;  CALL iom_put( "mldr10_1", hmlp )            ! mixed layer depth
124            END IF
125         END IF
126         IF( iom_use("mldkz5") ) THEN
127            IF( ln_isfcav ) THEN  ;  CALL iom_put( "mldkz5"  , hmld - risfdep )   ! turbocline thickness
128            ELSE                  ;  CALL iom_put( "mldkz5"  , hmld )             ! turbocline depth
129            END IF
130         ENDIF
131      ENDIF
132      !
133      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab2d_1=REAL(nmln,wp), clinfo1=' nmln : ', tab2d_2=hmlp, clinfo2=' hmlp : ' )
134      !
135   END SUBROUTINE zdf_mxl
136
137   !!======================================================================
138END MODULE zdfmxl
Note: See TracBrowser for help on using the repository browser.