New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zche.F90 in NEMO/trunk/src/TOP/PISCES/P4Z – NEMO

source: NEMO/trunk/src/TOP/PISCES/P4Z/p4zche.F90 @ 14086

Last change on this file since 14086 was 14086, checked in by cetlod, 19 months ago

Adding AGRIF branches into the trunk

  • Property svn:keywords set to Id
File size: 35.0 KB
Line 
1MODULE p4zche
2   !!======================================================================
3   !!                         ***  MODULE p4zche  ***
4   !! TOP :   PISCES Sea water chemistry computed following OCMIP protocol
5   !!======================================================================
6   !! History :   OPA  !  1988     (E. Maier-Reimer)  Original code
7   !!              -   !  1998     (O. Aumont)  addition
8   !!              -   !  1999     (C. Le Quere)  modification
9   !!   NEMO      1.0  !  2004     (O. Aumont)  modification
10   !!              -   !  2006     (R. Gangsto)  modification
11   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
12   !!                  !  2011-02  (J. Simeon, J.Orr ) update O2 solubility constants
13   !!             3.6  !  2016-03  (O. Aumont) Change chemistry to MOCSY standards
14   !!----------------------------------------------------------------------
15   !!   p4z_che      :  Sea water chemistry computed following OCMIP protocol
16   !!----------------------------------------------------------------------
17   USE oce_trc       !  shared variables between ocean and passive tracers
18   USE trc           !  passive tracers common variables
19   USE sms_pisces    !  PISCES Source Minus Sink variables
20   USE lib_mpp       !  MPP library
21   USE eosbn2, ONLY : neos
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC   p4z_che          !
27   PUBLIC   p4z_che_alloc    !
28   PUBLIC   ahini_for_at     !
29   PUBLIC   solve_at_general !
30
31   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)   :: sio3eq   ! chemistry of Si
32   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)   :: fekeq    ! chemistry of Fe
33   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)   :: chemc    ! Solubilities of O2 and CO2
34   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)   :: chemo2    ! Solubilities of O2 and CO2
35   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:,:) :: fesol    ! solubility of Fe
36   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   salinprac  ! Practical salinity
37   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   tempis   ! In situ temperature
38
39   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   akb3       !: ???
40   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   akw3       !: ???
41   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   akf3       !: ???
42   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   aks3       !: ???
43   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   ak1p3      !: ???
44   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   ak2p3      !: ???
45   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   ak3p3      !: ???
46   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   aksi3      !: ???
47   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   borat      !: ???
48   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   fluorid    !: ???
49   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sulfat     !: ???
50
51   !!* Variable for chemistry of the CO2 cycle
52
53   REAL(wp), PUBLIC ::   atcox  = 0.20946         ! units atm
54
55   REAL(wp) ::   o2atm  = 1. / ( 1000. * 0.20946 ) 
56
57   REAL(wp) ::   rgas   = 83.14472      ! universal gas constants
58   REAL(wp) ::   oxyco  = 1. / 22.4144  ! converts from liters of an ideal gas to moles
59   !                                    ! coeff. for seawater pressure correction : millero 95
60   !                                    ! AGRIF doesn't like the DATA instruction
61   REAL(wp) :: devk10  = -25.5
62   REAL(wp) :: devk11  = -15.82
63   REAL(wp) :: devk12  = -29.48
64   REAL(wp) :: devk13  = -20.02
65   REAL(wp) :: devk14  = -18.03
66   REAL(wp) :: devk15  = -9.78
67   REAL(wp) :: devk16  = -48.76
68   REAL(wp) :: devk17  = -14.51
69   REAL(wp) :: devk18  = -23.12
70   REAL(wp) :: devk19  = -26.57
71   REAL(wp) :: devk110  = -29.48
72   !
73   REAL(wp) :: devk20  = 0.1271
74   REAL(wp) :: devk21  = -0.0219
75   REAL(wp) :: devk22  = 0.1622
76   REAL(wp) :: devk23  = 0.1119
77   REAL(wp) :: devk24  = 0.0466
78   REAL(wp) :: devk25  = -0.0090
79   REAL(wp) :: devk26  = 0.5304
80   REAL(wp) :: devk27  = 0.1211
81   REAL(wp) :: devk28  = 0.1758
82   REAL(wp) :: devk29  = 0.2020
83   REAL(wp) :: devk210  = 0.1622
84   !
85   REAL(wp) :: devk30  = 0.
86   REAL(wp) :: devk31  = 0.
87   REAL(wp) :: devk32  = 2.608E-3
88   REAL(wp) :: devk33  = -1.409e-3
89   REAL(wp) :: devk34  = 0.316e-3
90   REAL(wp) :: devk35  = -0.942e-3
91   REAL(wp) :: devk36  = 0.
92   REAL(wp) :: devk37  = -0.321e-3
93   REAL(wp) :: devk38  = -2.647e-3
94   REAL(wp) :: devk39  = -3.042e-3
95   REAL(wp) :: devk310  = -2.6080e-3
96   !
97   REAL(wp) :: devk40  = -3.08E-3
98   REAL(wp) :: devk41  = 1.13E-3
99   REAL(wp) :: devk42  = -2.84E-3
100   REAL(wp) :: devk43  = -5.13E-3
101   REAL(wp) :: devk44  = -4.53e-3
102   REAL(wp) :: devk45  = -3.91e-3
103   REAL(wp) :: devk46  = -11.76e-3
104   REAL(wp) :: devk47  = -2.67e-3
105   REAL(wp) :: devk48  = -5.15e-3
106   REAL(wp) :: devk49  = -4.08e-3
107   REAL(wp) :: devk410  = -2.84e-3
108   !
109   REAL(wp) :: devk50  = 0.0877E-3
110   REAL(wp) :: devk51  = -0.1475E-3     
111   REAL(wp) :: devk52  = 0.
112   REAL(wp) :: devk53  = 0.0794E-3     
113   REAL(wp) :: devk54  = 0.09e-3
114   REAL(wp) :: devk55  = 0.054e-3
115   REAL(wp) :: devk56  = 0.3692E-3
116   REAL(wp) :: devk57  = 0.0427e-3
117   REAL(wp) :: devk58  = 0.09e-3
118   REAL(wp) :: devk59  = 0.0714e-3
119   REAL(wp) :: devk510  = 0.0
120   !
121   ! General parameters
122   REAL(wp), PARAMETER :: pp_rdel_ah_target = 1.E-4_wp
123   REAL(wp), PARAMETER :: pp_ln10 = 2.302585092994045684018_wp
124
125   ! Maximum number of iterations for each method
126   INTEGER, PARAMETER :: jp_maxniter_atgen    = 20
127
128   ! Bookkeeping variables for each method
129   ! - SOLVE_AT_GENERAL
130   INTEGER :: niter_atgen    = jp_maxniter_atgen
131
132   !! * Substitutions
133#  include "do_loop_substitute.h90"
134#  include "domzgr_substitute.h90"
135   !!----------------------------------------------------------------------
136   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
137   !! $Id$
138   !! Software governed by the CeCILL license (see ./LICENSE)
139   !!----------------------------------------------------------------------
140CONTAINS
141
142   SUBROUTINE p4z_che( Kbb, Kmm )
143      !!---------------------------------------------------------------------
144      !!                     ***  ROUTINE p4z_che  ***
145      !!
146      !! ** Purpose :   Sea water chemistry computed following OCMIP protocol
147      !!
148      !! ** Method  : - ...
149      !!---------------------------------------------------------------------
150      INTEGER, INTENT(in) ::   Kbb, Kmm  ! time level indices
151      INTEGER  ::   ji, jj, jk
152      REAL(wp) ::   ztkel, ztkel1, zt , zsal  , zsal2 , zbuf1 , zbuf2
153      REAL(wp) ::   ztgg , ztgg2, ztgg3 , ztgg4 , ztgg5
154      REAL(wp) ::   zpres, ztc  , zcl   , zcpexp, zoxy  , zcpexp2
155      REAL(wp) ::   zsqrt, ztr  , zlogt , zcek1, zc1, zplat
156      REAL(wp) ::   zis  , zis2 , zsal15, zisqrt, za1, za2
157      REAL(wp) ::   zckb , zck1 , zck2  , zckw  , zak1 , zak2  , zakb , zaksp0, zakw
158      REAL(wp) ::   zck1p, zck2p, zck3p, zcksi, zak1p, zak2p, zak3p, zaksi
159      REAL(wp) ::   zst  , zft  , zcks  , zckf  , zaksp1
160      REAL(wp) ::   total2free, free2SWS, total2SWS, SWS2total
161      !!---------------------------------------------------------------------
162      !
163      IF( ln_timing )   CALL timing_start('p4z_che')
164      !
165      ! Computation of chemical constants require practical salinity
166      ! Thus, when TEOS08 is used, absolute salinity is converted to
167      ! practical salinity
168      ! -------------------------------------------------------------
169      IF (neos == -1) THEN
170         salinprac(:,:,:) = ts(:,:,:,jp_sal,Kmm) * 35.0 / 35.16504
171      ELSE
172         salinprac(:,:,:) = ts(:,:,:,jp_sal,Kmm)
173      ENDIF
174
175      !
176      ! Computations of chemical constants require in situ temperature
177      ! Here a quite simple formulation is used to convert
178      ! potential temperature to in situ temperature. The errors is less than
179      ! 0.04°C relative to an exact computation
180      ! ---------------------------------------------------------------------
181      DO_3D( 1, 1, 1, 1, 1, jpk )
182         zpres = gdept(ji,jj,jk,Kmm) / 1000.
183         za1 = 0.04 * ( 1.0 + 0.185 * ts(ji,jj,jk,jp_tem,Kmm) + 0.035 * (salinprac(ji,jj,jk) - 35.0) )
184         za2 = 0.0075 * ( 1.0 - ts(ji,jj,jk,jp_tem,Kmm) / 30.0 )
185         tempis(ji,jj,jk) = ts(ji,jj,jk,jp_tem,Kmm) - za1 * zpres + za2 * zpres**2
186      END_3D
187      !
188      ! CHEMICAL CONSTANTS - SURFACE LAYER
189      ! ----------------------------------
190      DO_2D( 1, 1, 1, 1 )
191         !                             ! SET ABSOLUTE TEMPERATURE
192         ztkel = tempis(ji,jj,1) + 273.15
193         zt    = ztkel * 0.01
194         zsal  = salinprac(ji,jj,1) + ( 1.- tmask(ji,jj,1) ) * 35.
195         !                             ! LN(K0) OF SOLUBILITY OF CO2 (EQ. 12, WEISS, 1980)
196         !                             !     AND FOR THE ATMOSPHERE FOR NON IDEAL GAS
197         zcek1 = 9345.17/ztkel - 60.2409 + 23.3585 * LOG(zt) + zsal*(0.023517 - 0.00023656*ztkel    &
198         &       + 0.0047036e-4*ztkel**2)
199         chemc(ji,jj,1) = EXP( zcek1 ) * 1E-6 * rhop(ji,jj,1) / 1000. ! mol/(L atm)
200         chemc(ji,jj,2) = -1636.75 + 12.0408*ztkel - 0.0327957*ztkel**2 + 0.0000316528*ztkel**3
201         chemc(ji,jj,3) = 57.7 - 0.118*ztkel
202      END_2D
203
204      ! OXYGEN SOLUBILITY - DEEP OCEAN
205      ! -------------------------------
206      DO_3D( 1, 1, 1, 1, 1, jpk )
207         ztkel = tempis(ji,jj,jk) + 273.15
208         zsal  = salinprac(ji,jj,jk) + ( 1.- tmask(ji,jj,jk) ) * 35.
209         zsal2 = zsal * zsal
210         ztgg  = LOG( ( 298.15 - tempis(ji,jj,jk) ) / ztkel )  ! Set the GORDON & GARCIA scaled temperature
211         ztgg2 = ztgg  * ztgg
212         ztgg3 = ztgg2 * ztgg
213         ztgg4 = ztgg3 * ztgg
214         ztgg5 = ztgg4 * ztgg
215
216         zoxy  = 2.00856 + 3.22400 * ztgg + 3.99063 * ztgg2 + 4.80299 * ztgg3    &
217         &       + 9.78188e-1 * ztgg4 + 1.71069 * ztgg5 + zsal * ( -6.24097e-3   &
218         &       - 6.93498e-3 * ztgg - 6.90358e-3 * ztgg2 - 4.29155e-3 * ztgg3 )   &
219         &       - 3.11680e-7 * zsal2
220         chemo2(ji,jj,jk) = ( EXP( zoxy ) * o2atm ) * oxyco * atcox     ! mol/(L atm)
221      END_3D
222
223      ! CHEMICAL CONSTANTS - DEEP OCEAN
224      ! -------------------------------
225      DO_3D( 1, 1, 1, 1, 1, jpk )
226          ! SET PRESSION ACCORDING TO SAUNDER (1980)
227          zplat   = SIN ( ABS(gphit(ji,jj)*3.141592654/180.) )
228          zc1 = 5.92E-3 + zplat**2 * 5.25E-3
229          zpres = ((1-zc1)-SQRT(((1-zc1)**2)-(8.84E-6*gdept(ji,jj,jk,Kmm)))) / 4.42E-6
230          zpres = zpres / 10.0
231
232          ! SET ABSOLUTE TEMPERATURE
233          ztkel   = tempis(ji,jj,jk) + 273.15
234          zsal    = salinprac(ji,jj,jk) + ( 1.-tmask(ji,jj,jk) ) * 35.
235          zsqrt  = SQRT( zsal )
236          zsal15  = zsqrt * zsal
237          zlogt  = LOG( ztkel )
238          ztr    = 1. / ztkel
239          zis    = 19.924 * zsal / ( 1000.- 1.005 * zsal )
240          zis2   = zis * zis
241          zisqrt = SQRT( zis )
242          ztc     = tempis(ji,jj,jk) + ( 1.- tmask(ji,jj,jk) ) * 20.
243
244          ! CHLORINITY (WOOSTER ET AL., 1969)
245          zcl     = zsal / 1.80655
246
247          ! TOTAL SULFATE CONCENTR. [MOLES/kg soln]
248          zst     = 0.14 * zcl /96.062
249
250          ! TOTAL FLUORIDE CONCENTR. [MOLES/kg soln]
251          zft     = 0.000067 * zcl /18.9984
252
253          ! DISSOCIATION CONSTANT FOR SULFATES on free H scale (Dickson 1990)
254          zcks    = EXP(-4276.1 * ztr + 141.328 - 23.093 * zlogt         &
255          &         + (-13856. * ztr + 324.57 - 47.986 * zlogt) * zisqrt &
256          &         + (35474. * ztr - 771.54 + 114.723 * zlogt) * zis    &
257          &         - 2698. * ztr * zis**1.5 + 1776.* ztr * zis2         &
258          &         + LOG(1.0 - 0.001005 * zsal))
259
260          ! DISSOCIATION CONSTANT FOR FLUORIDES on free H scale (Dickson and Riley 79)
261          zckf    = EXP( 1590.2*ztr - 12.641 + 1.525*zisqrt   &
262          &         + LOG(1.0d0 - 0.001005d0*zsal)            &
263          &         + LOG(1.0d0 + zst/zcks))
264
265          ! DISSOCIATION CONSTANT FOR CARBONATE AND BORATE
266          zckb=  (-8966.90 - 2890.53*zsqrt - 77.942*zsal        &
267          &      + 1.728*zsal15 - 0.0996*zsal*zsal)*ztr         &
268          &      + (148.0248 + 137.1942*zsqrt + 1.62142*zsal)   &
269          &      + (-24.4344 - 25.085*zsqrt - 0.2474*zsal)      & 
270          &      * zlogt + 0.053105*zsqrt*ztkel
271
272          ! DISSOCIATION COEFFICIENT FOR CARBONATE ACCORDING TO
273          ! MEHRBACH (1973) REFIT BY MILLERO (1995), seawater scale
274          zck1    = -1.0*(3633.86*ztr - 61.2172 + 9.6777*zlogt  &
275             - 0.011555*zsal + 0.0001152*zsal*zsal)
276          zck2    = -1.0*(471.78*ztr + 25.9290 - 3.16967*zlogt      &
277             - 0.01781*zsal + 0.0001122*zsal*zsal)
278
279          ! PKW (H2O) (MILLERO, 1995) from composite data
280          zckw    = -13847.26 * ztr + 148.9652 - 23.6521 * zlogt + ( 118.67 * ztr    &
281                    - 5.977 + 1.0495 * zlogt ) * zsqrt - 0.01615 * zsal
282
283          ! CONSTANTS FOR PHOSPHATE (MILLERO, 1995)
284         zck1p    = -4576.752*ztr + 115.540 - 18.453*zlogt   &
285         &          + (-106.736*ztr + 0.69171) * zsqrt       &
286         &          + (-0.65643*ztr - 0.01844) * zsal
287
288         zck2p    = -8814.715*ztr + 172.1033 - 27.927*zlogt  &
289         &          + (-160.340*ztr + 1.3566)*zsqrt          &
290         &          + (0.37335*ztr - 0.05778)*zsal
291
292         zck3p    = -3070.75*ztr - 18.126                    &
293         &          + (17.27039*ztr + 2.81197) * zsqrt       &
294         &          + (-44.99486*ztr - 0.09984) * zsal 
295
296         ! CONSTANT FOR SILICATE, MILLERO (1995)
297         zcksi    = -8904.2*ztr  + 117.400 - 19.334*zlogt   &
298         &          + (-458.79*ztr + 3.5913) * zisqrt       &
299         &          + (188.74*ztr - 1.5998) * zis           &
300         &          + (-12.1652*ztr + 0.07871) * zis2       &
301         &          + LOG(1.0 - 0.001005*zsal)
302
303          ! APPARENT SOLUBILITY PRODUCT K'SP OF CALCITE IN SEAWATER
304          !       (S=27-43, T=2-25 DEG C) at pres =0 (atmos. pressure) (MUCCI 1983)
305          zaksp0  = -171.9065 -0.077993*ztkel + 2839.319*ztr + 71.595*LOG10( ztkel )   &
306             &      + (-0.77712 + 0.00284263*ztkel + 178.34*ztr) * zsqrt  &
307             &      - 0.07711*zsal + 0.0041249*zsal15
308
309          ! CONVERT FROM DIFFERENT PH SCALES
310          total2free  = 1.0/(1.0 + zst/zcks)
311          free2SWS    = 1. + zst/zcks + zft/(zckf*total2free)
312          total2SWS   = total2free * free2SWS
313          SWS2total   = 1.0 / total2SWS
314
315          ! K1, K2 OF CARBONIC ACID, KB OF BORIC ACID, KW (H2O) (LIT.?)
316          zak1    = 10**(zck1) * total2SWS
317          zak2    = 10**(zck2) * total2SWS
318          zakb    = EXP( zckb ) * total2SWS
319          zakw    = EXP( zckw )
320          zaksp1  = 10**(zaksp0)
321          zak1p   = exp( zck1p )
322          zak2p   = exp( zck2p )
323          zak3p   = exp( zck3p )
324          zaksi   = exp( zcksi )
325          zckf    = zckf * total2SWS
326
327          ! FORMULA FOR CPEXP AFTER EDMOND & GIESKES (1970)
328          !        (REFERENCE TO CULBERSON & PYTKOQICZ (1968) AS MADE
329          !        IN BROECKER ET AL. (1982) IS INCORRECT; HERE RGAS IS
330          !        TAKEN TENFOLD TO CORRECT FOR THE NOTATION OF pres  IN
331          !        DBAR INSTEAD OF BAR AND THE EXPRESSION FOR CPEXP IS
332          !        MULTIPLIED BY LN(10.) TO ALLOW USE OF EXP-FUNCTION
333          !        WITH BASIS E IN THE FORMULA FOR AKSPP (CF. EDMOND
334          !        & GIESKES (1970), P. 1285-1286 (THE SMALL
335          !        FORMULA ON P. 1286 IS RIGHT AND CONSISTENT WITH THE
336          !        SIGN IN PARTIAL MOLAR VOLUME CHANGE AS SHOWN ON P. 1285))
337          zcpexp  = zpres / (rgas*ztkel)
338          zcpexp2 = zpres * zcpexp
339
340          ! KB OF BORIC ACID, K1,K2 OF CARBONIC ACID PRESSURE
341          !        CORRECTION AFTER CULBERSON AND PYTKOWICZ (1968)
342          !        (CF. BROECKER ET AL., 1982)
343
344          zbuf1  = -     ( devk10 + devk20 * ztc + devk30 * ztc * ztc )
345          zbuf2  = 0.5 * ( devk40 + devk50 * ztc )
346          ak13(ji,jj,jk) = zak1 * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
347
348          zbuf1  =     - ( devk11 + devk21 * ztc + devk31 * ztc * ztc )
349          zbuf2  = 0.5 * ( devk41 + devk51 * ztc )
350          ak23(ji,jj,jk) = zak2 * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
351
352          zbuf1  =     - ( devk12 + devk22 * ztc + devk32 * ztc * ztc )
353          zbuf2  = 0.5 * ( devk42 + devk52 * ztc )
354          akb3(ji,jj,jk) = zakb * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
355
356          zbuf1  =     - ( devk13 + devk23 * ztc + devk33 * ztc * ztc )
357          zbuf2  = 0.5 * ( devk43 + devk53 * ztc )
358          akw3(ji,jj,jk) = zakw * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
359
360          zbuf1  =     - ( devk14 + devk24 * ztc + devk34 * ztc * ztc )
361          zbuf2  = 0.5 * ( devk44 + devk54 * ztc )
362          aks3(ji,jj,jk) = zcks * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
363
364          zbuf1  =     - ( devk15 + devk25 * ztc + devk35 * ztc * ztc )
365          zbuf2  = 0.5 * ( devk45 + devk55 * ztc )
366          akf3(ji,jj,jk) = zckf * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
367
368          zbuf1  =     - ( devk17 + devk27 * ztc + devk37 * ztc * ztc )
369          zbuf2  = 0.5 * ( devk47 + devk57 * ztc )
370          ak1p3(ji,jj,jk) = zak1p * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
371
372          zbuf1  =     - ( devk18 + devk28 * ztc + devk38 * ztc * ztc )
373          zbuf2  = 0.5 * ( devk48 + devk58 * ztc )
374          ak2p3(ji,jj,jk) = zak2p * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
375
376          zbuf1  =     - ( devk19 + devk29 * ztc + devk39 * ztc * ztc )
377          zbuf2  = 0.5 * ( devk49 + devk59 * ztc )
378          ak3p3(ji,jj,jk) = zak3p * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
379
380          zbuf1  =     - ( devk110 + devk210 * ztc + devk310 * ztc * ztc )
381          zbuf2  = 0.5 * ( devk410 + devk510 * ztc )
382          aksi3(ji,jj,jk) = zaksi * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
383
384          ! CONVERT FROM DIFFERENT PH SCALES
385          total2free  = 1.0/(1.0 + zst/aks3(ji,jj,jk))
386          free2SWS    = 1. + zst/aks3(ji,jj,jk) + zft/akf3(ji,jj,jk)
387          total2SWS   = total2free * free2SWS
388          SWS2total   = 1.0 / total2SWS
389
390          ! Convert to total scale
391          ak13(ji,jj,jk)  = ak13(ji,jj,jk)  * SWS2total
392          ak23(ji,jj,jk)  = ak23(ji,jj,jk)  * SWS2total
393          akb3(ji,jj,jk)  = akb3(ji,jj,jk)  * SWS2total
394          akw3(ji,jj,jk)  = akw3(ji,jj,jk)  * SWS2total
395          ak1p3(ji,jj,jk) = ak1p3(ji,jj,jk) * SWS2total
396          ak2p3(ji,jj,jk) = ak2p3(ji,jj,jk) * SWS2total
397          ak3p3(ji,jj,jk) = ak3p3(ji,jj,jk) * SWS2total
398          aksi3(ji,jj,jk) = aksi3(ji,jj,jk) * SWS2total
399          akf3(ji,jj,jk)  = akf3(ji,jj,jk)  / total2free
400
401          ! APPARENT SOLUBILITY PRODUCT K'SP OF CALCITE
402          !        AS FUNCTION OF PRESSURE FOLLOWING MILLERO
403          !        (P. 1285) AND BERNER (1976)
404          zbuf1  =     - ( devk16 + devk26 * ztc + devk36 * ztc * ztc )
405          zbuf2  = 0.5 * ( devk46 + devk56 * ztc )
406          aksp(ji,jj,jk) = zaksp1 * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
407
408          ! TOTAL F, S, and BORATE CONCENTR. [MOLES/L]
409          borat(ji,jj,jk) = 0.0002414 * zcl / 10.811
410          sulfat(ji,jj,jk) = zst
411          fluorid(ji,jj,jk) = zft 
412
413          ! Iron and SIO3 saturation concentration from ...
414          sio3eq(ji,jj,jk) = EXP(  LOG( 10.) * ( 6.44 - 968. / ztkel )  ) * 1.e-6
415          fekeq (ji,jj,jk) = 10**( 17.27 - 1565.7 / ztkel ) 
416          ! Liu and Millero (1999) only valid 5 - 50 degC
417          ztkel1 = MAX( 5. , tempis(ji,jj,jk) ) + 273.16
418          fesol(ji,jj,jk,1) = 10**(-13.486 - 0.1856* zis**0.5 + 0.3073*zis + 5254.0/ztkel1)
419          fesol(ji,jj,jk,2) = 10**(2.517 - 0.8885*zis**0.5 + 0.2139 * zis - 1320.0/ztkel1 )
420          fesol(ji,jj,jk,3) = 10**(0.4511 - 0.3305*zis**0.5 - 1996.0/ztkel1 )
421          fesol(ji,jj,jk,4) = 10**(-0.2965 - 0.7881*zis**0.5 - 4086.0/ztkel1 )
422          fesol(ji,jj,jk,5) = 10**(4.4466 - 0.8505*zis**0.5 - 7980.0/ztkel1 )
423      END_3D
424      !
425      IF( ln_timing )  CALL timing_stop('p4z_che')
426      !
427   END SUBROUTINE p4z_che
428
429   SUBROUTINE ahini_for_at(p_hini, Kbb )
430      !!---------------------------------------------------------------------
431      !!                     ***  ROUTINE ahini_for_at  ***
432      !!
433      !! Subroutine returns the root for the 2nd order approximation of the
434      !! DIC -- B_T -- A_CB equation for [H+] (reformulated as a cubic
435      !! polynomial) around the local minimum, if it exists.
436      !! Returns * 1E-03_wp if p_alkcb <= 0
437      !!         * 1E-10_wp if p_alkcb >= 2*p_dictot + p_bortot
438      !!         * 1E-07_wp if 0 < p_alkcb < 2*p_dictot + p_bortot
439      !!                    and the 2nd order approximation does not have
440      !!                    a solution
441      !!---------------------------------------------------------------------
442      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(OUT)  ::  p_hini
443      INTEGER,                          INTENT(in)   ::  Kbb      ! time level indices
444      INTEGER  ::   ji, jj, jk
445      REAL(wp)  ::  zca1, zba1
446      REAL(wp)  ::  zd, zsqrtd, zhmin
447      REAL(wp)  ::  za2, za1, za0
448      REAL(wp)  ::  p_dictot, p_bortot, p_alkcb 
449      !!---------------------------------------------------------------------
450
451      IF( ln_timing )  CALL timing_start('ahini_for_at')
452      !
453      DO_3D( 1, 1, 1, 1, 1, jpk )
454      p_alkcb  = tr(ji,jj,jk,jptal,Kbb) * 1000. / (rhop(ji,jj,jk) + rtrn)
455      p_dictot = tr(ji,jj,jk,jpdic,Kbb) * 1000. / (rhop(ji,jj,jk) + rtrn)
456      p_bortot = borat(ji,jj,jk)
457      IF (p_alkcb <= 0.) THEN
458          p_hini(ji,jj,jk) = 1.e-3
459      ELSEIF (p_alkcb >= (2.*p_dictot + p_bortot)) THEN
460          p_hini(ji,jj,jk) = 1.e-10_wp
461      ELSE
462          zca1 = p_dictot/( p_alkcb + rtrn )
463          zba1 = p_bortot/ (p_alkcb + rtrn )
464     ! Coefficients of the cubic polynomial
465          za2 = aKb3(ji,jj,jk)*(1. - zba1) + ak13(ji,jj,jk)*(1.-zca1)
466          za1 = ak13(ji,jj,jk)*akb3(ji,jj,jk)*(1. - zba1 - zca1)    &
467          &     + ak13(ji,jj,jk)*ak23(ji,jj,jk)*(1. - (zca1+zca1))
468          za0 = ak13(ji,jj,jk)*ak23(ji,jj,jk)*akb3(ji,jj,jk)*(1. - zba1 - (zca1+zca1))
469                                  ! Taylor expansion around the minimum
470          zd = za2*za2 - 3.*za1   ! Discriminant of the quadratic equation
471                                  ! for the minimum close to the root
472
473          IF(zd > 0.) THEN        ! If the discriminant is positive
474            zsqrtd = SQRT(zd)
475            IF(za2 < 0) THEN
476              zhmin = (-za2 + zsqrtd)/3.
477            ELSE
478              zhmin = -za1/(za2 + zsqrtd)
479            ENDIF
480            p_hini(ji,jj,jk) = zhmin + SQRT(-(za0 + zhmin*(za1 + zhmin*(za2 + zhmin)))/zsqrtd)
481          ELSE
482            p_hini(ji,jj,jk) = 1.e-7
483          ENDIF
484       !
485       ENDIF
486      END_3D
487      !
488      IF( ln_timing )  CALL timing_stop('ahini_for_at')
489      !
490   END SUBROUTINE ahini_for_at
491
492   !===============================================================================
493
494   SUBROUTINE anw_infsup( p_alknw_inf, p_alknw_sup, Kbb )
495
496   ! Subroutine returns the lower and upper bounds of "non-water-selfionization"
497   ! contributions to total alkalinity (the infimum and the supremum), i.e
498   ! inf(TA - [OH-] + [H+]) and sup(TA - [OH-] + [H+])
499
500   ! Argument variables
501   REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(OUT) :: p_alknw_inf
502   REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(OUT) :: p_alknw_sup
503   INTEGER,                          INTENT(in)  ::  Kbb      ! time level indices
504
505   p_alknw_inf(:,:,:) =  -tr(:,:,:,jppo4,Kbb) * 1000. / (rhop(:,:,:) + rtrn) - sulfat(:,:,:)  &
506   &              - fluorid(:,:,:)
507   p_alknw_sup(:,:,:) =   (2. * tr(:,:,:,jpdic,Kbb) + 2. * tr(:,:,:,jppo4,Kbb) + tr(:,:,:,jpsil,Kbb) )    &
508   &               * 1000. / (rhop(:,:,:) + rtrn) + borat(:,:,:) 
509
510   END SUBROUTINE anw_infsup
511
512
513   SUBROUTINE solve_at_general( p_hini, zhi, Kbb )
514
515   ! Universal pH solver that converges from any given initial value,
516   ! determines upper an lower bounds for the solution if required
517
518   ! Argument variables
519   !--------------------
520   REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(IN)   :: p_hini
521   REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(OUT)  :: zhi
522   INTEGER,                          INTENT(in)   :: Kbb  ! time level indices
523
524   ! Local variables
525   !-----------------
526   INTEGER   ::  ji, jj, jk, jn
527   REAL(wp)  ::  zh_ini, zh, zh_prev, zh_lnfactor
528   REAL(wp)  ::  zdelta, zh_delta
529   REAL(wp)  ::  zeqn, zdeqndh, zalka
530   REAL(wp)  ::  aphscale
531   REAL(wp)  ::  znumer_dic, zdnumer_dic, zdenom_dic, zalk_dic, zdalk_dic
532   REAL(wp)  ::  znumer_bor, zdnumer_bor, zdenom_bor, zalk_bor, zdalk_bor
533   REAL(wp)  ::  znumer_po4, zdnumer_po4, zdenom_po4, zalk_po4, zdalk_po4
534   REAL(wp)  ::  znumer_sil, zdnumer_sil, zdenom_sil, zalk_sil, zdalk_sil
535   REAL(wp)  ::  znumer_so4, zdnumer_so4, zdenom_so4, zalk_so4, zdalk_so4
536   REAL(wp)  ::  znumer_flu, zdnumer_flu, zdenom_flu, zalk_flu, zdalk_flu
537   REAL(wp)  ::  zalk_wat, zdalk_wat
538   REAL(wp)  ::  zfact, p_alktot, zdic, zbot, zpt, zst, zft, zsit
539   LOGICAL   ::  l_exitnow
540   REAL(wp), PARAMETER :: pz_exp_threshold = 1.0
541   REAL(wp), DIMENSION(jpi,jpj,jpk) :: zalknw_inf, zalknw_sup, rmask, zh_min, zh_max, zeqn_absmin
542
543   IF( ln_timing )  CALL timing_start('solve_at_general')
544
545   CALL anw_infsup( zalknw_inf, zalknw_sup, Kbb )
546
547   rmask(:,:,:) = tmask(:,:,:)
548   zhi(:,:,:)   = 0.
549
550   ! TOTAL H+ scale: conversion factor for Htot = aphscale * Hfree
551   DO_3D( 1, 1, 1, 1, 1, jpk )
552      IF (rmask(ji,jj,jk) == 1.) THEN
553         p_alktot = tr(ji,jj,jk,jptal,Kbb) * 1000. / (rhop(ji,jj,jk) + rtrn)
554         aphscale = 1. + sulfat(ji,jj,jk)/aks3(ji,jj,jk)
555         zh_ini = p_hini(ji,jj,jk)
556
557         zdelta = (p_alktot-zalknw_inf(ji,jj,jk))**2 + 4.*akw3(ji,jj,jk)/aphscale
558
559         IF(p_alktot >= zalknw_inf(ji,jj,jk)) THEN
560           zh_min(ji,jj,jk) = 2.*akw3(ji,jj,jk) /( p_alktot-zalknw_inf(ji,jj,jk) + SQRT(zdelta) )
561         ELSE
562           zh_min(ji,jj,jk) = aphscale*(-(p_alktot-zalknw_inf(ji,jj,jk)) + SQRT(zdelta) ) / 2.
563         ENDIF
564
565         zdelta = (p_alktot-zalknw_sup(ji,jj,jk))**2 + 4.*akw3(ji,jj,jk)/aphscale
566
567         IF(p_alktot <= zalknw_sup(ji,jj,jk)) THEN
568           zh_max(ji,jj,jk) = aphscale*(-(p_alktot-zalknw_sup(ji,jj,jk)) + SQRT(zdelta) ) / 2.
569         ELSE
570           zh_max(ji,jj,jk) = 2.*akw3(ji,jj,jk) /( p_alktot-zalknw_sup(ji,jj,jk) + SQRT(zdelta) )
571         ENDIF
572
573         zhi(ji,jj,jk) = MAX(MIN(zh_max(ji,jj,jk), zh_ini), zh_min(ji,jj,jk))
574      ENDIF
575   END_3D
576
577   zeqn_absmin(:,:,:) = HUGE(1._wp)
578
579   DO jn = 1, jp_maxniter_atgen 
580   DO_3D( 1, 1, 1, 1, 1, jpk )
581      IF (rmask(ji,jj,jk) == 1.) THEN
582         zfact = rhop(ji,jj,jk) / 1000. + rtrn
583         p_alktot = tr(ji,jj,jk,jptal,Kbb) / zfact
584         zdic  = tr(ji,jj,jk,jpdic,Kbb) / zfact
585         zbot  = borat(ji,jj,jk)
586         zpt = tr(ji,jj,jk,jppo4,Kbb) / zfact * po4r
587         zsit = tr(ji,jj,jk,jpsil,Kbb) / zfact
588         zst = sulfat (ji,jj,jk)
589         zft = fluorid(ji,jj,jk)
590         aphscale = 1. + sulfat(ji,jj,jk)/aks3(ji,jj,jk)
591         zh = zhi(ji,jj,jk)
592         zh_prev = zh
593
594         ! H2CO3 - HCO3 - CO3 : n=2, m=0
595         znumer_dic = 2.*ak13(ji,jj,jk)*ak23(ji,jj,jk) + zh*ak13(ji,jj,jk)
596         zdenom_dic = ak13(ji,jj,jk)*ak23(ji,jj,jk) + zh*(ak13(ji,jj,jk) + zh)
597         zalk_dic   = zdic * (znumer_dic/zdenom_dic)
598         zdnumer_dic = ak13(ji,jj,jk)*ak13(ji,jj,jk)*ak23(ji,jj,jk) + zh     &
599                       *(4.*ak13(ji,jj,jk)*ak23(ji,jj,jk) + zh*ak13(ji,jj,jk))
600         zdalk_dic   = -zdic*(zdnumer_dic/zdenom_dic**2)
601
602
603         ! B(OH)3 - B(OH)4 : n=1, m=0
604         znumer_bor = akb3(ji,jj,jk)
605         zdenom_bor = akb3(ji,jj,jk) + zh
606         zalk_bor   = zbot * (znumer_bor/zdenom_bor)
607         zdnumer_bor = akb3(ji,jj,jk)
608         zdalk_bor   = -zbot*(zdnumer_bor/zdenom_bor**2)
609
610
611         ! H3PO4 - H2PO4 - HPO4 - PO4 : n=3, m=1
612         znumer_po4 = 3.*ak1p3(ji,jj,jk)*ak2p3(ji,jj,jk)*ak3p3(ji,jj,jk)  &
613         &            + zh*(2.*ak1p3(ji,jj,jk)*ak2p3(ji,jj,jk) + zh* ak1p3(ji,jj,jk))
614         zdenom_po4 = ak1p3(ji,jj,jk)*ak2p3(ji,jj,jk)*ak3p3(ji,jj,jk)     &
615         &            + zh*( ak1p3(ji,jj,jk)*ak2p3(ji,jj,jk) + zh*(ak1p3(ji,jj,jk) + zh))
616         zalk_po4   = zpt * (znumer_po4/zdenom_po4 - 1.) ! Zero level of H3PO4 = 1
617         zdnumer_po4 = ak1p3(ji,jj,jk)*ak2p3(ji,jj,jk)*ak1p3(ji,jj,jk)*ak2p3(ji,jj,jk)*ak3p3(ji,jj,jk)  &
618         &             + zh*(4.*ak1p3(ji,jj,jk)*ak1p3(ji,jj,jk)*ak2p3(ji,jj,jk)*ak3p3(ji,jj,jk)         &
619         &             + zh*(9.*ak1p3(ji,jj,jk)*ak2p3(ji,jj,jk)*ak3p3(ji,jj,jk)                         &
620         &             + ak1p3(ji,jj,jk)*ak1p3(ji,jj,jk)*ak2p3(ji,jj,jk)                                &
621         &             + zh*(4.*ak1p3(ji,jj,jk)*ak2p3(ji,jj,jk) + zh * ak1p3(ji,jj,jk) ) ) )
622         zdalk_po4   = -zpt * (zdnumer_po4/zdenom_po4**2)
623
624         ! H4SiO4 - H3SiO4 : n=1, m=0
625         znumer_sil = aksi3(ji,jj,jk)
626         zdenom_sil = aksi3(ji,jj,jk) + zh
627         zalk_sil   = zsit * (znumer_sil/zdenom_sil)
628         zdnumer_sil = aksi3(ji,jj,jk)
629         zdalk_sil   = -zsit * (zdnumer_sil/zdenom_sil**2)
630
631         ! HSO4 - SO4 : n=1, m=1
632         aphscale = 1.0 + zst/aks3(ji,jj,jk)
633         znumer_so4 = aks3(ji,jj,jk) * aphscale
634         zdenom_so4 = aks3(ji,jj,jk) * aphscale + zh
635         zalk_so4   = zst * (znumer_so4/zdenom_so4 - 1.)
636         zdnumer_so4 = aks3(ji,jj,jk)
637         zdalk_so4   = -zst * (zdnumer_so4/zdenom_so4**2)
638
639         ! HF - F : n=1, m=1
640         znumer_flu =  akf3(ji,jj,jk)
641         zdenom_flu =  akf3(ji,jj,jk) + zh
642         zalk_flu   =  zft * (znumer_flu/zdenom_flu - 1.)
643         zdnumer_flu = akf3(ji,jj,jk)
644         zdalk_flu   = -zft * (zdnumer_flu/zdenom_flu**2)
645
646         ! H2O - OH
647         aphscale = 1.0 + zst/aks3(ji,jj,jk)
648         zalk_wat   = akw3(ji,jj,jk)/zh - zh/aphscale
649         zdalk_wat  = -akw3(ji,jj,jk)/zh**2 - 1./aphscale
650
651         ! CALCULATE [ALK]([CO3--], [HCO3-])
652         zeqn = zalk_dic + zalk_bor + zalk_po4 + zalk_sil   &
653         &      + zalk_so4 + zalk_flu                       &
654         &      + zalk_wat - p_alktot
655
656         zalka = p_alktot - (zalk_bor + zalk_po4 + zalk_sil   &
657         &       + zalk_so4 + zalk_flu + zalk_wat)
658
659         zdeqndh = zdalk_dic + zdalk_bor + zdalk_po4 + zdalk_sil &
660         &         + zdalk_so4 + zdalk_flu + zdalk_wat
661
662         ! Adapt bracketing interval
663         IF(zeqn > 0._wp) THEN
664           zh_min(ji,jj,jk) = zh_prev
665         ELSEIF(zeqn < 0._wp) THEN
666           zh_max(ji,jj,jk) = zh_prev
667         ENDIF
668
669         IF(ABS(zeqn) >= 0.5_wp*zeqn_absmin(ji,jj,jk)) THEN
670         ! if the function evaluation at the current point is
671         ! not decreasing faster than with a bisection step (at least linearly)
672         ! in absolute value take one bisection step on [ph_min, ph_max]
673         ! ph_new = (ph_min + ph_max)/2d0
674         !
675         ! In terms of [H]_new:
676         ! [H]_new = 10**(-ph_new)
677         !         = 10**(-(ph_min + ph_max)/2d0)
678         !         = SQRT(10**(-(ph_min + phmax)))
679         !         = SQRT(zh_max * zh_min)
680            zh = SQRT(zh_max(ji,jj,jk) * zh_min(ji,jj,jk))
681            zh_lnfactor = (zh - zh_prev)/zh_prev ! Required to test convergence below
682         ELSE
683         ! dzeqn/dpH = dzeqn/d[H] * d[H]/dpH
684         !           = -zdeqndh * LOG(10) * [H]
685         ! \Delta pH = -zeqn/(zdeqndh*d[H]/dpH) = zeqn/(zdeqndh*[H]*LOG(10))
686         !
687         ! pH_new = pH_old + \deltapH
688         !
689         ! [H]_new = 10**(-pH_new)
690         !         = 10**(-pH_old - \Delta pH)
691         !         = [H]_old * 10**(-zeqn/(zdeqndh*[H]_old*LOG(10)))
692         !         = [H]_old * EXP(-LOG(10)*zeqn/(zdeqndh*[H]_old*LOG(10)))
693         !         = [H]_old * EXP(-zeqn/(zdeqndh*[H]_old))
694
695            zh_lnfactor = -zeqn/(zdeqndh*zh_prev)
696
697            IF(ABS(zh_lnfactor) > pz_exp_threshold) THEN
698               zh          = zh_prev*EXP(zh_lnfactor)
699            ELSE
700               zh_delta    = zh_lnfactor*zh_prev
701               zh          = zh_prev + zh_delta
702            ENDIF
703
704            IF( zh < zh_min(ji,jj,jk) ) THEN
705               ! if [H]_new < [H]_min
706               ! i.e., if ph_new > ph_max then
707               ! take one bisection step on [ph_prev, ph_max]
708               ! ph_new = (ph_prev + ph_max)/2d0
709               ! In terms of [H]_new:
710               ! [H]_new = 10**(-ph_new)
711               !         = 10**(-(ph_prev + ph_max)/2d0)
712               !         = SQRT(10**(-(ph_prev + phmax)))
713               !         = SQRT([H]_old*10**(-ph_max))
714               !         = SQRT([H]_old * zh_min)
715               zh                = SQRT(zh_prev * zh_min(ji,jj,jk))
716               zh_lnfactor       = (zh - zh_prev)/zh_prev ! Required to test convergence below
717            ENDIF
718
719            IF( zh > zh_max(ji,jj,jk) ) THEN
720               ! if [H]_new > [H]_max
721               ! i.e., if ph_new < ph_min, then
722               ! take one bisection step on [ph_min, ph_prev]
723               ! ph_new = (ph_prev + ph_min)/2d0
724               ! In terms of [H]_new:
725               ! [H]_new = 10**(-ph_new)
726               !         = 10**(-(ph_prev + ph_min)/2d0)
727               !         = SQRT(10**(-(ph_prev + ph_min)))
728               !         = SQRT([H]_old*10**(-ph_min))
729               !         = SQRT([H]_old * zhmax)
730               zh                = SQRT(zh_prev * zh_max(ji,jj,jk))
731               zh_lnfactor       = (zh - zh_prev)/zh_prev ! Required to test convergence below
732            ENDIF
733         ENDIF
734
735         zeqn_absmin(ji,jj,jk) = MIN( ABS(zeqn), zeqn_absmin(ji,jj,jk))
736
737         ! Stop iterations once |\delta{[H]}/[H]| < rdel
738         ! <=> |(zh - zh_prev)/zh_prev| = |EXP(-zeqn/(zdeqndh*zh_prev)) -1| < rdel
739         ! |EXP(-zeqn/(zdeqndh*zh_prev)) -1| ~ |zeqn/(zdeqndh*zh_prev)|
740
741         ! Alternatively:
742         ! |\Delta pH| = |zeqn/(zdeqndh*zh_prev*LOG(10))|
743         !             ~ 1/LOG(10) * |\Delta [H]|/[H]
744         !             < 1/LOG(10) * rdel
745
746         ! Hence |zeqn/(zdeqndh*zh)| < rdel
747
748         ! rdel <-- pp_rdel_ah_target
749         l_exitnow = (ABS(zh_lnfactor) < pp_rdel_ah_target)
750
751         IF(l_exitnow) THEN
752            rmask(ji,jj,jk) = 0.
753         ENDIF
754
755         zhi(ji,jj,jk) =  zh
756
757         IF(jn >= jp_maxniter_atgen) THEN
758            zhi(ji,jj,jk) = -1._wp
759         ENDIF
760
761      ENDIF
762   END_3D
763   END DO
764   !
765
766      IF( ln_timing )   CALL timing_stop('solve_at_general')
767      !
768   END SUBROUTINE solve_at_general
769
770
771   INTEGER FUNCTION p4z_che_alloc()
772      !!----------------------------------------------------------------------
773      !!                     ***  ROUTINE p4z_che_alloc  ***
774      !!----------------------------------------------------------------------
775      INTEGER ::   ierr(3)        ! Local variables
776      !!----------------------------------------------------------------------
777
778      ierr(:) = 0
779
780      ALLOCATE( sio3eq(jpi,jpj,jpk), fekeq(jpi,jpj,jpk), chemc(jpi,jpj,3), chemo2(jpi,jpj,jpk), STAT=ierr(1) )
781
782      ALLOCATE( akb3(jpi,jpj,jpk)     , tempis(jpi, jpj, jpk),       &
783         &      akw3(jpi,jpj,jpk)     , borat (jpi,jpj,jpk)  ,       &
784         &      aks3(jpi,jpj,jpk)     , akf3(jpi,jpj,jpk)    ,       &
785         &      ak1p3(jpi,jpj,jpk)    , ak2p3(jpi,jpj,jpk)   ,       &
786         &      ak3p3(jpi,jpj,jpk)    , aksi3(jpi,jpj,jpk)   ,       &
787         &      fluorid(jpi,jpj,jpk)  , sulfat(jpi,jpj,jpk)  ,       &
788         &      salinprac(jpi,jpj,jpk),                 STAT=ierr(2) )
789
790      ALLOCATE( fesol(jpi,jpj,jpk,5), STAT=ierr(3) )
791
792      !* Variable for chemistry of the CO2 cycle
793      p4z_che_alloc = MAXVAL( ierr )
794      !
795      IF( p4z_che_alloc /= 0 )   CALL ctl_stop( 'STOP', 'p4z_che_alloc : failed to allocate arrays.' )
796      !
797   END FUNCTION p4z_che_alloc
798
799   !!======================================================================
800END MODULE p4zche
Note: See TracBrowser for help on using the repository browser.