source: NEMO/trunk/src/OCE/ZDF/zdftke.F90 @ 13007

Last change on this file since 13007 was 13007, checked in by cetlod, 17 months ago

trunk:add mixing length parameterization depending on sea-ice thickness, see ticket #2476

  • Property svn:keywords set to Id
File size: 41.3 KB
Line 
1MODULE zdftke
2   !!======================================================================
3   !!                       ***  MODULE  zdftke  ***
4   !! Ocean physics:  vertical mixing coefficient computed from the tke
5   !!                 turbulent closure parameterization
6   !!=====================================================================
7   !! History :  OPA  !  1991-03  (b. blanke)  Original code
8   !!            7.0  !  1991-11  (G. Madec)   bug fix
9   !!            7.1  !  1992-10  (G. Madec)   new mixing length and eav
10   !!            7.2  !  1993-03  (M. Guyon)   symetrical conditions
11   !!            7.3  !  1994-08  (G. Madec, M. Imbard)  nn_pdl flag
12   !!            7.5  !  1996-01  (G. Madec)   s-coordinates
13   !!            8.0  !  1997-07  (G. Madec)   lbc
14   !!            8.1  !  1999-01  (E. Stretta) new option for the mixing length
15   !!  NEMO      1.0  !  2002-06  (G. Madec) add tke_init routine
16   !!             -   !  2004-10  (C. Ethe )  1D configuration
17   !!            2.0  !  2006-07  (S. Masson)  distributed restart using iom
18   !!            3.0  !  2008-05  (C. Ethe,  G.Madec) : update TKE physics:
19   !!                 !           - tke penetration (wind steering)
20   !!                 !           - suface condition for tke & mixing length
21   !!                 !           - Langmuir cells
22   !!             -   !  2008-05  (J.-M. Molines, G. Madec)  2D form of avtb
23   !!             -   !  2008-06  (G. Madec)  style + DOCTOR name for namelist parameters
24   !!             -   !  2008-12  (G. Reffray) stable discretization of the production term
25   !!            3.2  !  2009-06  (G. Madec, S. Masson) TKE restart compatible with key_cpl
26   !!                 !                                + cleaning of the parameters + bugs correction
27   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
28   !!            3.6  !  2014-11  (P. Mathiot) add ice shelf capability
29   !!            4.0  !  2017-04  (G. Madec)  remove CPP ddm key & avm at t-point only
30   !!             -   !  2017-05  (G. Madec)  add top/bottom friction as boundary condition (ln_drg)
31   !!----------------------------------------------------------------------
32
33   !!----------------------------------------------------------------------
34   !!   zdf_tke       : update momentum and tracer Kz from a tke scheme
35   !!   tke_tke       : tke time stepping: update tke at now time step (en)
36   !!   tke_avn       : compute mixing length scale and deduce avm and avt
37   !!   zdf_tke_init  : initialization, namelist read, and parameters control
38   !!   tke_rst       : read/write tke restart in ocean restart file
39   !!----------------------------------------------------------------------
40   USE oce            ! ocean: dynamics and active tracers variables
41   USE phycst         ! physical constants
42   USE dom_oce        ! domain: ocean
43   USE domvvl         ! domain: variable volume layer
44   USE sbc_oce        ! surface boundary condition: ocean
45   USE zdfdrg         ! vertical physics: top/bottom drag coef.
46   USE zdfmxl         ! vertical physics: mixed layer
47#if defined key_si3
48   USE ice, ONLY: hm_i, h_i
49#endif
50#if defined key_cice
51   USE sbc_ice, ONLY: h_i
52#endif
53   !
54   USE in_out_manager ! I/O manager
55   USE iom            ! I/O manager library
56   USE lib_mpp        ! MPP library
57   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
58   USE prtctl         ! Print control
59   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
60
61   IMPLICIT NONE
62   PRIVATE
63
64   PUBLIC   zdf_tke        ! routine called in step module
65   PUBLIC   zdf_tke_init   ! routine called in opa module
66   PUBLIC   tke_rst        ! routine called in step module
67
68   !                      !!** Namelist  namzdf_tke  **
69   LOGICAL  ::   ln_mxl0   ! mixing length scale surface value as function of wind stress or not
70   INTEGER  ::   nn_mxl    ! type of mixing length (=0/1/2/3)
71   REAL(wp) ::   rn_mxl0   ! surface  min value of mixing length (kappa*z_o=0.4*0.1 m)  [m]
72   INTEGER  ::   nn_pdl    ! Prandtl number or not (ratio avt/avm) (=0/1)
73   REAL(wp) ::   rn_ediff  ! coefficient for avt: avt=rn_ediff*mxl*sqrt(e)
74   REAL(wp) ::   rn_ediss  ! coefficient of the Kolmogoroff dissipation
75   REAL(wp) ::   rn_ebb    ! coefficient of the surface input of tke
76   REAL(wp) ::   rn_emin   ! minimum value of tke           [m2/s2]
77   REAL(wp) ::   rn_emin0  ! surface minimum value of tke   [m2/s2]
78   REAL(wp) ::   rn_bshear ! background shear (>0) currently a numerical threshold (do not change it)
79   LOGICAL  ::   ln_drg    ! top/bottom friction forcing flag
80   INTEGER  ::   nn_etau   ! type of depth penetration of surface tke (=0/1/2/3)
81   INTEGER  ::      nn_htau   ! type of tke profile of penetration (=0/1)
82   REAL(wp) ::      rn_efr    ! fraction of TKE surface value which penetrates in the ocean
83   REAL(wp) ::      rn_eice   ! =0 ON below sea-ice, =4 OFF when ice fraction > 1/4   
84   LOGICAL  ::   ln_lc     ! Langmuir cells (LC) as a source term of TKE or not
85   REAL(wp) ::      rn_lc     ! coef to compute vertical velocity of Langmuir cells
86
87   REAL(wp) ::   ri_cri    ! critic Richardson number (deduced from rn_ediff and rn_ediss values)
88   REAL(wp) ::   rmxl_min  ! minimum mixing length value (deduced from rn_ediff and rn_emin values)  [m]
89   REAL(wp) ::   rhftau_add = 1.e-3_wp     ! add offset   applied to HF part of taum  (nn_etau=3)
90   REAL(wp) ::   rhftau_scl = 1.0_wp       ! scale factor applied to HF part of taum  (nn_etau=3)
91
92   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   htau    ! depth of tke penetration (nn_htau)
93   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   dissl   ! now mixing lenght of dissipation
94   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   apdlr   ! now mixing lenght of dissipation
95
96   !! * Substitutions
97#  include "do_loop_substitute.h90"
98   !!----------------------------------------------------------------------
99   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
100   !! $Id$
101   !! Software governed by the CeCILL license (see ./LICENSE)
102   !!----------------------------------------------------------------------
103CONTAINS
104
105   INTEGER FUNCTION zdf_tke_alloc()
106      !!----------------------------------------------------------------------
107      !!                ***  FUNCTION zdf_tke_alloc  ***
108      !!----------------------------------------------------------------------
109      ALLOCATE( htau(jpi,jpj) , dissl(jpi,jpj,jpk) , apdlr(jpi,jpj,jpk) ,   STAT= zdf_tke_alloc )
110      !
111      CALL mpp_sum ( 'zdftke', zdf_tke_alloc )
112      IF( zdf_tke_alloc /= 0 )   CALL ctl_stop( 'STOP', 'zdf_tke_alloc: failed to allocate arrays' )
113      !
114   END FUNCTION zdf_tke_alloc
115
116
117   SUBROUTINE zdf_tke( kt, Kbb, Kmm, p_sh2, p_avm, p_avt )
118      !!----------------------------------------------------------------------
119      !!                   ***  ROUTINE zdf_tke  ***
120      !!
121      !! ** Purpose :   Compute the vertical eddy viscosity and diffusivity
122      !!              coefficients using a turbulent closure scheme (TKE).
123      !!
124      !! ** Method  :   The time evolution of the turbulent kinetic energy (tke)
125      !!              is computed from a prognostic equation :
126      !!         d(en)/dt = avm (d(u)/dz)**2             ! shear production
127      !!                  + d( avm d(en)/dz )/dz         ! diffusion of tke
128      !!                  + avt N^2                      ! stratif. destruc.
129      !!                  - rn_ediss / emxl en**(2/3)    ! Kolmogoroff dissipation
130      !!      with the boundary conditions:
131      !!         surface: en = max( rn_emin0, rn_ebb * taum )
132      !!         bottom : en = rn_emin
133      !!      The associated critical Richardson number is: ri_cri = 2/(2+rn_ediss/rn_ediff)
134      !!
135      !!        The now Turbulent kinetic energy is computed using the following
136      !!      time stepping: implicit for vertical diffusion term, linearized semi
137      !!      implicit for kolmogoroff dissipation term, and explicit forward for
138      !!      both buoyancy and shear production terms. Therefore a tridiagonal
139      !!      linear system is solved. Note that buoyancy and shear terms are
140      !!      discretized in a energy conserving form (Bruchard 2002).
141      !!
142      !!        The dissipative and mixing length scale are computed from en and
143      !!      the stratification (see tke_avn)
144      !!
145      !!        The now vertical eddy vicosity and diffusivity coefficients are
146      !!      given by:
147      !!              avm = max( avtb, rn_ediff * zmxlm * en^1/2 )
148      !!              avt = max( avmb, pdl * avm                 ) 
149      !!              eav = max( avmb, avm )
150      !!      where pdl, the inverse of the Prandtl number is 1 if nn_pdl=0 and
151      !!      given by an empirical funtion of the localRichardson number if nn_pdl=1
152      !!
153      !! ** Action  :   compute en (now turbulent kinetic energy)
154      !!                update avt, avm (before vertical eddy coef.)
155      !!
156      !! References : Gaspar et al., JGR, 1990,
157      !!              Blanke and Delecluse, JPO, 1991
158      !!              Mellor and Blumberg, JPO 2004
159      !!              Axell, JGR, 2002
160      !!              Bruchard OM 2002
161      !!----------------------------------------------------------------------
162      INTEGER                   , INTENT(in   ) ::   kt             ! ocean time step
163      INTEGER                   , INTENT(in   ) ::   Kbb, Kmm       ! ocean time level indices
164      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   p_sh2          ! shear production term
165      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   p_avm, p_avt   !  momentum and tracer Kz (w-points)
166      !!----------------------------------------------------------------------
167      !
168      CALL tke_tke( Kbb, Kmm, p_sh2, p_avm, p_avt )   ! now tke (en)
169      !
170      CALL tke_avn( Kbb, Kmm,        p_avm, p_avt )   ! now avt, avm, dissl
171      !
172  END SUBROUTINE zdf_tke
173
174
175   SUBROUTINE tke_tke( Kbb, Kmm, p_sh2, p_avm, p_avt )
176      !!----------------------------------------------------------------------
177      !!                   ***  ROUTINE tke_tke  ***
178      !!
179      !! ** Purpose :   Compute the now Turbulente Kinetic Energy (TKE)
180      !!
181      !! ** Method  : - TKE surface boundary condition
182      !!              - source term due to Langmuir cells (Axell JGR 2002) (ln_lc=T)
183      !!              - source term due to shear (= Kz dz[Ub] * dz[Un] )
184      !!              - Now TKE : resolution of the TKE equation by inverting
185      !!                a tridiagonal linear system by a "methode de chasse"
186      !!              - increase TKE due to surface and internal wave breaking
187      !!             NB: when sea-ice is present, both LC parameterization
188      !!                 and TKE penetration are turned off when the ice fraction
189      !!                 is smaller than 0.25
190      !!
191      !! ** Action  : - en : now turbulent kinetic energy)
192      !! ---------------------------------------------------------------------
193      USE zdf_oce , ONLY : en   ! ocean vertical physics
194      !!
195      INTEGER                    , INTENT(in   ) ::   Kbb, Kmm       ! ocean time level indices
196      REAL(wp), DIMENSION(:,:,:) , INTENT(in   ) ::   p_sh2          ! shear production term
197      REAL(wp), DIMENSION(:,:,:) , INTENT(in   ) ::   p_avm, p_avt   ! vertical eddy viscosity & diffusivity (w-points)
198      !
199      INTEGER ::   ji, jj, jk              ! dummy loop arguments
200      REAL(wp) ::   zetop, zebot, zmsku, zmskv ! local scalars
201      REAL(wp) ::   zrhoa  = 1.22              ! Air density kg/m3
202      REAL(wp) ::   zcdrag = 1.5e-3            ! drag coefficient
203      REAL(wp) ::   zbbrau, zri                ! local scalars
204      REAL(wp) ::   zfact1, zfact2, zfact3     !   -         -
205      REAL(wp) ::   ztx2  , zty2  , zcof       !   -         -
206      REAL(wp) ::   ztau  , zdif               !   -         -
207      REAL(wp) ::   zus   , zwlc  , zind       !   -         -
208      REAL(wp) ::   zzd_up, zzd_lw             !   -         -
209      INTEGER , DIMENSION(jpi,jpj)     ::   imlc
210      REAL(wp), DIMENSION(jpi,jpj)     ::   zhlc, zfr_i
211      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zpelc, zdiag, zd_up, zd_lw
212      !!--------------------------------------------------------------------
213      !
214      zbbrau = rn_ebb / rho0       ! Local constant initialisation
215      zfact1 = -.5_wp * rn_Dt 
216      zfact2 = 1.5_wp * rn_Dt * rn_ediss
217      zfact3 = 0.5_wp       * rn_ediss
218      !
219      !                     !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
220      !                     !  Surface/top/bottom boundary condition on tke
221      !                     !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
222      !
223      DO_2D_00_00
224         en(ji,jj,1) = MAX( rn_emin0, zbbrau * taum(ji,jj) ) * tmask(ji,jj,1)
225      END_2D
226      !
227      !                     !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
228      !                     !  Bottom boundary condition on tke
229      !                     !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
230      !
231      !   en(bot)   = (ebb0/rho0)*0.5*sqrt(u_botfr^2+v_botfr^2) (min value rn_emin)
232      ! where ebb0 does not includes surface wave enhancement (i.e. ebb0=3.75)
233      ! Note that stress averaged is done using an wet-only calculation of u and v at t-point like in zdfsh2
234      !
235      IF( ln_drg ) THEN       !== friction used as top/bottom boundary condition on TKE
236         !
237         DO_2D_00_00
238            zmsku = ( 2. - umask(ji-1,jj,mbkt(ji,jj)) * umask(ji,jj,mbkt(ji,jj)) )
239            zmskv = ( 2. - vmask(ji,jj-1,mbkt(ji,jj)) * vmask(ji,jj,mbkt(ji,jj)) )
240            !                       ! where 0.001875 = (rn_ebb0/rho0) * 0.5 = 3.75*0.5/1000. (CAUTION CdU<0)
241            zebot = - 0.001875_wp * rCdU_bot(ji,jj) * SQRT(  ( zmsku*( uu(ji,jj,mbkt(ji,jj),Kbb)+uu(ji-1,jj,mbkt(ji,jj),Kbb) ) )**2  &
242               &                                           + ( zmskv*( vv(ji,jj,mbkt(ji,jj),Kbb)+vv(ji,jj-1,mbkt(ji,jj),Kbb) ) )**2  )
243            en(ji,jj,mbkt(ji,jj)+1) = MAX( zebot, rn_emin ) * ssmask(ji,jj)
244         END_2D
245         IF( ln_isfcav ) THEN       ! top friction
246            DO_2D_00_00
247               zmsku = ( 2. - umask(ji-1,jj,mikt(ji,jj)) * umask(ji,jj,mikt(ji,jj)) )
248               zmskv = ( 2. - vmask(ji,jj-1,mikt(ji,jj)) * vmask(ji,jj,mikt(ji,jj)) )
249               !                             ! where 0.001875 = (rn_ebb0/rho0) * 0.5 = 3.75*0.5/1000.  (CAUTION CdU<0)
250               zetop = - 0.001875_wp * rCdU_top(ji,jj) * SQRT(  ( zmsku*( uu(ji,jj,mikt(ji,jj),Kbb)+uu(ji-1,jj,mikt(ji,jj),Kbb) ) )**2  &
251                  &                                           + ( zmskv*( vv(ji,jj,mikt(ji,jj),Kbb)+vv(ji,jj-1,mikt(ji,jj),Kbb) ) )**2  )
252               ! (1._wp - tmask(ji,jj,1)) * ssmask(ji,jj) = 1 where ice shelves are present
253               en(ji,jj,mikt(ji,jj)) = en(ji,jj,1)           * tmask(ji,jj,1) &
254                  &                  + MAX( zetop, rn_emin ) * (1._wp - tmask(ji,jj,1)) * ssmask(ji,jj)
255            END_2D
256         ENDIF
257         !
258      ENDIF
259      !
260      !                     !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
261      IF( ln_lc ) THEN      !  Langmuir circulation source term added to tke   !   (Axell JGR 2002)
262         !                  !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
263         !
264         !                        !* total energy produce by LC : cumulative sum over jk
265         zpelc(:,:,1) =  MAX( rn2b(:,:,1), 0._wp ) * gdepw(:,:,1,Kmm) * e3w(:,:,1,Kmm)
266         DO jk = 2, jpk
267            zpelc(:,:,jk)  = zpelc(:,:,jk-1) + MAX( rn2b(:,:,jk), 0._wp ) * gdepw(:,:,jk,Kmm) * e3w(:,:,jk,Kmm)
268         END DO
269         !                        !* finite Langmuir Circulation depth
270         zcof = 0.5 * 0.016 * 0.016 / ( zrhoa * zcdrag )
271         imlc(:,:) = mbkt(:,:) + 1       ! Initialization to the number of w ocean point (=2 over land)
272         DO_3DS_11_11( jpkm1, 2, -1 )
273            zus  = zcof * taum(ji,jj)
274            IF( zpelc(ji,jj,jk) > zus )   imlc(ji,jj) = jk
275         END_3D
276         !                               ! finite LC depth
277         DO_2D_11_11
278            zhlc(ji,jj) = gdepw(ji,jj,imlc(ji,jj),Kmm)
279         END_2D
280         zcof = 0.016 / SQRT( zrhoa * zcdrag )
281         DO_2D_00_00
282            zus  = zcof * SQRT( taum(ji,jj) )           ! Stokes drift
283            zfr_i(ji,jj) = ( 1._wp - 4._wp * fr_i(ji,jj) ) * zus * zus * zus * tmask(ji,jj,1) ! zus > 0. ok
284            IF (zfr_i(ji,jj) < 0. ) zfr_i(ji,jj) = 0.
285         END_2D
286         DO_3D_00_00( 2, jpkm1 )
287            IF ( zfr_i(ji,jj) /= 0. ) THEN               
288               ! vertical velocity due to LC   
289               IF ( gdepw(ji,jj,jk,Kmm) - zhlc(ji,jj) < 0 .AND. wmask(ji,jj,jk) /= 0. ) THEN
290                  !                                           ! vertical velocity due to LC
291                  zwlc = rn_lc * SIN( rpi * gdepw(ji,jj,jk,Kmm) / zhlc(ji,jj) )   ! warning: optimization: zus^3 is in zfr_i
292                  !                                           ! TKE Langmuir circulation source term
293                  en(ji,jj,jk) = en(ji,jj,jk) + rn_Dt * zfr_i(ji,jj) * ( zwlc * zwlc * zwlc ) / zhlc(ji,jj)
294               ENDIF
295            ENDIF
296         END_3D
297         !
298      ENDIF
299      !
300      !                     !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
301      !                     !  Now Turbulent kinetic energy (output in en)
302      !                     !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
303      !                     ! Resolution of a tridiagonal linear system by a "methode de chasse"
304      !                     ! computation from level 2 to jpkm1  (e(1) already computed and e(jpk)=0 ).
305      !                     ! zdiag : diagonal zd_up : upper diagonal zd_lw : lower diagonal
306      !
307      IF( nn_pdl == 1 ) THEN      !* Prandtl number = F( Ri )
308         DO_3D_00_00( 2, jpkm1 )
309            !                             ! local Richardson number
310            zri = MAX( rn2b(ji,jj,jk), 0._wp ) * p_avm(ji,jj,jk) / ( p_sh2(ji,jj,jk) + rn_bshear )
311            !                             ! inverse of Prandtl number
312            apdlr(ji,jj,jk) = MAX(  0.1_wp,  ri_cri / MAX( ri_cri , zri )  )
313         END_3D
314      ENDIF
315      !         
316      DO_3D_00_00( 2, jpkm1 )
317         zcof   = zfact1 * tmask(ji,jj,jk)
318         !                                   ! A minimum of 2.e-5 m2/s is imposed on TKE vertical
319         !                                   ! eddy coefficient (ensure numerical stability)
320         zzd_up = zcof * MAX(  p_avm(ji,jj,jk+1) + p_avm(ji,jj,jk  ) , 2.e-5_wp  )   &  ! upper diagonal
321            &          /    (  e3t(ji,jj,jk  ,Kmm) * e3w(ji,jj,jk  ,Kmm)  )
322         zzd_lw = zcof * MAX(  p_avm(ji,jj,jk  ) + p_avm(ji,jj,jk-1) , 2.e-5_wp  )   &  ! lower diagonal
323            &          /    (  e3t(ji,jj,jk-1,Kmm) * e3w(ji,jj,jk  ,Kmm)  )
324         !
325         zd_up(ji,jj,jk) = zzd_up            ! Matrix (zdiag, zd_up, zd_lw)
326         zd_lw(ji,jj,jk) = zzd_lw
327         zdiag(ji,jj,jk) = 1._wp - zzd_lw - zzd_up + zfact2 * dissl(ji,jj,jk) * wmask(ji,jj,jk)
328         !
329         !                                   ! right hand side in en
330         en(ji,jj,jk) = en(ji,jj,jk) + rn_Dt * (  p_sh2(ji,jj,jk)                        &   ! shear
331            &                                 - p_avt(ji,jj,jk) * rn2(ji,jj,jk)          &   ! stratification
332            &                                 + zfact3 * dissl(ji,jj,jk) * en(ji,jj,jk)  &   ! dissipation
333            &                                ) * wmask(ji,jj,jk)
334      END_3D
335      !                          !* Matrix inversion from level 2 (tke prescribed at level 1)
336      DO_3D_00_00( 3, jpkm1 )
337         zdiag(ji,jj,jk) = zdiag(ji,jj,jk) - zd_lw(ji,jj,jk) * zd_up(ji,jj,jk-1) / zdiag(ji,jj,jk-1)
338      END_3D
339      DO_2D_00_00
340         zd_lw(ji,jj,2) = en(ji,jj,2) - zd_lw(ji,jj,2) * en(ji,jj,1)    ! Surface boudary conditions on tke
341      END_2D
342      DO_3D_00_00( 3, jpkm1 )
343         zd_lw(ji,jj,jk) = en(ji,jj,jk) - zd_lw(ji,jj,jk) / zdiag(ji,jj,jk-1) *zd_lw(ji,jj,jk-1)
344      END_3D
345      DO_2D_00_00
346         en(ji,jj,jpkm1) = zd_lw(ji,jj,jpkm1) / zdiag(ji,jj,jpkm1)
347      END_2D
348      DO_3DS_00_00( jpk-2, 2, -1 )
349         en(ji,jj,jk) = ( zd_lw(ji,jj,jk) - zd_up(ji,jj,jk) * en(ji,jj,jk+1) ) / zdiag(ji,jj,jk)
350      END_3D
351      DO_3D_00_00( 2, jpkm1 )
352         en(ji,jj,jk) = MAX( en(ji,jj,jk), rn_emin ) * wmask(ji,jj,jk)
353      END_3D
354      !
355      !                            !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
356      !                            !  TKE due to surface and internal wave breaking
357      !                            !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
358!!gm BUG : in the exp  remove the depth of ssh !!!
359!!gm       i.e. use gde3w in argument (gdepw(:,:,:,Kmm))
360     
361     
362      IF( nn_etau == 1 ) THEN           !* penetration below the mixed layer (rn_efr fraction)
363         DO_3D_00_00( 2, jpkm1 )
364            en(ji,jj,jk) = en(ji,jj,jk) + rn_efr * en(ji,jj,1) * EXP( -gdepw(ji,jj,jk,Kmm) / htau(ji,jj) )   &
365               &                                 * MAX(0.,1._wp - rn_eice *fr_i(ji,jj) )  * wmask(ji,jj,jk) * tmask(ji,jj,1)
366         END_3D
367      ELSEIF( nn_etau == 2 ) THEN       !* act only at the base of the mixed layer (jk=nmln)  (rn_efr fraction)
368         DO_2D_00_00
369            jk = nmln(ji,jj)
370            en(ji,jj,jk) = en(ji,jj,jk) + rn_efr * en(ji,jj,1) * EXP( -gdepw(ji,jj,jk,Kmm) / htau(ji,jj) )   &
371               &                                 * MAX(0.,1._wp - rn_eice *fr_i(ji,jj) )  * wmask(ji,jj,jk) * tmask(ji,jj,1)
372         END_2D
373      ELSEIF( nn_etau == 3 ) THEN       !* penetration belox the mixed layer (HF variability)
374         DO_3D_00_00( 2, jpkm1 )
375            ztx2 = utau(ji-1,jj  ) + utau(ji,jj)
376            zty2 = vtau(ji  ,jj-1) + vtau(ji,jj)
377            ztau = 0.5_wp * SQRT( ztx2 * ztx2 + zty2 * zty2 ) * tmask(ji,jj,1)    ! module of the mean stress
378            zdif = taum(ji,jj) - ztau                            ! mean of modulus - modulus of the mean
379            zdif = rhftau_scl * MAX( 0._wp, zdif + rhftau_add )  ! apply some modifications...
380            en(ji,jj,jk) = en(ji,jj,jk) + zbbrau * zdif * EXP( -gdepw(ji,jj,jk,Kmm) / htau(ji,jj) )   &
381               &                        * MAX(0.,1._wp - rn_eice *fr_i(ji,jj) ) * wmask(ji,jj,jk) * tmask(ji,jj,1)
382         END_3D
383      ENDIF
384      !
385   END SUBROUTINE tke_tke
386
387
388   SUBROUTINE tke_avn( Kbb, Kmm, p_avm, p_avt )
389      !!----------------------------------------------------------------------
390      !!                   ***  ROUTINE tke_avn  ***
391      !!
392      !! ** Purpose :   Compute the vertical eddy viscosity and diffusivity
393      !!
394      !! ** Method  :   At this stage, en, the now TKE, is known (computed in
395      !!              the tke_tke routine). First, the now mixing lenth is
396      !!      computed from en and the strafification (N^2), then the mixings
397      !!      coefficients are computed.
398      !!              - Mixing length : a first evaluation of the mixing lengh
399      !!      scales is:
400      !!                      mxl = sqrt(2*en) / N 
401      !!      where N is the brunt-vaisala frequency, with a minimum value set
402      !!      to rmxl_min (rn_mxl0) in the interior (surface) ocean.
403      !!        The mixing and dissipative length scale are bound as follow :
404      !!         nn_mxl=0 : mxl bounded by the distance to surface and bottom.
405      !!                        zmxld = zmxlm = mxl
406      !!         nn_mxl=1 : mxl bounded by the e3w and zmxld = zmxlm = mxl
407      !!         nn_mxl=2 : mxl bounded such that the vertical derivative of mxl is
408      !!                    less than 1 (|d/dz(mxl)|<1) and zmxld = zmxlm = mxl
409      !!         nn_mxl=3 : mxl is bounded from the surface to the bottom usings
410      !!                    |d/dz(xml)|<1 to obtain lup, and from the bottom to
411      !!                    the surface to obtain ldown. the resulting length
412      !!                    scales are:
413      !!                        zmxld = sqrt( lup * ldown )
414      !!                        zmxlm = min ( lup , ldown )
415      !!              - Vertical eddy viscosity and diffusivity:
416      !!                      avm = max( avtb, rn_ediff * zmxlm * en^1/2 )
417      !!                      avt = max( avmb, pdlr * avm ) 
418      !!      with pdlr=1 if nn_pdl=0, pdlr=1/pdl=F(Ri) otherwise.
419      !!
420      !! ** Action  : - avt, avm : now vertical eddy diffusivity and viscosity (w-point)
421      !!----------------------------------------------------------------------
422      USE zdf_oce , ONLY : en, avtb, avmb, avtb_2d   ! ocean vertical physics
423      !!
424      INTEGER                   , INTENT(in   ) ::   Kbb, Kmm       ! ocean time level indices
425      REAL(wp), DIMENSION(:,:,:), INTENT(  out) ::   p_avm, p_avt   ! vertical eddy viscosity & diffusivity (w-points)
426      !
427      INTEGER  ::   ji, jj, jk   ! dummy loop indices
428      REAL(wp) ::   zrn2, zraug, zcoef, zav   ! local scalars
429      REAL(wp) ::   zdku,   zdkv, zsqen       !   -      -
430      REAL(wp) ::   zemxl, zemlm, zemlp, zmaxice       !   -      -
431      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zmxlm, zmxld   ! 3D workspace
432      !!--------------------------------------------------------------------
433      !
434      !                     !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
435      !                     !  Mixing length
436      !                     !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
437      !
438      !                     !* Buoyancy length scale: l=sqrt(2*e/n**2)
439      !
440      ! initialisation of interior minimum value (avoid a 2d loop with mikt)
441      zmxlm(:,:,:)  = rmxl_min   
442      zmxld(:,:,:)  = rmxl_min
443      !
444     IF( ln_mxl0 ) THEN            ! surface mixing length = F(stress) : l=vkarmn*2.e5*taum/(rau0*g)
445         !
446         zraug = vkarmn * 2.e5_wp / ( rau0 * grav )
447#if ! defined key_si3 && ! defined key_cice
448         DO_2D_00_00
449            zmxlm(ji,jj,1) =  zraug * taum(ji,jj) * tmask(ji,jj,1)
450         END_2D
451#else
452         SELECT CASE( nn_mxlice )             ! Type of scaling under sea-ice
453         !
454         CASE( 0 )                      ! No scaling under sea-ice
455            DO_2D_00_00
456               zmxlm(ji,jj,1) = zraug * taum(ji,jj) * tmask(ji,jj,1)
457            END_2D
458            !
459         CASE( 1 )                           ! scaling with constant sea-ice thickness
460            DO_2D_00_00
461               zmxlm(ji,jj,1) =  ( ( 1. - fr_i(ji,jj) ) * zraug * taum(ji,jj) + fr_i(ji,jj) * rn_mxlice ) * tmask(ji,jj,1)
462            END_2D
463            !
464         CASE( 2 )                                 ! scaling with mean sea-ice thickness
465            DO_2D_00_00
466#if defined key_si3
467               zmxlm(ji,jj,1) = ( ( 1. - fr_i(ji,jj) ) * zraug * taum(ji,jj) + fr_i(ji,jj) * hm_i(ji,jj) * 2. ) * tmask(ji,jj,1)
468#elif defined key_cice
469               zmaxice = MAXVAL( h_i(ji,jj,:) )
470               zmxlm(ji,jj,1) = ( ( 1. - fr_i(ji,jj) ) * zraug * taum(ji,jj) + fr_i(ji,jj) * zmaxice ) * tmask(ji,jj,1)
471#endif
472            END_2D
473            !
474         CASE( 3 )                                 ! scaling with max sea-ice thickness
475            DO_2D_00_00
476               zmaxice = MAXVAL( h_i(ji,jj,:) )
477               zmxlm(ji,jj,1) = ( ( 1. - fr_i(ji,jj) ) * zraug * taum(ji,jj) + fr_i(ji,jj) * zmaxice ) * tmask(ji,jj,1)
478            END_2D
479            !
480         END SELECT
481#endif
482         !
483         DO_2D_00_00
484            zmxlm(ji,jj,1) = MAX( rn_mxl0, zmxlm(ji,jj,1) )
485         END_2D
486         !
487      ELSE
488         zmxlm(:,:,1) = rn_mxl0
489      ENDIF
490
491      !
492      DO_3D_00_00( 2, jpkm1 )
493         zrn2 = MAX( rn2(ji,jj,jk), rsmall )
494         zmxlm(ji,jj,jk) = MAX(  rmxl_min,  SQRT( 2._wp * en(ji,jj,jk) / zrn2 )  )
495      END_3D
496      !
497      !                     !* Physical limits for the mixing length
498      !
499      zmxld(:,:, 1 ) = zmxlm(:,:,1)   ! surface set to the minimum value
500      zmxld(:,:,jpk) = rmxl_min       ! last level  set to the minimum value
501      !
502      SELECT CASE ( nn_mxl )
503      !
504 !!gm Not sure of that coding for ISF....
505      ! where wmask = 0 set zmxlm == e3w(:,:,:,Kmm)
506      CASE ( 0 )           ! bounded by the distance to surface and bottom
507         DO_3D_00_00( 2, jpkm1 )
508            zemxl = MIN( gdepw(ji,jj,jk,Kmm) - gdepw(ji,jj,mikt(ji,jj),Kmm), zmxlm(ji,jj,jk),   &
509            &            gdepw(ji,jj,mbkt(ji,jj)+1,Kmm) - gdepw(ji,jj,jk,Kmm) )
510            ! wmask prevent zmxlm = 0 if jk = mikt(ji,jj)
511            zmxlm(ji,jj,jk) = zemxl * wmask(ji,jj,jk) + MIN( zmxlm(ji,jj,jk) , e3w(ji,jj,jk,Kmm) ) * (1 - wmask(ji,jj,jk))
512            zmxld(ji,jj,jk) = zemxl * wmask(ji,jj,jk) + MIN( zmxlm(ji,jj,jk) , e3w(ji,jj,jk,Kmm) ) * (1 - wmask(ji,jj,jk))
513         END_3D
514         !
515      CASE ( 1 )           ! bounded by the vertical scale factor
516         DO_3D_00_00( 2, jpkm1 )
517            zemxl = MIN( e3w(ji,jj,jk,Kmm), zmxlm(ji,jj,jk) )
518            zmxlm(ji,jj,jk) = zemxl
519            zmxld(ji,jj,jk) = zemxl
520         END_3D
521         !
522      CASE ( 2 )           ! |dk[xml]| bounded by e3t :
523         DO_3D_00_00( 2, jpkm1 )
524            zmxlm(ji,jj,jk) = MIN( zmxlm(ji,jj,jk-1) + e3t(ji,jj,jk-1,Kmm), zmxlm(ji,jj,jk) )
525         END_3D
526         DO_3DS_00_00( jpkm1, 2, -1 )
527            zemxl = MIN( zmxlm(ji,jj,jk+1) + e3t(ji,jj,jk+1,Kmm), zmxlm(ji,jj,jk) )
528            zmxlm(ji,jj,jk) = zemxl
529            zmxld(ji,jj,jk) = zemxl
530         END_3D
531         !
532      CASE ( 3 )           ! lup and ldown, |dk[xml]| bounded by e3t :
533         DO_3D_00_00( 2, jpkm1 )
534            zmxld(ji,jj,jk) = MIN( zmxld(ji,jj,jk-1) + e3t(ji,jj,jk-1,Kmm), zmxlm(ji,jj,jk) )
535         END_3D
536         DO_3DS_00_00( jpkm1, 2, -1 )
537            zmxlm(ji,jj,jk) = MIN( zmxlm(ji,jj,jk+1) + e3t(ji,jj,jk+1,Kmm), zmxlm(ji,jj,jk) )
538         END_3D
539         DO_3D_00_00( 2, jpkm1 )
540            zemlm = MIN ( zmxld(ji,jj,jk),  zmxlm(ji,jj,jk) )
541            zemlp = SQRT( zmxld(ji,jj,jk) * zmxlm(ji,jj,jk) )
542            zmxlm(ji,jj,jk) = zemlm
543            zmxld(ji,jj,jk) = zemlp
544         END_3D
545         !
546      END SELECT
547      !
548      !                     !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
549      !                     !  Vertical eddy viscosity and diffusivity  (avm and avt)
550      !                     !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
551      DO_3D_00_00( 1, jpkm1 )
552         zsqen = SQRT( en(ji,jj,jk) )
553         zav   = rn_ediff * zmxlm(ji,jj,jk) * zsqen
554         p_avm(ji,jj,jk) = MAX( zav,                  avmb(jk) ) * wmask(ji,jj,jk)
555         p_avt(ji,jj,jk) = MAX( zav, avtb_2d(ji,jj) * avtb(jk) ) * wmask(ji,jj,jk)
556         dissl(ji,jj,jk) = zsqen / zmxld(ji,jj,jk)
557      END_3D
558      !
559      !
560      IF( nn_pdl == 1 ) THEN      !* Prandtl number case: update avt
561         DO_3D_00_00( 2, jpkm1 )
562            p_avt(ji,jj,jk)   = MAX( apdlr(ji,jj,jk) * p_avt(ji,jj,jk), avtb_2d(ji,jj) * avtb(jk) ) * wmask(ji,jj,jk)
563         END_3D
564      ENDIF
565      !
566      IF(sn_cfctl%l_prtctl) THEN
567         CALL prt_ctl( tab3d_1=en   , clinfo1=' tke  - e: ', tab3d_2=p_avt, clinfo2=' t: ', kdim=jpk)
568         CALL prt_ctl( tab3d_1=p_avm, clinfo1=' tke  - m: ', kdim=jpk )
569      ENDIF
570      !
571   END SUBROUTINE tke_avn
572
573
574   SUBROUTINE zdf_tke_init( Kmm )
575      !!----------------------------------------------------------------------
576      !!                  ***  ROUTINE zdf_tke_init  ***
577      !!                     
578      !! ** Purpose :   Initialization of the vertical eddy diffivity and
579      !!              viscosity when using a tke turbulent closure scheme
580      !!
581      !! ** Method  :   Read the namzdf_tke namelist and check the parameters
582      !!              called at the first timestep (nit000)
583      !!
584      !! ** input   :   Namlist namzdf_tke
585      !!
586      !! ** Action  :   Increase by 1 the nstop flag is setting problem encounter
587      !!----------------------------------------------------------------------
588      USE zdf_oce , ONLY : ln_zdfiwm   ! Internal Wave Mixing flag
589      !!
590      INTEGER, INTENT(in) ::   Kmm          ! time level index
591      INTEGER             ::   ji, jj, jk   ! dummy loop indices
592      INTEGER             ::   ios
593      !!
594      NAMELIST/namzdf_tke/ rn_ediff, rn_ediss , rn_ebb   , rn_emin  ,  &
595         &                 rn_emin0, rn_bshear, nn_mxl   , ln_mxl0  ,  &
596         &                 rn_mxl0 , nn_mxlice, rn_mxlice,             &
597         &                 nn_pdl  , ln_drg   , ln_lc    , rn_lc,      &
598         &                 nn_etau , nn_htau  , rn_efr   , rn_eice 
599      !!----------------------------------------------------------------------
600      !
601      READ  ( numnam_ref, namzdf_tke, IOSTAT = ios, ERR = 901)
602901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_tke in reference namelist' )
603
604      READ  ( numnam_cfg, namzdf_tke, IOSTAT = ios, ERR = 902 )
605902   IF( ios >  0 ) CALL ctl_nam ( ios , 'namzdf_tke in configuration namelist' )
606      IF(lwm) WRITE ( numond, namzdf_tke )
607      !
608      ri_cri   = 2._wp    / ( 2._wp + rn_ediss / rn_ediff )   ! resulting critical Richardson number
609      !
610      IF(lwp) THEN                    !* Control print
611         WRITE(numout,*)
612         WRITE(numout,*) 'zdf_tke_init : tke turbulent closure scheme - initialisation'
613         WRITE(numout,*) '~~~~~~~~~~~~'
614         WRITE(numout,*) '   Namelist namzdf_tke : set tke mixing parameters'
615         WRITE(numout,*) '      coef. to compute avt                        rn_ediff  = ', rn_ediff
616         WRITE(numout,*) '      Kolmogoroff dissipation coef.               rn_ediss  = ', rn_ediss
617         WRITE(numout,*) '      tke surface input coef.                     rn_ebb    = ', rn_ebb
618         WRITE(numout,*) '      minimum value of tke                        rn_emin   = ', rn_emin
619         WRITE(numout,*) '      surface minimum value of tke                rn_emin0  = ', rn_emin0
620         WRITE(numout,*) '      prandl number flag                          nn_pdl    = ', nn_pdl
621         WRITE(numout,*) '      background shear (>0)                       rn_bshear = ', rn_bshear
622         WRITE(numout,*) '      mixing length type                          nn_mxl    = ', nn_mxl
623         WRITE(numout,*) '         surface mixing length = F(stress) or not    ln_mxl0   = ', ln_mxl0
624         IF( ln_mxl0 ) THEN
625            WRITE(numout,*) '      type of scaling under sea-ice               nn_mxlice = ', nn_mxlice
626            IF( nn_mxlice == 1 ) &
627            WRITE(numout,*) '      ice thickness when scaling under sea-ice    rn_mxlice = ', rn_mxlice
628         ENDIF         
629         WRITE(numout,*) '         surface  mixing length minimum value        rn_mxl0   = ', rn_mxl0
630         WRITE(numout,*) '      top/bottom friction forcing flag            ln_drg    = ', ln_drg
631         WRITE(numout,*) '      Langmuir cells parametrization              ln_lc     = ', ln_lc
632         WRITE(numout,*) '         coef to compute vertical velocity of LC     rn_lc  = ', rn_lc
633         WRITE(numout,*) '      test param. to add tke induced by wind      nn_etau   = ', nn_etau
634         WRITE(numout,*) '          type of tke penetration profile            nn_htau   = ', nn_htau
635         WRITE(numout,*) '          fraction of TKE that penetrates            rn_efr    = ', rn_efr
636         WRITE(numout,*) '          below sea-ice:  =0 ON                      rn_eice   = ', rn_eice
637         WRITE(numout,*) '          =4 OFF when ice fraction > 1/4   '
638         IF( ln_drg ) THEN
639            WRITE(numout,*)
640            WRITE(numout,*) '   Namelist namdrg_top/_bot:   used values:'
641            WRITE(numout,*) '      top    ocean cavity roughness (m)          rn_z0(_top)= ', r_z0_top
642            WRITE(numout,*) '      Bottom seafloor     roughness (m)          rn_z0(_bot)= ', r_z0_bot
643         ENDIF
644         WRITE(numout,*)
645         WRITE(numout,*) '   ==>>>   critical Richardson nb with your parameters  ri_cri = ', ri_cri
646         WRITE(numout,*)
647      ENDIF
648      !
649      IF( ln_zdfiwm ) THEN          ! Internal wave-driven mixing
650         rn_emin  = 1.e-10_wp             ! specific values of rn_emin & rmxl_min are used
651         rmxl_min = 1.e-03_wp             ! associated avt minimum = molecular salt diffusivity (10^-9 m2/s)
652         IF(lwp) WRITE(numout,*) '   ==>>>   Internal wave-driven mixing case:   force   rn_emin = 1.e-10 and rmxl_min = 1.e-3'
653      ELSE                          ! standard case : associated avt minimum = molecular viscosity (10^-6 m2/s)
654         rmxl_min = 1.e-6_wp / ( rn_ediff * SQRT( rn_emin ) )    ! resulting minimum length to recover molecular viscosity
655         IF(lwp) WRITE(numout,*) '   ==>>>   minimum mixing length with your parameters rmxl_min = ', rmxl_min
656      ENDIF
657      !
658      !                              ! allocate tke arrays
659      IF( zdf_tke_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'zdf_tke_init : unable to allocate arrays' )
660      !
661      !                               !* Check of some namelist values
662      IF( nn_mxl  < 0   .OR.  nn_mxl  > 3 )   CALL ctl_stop( 'bad flag: nn_mxl is  0, 1 or 2 ' )
663      IF( nn_pdl  < 0   .OR.  nn_pdl  > 1 )   CALL ctl_stop( 'bad flag: nn_pdl is  0 or 1    ' )
664      IF( nn_htau < 0   .OR.  nn_htau > 1 )   CALL ctl_stop( 'bad flag: nn_htau is 0, 1 or 2 ' )
665      IF( nn_etau == 3 .AND. .NOT. ln_cpl )   CALL ctl_stop( 'nn_etau == 3 : HF taum only known in coupled mode' )
666      !
667      IF( ln_mxl0 ) THEN
668         IF(lwp) WRITE(numout,*)
669         IF(lwp) WRITE(numout,*) '   ==>>>   use a surface mixing length = F(stress) :   set rn_mxl0 = rmxl_min'
670         rn_mxl0 = rmxl_min
671      ENDIF
672     
673      IF( nn_etau == 2  )   CALL zdf_mxl( nit000, Kmm )      ! Initialization of nmln
674
675      !                               !* depth of penetration of surface tke
676      IF( nn_etau /= 0 ) THEN     
677         SELECT CASE( nn_htau )             ! Choice of the depth of penetration
678         CASE( 0 )                                 ! constant depth penetration (here 10 meters)
679            htau(:,:) = 10._wp
680         CASE( 1 )                                 ! F(latitude) : 0.5m to 30m poleward of 40 degrees
681            htau(:,:) = MAX(  0.5_wp, MIN( 30._wp, 45._wp* ABS( SIN( rpi/180._wp * gphit(:,:) ) ) )   )           
682         END SELECT
683      ENDIF
684      !                                !* read or initialize all required files
685      CALL tke_rst( nit000, 'READ' )      ! (en, avt_k, avm_k, dissl)
686      !
687      IF( lwxios ) THEN
688         CALL iom_set_rstw_var_active('en')
689         CALL iom_set_rstw_var_active('avt_k')
690         CALL iom_set_rstw_var_active('avm_k')
691         CALL iom_set_rstw_var_active('dissl')
692      ENDIF
693   END SUBROUTINE zdf_tke_init
694
695
696   SUBROUTINE tke_rst( kt, cdrw )
697      !!---------------------------------------------------------------------
698      !!                   ***  ROUTINE tke_rst  ***
699      !!                     
700      !! ** Purpose :   Read or write TKE file (en) in restart file
701      !!
702      !! ** Method  :   use of IOM library
703      !!                if the restart does not contain TKE, en is either
704      !!                set to rn_emin or recomputed
705      !!----------------------------------------------------------------------
706      USE zdf_oce , ONLY : en, avt_k, avm_k   ! ocean vertical physics
707      !!
708      INTEGER         , INTENT(in) ::   kt     ! ocean time-step
709      CHARACTER(len=*), INTENT(in) ::   cdrw   ! "READ"/"WRITE" flag
710      !
711      INTEGER ::   jit, jk              ! dummy loop indices
712      INTEGER ::   id1, id2, id3, id4   ! local integers
713      !!----------------------------------------------------------------------
714      !
715      IF( TRIM(cdrw) == 'READ' ) THEN        ! Read/initialise
716         !                                   ! ---------------
717         IF( ln_rstart ) THEN                   !* Read the restart file
718            id1 = iom_varid( numror, 'en'   , ldstop = .FALSE. )
719            id2 = iom_varid( numror, 'avt_k', ldstop = .FALSE. )
720            id3 = iom_varid( numror, 'avm_k', ldstop = .FALSE. )
721            id4 = iom_varid( numror, 'dissl', ldstop = .FALSE. )
722            !
723            IF( MIN( id1, id2, id3, id4 ) > 0 ) THEN      ! fields exist
724               CALL iom_get( numror, jpdom_autoglo, 'en'   , en   , ldxios = lrxios )
725               CALL iom_get( numror, jpdom_autoglo, 'avt_k', avt_k, ldxios = lrxios )
726               CALL iom_get( numror, jpdom_autoglo, 'avm_k', avm_k, ldxios = lrxios )
727               CALL iom_get( numror, jpdom_autoglo, 'dissl', dissl, ldxios = lrxios )
728            ELSE                                          ! start TKE from rest
729               IF(lwp) WRITE(numout,*)
730               IF(lwp) WRITE(numout,*) '   ==>>>   previous run without TKE scheme, set en to background values'
731               en   (:,:,:) = rn_emin * wmask(:,:,:)
732               dissl(:,:,:) = 1.e-12_wp
733               ! avt_k, avm_k already set to the background value in zdf_phy_init
734            ENDIF
735         ELSE                                   !* Start from rest
736            IF(lwp) WRITE(numout,*)
737            IF(lwp) WRITE(numout,*) '   ==>>>   start from rest: set en to the background value'
738            en   (:,:,:) = rn_emin * wmask(:,:,:)
739            dissl(:,:,:) = 1.e-12_wp
740            ! avt_k, avm_k already set to the background value in zdf_phy_init
741         ENDIF
742         !
743      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN   ! Create restart file
744         !                                   ! -------------------
745         IF(lwp) WRITE(numout,*) '---- tke_rst ----'
746         IF( lwxios ) CALL iom_swap(      cwxios_context          ) 
747         CALL iom_rstput( kt, nitrst, numrow, 'en'   , en   , ldxios = lwxios )
748         CALL iom_rstput( kt, nitrst, numrow, 'avt_k', avt_k, ldxios = lwxios )
749         CALL iom_rstput( kt, nitrst, numrow, 'avm_k', avm_k, ldxios = lwxios )
750         CALL iom_rstput( kt, nitrst, numrow, 'dissl', dissl, ldxios = lwxios )
751         IF( lwxios ) CALL iom_swap(      cxios_context          )
752         !
753      ENDIF
754      !
755   END SUBROUTINE tke_rst
756
757   !!======================================================================
758END MODULE zdftke
Note: See TracBrowser for help on using the repository browser.