New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
stpctl.F90 in NEMO/trunk/src/OCE – NEMO

source: NEMO/trunk/src/OCE/stpctl.F90

Last change on this file was 15023, checked in by gsamson, 11 months ago

merge ticket2680_C1D_PAPA branch back into the trunk; see ticket #2680 for details

  • Property svn:keywords set to Id
File size: 19.7 KB
Line 
1MODULE stpctl
2   !!======================================================================
3   !!                       ***  MODULE  stpctl  ***
4   !! Ocean run control :  gross check of the ocean time stepping
5   !!======================================================================
6   !! History :  OPA  ! 1991-03  (G. Madec) Original code
7   !!            6.0  ! 1992-06  (M. Imbard)
8   !!            8.0  ! 1997-06  (A.M. Treguier)
9   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
10   !!            2.0  ! 2009-07  (G. Madec)  Add statistic for time-spliting
11   !!            3.7  ! 2016-09  (G. Madec)  Remove solver
12   !!            4.0  ! 2017-04  (G. Madec)  regroup global communications
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   stp_ctl      : Control the run
17   !!----------------------------------------------------------------------
18   USE oce             ! ocean dynamics and tracers variables
19   USE dom_oce         ! ocean space and time domain variables
20   USE zdf_oce ,  ONLY : ln_zad_Aimp       ! ocean vertical physics variables
21   USE wet_dry,   ONLY : ll_wd, ssh_ref    ! reference depth for negative bathy
22   
23   USE diawri          ! Standard run outputs       (dia_wri_state routine)
24   USE in_out_manager  ! I/O manager
25   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
26   USE lib_mpp         ! distributed memory computing
27   USE eosbn2, ONLY: ln_SEOS, rn_b0
28   !
29   USE netcdf          ! NetCDF library
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC stp_ctl           ! routine called by step.F90
34
35   INTEGER, PARAMETER         ::   jpvar = 8
36   INTEGER                    ::   nrunid   ! netcdf file id
37   INTEGER, DIMENSION(jpvar)  ::   nvarid   ! netcdf variable id
38   !!----------------------------------------------------------------------
39   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
40   !! $Id$
41   !! Software governed by the CeCILL license (see ./LICENSE)
42   !!----------------------------------------------------------------------
43CONTAINS
44
45   SUBROUTINE stp_ctl( kt, Kmm )
46      !!----------------------------------------------------------------------
47      !!                    ***  ROUTINE stp_ctl  ***
48      !!
49      !! ** Purpose :   Control the run
50      !!
51      !! ** Method  : - Save the time step in numstp
52      !!              - Stop the run IF problem encountered by setting nstop > 0
53      !!                Problems checked: |ssh| maximum larger than 10 m
54      !!                                  |U|   maximum larger than 10 m/s
55      !!                                  negative sea surface salinity
56      !!
57      !! ** Actions :   "time.step" file = last ocean time-step
58      !!                "run.stat"  file = run statistics
59      !!                 nstop indicator sheared among all local domain
60      !!----------------------------------------------------------------------
61      INTEGER, INTENT(in   ) ::   kt       ! ocean time-step index
62      INTEGER, INTENT(in   ) ::   Kmm      ! ocean time level index
63      !!
64      INTEGER, PARAMETER              ::   jptst = 4
65      INTEGER                         ::   ji                                    ! dummy loop indices
66      INTEGER                         ::   idtime, istatus
67      INTEGER , DIMENSION(jptst)      ::   iareasum, iareamin, iareamax
68      INTEGER , DIMENSION(3,jptst)    ::   iloc                                  ! min/max loc indices
69      REAL(wp)                        ::   zzz, zminsal, zmaxsal                 ! local real
70      REAL(wp), DIMENSION(jpvar+1)    ::   zmax
71      REAL(wp), DIMENSION(jptst)      ::   zmaxlocal
72      LOGICAL                         ::   ll_wrtstp, ll_colruns, ll_wrtruns, ll_0oce
73      LOGICAL, DIMENSION(jpi,jpj,jpk) ::   llmsk
74      CHARACTER(len=20)               ::   clname
75      !!----------------------------------------------------------------------
76      IF( nstop > 0 .AND. ngrdstop > -1 )   RETURN   !   stpctl was already called by a child grid
77      !
78      ll_wrtstp  = ( MOD( kt-nit000, sn_cfctl%ptimincr ) == 0 ) .OR. ( kt == nitend )
79      ll_colruns = ll_wrtstp .AND. sn_cfctl%l_runstat .AND. jpnij > 1
80      ll_wrtruns = ( ll_colruns .OR. jpnij == 1 ) .AND. lwm
81      !
82      IF( kt == nit000 ) THEN
83         !
84         IF( lwp ) THEN
85            WRITE(numout,*)
86            WRITE(numout,*) 'stp_ctl : time-stepping control'
87            WRITE(numout,*) '~~~~~~~'
88         ENDIF
89         !                                ! open time.step    ascii file, done only by 1st subdomain
90         IF( lwm )   CALL ctl_opn( numstp, 'time.step', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
91         !
92         IF( ll_wrtruns ) THEN
93            !                             ! open run.stat     ascii file, done only by 1st subdomain
94            CALL ctl_opn( numrun, 'run.stat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
95            !                             ! open run.stat.nc netcdf file, done only by 1st subdomain
96            clname = 'run.stat.nc'
97            IF( .NOT. Agrif_Root() )   clname = TRIM(Agrif_CFixed())//"_"//TRIM(clname)
98            istatus = NF90_CREATE( TRIM(clname), NF90_CLOBBER, nrunid )
99            istatus = NF90_DEF_DIM( nrunid, 'time', NF90_UNLIMITED, idtime )
100            istatus = NF90_DEF_VAR( nrunid, 'abs_ssh_max', NF90_DOUBLE, (/ idtime /), nvarid(1) )
101            istatus = NF90_DEF_VAR( nrunid,   'abs_u_max', NF90_DOUBLE, (/ idtime /), nvarid(2) )
102            istatus = NF90_DEF_VAR( nrunid,       's_min', NF90_DOUBLE, (/ idtime /), nvarid(3) )
103            istatus = NF90_DEF_VAR( nrunid,       's_max', NF90_DOUBLE, (/ idtime /), nvarid(4) )
104            istatus = NF90_DEF_VAR( nrunid,       't_min', NF90_DOUBLE, (/ idtime /), nvarid(5) )
105            istatus = NF90_DEF_VAR( nrunid,       't_max', NF90_DOUBLE, (/ idtime /), nvarid(6) )
106            IF( ln_zad_Aimp ) THEN
107               istatus = NF90_DEF_VAR( nrunid,   'Cf_max', NF90_DOUBLE, (/ idtime /), nvarid(7) )
108               istatus = NF90_DEF_VAR( nrunid,'abs_wi_max',NF90_DOUBLE, (/ idtime /), nvarid(8) )
109            ENDIF
110            istatus = NF90_ENDDEF(nrunid)
111         ENDIF
112         !
113      ENDIF
114      !
115      !                                   !==              write current time step              ==!
116      !                                   !==  done only by 1st subdomain at writting timestep  ==!
117      IF( lwm .AND. ll_wrtstp ) THEN
118         WRITE ( numstp, '(1x, i8)' )   kt
119         REWIND( numstp )
120      ENDIF
121      !                                   !==            test of local extrema           ==!
122      !                                   !==  done by all processes at every time step  ==!
123      !
124      llmsk(     1:nn_hls,:,:) = .FALSE.                                          ! exclude halos from the checked region
125      llmsk(Nie0+1:   jpi,:,:) = .FALSE.
126      llmsk(:,     1:nn_hls,:) = .FALSE.
127      llmsk(:,Nje0+1:   jpj,:) = .FALSE.
128      !
129      llmsk(Nis0:Nie0,Njs0:Nje0,1) = ssmask(Nis0:Nie0,Njs0:Nje0) == 1._wp         ! define only the inner domain
130      !
131      ll_0oce = .NOT. ANY( llmsk(:,:,1) )                                         ! no ocean point in the inner domain?
132      !
133      IF( ll_wd ) THEN
134         zmax(1) = MAXVAL( ABS( ssh(:,:,Kmm) + ssh_ref ), mask = llmsk(:,:,1) )   ! ssh max
135      ELSE
136         zmax(1) = MAXVAL( ABS( ssh(:,:,Kmm)           ), mask = llmsk(:,:,1) )   ! ssh max
137      ENDIF
138      llmsk(Nis0:Nie0,Njs0:Nje0,:) = umask(Nis0:Nie0,Njs0:Nje0,:) == 1._wp        ! define only the inner domain
139      zmax(2) = MAXVAL(  ABS( uu(:,:,:,Kmm) ), mask = llmsk )                     ! velocity max (zonal only)
140      llmsk(Nis0:Nie0,Njs0:Nje0,:) = tmask(Nis0:Nie0,Njs0:Nje0,:) == 1._wp        ! define only the inner domain
141      zmax(3) = MAXVAL( -ts(:,:,:,jp_sal,Kmm), mask = llmsk )                     ! minus salinity max
142      zmax(4) = MAXVAL(  ts(:,:,:,jp_sal,Kmm), mask = llmsk )                     !       salinity max
143      IF( ll_colruns .OR. jpnij == 1 ) THEN     ! following variables are used only in the netcdf file
144         zmax(5) = MAXVAL( -ts(:,:,:,jp_tem,Kmm), mask = llmsk )                  ! minus temperature max
145         zmax(6) = MAXVAL(  ts(:,:,:,jp_tem,Kmm), mask = llmsk )                  !       temperature max
146         IF( ln_zad_Aimp ) THEN
147            zmax(7) = MAXVAL(   Cu_adv(:,:,:)   , mask = llmsk )                  ! partitioning coeff. max
148            llmsk(:,:,:) = wmask(:,:,:) == 1._wp
149            zmax(8) = MAXVAL(  ABS( wi(:,:,:) ) , mask = llmsk )                  ! implicit vertical vel. max
150         ELSE
151            zmax(7:8) = 0._wp
152         ENDIF
153      ELSE
154         zmax(5:8) = 0._wp
155      ENDIF
156      zmax(jpvar+1) = REAL( nstop, wp )                                           ! stop indicator
157      !
158      !                                   !==               get global extrema             ==!
159      !                                   !==  done by all processes if writting run.stat  ==!
160      IF( ll_colruns ) THEN
161         zmaxlocal(:) = zmax(1:jptst)
162         CALL mpp_max( "stpctl", zmax )          ! max over the global domain: ok even of ll_0oce = .true.
163         nstop = NINT( zmax(jpvar+1) )           ! update nstop indicator (now sheared among all local domains)
164      ELSE
165         ! if no ocean point: MAXVAL returns -HUGE => we must overwrite this value to avoid error handling bellow.
166         IF( ll_0oce )   zmax(1:jptst) = (/ 0._wp, 0._wp, -1._wp, 1._wp /)   ! default "valid" values...
167      ENDIF
168      !
169      zmax(3) = -zmax(3)                              ! move back from max(-zz) to min(zz) : easier to manage!
170      zmax(5) = -zmax(5)                              ! move back from max(-zz) to min(zz) : easier to manage!
171      IF( ll_colruns ) zmaxlocal(3) = -zmaxlocal(3)   ! move back from max(-zz) to min(zz) : easier to manage!
172      !
173      !                                   !==              write "run.stat" files              ==!
174      !                                   !==  done only by 1st subdomain at writting timestep  ==!
175      IF( ll_wrtruns ) THEN
176         WRITE(numrun,9500) kt, zmax(1:jptst)
177         DO ji = 1, jpvar - 2 * COUNT( .NOT. (/ln_zad_Aimp/) )
178            istatus = NF90_PUT_VAR( nrunid, nvarid(ji), (/zmax(ji)/), (/kt/), (/1/) )
179         END DO
180         IF( kt == nitend )   istatus = NF90_CLOSE(nrunid)
181      END IF
182      !                                   !==               error handling               ==!
183      !                                   !==  done by all processes at every time step  ==!
184      !
185      IF ( ln_SEOS.AND.(rn_b0==0._wp) ) THEN             ! Discard checks on salinity
186         zmaxsal =  HUGE(1._wp)                               ! if not used in eos
187         zminsal = -HUGE(1._wp)
188      ELSE
189         zmaxsal = 100._wp
190         zminsal =   0._wp
191      ENDIF 
192      !
193      IF(  zmax(1) >   20._wp .OR.   &                        ! too large sea surface height ( > 20 m )
194         & zmax(2) >   10._wp .OR.   &                        ! too large velocity ( > 10 m/s)
195         & zmax(3) <= zminsal .OR.   &                        ! negative or zero sea surface salinity
196         & zmax(4) >= zmaxsal .OR.   &                        ! too large sea surface salinity ( > 100 )
197         & zmax(4) <  zminsal .OR.   &                        ! too large sea surface salinity (keep this line for sea-ice)
198         & ISNAN( SUM(zmax(1:jptst)) ) .OR.   &               ! NaN encounter in the tests
199         & ABS(   SUM(zmax(1:jptst)) ) > HUGE(1._wp) ) THEN   ! Infinity encounter in the tests
200         !
201         iloc(:,:) = 0
202         IF( ll_colruns ) THEN   ! zmax is global, so it is the same on all subdomains -> no dead lock with mpp_maxloc
203            ! first: close the netcdf file, so we can read it
204            IF( lwm .AND. kt /= nitend )   istatus = NF90_CLOSE(nrunid)
205            ! get global loc on the min/max
206            llmsk(Nis0:Nie0,Njs0:Nje0,1) = ssmask(Nis0:Nie0,Njs0:Nje0 ) == 1._wp         ! define only the inner domain
207            CALL mpp_maxloc( 'stpctl', ABS(ssh(:,:,         Kmm)), llmsk(:,:,1), zzz, iloc(1:2,1) )   ! mpp_maxloc ok if mask = F
208            llmsk(Nis0:Nie0,Njs0:Nje0,:) = umask(Nis0:Nie0,Njs0:Nje0,:) == 1._wp        ! define only the inner domain
209            CALL mpp_maxloc( 'stpctl', ABS( uu(:,:,:,       Kmm)), llmsk(:,:,:), zzz, iloc(1:3,2) )
210            llmsk(Nis0:Nie0,Njs0:Nje0,:) = tmask(Nis0:Nie0,Njs0:Nje0,:) == 1._wp        ! define only the inner domain
211            CALL mpp_minloc( 'stpctl',      ts(:,:,:,jp_sal,Kmm) , llmsk(:,:,:), zzz, iloc(1:3,3) )
212            CALL mpp_maxloc( 'stpctl',      ts(:,:,:,jp_sal,Kmm) , llmsk(:,:,:), zzz, iloc(1:3,4) )
213            ! find which subdomain has the max.
214            iareamin(:) = jpnij+1   ;   iareamax(:) = 0   ;   iareasum(:) = 0
215            DO ji = 1, jptst
216               IF( zmaxlocal(ji) == zmax(ji) ) THEN
217                  iareamin(ji) = narea   ;   iareamax(ji) = narea   ;   iareasum(ji) = 1
218               ENDIF
219            END DO
220            CALL mpp_min( "stpctl", iareamin )         ! min over the global domain
221            CALL mpp_max( "stpctl", iareamax )         ! max over the global domain
222            CALL mpp_sum( "stpctl", iareasum )         ! sum over the global domain
223         ELSE                    ! find local min and max locations:
224            ! if we are here, this means that the subdomain contains some oce points -> no need to test the mask used in maxloc
225            llmsk(Nis0:Nie0,Njs0:Nje0,1) = ssmask(Nis0:Nie0,Njs0:Nje0 ) == 1._wp        ! define only the inner domain
226            iloc(1:2,1) = MAXLOC( ABS( ssh(:,:,         Kmm)), mask = llmsk(:,:,1) )
227            llmsk(Nis0:Nie0,Njs0:Nje0,:) = umask(Nis0:Nie0,Njs0:Nje0,:) == 1._wp        ! define only the inner domain
228            iloc(1:3,2) = MAXLOC( ABS(  uu(:,:,:,       Kmm)), mask = llmsk(:,:,:) )
229            llmsk(Nis0:Nie0,Njs0:Nje0,:) = tmask(Nis0:Nie0,Njs0:Nje0,:) == 1._wp        ! define only the inner domain
230            iloc(1:3,3) = MINLOC(       ts(:,:,:,jp_sal,Kmm) , mask = llmsk(:,:,:) )
231            iloc(1:3,4) = MAXLOC(       ts(:,:,:,jp_sal,Kmm) , mask = llmsk(:,:,:) )
232            DO ji = 1, jptst   ! local domain indices ==> global domain indices, excluding halos
233               iloc(1:2,ji) = (/ mig0(iloc(1,ji)), mjg0(iloc(2,ji)) /)
234            END DO
235            iareamin(:) = narea   ;   iareamax(:) = narea   ;   iareasum(:) = 1         ! this is local information
236         ENDIF
237         !
238         WRITE(ctmp1,*) ' stp_ctl: |ssh| > 20 m  or  |U| > 10 m/s  or  S <= 0  or  S >= 100  or  NaN encounter in the tests'
239         CALL wrt_line( ctmp2, kt, '|ssh| max', zmax(1), iloc(:,1), iareasum(1), iareamin(1), iareamax(1) )
240         CALL wrt_line( ctmp3, kt, '|U|   max', zmax(2), iloc(:,2), iareasum(2), iareamin(2), iareamax(2) )
241         CALL wrt_line( ctmp4, kt, 'Sal   min', zmax(3), iloc(:,3), iareasum(3), iareamin(3), iareamax(3) )
242         CALL wrt_line( ctmp5, kt, 'Sal   max', zmax(4), iloc(:,4), iareasum(4), iareamin(4), iareamax(4) )
243         IF( Agrif_Root() ) THEN
244            WRITE(ctmp6,*) '      ===> output of last computed fields in output.abort* files'
245         ELSE
246            WRITE(ctmp6,*) '      ===> output of last computed fields in '//TRIM(Agrif_CFixed())//'_output.abort* files'
247         ENDIF
248         !
249         CALL dia_wri_state( Kmm, 'output.abort' )     ! create an output.abort file
250         !
251         IF( ll_colruns .OR. jpnij == 1 ) THEN   ! all processes synchronized -> use lwp to print in opened ocean.output files
252            IF(lwp) THEN   ;   CALL ctl_stop( ctmp1, ' ', ctmp2, ctmp3, ctmp4, ctmp5, ' ', ctmp6 )
253            ELSE           ;   nstop = MAX(1, nstop)   ! make sure nstop > 0 (automatically done when calling ctl_stop)
254            ENDIF
255         ELSE                                    ! only mpi subdomains with errors are here -> STOP now
256            CALL ctl_stop( 'STOP', ctmp1, ' ', ctmp2, ctmp3, ctmp4, ctmp5, ' ', ctmp6 )
257         ENDIF
258         !
259      ENDIF
260      !
261      IF( nstop > 0 ) THEN                                                  ! an error was detected and we did not abort yet...
262         ngrdstop = Agrif_Fixed()                                           ! store which grid got this error
263         IF( .NOT. ll_colruns .AND. jpnij > 1 )   CALL ctl_stop( 'STOP' )   ! we must abort here to avoid MPI deadlock
264      ENDIF
265      !
2669500  FORMAT(' it :', i8, '    |ssh|_max: ', D23.16, ' |U|_max: ', D23.16,' S_min: ', D23.16,' S_max: ', D23.16)
267      !
268   END SUBROUTINE stp_ctl
269
270
271   SUBROUTINE wrt_line( cdline, kt, cdprefix, pval, kloc, ksum, kmin, kmax )
272      !!----------------------------------------------------------------------
273      !!                     ***  ROUTINE wrt_line  ***
274      !!
275      !! ** Purpose :   write information line
276      !!
277      !!----------------------------------------------------------------------
278      CHARACTER(len=*),      INTENT(  out) ::   cdline
279      CHARACTER(len=*),      INTENT(in   ) ::   cdprefix
280      REAL(wp),              INTENT(in   ) ::   pval
281      INTEGER, DIMENSION(3), INTENT(in   ) ::   kloc
282      INTEGER,               INTENT(in   ) ::   kt, ksum, kmin, kmax
283      !
284      CHARACTER(len=80) ::   clsuff
285      CHARACTER(len=9 ) ::   clkt, clsum, clmin, clmax
286      CHARACTER(len=9 ) ::   cli, clj, clk
287      CHARACTER(len=1 ) ::   clfmt
288      CHARACTER(len=4 ) ::   cl4   ! needed to be able to compile with Agrif, I don't know why
289      INTEGER           ::   ifmtk
290      !!----------------------------------------------------------------------
291      WRITE(clkt , '(i9)') kt
292     
293      WRITE(clfmt, '(i1)') INT(LOG10(REAL(jpnij  ,wp))) + 1     ! how many digits to we need to write ? (we decide max = 9)
294      !!! WRITE(clsum, '(i'//clfmt//')') ksum                   ! this is creating a compilation error with AGRIF
295      cl4 = '(i'//clfmt//')'   ;   WRITE(clsum, cl4) ksum
296      WRITE(clfmt, '(i1)') INT(LOG10(REAL(MAX(1,jpnij-1),wp))) + 1    ! how many digits to we need to write ? (we decide max = 9)
297      cl4 = '(i'//clfmt//')'   ;   WRITE(clmin, cl4) kmin-1
298                                   WRITE(clmax, cl4) kmax-1
299      !
300      WRITE(clfmt, '(i1)') INT(LOG10(REAL(jpiglo,wp))) + 1      ! how many digits to we need to write jpiglo? (we decide max = 9)
301      cl4 = '(i'//clfmt//')'   ;   WRITE(cli, cl4) kloc(1)      ! this is ok with AGRIF
302      WRITE(clfmt, '(i1)') INT(LOG10(REAL(jpjglo,wp))) + 1      ! how many digits to we need to write jpjglo? (we decide max = 9)
303      cl4 = '(i'//clfmt//')'   ;   WRITE(clj, cl4) kloc(2)      ! this is ok with AGRIF
304      !
305      IF( ksum == 1 ) THEN   ;   WRITE(clsuff,9100) TRIM(clmin)
306      ELSE                   ;   WRITE(clsuff,9200) TRIM(clsum), TRIM(clmin), TRIM(clmax)
307      ENDIF
308      IF(kloc(3) == 0) THEN
309         ifmtk = INT(LOG10(REAL(jpk,wp))) + 1                   ! how many digits to we need to write jpk? (we decide max = 9)
310         clk = REPEAT(' ', ifmtk)                               ! create the equivalent in blank string
311         WRITE(cdline,9300) TRIM(ADJUSTL(clkt)), TRIM(ADJUSTL(cdprefix)), pval, TRIM(cli), TRIM(clj), clk(1:ifmtk), TRIM(clsuff)
312      ELSE
313         WRITE(clfmt, '(i1)') INT(LOG10(REAL(jpk,wp))) + 1      ! how many digits to we need to write jpk? (we decide max = 9)
314         !!! WRITE(clk, '(i'//clfmt//')') kloc(3)               ! this is creating a compilation error with AGRIF
315         cl4 = '(i'//clfmt//')'   ;   WRITE(clk, cl4) kloc(3)   ! this is ok with AGRIF
316         WRITE(cdline,9400) TRIM(ADJUSTL(clkt)), TRIM(ADJUSTL(cdprefix)), pval, TRIM(cli), TRIM(clj),    TRIM(clk), TRIM(clsuff)
317      ENDIF
318      !
3199100  FORMAT('MPI rank ', a)
3209200  FORMAT('found in ', a, ' MPI tasks, spread out among ranks ', a, ' to ', a)
3219300  FORMAT('kt ', a, ' ', a, ' ', 1pg11.4, ' at i j   ', a, ' ', a, ' ', a, ' ', a)
3229400  FORMAT('kt ', a, ' ', a, ' ', 1pg11.4, ' at i j k ', a, ' ', a, ' ', a, ' ', a)
323      !
324   END SUBROUTINE wrt_line
325
326
327   !!======================================================================
328END MODULE stpctl
Note: See TracBrowser for help on using the repository browser.