source: NEMO/trunk/src/OCE/nemogcm.F90 @ 9780

Last change on this file since 9780 was 9780, checked in by jchanut, 3 years ago

Reorganize Agrif update in a single subroutine ; use adjoint stepping for initial state update

  • Property svn:keywords set to Id
File size: 30.9 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!             -   ! 2011-11  (C. Harris) decomposition changes for running with CICE
31   !!            3.6  ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32   !!             -   ! 2014-12  (G. Madec) remove KPP scheme and cross-land advection (cla)
33   !!            4.0  ! 2016-10  (G. Madec, S. Flavoni)  domain configuration / user defined interface
34   !!----------------------------------------------------------------------
35
36   !!----------------------------------------------------------------------
37   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
38   !!   nemo_init     : initialization of the NEMO system
39   !!   nemo_ctl      : initialisation of the contol print
40   !!   nemo_closefile: close remaining open files
41   !!   nemo_alloc    : dynamical allocation
42   !!----------------------------------------------------------------------
43   USE step_oce       ! module used in the ocean time stepping module (step.F90)
44   USE phycst         ! physical constant                  (par_cst routine)
45   USE domain         ! domain initialization   (dom_init & dom_cfg routines)
46   USE closea         ! treatment of closed seas (for ln_closea)
47   USE usrdef_nam     ! user defined configuration
48   USE tideini        ! tidal components initialization   (tide_ini routine)
49   USE bdy_oce,  ONLY : ln_bdy
50   USE bdyini         ! open boundary cond. setting       (bdy_init routine)
51   USE istate         ! initial state setting          (istate_init routine)
52   USE ldfdyn         ! lateral viscosity setting      (ldfdyn_init routine)
53   USE ldftra         ! lateral diffusivity setting    (ldftra_init routine)
54   USE trdini         ! dyn/tra trends initialization     (trd_init routine)
55   USE asminc         ! assimilation increments     
56   USE asmbkg         ! writing out state trajectory
57   USE diaptr         ! poleward transports           (dia_ptr_init routine)
58   USE diadct         ! sections transports           (dia_dct_init routine)
59   USE diaobs         ! Observation diagnostics       (dia_obs_init routine)
60   USE diacfl         ! CFL diagnostics               (dia_cfl_init routine)
61   USE step           ! NEMO time-stepping                 (stp     routine)
62   USE icbini         ! handle bergs, initialisation
63   USE icbstp         ! handle bergs, calving, themodynamics and transport
64   USE cpl_oasis3     ! OASIS3 coupling
65   USE c1d            ! 1D configuration
66   USE step_c1d       ! Time stepping loop for the 1D configuration
67   USE dyndmp         ! Momentum damping
68   USE stopar         ! Stochastic param.: ???
69   USE stopts         ! Stochastic param.: ???
70   USE diurnal_bulk   ! diurnal bulk SST
71   USE step_diu       ! diurnal bulk SST timestepping (called from here if run offline)
72   USE crsini         ! initialise grid coarsening utility
73   USE diatmb         ! Top,middle,bottom output
74   USE dia25h         ! 25h mean output
75   USE sbc_oce , ONLY : lk_oasis
76   USE wet_dry        ! Wetting and drying setting   (wad_init routine)
77#if defined key_top
78   USE trcini         ! passive tracer initialisation
79#endif
80#if defined key_nemocice_decomp
81   USE ice_domain_size, only: nx_global, ny_global
82#endif
83   !
84   USE lib_mpp        ! distributed memory computing
85   USE mppini         ! shared/distributed memory setting (mpp_init routine)
86   USE lbcnfd  , ONLY : isendto, nsndto, nfsloop, nfeloop   ! Setup of north fold exchanges
87   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
88#if defined key_iomput
89   USE xios           ! xIOserver
90#endif
91#if defined key_agrif
92   USE agrif_all_update   ! Master Agrif update
93#endif
94
95   IMPLICIT NONE
96   PRIVATE
97
98   PUBLIC   nemo_gcm    ! called by model.F90
99   PUBLIC   nemo_init   ! needed by AGRIF
100   PUBLIC   nemo_alloc  ! needed by TAM
101
102   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
103
104   !!----------------------------------------------------------------------
105   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
106   !! $Id$
107   !! Software governed by the CeCILL licence     (./LICENSE)
108   !!----------------------------------------------------------------------
109CONTAINS
110
111   SUBROUTINE nemo_gcm
112      !!----------------------------------------------------------------------
113      !!                     ***  ROUTINE nemo_gcm  ***
114      !!
115      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
116      !!              curvilinear mesh on the sphere.
117      !!
118      !! ** Method  : - model general initialization
119      !!              - launch the time-stepping (stp routine)
120      !!              - finalize the run by closing files and communications
121      !!
122      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
123      !!              Madec, 2008, internal report, IPSL.
124      !!----------------------------------------------------------------------
125      INTEGER ::   istp   ! time step index
126      !!----------------------------------------------------------------------
127      !
128#if defined key_agrif
129      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
130#endif
131      !                            !-----------------------!
132      CALL nemo_init               !==  Initialisations  ==!
133      !                            !-----------------------!
134#if defined key_agrif
135      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
136      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
137# if defined key_top
138      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
139# endif
140# if defined key_si3
141      CALL Agrif_Declare_Var_ice   !  "      "   "   "      "  Sea ice
142# endif
143#endif
144      ! check that all process are still there... If some process have an error,
145      ! they will never enter in step and other processes will wait until the end of the cpu time!
146      IF( lk_mpp )   CALL mpp_max( nstop )
147
148      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
149
150      !                            !-----------------------!
151      !                            !==   time stepping   ==!
152      !                            !-----------------------!
153      istp = nit000
154      !
155#if defined key_c1d
156      DO WHILE ( istp <= nitend .AND. nstop == 0 )    !==  C1D time-stepping  ==!
157         CALL stp_c1d( istp )
158         istp = istp + 1
159      END DO
160#else
161      !
162# if defined key_agrif
163      !                                               !==  AGRIF time-stepping  ==!
164      CALL Agrif_Regrid()
165      !
166      ! Recursive update from highest nested level to lowest:
167      CALL Agrif_step_child_adj(Agrif_Update_All)
168      !
169      DO WHILE( istp <= nitend .AND. nstop == 0 )
170         CALL stp
171         istp = istp + 1
172      END DO
173      !
174      IF( .NOT. Agrif_Root() ) THEN
175         CALL Agrif_ParentGrid_To_ChildGrid()
176         IF( ln_diaobs )   CALL dia_obs_wri
177         IF( ln_timing )   CALL timing_finalize
178         CALL Agrif_ChildGrid_To_ParentGrid()
179      ENDIF
180      !
181# else
182      !
183      IF( .NOT.ln_diurnal_only ) THEN                 !==  Standard time-stepping  ==!
184         !
185         DO WHILE( istp <= nitend .AND. nstop == 0 )
186            CALL stp        ( istp ) 
187            istp = istp + 1
188         END DO
189         !
190      ELSE                                            !==  diurnal SST time-steeping only  ==!
191         !
192         DO WHILE( istp <= nitend .AND. nstop == 0 )
193            CALL stp_diurnal( istp )   ! time step only the diurnal SST
194            istp = istp + 1
195         END DO
196         !
197      ENDIF
198      !
199# endif
200      !
201#endif
202      !
203      IF( ln_diaobs   )   CALL dia_obs_wri
204      !
205      IF( ln_icebergs )   CALL icb_end( nitend )
206
207      !                            !------------------------!
208      !                            !==  finalize the run  ==!
209      !                            !------------------------!
210      IF(lwp) WRITE(numout,cform_aaa)        ! Flag AAAAAAA
211      !
212      IF( nstop /= 0 .AND. lwp ) THEN        ! error print
213         WRITE(numout,cform_err)
214         WRITE(numout,*) '   ==>>>   nemo_gcm: a total of ', nstop, ' errors have been found'
215         WRITE(numout,*)
216      ENDIF
217      !
218      IF( ln_timing )   CALL timing_finalize
219      !
220      CALL nemo_closefile
221      !
222#if defined key_iomput
223                                    CALL xios_finalize  ! end mpp communications with xios
224      IF( lk_oasis     )            CALL cpl_finalize   ! end coupling and mpp communications with OASIS
225#else
226      IF    ( lk_oasis ) THEN   ;   CALL cpl_finalize   ! end coupling and mpp communications with OASIS
227      ELSEIF( lk_mpp   ) THEN   ;   CALL mppstop        ! end mpp communications
228      ENDIF
229#endif
230      !
231   END SUBROUTINE nemo_gcm
232
233
234   SUBROUTINE nemo_init
235      !!----------------------------------------------------------------------
236      !!                     ***  ROUTINE nemo_init  ***
237      !!
238      !! ** Purpose :   initialization of the NEMO GCM
239      !!----------------------------------------------------------------------
240      INTEGER  ::   ji                 ! dummy loop indices
241      INTEGER  ::   ios, ilocal_comm   ! local integers
242      CHARACTER(len=120), DIMENSION(60) ::   cltxt, cltxt2, clnam
243      !!
244      NAMELIST/namctl/ ln_ctl   , nn_print, nn_ictls, nn_ictle,   &
245         &             nn_isplt , nn_jsplt, nn_jctls, nn_jctle,   &
246         &             ln_timing, ln_diacfl
247      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
248      !!----------------------------------------------------------------------
249      !
250      cltxt  = ''
251      cltxt2 = ''
252      clnam  = '' 
253      cxios_context = 'nemo'
254      !
255      !                             ! Open reference namelist and configuration namelist files
256      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
257      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
258      !
259      REWIND( numnam_ref )              ! Namelist namctl in reference namelist
260      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
261901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
262      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist
263      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
264902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
265      !
266      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist
267      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
268903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
269      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist
270      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
271904   IF( ios >  0 )   CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
272
273      !                             !--------------------------!
274      !                             !  Set global domain size  !   (control print return in cltxt2)
275      !                             !--------------------------!
276      IF( ln_read_cfg ) THEN              ! Read sizes in domain configuration file
277         CALL domain_cfg ( cltxt2,        cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
278         !
279      ELSE                                ! user-defined namelist
280         CALL usr_def_nam( cltxt2, clnam, cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
281      ENDIF
282      !
283      !
284      !                             !--------------------------------------------!
285      !                             !  set communicator & select the local node  !
286      !                             !  NB: mynode also opens output.namelist.dyn !
287      !                             !      on unit number numond on first proc   !
288      !                             !--------------------------------------------!
289#if defined key_iomput
290      IF( Agrif_Root() ) THEN
291         IF( lk_oasis ) THEN
292            CALL cpl_init( "oceanx", ilocal_comm )                               ! nemo local communicator given by oasis
293            CALL xios_initialize( "not used"       ,local_comm= ilocal_comm )    ! send nemo communicator to xios
294         ELSE
295            CALL xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )    ! nemo local communicator given by xios
296         ENDIF
297      ENDIF
298      ! Nodes selection (control print return in cltxt)
299      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
300#else
301      IF( lk_oasis ) THEN
302         IF( Agrif_Root() ) THEN
303            CALL cpl_init( "oceanx", ilocal_comm )          ! nemo local communicator given by oasis
304         ENDIF
305         ! Nodes selection (control print return in cltxt)
306         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
307      ELSE
308         ilocal_comm = 0                                    ! Nodes selection (control print return in cltxt)
309         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )
310      ENDIF
311#endif
312
313      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
314
315      lwm = (narea == 1)                                    ! control of output namelists
316      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
317
318      IF(lwm) THEN               ! write merged namelists from earlier to output namelist
319         !                       ! now that the file has been opened in call to mynode.
320         !                       ! NB: nammpp has already been written in mynode (if lk_mpp_mpi)
321         WRITE( numond, namctl )
322         WRITE( numond, namcfg )
323         IF( .NOT.ln_read_cfg ) THEN
324            DO ji = 1, SIZE(clnam)
325               IF( TRIM(clnam(ji)) /= '' )   WRITE(numond, * ) clnam(ji)     ! namusr_def print
326            END DO
327         ENDIF
328      ENDIF
329
330      IF(lwp) THEN                            ! open listing units
331         !
332         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
333         !
334         WRITE(numout,*)
335         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
336         WRITE(numout,*) '                       NEMO team'
337         WRITE(numout,*) '            Ocean General Circulation Model'
338         WRITE(numout,*) '                NEMO version 4.0  (2017) '
339         WRITE(numout,*)
340         WRITE(numout,*)
341         DO ji = 1, SIZE(cltxt)
342            IF( TRIM(cltxt (ji)) /= '' )   WRITE(numout,*) cltxt(ji)    ! control print of mynode
343         END DO
344         WRITE(numout,*)
345         WRITE(numout,*)
346         DO ji = 1, SIZE(cltxt2)
347            IF( TRIM(cltxt2(ji)) /= '' )   WRITE(numout,*) cltxt2(ji)   ! control print of domain size
348         END DO
349         !
350         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
351         !
352      ENDIF
353      !                                      ! Domain decomposition
354      CALL mpp_init                          ! MPP
355
356      ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
357      CALL nemo_alloc()
358
359      !                             !-------------------------------!
360      !                             !  NEMO general initialization  !
361      !                             !-------------------------------!
362
363      CALL nemo_ctl                          ! Control prints
364      !
365      !                                      ! General initialization
366      IF( ln_timing    )   CALL timing_init     ! timing
367      IF( ln_timing    )   CALL timing_start( 'nemo_init')
368      !
369                           CALL     phy_cst         ! Physical constants
370                           CALL     eos_init        ! Equation of state
371      IF( lk_c1d       )   CALL     c1d_init        ! 1D column configuration
372                           CALL     wad_init        ! Wetting and drying options
373                           CALL     dom_init("OPA") ! Domain
374      IF( ln_crs       )   CALL     crs_init        ! coarsened grid: domain initialization
375      IF( ln_ctl       )   CALL prt_ctl_init        ! Print control
376     
377      CALL diurnal_sst_bulk_init                ! diurnal sst
378      IF( ln_diurnal   )   CALL diurnal_sst_coolskin_init   ! cool skin   
379      !                           
380      IF( ln_diurnal_only ) THEN                   ! diurnal only: a subset of the initialisation routines
381         CALL  istate_init                            ! ocean initial state (Dynamics and tracers)
382         CALL     sbc_init                            ! Forcings : surface module
383         CALL tra_qsr_init                            ! penetrative solar radiation qsr
384         IF( ln_diaobs ) THEN                         ! Observation & model comparison
385            CALL dia_obs_init                            ! Initialize observational data
386            CALL dia_obs( nit000 - 1 )                   ! Observation operator for restart
387         ENDIF     
388         IF( lk_asminc )   CALL asm_inc_init          ! Assimilation increments
389         !
390         RETURN                                       ! end of initialization
391      ENDIF
392     
393                           CALL  istate_init    ! ocean initial state (Dynamics and tracers)
394
395      !                                      ! external forcing
396                           CALL    tide_init    ! tidal harmonics
397                           CALL     sbc_init    ! surface boundary conditions (including sea-ice)
398                           CALL     bdy_init    ! Open boundaries initialisation
399
400      !                                      ! Ocean physics
401                           CALL zdf_phy_init    ! Vertical physics
402                                     
403      !                                         ! Lateral physics
404                           CALL ldf_tra_init      ! Lateral ocean tracer physics
405                           CALL ldf_eiv_init      ! eddy induced velocity param.
406                           CALL ldf_dyn_init      ! Lateral ocean momentum physics
407
408      !                                      ! Active tracers
409      IF( ln_traqsr    )   CALL tra_qsr_init      ! penetrative solar radiation qsr
410                           CALL tra_bbc_init      ! bottom heat flux
411      IF( ln_trabbl    )   CALL tra_bbl_init      ! advective (and/or diffusive) bottom boundary layer scheme
412                           CALL tra_dmp_init      ! internal tracer damping
413                           CALL tra_adv_init      ! horizontal & vertical advection
414                           CALL tra_ldf_init      ! lateral mixing
415
416      !                                      ! Dynamics
417      IF( lk_c1d       )   CALL dyn_dmp_init      ! internal momentum damping
418                           CALL dyn_adv_init      ! advection (vector or flux form)
419                           CALL dyn_vor_init      ! vorticity term including Coriolis
420                           CALL dyn_ldf_init      ! lateral mixing
421                           CALL dyn_hpg_init      ! horizontal gradient of Hydrostatic pressure
422                           CALL dyn_spg_init      ! surface pressure gradient
423
424#if defined key_top
425      !                                      ! Passive tracers
426                           CALL     trc_init
427#endif
428      IF( l_ldfslp     )   CALL ldf_slp_init    ! slope of lateral mixing
429
430      !                                      ! Icebergs
431                           CALL icb_init( rdt, nit000)   ! initialise icebergs instance
432
433      !                                      ! Misc. options
434                           CALL sto_par_init    ! Stochastic parametrization
435      IF( ln_sto_eos   )   CALL sto_pts_init    ! RRandom T/S fluctuations
436     
437      !                                      ! Diagnostics
438      IF( lk_floats    )   CALL     flo_init    ! drifting Floats
439      IF( ln_diacfl    )   CALL dia_cfl_init    ! Initialise CFL diagnostics
440                           CALL dia_ptr_init    ! Poleward TRansports initialization
441      IF( lk_diadct    )   CALL dia_dct_init    ! Sections tranports
442                           CALL dia_hsb_init    ! heat content, salt content and volume budgets
443                           CALL     trd_init    ! Mixed-layer/Vorticity/Integral constraints trends
444                           CALL dia_obs_init    ! Initialize observational data
445                           CALL dia_tmb_init    ! TMB outputs
446                           CALL dia_25h_init    ! 25h mean  outputs
447      IF( ln_diaobs    )   CALL dia_obs( nit000-1 )   ! Observation operator for restart
448
449      !                                      ! Assimilation increments
450      IF( lk_asminc    )   CALL asm_inc_init    ! Initialize assimilation increments
451      !
452      IF(lwp) WRITE(numout,cform_aaa)           ! Flag AAAAAAA
453      !
454      IF( ln_timing    )   CALL timing_stop( 'nemo_init')
455      !
456   END SUBROUTINE nemo_init
457
458
459   SUBROUTINE nemo_ctl
460      !!----------------------------------------------------------------------
461      !!                     ***  ROUTINE nemo_ctl  ***
462      !!
463      !! ** Purpose :   control print setting
464      !!
465      !! ** Method  : - print namctl information and check some consistencies
466      !!----------------------------------------------------------------------
467      !
468      IF(lwp) THEN                  ! control print
469         WRITE(numout,*)
470         WRITE(numout,*) 'nemo_ctl: Control prints'
471         WRITE(numout,*) '~~~~~~~~'
472         WRITE(numout,*) '   Namelist namctl'
473         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
474         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
475         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
476         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
477         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
478         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
479         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
480         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
481         WRITE(numout,*) '      timing by routine               ln_timing  = ', ln_timing
482         WRITE(numout,*) '      CFL diagnostics                 ln_diacfl  = ', ln_diacfl
483      ENDIF
484      !
485      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
486      nictls    = nn_ictls
487      nictle    = nn_ictle
488      njctls    = nn_jctls
489      njctle    = nn_jctle
490      isplt     = nn_isplt
491      jsplt     = nn_jsplt
492
493      IF(lwp) THEN                  ! control print
494         WRITE(numout,*)
495         WRITE(numout,*) '   Namelist namcfg'
496         WRITE(numout,*) '      read domain configuration file                ln_read_cfg      = ', ln_read_cfg
497         WRITE(numout,*) '         filename to be read                           cn_domcfg     = ', TRIM(cn_domcfg)
498         WRITE(numout,*) '         keep closed seas in the domain (if exist)     ln_closea     = ', ln_closea
499         WRITE(numout,*) '      create a configuration definition file        ln_write_cfg     = ', ln_write_cfg
500         WRITE(numout,*) '         filename to be written                        cn_domcfg_out = ', TRIM(cn_domcfg_out)
501         WRITE(numout,*) '      use file attribute if exists as i/p j-start   ln_use_jattr     = ', ln_use_jattr
502      ENDIF
503      IF( .NOT.ln_read_cfg )   ln_closea = .false.   ! dealing possible only with a domcfg file
504      !
505      !                             ! Parameter control
506      !
507      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
508         IF( lk_mpp .AND. jpnij > 1 ) THEN
509            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
510         ELSE
511            IF( isplt == 1 .AND. jsplt == 1  ) THEN
512               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
513                  &           ' - the print control will be done over the whole domain' )
514            ENDIF
515            ijsplt = isplt * jsplt            ! total number of processors ijsplt
516         ENDIF
517         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
518         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
519         !
520         !                              ! indices used for the SUM control
521         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
522            lsp_area = .FALSE.
523         ELSE                                             ! print control done over a specific  area
524            lsp_area = .TRUE.
525            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
526               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
527               nictls = 1
528            ENDIF
529            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
530               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
531               nictle = jpiglo
532            ENDIF
533            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
534               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
535               njctls = 1
536            ENDIF
537            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
538               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
539               njctle = jpjglo
540            ENDIF
541         ENDIF
542      ENDIF
543      !
544      IF( 1._wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.',  &
545         &                                                'Compile with key_nosignedzero enabled' )
546      !
547#if defined key_agrif
548      IF( ln_timing )   CALL ctl_stop( 'AGRIF not implemented with ln_timing = true')
549#endif
550      !
551   END SUBROUTINE nemo_ctl
552
553
554   SUBROUTINE nemo_closefile
555      !!----------------------------------------------------------------------
556      !!                     ***  ROUTINE nemo_closefile  ***
557      !!
558      !! ** Purpose :   Close the files
559      !!----------------------------------------------------------------------
560      !
561      IF( lk_mpp )   CALL mppsync
562      !
563      CALL iom_close                                 ! close all input/output files managed by iom_*
564      !
565      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
566      IF( numrun          /= -1 )   CLOSE( numrun          )   ! run statistics file
567      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
568      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
569      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
570      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
571      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
572      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
573      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
574      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
575      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
576      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
577      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
578      !
579      numout = 6                                     ! redefine numout in case it is used after this point...
580      !
581   END SUBROUTINE nemo_closefile
582
583
584   SUBROUTINE nemo_alloc
585      !!----------------------------------------------------------------------
586      !!                     ***  ROUTINE nemo_alloc  ***
587      !!
588      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
589      !!
590      !! ** Method  :
591      !!----------------------------------------------------------------------
592      USE diawri    , ONLY : dia_wri_alloc
593      USE dom_oce   , ONLY : dom_oce_alloc
594      USE trc_oce   , ONLY : trc_oce_alloc
595      USE bdy_oce   , ONLY : bdy_oce_alloc
596#if defined key_diadct 
597      USE diadct    , ONLY : diadct_alloc 
598#endif 
599      !
600      INTEGER :: ierr
601      !!----------------------------------------------------------------------
602      !
603      ierr =        oce_alloc    ()    ! ocean
604      ierr = ierr + dia_wri_alloc()
605      ierr = ierr + dom_oce_alloc()    ! ocean domain
606      ierr = ierr + zdf_oce_alloc()    ! ocean vertical physics
607      ierr = ierr + trc_oce_alloc()    ! shared TRC / TRA arrays
608      ierr = ierr + bdy_oce_alloc()    ! bdy masks (incl. initialization)
609      !
610#if defined key_diadct 
611      ierr = ierr + diadct_alloc ()    !
612#endif 
613      !
614      IF( lk_mpp    )   CALL mpp_sum( ierr )
615      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
616      !
617   END SUBROUTINE nemo_alloc
618
619   !!======================================================================
620END MODULE nemogcm
621
Note: See TracBrowser for help on using the repository browser.