source: branches/2011/dev_LOCEAN_CMCC_INGV_MERCATOR_2011/NEMOGCM/NEMO/OPA_SRC/SBC/sbcmod.F90 @ 3105

Last change on this file since 3105 was 3105, checked in by poddo, 10 years ago

Rename mfs bulk routine, namelist and doc files

  • Property svn:keywords set to Id
File size: 21.6 KB
Line 
1MODULE sbcmod
2   !!======================================================================
3   !!                       ***  MODULE  sbcmod  ***
4   !! Surface module :  provide to the ocean its surface boundary condition
5   !!======================================================================
6   !! History :  3.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.1  ! 2008-08  (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface
8   !!            3.3  ! 2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
9   !!            3.3  ! 2010-10  (S. Masson)  add diurnal cycle
10   !!            3.3  ! 2010-09  (D. Storkey) add ice boundary conditions (BDY)
11   !!             -   ! 2010-11  (G. Madec) ice-ocean stress always computed at each ocean time-step
12   !!             -   ! 2010-10  (J. Chanut, C. Bricaud, G. Madec)  add the surface pressure forcing
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   sbc_init       : read namsbc namelist
17   !!   sbc            : surface ocean momentum, heat and freshwater boundary conditions
18   !!----------------------------------------------------------------------
19   USE oce              ! ocean dynamics and tracers
20   USE dom_oce          ! ocean space and time domain
21   USE phycst           ! physical constants
22   USE sbc_oce          ! Surface boundary condition: ocean fields
23   USE sbc_ice          ! Surface boundary condition: ice fields
24   USE sbcdcy           ! surface boundary condition: diurnal cycle
25   USE sbcssm           ! surface boundary condition: sea-surface mean variables
26   USE sbcapr           ! surface boundary condition: atmospheric pressure
27   USE sbcana           ! surface boundary condition: analytical formulation
28   USE sbcflx           ! surface boundary condition: flux formulation
29   USE sbcblk_clio      ! surface boundary condition: bulk formulation : CLIO
30   USE sbcblk_core      ! surface boundary condition: bulk formulation : CORE
31   USE sbcblk_mfs       ! surface boundary condition: bulk formulation : MFS
32   USE sbcice_if        ! surface boundary condition: ice-if sea-ice model
33   USE sbcice_lim       ! surface boundary condition: LIM 3.0 sea-ice model
34   USE sbcice_lim_2     ! surface boundary condition: LIM 2.0 sea-ice model
35   USE sbccpl           ! surface boundary condition: coupled florulation
36   USE cpl_oasis3, ONLY:lk_cpl      ! are we in coupled mode?
37   USE sbcssr           ! surface boundary condition: sea surface restoring
38   USE sbcrnf           ! surface boundary condition: runoffs
39   USE sbcfwb           ! surface boundary condition: freshwater budget
40   USE closea           ! closed sea
41   USE bdy_par          ! unstructured open boundary data variables
42   USE bdyice           ! unstructured open boundary data  (bdy_ice_frs routine)
43
44   USE prtctl           ! Print control                    (prt_ctl routine)
45   USE restart          ! ocean restart
46   USE iom              ! IOM library
47   USE in_out_manager   ! I/O manager
48   USE lib_mpp          ! MPP library
49   USE sbcwave          ! Wave module
50
51   IMPLICIT NONE
52   PRIVATE
53
54   PUBLIC   sbc        ! routine called by step.F90
55   PUBLIC   sbc_init   ! routine called by opa.F90
56   
57   INTEGER ::   nsbc   ! type of surface boundary condition (deduced from namsbc informations)
58     
59   !! * Substitutions
60#  include "domzgr_substitute.h90"
61   !!----------------------------------------------------------------------
62   !! NEMO/OPA 4.0 , NEMO-consortium (2011)
63   !! $Id$
64   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
65   !!----------------------------------------------------------------------
66CONTAINS
67
68   SUBROUTINE sbc_init
69      !!---------------------------------------------------------------------
70      !!                    ***  ROUTINE sbc_init ***
71      !!
72      !! ** Purpose :   Initialisation of the ocean surface boundary computation
73      !!
74      !! ** Method  :   Read the namsbc namelist and set derived parameters
75      !!
76      !! ** Action  : - read namsbc parameters
77      !!              - nsbc: type of sbc
78      !!----------------------------------------------------------------------
79      INTEGER ::   icpt   ! local integer
80      !!
81      NAMELIST/namsbc/ nn_fsbc   , ln_ana , ln_flx  , ln_blk_clio, ln_blk_core, ln_cpl,   &
82         &             ln_blk_mfs, ln_apr_dyn, nn_ice , ln_dm2dc, ln_rnf, ln_ssr     , nn_fwb, ln_cdgw
83      !!----------------------------------------------------------------------
84
85      IF(lwp) THEN
86         WRITE(numout,*)
87         WRITE(numout,*) 'sbc_init : surface boundary condition setting'
88         WRITE(numout,*) '~~~~~~~~ '
89      ENDIF
90
91      REWIND( numnam )           ! Read Namelist namsbc
92      READ  ( numnam, namsbc )
93
94      !                          ! overwrite namelist parameter using CPP key information
95      IF( Agrif_Root() ) THEN                ! AGRIF zoom
96        IF( lk_lim2 )   nn_ice      = 2
97        IF( lk_lim3 )   nn_ice      = 3
98      ENDIF
99      IF( cp_cfg == 'gyre' ) THEN            ! GYRE configuration
100          ln_ana      = .TRUE.   
101          nn_ice      =   0
102      ENDIF
103     
104      IF(lwp) THEN               ! Control print
105         WRITE(numout,*) '        Namelist namsbc (partly overwritten with CPP key setting)'
106         WRITE(numout,*) '           frequency update of sbc (and ice)             nn_fsbc     = ', nn_fsbc
107         WRITE(numout,*) '           Type of sbc : '
108         WRITE(numout,*) '              analytical formulation                     ln_ana      = ', ln_ana
109         WRITE(numout,*) '              flux       formulation                     ln_flx      = ', ln_flx
110         WRITE(numout,*) '              CLIO bulk  formulation                     ln_blk_clio = ', ln_blk_clio
111         WRITE(numout,*) '              CORE bulk  formulation                     ln_blk_core = ', ln_blk_core
112         WRITE(numout,*) '              MFS  bulk  formulation                     ln_blk_mfs  = ', ln_blk_mfs
113         WRITE(numout,*) '              coupled    formulation (T if key_sbc_cpl)  ln_cpl      = ', ln_cpl
114         WRITE(numout,*) '           Misc. options of sbc : '
115         WRITE(numout,*) '              Patm gradient added in ocean & ice Eqs.    ln_apr_dyn  = ', ln_apr_dyn
116         WRITE(numout,*) '              ice management in the sbc (=0/1/2/3)       nn_ice      = ', nn_ice 
117         WRITE(numout,*) '              daily mean to diurnal cycle qsr            ln_dm2dc    = ', ln_dm2dc 
118         WRITE(numout,*) '              runoff / runoff mouths                     ln_rnf      = ', ln_rnf
119         WRITE(numout,*) '              Sea Surface Restoring on SST and/or SSS    ln_ssr      = ', ln_ssr
120         WRITE(numout,*) '              FreshWater Budget control  (=0/1/2)        nn_fwb      = ', nn_fwb
121         WRITE(numout,*) '              closed sea (=0/1) (set in namdom)          nn_closea   = ', nn_closea
122      ENDIF
123
124      !                              ! allocate sbc arrays
125      IF( sbc_oce_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_oce arrays' )
126
127      !                          ! Checks:
128      IF( .NOT. ln_rnf ) THEN                      ! no specific treatment in vicinity of river mouths
129         ln_rnf_mouth  = .false.                     
130         IF( sbc_rnf_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_rnf arrays' )
131         nkrnf         = 0
132         rnf     (:,:) = 0.e0
133         rnfmsk  (:,:) = 0.e0
134         rnfmsk_z(:)   = 0.e0
135      ENDIF
136      IF( nn_ice == 0  )   fr_i(:,:) = 0.e0        ! no ice in the domain, ice fraction is always zero
137
138      !                                            ! restartability   
139      IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 .OR.   &
140          MOD( nstock             , nn_fsbc) /= 0 ) THEN
141         WRITE(ctmp1,*) 'experiment length (', nitend - nit000 + 1, ') or nstock (', nstock,   &
142            &           ' is NOT a multiple of nn_fsbc (', nn_fsbc, ')'
143         CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' )
144      ENDIF
145      !
146      IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 )   &
147         &  CALL ctl_warn( 'nn_fsbc is NOT a multiple of the number of time steps in a day' )
148      !
149      IF( nn_ice == 2 .AND. .NOT.( ln_blk_clio .OR. ln_blk_core .OR. lk_cpl ) )   &
150         &   CALL ctl_stop( 'sea-ice model requires a bulk formulation or coupled configuration' )
151     
152      IF( ln_dm2dc )   nday_qsr = -1   ! initialisation flag
153
154      IF( ln_dm2dc .AND. .NOT.( ln_flx .OR. ln_blk_core ) )   &
155         &   CALL ctl_stop( 'diurnal cycle into qsr field from daily values requires a flux or core-bulk formulation' )
156     
157      IF( ln_dm2dc .AND. ( ( NINT(rday) / ( nn_fsbc * NINT(rdt) ) )  < 8 ) )   &
158         &   CALL ctl_warn( 'diurnal cycle for qsr: the sampling of the diurnal cycle is too small...' )
159
160       !drag coefficient read from wave model definable only with mfs bulk formulae and core
161       IF(ln_cdgw .AND. .NOT.(ln_blk_mfs .OR. ln_blk_core) )              &
162          &   CALL ctl_stop( 'drag coefficient read from wave model definable only with mfs bulk formulae and core')
163     
164      !                          ! Choice of the Surface Boudary Condition (set nsbc)
165      icpt = 0
166      IF( ln_ana          ) THEN   ;   nsbc =  1   ; icpt = icpt + 1   ;   ENDIF       ! analytical      formulation
167      IF( ln_flx          ) THEN   ;   nsbc =  2   ; icpt = icpt + 1   ;   ENDIF       ! flux            formulation
168      IF( ln_blk_clio     ) THEN   ;   nsbc =  3   ; icpt = icpt + 1   ;   ENDIF       ! CLIO bulk       formulation
169      IF( ln_blk_core     ) THEN   ;   nsbc =  4   ; icpt = icpt + 1   ;   ENDIF       ! CORE bulk       formulation
170      IF( ln_blk_mfs      ) THEN   ;   nsbc =  6   ; icpt = icpt + 1   ;   ENDIF       ! MFS  bulk       formulation
171      IF( ln_cpl          ) THEN   ;   nsbc =  5   ; icpt = icpt + 1   ;   ENDIF       ! Coupled         formulation
172      IF( cp_cfg == 'gyre') THEN   ;   nsbc =  0                       ;   ENDIF       ! GYRE analytical formulation
173      IF( lk_esopa        )            nsbc = -1                                       ! esopa test, ALL formulations
174      !
175      IF( icpt /= 1 .AND. .NOT.lk_esopa ) THEN
176         WRITE(numout,*)
177         WRITE(numout,*) '           E R R O R in setting the sbc, one and only one namelist/CPP key option '
178         WRITE(numout,*) '                     must be choosen. You choose ', icpt, ' option(s)'
179         WRITE(numout,*) '                     We stop'
180         nstop = nstop + 1
181      ENDIF
182      IF(lwp) THEN
183         WRITE(numout,*)
184         IF( nsbc == -1 )   WRITE(numout,*) '              ESOPA test All surface boundary conditions'
185         IF( nsbc ==  0 )   WRITE(numout,*) '              GYRE analytical formulation'
186         IF( nsbc ==  1 )   WRITE(numout,*) '              analytical formulation'
187         IF( nsbc ==  2 )   WRITE(numout,*) '              flux formulation'
188         IF( nsbc ==  3 )   WRITE(numout,*) '              CLIO bulk formulation'
189         IF( nsbc ==  4 )   WRITE(numout,*) '              CORE bulk formulation'
190         IF( nsbc ==  5 )   WRITE(numout,*) '              coupled formulation'
191         IF( nsbc ==  6 )   WRITE(numout,*) '              MFS Bulk formulation'
192      ENDIF
193      !
194   END SUBROUTINE sbc_init
195
196
197   SUBROUTINE sbc( kt )
198      !!---------------------------------------------------------------------
199      !!                    ***  ROUTINE sbc  ***
200      !!             
201      !! ** Purpose :   provide at each time-step the ocean surface boundary
202      !!                condition (momentum, heat and freshwater fluxes)
203      !!
204      !! ** Method  :   blah blah  to be written ?????????
205      !!                CAUTION : never mask the surface stress field (tke sbc)
206      !!
207      !! ** Action  : - set the ocean surface boundary condition at before and now
208      !!                time step, i.e. 
209      !!                utau_b, vtau_b, qns_b, qsr_b, emp_n, emps_b, qrp_b, erp_b
210      !!                utau  , vtau  , qns  , qsr  , emp  , emps  , qrp  , erp
211      !!              - updte the ice fraction : fr_i
212      !!----------------------------------------------------------------------
213      INTEGER, INTENT(in) ::   kt       ! ocean time step
214      !!---------------------------------------------------------------------
215
216      !                                            ! ---------------------------------------- !
217      IF( kt /= nit000 ) THEN                      !          Swap of forcing fields          !
218         !                                         ! ---------------------------------------- !
219         utau_b(:,:) = utau(:,:)                         ! Swap the ocean forcing fields
220         vtau_b(:,:) = vtau(:,:)                         ! (except at nit000 where before fields
221         qns_b (:,:) = qns (:,:)                         !  are set at the end of the routine)
222         ! The 3D heat content due to qsr forcing is treated in traqsr
223         ! qsr_b (:,:) = qsr (:,:)
224         emp_b (:,:) = emp (:,:)
225         emps_b(:,:) = emps(:,:)
226      ENDIF
227      !                                            ! ---------------------------------------- !
228      !                                            !        forcing field computation         !
229      !                                            ! ---------------------------------------- !
230
231      CALL iom_setkt( kt + nn_fsbc - 1 )                 ! in sbc, iom_put is called every nn_fsbc time step
232      !
233      IF( ln_apr_dyn ) CALL sbc_apr( kt )                ! atmospheric pressure provided at kt+0.5*nn_fsbc
234                                                         ! (caution called before sbc_ssm)
235      !
236      CALL sbc_ssm( kt )                                 ! ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m)
237      !                                                  ! averaged over nf_sbc time-step
238
239      IF (ln_cdgw) CALL sbc_wave( kt )
240                                                   !==  sbc formulation  ==!
241                                                           
242      SELECT CASE( nsbc )                                ! Compute ocean surface boundary condition
243      !                                                  ! (i.e. utau,vtau, qns, qsr, emp, emps)
244      CASE(  0 )   ;   CALL sbc_gyre    ( kt )                    ! analytical formulation : GYRE configuration
245      CASE(  1 )   ;   CALL sbc_ana     ( kt )                    ! analytical formulation : uniform sbc
246      CASE(  2 )   ;   CALL sbc_flx     ( kt )                    ! flux formulation
247      CASE(  3 )   ;   CALL sbc_blk_clio( kt )                    ! bulk formulation : CLIO for the ocean
248      CASE(  4 )   ;   CALL sbc_blk_core( kt )                    ! bulk formulation : CORE for the ocean
249      CASE(  5 )   ;   CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   ! coupled formulation
250      CASE(  6 )   ;   CALL sbc_blk_mfs ( kt )                    ! bulk formulation : MFS for the ocean
251      CASE( -1 )                               
252                       CALL sbc_ana     ( kt )                    ! ESOPA, test ALL the formulations
253                       CALL sbc_gyre    ( kt )                    !
254                       CALL sbc_flx     ( kt )                    !
255                       CALL sbc_blk_clio( kt )                    !
256                       CALL sbc_blk_core( kt )                    !
257                       CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   !
258      END SELECT
259
260      !                                            !==  Misc. Options  ==!
261     
262      SELECT CASE( nn_ice )                                     ! Update heat and freshwater fluxes over sea-ice areas
263      CASE(  1 )   ;       CALL sbc_ice_if   ( kt )                  ! Ice-cover climatology ("Ice-if" model)
264         !                                                     
265      CASE(  2 )   ;       CALL sbc_ice_lim_2( kt, nsbc )            ! LIM-2 ice model
266         IF( lk_bdy )      CALL bdy_ice_frs  ( kt )                  ! BDY boundary condition
267         !                                                     
268      CASE(  3 )   ;       CALL sbc_ice_lim  ( kt, nsbc )            ! LIM-3 ice model
269      END SELECT                                             
270
271      IF( ln_rnf       )   CALL sbc_rnf( kt )                   ! add runoffs to fresh water fluxes
272 
273      IF( ln_ssr       )   CALL sbc_ssr( kt )                   ! add SST/SSS damping term
274
275      IF( nn_fwb  /= 0 )   CALL sbc_fwb( kt, nn_fwb, nn_fsbc )  ! control the freshwater budget
276
277      IF( nclosea == 1 )   CALL sbc_clo( kt )                   ! treatment of closed sea in the model domain
278      !                                                         ! (update freshwater fluxes)
279!RBbug do not understand why see ticket 667
280      CALL lbc_lnk( emp, 'T', 1. )
281      !
282      IF( kt == nit000 ) THEN                          !   set the forcing field at nit000 - 1    !
283         !                                             ! ---------------------------------------- !
284         IF( ln_rstart .AND.    &                               !* Restart: read in restart file
285            & iom_varid( numror, 'utau_b', ldstop = .FALSE. ) > 0 ) THEN
286            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields red in the restart file'
287            CALL iom_get( numror, jpdom_autoglo, 'utau_b', utau_b )   ! before i-stress  (U-point)
288            CALL iom_get( numror, jpdom_autoglo, 'vtau_b', vtau_b )   ! before j-stress  (V-point)
289            CALL iom_get( numror, jpdom_autoglo, 'qns_b' , qns_b  )   ! before non solar heat flux (T-point)
290            ! The 3D heat content due to qsr forcing is treated in traqsr
291            ! CALL iom_get( numror, jpdom_autoglo, 'qsr_b' , qsr_b  )   ! before     solar heat flux (T-point)
292            CALL iom_get( numror, jpdom_autoglo, 'emp_b' , emp_b  )   ! before     freshwater flux (T-point)
293            CALL iom_get( numror, jpdom_autoglo, 'emps_b', emps_b )   ! before C/D freshwater flux (T-point)
294         ELSE                                                   !* no restart: set from nit000 values
295            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields set to nit000'
296            utau_b(:,:) = utau(:,:) 
297            vtau_b(:,:) = vtau(:,:)
298            qns_b (:,:) = qns (:,:)
299            ! qsr_b (:,:) = qsr (:,:)
300            emp_b (:,:) = emp (:,:)
301            emps_b(:,:) = emps(:,:)
302         ENDIF
303      ENDIF
304      !                                                ! ---------------------------------------- !
305      IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
306         !                                             ! ---------------------------------------- !
307         IF(lwp) WRITE(numout,*)
308         IF(lwp) WRITE(numout,*) 'sbc : ocean surface forcing fields written in ocean restart file ',   &
309            &                    'at it= ', kt,' date= ', ndastp
310         IF(lwp) WRITE(numout,*) '~~~~'
311         CALL iom_rstput( kt, nitrst, numrow, 'utau_b' , utau )
312         CALL iom_rstput( kt, nitrst, numrow, 'vtau_b' , vtau )
313         CALL iom_rstput( kt, nitrst, numrow, 'qns_b'  , qns  )
314         ! The 3D heat content due to qsr forcing is treated in traqsr
315         ! CALL iom_rstput( kt, nitrst, numrow, 'qsr_b'  , qsr  )
316         CALL iom_rstput( kt, nitrst, numrow, 'emp_b'  , emp  )
317         CALL iom_rstput( kt, nitrst, numrow, 'emps_b' , emps )
318      ENDIF
319
320      !                                                ! ---------------------------------------- !
321      !                                                !        Outputs and control print         !
322      !                                                ! ---------------------------------------- !
323      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
324         CALL iom_put( "empmr" , emp  - rnf )                   ! upward water flux
325         CALL iom_put( "empsmr", emps - rnf )                   ! c/d water flux
326         CALL iom_put( "qt"    , qns  + qsr )                   ! total heat flux
327         CALL iom_put( "qns"   , qns        )                   ! solar heat flux
328         CALL iom_put( "qsr"   ,       qsr  )                   ! solar heat flux
329         IF( nn_ice > 0 )   CALL iom_put( "ice_cover", fr_i )   ! ice fraction
330      ENDIF
331      !
332      CALL iom_setkt( kt )           ! iom_put outside of sbc is called at every time step
333      !
334      CALL iom_put( "utau", utau )   ! i-wind stress   (stress can be updated at
335      CALL iom_put( "vtau", vtau )   ! j-wind stress    each time step in sea-ice)
336      CALL iom_put( "taum", taum )   ! wind stress module
337      CALL iom_put( "wspd", wndm )   ! wind speed  module
338      !
339      IF(ln_ctl) THEN         ! print mean trends (used for debugging)
340         CALL prt_ctl(tab2d_1=fr_i             , clinfo1=' fr_i     - : ', mask1=tmask, ovlap=1 )
341         CALL prt_ctl(tab2d_1=(emp-rnf)        , clinfo1=' emp-rnf  - : ', mask1=tmask, ovlap=1 )
342         CALL prt_ctl(tab2d_1=(emps-rnf)       , clinfo1=' emps-rnf - : ', mask1=tmask, ovlap=1 )
343         CALL prt_ctl(tab2d_1=qns              , clinfo1=' qns      - : ', mask1=tmask, ovlap=1 )
344         CALL prt_ctl(tab2d_1=qsr              , clinfo1=' qsr      - : ', mask1=tmask, ovlap=1 )
345         CALL prt_ctl(tab3d_1=tmask            , clinfo1=' tmask    - : ', mask1=tmask, ovlap=1, kdim=jpk )
346         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_tem), clinfo1=' sst      - : ', mask1=tmask, ovlap=1, kdim=1   )
347         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_sal), clinfo1=' sss      - : ', mask1=tmask, ovlap=1, kdim=1   )
348         CALL prt_ctl(tab2d_1=utau             , clinfo1=' utau     - : ', mask1=umask,                      &
349            &         tab2d_2=vtau             , clinfo2=' vtau     - : ', mask2=vmask, ovlap=1 )
350      ENDIF
351      !
352   END SUBROUTINE sbc
353
354   !!======================================================================
355END MODULE sbcmod
Note: See TracBrowser for help on using the repository browser.