source: branches/2011/dev_NEMO_MERGE_2011/NEMOGCM/NEMO/OPA_SRC/SBC/sbcfwb.F90 @ 3229

Last change on this file since 3229 was 3229, checked in by charris, 10 years ago

Added timing calls to most significant routines in LDF, SBC and ZDF.

  • Property svn:keywords set to Id
File size: 10.4 KB
Line 
1MODULE sbcfwb
2   !!======================================================================
3   !!                       ***  MODULE  sbcfwb  ***
4   !! Ocean fluxes   : domain averaged freshwater budget
5   !!======================================================================
6   !! History :  OPA  ! 2001-02  (E. Durand)  Original code
7   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
8   !!            3.0  ! 2006-08  (G. Madec)  Surface module
9   !!            3.2  ! 2009-07  (C. Talandier) emp mean s spread over erp area
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   sbc_fwb      : freshwater budget for global ocean configurations
14   !!                  in free surface and forced mode
15   !!----------------------------------------------------------------------
16   USE oce             ! ocean dynamics and tracers
17   USE dom_oce         ! ocean space and time domain
18   USE sbc_oce         ! surface ocean boundary condition
19   USE phycst          ! physical constants
20   USE sbcrnf          ! ocean runoffs
21   USE sbcssr          ! SS damping terms
22   USE in_out_manager  ! I/O manager
23   USE lib_mpp         ! distribued memory computing library
24   USE wrk_nemo        ! work arrays
25   USE timing          ! Timing
26   USE lbclnk          ! ocean lateral boundary conditions
27   USE lib_fortran
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   sbc_fwb    ! routine called by step
33
34   REAL(wp) ::   a_fwb_b   ! annual domain averaged freshwater budget
35   REAL(wp) ::   a_fwb     ! for 2 year before (_b) and before year.
36   REAL(wp) ::   fwfold    ! fwfold to be suppressed
37   REAL(wp) ::   area      ! global mean ocean surface (interior domain)
38
39   !! * Substitutions
40#  include "domzgr_substitute.h90"
41#  include "vectopt_loop_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
44   !! $Id$
45   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   SUBROUTINE sbc_fwb( kt, kn_fwb, kn_fsbc )
50      !!---------------------------------------------------------------------
51      !!                  ***  ROUTINE sbc_fwb  ***
52      !!
53      !! ** Purpose :   Control the mean sea surface drift
54      !!
55      !! ** Method  :   several ways  depending on kn_fwb
56      !!                =0 no control
57      !!                =1 global mean of emp set to zero at each nn_fsbc time step
58      !!                =2 annual global mean corrected from previous year
59      !!                =3 global mean of emp set to zero at each nn_fsbc time step
60      !!                   & spread out over erp area depending its sign
61      !!----------------------------------------------------------------------
62      INTEGER, INTENT( in ) ::   kt       ! ocean time-step index
63      INTEGER, INTENT( in ) ::   kn_fsbc  !
64      INTEGER, INTENT( in ) ::   kn_fwb   ! ocean time-step index
65      !
66      INTEGER  ::   inum, ikty, iyear   ! local integers
67      REAL(wp) ::   z_fwf, z_fwf_nsrf, zsum_fwf, zsum_erp   ! local scalars
68      REAL(wp) ::   zsurf_neg, zsurf_pos, zsurf_tospread    !   -      -
69      REAL(wp), POINTER, DIMENSION(:,:) ::   ztmsk_neg, ztmsk_pos, ztmsk_tospread, z_wgt, zerp_cor
70      !!----------------------------------------------------------------------
71      !
72      IF( nn_timing == 1 )  CALL timing_start('sbc_fwb')
73      !
74      CALL wrk_alloc( jpi,jpj, ztmsk_neg, ztmsk_pos, ztmsk_tospread, z_wgt, zerp_cor )
75      !
76      IF( kt == nit000 ) THEN
77         IF(lwp) THEN
78            WRITE(numout,*)
79            WRITE(numout,*) 'sbc_fwb : FreshWater Budget correction'
80            WRITE(numout,*) '~~~~~~~'
81            IF( kn_fwb == 1 )   WRITE(numout,*) '          instantaneously set to zero'
82            IF( kn_fwb == 2 )   WRITE(numout,*) '          adjusted from previous year budget'
83            IF( kn_fwb == 3 )   WRITE(numout,*) '          fwf set to zero and spread out over erp area'
84         ENDIF
85         !
86         IF( kn_fwb == 3 .AND. nn_sssr /= 2 )   CALL ctl_stop( 'sbc_fwb: nn_fwb = 3 requires nn_sssr = 2, we stop ' )
87         !
88         area = glob_sum( e1e2t(:,:) )           ! interior global domain surface
89      ENDIF
90     
91
92      SELECT CASE ( kn_fwb )
93      !
94      CASE ( 1 )                             !==  global mean fwf set to zero  ==!
95         !
96         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
97            z_fwf = glob_sum( e1e2t(:,:) * ( emp(:,:) - rnf(:,:) ) ) / area   ! sum over the global domain
98            emp (:,:) = emp (:,:) - z_fwf 
99            emps(:,:) = emps(:,:) - z_fwf 
100         ENDIF
101         !
102      CASE ( 2 )                             !==  fwf budget adjusted from the previous year  ==!
103         !
104         IF( kt == nit000 ) THEN                   ! initialisation
105            !                                         ! Read the corrective factor on precipitations (fwfold)
106            CALL ctl_opn( inum, 'EMPave_old.dat', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE. )
107            READ ( inum, "(24X,I8,2ES24.16)" ) iyear, a_fwb_b, a_fwb
108            CLOSE( inum )
109            fwfold = a_fwb                            ! current year freshwater budget correction
110            !                                         ! estimate from the previous year budget
111            IF(lwp)WRITE(numout,*)
112            IF(lwp)WRITE(numout,*)'sbc_fwb : year = ',iyear  , ' freshwater budget correction = ', fwfold
113            IF(lwp)WRITE(numout,*)'          year = ',iyear-1, ' freshwater budget read       = ', a_fwb
114            IF(lwp)WRITE(numout,*)'          year = ',iyear-2, ' freshwater budget read       = ', a_fwb_b
115         ENDIF   
116         !                                         ! Update fwfold if new year start
117         ikty = 365 * 86400 / rdttra(1)    !!bug  use of 365 days leap year or 360d year !!!!!!!
118         IF( MOD( kt, ikty ) == 0 ) THEN
119            a_fwb_b = a_fwb
120            a_fwb   = glob_sum( e1e2t(:,:) * sshn(:,:) )   ! sum over the global domain
121            a_fwb   = a_fwb * 1.e+3 / ( area * 86400. * 365. )     ! convert in Kg/m3/s = mm/s
122!!gm        !                                                      !!bug 365d year
123            fwfold =  a_fwb                           ! current year freshwater budget correction
124            !                                         ! estimate from the previous year budget
125         ENDIF
126         !
127         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN      ! correct the freshwater fluxes
128            emp (:,:) = emp (:,:) + fwfold
129            emps(:,:) = emps(:,:) + fwfold
130         ENDIF
131         !
132         IF( kt == nitend .AND. lwp ) THEN         ! save fwfold value in a file
133            CALL ctl_opn( inum, 'EMPave.dat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE., narea )
134            WRITE( inum, "(24X,I8,2ES24.16)" ) nyear, a_fwb_b, a_fwb
135            CLOSE( inum )
136         ENDIF
137         !
138      CASE ( 3 )                             !==  global fwf set to zero and spread out over erp area  ==!
139         !
140         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
141            ztmsk_pos(:,:) = tmask_i(:,:)                      ! Select <0 and >0 area of erp
142            WHERE( erp < 0._wp )   ztmsk_pos = 0._wp
143            ztmsk_neg(:,:) = tmask_i(:,:) - ztmsk_pos(:,:)
144            !
145            zsurf_neg = glob_sum( e1e2t(:,:)*ztmsk_neg(:,:) )   ! Area filled by <0 and >0 erp
146            zsurf_pos = glob_sum( e1e2t(:,:)*ztmsk_pos(:,:) )
147            !                                                  ! fwf global mean
148            z_fwf = glob_sum( e1e2t(:,:) * ( emp(:,:) - rnf(:,:) ) ) / area
149            !           
150            IF( z_fwf < 0._wp ) THEN         ! spread out over >0 erp area to increase evaporation
151                zsurf_tospread      = zsurf_pos
152                ztmsk_tospread(:,:) = ztmsk_pos(:,:)
153            ELSE                             ! spread out over <0 erp area to increase precipitation
154                zsurf_tospread      = zsurf_neg
155                ztmsk_tospread(:,:) = ztmsk_neg(:,:)
156            ENDIF
157            !
158            zsum_fwf   = glob_sum( e1e2t(:,:) * z_fwf )         ! fwf global mean over <0 or >0 erp area
159!!gm :  zsum_fwf   = z_fwf * area   ???  it is right?  I think so....
160            z_fwf_nsrf =  zsum_fwf / ( zsurf_tospread + rsmall )
161            !                                                  ! weight to respect erp field 2D structure
162            zsum_erp = glob_sum( ztmsk_tospread(:,:) * erp(:,:) * e1e2t(:,:) )
163            z_wgt(:,:) = ztmsk_tospread(:,:) * erp(:,:) / ( zsum_erp + rsmall )
164            !                                                  ! final correction term to apply
165            zerp_cor(:,:) = -1. * z_fwf_nsrf * zsurf_tospread * z_wgt(:,:)
166            !
167!!gm   ===>>>>  lbc_lnk should be useless as all the computation is done over the whole domain !
168            CALL lbc_lnk( zerp_cor, 'T', 1. )
169            !
170            emp (:,:) = emp (:,:) + zerp_cor(:,:)
171            emps(:,:) = emps(:,:) + zerp_cor(:,:)
172            erp (:,:) = erp (:,:) + zerp_cor(:,:)
173            !
174            IF( nprint == 1 .AND. lwp ) THEN                   ! control print
175               IF( z_fwf < 0._wp ) THEN
176                  WRITE(numout,*)'   z_fwf < 0'
177                  WRITE(numout,*)'   SUM(erp+)     = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv'
178               ELSE
179                  WRITE(numout,*)'   z_fwf >= 0'
180                  WRITE(numout,*)'   SUM(erp-)     = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv'
181               ENDIF
182               WRITE(numout,*)'   SUM(empG)     = ', SUM( z_fwf*e1e2t(:,:) )*1.e-9,' Sv'
183               WRITE(numout,*)'   z_fwf         = ', z_fwf      ,' Kg/m2/s'
184               WRITE(numout,*)'   z_fwf_nsrf    = ', z_fwf_nsrf ,' Kg/m2/s'
185               WRITE(numout,*)'   MIN(zerp_cor) = ', MINVAL(zerp_cor) 
186               WRITE(numout,*)'   MAX(zerp_cor) = ', MAXVAL(zerp_cor) 
187            ENDIF
188         ENDIF
189         !
190      CASE DEFAULT                           !==  you should never be there  ==!
191         CALL ctl_stop( 'sbc_fwb : wrong nn_fwb value for the FreshWater Budget correction, choose either 1, 2 or 3' )
192         !
193      END SELECT
194      !
195      CALL wrk_dealloc( jpi,jpj, ztmsk_neg, ztmsk_pos, ztmsk_tospread, z_wgt, zerp_cor )
196      !
197      IF( nn_timing == 1 )  CALL timing_stop('sbc_fwb')
198      !
199   END SUBROUTINE sbc_fwb
200
201   !!======================================================================
202END MODULE sbcfwb
Note: See TracBrowser for help on using the repository browser.