source: NEMO/trunk/src/OCE/step.F90 @ 14010

Last change on this file since 14010 was 14010, checked in by gsamson, 6 months ago

merge dev_r2052_ENHANCE-09_rbourdal_massfluxconvection into trunk

  • Property svn:keywords set to Id
File size: 24.3 KB
Line 
1MODULE step
2   !!======================================================================
3   !!                       ***  MODULE step  ***
4   !! Time-stepping   : manager of the ocean, tracer and ice time stepping
5   !!======================================================================
6   !! History :  OPA  !  1991-03  (G. Madec)  Original code
7   !!             -   !  1991-11  (G. Madec)
8   !!             -   !  1992-06  (M. Imbard)  add a first output record
9   !!             -   !  1996-04  (G. Madec)  introduction of dynspg
10   !!             -   !  1996-04  (M.A. Foujols)  introduction of passive tracer
11   !!            8.0  !  1997-06  (G. Madec)  new architecture of call
12   !!            8.2  !  1997-06  (G. Madec, M. Imbard, G. Roullet)  free surface
13   !!             -   !  1999-02  (G. Madec, N. Grima)  hpg implicit
14   !!             -   !  2000-07  (J-M Molines, M. Imbard)  Open Bondary Conditions
15   !!   NEMO     1.0  !  2002-06  (G. Madec)  free form, suppress macro-tasking
16   !!             -   !  2004-08  (C. Talandier) New trends organization
17   !!             -   !  2005-01  (C. Ethe) Add the KPP closure scheme
18   !!             -   !  2005-11  (G. Madec)  Reorganisation of tra and dyn calls
19   !!             -   !  2006-01  (L. Debreu, C. Mazauric)  Agrif implementation
20   !!             -   !  2006-07  (S. Masson)  restart using iom
21   !!            3.2  !  2009-02  (G. Madec, R. Benshila)  reintroduicing z*-coordinate
22   !!             -   !  2009-06  (S. Masson, G. Madec)  TKE restart compatible with key_cpl
23   !!            3.3  !  2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
24   !!             -   !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase + merge TRC-TRA
25   !!            3.4  !  2011-04  (G. Madec, C. Ethe) Merge of dtatem and dtasal
26   !!            3.6  !  2012-07  (J. Simeon, G. Madec. C. Ethe)  Online coarsening of outputs
27   !!            3.6  !  2014-04  (F. Roquet, G. Madec) New equations of state
28   !!            3.6  !  2014-10  (E. Clementi, P. Oddo) Add Qiao vertical mixing in case of waves
29   !!            3.7  !  2014-10  (G. Madec)  LDF simplication
30   !!             -   !  2014-12  (G. Madec) remove KPP scheme
31   !!             -   !  2015-11  (J. Chanut) free surface simplification (remove filtered free surface)
32   !!            4.0  !  2017-05  (G. Madec)  introduction of the vertical physics manager (zdfphy)
33   !!            4.1  !  2019-08  (A. Coward, D. Storkey) rewrite in preparation for new timestepping scheme
34   !!----------------------------------------------------------------------
35#if defined key_qco
36   !!----------------------------------------------------------------------
37   !!   'key_qco'      EMPTY MODULE      Quasi-Eulerian vertical coordonate
38   !!----------------------------------------------------------------------
39#else
40   !!----------------------------------------------------------------------
41   !!   stp             : OPA system time-stepping
42   !!----------------------------------------------------------------------
43   USE step_oce         ! time stepping definition modules
44   !
45   USE iom              ! xIOs server
46
47   IMPLICIT NONE
48   PRIVATE
49
50   PUBLIC   stp   ! called by nemogcm.F90
51
52   !!----------------------------------------------------------------------
53   !! time level indices
54   !!----------------------------------------------------------------------
55   INTEGER, PUBLIC :: Nbb, Nnn, Naa, Nrhs          !! used by nemo_init
56
57   !! * Substitutions
58#  include "do_loop_substitute.h90"
59   !!----------------------------------------------------------------------
60   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
61   !! $Id$
62   !! Software governed by the CeCILL license (see ./LICENSE)
63   !!----------------------------------------------------------------------
64CONTAINS
65
66#if defined key_agrif
67   RECURSIVE SUBROUTINE stp( )
68      INTEGER             ::   kstp   ! ocean time-step index
69#else
70   SUBROUTINE stp( kstp )
71      INTEGER, INTENT(in) ::   kstp   ! ocean time-step index
72#endif
73      !!----------------------------------------------------------------------
74      !!                     ***  ROUTINE stp  ***
75      !!
76      !! ** Purpose : - Time stepping of OPA  (momentum and active tracer eqs.)
77      !!              - Time stepping of SI3 (dynamic and thermodynamic eqs.)
78      !!              - Time stepping of TRC  (passive tracer eqs.)
79      !!
80      !! ** Method  : -1- Update forcings and data
81      !!              -2- Update ocean physics
82      !!              -3- Compute the t and s trends
83      !!              -4- Update t and s
84      !!              -5- Compute the momentum trends
85      !!              -6- Update the horizontal velocity
86      !!              -7- Compute the diagnostics variables (rd,N2, hdiv,w)
87      !!              -8- Outputs and diagnostics
88      !!----------------------------------------------------------------------
89      INTEGER ::   ji, jj, jk, jtile   ! dummy loop indice
90!!gm kcall can be removed, I guess
91      INTEGER ::   kcall        ! optional integer argument (dom_vvl_sf_nxt)
92      !! ---------------------------------------------------------------------
93#if defined key_agrif
94      IF( nstop > 0 ) RETURN   ! avoid to go further if an error was detected during previous time step (child grid)
95      kstp = nit000 + Agrif_Nb_Step()
96      Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs   ! agrif_oce module copies of time level indices
97      IF( lk_agrif_debug ) THEN
98         IF( Agrif_Root() .and. lwp)   WRITE(*,*) '---'
99         IF(lwp)   WRITE(*,*) 'Grid Number', Agrif_Fixed(),' time step ', kstp, 'int tstep', Agrif_NbStepint()
100      ENDIF
101      IF( kstp == nit000 + 1 )   lk_agrif_fstep = .FALSE.
102# if defined key_iomput
103      IF( Agrif_Nbstepint() == 0 )   CALL iom_swap( cxios_context )
104# endif
105#endif
106      !
107      IF( ln_timing )   CALL timing_start('stp')
108      !
109      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
110      ! model timestep
111      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
112      !
113      IF( l_1st_euler ) THEN 
114         ! start or restart with Euler 1st time-step
115         rDt =  rn_Dt   
116         r1_Dt = 1._wp / rDt
117      ENDIF
118      !
119      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
120      ! update I/O and calendar
121      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
122      IF( kstp == nit000 ) THEN                       ! initialize IOM context (must be done after nemo_init for AGRIF+XIOS+OASIS)
123                             CALL iom_init( cxios_context, ld_closedef=.FALSE. )   ! for model grid (including possible AGRIF zoom)
124         IF( lk_diamlr   )   CALL dia_mlr_iom_init    ! with additional setup for multiple-linear-regression analysis
125                             CALL iom_init_closedef
126         IF( ln_crs      )   CALL iom_init( TRIM(cxios_context)//"_crs" )  ! for coarse grid
127      ENDIF
128      IF((kstp == nitrst) .AND. lwxios) THEN
129         CALL iom_swap(      cw_ocerst_cxt          )
130         CALL iom_init_closedef(cw_ocerst_cxt)
131         CALL iom_setkt( kstp - nit000 + 1,      cw_ocerst_cxt          )
132#if defined key_top
133         CALL iom_swap(      cw_toprst_cxt          )
134         CALL iom_init_closedef(cw_toprst_cxt)
135         CALL iom_setkt( kstp - nit000 + 1,      cw_toprst_cxt          )
136#endif
137      ENDIF
138#if defined key_si3
139      IF(((kstp + nn_fsbc - 1) == nitrst) .AND. lwxios) THEN
140         CALL iom_swap(      cw_icerst_cxt          )
141         CALL iom_init_closedef(cw_icerst_cxt)
142         CALL iom_setkt( kstp - nit000 + 1,      cw_icerst_cxt          )
143      ENDIF
144#endif
145      IF( kstp /= nit000 )   CALL day( kstp )         ! Calendar (day was already called at nit000 in day_init)
146                             CALL iom_setkt( kstp - nit000 + 1,      cxios_context          )   ! tell IOM we are at time step kstp
147      IF( ln_crs         )   CALL iom_setkt( kstp - nit000 + 1, TRIM(cxios_context)//"_crs" )   ! tell IOM we are at time step kstp
148
149      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
150      ! Update external forcing (tides, open boundaries, ice shelf interaction and surface boundary condition (including sea-ice)
151      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
152      IF( ln_tide    )   CALL tide_update( kstp )                     ! update tide potential
153      IF( ln_apr_dyn )   CALL sbc_apr ( kstp )                        ! atmospheric pressure (NB: call before bdy_dta which needs ssh_ib)
154      IF( ln_bdy     )   CALL bdy_dta ( kstp, Nnn )                   ! update dynamic & tracer data at open boundaries
155      IF( ln_isf     )   CALL isf_stp ( kstp, Nnn )
156                         CALL sbc     ( kstp, Nbb, Nnn )              ! Sea Boundary Condition (including sea-ice)
157
158      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
159      ! Update stochastic parameters and random T/S fluctuations
160      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
161      IF( ln_sto_eos ) CALL sto_par( kstp )          ! Stochastic parameters
162      IF( ln_sto_eos ) CALL sto_pts( ts(:,:,:,:,Nnn)  )          ! Random T/S fluctuations
163
164      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
165      ! Ocean physics update
166      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
167      !  THERMODYNAMICS
168                         CALL eos_rab( ts(:,:,:,:,Nbb), rab_b, Nnn )       ! before local thermal/haline expension ratio at T-points
169                         CALL eos_rab( ts(:,:,:,:,Nnn), rab_n, Nnn )       ! now    local thermal/haline expension ratio at T-points
170                         CALL bn2    ( ts(:,:,:,:,Nbb), rab_b, rn2b, Nnn ) ! before Brunt-Vaisala frequency
171                         CALL bn2    ( ts(:,:,:,:,Nnn), rab_n, rn2, Nnn  ) ! now    Brunt-Vaisala frequency
172
173      !  VERTICAL PHYSICS
174                         CALL zdf_phy( kstp, Nbb, Nnn, Nrhs )   ! vertical physics update (top/bot drag, avt, avs, avm + MLD)
175
176      !  LATERAL  PHYSICS
177      !
178      IF( l_ldfslp ) THEN                             ! slope of lateral mixing
179                         CALL eos( ts(:,:,:,:,Nbb), rhd, gdept_0(:,:,:) )               ! before in situ density
180
181         IF( ln_zps .AND. .NOT. ln_isfcav)                                    &
182            &            CALL zps_hde    ( kstp, Nnn, jpts, ts(:,:,:,:,Nbb), gtsu, gtsv,  &  ! Partial steps: before horizontal gradient
183            &                                          rhd, gru , grv    )       ! of t, s, rd at the last ocean level
184
185         IF( ln_zps .AND.       ln_isfcav)                                                &
186            &            CALL zps_hde_isf( kstp, Nnn, jpts, ts(:,:,:,:,Nbb), gtsu, gtsv, gtui, gtvi,  &  ! Partial steps for top cell (ISF)
187            &                                          rhd, gru , grv , grui, grvi   )       ! of t, s, rd at the first ocean level
188         IF( ln_traldf_triad ) THEN
189                         CALL ldf_slp_triad( kstp, Nbb, Nnn )             ! before slope for triad operator
190         ELSE     
191                         CALL ldf_slp     ( kstp, rhd, rn2b, Nbb, Nnn )   ! before slope for standard operator
192         ENDIF
193      ENDIF
194      !                                                                        ! eddy diffusivity coeff.
195      IF( l_ldftra_time .OR. l_ldfeiv_time )   CALL ldf_tra( kstp, Nbb, Nnn )  !       and/or eiv coeff.
196      IF( l_ldfdyn_time                    )   CALL ldf_dyn( kstp, Nbb )       ! eddy viscosity coeff.
197
198      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
199      !  Ocean dynamics : hdiv, ssh, e3, u, v, w
200      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
201
202                            CALL ssh_nxt       ( kstp, Nbb, Nnn, ssh, Naa )    ! after ssh (includes call to div_hor)
203      IF( .NOT.ln_linssh )  CALL dom_vvl_sf_nxt( kstp, Nbb, Nnn,      Naa )    ! after vertical scale factors
204                            CALL wzv           ( kstp, Nbb, Nnn, Naa, ww  )    ! now cross-level velocity
205      IF( ln_zad_Aimp )     CALL wAimp         ( kstp,      Nnn           )  ! Adaptive-implicit vertical advection partitioning
206                            CALL eos    ( ts(:,:,:,:,Nnn), rhd, rhop, gdept(:,:,:,Nnn) )  ! now in situ density for hpg computation
207                           
208                           
209                         uu(:,:,:,Nrhs) = 0._wp            ! set dynamics trends to zero
210                         vv(:,:,:,Nrhs) = 0._wp
211
212      IF(  lk_asminc .AND. ln_asmiau .AND. ln_dyninc )   &
213               &         CALL dyn_asm_inc   ( kstp, Nbb, Nnn, uu, vv, Nrhs )  ! apply dynamics assimilation increment
214      IF( ln_bdy     )   CALL bdy_dyn3d_dmp ( kstp, Nbb,      uu, vv, Nrhs )  ! bdy damping trends
215#if defined key_agrif
216      IF(.NOT. Agrif_Root())  & 
217               &         CALL Agrif_Sponge_dyn        ! momentum sponge
218#endif
219                         CALL dyn_adv( kstp, Nbb, Nnn      , uu, vv, Nrhs )  ! advection (VF or FF)   ==> RHS
220                         CALL dyn_vor( kstp,      Nnn      , uu, vv, Nrhs )  ! vorticity              ==> RHS
221                         CALL dyn_ldf( kstp, Nbb, Nnn      , uu, vv, Nrhs )  ! lateral mixing
222      IF( ln_zdfosm  )   CALL dyn_osm( kstp,      Nnn      , uu, vv, Nrhs )  ! OSMOSIS non-local velocity fluxes ==> RHS
223                         CALL dyn_hpg( kstp,      Nnn      , uu, vv, Nrhs )  ! horizontal gradient of Hydrostatic pressure
224                         CALL dyn_spg( kstp, Nbb, Nnn, Nrhs, uu, vv, ssh, uu_b, vv_b, Naa )  ! surface pressure gradient
225
226                                                      ! With split-explicit free surface, since now transports have been updated and ssh(:,:,Nrhs) as well
227      IF( ln_dynspg_ts ) THEN                         ! vertical scale factors and vertical velocity need to be updated
228                            CALL div_hor       ( kstp, Nbb, Nnn )                ! Horizontal divergence  (2nd call in time-split case)
229         IF(.NOT.ln_linssh) CALL dom_vvl_sf_nxt( kstp, Nbb, Nnn, Naa, kcall=2 )  ! after vertical scale factors (update depth average component)
230      ENDIF
231                            CALL dyn_zdf    ( kstp, Nbb, Nnn, Nrhs, uu, vv, Naa  )  ! vertical diffusion
232      IF( ln_dynspg_ts ) THEN                                                       ! vertical scale factors and vertical velocity need to be updated
233                            CALL wzv        ( kstp, Nbb, Nnn, Naa, ww )             ! now cross-level velocity
234         IF( ln_zad_Aimp )  CALL wAimp      ( kstp,      Nnn )                      ! Adaptive-implicit vertical advection partitioning
235      ENDIF
236     
237
238      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
239      ! cool skin
240      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<     
241      IF ( ln_diurnal )  CALL diurnal_layers( kstp )
242     
243      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
244      ! diagnostics and outputs
245      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
246      IF( ln_floats  )   CALL flo_stp   ( kstp, Nbb, Nnn )      ! drifting Floats
247      IF( ln_diacfl  )   CALL dia_cfl   ( kstp,      Nnn )      ! Courant number diagnostics
248                         CALL dia_hth   ( kstp,      Nnn )      ! Thermocline depth (20 degres isotherm depth)
249      IF( ln_diadct  )   CALL dia_dct   ( kstp,      Nnn )      ! Transports
250                         CALL dia_ar5   ( kstp,      Nnn )      ! ar5 diag
251                         CALL dia_ptr   ( kstp,      Nnn )      ! Poleward adv/ldf TRansports diagnostics
252                         CALL dia_wri   ( kstp,      Nnn )      ! ocean model: outputs
253      IF( ln_crs     )   CALL crs_fld   ( kstp,      Nnn )      ! ocean model: online field coarsening & output
254      IF( lk_diadetide ) CALL dia_detide( kstp )                ! Weights computation for daily detiding of model diagnostics
255      IF( lk_diamlr  )   CALL dia_mlr                           ! Update time used in multiple-linear-regression analysis
256     
257#if defined key_top
258      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
259      ! Passive Tracer Model
260      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
261                         CALL trc_stp       ( kstp, Nbb, Nnn, Nrhs, Naa )  ! time-stepping
262#endif
263
264      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
265      ! Active tracers                             
266      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
267      ! Loop over tile domains
268      DO jtile = 1, nijtile
269         IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = jtile )
270
271         DO_3D( 0, 0, 0, 0, 1, jpk )
272            ts(ji,jj,jk,:,Nrhs) = 0._wp                                         ! set tracer trends to zero
273         END_3D
274
275         IF(  lk_asminc .AND. ln_asmiau .AND. &
276            & ln_trainc )   CALL tra_asm_inc( kstp, Nbb, Nnn, ts, Nrhs )  ! apply tracer assimilation increment
277                            CALL tra_sbc    ( kstp,      Nnn, ts, Nrhs )  ! surface boundary condition
278         IF( ln_traqsr  )   CALL tra_qsr    ( kstp,      Nnn, ts, Nrhs )  ! penetrative solar radiation qsr
279         IF( ln_isf     )   CALL tra_isf    ( kstp,      Nnn, ts, Nrhs )  ! ice shelf heat flux
280         IF( ln_trabbc  )   CALL tra_bbc    ( kstp,      Nnn, ts, Nrhs )  ! bottom heat flux
281         IF( ln_trabbl  )   CALL tra_bbl    ( kstp, Nbb, Nnn, ts, Nrhs )  ! advective (and/or diffusive) bottom boundary layer scheme
282         IF( ln_tradmp  )   CALL tra_dmp    ( kstp, Nbb, Nnn, ts, Nrhs )  ! internal damping trends
283         IF( ln_bdy     )   CALL bdy_tra_dmp( kstp, Nbb,      ts, Nrhs )  ! bdy damping trends
284      END DO
285
286#if defined key_agrif
287         IF(.NOT. Agrif_Root()) THEN
288            IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = 0 )
289            CALL Agrif_Sponge_tra        ! tracers sponge
290         ENDIF
291#endif
292
293      ! TEMP: [tiling] Separate loop over tile domains (due to tra_adv workarounds for tiling)
294      DO jtile = 1, nijtile
295         IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = jtile )
296
297                            CALL tra_adv    ( kstp, Nbb, Nnn, ts, Nrhs )  ! hor. + vert. advection ==> RHS
298         IF( ln_zdfmfc  )   CALL tra_mfc    ( kstp, Nbb,      ts, Nrhs )  ! Mass Flux Convection
299         IF( ln_zdfosm  )   CALL tra_osm    ( kstp,      Nnn, ts, Nrhs )  ! OSMOSIS non-local tracer fluxes ==> RHS
300         IF( lrst_oce .AND. ln_zdfosm ) &
301              &             CALL osm_rst    ( kstp,      Nnn, 'WRITE'  )  ! write OSMOSIS outputs + ww (so must do here) to restarts
302                            CALL tra_ldf    ( kstp, Nbb, Nnn, ts, Nrhs )  ! lateral mixing
303
304                            CALL tra_zdf    ( kstp, Nbb, Nnn, Nrhs, ts, Naa  )  ! vertical mixing and after tracer fields
305         IF( ln_zdfnpc  )   CALL tra_npc    ( kstp,      Nnn, Nrhs, ts, Naa  )  ! update after fields by non-penetrative convection
306      END DO
307
308      IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = 0 ) ! Revert to tile over full domain
309      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
310      ! Set boundary conditions, time filter and swap time levels
311      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
312!!jc1: For agrif, it would be much better to finalize tracers/momentum here (e.g. bdy conditions) and move the swap
313!!    (and time filtering) after Agrif update. Then restart would be done after and would contain updated fields.
314!!    If so:
315!!    (i) no need to call agrif update at initialization time
316!!    (ii) no need to update "before" fields
317!!
318!!    Apart from creating new tra_swp/dyn_swp routines, this however:
319!!    (i) makes boundary conditions at initialization time computed from updated fields which is not the case between
320!!    two restarts => restartability issue. One can circumvent this, maybe, by assuming "interface separation",
321!!    e.g. a shift of the feedback interface inside child domain.
322!!    (ii) requires that all restart outputs of updated variables by agrif (e.g. passive tracers/tke/barotropic arrays) are done at the same
323!!    place.
324!!
325!!jc2: dynnxt must be the latest call. e3t(:,:,:,Nbb) are indeed updated in that routine
326                         CALL tra_atf       ( kstp, Nbb, Nnn, Naa, ts )                      ! time filtering of "now" tracer arrays
327                         CALL dyn_atf       ( kstp, Nbb, Nnn, Naa, uu, vv, e3t, e3u, e3v  )  ! time filtering of "now" velocities and scale factors
328                         CALL ssh_atf       ( kstp, Nbb, Nnn, Naa, ssh )                     ! time filtering of "now" sea surface height
329      !
330      ! Swap time levels
331      Nrhs = Nbb
332      Nbb = Nnn
333      Nnn = Naa
334      Naa = Nrhs
335      !
336      IF(.NOT.ln_linssh) CALL dom_vvl_sf_update( kstp, Nbb, Nnn, Naa )  ! recompute vertical scale factors
337      !
338      IF( ln_diahsb  )   CALL dia_hsb       ( kstp, Nbb, Nnn )  ! - ML - global conservation diagnostics
339
340!!gm : This does not only concern the dynamics ==>>> add a new title
341!!gm2: why ouput restart before AGRIF update?
342!!
343!!jc: That would be better, but see comment above
344!!
345      IF( lrst_oce   )   CALL rst_write    ( kstp, Nbb, Nnn )   ! write output ocean restart file
346      IF( ln_sto_eos )   CALL sto_rst_write( kstp )   ! write restart file for stochastic parameters
347
348#if defined key_agrif
349      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
350      ! AGRIF recursive integration
351      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<     
352                         Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs      ! agrif_oce module copies of time level indices
353                         CALL Agrif_Integrate_ChildGrids( stp )       ! allows to finish all the Child Grids before updating
354
355#endif
356      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
357      ! Control
358      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
359                         CALL stp_ctl      ( kstp, Nnn )
360
361#if defined key_agrif
362      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
363      ! AGRIF update
364      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<     
365      IF( Agrif_NbStepint() == 0 .AND. nstop == 0 ) THEN
366                         CALL Agrif_update_all( )                  ! Update all components
367      ENDIF
368
369#endif
370      IF( ln_diaobs .AND. nstop == 0 )  CALL dia_obs( kstp, Nnn )  ! obs-minus-model (assimilation) diags (after dynamics update)
371
372      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
373      ! File manipulation at the end of the first time step
374      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<                         
375      IF( kstp == nit000 ) THEN                          ! 1st time step only
376                                        CALL iom_close( numror )   ! close input  ocean restart file
377         IF( lrxios )                   CALL iom_context_finalize(      cr_ocerst_cxt         )
378         IF(lwm)                        CALL FLUSH    ( numond )   ! flush output namelist oce
379         IF(lwm .AND. numoni /= -1 )    CALL FLUSH    ( numoni )   ! flush output namelist ice (if exist)
380      ENDIF
381
382      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
383      ! Coupled mode
384      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
385      IF( lk_oasis .AND. nstop == 0 )   CALL sbc_cpl_snd( kstp, Nbb, Nnn )     ! coupled mode : field exchanges
386      !
387#if defined key_iomput
388      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
389      ! Finalize contextes if end of simulation or error detected
390      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<                         
391      IF( kstp == nitend .OR. nstop > 0 ) THEN
392                      CALL iom_context_finalize(      cxios_context          ) ! needed for XIOS+AGRIF
393         IF( ln_crs ) CALL iom_context_finalize( trim(cxios_context)//"_crs" ) !
394      ENDIF
395#endif
396      !
397      IF( l_1st_euler ) THEN         ! recover Leap-frog timestep
398         rDt = 2._wp * rn_Dt   
399         r1_Dt = 1._wp / rDt
400         l_1st_euler = .FALSE.     
401      ENDIF
402      !
403      IF( ln_timing )   CALL timing_stop('stp')
404      !
405   END SUBROUTINE stp
406   !
407#endif
408   !!======================================================================
409END MODULE step
Note: See TracBrowser for help on using the repository browser.