source: NEMO/trunk/src/OCE/timing.F90 @ 13226

Last change on this file since 13226 was 12489, checked in by davestorkey, 9 months ago

Preparation for new timestepping scheme #2390.
Main changes:

  1. Initial euler timestep now handled in stp and not in TRA/DYN routines.
  2. Renaming of all timestep parameters. In summary, the namelist parameter is now rn_Dt and the current timestep is rDt (and rDt_ice, rDt_trc etc).
  3. Renaming of a few miscellaneous parameters, eg. atfp → rn_atfp (namelist parameter used everywhere) and rau0 → rho0.

This version gives bit-comparable results to the previous version of the trunk.

  • Property svn:keywords set to Id
File size: 35.6 KB
Line 
1MODULE timing
2   !!========================================================================
3   !!                     ***  MODULE  timing  ***
4   !!========================================================================
5   !! History : 4.0  ! 2001-05  (R. Benshila)   
6   !!------------------------------------------------------------------------
7
8   !!------------------------------------------------------------------------
9   !!   timming_init    : initialize timing process
10   !!   timing_start    : start Timer
11   !!   timing_stop     : stop  Timer
12   !!   timing_reset    : end timing variable creation
13   !!   timing_finalize : compute stats and write output in calling w*_info
14   !!   timing_ini_var  : create timing variables
15   !!   timing_listing  : print instumented subroutines in ocean.output
16   !!   wcurrent_info   : compute and print detailed stats on the current CPU
17   !!   wave_info       : compute and print averaged statson all processors
18   !!   wmpi_info       : compute and write global stats 
19   !!   supress         : suppress an element of the timing linked list 
20   !!   insert          : insert an element of the timing linked list 
21   !!------------------------------------------------------------------------
22   USE in_out_manager  ! I/O manager
23   USE dom_oce         ! ocean domain
24   USE lib_mpp         
25   
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   timing_init, timing_finalize   ! called in nemogcm module
30   PUBLIC   timing_reset                   ! called in step module
31   PUBLIC   timing_start, timing_stop      ! called in each routine to time
32   
33#if defined key_mpp_mpi
34   INCLUDE 'mpif.h'
35#endif
36
37   ! Variables for fine grain timing
38   TYPE timer
39      CHARACTER(LEN=20)  :: cname
40      CHARACTER(LEN=20)  :: surname
41      INTEGER :: rank
42      REAL(wp)  :: t_cpu, t_clock, tsum_cpu, tsum_clock, tmax_cpu, tmax_clock, tmin_cpu, tmin_clock, tsub_cpu, tsub_clock
43      INTEGER :: ncount, ncount_max, ncount_rate 
44      INTEGER :: niter
45      LOGICAL :: l_tdone
46      TYPE(timer), POINTER :: next => NULL()
47      TYPE(timer), POINTER :: prev => NULL()
48      TYPE(timer), POINTER :: parent_section => NULL()
49   END TYPE timer
50   
51   TYPE alltimer
52      CHARACTER(LEN=20), DIMENSION(:), POINTER :: cname => NULL()
53      REAL(wp), DIMENSION(:), POINTER :: tsum_cpu   => NULL()
54      REAL(wp), DIMENSION(:), POINTER :: tsum_clock => NULL()
55      INTEGER, DIMENSION(:), POINTER :: niter => NULL()
56      TYPE(alltimer), POINTER :: next => NULL()
57      TYPE(alltimer), POINTER :: prev => NULL()
58   END TYPE alltimer 
59 
60   TYPE(timer), POINTER :: s_timer_root => NULL()
61   TYPE(timer), POINTER :: s_timer      => NULL()
62   TYPE(timer), POINTER :: s_timer_old      => NULL()
63
64   TYPE(timer), POINTER :: s_wrk        => NULL()
65   REAL(wp) :: t_overclock, t_overcpu
66   LOGICAL :: l_initdone = .FALSE.
67   INTEGER :: nsize
68   
69   ! Variables for coarse grain timing
70   REAL(wp) :: tot_etime, tot_ctime
71   REAL(kind=wp), DIMENSION(2)     :: t_elaps, t_cpu
72   REAL(wp), ALLOCATABLE, DIMENSION(:) :: all_etime, all_ctime
73   INTEGER :: nfinal_count, ncount, ncount_rate, ncount_max
74   INTEGER, DIMENSION(8)           :: nvalues
75   CHARACTER(LEN=8), DIMENSION(2)  :: cdate
76   CHARACTER(LEN=10), DIMENSION(2) :: ctime
77   CHARACTER(LEN=5)                :: czone
78   
79   ! From of ouput file (1/proc or one global)   !RB to put in nammpp or namctl
80   LOGICAL :: ln_onefile = .TRUE. 
81   LOGICAL :: lwriter
82   !!----------------------------------------------------------------------
83   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
84   !! $Id$
85   !! Software governed by the CeCILL license (see ./LICENSE)
86   !!----------------------------------------------------------------------
87CONTAINS
88
89   SUBROUTINE timing_start(cdinfo)
90      !!----------------------------------------------------------------------
91      !!               ***  ROUTINE timing_start  ***
92      !! ** Purpose :   collect execution time
93      !!----------------------------------------------------------------------
94      CHARACTER(len=*), INTENT(in) :: cdinfo
95      !
96       IF(ASSOCIATED(s_timer) ) s_timer_old => s_timer
97       !
98      ! Create timing structure at first call of the routine
99       CALL timing_ini_var(cdinfo)
100   !   write(*,*) 'after inivar ', s_timer%cname
101
102      ! ici timing_ini_var a soit retrouve s_timer et fait return soit ajoute un maillon
103      ! maintenant on regarde si le call d'avant corrsspond a un parent ou si il est ferme
104      IF( .NOT. s_timer_old%l_tdone ) THEN     
105         s_timer%parent_section => s_timer_old
106      ELSE
107         s_timer%parent_section => NULL()
108      ENDIF   
109
110      s_timer%l_tdone = .FALSE.
111      s_timer%niter = s_timer%niter + 1
112      s_timer%t_cpu = 0.
113      s_timer%t_clock = 0.
114                 
115      ! CPU time collection
116      CALL CPU_TIME( s_timer%t_cpu  )
117      ! clock time collection
118#if defined key_mpp_mpi
119      s_timer%t_clock= MPI_Wtime()
120#else
121      CALL SYSTEM_CLOCK(COUNT_RATE=s_timer%ncount_rate, COUNT_MAX=s_timer%ncount_max)
122      CALL SYSTEM_CLOCK(COUNT = s_timer%ncount)
123#endif
124!      write(*,*) 'end of start ', s_timer%cname
125
126      !
127   END SUBROUTINE timing_start
128
129
130   SUBROUTINE timing_stop(cdinfo, csection)
131      !!----------------------------------------------------------------------
132      !!               ***  ROUTINE timing_stop  ***
133      !! ** Purpose :   finalize timing and output
134      !!----------------------------------------------------------------------
135      CHARACTER(len=*), INTENT(in) :: cdinfo
136      CHARACTER(len=*), INTENT(in), OPTIONAL :: csection
137      !
138      INTEGER  :: ifinal_count, iperiods   
139      REAL(wp) :: zcpu_end, zmpitime,zcpu_raw,zclock_raw
140      !
141      s_wrk => NULL()
142
143      ! clock time collection
144#if defined key_mpp_mpi
145      zmpitime = MPI_Wtime()
146#else
147      CALL SYSTEM_CLOCK(COUNT = ifinal_count)
148#endif
149      ! CPU time collection
150      CALL CPU_TIME( zcpu_end )
151
152!!$      IF(associated(s_timer%parent_section))then
153!!$        write(*,*) s_timer%cname,' <-- ', s_timer%parent_section%cname
154!!$      ENDIF 
155
156 !     No need to search ... : s_timer has the last value defined in start
157 !     s_timer => s_timer_root
158 !     DO WHILE( TRIM(s_timer%cname) /= TRIM(cdinfo) )
159 !        IF( ASSOCIATED(s_timer%next) ) s_timer => s_timer%next
160 !     END DO
161 
162      ! CPU time correction
163      zcpu_raw = zcpu_end - s_timer%t_cpu - t_overcpu ! total time including child
164      s_timer%t_cpu  = zcpu_raw - s_timer%tsub_cpu
165  !    IF(s_timer%cname==trim('lbc_lnk_2d'))  write(*,*) s_timer%tsub_cpu,zcpu_end
166
167      ! clock time correction
168#if defined key_mpp_mpi
169      zclock_raw = zmpitime - s_timer%t_clock - t_overclock ! total time including child
170      s_timer%t_clock = zclock_raw - t_overclock - s_timer%tsub_clock
171#else
172      iperiods = ifinal_count - s_timer%ncount
173      IF( ifinal_count < s_timer%ncount )  &
174         iperiods = iperiods + s_timer%ncount_max 
175         zclock_raw = REAL(iperiods) / s_timer%ncount_rate !- t_overclock   
176         s_timer%t_clock  = zclock_raw - s_timer%tsub_clock
177#endif
178 !     IF(s_timer%cname==trim('lbc_lnk_2d')) write(*,*) zclock_raw , s_timer%tsub_clock
179     
180      ! Correction of parent section
181      IF( .NOT. PRESENT(csection) ) THEN
182         IF ( ASSOCIATED(s_timer%parent_section ) ) THEN
183            s_timer%parent_section%tsub_cpu   = zcpu_raw   + s_timer%parent_section%tsub_cpu 
184            s_timer%parent_section%tsub_clock = zclock_raw + s_timer%parent_section%tsub_clock             
185         ENDIF
186      ENDIF
187           
188      ! time diagnostics
189      s_timer%tsum_clock = s_timer%tsum_clock + s_timer%t_clock 
190      s_timer%tsum_cpu   = s_timer%tsum_cpu   + s_timer%t_cpu
191!RB to use to get min/max during a time integration
192!      IF( .NOT. l_initdone ) THEN
193!         s_timer%tmin_clock = s_timer%t_clock
194!         s_timer%tmin_cpu   = s_timer%t_cpu
195!      ELSE
196!         s_timer%tmin_clock = MIN( s_timer%tmin_clock, s_timer%t_clock )
197!         s_timer%tmin_cpu   = MIN( s_timer%tmin_cpu  , s_timer%t_cpu   )
198!      ENDIF   
199!      s_timer%tmax_clock = MAX( s_timer%tmax_clock, s_timer%t_clock )
200!      s_timer%tmax_cpu   = MAX( s_timer%tmax_cpu  , s_timer%t_cpu   ) 
201      !
202      s_timer%tsub_clock = 0.
203      s_timer%tsub_cpu = 0.
204      s_timer%l_tdone = .TRUE.
205      !
206      !
207      ! we come back
208      IF ( ASSOCIATED(s_timer%parent_section ) ) s_timer => s_timer%parent_section
209     
210!      write(*,*) 'end of stop ', s_timer%cname
211
212   END SUBROUTINE timing_stop
213 
214 
215   SUBROUTINE timing_init
216      !!----------------------------------------------------------------------
217      !!               ***  ROUTINE timing_init  ***
218      !! ** Purpose :   open timing output file
219      !!----------------------------------------------------------------------
220      INTEGER :: iperiods, istart_count, ifinal_count
221      REAL(wp) :: zdum
222      LOGICAL :: ll_f
223             
224      IF( ln_onefile ) THEN
225         IF( lwp) CALL ctl_opn( numtime, 'timing.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout,.TRUE., narea )
226         lwriter = lwp
227      ELSE
228         CALL ctl_opn( numtime, 'timing.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout,.FALSE., narea )
229         lwriter = .TRUE.
230      ENDIF
231     
232      IF( lwriter) THEN     
233         WRITE(numtime,*)
234         WRITE(numtime,*) '      CNRS - NERC - Met OFFICE - MERCATOR-ocean - CMCC - INGV'
235         WRITE(numtime,*) '                             NEMO team'
236         WRITE(numtime,*) '                  Ocean General Circulation Model'
237         WRITE(numtime,*) '                        version 4.0  (2019) '
238         WRITE(numtime,*)
239         WRITE(numtime,*) '                        Timing Informations '
240         WRITE(numtime,*)
241         WRITE(numtime,*)
242      ENDIF   
243     
244      ! Compute clock function overhead
245#if defined key_mpp_mpi       
246      t_overclock = MPI_WTIME()
247      t_overclock = MPI_WTIME() - t_overclock
248#else       
249      CALL SYSTEM_CLOCK(COUNT_RATE=ncount_rate, COUNT_MAX=ncount_max)
250      CALL SYSTEM_CLOCK(COUNT = istart_count)
251      CALL SYSTEM_CLOCK(COUNT = ifinal_count)
252      iperiods = ifinal_count - istart_count
253      IF( ifinal_count < istart_count )  &
254          iperiods = iperiods + ncount_max 
255      t_overclock = REAL(iperiods) / ncount_rate
256#endif
257
258      ! Compute cpu_time function overhead
259      CALL CPU_TIME(zdum)
260      CALL CPU_TIME(t_overcpu)
261     
262      ! End overhead omputation 
263      t_overcpu = t_overcpu - zdum       
264      t_overclock = t_overcpu + t_overclock       
265
266      ! Timing on date and time
267      CALL DATE_AND_TIME(cdate(1),ctime(1),czone,nvalues)
268   
269      CALL CPU_TIME(t_cpu(1))     
270#if defined key_mpp_mpi       
271      ! Start elapsed and CPU time counters
272      t_elaps(1) = MPI_WTIME()
273#else
274      CALL SYSTEM_CLOCK(COUNT_RATE=ncount_rate, COUNT_MAX=ncount_max)
275      CALL SYSTEM_CLOCK(COUNT = ncount)
276#endif                 
277      !
278   END SUBROUTINE timing_init
279
280
281   SUBROUTINE timing_finalize
282      !!----------------------------------------------------------------------
283      !!               ***  ROUTINE timing_finalize ***
284      !! ** Purpose :  compute average time
285      !!               write timing output file
286      !!----------------------------------------------------------------------
287      TYPE(timer), POINTER :: s_temp
288      INTEGER :: idum, iperiods, icode
289      INTEGER :: ji
290      LOGICAL :: ll_ord, ll_averep
291      CHARACTER(len=120) :: clfmt           
292      REAL(wp), DIMENSION(:), ALLOCATABLE ::   timing_glob
293      REAL(wp) ::   zsypd   ! simulated years per day (Balaji 2017)
294      REAL(wp) ::   zperc, ztot
295
296      ll_averep = .TRUE.
297   
298      ! total CPU and elapse
299      CALL CPU_TIME(t_cpu(2))
300      t_cpu(2)   = t_cpu(2)    - t_cpu(1)   - t_overcpu
301#if defined key_mpp_mpi
302      t_elaps(2) = MPI_WTIME() - t_elaps(1) - t_overclock
303#else
304      CALL SYSTEM_CLOCK(COUNT = nfinal_count)
305      iperiods = nfinal_count - ncount
306      IF( nfinal_count < ncount )  &
307          iperiods = iperiods + ncount_max 
308      t_elaps(2) = REAL(iperiods) / ncount_rate - t_overclock
309#endif     
310
311      ! End of timings on date & time
312      CALL DATE_AND_TIME(cdate(2),ctime(2),czone,nvalues)
313       
314      ! Compute the numer of routines
315      nsize = 0 
316      s_timer => s_timer_root
317      DO WHILE( ASSOCIATED(s_timer) )
318         nsize = nsize + 1
319         s_timer => s_timer%next
320      END DO
321      idum = nsize
322      CALL mpp_sum('timing', idum)
323      IF( idum/jpnij /= nsize ) THEN
324         IF( lwriter ) WRITE(numtime,*) '        ===> W A R N I N G: '
325         IF( lwriter ) WRITE(numtime,*) ' Some CPU have different number of routines instrumented for timing'
326         IF( lwriter ) WRITE(numtime,*) ' No detailed report on averaged timing can be provided'
327         IF( lwriter ) WRITE(numtime,*) ' The following detailed report only deals with the current processor'
328         IF( lwriter ) WRITE(numtime,*)
329         ll_averep = .FALSE.
330      ENDIF   
331
332#if defined key_mpp_mpi     
333      ! in MPI gather some info
334      ALLOCATE( all_etime(jpnij), all_ctime(jpnij) )
335      CALL MPI_ALLGATHER(t_elaps(2), 1, MPI_DOUBLE_PRECISION,   &
336                         all_etime , 1, MPI_DOUBLE_PRECISION,   &
337                         MPI_COMM_OCE, icode)
338      CALL MPI_ALLGATHER(t_cpu(2) , 1, MPI_DOUBLE_PRECISION,   &
339                         all_ctime, 1, MPI_DOUBLE_PRECISION,   &
340                         MPI_COMM_OCE, icode)
341      tot_etime = SUM(all_etime(:))
342      tot_ctime = SUM(all_ctime(:))
343#else
344      tot_etime = t_elaps(2)
345      tot_ctime = t_cpu  (2)           
346#endif
347
348      ! write output file
349      IF( lwriter ) WRITE(numtime,*) 
350      IF( lwriter ) WRITE(numtime,*) 
351      IF( lwriter ) WRITE(numtime,*) 'Total timing (sum) :'
352      IF( lwriter ) WRITE(numtime,*) '--------------------'
353      IF( lwriter ) WRITE(numtime,"('Elapsed Time (s)  CPU Time (s)')")
354      IF( lwriter ) WRITE(numtime,'(5x,f12.3,1x,f12.3)')  tot_etime, tot_ctime
355      IF( lwriter ) WRITE(numtime,*) 
356#if defined key_mpp_mpi
357      IF( ll_averep ) CALL waver_info
358      CALL wmpi_info
359#endif     
360      IF( lwriter ) CALL wcurrent_info
361     
362      clfmt='(1X,"Timing started on ",2(A2,"/"),A4," at ",2(A2,":"),A2," MET ",A3,":",A2," from GMT")'
363      IF( lwriter ) WRITE(numtime, TRIM(clfmt)) &           
364      &       cdate(1)(7:8), cdate(1)(5:6), cdate(1)(1:4),   &
365      &       ctime(1)(1:2), ctime(1)(3:4), ctime(1)(5:6),   &
366      &       czone(1:3),    czone(4:5)                     
367      clfmt='(1X,  "Timing   ended on ",2(A2,"/"),A4," at ",2(A2,":"),A2," MET ",A3,":",A2," from GMT")'
368      IF( lwriter ) WRITE(numtime, TRIM(clfmt)) &           
369      &       cdate(2)(7:8), cdate(2)(5:6), cdate(2)(1:4),   &
370      &       ctime(2)(1:2), ctime(2)(3:4), ctime(2)(5:6),   &
371      &       czone(1:3),    czone(4:5)
372
373#if defined key_mpp_mpi
374      ALLOCATE(timing_glob(4*jpnij), stat=icode)
375      CALL MPI_GATHER( (/compute_time, waiting_time(1), waiting_time(2), elapsed_time/),   &
376         &             4, MPI_DOUBLE_PRECISION, timing_glob, 4, MPI_DOUBLE_PRECISION, 0, MPI_COMM_OCE, icode)
377      IF( narea == 1 ) THEN
378         WRITE(numtime,*) ' '
379         WRITE(numtime,*) ' Report on time spent on waiting MPI messages '
380         WRITE(numtime,*) '    total timing measured between nit000+1 and nitend-1 '
381         WRITE(numtime,*) '    warning: includes restarts writing time if output before nitend... '
382         WRITE(numtime,*) ' '
383         DO ji = 1, jpnij
384            ztot = SUM( timing_glob(4*ji-3:4*ji-1) )
385            WRITE(numtime,'(A28,F11.6,            A34,I8)') 'Computing       time : ',timing_glob(4*ji-3), ' on MPI rank : ', ji
386            IF ( ztot /= 0. ) zperc = timing_glob(4*ji-2) / ztot * 100.
387            WRITE(numtime,'(A28,F11.6,A2, F4.1,A3,A25,I8)') 'Waiting lbc_lnk time : ',timing_glob(4*ji-2)   &
388               &                                                         , ' (',      zperc,' %)',   ' on MPI rank : ', ji
389            IF ( ztot /= 0. ) zperc = timing_glob(4*ji-1) / ztot * 100.
390            WRITE(numtime,'(A28,F11.6,A2, F4.1,A3,A25,I8)') 'Waiting  global time : ',timing_glob(4*ji-1)   &
391               &                                                         , ' (',      zperc,' %)',   ' on MPI rank : ', ji
392            zsypd = rn_Dt * REAL(nitend-nit000-1, wp) / (timing_glob(4*ji) * 365.)
393            WRITE(numtime,'(A28,F11.6,A7,F10.3,A2,A15,I8)') 'Total           time : ',timing_glob(4*ji  )   &
394               &                                                         , ' (SYPD: ', zsypd, ')',   ' on MPI rank : ', ji
395         END DO
396      ENDIF
397      DEALLOCATE(timing_glob)
398#endif     
399
400      IF( lwriter ) CLOSE(numtime) 
401      !
402   END SUBROUTINE timing_finalize
403   
404
405   SUBROUTINE wcurrent_info
406      !!----------------------------------------------------------------------
407      !!               ***  ROUTINE wcurrent_info ***
408      !! ** Purpose :  compute and write timing output file
409      !!----------------------------------------------------------------------
410      LOGICAL :: ll_ord
411      CHARACTER(len=2048) :: clfmt           
412   
413      ! reorder the current list by elapse time     
414      s_wrk => NULL()
415      s_timer => s_timer_root
416      DO
417         ll_ord = .TRUE.
418         s_timer => s_timer_root
419         DO WHILE ( ASSOCIATED( s_timer%next ) )
420         IF (.NOT. ASSOCIATED(s_timer%next)) EXIT
421            IF ( s_timer%tsum_clock < s_timer%next%tsum_clock ) THEN
422               ALLOCATE(s_wrk)
423               s_wrk = s_timer%next
424               CALL insert  (s_timer, s_timer_root, s_wrk)
425               CALL suppress(s_timer%next)           
426               ll_ord = .FALSE.
427               CYCLE           
428            ENDIF           
429         IF( ASSOCIATED(s_timer%next) ) s_timer => s_timer%next
430         END DO         
431         IF( ll_ord ) EXIT
432      END DO
433           
434      ! write current info
435      WRITE(numtime,*) 'Detailed timing for proc :', narea-1
436      WRITE(numtime,*) '--------------------------'
437      WRITE(numtime,*) 'Section             ',            &
438      &   'Elapsed Time (s)  ','Elapsed Time (%)  ',   &
439      &   'CPU Time(s)  ','CPU Time (%)  ','CPU/Elapsed  ','Frequency' 
440      s_timer => s_timer_root 
441      clfmt = '(1x,a,4x,f12.3,6x,f12.3,x,f12.3,2x,f12.3,6x,f7.3,2x,i9)'
442      DO WHILE ( ASSOCIATED(s_timer) )
443         WRITE(numtime,TRIM(clfmt))   s_timer%cname,   &
444         &   s_timer%tsum_clock,s_timer%tsum_clock*100./t_elaps(2),            &
445         &   s_timer%tsum_cpu  ,s_timer%tsum_cpu*100./t_cpu(2)    ,            &
446         &   s_timer%tsum_cpu/s_timer%tsum_clock, s_timer%niter
447         s_timer => s_timer%next
448      END DO
449      WRITE(numtime,*)
450      !                 
451   END SUBROUTINE wcurrent_info
452
453#if defined key_mpp_mpi     
454   SUBROUTINE waver_info
455      !!----------------------------------------------------------------------
456      !!               ***  ROUTINE wcurrent_info ***
457      !! ** Purpose :  compute and write averaged timing informations
458      !!----------------------------------------------------------------------
459      TYPE(alltimer), POINTER :: sl_timer_glob_root => NULL()
460      TYPE(alltimer), POINTER :: sl_timer_glob      => NULL()
461      TYPE(timer), POINTER :: sl_timer_ave_root => NULL()
462      TYPE(timer), POINTER :: sl_timer_ave      => NULL()
463      INTEGER :: icode
464      INTEGER :: ierr
465      LOGICAL :: ll_ord           
466      CHARACTER(len=200) :: clfmt             
467                 
468      ! Initialised the global strucutre   
469      ALLOCATE(sl_timer_glob_root, Stat=ierr)
470      IF(ierr /= 0)THEN
471         WRITE(numtime,*) 'Failed to allocate global timing structure in waver_info'
472         RETURN
473      END IF
474
475      ALLOCATE(sl_timer_glob_root%cname     (jpnij), &
476               sl_timer_glob_root%tsum_cpu  (jpnij), &
477               sl_timer_glob_root%tsum_clock(jpnij), &
478               sl_timer_glob_root%niter     (jpnij), Stat=ierr)
479      IF(ierr /= 0)THEN
480         WRITE(numtime,*) 'Failed to allocate global timing structure in waver_info'
481         RETURN
482      END IF
483      sl_timer_glob_root%cname(:)       = ''
484      sl_timer_glob_root%tsum_cpu(:)   = 0._wp
485      sl_timer_glob_root%tsum_clock(:) = 0._wp
486      sl_timer_glob_root%niter(:)      = 0
487      sl_timer_glob_root%next => NULL()
488      sl_timer_glob_root%prev => NULL()
489      !ARPDBG - don't need to allocate a pointer that's immediately then
490      !         set to point to some other object.
491      !ALLOCATE(sl_timer_glob)
492      !ALLOCATE(sl_timer_glob%cname     (jpnij))
493      !ALLOCATE(sl_timer_glob%tsum_cpu  (jpnij))
494      !ALLOCATE(sl_timer_glob%tsum_clock(jpnij))
495      !ALLOCATE(sl_timer_glob%niter     (jpnij))
496      sl_timer_glob => sl_timer_glob_root
497      !
498      IF( narea .EQ. 1 ) THEN
499         ALLOCATE(sl_timer_ave_root)
500         sl_timer_ave_root%cname       = ''
501         sl_timer_ave_root%t_cpu      = 0._wp
502         sl_timer_ave_root%t_clock    = 0._wp
503         sl_timer_ave_root%tsum_cpu   = 0._wp
504         sl_timer_ave_root%tsum_clock = 0._wp
505         sl_timer_ave_root%tmax_cpu   = 0._wp
506         sl_timer_ave_root%tmax_clock = 0._wp
507         sl_timer_ave_root%tmin_cpu   = 0._wp
508         sl_timer_ave_root%tmin_clock = 0._wp
509         sl_timer_ave_root%tsub_cpu   = 0._wp
510         sl_timer_ave_root%tsub_clock = 0._wp
511         sl_timer_ave_root%ncount      = 0
512         sl_timer_ave_root%ncount_rate = 0
513         sl_timer_ave_root%ncount_max  = 0
514         sl_timer_ave_root%niter       = 0
515         sl_timer_ave_root%l_tdone  = .FALSE.
516         sl_timer_ave_root%next => NULL()
517         sl_timer_ave_root%prev => NULL()
518         ALLOCATE(sl_timer_ave)
519         sl_timer_ave => sl_timer_ave_root           
520      ENDIF 
521
522      ! Gather info from all processors
523      s_timer => s_timer_root
524      DO WHILE ( ASSOCIATED(s_timer) )
525         CALL MPI_GATHER(s_timer%cname     , 20, MPI_CHARACTER,   &
526                         sl_timer_glob%cname, 20, MPI_CHARACTER,   &
527                         0, MPI_COMM_OCE, icode)
528         CALL MPI_GATHER(s_timer%tsum_clock     , 1, MPI_DOUBLE_PRECISION,   &
529                         sl_timer_glob%tsum_clock, 1, MPI_DOUBLE_PRECISION,   &
530                         0, MPI_COMM_OCE, icode)
531         CALL MPI_GATHER(s_timer%tsum_cpu     , 1, MPI_DOUBLE_PRECISION,   &
532                         sl_timer_glob%tsum_cpu, 1, MPI_DOUBLE_PRECISION,   &
533                         0, MPI_COMM_OCE, icode)
534         CALL MPI_GATHER(s_timer%niter     , 1, MPI_INTEGER,   &
535                         sl_timer_glob%niter, 1, MPI_INTEGER,   &
536                         0, MPI_COMM_OCE, icode)
537
538         IF( narea == 1 .AND. ASSOCIATED(s_timer%next) ) THEN
539            ALLOCATE(sl_timer_glob%next)
540            ALLOCATE(sl_timer_glob%next%cname     (jpnij))
541            ALLOCATE(sl_timer_glob%next%tsum_cpu  (jpnij))
542            ALLOCATE(sl_timer_glob%next%tsum_clock(jpnij))
543            ALLOCATE(sl_timer_glob%next%niter     (jpnij))
544            sl_timer_glob%next%prev => sl_timer_glob
545            sl_timer_glob%next%next => NULL()
546            sl_timer_glob           => sl_timer_glob%next
547         ENDIF             
548         s_timer => s_timer%next
549      END DO     
550     
551      IF( narea == 1 ) THEN   
552         ! Compute some stats
553         sl_timer_glob => sl_timer_glob_root
554         DO WHILE( ASSOCIATED(sl_timer_glob) )
555            sl_timer_ave%cname  = sl_timer_glob%cname(1)
556            sl_timer_ave%tsum_cpu   = SUM   (sl_timer_glob%tsum_cpu  (:)) / jpnij
557            sl_timer_ave%tsum_clock = SUM   (sl_timer_glob%tsum_clock(:)) / jpnij
558            sl_timer_ave%tmax_cpu   = MAXVAL(sl_timer_glob%tsum_cpu  (:))
559            sl_timer_ave%tmax_clock = MAXVAL(sl_timer_glob%tsum_clock(:))
560            sl_timer_ave%tmin_cpu   = MINVAL(sl_timer_glob%tsum_cpu  (:))
561            sl_timer_ave%tmin_clock = MINVAL(sl_timer_glob%tsum_clock(:))
562            sl_timer_ave%niter      = SUM   (sl_timer_glob%niter     (:))
563            !
564            IF( ASSOCIATED(sl_timer_glob%next) ) THEN
565               ALLOCATE(sl_timer_ave%next)         
566               sl_timer_ave%next%prev => sl_timer_ave
567               sl_timer_ave%next%next => NULL()           
568               sl_timer_ave           => sl_timer_ave%next
569            ENDIF
570            sl_timer_glob => sl_timer_glob%next                               
571         END DO
572     
573         ! reorder the averaged list by CPU time     
574         s_wrk => NULL()
575         sl_timer_ave => sl_timer_ave_root
576         DO
577            ll_ord = .TRUE.
578            sl_timer_ave => sl_timer_ave_root
579            DO WHILE( ASSOCIATED( sl_timer_ave%next ) )
580
581               IF( .NOT. ASSOCIATED(sl_timer_ave%next) ) EXIT
582
583               IF ( sl_timer_ave%tsum_clock < sl_timer_ave%next%tsum_clock ) THEN
584                  ALLOCATE(s_wrk)
585                  ! Copy data into the new object pointed to by s_wrk
586                  s_wrk = sl_timer_ave%next
587                  ! Insert this new timer object before our current position
588                  CALL insert  (sl_timer_ave, sl_timer_ave_root, s_wrk)
589                  ! Remove the old object from the list
590                  CALL suppress(sl_timer_ave%next)           
591                  ll_ord = .FALSE.
592                  CYCLE           
593               ENDIF           
594               IF( ASSOCIATED(sl_timer_ave%next) ) sl_timer_ave => sl_timer_ave%next
595            END DO         
596            IF( ll_ord ) EXIT
597         END DO
598
599         ! write averaged info
600         WRITE(numtime,"('Averaged timing on all processors :')")
601         WRITE(numtime,"('-----------------------------------')")
602         WRITE(numtime,"('Section',13x,'Elap. Time(s)',2x,'Elap. Time(%)',2x, &
603         &   'CPU Time(s)',2x,'CPU Time(%)',2x,'CPU/Elap',1x,   &
604         &   'Max elap(%)',2x,'Min elap(%)',2x,            &           
605         &   'Freq')")
606         sl_timer_ave => sl_timer_ave_root 
607         clfmt = '((A),E15.7,2x,f6.2,5x,f12.2,5x,f6.2,5x,f7.2,2x,f12.2,4x,f6.2,2x,f9.2)'
608         DO WHILE ( ASSOCIATED(sl_timer_ave) )
609            WRITE(numtime,TRIM(clfmt))   sl_timer_ave%cname(1:18),                            &
610            &   sl_timer_ave%tsum_clock,sl_timer_ave%tsum_clock*100.*jpnij/tot_etime,   &
611            &   sl_timer_ave%tsum_cpu  ,sl_timer_ave%tsum_cpu*100.*jpnij/tot_ctime  ,   &
612            &   sl_timer_ave%tsum_cpu/sl_timer_ave%tsum_clock,                          &
613            &   sl_timer_ave%tmax_clock*100.*jpnij/tot_etime,                           &
614            &   sl_timer_ave%tmin_clock*100.*jpnij/tot_etime,                           &                                               
615            &   sl_timer_ave%niter/REAL(jpnij)
616            sl_timer_ave => sl_timer_ave%next
617         END DO
618         WRITE(numtime,*)
619         !
620         DEALLOCATE(sl_timer_ave_root)
621      ENDIF
622      !
623      DEALLOCATE(sl_timer_glob_root)
624      !                 
625   END SUBROUTINE waver_info
626 
627 
628   SUBROUTINE wmpi_info
629      !!----------------------------------------------------------------------
630      !!               ***  ROUTINE wmpi_time  ***
631      !! ** Purpose :   compute and write a summary of MPI infos
632      !!----------------------------------------------------------------------   
633      !   
634      INTEGER                            :: idum, icode
635      INTEGER, ALLOCATABLE, DIMENSION(:) :: iall_rank
636      REAL(wp) :: ztot_ratio
637      REAL(wp) :: zmax_etime, zmax_ctime, zmax_ratio, zmin_etime, zmin_ctime, zmin_ratio
638      REAL(wp) :: zavg_etime, zavg_ctime, zavg_ratio
639      REAL(wp), ALLOCATABLE, DIMENSION(:) :: zall_ratio
640      CHARACTER(LEN=128), dimension(8) :: cllignes
641      CHARACTER(LEN=128)               :: clhline, clstart_date, clfinal_date
642      CHARACTER(LEN=2048)              :: clfmt   
643   
644      ! Gather all times
645      ALLOCATE( zall_ratio(jpnij), iall_rank(jpnij) )
646      IF( narea == 1 ) THEN
647         iall_rank(:) = (/ (idum,idum=0,jpnij-1) /)
648   
649         ! Compute elapse user time
650         zavg_etime = tot_etime/REAL(jpnij,wp)
651         zmax_etime = MAXVAL(all_etime(:))
652         zmin_etime = MINVAL(all_etime(:))
653
654         ! Compute CPU user time
655         zavg_ctime = tot_ctime/REAL(jpnij,wp)
656         zmax_ctime = MAXVAL(all_ctime(:))
657         zmin_ctime = MINVAL(all_ctime(:))
658   
659         ! Compute cpu/elapsed ratio
660         zall_ratio(:) = all_ctime(:) / all_etime(:)
661         ztot_ratio    = SUM(all_ctime(:))/SUM(all_etime(:))
662         zavg_ratio    = SUM(zall_ratio(:))/REAL(jpnij,wp)
663         zmax_ratio    = MAXVAL(zall_ratio(:))
664         zmin_ratio    = MINVAL(zall_ratio(:))   
665   
666         ! Output Format
667         clhline    ='1x,13("-"),"|",18("-"),"|",14("-"),"|",18("-"),/,'
668         cllignes(1)='(1x,"MPI summary report :",/,'
669         cllignes(2)='1x,"--------------------",//,'
670         cllignes(3)='1x,"Process Rank |"," Elapsed Time (s) |"," CPU Time (s) |"," Ratio CPU/Elapsed",/,'
671         cllignes(4)='      (4x,i6,4x,"|",f12.3,6x,"|",f12.3,2x,"|",4x,f7.3,/),'
672         WRITE(cllignes(4)(1:6),'(I6)') jpnij
673         cllignes(5)='1x,"Total        |",f12.3,6x,"|",F12.3,2x,"|",4x,f7.3,/,'
674         cllignes(6)='1x,"Minimum      |",f12.3,6x,"|",F12.3,2x,"|",4x,f7.3,/,'
675         cllignes(7)='1x,"Maximum      |",f12.3,6x,"|",F12.3,2x,"|",4x,f7.3,/,'
676         cllignes(8)='1x,"Average      |",f12.3,6x,"|",F12.3,2x,"|",4x,f7.3)'
677         clfmt=TRIM(cllignes(1))// TRIM(cllignes(2))//TRIM(cllignes(3))//          &
678           & TRIM(clhline)//TRIM(cllignes(4))//TRIM(clhline)//TRIM(cllignes(5))//  &
679           & TRIM(clhline)//TRIM(cllignes(6))//TRIM(clhline)//TRIM(cllignes(7))//  &
680           & TRIM(clhline)//TRIM(cllignes(8))
681         WRITE(numtime, TRIM(clfmt)) &
682             (iall_rank(idum),all_etime(idum),all_ctime(idum),zall_ratio(idum),idum=1, jpnij), &
683             tot_etime,     tot_ctime,     ztot_ratio,   &
684             zmin_etime,    zmin_ctime,    zmin_ratio,   &
685             zmax_etime,    zmax_ctime,    zmax_ratio,   &
686             zavg_etime,    zavg_ctime,    zavg_ratio
687         WRITE(numtime,*)   
688      END IF
689      !
690      DEALLOCATE(zall_ratio, iall_rank)
691      !
692   END SUBROUTINE wmpi_info
693#endif   
694
695
696   SUBROUTINE timing_ini_var(cdinfo)
697      !!----------------------------------------------------------------------
698      !!               ***  ROUTINE timing_ini_var  ***
699      !! ** Purpose :   create timing structure
700      !!----------------------------------------------------------------------
701      CHARACTER(len=*), INTENT(in) :: cdinfo
702      LOGICAL :: ll_section
703       
704      !
705      IF( .NOT. ASSOCIATED(s_timer_root) ) THEN
706         ALLOCATE(s_timer_root)
707         s_timer_root%cname       = cdinfo
708         s_timer_root%t_cpu      = 0._wp
709         s_timer_root%t_clock    = 0._wp
710         s_timer_root%tsum_cpu   = 0._wp
711         s_timer_root%tsum_clock = 0._wp
712         s_timer_root%tmax_cpu   = 0._wp
713         s_timer_root%tmax_clock = 0._wp
714         s_timer_root%tmin_cpu   = 0._wp
715         s_timer_root%tmin_clock = 0._wp
716         s_timer_root%tsub_cpu   = 0._wp
717         s_timer_root%tsub_clock = 0._wp
718         s_timer_root%ncount      = 0
719         s_timer_root%ncount_rate = 0
720         s_timer_root%ncount_max  = 0
721         s_timer_root%niter       = 0
722         s_timer_root%l_tdone  = .FALSE.
723         s_timer_root%next => NULL()
724         s_timer_root%prev => NULL()
725         s_timer => s_timer_root
726         !
727         ALLOCATE(s_wrk)
728         s_wrk => NULL()
729         !
730         ALLOCATE(s_timer_old)
731         s_timer_old%cname       = cdinfo
732         s_timer_old%t_cpu      = 0._wp
733         s_timer_old%t_clock    = 0._wp
734         s_timer_old%tsum_cpu   = 0._wp
735         s_timer_old%tsum_clock = 0._wp
736         s_timer_old%tmax_cpu   = 0._wp
737         s_timer_old%tmax_clock = 0._wp
738         s_timer_old%tmin_cpu   = 0._wp
739         s_timer_old%tmin_clock = 0._wp
740         s_timer_old%tsub_cpu   = 0._wp
741         s_timer_old%tsub_clock = 0._wp
742         s_timer_old%ncount      = 0
743         s_timer_old%ncount_rate = 0
744         s_timer_old%ncount_max  = 0
745         s_timer_old%niter       = 0
746         s_timer_old%l_tdone  = .TRUE.
747         s_timer_old%next => NULL()
748         s_timer_old%prev => NULL()
749
750      ELSE
751         s_timer => s_timer_root
752         ! case of already existing area (typically inside a loop)
753   !         write(*,*) 'in ini_var for routine : ', cdinfo
754         DO WHILE( ASSOCIATED(s_timer) ) 
755            IF( TRIM(s_timer%cname) .EQ. TRIM(cdinfo) ) THEN
756 !             write(*,*) 'in ini_var for routine : ', cdinfo,' we return'           
757               RETURN ! cdinfo is already in the chain
758            ENDIF
759            s_timer => s_timer%next
760         END DO
761
762         ! end of the chain
763         s_timer => s_timer_root
764         DO WHILE( ASSOCIATED(s_timer%next) )
765            s_timer => s_timer%next
766         END DO
767
768    !     write(*,*) 'after search', s_timer%cname
769         ! cdinfo is not part of the chain so we add it with initialisation         
770          ALLOCATE(s_timer%next)
771    !     write(*,*) 'after allocation of next'
772 
773         s_timer%next%cname       = cdinfo
774         s_timer%next%t_cpu      = 0._wp
775         s_timer%next%t_clock    = 0._wp
776         s_timer%next%tsum_cpu   = 0._wp
777         s_timer%next%tsum_clock = 0._wp 
778         s_timer%next%tmax_cpu   = 0._wp
779         s_timer%next%tmax_clock = 0._wp
780         s_timer%next%tmin_cpu   = 0._wp
781         s_timer%next%tmin_clock = 0._wp
782         s_timer%next%tsub_cpu   = 0._wp
783         s_timer%next%tsub_clock = 0._wp
784         s_timer%next%ncount      = 0
785         s_timer%next%ncount_rate = 0
786         s_timer%next%ncount_max  = 0
787         s_timer%next%niter       = 0
788         s_timer%next%l_tdone  = .FALSE.
789         s_timer%next%parent_section => NULL()
790         s_timer%next%prev => s_timer
791         s_timer%next%next => NULL()
792         s_timer => s_timer%next
793      ENDIF 
794      !    write(*,*) 'after allocation'
795     !
796   END SUBROUTINE timing_ini_var
797
798
799   SUBROUTINE timing_reset
800      !!----------------------------------------------------------------------
801      !!               ***  ROUTINE timing_reset  ***
802      !! ** Purpose :   go to root of timing tree
803      !!----------------------------------------------------------------------
804      l_initdone = .TRUE. 
805!      IF(lwp) WRITE(numout,*)
806!      IF(lwp) WRITE(numout,*) 'timing_reset : instrumented routines for timing'
807!      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~'
808      CALL timing_list(s_timer_root)
809!      WRITE(numout,*)
810      !
811   END SUBROUTINE timing_reset
812
813
814   RECURSIVE SUBROUTINE timing_list(ptr)
815   
816      TYPE(timer), POINTER, INTENT(inout) :: ptr
817      !
818      IF( ASSOCIATED(ptr%next) ) CALL timing_list(ptr%next)
819      IF(lwp) WRITE(numout,*)'   ', ptr%cname   
820      !
821   END SUBROUTINE timing_list
822
823
824   SUBROUTINE insert(sd_current, sd_root ,sd_ptr)
825      !!----------------------------------------------------------------------
826      !!               ***  ROUTINE insert  ***
827      !! ** Purpose :   insert an element in timer structure
828      !!----------------------------------------------------------------------
829      TYPE(timer), POINTER, INTENT(inout) :: sd_current, sd_root, sd_ptr
830      !
831     
832      IF( ASSOCIATED( sd_current, sd_root ) ) THEN
833         ! If our current element is the root element then
834         ! replace it with the one being inserted
835         sd_root => sd_ptr
836      ELSE
837         sd_current%prev%next => sd_ptr
838      END IF
839      sd_ptr%next     => sd_current
840      sd_ptr%prev     => sd_current%prev
841      sd_current%prev => sd_ptr
842      ! Nullify the pointer to the new element now that it is held
843      ! within the list. If we don't do this then a subsequent call
844      ! to ALLOCATE memory to this pointer will fail.
845      sd_ptr => NULL()
846      !   
847   END SUBROUTINE insert
848 
849 
850   SUBROUTINE suppress(sd_ptr)
851      !!----------------------------------------------------------------------
852      !!               ***  ROUTINE suppress  ***
853      !! ** Purpose :   supress an element in timer structure
854      !!----------------------------------------------------------------------
855      TYPE(timer), POINTER, INTENT(inout) :: sd_ptr
856      !
857      TYPE(timer), POINTER :: sl_temp
858   
859      sl_temp => sd_ptr
860      sd_ptr => sd_ptr%next   
861      IF ( ASSOCIATED(sl_temp%next) ) sl_temp%next%prev => sl_temp%prev
862      DEALLOCATE(sl_temp)
863      sl_temp => NULL()
864      !
865    END SUBROUTINE suppress
866
867   !!=====================================================================
868END MODULE timing
Note: See TracBrowser for help on using the repository browser.