New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
stpmlf.F90 in NEMO/trunk/src/OCE – NEMO

source: NEMO/trunk/src/OCE/stpmlf.F90 @ 15061

Last change on this file since 15061 was 15061, checked in by clem, 15 months ago

nn_hls=2: orca2 runs in debug mode.

File size: 32.7 KB
Line 
1MODULE stpmlf
2   !!======================================================================
3   !!                       ***  MODULE stpMLF  ***
4   !! Time-stepping   : manager of the ocean, tracer and ice time stepping
5   !!                   using Modified Leap Frog for OCE
6   !!======================================================================
7   !! History :  OPA  !  1991-03  (G. Madec)  Original code
8   !!             -   !  1991-11  (G. Madec)
9   !!             -   !  1992-06  (M. Imbard)  add a first output record
10   !!             -   !  1996-04  (G. Madec)  introduction of dynspg
11   !!             -   !  1996-04  (M.A. Foujols)  introduction of passive tracer
12   !!            8.0  !  1997-06  (G. Madec)  new architecture of call
13   !!            8.2  !  1997-06  (G. Madec, M. Imbard, G. Roullet)  free surface
14   !!             -   !  1999-02  (G. Madec, N. Grima)  hpg implicit
15   !!             -   !  2000-07  (J-M Molines, M. Imbard)  Open Bondary Conditions
16   !!   NEMO     1.0  !  2002-06  (G. Madec)  free form, suppress macro-tasking
17   !!             -   !  2004-08  (C. Talandier) New trends organization
18   !!             -   !  2005-01  (C. Ethe) Add the KPP closure scheme
19   !!             -   !  2005-11  (G. Madec)  Reorganisation of tra and dyn calls
20   !!             -   !  2006-01  (L. Debreu, C. Mazauric)  Agrif implementation
21   !!             -   !  2006-07  (S. Masson)  restart using iom
22   !!            3.2  !  2009-02  (G. Madec, R. Benshila)  reintroduicing z*-coordinate
23   !!             -   !  2009-06  (S. Masson, G. Madec)  TKE restart compatible with key_cpl
24   !!            3.3  !  2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
25   !!             -   !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase + merge TRC-TRA
26   !!            3.4  !  2011-04  (G. Madec, C. Ethe) Merge of dtatem and dtasal
27   !!            3.6  !  2012-07  (J. Simeon, G. Madec. C. Ethe)  Online coarsening of outputs
28   !!            3.6  !  2014-04  (F. Roquet, G. Madec) New equations of state
29   !!            3.6  !  2014-10  (E. Clementi, P. Oddo) Add Qiao vertical mixing in case of waves
30   !!            3.7  !  2014-10  (G. Madec)  LDF simplication
31   !!             -   !  2014-12  (G. Madec) remove KPP scheme
32   !!             -   !  2015-11  (J. Chanut) free surface simplification (remove filtered free surface)
33   !!            4.0  !  2017-05  (G. Madec)  introduction of the vertical physics manager (zdfphy)
34   !!            4.1  !  2019-08  (A. Coward, D. Storkey) rewrite in preparation for new timestepping scheme
35   !!            4.x  !  2020-08  (S. Techene, G. Madec)  quasi eulerian coordinate time stepping
36   !!----------------------------------------------------------------------
37#if defined key_qco   ||   defined key_linssh
38   !!----------------------------------------------------------------------
39   !!   'key_qco'                        Quasi-Eulerian vertical coordinate
40   !!                          OR
41   !!   'key_linssh                       Fixed in time vertical coordinate
42   !!----------------------------------------------------------------------
43   !!
44   !!----------------------------------------------------------------------
45   !!   stp_MLF       : NEMO modified Leap Frog time-stepping with qco or linssh
46   !!----------------------------------------------------------------------
47   USE step_oce       ! time stepping definition modules
48   !
49   USE domqco         ! quasi-eulerian coordinate
50   USE traatf_qco     ! time filtering                 (tra_atf_qco routine)
51   USE dynatf_qco     ! time filtering                 (dyn_atf_qco routine)
52
53   IMPLICIT NONE
54   PRIVATE
55
56   PUBLIC   stp_MLF   ! called by nemogcm.F90
57
58   !                                          !**  time level indices  **!
59   INTEGER, PUBLIC ::   Nbb, Nnn, Naa, Nrhs   !: used by nemo_init
60
61   !! * Substitutions
62#  include "do_loop_substitute.h90"
63#  include "domzgr_substitute.h90"
64   !!----------------------------------------------------------------------
65   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
66   !! $Id: step.F90 12377 2020-02-12 14:39:06Z acc $
67   !! Software governed by the CeCILL license (see ./LICENSE)
68   !!----------------------------------------------------------------------
69CONTAINS
70
71#if defined key_agrif
72   RECURSIVE SUBROUTINE stp_MLF( )
73      INTEGER             ::   kstp   ! ocean time-step index
74#else
75   SUBROUTINE stp_MLF( kstp )
76      INTEGER, INTENT(in) ::   kstp   ! ocean time-step index
77#endif
78      !!----------------------------------------------------------------------
79      !!                     ***  ROUTINE stp_MLF  ***
80      !!
81      !! ** Purpose : - Time stepping of OCE  (momentum and active tracer eqs.)
82      !!              - Time stepping of SI3 (dynamic and thermodynamic eqs.)
83      !!              - Time stepping of TRC  (passive tracer eqs.)
84      !!
85      !! ** Method  : -1- Update forcings and data
86      !!              -2- Update ocean physics
87      !!              -3- Compute the t and s trends
88      !!              -4- Update t and s
89      !!              -5- Compute the momentum trends
90      !!              -6- Update the horizontal velocity
91      !!              -7- Compute the diagnostics variables (rd,N2, hdiv,w)
92      !!              -8- Outputs and diagnostics
93      !!----------------------------------------------------------------------
94      INTEGER ::   ji, jj, jk, jtile   ! dummy loop indice
95      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   zgdept
96      !! ---------------------------------------------------------------------
97#if defined key_agrif
98      IF( nstop > 0 ) RETURN   ! avoid to go further if an error was detected during previous time step (child grid)
99      kstp = nit000 + Agrif_Nb_Step()
100      Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs   ! agrif_oce module copies of time level indices
101      IF( lk_agrif_debug ) THEN
102         IF( Agrif_Root() .and. lwp)   WRITE(*,*) '---'
103         IF(lwp)   WRITE(*,*) 'Grid Number', Agrif_Fixed(),' time step ', kstp, 'int tstep', Agrif_NbStepint()
104      ENDIF
105      IF( kstp == nit000 + 1 )   lk_agrif_fstep = .FALSE.
106# if defined key_xios
107      IF( Agrif_Nbstepint() == 0 )   CALL iom_swap( cxios_context )
108# endif
109#endif
110      !
111      IF( ln_timing )   CALL timing_start('stp_MLF')
112      !
113      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
114      ! model timestep
115      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
116      !
117      IF( l_1st_euler ) THEN     ! start or restart with Euler 1st time-step
118         rDt   = rn_Dt   
119         r1_Dt = 1._wp / rDt
120      ENDIF
121      !
122      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
123      ! update I/O and calendar
124      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
125      !
126      IF( kstp == nit000 ) THEN                       ! initialize IOM context (must be done after nemo_init for AGRIF+XIOS+OASIS)
127                             CALL iom_init( cxios_context, ld_closedef=.FALSE. )   ! for model grid (including possible AGRIF zoom)
128         IF( lk_diamlr   )   CALL dia_mlr_iom_init    ! with additional setup for multiple-linear-regression analysis
129                             CALL iom_init_closedef
130         IF( ln_crs      )   CALL iom_init( TRIM(cxios_context)//"_crs" )  ! for coarse grid
131      ENDIF
132      IF( kstp == nitrst .AND. lwxios ) THEN
133                             CALL iom_swap(                     cw_ocerst_cxt )
134                             CALL iom_init_closedef(            cw_ocerst_cxt )
135                             CALL iom_setkt( kstp - nit000 + 1, cw_ocerst_cxt )
136#if defined key_top
137                             CALL iom_swap(                     cw_toprst_cxt )
138                             CALL iom_init_closedef(            cw_toprst_cxt )
139                             CALL iom_setkt( kstp - nit000 + 1, cw_toprst_cxt )
140#endif
141      ENDIF
142      IF( kstp + nn_fsbc - 1 == nitrst .AND. lwxios ) THEN
143#if defined key_si3
144                             CALL iom_swap(                     cw_icerst_cxt )
145                             CALL iom_init_closedef(            cw_icerst_cxt )
146                             CALL iom_setkt( kstp - nit000 + 1, cw_icerst_cxt )
147#endif
148         IF( ln_abl      ) THEN
149                             CALL iom_swap(                     cw_ablrst_cxt )
150                             CALL iom_init_closedef(            cw_ablrst_cxt )
151                             CALL iom_setkt( kstp - nit000 + 1, cw_ablrst_cxt )
152         ENDIF
153      ENDIF
154      IF( kstp /= nit000 )   CALL day( kstp )         ! Calendar (day was already called at nit000 in day_init)
155                             CALL iom_setkt( kstp - nit000 + 1,      cxios_context          )   ! tell IOM we are at time step kstp
156      IF( ln_crs         )   CALL iom_setkt( kstp - nit000 + 1, TRIM(cxios_context)//"_crs" )   ! tell IOM we are at time step kstp
157
158      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
159      ! Update external forcing (tides, open boundaries, ice shelf interaction and surface boundary condition (including sea-ice)
160      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
161      IF( ln_tide    )   CALL tide_update( kstp )                     ! update tide potential
162      IF( ln_apr_dyn )   CALL sbc_apr ( kstp )                        ! atmospheric pressure (NB: call before bdy_dta which needs ssh_ib)
163      IF( ln_bdy     )   CALL bdy_dta ( kstp, Nnn )                   ! update dynamic & tracer data at open boundaries
164      IF( ln_isf     )   CALL isf_stp ( kstp, Nnn )
165                         CALL sbc     ( kstp, Nbb, Nnn )              ! Sea Boundary Condition (including sea-ice)
166
167      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
168      ! Update stochastic parameters and random T/S fluctuations
169      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
170      IF( ln_sto_eos )   CALL sto_par( kstp )                         ! Stochastic parameters
171      IF( ln_sto_eos )   CALL sto_pts( ts(:,:,:,:,Nnn)  )             ! Random T/S fluctuations
172
173      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
174      ! Ocean physics update
175      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
176      !  THERMODYNAMICS
177                         CALL eos_rab( ts(:,:,:,:,Nbb), rab_b, Nnn )       ! before local thermal/haline expension ratio at T-points
178                         CALL eos_rab( ts(:,:,:,:,Nnn), rab_n, Nnn )       ! now    local thermal/haline expension ratio at T-points
179                         CALL bn2    ( ts(:,:,:,:,Nbb), rab_b, rn2b, Nnn ) ! before Brunt-Vaisala frequency
180                         CALL bn2    ( ts(:,:,:,:,Nnn), rab_n, rn2, Nnn  ) ! now    Brunt-Vaisala frequency
181
182      !  VERTICAL PHYSICS
183      IF( ln_tile ) CALL dom_tile_start         ! [tiling] ZDF tiling loop
184      DO jtile = 1, nijtile
185         IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = jtile )
186                         CALL zdf_phy( kstp, Nbb, Nnn, Nrhs )   ! vertical physics update (top/bot drag, avt, avs, avm + MLD)
187      END DO
188      IF( ln_tile ) CALL dom_tile_stop
189
190      !  LATERAL  PHYSICS
191      !
192      IF( ln_zps .OR. l_ldfslp ) CALL eos( ts(:,:,:,:,Nbb), rhd, gdept_0(:,:,:) )               ! before in situ density
193
194      IF( ln_zps .AND. .NOT. ln_isfcav)                                    &
195            &            CALL zps_hde    ( kstp, Nnn, jpts, ts(:,:,:,:,Nbb), gtsu, gtsv,  &  ! Partial steps: before horizontal gradient
196            &                                          rhd, gru , grv    )       ! of t, s, rd at the last ocean level
197
198      IF( ln_zps .AND.       ln_isfcav)                                                &
199            &            CALL zps_hde_isf( kstp, Nnn, jpts, ts(:,:,:,:,Nbb), gtsu, gtsv, gtui, gtvi,  &  ! Partial steps for top cell (ISF)
200            &                                          rhd, gru , grv , grui, grvi   )       ! of t, s, rd at the first ocean level
201
202      IF( l_ldfslp ) THEN                             ! slope of lateral mixing
203         IF( ln_traldf_triad ) THEN
204                         CALL ldf_slp_triad( kstp, Nbb, Nnn )             ! before slope for triad operator
205         ELSE
206                         CALL ldf_slp     ( kstp, rhd, rn2b, Nbb, Nnn )   ! before slope for standard operator
207         ENDIF
208      ENDIF
209      !                                                                        ! eddy diffusivity coeff.
210      IF( l_ldftra_time .OR. l_ldfeiv_time )   CALL ldf_tra( kstp, Nbb, Nnn )  !       and/or eiv coeff.
211      IF( l_ldfdyn_time                    )   CALL ldf_dyn( kstp, Nbb )       ! eddy viscosity coeff.
212
213      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
214      !  Ocean dynamics : hdiv, ssh, e3, u, v, w
215      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
216     
217                         CALL ssh_nxt    ( kstp, Nbb, Nnn, ssh,  Naa )   ! after ssh (includes call to div_hor)
218      IF( .NOT.lk_linssh ) THEN
219                         CALL dom_qco_r3c( ssh(:,:,Naa), r3t(:,:,Naa), r3u(:,:,Naa), r3v(:,:,Naa)           )   ! "after" ssh/h_0 ratio at t,u,v pts
220         IF( ln_dynspg_exp )   &
221            &            CALL dom_qco_r3c( ssh(:,:,Nnn), r3t(:,:,Nnn), r3u(:,:,Nnn), r3v(:,:,Nnn), r3f(:,:) )   ! spg_exp : needed only for "now" ssh/h_0 ratio at f point
222      ENDIF
223                         CALL wzv        ( kstp, Nbb, Nnn, Naa, ww  )    ! Nnn cross-level velocity
224      IF( ln_zad_Aimp )  CALL wAimp      ( kstp,      Nnn           )    ! Adaptive-implicit vertical advection partitioning
225                         ALLOCATE( zgdept(jpi,jpj,jpk) )
226                         DO jk = 1, jpk
227                            zgdept(:,:,jk) = gdept(:,:,jk,Nnn)
228                         END DO
229                         CALL eos        ( ts(:,:,:,:,Nnn), rhd, rhop, zgdept ) ! now in situ density for hpg computation
230                         DEALLOCATE( zgdept )
231
232                         uu(:,:,:,Nrhs) = 0._wp            ! set dynamics trends to zero
233                         vv(:,:,:,Nrhs) = 0._wp
234
235      IF( ln_dyndmp .AND. ln_c1d )  CALL dyn_dmp( kstp, Nbb, Nnn, uu(:,:,:,Nrhs), vv(:,:,:,Nrhs), Nrhs )   ! internal damping trends- momentum
236
237      IF( ln_tile ) CALL dom_tile_start         ! [tiling] DYN tiling loop (1)
238      DO jtile = 1, nijtile
239         IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = jtile )
240
241         IF(  lk_asminc .AND. ln_asmiau .AND. ln_dyninc )   &
242                  &         CALL dyn_asm_inc   ( kstp, Nbb, Nnn, uu, vv, Nrhs )  ! apply dynamics assimilation increment
243         IF( ln_bdy     )   CALL bdy_dyn3d_dmp ( kstp, Nbb,      uu, vv, Nrhs )  ! bdy damping trends
244#if defined key_agrif
245      END DO
246      IF( ln_tile ) CALL dom_tile_stop
247
248      IF(.NOT. Agrif_Root())  &
249               &         CALL Agrif_Sponge_dyn        ! momentum sponge
250
251      IF( ln_tile ) CALL dom_tile_start         ! [tiling] DYN tiling loop (1, continued)
252      DO jtile = 1, nijtile
253         IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = jtile )
254#endif
255                            CALL dyn_adv( kstp, Nbb, Nnn      , uu, vv, Nrhs )  ! advection (VF or FF)   ==> RHS
256                            CALL dyn_vor( kstp,      Nnn      , uu, vv, Nrhs )  ! vorticity              ==> RHS
257                            CALL dyn_ldf( kstp, Nbb, Nnn      , uu, vv, Nrhs )  ! lateral mixing
258         IF( ln_zdfosm  )   CALL dyn_osm( kstp,      Nnn      , uu, vv, Nrhs )  ! OSMOSIS non-local velocity fluxes ==> RHS
259                            CALL dyn_hpg( kstp,      Nnn      , uu, vv, Nrhs )  ! horizontal gradient of Hydrostatic pressure
260      END DO
261      IF( ln_tile ) CALL dom_tile_stop
262
263                            CALL dyn_spg( kstp, Nbb, Nnn, Nrhs, uu, vv, ssh, uu_b, vv_b, Naa )  ! surface pressure gradient
264
265      IF( ln_tile ) CALL dom_tile_start         ! [tiling] DYN tiling loop (2)
266      DO jtile = 1, nijtile
267         IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = jtile )
268
269         IF( ln_dynspg_ts ) THEN      ! With split-explicit free surface, since now transports have been updated and ssh(:,:,Nrhs)
270                                      ! as well as vertical scale factors and vertical velocity need to be updated
271                            CALL div_hor    ( kstp, Nbb, Nnn )                  ! Horizontal divergence  (2nd call in time-split case)
272            IF(.NOT.lk_linssh) CALL dom_qco_r3c( ssh(:,:,Naa), r3t(:,:,Naa), r3u(:,:,Naa), r3v(:,:,Naa), r3f(:,:) )   ! update ssh/h_0 ratio at t,u,v,f pts
273         ENDIF
274                            CALL dyn_zdf    ( kstp, Nbb, Nnn, Nrhs, uu, vv, Naa  )  ! vertical diffusion
275      END DO
276      IF( ln_tile ) CALL dom_tile_stop
277
278      IF( ln_dynspg_ts ) THEN                                                       ! vertical scale factors and vertical velocity need to be updated
279                            CALL wzv        ( kstp, Nbb, Nnn, Naa, ww )             ! Nnn cross-level velocity
280         IF( ln_zad_Aimp )  CALL wAimp      ( kstp,      Nnn )                      ! Adaptive-implicit vertical advection partitioning
281      ENDIF
282
283
284      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
285      ! cool skin
286      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
287      IF ( ln_diurnal )  CALL diurnal_layers( kstp )
288
289      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
290      ! diagnostics and outputs
291      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
292      IF( ln_floats  )   CALL flo_stp   ( kstp, Nbb, Nnn )      ! drifting Floats
293      IF( ln_diacfl  )   CALL dia_cfl   ( kstp,      Nnn )      ! Courant number diagnostics
294                         CALL dia_hth   ( kstp,      Nnn )      ! Thermocline depth (20 degres isotherm depth)
295      IF( ln_diadct  )   CALL dia_dct   ( kstp,      Nnn )      ! Transports
296                         CALL dia_ar5   ( kstp,      Nnn )      ! ar5 diag
297                         CALL dia_ptr   ( kstp,      Nnn )      ! Poleward adv/ldf TRansports diagnostics
298                         CALL dia_wri   ( kstp,      Nnn )      ! ocean model: outputs
299      IF( ln_crs     )   CALL crs_fld   ( kstp,      Nnn )      ! ocean model: online field coarsening & output
300      IF( lk_diadetide ) CALL dia_detide( kstp )                ! Weights computation for daily detiding of model diagnostics
301      IF( lk_diamlr  )   CALL dia_mlr                           ! Update time used in multiple-linear-regression analysis
302
303      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
304      ! Now ssh filtering
305      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
306                         CALL ssh_atf    ( kstp, Nbb, Nnn, Naa, ssh )            ! time filtering of "now" sea surface height
307      IF(.NOT.lk_linssh) CALL dom_qco_r3c( ssh(:,:,Nnn), r3t_f, r3u_f, r3v_f )   ! "now" ssh/h_0 ratio from filtrered ssh
308#if defined key_top
309      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
310      ! Passive Tracer Model
311      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
312                         CALL trc_stp    ( kstp, Nbb, Nnn, Nrhs, Naa )           ! time-stepping
313#endif
314
315      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
316      ! Active tracers
317      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
318                         ts(:,:,:,:,Nrhs) = 0._wp         ! set tracer trends to zero
319
320      IF( ln_tile ) CALL dom_tile_start         ! [tiling] TRA tiling loop (1)
321      DO jtile = 1, nijtile
322         IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = jtile )
323
324         IF(  lk_asminc .AND. ln_asmiau .AND. &
325            & ln_trainc )   CALL tra_asm_inc( kstp, Nbb, Nnn, ts, Nrhs )  ! apply tracer assimilation increment
326                            CALL tra_sbc    ( kstp,      Nnn, ts, Nrhs )  ! surface boundary condition
327         IF( ln_traqsr  )   CALL tra_qsr    ( kstp,      Nnn, ts, Nrhs )  ! penetrative solar radiation qsr
328         IF( ln_isf     )   CALL tra_isf    ( kstp,      Nnn, ts, Nrhs )  ! ice shelf heat flux
329         IF( ln_trabbc  )   CALL tra_bbc    ( kstp,      Nnn, ts, Nrhs )  ! bottom heat flux
330         IF( ln_trabbl  )   CALL tra_bbl    ( kstp, Nbb, Nnn, ts, Nrhs )  ! advective (and/or diffusive) bottom boundary layer scheme
331         IF( ln_tradmp  )   CALL tra_dmp    ( kstp, Nbb, Nnn, ts, Nrhs )  ! internal damping trends
332         IF( ln_bdy     )   CALL bdy_tra_dmp( kstp, Nbb,      ts, Nrhs )  ! bdy damping trends
333      END DO
334      IF( ln_tile ) CALL dom_tile_stop
335
336#if defined key_agrif
337      IF(.NOT. Agrif_Root() ) THEN
338                            CALL Agrif_Sponge_tra        ! tracers sponge
339      ENDIF
340#endif
341
342      ! TEMP: [tiling] Separate loop over tile domains (due to tra_adv workarounds for tiling)
343      IF( ln_tile ) CALL dom_tile_start         ! [tiling] TRA tiling loop (2)
344      DO jtile = 1, nijtile
345         IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = jtile )
346
347                            CALL tra_adv    ( kstp, Nbb, Nnn, ts, Nrhs )  ! hor. + vert. advection ==> RHS
348         IF( ln_zdfmfc  )   CALL tra_mfc    ( kstp, Nbb,      ts, Nrhs )  ! Mass Flux Convection
349         IF( ln_zdfosm  ) THEN
350                            CALL tra_osm    ( kstp,      Nnn, ts, Nrhs )  ! OSMOSIS non-local tracer fluxes ==> RHS
351            IF( lrst_oce )  CALL osm_rst    ( kstp,      Nnn, 'WRITE'  )  ! write OSMOSIS outputs + ww (so must do here) to restarts
352         ENDIF
353                            CALL tra_ldf    ( kstp, Nbb, Nnn, ts, Nrhs )  ! lateral mixing
354
355                            CALL tra_zdf    ( kstp, Nbb, Nnn, Nrhs, ts, Naa  )  ! vertical mixing and after tracer fields
356         IF( ln_zdfnpc  )   CALL tra_npc    ( kstp,      Nnn, Nrhs, ts, Naa  )  ! update after fields by non-penetrative convection
357      END DO
358      IF( ln_tile ) CALL dom_tile_stop
359
360      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
361      ! Set boundary conditions, time filter and swap time levels
362      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
363!!jc1: For agrif, it would be much better to finalize tracers/momentum here (e.g. bdy conditions) and move the swap
364!!    (and time filtering) after Agrif update. Then restart would be done after and would contain updated fields.
365!!    If so:
366!!    (i) no need to call agrif update at initialization time
367!!    (ii) no need to update "before" fields
368!!
369!!    Apart from creating new tra_swp/dyn_swp routines, this however:
370!!    (i) makes boundary conditions at initialization time computed from updated fields which is not the case between
371!!    two restarts => restartability issue. One can circumvent this, maybe, by assuming "interface separation",
372!!    e.g. a shift of the feedback interface inside child domain.
373!!    (ii) requires that all restart outputs of updated variables by agrif (e.g. passive tracers/tke/barotropic arrays) are done at the same
374!!    place.
375!!
376      IF( ln_dynspg_ts ) CALL mlf_baro_corr (            Nnn, Naa, uu, vv     )   ! barotrope adjustment
377                         CALL finalize_lbc  ( kstp, Nbb     , Naa, uu, vv, ts )   ! boundary conditions
378                         CALL tra_atf_qco   ( kstp, Nbb, Nnn, Naa        , ts )   ! time filtering of "now" tracer arrays
379                         CALL dyn_atf_qco   ( kstp, Nbb, Nnn, Naa, uu, vv     )   ! time filtering of "now" velocities
380      IF(.NOT.lk_linssh) THEN
381                         r3t(:,:,Nnn) = r3t_f(:,:)                                ! update now ssh/h_0 with time filtered values
382                         r3u(:,:,Nnn) = r3u_f(:,:)
383                         r3v(:,:,Nnn) = r3v_f(:,:)
384      ENDIF
385      !
386      ! Swap time levels
387      Nrhs = Nbb
388      Nbb = Nnn
389      Nnn = Naa
390      Naa = Nrhs
391      !
392      !
393      IF( ln_diahsb  )   CALL dia_hsb       ( kstp, Nbb, Nnn )  ! - ML - global conservation diagnostics
394
395!!gm : This does not only concern the dynamics ==>>> add a new title
396!!gm2: why ouput restart before AGRIF update?
397!!
398!!jc: That would be better, but see comment above
399!!
400      IF( lrst_oce   )   CALL rst_write    ( kstp, Nbb, Nnn )   ! write output ocean restart file
401      IF( ln_sto_eos )   CALL sto_rst_write( kstp )   ! write restart file for stochastic parameters
402
403#if defined key_agrif
404      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
405      ! AGRIF recursive integration
406      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
407                         Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs      ! agrif_oce module copies of time level indices
408                         CALL Agrif_Integrate_ChildGrids( stp_MLF )       ! allows to finish all the Child Grids before updating
409
410#endif
411      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
412      ! Control
413      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
414                         CALL stp_ctl      ( kstp, Nnn )
415
416#if defined key_agrif
417      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
418      ! AGRIF update
419      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
420      IF( Agrif_NbStepint() == 0 .AND. nstop == 0 )   &
421         &               CALL Agrif_update_all( )                  ! Update all components
422
423#endif
424      IF( ln_diaobs .AND. nstop == 0 )   &
425         &               CALL dia_obs( kstp, Nnn )  ! obs-minus-model (assimilation) diags (after dynamics update)
426
427      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
428      ! File manipulation at the end of the first time step
429      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
430      IF( kstp == nit000 ) THEN                          ! 1st time step only
431                                        CALL iom_close( numror )   ! close input  ocean restart file
432         IF( lrxios )                   CALL iom_context_finalize( cr_ocerst_cxt )
433         IF(lwm)                        CALL FLUSH    ( numond )   ! flush output namelist oce
434         IF(lwm .AND. numoni /= -1 )    CALL FLUSH    ( numoni )   ! flush output namelist ice (if exist)
435      ENDIF
436
437      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
438      ! Coupled mode
439      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
440      IF( lk_oasis .AND. nstop == 0 )   CALL sbc_cpl_snd( kstp, Nbb, Nnn )     ! coupled mode : field exchanges
441      !
442#if defined key_xios
443      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
444      ! Finalize contextes if end of simulation or error detected
445      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
446      IF( kstp == nitend .OR. nstop > 0 ) THEN
447                      CALL iom_context_finalize(      cxios_context          ) ! needed for XIOS+AGRIF
448         IF( ln_crs ) CALL iom_context_finalize( trim(cxios_context)//"_crs" ) !
449      ENDIF
450#endif
451      !
452      IF( l_1st_euler ) THEN         ! recover Leap-frog timestep
453         rDt   = 2._wp * rn_Dt
454         r1_Dt = 1._wp / rDt
455         l_1st_euler = .FALSE.
456      ENDIF
457      !
458      IF( ln_timing )   CALL timing_stop('stp_MLF')
459      !
460   END SUBROUTINE stp_MLF
461
462
463   SUBROUTINE mlf_baro_corr( Kmm, Kaa, puu, pvv )
464      !!----------------------------------------------------------------------
465      !!                  ***  ROUTINE mlf_baro_corr  ***
466      !!
467      !! ** Purpose :   Finalize after horizontal velocity.
468      !!
469      !! ** Method  : * Ensure after velocities transport matches time splitting
470      !!             estimate (ln_dynspg_ts=T)
471      !!
472      !! ** Action :   puu(Kmm),pvv(Kmm)   updated now horizontal velocity (ln_bt_fw=F)
473      !!               puu(Kaa),pvv(Kaa)   after horizontal velocity
474      !!----------------------------------------------------------------------
475      USE dynspg_ts, ONLY : un_adv, vn_adv   ! updated Kmm barotropic transport
476      !!
477      INTEGER                             , INTENT(in   ) ::   Kmm, Kaa   ! before and after time level indices
478      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::   puu, pvv   ! velocities
479      !
480      INTEGER  ::   ji,jj, jk   ! dummy loop indices
481      REAL(wp), DIMENSION(jpi,jpj) ::   zue, zve
482      !!----------------------------------------------------------------------
483
484      ! Ensure below that barotropic velocities match time splitting estimate
485      ! Compute actual transport and replace it with ts estimate at "after" time step
486      DO_2D( 0, 0, 0, 0 )
487         zue(ji,jj) = e3u(ji,jj,1,Kaa) * puu(ji,jj,1,Kaa) * umask(ji,jj,1)
488         zve(ji,jj) = e3v(ji,jj,1,Kaa) * pvv(ji,jj,1,Kaa) * vmask(ji,jj,1)
489      END_2D
490      DO jk = 2, jpkm1
491         DO_2D( 0, 0, 0, 0 )
492            zue(ji,jj) = zue(ji,jj) + e3u(ji,jj,jk,Kaa) * puu(ji,jj,jk,Kaa) * umask(ji,jj,jk)
493            zve(ji,jj) = zve(ji,jj) + e3v(ji,jj,jk,Kaa) * pvv(ji,jj,jk,Kaa) * vmask(ji,jj,jk)
494         END_2D
495      END DO
496      DO jk = 1, jpkm1
497         DO_2D( 0, 0, 0, 0 )
498            puu(ji,jj,jk,Kaa) = ( puu(ji,jj,jk,Kaa) - zue(ji,jj) * r1_hu(ji,jj,Kaa) + uu_b(ji,jj,Kaa) ) * umask(ji,jj,jk)
499            pvv(ji,jj,jk,Kaa) = ( pvv(ji,jj,jk,Kaa) - zve(ji,jj) * r1_hv(ji,jj,Kaa) + vv_b(ji,jj,Kaa) ) * vmask(ji,jj,jk)
500         END_2D
501      END DO
502      !
503      IF( .NOT.ln_bt_fw ) THEN
504         ! Remove advective velocity from "now velocities"
505         ! prior to asselin filtering
506         ! In the forward case, this is done below after asselin filtering
507         ! so that asselin contribution is removed at the same time
508         DO jk = 1, jpkm1
509            DO_2D( 0, 0, 0, 0 )
510               puu(ji,jj,jk,Kmm) = ( puu(ji,jj,jk,Kmm) - un_adv(ji,jj)*r1_hu(ji,jj,Kmm) + uu_b(ji,jj,Kmm) )*umask(ji,jj,jk)
511               pvv(ji,jj,jk,Kmm) = ( pvv(ji,jj,jk,Kmm) - vn_adv(ji,jj)*r1_hv(ji,jj,Kmm) + vv_b(ji,jj,Kmm) )*vmask(ji,jj,jk)
512            END_2D
513         END DO
514      ENDIF
515      !
516   END SUBROUTINE mlf_baro_corr
517
518
519   SUBROUTINE finalize_lbc( kt, Kbb, Kaa, puu, pvv, pts )
520      !!----------------------------------------------------------------------
521      !!                  ***  ROUTINE finalize_lbc  ***
522      !!
523      !! ** Purpose :   Apply the boundary condition on the after velocity
524      !!
525      !! ** Method  : * Apply lateral boundary conditions on after velocity
526      !!             at the local domain boundaries through lbc_lnk call,
527      !!             at the one-way open boundaries (ln_bdy=T),
528      !!             at the AGRIF zoom   boundaries (lk_agrif=T)
529      !!
530      !! ** Action :   puu(Kaa),pvv(Kaa)   after horizontal velocity and tracers
531      !!----------------------------------------------------------------------
532#if defined key_agrif
533      USE agrif_oce_interp
534#endif
535      USE bdydyn         ! ocean open boundary conditions (define bdy_dyn)
536      !!
537      INTEGER                                  , INTENT(in   ) ::   kt         ! ocean time-step index
538      INTEGER                                  , INTENT(in   ) ::   Kbb, Kaa   ! before and after time level indices
539      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt)     , INTENT(inout) ::   puu, pvv   ! velocities to be time filtered
540      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts,jpt), INTENT(inout) ::   pts        ! active tracers
541      !!----------------------------------------------------------------------
542      !
543      ! Update after tracer and velocity on domain lateral boundaries
544      !
545# if defined key_agrif
546            CALL Agrif_tra                     !* AGRIF zoom boundaries
547            CALL Agrif_dyn( kt )
548# endif
549      !                                        ! local domain boundaries  (T-point, unchanged sign)
550      CALL lbc_lnk( 'finalize_lbc', puu(:,:,:,       Kaa), 'U', -1., pvv(:,:,:       ,Kaa), 'V', -1.   &
551                       &          , pts(:,:,:,jp_tem,Kaa), 'T',  1., pts(:,:,:,jp_sal,Kaa), 'T',  1. )
552      !
553      ! lbc_lnk needed for zdf_sh2 when using nn_hls = 2, moved here to allow tiling in zdf_phy
554      IF( nn_hls == 2 .AND. l_zdfsh2 ) CALL lbc_lnk( 'stp', avm_k, 'W', 1.0_wp )
555
556      ! dom_qco_r3c defines over [nn_hls, nn_hls-1, nn_hls, nn_hls-1]
557      IF( nn_hls == 2 .AND. .NOT. lk_linssh ) THEN
558         CALL lbc_lnk( 'finalize_lbc', r3u(:,:,Kaa), 'U', 1._wp, r3v(:,:,Kaa), 'V', 1._wp, &
559            &                          r3u_f(:,:),   'U', 1._wp, r3v_f(:,:),   'V', 1._wp )
560      ENDIF
561      !                                        !* BDY open boundaries
562      IF( ln_bdy )   THEN
563                               CALL bdy_tra( kt, Kbb, pts,      Kaa )
564         IF( ln_dynspg_exp )   CALL bdy_dyn( kt, Kbb, puu, pvv, Kaa )
565         IF( ln_dynspg_ts  )   CALL bdy_dyn( kt, Kbb, puu, pvv, Kaa, dyn3d_only=.true. )
566      ENDIF
567      !
568   END SUBROUTINE finalize_lbc
569
570#else
571   !!----------------------------------------------------------------------
572   !!   default option             EMPTY MODULE           qco not activated
573   !!----------------------------------------------------------------------
574#endif
575   
576   !!======================================================================
577END MODULE stpmlf
Note: See TracBrowser for help on using the repository browser.