source: branches/2011/dev_NEMO_MERGE_2011/NEMOGCM/NEMO/OPA_SRC/ZDF/zdfgls.F90 @ 3186

Last change on this file since 3186 was 3186, checked in by smasson, 10 years ago

dev_NEMO_MERGE_2011: replace the old wrk_nemo with the new wrk_nemo

  • Property svn:keywords set to Id
File size: 59.6 KB
Line 
1MODULE zdfgls
2   !!======================================================================
3   !!                       ***  MODULE  zdfgls  ***
4   !! Ocean physics:  vertical mixing coefficient computed from the gls
5   !!                 turbulent closure parameterization
6   !!======================================================================
7   !! History :   3.0  !  2009-09  (G. Reffray)  Original code
8   !!             3.3  !  2010-10  (C. Bricaud)  Add in the reference
9   !!----------------------------------------------------------------------
10#if defined key_zdfgls   ||   defined key_esopa
11   !!----------------------------------------------------------------------
12   !!   'key_zdfgls'                 Generic Length Scale vertical physics
13   !!----------------------------------------------------------------------
14   !!   zdf_gls      : update momentum and tracer Kz from a gls scheme
15   !!   zdf_gls_init : initialization, namelist read, and parameters control
16   !!   gls_rst      : read/write gls restart in ocean restart file
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE dom_oce        ! ocean space and time domain
20   USE domvvl         ! ocean space and time domain : variable volume layer
21   USE zdf_oce        ! ocean vertical physics
22   USE sbc_oce        ! surface boundary condition: ocean
23   USE phycst         ! physical constants
24   USE zdfmxl         ! mixed layer
25   USE restart        ! only for lrst_oce
26   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
27   USE lib_mpp        ! MPP manager
28   USE wrk_nemo       ! work arrays
29   USE prtctl         ! Print control
30   USE in_out_manager ! I/O manager
31   USE iom            ! I/O manager library
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   zdf_gls        ! routine called in step module
37   PUBLIC   zdf_gls_init   ! routine called in opa module
38   PUBLIC   gls_rst        ! routine called in step module
39
40   LOGICAL , PUBLIC, PARAMETER ::   lk_zdfgls = .TRUE.   !: TKE vertical mixing flag
41   !
42   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   en      !: now turbulent kinetic energy
43   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   mxln    !: now mixing length
44   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   zwall   !: wall function
45   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   ustars2 !: Squared surface velocity scale at T-points
46   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   ustarb2 !: Squared bottom  velocity scale at T-points
47
48   !                                         !!! ** Namelist  namzdf_gls  **
49   LOGICAL  ::   ln_crban      = .FALSE.      ! =T use Craig and Banner scheme
50   LOGICAL  ::   ln_length_lim = .FALSE.      ! use limit on the dissipation rate under stable stratification (Galperin et al. 1988)
51   LOGICAL  ::   ln_sigpsi     = .FALSE.      ! Activate Burchard (2003) modification for k-eps closure & wave breaking mixing
52   INTEGER  ::   nn_tkebc_surf = 0            ! TKE surface boundary condition (=0/1)
53   INTEGER  ::   nn_tkebc_bot  = 0            ! TKE bottom boundary condition (=0/1)
54   INTEGER  ::   nn_psibc_surf = 0            ! PSI surface boundary condition (=0/1)
55   INTEGER  ::   nn_psibc_bot  = 0            ! PSI bottom boundary condition (=0/1)
56   INTEGER  ::   nn_stab_func  = 0            ! stability functions G88, KC or Canuto (=0/1/2)
57   INTEGER  ::   nn_clos       = 0            ! closure 0/1/2/3 MY82/k-eps/k-w/gen
58   REAL(wp) ::   rn_clim_galp  = 0.53_wp      ! Holt 2008 value for k-eps: 0.267
59   REAL(wp) ::   rn_epsmin     = 1.e-12_wp    ! minimum value of dissipation (m2/s3)
60   REAL(wp) ::   rn_emin       = 1.e-6_wp     ! minimum value of TKE (m2/s2)
61   REAL(wp) ::   rn_charn      = 2.e+5_wp     ! Charnock constant for surface breaking waves mixing : 1400. (standard) or 2.e5 (Stacey value)
62   REAL(wp) ::   rn_crban      = 100._wp      ! Craig and Banner constant for surface breaking waves mixing
63
64   REAL(wp) ::   hsro          =  0.003_wp    ! Minimum surface roughness
65   REAL(wp) ::   hbro          =  0.003_wp    ! Bottom roughness (m)
66   REAL(wp) ::   rcm_sf        =  0.73_wp     ! Shear free turbulence parameters
67   REAL(wp) ::   ra_sf         = -2.0_wp      ! Must be negative -2 < ra_sf < -1
68   REAL(wp) ::   rl_sf         =  0.2_wp      ! 0 <rl_sf<vkarmn   
69   REAL(wp) ::   rghmin        = -0.28_wp
70   REAL(wp) ::   rgh0          =  0.0329_wp
71   REAL(wp) ::   rghcri        =  0.03_wp
72   REAL(wp) ::   ra1           =  0.92_wp
73   REAL(wp) ::   ra2           =  0.74_wp
74   REAL(wp) ::   rb1           = 16.60_wp
75   REAL(wp) ::   rb2           = 10.10_wp         
76   REAL(wp) ::   re2           =  1.33_wp         
77   REAL(wp) ::   rl1           =  0.107_wp
78   REAL(wp) ::   rl2           =  0.0032_wp
79   REAL(wp) ::   rl3           =  0.0864_wp
80   REAL(wp) ::   rl4           =  0.12_wp
81   REAL(wp) ::   rl5           = 11.9_wp
82   REAL(wp) ::   rl6           =  0.4_wp
83   REAL(wp) ::   rl7           =  0.0_wp
84   REAL(wp) ::   rl8           =  0.48_wp
85   REAL(wp) ::   rm1           =  0.127_wp
86   REAL(wp) ::   rm2           =  0.00336_wp
87   REAL(wp) ::   rm3           =  0.0906_wp
88   REAL(wp) ::   rm4           =  0.101_wp
89   REAL(wp) ::   rm5           = 11.2_wp
90   REAL(wp) ::   rm6           =  0.4_wp
91   REAL(wp) ::   rm7           =  0.0_wp
92   REAL(wp) ::   rm8           =  0.318_wp
93   
94   REAL(wp) ::   rc02, rc02r, rc03, rc04                          ! coefficients deduced from above parameters
95   REAL(wp) ::   rc03_sqrt2_galp                                  !     -           -           -        -
96   REAL(wp) ::   rsbc_tke1, rsbc_tke2, rsbc_tke3, rfact_tke       !     -           -           -        -
97   REAL(wp) ::   rsbc_psi1, rsbc_psi2, rsbc_psi3, rfact_psi       !     -           -           -        -
98   REAL(wp) ::   rsbc_mb  , rsbc_std , rsbc_zs                    !     -           -           -        -
99   REAL(wp) ::   rc0, rc2, rc3, rf6, rcff, rc_diff                !     -           -           -        -
100   REAL(wp) ::   rs0, rs1, rs2, rs4, rs5, rs6                     !     -           -           -        -
101   REAL(wp) ::   rd0, rd1, rd2, rd3, rd4, rd5                     !     -           -           -        -
102   REAL(wp) ::   rsc_tke, rsc_psi, rpsi1, rpsi2, rpsi3, rsc_psi0  !     -           -           -        -
103   REAL(wp) ::   rpsi3m, rpsi3p, rpp, rmm, rnn                    !     -           -           -        -
104
105   !! * Substitutions
106#  include "domzgr_substitute.h90"
107#  include "vectopt_loop_substitute.h90"
108   !!----------------------------------------------------------------------
109   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
110   !! $Id$
111   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
112   !!----------------------------------------------------------------------
113CONTAINS
114
115   INTEGER FUNCTION zdf_gls_alloc()
116      !!----------------------------------------------------------------------
117      !!                ***  FUNCTION zdf_gls_alloc  ***
118      !!----------------------------------------------------------------------
119      ALLOCATE( en(jpi,jpj,jpk),  mxln(jpi,jpj,jpk), zwall(jpi,jpj,jpk) ,     &
120         &      ustars2(jpi,jpj), ustarb2(jpi,jpj)                      , STAT= zdf_gls_alloc )
121         !
122      IF( lk_mpp             )   CALL mpp_sum ( zdf_gls_alloc )
123      IF( zdf_gls_alloc /= 0 )   CALL ctl_warn('zdf_gls_alloc: failed to allocate arrays')
124   END FUNCTION zdf_gls_alloc
125
126
127   SUBROUTINE zdf_gls( kt )
128      !!----------------------------------------------------------------------
129      !!                   ***  ROUTINE zdf_gls  ***
130      !!
131      !! ** Purpose :   Compute the vertical eddy viscosity and diffusivity
132      !!              coefficients using the GLS turbulent closure scheme.
133      !!----------------------------------------------------------------------
134      USE oce     , ONLY: tsa                 ! use tsa as workspace
135      USE oce     , ONLY: z_elem_a  =>   ua   ! use ua as workspace
136      USE oce     , ONLY: z_elem_b  =>   va   ! use va as workspace
137      !
138      INTEGER, INTENT(in) ::   kt ! ocean time step
139      INTEGER  ::   ji, jj, jk, ibot, ibotm1, dir  ! dummy loop arguments
140      REAL(wp) ::   zesh2, zsigpsi, zcoef, zex1, zex2   ! local scalars
141      REAL(wp) ::   ztx2, zty2, zup, zdown, zcof        !   -      -
142      REAL(wp) ::   zratio, zrn2, zflxb, sh             !   -      -
143      REAL(wp) ::   prod, buoy, diss, zdiss, sm         !   -      -
144      REAL(wp) ::   gh, gm, shr, dif, zsqen, zav        !   -      -
145      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zdep
146      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zflxs       ! Turbulence fluxed induced by internal waves
147      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zhsro       ! Surface roughness (surface waves)
148      REAL(wp), POINTER, DIMENSION(:,:,:) ::   eb          ! tke at time before
149      REAL(wp), POINTER, DIMENSION(:,:,:) ::   mxlb        ! mixing length at time before
150      REAL(wp), POINTER, DIMENSION(:,:,:) ::   shear       ! vertical shear
151      REAL(wp), POINTER, DIMENSION(:,:,:) ::   eps         ! dissipation rate
152      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zwall_psi   ! Wall function use in the wb case (ln_sigpsi.AND.ln_crban=T)
153      REAL(wp), POINTER, DIMENSION(:,:,:) ::   z_elem_c, psi
154      !!--------------------------------------------------------------------
155
156      CALL wrk_alloc( jpi,jpj, zdep, zflxs, zhsro )
157      CALL wrk_alloc( jpi,jpj,jpk, eb, mxlb, shear, eps, zwall_psi )
158      !
159      z_elem_c  => tsa(:,:,:,1)
160      psi       => tsa(:,:,:,2)
161
162      ! Preliminary computing
163
164      ustars2 = 0._wp   ;   ustarb2 = 0._wp   ;   psi  = 0._wp   ;   zwall_psi = 0._wp
165
166      ! Compute surface and bottom friction at T-points
167!CDIR NOVERRCHK
168      DO jj = 2, jpjm1
169!CDIR NOVERRCHK
170         DO ji = fs_2, fs_jpim1   ! vector opt.
171            !
172            ! surface friction
173            ustars2(ji,jj) = rau0r * taum(ji,jj) * tmask(ji,jj,1)
174            !
175            ! bottom friction (explicit before friction)
176            ! Note that we chose here not to bound the friction as in dynbfr)
177            ztx2 = (  bfrua(ji,jj)  * ub(ji,jj,mbku(ji,jj)) + bfrua(ji-1,jj) * ub(ji-1,jj,mbku(ji-1,jj))  )   &
178               & * ( 1._wp - 0.5_wp * umask(ji,jj,1) * umask(ji-1,jj,1)  )
179            zty2 = (  bfrva(ji,jj)  * vb(ji,jj,mbkv(ji,jj)) + bfrva(ji,jj-1) * vb(ji,jj-1,mbkv(ji,jj-1))  )   &
180               & * ( 1._wp - 0.5_wp * vmask(ji,jj,1) * vmask(ji,jj-1,1)  )
181            ustarb2(ji,jj) = SQRT( ztx2 * ztx2 + zty2 * zty2 ) * tmask(ji,jj,1)
182         END DO
183      END DO 
184
185      ! In case of breaking surface waves mixing,
186      ! Compute surface roughness length according to Charnock formula:
187      IF( ln_crban ) THEN   ;   zhsro(:,:) = MAX(rsbc_zs * ustars2(:,:), hsro)
188      ELSE                  ;   zhsro(:,:) = hsro
189      ENDIF
190
191      ! Compute shear and dissipation rate
192      DO jk = 2, jpkm1
193         DO jj = 2, jpjm1
194            DO ji = fs_2, fs_jpim1   ! vector opt.
195               avmu(ji,jj,jk) = avmu(ji,jj,jk) * ( un(ji,jj,jk-1) - un(ji,jj,jk) )   &
196                  &                            * ( ub(ji,jj,jk-1) - ub(ji,jj,jk) )   &
197                  &                            / (  fse3uw_n(ji,jj,jk)               &
198                  &                            *    fse3uw_b(ji,jj,jk) )
199               avmv(ji,jj,jk) = avmv(ji,jj,jk) * ( vn(ji,jj,jk-1) - vn(ji,jj,jk) )   &
200                  &                            * ( vb(ji,jj,jk-1) - vb(ji,jj,jk) )   &
201                  &                            / (  fse3vw_n(ji,jj,jk)               &
202                  &                            *    fse3vw_b(ji,jj,jk) )
203               eps(ji,jj,jk)  = rc03 * en(ji,jj,jk) * SQRT(en(ji,jj,jk)) / mxln(ji,jj,jk)
204            END DO
205         END DO
206      END DO
207      !
208      ! Lateral boundary conditions (avmu,avmv) (sign unchanged)
209      CALL lbc_lnk( avmu, 'U', 1. )   ;   CALL lbc_lnk( avmv, 'V', 1. )
210
211      ! Save tke at before time step
212      eb  (:,:,:) = en  (:,:,:)
213      mxlb(:,:,:) = mxln(:,:,:)
214
215      IF( nn_clos == 0 ) THEN    ! Mellor-Yamada
216         DO jk = 2, jpkm1
217            DO jj = 2, jpjm1 
218               DO ji = fs_2, fs_jpim1   ! vector opt.
219                  zup   = mxln(ji,jj,jk) * fsdepw(ji,jj,mbkt(ji,jj)+1)
220                  zdown = vkarmn * fsdepw(ji,jj,jk) * ( -fsdepw(ji,jj,jk) + fsdepw(ji,jj,mbkt(ji,jj)+1) )
221                  zcoef = ( zup / MAX( zdown, rsmall ) )
222                  zwall (ji,jj,jk) = ( 1._wp + re2 * zcoef*zcoef ) * tmask(ji,jj,jk)
223               END DO
224            END DO
225         END DO
226      ENDIF
227
228      !!---------------------------------!!
229      !!   Equation to prognostic k      !!
230      !!---------------------------------!!
231      !
232      ! Now Turbulent kinetic energy (output in en)
233      ! -------------------------------
234      ! Resolution of a tridiagonal linear system by a "methode de chasse"
235      ! computation from level 2 to jpkm1  (e(1) computed after and e(jpk)=0 ).
236      ! The surface boundary condition are set after
237      ! The bottom boundary condition are also set after. In standard e(bottom)=0.
238      ! z_elem_b : diagonal z_elem_c : upper diagonal z_elem_a : lower diagonal
239      ! Warning : after this step, en : right hand side of the matrix
240
241      DO jk = 2, jpkm1
242         DO jj = 2, jpjm1
243            DO ji = fs_2, fs_jpim1   ! vector opt.
244               !
245               ! shear prod. at w-point weightened by mask
246               shear(ji,jj,jk) =  ( avmu(ji-1,jj,jk) + avmu(ji,jj,jk) ) / MAX( 1.e0 , umask(ji-1,jj,jk) + umask(ji,jj,jk) )   &
247                  &             + ( avmv(ji,jj-1,jk) + avmv(ji,jj,jk) ) / MAX( 1.e0 , vmask(ji,jj-1,jk) + vmask(ji,jj,jk) )
248               !
249               ! stratif. destruction
250               buoy = - avt(ji,jj,jk) * rn2(ji,jj,jk)
251               !
252               ! shear prod. - stratif. destruction
253               diss = eps(ji,jj,jk)
254               !
255               dir = 0.5_wp + SIGN( 0.5_wp, shear(ji,jj,jk) + buoy )   ! dir =1(=0) if shear(ji,jj,jk)+buoy >0(<0)
256               !
257               zesh2 = dir*(shear(ji,jj,jk)+buoy)+(1._wp-dir)*shear(ji,jj,jk)          ! production term
258               zdiss = dir*(diss/en(ji,jj,jk))   +(1._wp-dir)*(diss-buoy)/en(ji,jj,jk) ! dissipation term
259               !
260               ! Compute a wall function from 1. to rsc_psi*zwall/rsc_psi0
261               ! Note that as long that Dirichlet boundary conditions are NOT set at the first and last levels (GOTM style)
262               ! there is no need to set a boundary condition for zwall_psi at the top and bottom boundaries.
263               ! Otherwise, this should be rsc_psi/rsc_psi0
264               IF( ln_sigpsi ) THEN
265                  zsigpsi = MIN( 1._wp, zesh2 / eps(ji,jj,jk) )     ! 0. <= zsigpsi <= 1.
266                  zwall_psi(ji,jj,jk) = rsc_psi /   & 
267                     &     (  zsigpsi * rsc_psi + (1._wp-zsigpsi) * rsc_psi0 / MAX( zwall(ji,jj,jk), 1._wp )  )
268               ELSE
269                  zwall_psi(ji,jj,jk) = 1._wp
270               ENDIF
271               !
272               ! building the matrix
273               zcof = rfact_tke * tmask(ji,jj,jk)
274               !
275               ! lower diagonal
276               z_elem_a(ji,jj,jk) = zcof * ( avm  (ji,jj,jk  ) + avm  (ji,jj,jk-1) )   &
277                  &                      / ( fse3t(ji,jj,jk-1) * fse3w(ji,jj,jk  ) )
278               !
279               ! upper diagonal
280               z_elem_c(ji,jj,jk) = zcof * ( avm  (ji,jj,jk+1) + avm  (ji,jj,jk  ) )   &
281                  &                      / ( fse3t(ji,jj,jk  ) * fse3w(ji,jj,jk) )
282               !
283               ! diagonal
284               z_elem_b(ji,jj,jk) = 1._wp - z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk)  &
285                  &                       + rdt * zdiss * tmask(ji,jj,jk) 
286               !
287               ! right hand side in en
288               en(ji,jj,jk) = en(ji,jj,jk) + rdt * zesh2 * tmask(ji,jj,jk)
289            END DO
290         END DO
291      END DO
292      !
293      z_elem_b(:,:,jpk) = 1._wp
294      !
295      ! Set surface condition on zwall_psi (1 at the bottom)
296      IF( ln_sigpsi ) THEN
297         zcoef = rsc_psi / rsc_psi0
298         DO jj = 2, jpjm1
299            DO ji = fs_2, fs_jpim1   ! vector opt.
300               zwall_psi(ji,jj,1) = zcoef
301            END DO
302         END DO
303      ENDIF
304
305      ! Surface boundary condition on tke
306      ! ---------------------------------
307      !
308      SELECT CASE ( nn_tkebc_surf )
309      !
310      CASE ( 0 )             ! Dirichlet case
311         !
312         IF (ln_crban) THEN     ! Wave induced mixing case
313            !                      ! en(1) = q2(1) = 0.5 * (15.8 * Ccb)^(2/3) * u*^2
314            !                      ! balance between the production and the dissipation terms including the wave effect
315            en(:,:,1) = MAX( rsbc_tke1 * ustars2(:,:), rn_emin )
316            z_elem_a(:,:,1) = en(:,:,1)
317            z_elem_c(:,:,1) = 0._wp
318            z_elem_b(:,:,1) = 1._wp
319            !
320            ! one level below
321            en(:,:,2) = MAX( rsbc_tke1 * ustars2(:,:) * ( (zhsro(:,:)+fsdepw(:,:,2))/zhsro(:,:) )**ra_sf, rn_emin )
322            z_elem_a(:,:,2) = 0._wp
323            z_elem_c(:,:,2) = 0._wp
324            z_elem_b(:,:,2) = 1._wp
325            !
326         ELSE                   ! No wave induced mixing case
327            !                      ! en(1) = u*^2/C0^2  &  l(1)  = K*zs
328            !                      ! balance between the production and the dissipation terms
329            en(:,:,1) = MAX( rc02r * ustars2(:,:), rn_emin )
330            z_elem_a(:,:,1) = en(:,:,1) 
331            z_elem_c(:,:,1) = 0._wp
332            z_elem_b(:,:,1) = 1._wp
333            !
334            ! one level below
335            en(:,:,2) = MAX( rc02r * ustars2(:,:), rn_emin )
336            z_elem_a(:,:,2) = 0._wp
337            z_elem_c(:,:,2) = 0._wp
338            z_elem_b(:,:,2) = 1._wp
339            !
340         ENDIF
341         !
342      CASE ( 1 )             ! Neumann boundary condition on d(e)/dz
343         !
344         IF (ln_crban) THEN ! Shear free case: d(e)/dz= Fw
345            !
346            ! Dirichlet conditions at k=1 (Cosmetic)
347            en(:,:,1) = MAX( rsbc_tke1 * ustars2(:,:), rn_emin )
348            z_elem_a(:,:,1) = en(:,:,1)
349            z_elem_c(:,:,1) = 0._wp
350            z_elem_b(:,:,1) = 1._wp
351            ! at k=2, set de/dz=Fw
352            z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
353            z_elem_a(:,:,2) = 0._wp       
354            zflxs(:,:) = rsbc_tke3 * ustars2(:,:)**1.5_wp * ( (zhsro(:,:)+fsdept(:,:,1) ) / zhsro(:,:) )**(1.5*ra_sf)
355            en(:,:,2) = en(:,:,2) + zflxs(:,:) / fse3w(:,:,2)
356            !
357         ELSE                   ! No wave induced mixing case: d(e)/dz=0.
358            !
359            ! Dirichlet conditions at k=1 (Cosmetic)
360            en(:,:,1) = MAX( rc02r * ustars2(:,:), rn_emin )
361            z_elem_a(:,:,1) = en(:,:,1)
362            z_elem_c(:,:,1) = 0._wp
363            z_elem_b(:,:,1) = 1._wp
364            ! at k=2 set de/dz=0.:
365            z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2)  ! Remove z_elem_a from z_elem_b
366            z_elem_a(:,:,2) = 0._wp
367            !
368         ENDIF
369         !
370      END SELECT
371
372      ! Bottom boundary condition on tke
373      ! --------------------------------
374      !
375      SELECT CASE ( nn_tkebc_bot )
376      !
377      CASE ( 0 )             ! Dirichlet
378         !                      ! en(ibot) = u*^2 / Co2 and mxln(ibot) = rn_lmin
379         !                      ! Balance between the production and the dissipation terms
380!CDIR NOVERRCHK
381         DO jj = 2, jpjm1
382!CDIR NOVERRCHK
383            DO ji = fs_2, fs_jpim1   ! vector opt.
384               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
385               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
386               !
387               ! Bottom level Dirichlet condition:
388               z_elem_a(ji,jj,ibot  ) = 0._wp
389               z_elem_c(ji,jj,ibot  ) = 0._wp
390               z_elem_b(ji,jj,ibot  ) = 1._wp
391               en(ji,jj,ibot  ) = MAX( rc02r * ustarb2(ji,jj), rn_emin )
392               !
393               ! Just above last level, Dirichlet condition again
394               z_elem_a(ji,jj,ibotm1) = 0._wp
395               z_elem_c(ji,jj,ibotm1) = 0._wp
396               z_elem_b(ji,jj,ibotm1) = 1._wp
397               en(ji,jj,ibotm1) = MAX( rc02r * ustarb2(ji,jj), rn_emin ) 
398            END DO
399         END DO
400         !
401      CASE ( 1 )             ! Neumman boundary condition
402         !                     
403!CDIR NOVERRCHK
404         DO jj = 2, jpjm1
405!CDIR NOVERRCHK
406            DO ji = fs_2, fs_jpim1   ! vector opt.
407               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
408               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
409               !
410               ! Bottom level Dirichlet condition:
411               z_elem_a(ji,jj,ibot) = 0._wp
412               z_elem_c(ji,jj,ibot) = 0._wp
413               z_elem_b(ji,jj,ibot) = 1._wp
414               en(ji,jj,ibot) = MAX( rc02r * ustarb2(ji,jj), rn_emin )
415               !
416               ! Just above last level: Neumann condition
417               z_elem_b(ji,jj,ibotm1) = z_elem_b(ji,jj,ibotm1) + z_elem_c(ji,jj,ibotm1)   ! Remove z_elem_c from z_elem_b
418               z_elem_c(ji,jj,ibotm1) = 0._wp
419            END DO
420         END DO
421         !
422      END SELECT
423
424      ! Matrix inversion (en prescribed at surface and the bottom)
425      ! ----------------------------------------------------------
426      !
427      DO jk = 2, jpkm1                             ! First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1
428         DO jj = 2, jpjm1
429            DO ji = fs_2, fs_jpim1    ! vector opt.
430               z_elem_b(ji,jj,jk) = z_elem_b(ji,jj,jk) - z_elem_a(ji,jj,jk) * z_elem_c(ji,jj,jk-1) / z_elem_b(ji,jj,jk-1)
431            END DO
432         END DO
433      END DO
434      DO jk = 2, jpk                               ! Second recurrence : Lk = RHSk - Lk / Dk-1 * Lk-1
435         DO jj = 2, jpjm1
436            DO ji = fs_2, fs_jpim1    ! vector opt.
437               z_elem_a(ji,jj,jk) = en(ji,jj,jk) - z_elem_a(ji,jj,jk) / z_elem_b(ji,jj,jk-1) * z_elem_a(ji,jj,jk-1)
438            END DO
439         END DO
440      END DO
441      DO jk = jpk-1, 2, -1                         ! thrid recurrence : Ek = ( Lk - Uk * Ek+1 ) / Dk
442         DO jj = 2, jpjm1
443            DO ji = fs_2, fs_jpim1    ! vector opt.
444               en(ji,jj,jk) = ( z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk) * en(ji,jj,jk+1) ) / z_elem_b(ji,jj,jk)
445            END DO
446         END DO
447      END DO
448      !                                            ! set the minimum value of tke
449      en(:,:,:) = MAX( en(:,:,:), rn_emin )
450     
451      !!----------------------------------------!!
452      !!   Solve prognostic equation for psi    !!
453      !!----------------------------------------!!
454
455      ! Set psi to previous time step value
456      !
457      SELECT CASE ( nn_clos )
458      !
459      CASE( 0 )               ! k-kl  (Mellor-Yamada)
460         DO jk = 2, jpkm1
461            DO jj = 2, jpjm1
462               DO ji = fs_2, fs_jpim1   ! vector opt.
463                  psi(ji,jj,jk)  = en(ji,jj,jk) * mxln(ji,jj,jk)
464               END DO
465            END DO
466         END DO
467         !
468      CASE( 1 )               ! k-eps
469         DO jk = 2, jpkm1
470            DO jj = 2, jpjm1
471               DO ji = fs_2, fs_jpim1   ! vector opt.
472                  psi(ji,jj,jk)  = eps(ji,jj,jk)
473               END DO
474            END DO
475         END DO
476         !
477      CASE( 2 )               ! k-w
478         DO jk = 2, jpkm1
479            DO jj = 2, jpjm1
480               DO ji = fs_2, fs_jpim1   ! vector opt.
481                  psi(ji,jj,jk)  = SQRT( en(ji,jj,jk) ) / ( rc0 * mxln(ji,jj,jk) )
482               END DO
483            END DO
484         END DO
485         !
486      CASE( 3 )               ! generic
487         DO jk = 2, jpkm1
488            DO jj = 2, jpjm1
489               DO ji = fs_2, fs_jpim1   ! vector opt.
490                  psi(ji,jj,jk)  = rc02 * en(ji,jj,jk) * mxln(ji,jj,jk)**rnn 
491               END DO
492            END DO
493         END DO
494         !
495      END SELECT
496      !
497      ! Now gls (output in psi)
498      ! -------------------------------
499      ! Resolution of a tridiagonal linear system by a "methode de chasse"
500      ! computation from level 2 to jpkm1  (e(1) already computed and e(jpk)=0 ).
501      ! z_elem_b : diagonal z_elem_c : upper diagonal z_elem_a : lower diagonal
502      ! Warning : after this step, en : right hand side of the matrix
503
504      DO jk = 2, jpkm1
505         DO jj = 2, jpjm1
506            DO ji = fs_2, fs_jpim1   ! vector opt.
507               !
508               ! psi / k
509               zratio = psi(ji,jj,jk) / eb(ji,jj,jk) 
510               !
511               ! psi3+ : stable : B=-KhN²<0 => N²>0 if rn2>0 dir = 1 (stable) otherwise dir = 0 (unstable)
512               dir = 0.5_wp + SIGN( 0.5_wp, rn2(ji,jj,jk) )
513               !
514               rpsi3 = dir * rpsi3m + ( 1._wp - dir ) * rpsi3p
515               !
516               ! shear prod. - stratif. destruction
517               prod = rpsi1 * zratio * shear(ji,jj,jk)
518               !
519               ! stratif. destruction
520               buoy = rpsi3 * zratio * (- avt(ji,jj,jk) * rn2(ji,jj,jk) )
521               !
522               ! shear prod. - stratif. destruction
523               diss = rpsi2 * zratio * zwall(ji,jj,jk) * eps(ji,jj,jk)
524               !
525               dir = 0.5_wp + SIGN( 0.5_wp, prod + buoy )   ! dir =1(=0) if shear(ji,jj,jk)+buoy >0(<0)
526               !
527               zesh2 = dir * ( prod + buoy )          + (1._wp - dir ) * prod                        ! production term
528               zdiss = dir * ( diss / psi(ji,jj,jk) ) + (1._wp - dir ) * (diss-buoy) / psi(ji,jj,jk) ! dissipation term
529               !                                                       
530               ! building the matrix
531               zcof = rfact_psi * zwall_psi(ji,jj,jk) * tmask(ji,jj,jk)
532               ! lower diagonal
533               z_elem_a(ji,jj,jk) = zcof * ( avm  (ji,jj,jk  ) + avm  (ji,jj,jk-1) )   &
534                  &                      / ( fse3t(ji,jj,jk-1) * fse3w(ji,jj,jk  ) )
535               ! upper diagonal
536               z_elem_c(ji,jj,jk) = zcof * ( avm  (ji,jj,jk+1) + avm  (ji,jj,jk  ) )   &
537                  &                      / ( fse3t(ji,jj,jk  ) * fse3w(ji,jj,jk) )
538               ! diagonal
539               z_elem_b(ji,jj,jk) = 1._wp - z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk)  &
540                  &                       + rdt * zdiss * tmask(ji,jj,jk)
541               !
542               ! right hand side in psi
543               psi(ji,jj,jk) = psi(ji,jj,jk) + rdt * zesh2 * tmask(ji,jj,jk)
544            END DO
545         END DO
546      END DO
547      !
548      z_elem_b(:,:,jpk) = 1._wp
549
550      ! Surface boundary condition on psi
551      ! ---------------------------------
552      !
553      SELECT CASE ( nn_psibc_surf )
554      !
555      CASE ( 0 )             ! Dirichlet boundary conditions
556         !
557         IF( ln_crban ) THEN       ! Wave induced mixing case
558            !                      ! en(1) = q2(1) = 0.5 * (15.8 * Ccb)^(2/3) * u*^2
559            !                      ! balance between the production and the dissipation terms including the wave effect
560            zdep(:,:) = rl_sf * zhsro(:,:)
561            psi (:,:,1) = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
562            z_elem_a(:,:,1) = psi(:,:,1)
563            z_elem_c(:,:,1) = 0._wp
564            z_elem_b(:,:,1) = 1._wp
565            !
566            ! one level below
567            zex1 = (rmm*ra_sf+rnn)
568            zex2 = (rmm*ra_sf)
569            zdep(:,:) = ( (zhsro(:,:) + fsdepw(:,:,2))**zex1 ) / zhsro(:,:)**zex2
570            psi (:,:,2) = rsbc_psi1 * ustars2(:,:)**rmm * zdep(:,:) * tmask(:,:,1)
571            z_elem_a(:,:,2) = 0._wp
572            z_elem_c(:,:,2) = 0._wp
573            z_elem_b(:,:,2) = 1._wp
574            !
575         ELSE                   ! No wave induced mixing case
576            !                      ! en(1) = u*^2/C0^2  &  l(1)  = K*zs
577            !                      ! balance between the production and the dissipation terms
578            !
579            zdep(:,:) = vkarmn * zhsro(:,:)
580            psi (:,:,1) = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
581            z_elem_a(:,:,1) = psi(:,:,1)
582            z_elem_c(:,:,1) = 0._wp
583            z_elem_b(:,:,1) = 1._wp
584            !
585            ! one level below
586            zdep(:,:) = vkarmn * ( zhsro(:,:) + fsdepw(:,:,2) )
587            psi (:,:,2) = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
588            z_elem_a(:,:,2) = 0._wp
589            z_elem_c(:,:,2) = 0._wp
590            z_elem_b(:,:,2) = 1.
591            !
592         ENDIF
593         !
594      CASE ( 1 )             ! Neumann boundary condition on d(psi)/dz
595         !
596         IF( ln_crban ) THEN     ! Wave induced mixing case
597            !
598            zdep(:,:) = rl_sf * zhsro(:,:)
599            psi (:,:,1) = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
600            z_elem_a(:,:,1) = psi(:,:,1)
601            z_elem_c(:,:,1) = 0._wp
602            z_elem_b(:,:,1) = 1._wp
603            !
604            ! Neumann condition at k=2
605            z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
606            z_elem_a(:,:,2) = 0._wp
607            !
608            ! Set psi vertical flux at the surface:
609            zdep(:,:) = (zhsro(:,:) + fsdept(:,:,1))**(rmm*ra_sf+rnn-1._wp) / zhsro(:,:)**(rmm*ra_sf)
610            zflxs(:,:) = rsbc_psi3 * ( zwall_psi(:,:,1)*avm(:,:,1) + zwall_psi(:,:,2)*avm(:,:,2) ) & 
611               &                   * en(:,:,1)**rmm * zdep         
612            psi(:,:,2) = psi(:,:,2) + zflxs(:,:) / fse3w(:,:,2)
613            !
614      ELSE                   ! No wave induced mixing
615            !
616            zdep(:,:) = vkarmn * zhsro(:,:)
617            psi (:,:,1) = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
618            z_elem_a(:,:,1) = psi(:,:,1)
619            z_elem_c(:,:,1) = 0._wp
620            z_elem_b(:,:,1) = 1._wp
621            !
622            ! Neumann condition at k=2
623            z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
624            z_elem_a(ji,jj,2) = 0._wp
625            !
626            ! Set psi vertical flux at the surface:
627            zdep(:,:)  = zhsro(:,:) + fsdept(:,:,1)
628            zflxs(:,:) = rsbc_psi2 * ( avm(:,:,1) + avm(:,:,2) ) * en(:,:,1)**rmm * zdep**(rnn-1._wp)
629            psi(:,:,2) = psi(:,:,2) + zflxs(:,:) / fse3w(:,:,2)
630            !     
631         ENDIF
632         !
633      END SELECT
634
635      ! Bottom boundary condition on psi
636      ! --------------------------------
637      !
638      SELECT CASE ( nn_psibc_bot )
639      !
640      CASE ( 0 )             ! Dirichlet
641         !                      ! en(ibot) = u*^2 / Co2 and mxln(ibot) = vkarmn * hbro
642         !                      ! Balance between the production and the dissipation terms
643!CDIR NOVERRCHK
644         DO jj = 2, jpjm1
645!CDIR NOVERRCHK
646            DO ji = fs_2, fs_jpim1   ! vector opt.
647               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
648               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
649               zdep(ji,jj) = vkarmn * hbro
650               psi (ji,jj,ibot) = rc0**rpp * en(ji,jj,ibot)**rmm * zdep(ji,jj)**rnn
651               z_elem_a(ji,jj,ibot) = 0._wp
652               z_elem_c(ji,jj,ibot) = 0._wp
653               z_elem_b(ji,jj,ibot) = 1._wp
654               !
655               ! Just above last level, Dirichlet condition again (GOTM like)
656               zdep(ji,jj) = vkarmn * ( hbro + fse3t(ji,jj,ibotm1) )
657               psi (ji,jj,ibotm1) = rc0**rpp * en(ji,jj,ibot  )**rmm * zdep(ji,jj)**rnn
658               z_elem_a(ji,jj,ibotm1) = 0._wp
659               z_elem_c(ji,jj,ibotm1) = 0._wp
660               z_elem_b(ji,jj,ibotm1) = 1._wp
661            END DO
662         END DO
663         !
664      CASE ( 1 )             ! Neumman boundary condition
665         !                     
666!CDIR NOVERRCHK
667         DO jj = 2, jpjm1
668!CDIR NOVERRCHK
669            DO ji = fs_2, fs_jpim1   ! vector opt.
670               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
671               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
672               !
673               ! Bottom level Dirichlet condition:
674               zdep(ji,jj) = vkarmn * hbro
675               psi (ji,jj,ibot) = rc0**rpp * en(ji,jj,ibot)**rmm * zdep(ji,jj)**rnn
676               !
677               z_elem_a(ji,jj,ibot) = 0._wp
678               z_elem_c(ji,jj,ibot) = 0._wp
679               z_elem_b(ji,jj,ibot) = 1._wp
680               !
681               ! Just above last level: Neumann condition with flux injection
682               z_elem_b(ji,jj,ibotm1) = z_elem_b(ji,jj,ibotm1) + z_elem_c(ji,jj,ibotm1) ! Remove z_elem_c from z_elem_b
683               z_elem_c(ji,jj,ibotm1) = 0.
684               !
685               ! Set psi vertical flux at the bottom:
686               zdep(ji,jj) = hbro + 0.5_wp*fse3t(ji,jj,ibotm1)
687               zflxb = rsbc_psi2 * ( avm(ji,jj,ibot) + avm(ji,jj,ibotm1) )   &
688                  &  * (0.5_wp*(en(ji,jj,ibot)+en(ji,jj,ibotm1)))**rmm * zdep(ji,jj)**(rnn-1._wp)
689               psi(ji,jj,ibotm1) = psi(ji,jj,ibotm1) + zflxb / fse3w(ji,jj,ibotm1)
690            END DO
691         END DO
692         !
693      END SELECT
694
695      ! Matrix inversion
696      ! ----------------
697      !
698      DO jk = 2, jpkm1                             ! First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1
699         DO jj = 2, jpjm1
700            DO ji = fs_2, fs_jpim1    ! vector opt.
701               z_elem_b(ji,jj,jk) = z_elem_b(ji,jj,jk) - z_elem_a(ji,jj,jk) * z_elem_c(ji,jj,jk-1) / z_elem_b(ji,jj,jk-1)
702            END DO
703         END DO
704      END DO
705      DO jk = 2, jpk                               ! Second recurrence : Lk = RHSk - Lk / Dk-1 * Lk-1
706         DO jj = 2, jpjm1
707            DO ji = fs_2, fs_jpim1    ! vector opt.
708               z_elem_a(ji,jj,jk) = psi(ji,jj,jk) - z_elem_a(ji,jj,jk) / z_elem_b(ji,jj,jk-1) * z_elem_a(ji,jj,jk-1)
709            END DO
710         END DO
711      END DO
712      DO jk = jpk-1, 2, -1                         ! Third recurrence : Ek = ( Lk - Uk * Ek+1 ) / Dk
713         DO jj = 2, jpjm1
714            DO ji = fs_2, fs_jpim1    ! vector opt.
715               psi(ji,jj,jk) = ( z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk) * psi(ji,jj,jk+1) ) / z_elem_b(ji,jj,jk)
716            END DO
717         END DO
718      END DO
719
720      ! Set dissipation
721      !----------------
722
723      SELECT CASE ( nn_clos )
724      !
725      CASE( 0 )               ! k-kl  (Mellor-Yamada)
726         DO jk = 1, jpkm1
727            DO jj = 2, jpjm1
728               DO ji = fs_2, fs_jpim1   ! vector opt.
729                  eps(ji,jj,jk) = rc03 * en(ji,jj,jk) * en(ji,jj,jk) * SQRT( en(ji,jj,jk) ) / psi(ji,jj,jk)
730               END DO
731            END DO
732         END DO
733         !
734      CASE( 1 )               ! k-eps
735         DO jk = 1, jpkm1
736            DO jj = 2, jpjm1
737               DO ji = fs_2, fs_jpim1   ! vector opt.
738                  eps(ji,jj,jk) = psi(ji,jj,jk)
739               END DO
740            END DO
741         END DO
742         !
743      CASE( 2 )               ! k-w
744         DO jk = 1, jpkm1
745            DO jj = 2, jpjm1
746               DO ji = fs_2, fs_jpim1   ! vector opt.
747                  eps(ji,jj,jk) = rc04 * en(ji,jj,jk) * psi(ji,jj,jk) 
748               END DO
749            END DO
750         END DO
751         !
752      CASE( 3 )               ! generic
753         zcoef = rc0**( 3._wp  + rpp/rnn )
754         zex1  =      ( 1.5_wp + rmm/rnn )
755         zex2  = -1._wp / rnn
756         DO jk = 1, jpkm1
757            DO jj = 2, jpjm1
758               DO ji = fs_2, fs_jpim1   ! vector opt.
759                  eps(ji,jj,jk) = zcoef * en(ji,jj,jk)**zex1 * psi(ji,jj,jk)**zex2
760               END DO
761            END DO
762         END DO
763         !
764      END SELECT
765
766      ! Limit dissipation rate under stable stratification
767      ! --------------------------------------------------
768      DO jk = 1, jpkm1 ! Note that this set boundary conditions on mxln at the same time
769         DO jj = 2, jpjm1
770            DO ji = fs_2, fs_jpim1    ! vector opt.
771               ! limitation
772               eps(ji,jj,jk)  = MAX( eps(ji,jj,jk), rn_epsmin )
773               mxln(ji,jj,jk)  = rc03 * en(ji,jj,jk) * SQRT( en(ji,jj,jk) ) / eps(ji,jj,jk)
774               ! Galperin criterium (NOTE : Not required if the proper value of C3 in stable cases is calculated)
775               zrn2 = MAX( rn2(ji,jj,jk), rsmall )
776               mxln(ji,jj,jk) = MIN(  rn_clim_galp * SQRT( 2._wp * en(ji,jj,jk) / zrn2 ), mxln(ji,jj,jk)  )
777            END DO
778         END DO
779      END DO 
780
781      !
782      ! Stability function and vertical viscosity and diffusivity
783      ! ---------------------------------------------------------
784      !
785      SELECT CASE ( nn_stab_func )
786      !
787      CASE ( 0 , 1 )             ! Galperin or Kantha-Clayson stability functions
788         DO jk = 2, jpkm1
789            DO jj = 2, jpjm1
790               DO ji = fs_2, fs_jpim1   ! vector opt.
791                  ! zcof =  l²/q²
792                  zcof = mxlb(ji,jj,jk) * mxlb(ji,jj,jk) / ( 2._wp*eb(ji,jj,jk) )
793                  ! Gh = -N²l²/q²
794                  gh = - rn2(ji,jj,jk) * zcof
795                  gh = MIN( gh, rgh0   )
796                  gh = MAX( gh, rghmin )
797                  ! Stability functions from Kantha and Clayson (if C2=C3=0 => Galperin)
798                  sh = ra2*( 1._wp-6._wp*ra1/rb1 ) / ( 1.-3.*ra2*gh*(6.*ra1+rb2*( 1._wp-rc3 ) ) )
799                  sm = ( rb1**(-1._wp/3._wp) + ( 18._wp*ra1*ra1 + 9._wp*ra1*ra2*(1._wp-rc2) )*sh*gh ) / (1._wp-9._wp*ra1*ra2*gh)
800                  !
801                  ! Store stability function in avmu and avmv
802                  avmu(ji,jj,jk) = rc_diff * sh * tmask(ji,jj,jk)
803                  avmv(ji,jj,jk) = rc_diff * sm * tmask(ji,jj,jk)
804               END DO
805            END DO
806         END DO
807         !
808      CASE ( 2, 3 )               ! Canuto stability functions
809         DO jk = 2, jpkm1
810            DO jj = 2, jpjm1
811               DO ji = fs_2, fs_jpim1   ! vector opt.
812                  ! zcof =  l²/q²
813                  zcof = mxlb(ji,jj,jk)*mxlb(ji,jj,jk) / ( 2._wp * eb(ji,jj,jk) )
814                  ! Gh = -N²l²/q²
815                  gh = - rn2(ji,jj,jk) * zcof
816                  gh = MIN( gh, rgh0   )
817                  gh = MAX( gh, rghmin )
818                  gh = gh * rf6
819                  ! Gm =  M²l²/q² Shear number
820                  shr = shear(ji,jj,jk) / MAX( avm(ji,jj,jk), rsmall )
821                  gm = MAX( shr * zcof , 1.e-10 )
822                  gm = gm * rf6
823                  gm = MIN ( (rd0 - rd1*gh + rd3*gh*gh) / (rd2-rd4*gh) , gm )
824                  ! Stability functions from Canuto
825                  rcff = rd0 - rd1*gh +rd2*gm + rd3*gh*gh - rd4*gh*gm + rd5*gm*gm
826                  sm = (rs0 - rs1*gh + rs2*gm) / rcff
827                  sh = (rs4 - rs5*gh + rs6*gm) / rcff
828                  !
829                  ! Store stability function in avmu and avmv
830                  avmu(ji,jj,jk) = rc_diff * sh * tmask(ji,jj,jk)
831                  avmv(ji,jj,jk) = rc_diff * sm * tmask(ji,jj,jk)
832               END DO
833            END DO
834         END DO
835         !
836      END SELECT
837
838      ! Boundary conditions on stability functions for momentum (Neumann):
839      ! Lines below are useless if GOTM style Dirichlet conditions are used
840      zcoef = rcm_sf / SQRT( 2._wp )
841      DO jj = 2, jpjm1
842         DO ji = fs_2, fs_jpim1   ! vector opt.
843            avmv(ji,jj,1) = zcoef
844         END DO
845      END DO
846      zcoef = rc0 / SQRT( 2._wp )
847      DO jj = 2, jpjm1
848         DO ji = fs_2, fs_jpim1   ! vector opt.
849            avmv(ji,jj,mbkt(ji,jj)+1) = zcoef
850         END DO
851      END DO
852
853      ! Compute diffusivities/viscosities
854      ! The computation below could be restrained to jk=2 to jpkm1 if GOTM style Dirichlet conditions are used
855      DO jk = 1, jpk
856         DO jj = 2, jpjm1
857            DO ji = fs_2, fs_jpim1   ! vector opt.
858               zsqen         = SQRT( 2._wp * en(ji,jj,jk) ) * mxln(ji,jj,jk)
859               zav           = zsqen * avmu(ji,jj,jk)
860               avt(ji,jj,jk) = MAX( zav, avtb(jk) )*tmask(ji,jj,jk) ! apply mask for zdfmxl routine
861               zav           = zsqen * avmv(ji,jj,jk)
862               avm(ji,jj,jk) = MAX( zav, avmb(jk) ) ! Note that avm is not masked at the surface and the bottom
863            END DO
864         END DO
865      END DO
866      !
867      ! Lateral boundary conditions (sign unchanged)
868      avt(:,:,1)  = 0._wp
869      CALL lbc_lnk( avm, 'W', 1. )   ;   CALL lbc_lnk( avt, 'W', 1. )
870
871      DO jk = 2, jpkm1            !* vertical eddy viscosity at u- and v-points
872         DO jj = 2, jpjm1
873            DO ji = fs_2, fs_jpim1   ! vector opt.
874               avmu(ji,jj,jk) = 0.5 * ( avm(ji,jj,jk) + avm(ji+1,jj  ,jk) ) * umask(ji,jj,jk)
875               avmv(ji,jj,jk) = 0.5 * ( avm(ji,jj,jk) + avm(ji  ,jj+1,jk) ) * vmask(ji,jj,jk)
876            END DO
877         END DO
878      END DO
879      avmu(:,:,1) = 0._wp             ;   avmv(:,:,1) = 0._wp                 ! set surface to zero
880      CALL lbc_lnk( avmu, 'U', 1. )   ;   CALL lbc_lnk( avmv, 'V', 1. )       ! Lateral boundary conditions
881
882      IF(ln_ctl) THEN
883         CALL prt_ctl( tab3d_1=en  , clinfo1=' gls  - e: ', tab3d_2=avt, clinfo2=' t: ', ovlap=1, kdim=jpk)
884         CALL prt_ctl( tab3d_1=avmu, clinfo1=' gls  - u: ', mask1=umask,                   &
885            &          tab3d_2=avmv, clinfo2=       ' v: ', mask2=vmask, ovlap=1, kdim=jpk )
886      ENDIF
887      !
888      CALL wrk_dealloc( jpi,jpj, zdep, zflxs, zhsro )
889      CALL wrk_dealloc( jpi,jpj,jpk, eb, mxlb, shear, eps, zwall_psi )
890      !
891   END SUBROUTINE zdf_gls
892
893
894   SUBROUTINE zdf_gls_init
895      !!----------------------------------------------------------------------
896      !!                  ***  ROUTINE zdf_gls_init  ***
897      !!                     
898      !! ** Purpose :   Initialization of the vertical eddy diffivity and
899      !!      viscosity when using a gls turbulent closure scheme
900      !!
901      !! ** Method  :   Read the namzdf_gls namelist and check the parameters
902      !!      called at the first timestep (nit000)
903      !!
904      !! ** input   :   Namlist namzdf_gls
905      !!
906      !! ** Action  :   Increase by 1 the nstop flag is setting problem encounter
907      !!
908      !!----------------------------------------------------------------------
909      USE dynzdf_exp
910      USE trazdf_exp
911      !
912      INTEGER ::   jk    ! dummy loop indices
913      REAL(wp)::   zcr   ! local scalar
914      !!
915      NAMELIST/namzdf_gls/rn_emin, rn_epsmin, ln_length_lim, &
916         &            rn_clim_galp, ln_crban, ln_sigpsi,     &
917         &            rn_crban, rn_charn,                    &
918         &            nn_tkebc_surf, nn_tkebc_bot,           &
919         &            nn_psibc_surf, nn_psibc_bot,           &
920         &            nn_stab_func, nn_clos
921      !!----------------------------------------------------------
922
923      REWIND( numnam )                 !* Read Namelist namzdf_gls
924      READ  ( numnam, namzdf_gls )
925
926      IF(lwp) THEN                     !* Control print
927         WRITE(numout,*)
928         WRITE(numout,*) 'zdf_gls_init : gls turbulent closure scheme'
929         WRITE(numout,*) '~~~~~~~~~~~~'
930         WRITE(numout,*) '   Namelist namzdf_gls : set gls mixing parameters'
931         WRITE(numout,*) '      minimum value of en                           rn_emin       = ', rn_emin
932         WRITE(numout,*) '      minimum value of eps                          rn_epsmin     = ', rn_epsmin
933         WRITE(numout,*) '      Limit dissipation rate under stable stratif.  ln_length_lim = ', ln_length_lim
934         WRITE(numout,*) '      Galperin limit (Standard: 0.53, Holt: 0.26)   rn_clim_galp  = ', rn_clim_galp
935         WRITE(numout,*) '      TKE Surface boundary condition                nn_tkebc_surf = ', nn_tkebc_surf
936         WRITE(numout,*) '      TKE Bottom boundary condition                 nn_tkebc_bot  = ', nn_tkebc_bot
937         WRITE(numout,*) '      PSI Surface boundary condition                nn_psibc_surf = ', nn_psibc_surf
938         WRITE(numout,*) '      PSI Bottom boundary condition                 nn_psibc_bot  = ', nn_psibc_bot
939         WRITE(numout,*) '      Craig and Banner scheme                       ln_crban      = ', ln_crban
940         WRITE(numout,*) '      Modify psi Schmidt number (wb case)           ln_sigpsi     = ', ln_sigpsi
941         WRITE(numout,*) '      Craig and Banner coefficient                  rn_crban       = ', rn_crban
942         WRITE(numout,*) '      Charnock coefficient                          rn_charn       = ', rn_charn
943         WRITE(numout,*) '      Stability functions                           nn_stab_func   = ', nn_stab_func
944         WRITE(numout,*) '      Type of closure                               nn_clos        = ', nn_clos
945         WRITE(numout,*) '   Hard coded parameters'
946         WRITE(numout,*) '      Surface roughness (m)                         hsro          = ', hsro
947         WRITE(numout,*) '      Bottom roughness (m)                          hbro          = ', hbro
948      ENDIF
949
950      !                                !* allocate gls arrays
951      IF( zdf_gls_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'zdf_gls_init : unable to allocate arrays' )
952
953      !                                !* Check of some namelist values
954      IF( nn_tkebc_surf < 0 .OR. nn_tkebc_surf > 1 ) CALL ctl_stop( 'bad flag: nn_tkebc_surf is 0 or 1' )
955      IF( nn_psibc_surf < 0 .OR. nn_psibc_surf > 1 ) CALL ctl_stop( 'bad flag: nn_psibc_surf is 0 or 1' )
956      IF( nn_tkebc_bot  < 0 .OR. nn_tkebc_bot  > 1 ) CALL ctl_stop( 'bad flag: nn_tkebc_bot is 0 or 1' )
957      IF( nn_psibc_bot  < 0 .OR. nn_psibc_bot  > 1 ) CALL ctl_stop( 'bad flag: nn_psibc_bot is 0 or 1' )
958      IF( nn_stab_func  < 0 .OR. nn_stab_func  > 3 ) CALL ctl_stop( 'bad flag: nn_stab_func is 0, 1, 2 and 3' )
959      IF( nn_clos       < 0 .OR. nn_clos       > 3 ) CALL ctl_stop( 'bad flag: nn_clos is 0, 1, 2 or 3' )
960
961      SELECT CASE ( nn_clos )          !* set the parameters for the chosen closure
962      !
963      CASE( 0 )                              ! k-kl  (Mellor-Yamada)
964         !
965         IF(lwp) WRITE(numout,*) 'The choosen closure is k-kl closed to the classical Mellor-Yamada'
966         rpp     = 0._wp
967         rmm     = 1._wp
968         rnn     = 1._wp
969         rsc_tke = 1.96_wp
970         rsc_psi = 1.96_wp
971         rpsi1   = 0.9_wp
972         rpsi3p  = 1._wp
973         rpsi2   = 0.5_wp
974         !
975         SELECT CASE ( nn_stab_func )
976         CASE( 0, 1 )   ;   rpsi3m = 2.53_wp       ! G88 or KC stability functions
977         CASE( 2 )      ;   rpsi3m = 2.38_wp       ! Canuto A stability functions
978         CASE( 3 )      ;   rpsi3m = 2.38          ! Canuto B stability functions (caution : constant not identified)
979         END SELECT
980         !
981      CASE( 1 )                              ! k-eps
982         !
983         IF(lwp) WRITE(numout,*) 'The choosen closure is k-eps'
984         rpp     =  3._wp
985         rmm     =  1.5_wp
986         rnn     = -1._wp
987         rsc_tke =  1._wp
988         rsc_psi =  1.3_wp  ! Schmidt number for psi
989         rpsi1   =  1.44_wp
990         rpsi3p  =  1._wp
991         rpsi2   =  1.92_wp
992         !
993         SELECT CASE ( nn_stab_func )
994         CASE( 0, 1 )   ;   rpsi3m = -0.52_wp      ! G88 or KC stability functions
995         CASE( 2 )      ;   rpsi3m = -0.629_wp     ! Canuto A stability functions
996         CASE( 3 )      ;   rpsi3m = -0.566        ! Canuto B stability functions
997         END SELECT
998         !
999      CASE( 2 )                              ! k-omega
1000         !
1001         IF(lwp) WRITE(numout,*) 'The choosen closure is k-omega'
1002         rpp     = -1._wp
1003         rmm     =  0.5_wp
1004         rnn     = -1._wp
1005         rsc_tke =  2._wp
1006         rsc_psi =  2._wp
1007         rpsi1   =  0.555_wp
1008         rpsi3p  =  1._wp
1009         rpsi2   =  0.833_wp
1010         !
1011         SELECT CASE ( nn_stab_func )
1012         CASE( 0, 1 )   ;   rpsi3m = -0.58_wp       ! G88 or KC stability functions
1013         CASE( 2 )      ;   rpsi3m = -0.64_wp       ! Canuto A stability functions
1014         CASE( 3 )      ;   rpsi3m = -0.64_wp       ! Canuto B stability functions caution : constant not identified)
1015         END SELECT
1016         !
1017      CASE( 3 )                              ! generic
1018         !
1019         IF(lwp) WRITE(numout,*) 'The choosen closure is generic'
1020         rpp     = 2._wp
1021         rmm     = 1._wp
1022         rnn     = -0.67_wp
1023         rsc_tke = 0.8_wp
1024         rsc_psi = 1.07_wp
1025         rpsi1   = 1._wp
1026         rpsi3p  = 1._wp
1027         rpsi2   = 1.22_wp
1028         !
1029         SELECT CASE ( nn_stab_func )
1030         CASE( 0, 1 )   ;   rpsi3m = 0.1_wp         ! G88 or KC stability functions
1031         CASE( 2 )      ;   rpsi3m = 0.05_wp        ! Canuto A stability functions
1032         CASE( 3 )      ;   rpsi3m = 0.05_wp        ! Canuto B stability functions caution : constant not identified)
1033         END SELECT
1034         !
1035      END SELECT
1036
1037      !
1038      SELECT CASE ( nn_stab_func )     !* set the parameters of the stability functions
1039      !
1040      CASE ( 0 )                             ! Galperin stability functions
1041         !
1042         IF(lwp) WRITE(numout,*) 'Stability functions from Galperin'
1043         rc2     =  0._wp
1044         rc3     =  0._wp
1045         rc_diff =  1._wp
1046         rc0     =  0.5544_wp
1047         rcm_sf  =  0.9884_wp
1048         rghmin  = -0.28_wp
1049         rgh0    =  0.0233_wp
1050         rghcri  =  0.02_wp
1051         !
1052      CASE ( 1 )                             ! Kantha-Clayson stability functions
1053         !
1054         IF(lwp) WRITE(numout,*) 'Stability functions from Kantha-Clayson'
1055         rc2     =  0.7_wp
1056         rc3     =  0.2_wp
1057         rc_diff =  1._wp
1058         rc0     =  0.5544_wp
1059         rcm_sf  =  0.9884_wp
1060         rghmin  = -0.28_wp
1061         rgh0    =  0.0233_wp
1062         rghcri  =  0.02_wp
1063         !
1064      CASE ( 2 )                             ! Canuto A stability functions
1065         !
1066         IF(lwp) WRITE(numout,*) 'Stability functions from Canuto A'
1067         rs0 = 1.5_wp * rl1 * rl5*rl5
1068         rs1 = -rl4*(rl6+rl7) + 2._wp*rl4*rl5*(rl1-(1._wp/3._wp)*rl2-rl3) + 1.5_wp*rl1*rl5*rl8
1069         rs2 = -(3._wp/8._wp) * rl1*(rl6*rl6-rl7*rl7)
1070         rs4 = 2._wp * rl5
1071         rs5 = 2._wp * rl4
1072         rs6 = (2._wp/3._wp) * rl5 * ( 3._wp*rl3*rl3 - rl2*rl2 ) - 0.5_wp * rl5*rl1 * (3._wp*rl3-rl2)   &
1073            &                                                    + 0.75_wp * rl1 * ( rl6 - rl7 )
1074         rd0 = 3._wp * rl5*rl5
1075         rd1 = rl5 * ( 7._wp*rl4 + 3._wp*rl8 )
1076         rd2 = rl5*rl5 * ( 3._wp*rl3*rl3 - rl2*rl2 ) - 0.75_wp*(rl6*rl6 - rl7*rl7 )
1077         rd3 = rl4 * ( 4._wp*rl4 + 3._wp*rl8)
1078         rd4 = rl4 * ( rl2 * rl6 - 3._wp*rl3*rl7 - rl5*(rl2*rl2 - rl3*rl3 ) ) + rl5*rl8 * ( 3._wp*rl3*rl3 - rl2*rl2 )
1079         rd5 = 0.25_wp * ( rl2*rl2 - 3._wp *rl3*rl3 ) * ( rl6*rl6 - rl7*rl7 )
1080         rc0 = 0.5268_wp
1081         rf6 = 8._wp / (rc0**6._wp)
1082         rc_diff = SQRT(2._wp) / (rc0**3._wp)
1083         rcm_sf  =  0.7310_wp
1084         rghmin  = -0.28_wp
1085         rgh0    =  0.0329_wp
1086         rghcri  =  0.03_wp
1087         !
1088      CASE ( 3 )                             ! Canuto B stability functions
1089         !
1090         IF(lwp) WRITE(numout,*) 'Stability functions from Canuto B'
1091         rs0 = 1.5_wp * rm1 * rm5*rm5
1092         rs1 = -rm4 * (rm6+rm7) + 2._wp * rm4*rm5*(rm1-(1._wp/3._wp)*rm2-rm3) + 1.5_wp * rm1*rm5*rm8
1093         rs2 = -(3._wp/8._wp) * rm1 * (rm6*rm6-rm7*rm7 )
1094         rs4 = 2._wp * rm5
1095         rs5 = 2._wp * rm4
1096         rs6 = (2._wp/3._wp) * rm5 * (3._wp*rm3*rm3-rm2*rm2) - 0.5_wp * rm5*rm1*(3._wp*rm3-rm2) + 0.75_wp * rm1*(rm6-rm7)
1097         rd0 = 3._wp * rm5*rm5
1098         rd1 = rm5 * (7._wp*rm4 + 3._wp*rm8)
1099         rd2 = rm5*rm5 * (3._wp*rm3*rm3 - rm2*rm2) - 0.75_wp * (rm6*rm6 - rm7*rm7)
1100         rd3 = rm4 * ( 4._wp*rm4 + 3._wp*rm8 )
1101         rd4 = rm4 * ( rm2*rm6 -3._wp*rm3*rm7 - rm5*(rm2*rm2 - rm3*rm3) ) + rm5 * rm8 * ( 3._wp*rm3*rm3 - rm2*rm2 )
1102         rd5 = 0.25_wp * ( rm2*rm2 - 3._wp*rm3*rm3 ) * ( rm6*rm6 - rm7*rm7 )
1103         rc0 = 0.5268_wp            !!       rc0 = 0.5540_wp (Warner ...) to verify !
1104         rf6 = 8._wp / ( rc0**6._wp )
1105         rc_diff = SQRT(2._wp)/(rc0**3.)
1106         rcm_sf  =  0.7470_wp
1107         rghmin  = -0.28_wp
1108         rgh0    =  0.0444_wp
1109         rghcri  =  0.0414_wp
1110         !
1111      END SELECT
1112   
1113      !                                !* Set Schmidt number for psi diffusion in the wave breaking case
1114      !                                     ! See Eq. (13) of Carniel et al, OM, 30, 225-239, 2009
1115      !                                     !  or Eq. (17) of Burchard, JPO, 31, 3133-3145, 2001
1116      IF( ln_sigpsi .AND. ln_crban ) THEN
1117         zcr = SQRT( 1.5_wp*rsc_tke ) * rcm_sf / vkarmn
1118         rsc_psi0 = vkarmn*vkarmn / ( rpsi2 * rcm_sf*rcm_sf )                       & 
1119        &         * ( rnn*rnn - 4._wp/3._wp * zcr*rnn*rmm - 1._wp/3._wp * zcr*rnn   &
1120        &           + 2._wp/9._wp * rmm * zcr*zcr + 4._wp/9._wp * zcr*zcr * rmm*rmm )                                 
1121      ELSE
1122         rsc_psi0 = rsc_psi
1123      ENDIF
1124 
1125      !                                !* Shear free turbulence parameters
1126      !
1127      ra_sf  = -4._wp * rnn * SQRT( rsc_tke ) / ( (1._wp+4._wp*rmm) * SQRT( rsc_tke )   &
1128         &                                      - SQRT(rsc_tke + 24._wp*rsc_psi0*rpsi2 ) )
1129      rl_sf  = rc0 * SQRT( rc0 / rcm_sf )                                                                   &
1130         &         * SQRT(  (  (1._wp + 4._wp*rmm + 8._wp*rmm*rmm) * rsc_tke                                &
1131         &                   + 12._wp * rsc_psi0 * rpsi2                                                    &
1132         &                   - (1._wp + 4._wp*rmm) * SQRT( rsc_tke*(rsc_tke+ 24._wp*rsc_psi0*rpsi2) )  )    &
1133         &                / ( 12._wp*rnn*rnn )                                                              )
1134
1135      !
1136      IF(lwp) THEN                     !* Control print
1137         WRITE(numout,*)
1138         WRITE(numout,*) 'Limit values'
1139         WRITE(numout,*) '~~~~~~~~~~~~'
1140         WRITE(numout,*) 'Parameter  m = ',rmm
1141         WRITE(numout,*) 'Parameter  n = ',rnn
1142         WRITE(numout,*) 'Parameter  p = ',rpp
1143         WRITE(numout,*) 'rpsi1   = ',rpsi1
1144         WRITE(numout,*) 'rpsi2   = ',rpsi2
1145         WRITE(numout,*) 'rpsi3m  = ',rpsi3m
1146         WRITE(numout,*) 'rpsi3p  = ',rpsi3p
1147         WRITE(numout,*) 'rsc_tke = ',rsc_tke
1148         WRITE(numout,*) 'rsc_psi = ',rsc_psi
1149         WRITE(numout,*) 'rsc_psi0 = ',rsc_psi0
1150         WRITE(numout,*) 'rc0     = ',rc0
1151         WRITE(numout,*)
1152         WRITE(numout,*) 'Shear free turbulence parameters:'
1153         WRITE(numout,*) 'rcm_sf  = ',rcm_sf
1154         WRITE(numout,*) 'ra_sf   = ',ra_sf
1155         WRITE(numout,*) 'rl_sf   = ',rl_sf
1156         WRITE(numout,*)
1157      ENDIF
1158
1159      !                                !* Constants initialization
1160      rc02  = rc0  * rc0   ;   rc02r = 1. / rc02
1161      rc03  = rc02 * rc0
1162      rc04  = rc03 * rc0
1163      rc03_sqrt2_galp = rc03 / SQRT(2._wp) / rn_clim_galp
1164      rsbc_mb   = 0.5_wp * (15.8_wp*rn_crban)**(2._wp/3._wp)               ! Surf. bound. cond. from Mellor and Blumberg
1165      rsbc_std  = 3.75_wp                                                  ! Surf. bound. cond. standard (prod=diss)
1166      rsbc_tke1 = (-rsc_tke*rn_crban/(rcm_sf*ra_sf*rl_sf))**(2._wp/3._wp)  ! k_eps = 53.  Dirichlet + Wave breaking
1167      rsbc_tke2 = 0.5_wp / rau0
1168      rsbc_tke3 = rdt * rn_crban                                                         ! Neumann + Wave breaking
1169      rsbc_zs   = rn_charn / grav                                                        ! Charnock formula
1170      rsbc_psi1 = rc0**rpp * rsbc_tke1**rmm * rl_sf**rnn                           ! Dirichlet + Wave breaking
1171      rsbc_psi2 = -0.5_wp * rdt * rc0**rpp * rnn * vkarmn**rnn / rsc_psi                   ! Neumann + NO Wave breaking
1172      rsbc_psi3 = -0.5_wp * rdt * rc0**rpp * rl_sf**rnn / rsc_psi  * (rnn + rmm*ra_sf) ! Neumann + Wave breaking
1173      rfact_tke = -0.5_wp / rsc_tke * rdt               ! Cst used for the Diffusion term of tke
1174      rfact_psi = -0.5_wp / rsc_psi * rdt               ! Cst used for the Diffusion term of tke
1175
1176      !                                !* Wall proximity function
1177      zwall (:,:,:) = 1._wp * tmask(:,:,:)
1178
1179      !                                !* set vertical eddy coef. to the background value
1180      DO jk = 1, jpk
1181         avt (:,:,jk) = avtb(jk) * tmask(:,:,jk)
1182         avm (:,:,jk) = avmb(jk) * tmask(:,:,jk)
1183         avmu(:,:,jk) = avmb(jk) * umask(:,:,jk)
1184         avmv(:,:,jk) = avmb(jk) * vmask(:,:,jk)
1185      END DO
1186      !                             
1187      CALL gls_rst( nit000, 'READ' )   !* read or initialize all required files
1188      !
1189   END SUBROUTINE zdf_gls_init
1190
1191
1192   SUBROUTINE gls_rst( kt, cdrw )
1193      !!---------------------------------------------------------------------
1194      !!                   ***  ROUTINE ts_rst  ***
1195      !!                     
1196      !! ** Purpose :   Read or write TKE file (en) in restart file
1197      !!
1198      !! ** Method  :   use of IOM library
1199      !!                if the restart does not contain TKE, en is either
1200      !!                set to rn_emin or recomputed (nn_igls/=0)
1201      !!----------------------------------------------------------------------
1202      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
1203      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
1204      !
1205      INTEGER ::   jit, jk   ! dummy loop indices
1206      INTEGER ::   id1, id2, id3, id4, id5, id6
1207      INTEGER ::   ji, jj, ikbu, ikbv
1208      REAL(wp)::   cbx, cby
1209      !!----------------------------------------------------------------------
1210      !
1211      IF( TRIM(cdrw) == 'READ' ) THEN        ! Read/initialise
1212         !                                   ! ---------------
1213         IF( ln_rstart ) THEN                   !* Read the restart file
1214            id1 = iom_varid( numror, 'en'   , ldstop = .FALSE. )
1215            id2 = iom_varid( numror, 'avt'  , ldstop = .FALSE. )
1216            id3 = iom_varid( numror, 'avm'  , ldstop = .FALSE. )
1217            id4 = iom_varid( numror, 'avmu' , ldstop = .FALSE. )
1218            id5 = iom_varid( numror, 'avmv' , ldstop = .FALSE. )
1219            id6 = iom_varid( numror, 'mxln' , ldstop = .FALSE. )
1220            !
1221            IF( MIN( id1, id2, id3, id4, id5, id6 ) > 0 ) THEN        ! all required arrays exist
1222               CALL iom_get( numror, jpdom_autoglo, 'en'    , en     )
1223               CALL iom_get( numror, jpdom_autoglo, 'avt'   , avt    )
1224               CALL iom_get( numror, jpdom_autoglo, 'avm'   , avm    )
1225               CALL iom_get( numror, jpdom_autoglo, 'avmu'  , avmu   )
1226               CALL iom_get( numror, jpdom_autoglo, 'avmv'  , avmv   )
1227               CALL iom_get( numror, jpdom_autoglo, 'mxln'  , mxln   )
1228            ELSE                       
1229               IF(lwp) WRITE(numout,*) ' ===>>>> : previous run without gls scheme, en and mxln computed by iterative loop'
1230               en  (:,:,:) = rn_emin
1231               mxln(:,:,:) = 0.001       
1232               DO jit = nit000 + 1, nit000 + 10   ;   CALL zdf_gls( jit )   ;   END DO
1233            ENDIF
1234         ELSE                                   !* Start from rest
1235            IF(lwp) WRITE(numout,*) ' ===>>>> : Initialisation of en and mxln by background values'
1236            en  (:,:,:) = rn_emin
1237            mxln(:,:,:) = 0.001       
1238         ENDIF
1239         !
1240      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN   ! Create restart file
1241         !                                   ! -------------------
1242         IF(lwp) WRITE(numout,*) '---- gls-rst ----'
1243         CALL iom_rstput( kt, nitrst, numrow, 'en'   , en    )
1244         CALL iom_rstput( kt, nitrst, numrow, 'avt'  , avt   )
1245         CALL iom_rstput( kt, nitrst, numrow, 'avm'  , avm   )
1246         CALL iom_rstput( kt, nitrst, numrow, 'avmu' , avmu  )
1247         CALL iom_rstput( kt, nitrst, numrow, 'avmv' , avmv  )
1248         CALL iom_rstput( kt, nitrst, numrow, 'mxln' , mxln  )
1249         !
1250      ENDIF
1251      !
1252   END SUBROUTINE gls_rst
1253
1254#else
1255   !!----------------------------------------------------------------------
1256   !!   Dummy module :                                        NO TKE scheme
1257   !!----------------------------------------------------------------------
1258   LOGICAL, PUBLIC, PARAMETER ::   lk_zdfgls = .FALSE.   !: TKE flag
1259CONTAINS
1260   SUBROUTINE zdf_gls_init           ! Empty routine
1261      WRITE(*,*) 'zdf_gls_init: You should not have seen this print! error?'
1262   END SUBROUTINE zdf_gls_init
1263   SUBROUTINE zdf_gls( kt )          ! Empty routine
1264      WRITE(*,*) 'zdf_gls: You should not have seen this print! error?', kt
1265   END SUBROUTINE zdf_gls
1266   SUBROUTINE gls_rst( kt, cdrw )          ! Empty routine
1267      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
1268      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
1269      WRITE(*,*) 'gls_rst: You should not have seen this print! error?', kt, cdrw
1270   END SUBROUTINE gls_rst
1271#endif
1272
1273   !!======================================================================
1274END MODULE zdfgls
1275
Note: See TracBrowser for help on using the repository browser.