source: branches/2011/dev_NEMO_MERGE_2011/NEMOGCM/NEMO/OPA_SRC/ZDF/zdfgls.F90 @ 3229

Last change on this file since 3229 was 3229, checked in by charris, 10 years ago

Added timing calls to most significant routines in LDF, SBC and ZDF.

  • Property svn:keywords set to Id
File size: 60.0 KB
Line 
1MODULE zdfgls
2   !!======================================================================
3   !!                       ***  MODULE  zdfgls  ***
4   !! Ocean physics:  vertical mixing coefficient computed from the gls
5   !!                 turbulent closure parameterization
6   !!======================================================================
7   !! History :   3.0  !  2009-09  (G. Reffray)  Original code
8   !!             3.3  !  2010-10  (C. Bricaud)  Add in the reference
9   !!----------------------------------------------------------------------
10#if defined key_zdfgls   ||   defined key_esopa
11   !!----------------------------------------------------------------------
12   !!   'key_zdfgls'                 Generic Length Scale vertical physics
13   !!----------------------------------------------------------------------
14   !!   zdf_gls      : update momentum and tracer Kz from a gls scheme
15   !!   zdf_gls_init : initialization, namelist read, and parameters control
16   !!   gls_rst      : read/write gls restart in ocean restart file
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE dom_oce        ! ocean space and time domain
20   USE domvvl         ! ocean space and time domain : variable volume layer
21   USE zdf_oce        ! ocean vertical physics
22   USE sbc_oce        ! surface boundary condition: ocean
23   USE phycst         ! physical constants
24   USE zdfmxl         ! mixed layer
25   USE restart        ! only for lrst_oce
26   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
27   USE lib_mpp        ! MPP manager
28   USE wrk_nemo       ! work arrays
29   USE prtctl         ! Print control
30   USE in_out_manager ! I/O manager
31   USE iom            ! I/O manager library
32   USE timing         ! Timing
33
34   IMPLICIT NONE
35   PRIVATE
36
37   PUBLIC   zdf_gls        ! routine called in step module
38   PUBLIC   zdf_gls_init   ! routine called in opa module
39   PUBLIC   gls_rst        ! routine called in step module
40
41   LOGICAL , PUBLIC, PARAMETER ::   lk_zdfgls = .TRUE.   !: TKE vertical mixing flag
42   !
43   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   en      !: now turbulent kinetic energy
44   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   mxln    !: now mixing length
45   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   zwall   !: wall function
46   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   ustars2 !: Squared surface velocity scale at T-points
47   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   ustarb2 !: Squared bottom  velocity scale at T-points
48
49   !                                         !!! ** Namelist  namzdf_gls  **
50   LOGICAL  ::   ln_crban      = .FALSE.      ! =T use Craig and Banner scheme
51   LOGICAL  ::   ln_length_lim = .FALSE.      ! use limit on the dissipation rate under stable stratification (Galperin et al. 1988)
52   LOGICAL  ::   ln_sigpsi     = .FALSE.      ! Activate Burchard (2003) modification for k-eps closure & wave breaking mixing
53   INTEGER  ::   nn_tkebc_surf = 0            ! TKE surface boundary condition (=0/1)
54   INTEGER  ::   nn_tkebc_bot  = 0            ! TKE bottom boundary condition (=0/1)
55   INTEGER  ::   nn_psibc_surf = 0            ! PSI surface boundary condition (=0/1)
56   INTEGER  ::   nn_psibc_bot  = 0            ! PSI bottom boundary condition (=0/1)
57   INTEGER  ::   nn_stab_func  = 0            ! stability functions G88, KC or Canuto (=0/1/2)
58   INTEGER  ::   nn_clos       = 0            ! closure 0/1/2/3 MY82/k-eps/k-w/gen
59   REAL(wp) ::   rn_clim_galp  = 0.53_wp      ! Holt 2008 value for k-eps: 0.267
60   REAL(wp) ::   rn_epsmin     = 1.e-12_wp    ! minimum value of dissipation (m2/s3)
61   REAL(wp) ::   rn_emin       = 1.e-6_wp     ! minimum value of TKE (m2/s2)
62   REAL(wp) ::   rn_charn      = 2.e+5_wp     ! Charnock constant for surface breaking waves mixing : 1400. (standard) or 2.e5 (Stacey value)
63   REAL(wp) ::   rn_crban      = 100._wp      ! Craig and Banner constant for surface breaking waves mixing
64
65   REAL(wp) ::   hsro          =  0.003_wp    ! Minimum surface roughness
66   REAL(wp) ::   hbro          =  0.003_wp    ! Bottom roughness (m)
67   REAL(wp) ::   rcm_sf        =  0.73_wp     ! Shear free turbulence parameters
68   REAL(wp) ::   ra_sf         = -2.0_wp      ! Must be negative -2 < ra_sf < -1
69   REAL(wp) ::   rl_sf         =  0.2_wp      ! 0 <rl_sf<vkarmn   
70   REAL(wp) ::   rghmin        = -0.28_wp
71   REAL(wp) ::   rgh0          =  0.0329_wp
72   REAL(wp) ::   rghcri        =  0.03_wp
73   REAL(wp) ::   ra1           =  0.92_wp
74   REAL(wp) ::   ra2           =  0.74_wp
75   REAL(wp) ::   rb1           = 16.60_wp
76   REAL(wp) ::   rb2           = 10.10_wp         
77   REAL(wp) ::   re2           =  1.33_wp         
78   REAL(wp) ::   rl1           =  0.107_wp
79   REAL(wp) ::   rl2           =  0.0032_wp
80   REAL(wp) ::   rl3           =  0.0864_wp
81   REAL(wp) ::   rl4           =  0.12_wp
82   REAL(wp) ::   rl5           = 11.9_wp
83   REAL(wp) ::   rl6           =  0.4_wp
84   REAL(wp) ::   rl7           =  0.0_wp
85   REAL(wp) ::   rl8           =  0.48_wp
86   REAL(wp) ::   rm1           =  0.127_wp
87   REAL(wp) ::   rm2           =  0.00336_wp
88   REAL(wp) ::   rm3           =  0.0906_wp
89   REAL(wp) ::   rm4           =  0.101_wp
90   REAL(wp) ::   rm5           = 11.2_wp
91   REAL(wp) ::   rm6           =  0.4_wp
92   REAL(wp) ::   rm7           =  0.0_wp
93   REAL(wp) ::   rm8           =  0.318_wp
94   
95   REAL(wp) ::   rc02, rc02r, rc03, rc04                          ! coefficients deduced from above parameters
96   REAL(wp) ::   rc03_sqrt2_galp                                  !     -           -           -        -
97   REAL(wp) ::   rsbc_tke1, rsbc_tke2, rsbc_tke3, rfact_tke       !     -           -           -        -
98   REAL(wp) ::   rsbc_psi1, rsbc_psi2, rsbc_psi3, rfact_psi       !     -           -           -        -
99   REAL(wp) ::   rsbc_mb  , rsbc_std , rsbc_zs                    !     -           -           -        -
100   REAL(wp) ::   rc0, rc2, rc3, rf6, rcff, rc_diff                !     -           -           -        -
101   REAL(wp) ::   rs0, rs1, rs2, rs4, rs5, rs6                     !     -           -           -        -
102   REAL(wp) ::   rd0, rd1, rd2, rd3, rd4, rd5                     !     -           -           -        -
103   REAL(wp) ::   rsc_tke, rsc_psi, rpsi1, rpsi2, rpsi3, rsc_psi0  !     -           -           -        -
104   REAL(wp) ::   rpsi3m, rpsi3p, rpp, rmm, rnn                    !     -           -           -        -
105
106   !! * Substitutions
107#  include "domzgr_substitute.h90"
108#  include "vectopt_loop_substitute.h90"
109   !!----------------------------------------------------------------------
110   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
111   !! $Id$
112   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
113   !!----------------------------------------------------------------------
114CONTAINS
115
116   INTEGER FUNCTION zdf_gls_alloc()
117      !!----------------------------------------------------------------------
118      !!                ***  FUNCTION zdf_gls_alloc  ***
119      !!----------------------------------------------------------------------
120      ALLOCATE( en(jpi,jpj,jpk),  mxln(jpi,jpj,jpk), zwall(jpi,jpj,jpk) ,     &
121         &      ustars2(jpi,jpj), ustarb2(jpi,jpj)                      , STAT= zdf_gls_alloc )
122         !
123      IF( lk_mpp             )   CALL mpp_sum ( zdf_gls_alloc )
124      IF( zdf_gls_alloc /= 0 )   CALL ctl_warn('zdf_gls_alloc: failed to allocate arrays')
125   END FUNCTION zdf_gls_alloc
126
127
128   SUBROUTINE zdf_gls( kt )
129      !!----------------------------------------------------------------------
130      !!                   ***  ROUTINE zdf_gls  ***
131      !!
132      !! ** Purpose :   Compute the vertical eddy viscosity and diffusivity
133      !!              coefficients using the GLS turbulent closure scheme.
134      !!----------------------------------------------------------------------
135      USE oce     , ONLY: tsa                 ! use tsa as workspace
136      USE oce     , ONLY: z_elem_a  =>   ua   ! use ua as workspace
137      USE oce     , ONLY: z_elem_b  =>   va   ! use va as workspace
138      !
139      INTEGER, INTENT(in) ::   kt ! ocean time step
140      INTEGER  ::   ji, jj, jk, ibot, ibotm1, dir  ! dummy loop arguments
141      REAL(wp) ::   zesh2, zsigpsi, zcoef, zex1, zex2   ! local scalars
142      REAL(wp) ::   ztx2, zty2, zup, zdown, zcof        !   -      -
143      REAL(wp) ::   zratio, zrn2, zflxb, sh             !   -      -
144      REAL(wp) ::   prod, buoy, diss, zdiss, sm         !   -      -
145      REAL(wp) ::   gh, gm, shr, dif, zsqen, zav        !   -      -
146      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zdep
147      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zflxs       ! Turbulence fluxed induced by internal waves
148      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zhsro       ! Surface roughness (surface waves)
149      REAL(wp), POINTER, DIMENSION(:,:,:) ::   eb          ! tke at time before
150      REAL(wp), POINTER, DIMENSION(:,:,:) ::   mxlb        ! mixing length at time before
151      REAL(wp), POINTER, DIMENSION(:,:,:) ::   shear       ! vertical shear
152      REAL(wp), POINTER, DIMENSION(:,:,:) ::   eps         ! dissipation rate
153      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zwall_psi   ! Wall function use in the wb case (ln_sigpsi.AND.ln_crban=T)
154      REAL(wp), POINTER, DIMENSION(:,:,:) ::   z_elem_c, psi
155      !!--------------------------------------------------------------------
156      !
157      IF( nn_timing == 1 )  CALL timing_start('zdf_gls')
158      !
159      CALL wrk_alloc( jpi,jpj, zdep, zflxs, zhsro )
160      CALL wrk_alloc( jpi,jpj,jpk, eb, mxlb, shear, eps, zwall_psi )
161      !
162      z_elem_c  => tsa(:,:,:,1)
163      psi       => tsa(:,:,:,2)
164
165      ! Preliminary computing
166
167      ustars2 = 0._wp   ;   ustarb2 = 0._wp   ;   psi  = 0._wp   ;   zwall_psi = 0._wp
168
169      ! Compute surface and bottom friction at T-points
170!CDIR NOVERRCHK
171      DO jj = 2, jpjm1
172!CDIR NOVERRCHK
173         DO ji = fs_2, fs_jpim1   ! vector opt.
174            !
175            ! surface friction
176            ustars2(ji,jj) = rau0r * taum(ji,jj) * tmask(ji,jj,1)
177            !
178            ! bottom friction (explicit before friction)
179            ! Note that we chose here not to bound the friction as in dynbfr)
180            ztx2 = (  bfrua(ji,jj)  * ub(ji,jj,mbku(ji,jj)) + bfrua(ji-1,jj) * ub(ji-1,jj,mbku(ji-1,jj))  )   &
181               & * ( 1._wp - 0.5_wp * umask(ji,jj,1) * umask(ji-1,jj,1)  )
182            zty2 = (  bfrva(ji,jj)  * vb(ji,jj,mbkv(ji,jj)) + bfrva(ji,jj-1) * vb(ji,jj-1,mbkv(ji,jj-1))  )   &
183               & * ( 1._wp - 0.5_wp * vmask(ji,jj,1) * vmask(ji,jj-1,1)  )
184            ustarb2(ji,jj) = SQRT( ztx2 * ztx2 + zty2 * zty2 ) * tmask(ji,jj,1)
185         END DO
186      END DO 
187
188      ! In case of breaking surface waves mixing,
189      ! Compute surface roughness length according to Charnock formula:
190      IF( ln_crban ) THEN   ;   zhsro(:,:) = MAX(rsbc_zs * ustars2(:,:), hsro)
191      ELSE                  ;   zhsro(:,:) = hsro
192      ENDIF
193
194      ! Compute shear and dissipation rate
195      DO jk = 2, jpkm1
196         DO jj = 2, jpjm1
197            DO ji = fs_2, fs_jpim1   ! vector opt.
198               avmu(ji,jj,jk) = avmu(ji,jj,jk) * ( un(ji,jj,jk-1) - un(ji,jj,jk) )   &
199                  &                            * ( ub(ji,jj,jk-1) - ub(ji,jj,jk) )   &
200                  &                            / (  fse3uw_n(ji,jj,jk)               &
201                  &                            *    fse3uw_b(ji,jj,jk) )
202               avmv(ji,jj,jk) = avmv(ji,jj,jk) * ( vn(ji,jj,jk-1) - vn(ji,jj,jk) )   &
203                  &                            * ( vb(ji,jj,jk-1) - vb(ji,jj,jk) )   &
204                  &                            / (  fse3vw_n(ji,jj,jk)               &
205                  &                            *    fse3vw_b(ji,jj,jk) )
206               eps(ji,jj,jk)  = rc03 * en(ji,jj,jk) * SQRT(en(ji,jj,jk)) / mxln(ji,jj,jk)
207            END DO
208         END DO
209      END DO
210      !
211      ! Lateral boundary conditions (avmu,avmv) (sign unchanged)
212      CALL lbc_lnk( avmu, 'U', 1. )   ;   CALL lbc_lnk( avmv, 'V', 1. )
213
214      ! Save tke at before time step
215      eb  (:,:,:) = en  (:,:,:)
216      mxlb(:,:,:) = mxln(:,:,:)
217
218      IF( nn_clos == 0 ) THEN    ! Mellor-Yamada
219         DO jk = 2, jpkm1
220            DO jj = 2, jpjm1 
221               DO ji = fs_2, fs_jpim1   ! vector opt.
222                  zup   = mxln(ji,jj,jk) * fsdepw(ji,jj,mbkt(ji,jj)+1)
223                  zdown = vkarmn * fsdepw(ji,jj,jk) * ( -fsdepw(ji,jj,jk) + fsdepw(ji,jj,mbkt(ji,jj)+1) )
224                  zcoef = ( zup / MAX( zdown, rsmall ) )
225                  zwall (ji,jj,jk) = ( 1._wp + re2 * zcoef*zcoef ) * tmask(ji,jj,jk)
226               END DO
227            END DO
228         END DO
229      ENDIF
230
231      !!---------------------------------!!
232      !!   Equation to prognostic k      !!
233      !!---------------------------------!!
234      !
235      ! Now Turbulent kinetic energy (output in en)
236      ! -------------------------------
237      ! Resolution of a tridiagonal linear system by a "methode de chasse"
238      ! computation from level 2 to jpkm1  (e(1) computed after and e(jpk)=0 ).
239      ! The surface boundary condition are set after
240      ! The bottom boundary condition are also set after. In standard e(bottom)=0.
241      ! z_elem_b : diagonal z_elem_c : upper diagonal z_elem_a : lower diagonal
242      ! Warning : after this step, en : right hand side of the matrix
243
244      DO jk = 2, jpkm1
245         DO jj = 2, jpjm1
246            DO ji = fs_2, fs_jpim1   ! vector opt.
247               !
248               ! shear prod. at w-point weightened by mask
249               shear(ji,jj,jk) =  ( avmu(ji-1,jj,jk) + avmu(ji,jj,jk) ) / MAX( 1.e0 , umask(ji-1,jj,jk) + umask(ji,jj,jk) )   &
250                  &             + ( avmv(ji,jj-1,jk) + avmv(ji,jj,jk) ) / MAX( 1.e0 , vmask(ji,jj-1,jk) + vmask(ji,jj,jk) )
251               !
252               ! stratif. destruction
253               buoy = - avt(ji,jj,jk) * rn2(ji,jj,jk)
254               !
255               ! shear prod. - stratif. destruction
256               diss = eps(ji,jj,jk)
257               !
258               dir = 0.5_wp + SIGN( 0.5_wp, shear(ji,jj,jk) + buoy )   ! dir =1(=0) if shear(ji,jj,jk)+buoy >0(<0)
259               !
260               zesh2 = dir*(shear(ji,jj,jk)+buoy)+(1._wp-dir)*shear(ji,jj,jk)          ! production term
261               zdiss = dir*(diss/en(ji,jj,jk))   +(1._wp-dir)*(diss-buoy)/en(ji,jj,jk) ! dissipation term
262               !
263               ! Compute a wall function from 1. to rsc_psi*zwall/rsc_psi0
264               ! Note that as long that Dirichlet boundary conditions are NOT set at the first and last levels (GOTM style)
265               ! there is no need to set a boundary condition for zwall_psi at the top and bottom boundaries.
266               ! Otherwise, this should be rsc_psi/rsc_psi0
267               IF( ln_sigpsi ) THEN
268                  zsigpsi = MIN( 1._wp, zesh2 / eps(ji,jj,jk) )     ! 0. <= zsigpsi <= 1.
269                  zwall_psi(ji,jj,jk) = rsc_psi /   & 
270                     &     (  zsigpsi * rsc_psi + (1._wp-zsigpsi) * rsc_psi0 / MAX( zwall(ji,jj,jk), 1._wp )  )
271               ELSE
272                  zwall_psi(ji,jj,jk) = 1._wp
273               ENDIF
274               !
275               ! building the matrix
276               zcof = rfact_tke * tmask(ji,jj,jk)
277               !
278               ! lower diagonal
279               z_elem_a(ji,jj,jk) = zcof * ( avm  (ji,jj,jk  ) + avm  (ji,jj,jk-1) )   &
280                  &                      / ( fse3t(ji,jj,jk-1) * fse3w(ji,jj,jk  ) )
281               !
282               ! upper diagonal
283               z_elem_c(ji,jj,jk) = zcof * ( avm  (ji,jj,jk+1) + avm  (ji,jj,jk  ) )   &
284                  &                      / ( fse3t(ji,jj,jk  ) * fse3w(ji,jj,jk) )
285               !
286               ! diagonal
287               z_elem_b(ji,jj,jk) = 1._wp - z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk)  &
288                  &                       + rdt * zdiss * tmask(ji,jj,jk) 
289               !
290               ! right hand side in en
291               en(ji,jj,jk) = en(ji,jj,jk) + rdt * zesh2 * tmask(ji,jj,jk)
292            END DO
293         END DO
294      END DO
295      !
296      z_elem_b(:,:,jpk) = 1._wp
297      !
298      ! Set surface condition on zwall_psi (1 at the bottom)
299      IF( ln_sigpsi ) THEN
300         zcoef = rsc_psi / rsc_psi0
301         DO jj = 2, jpjm1
302            DO ji = fs_2, fs_jpim1   ! vector opt.
303               zwall_psi(ji,jj,1) = zcoef
304            END DO
305         END DO
306      ENDIF
307
308      ! Surface boundary condition on tke
309      ! ---------------------------------
310      !
311      SELECT CASE ( nn_tkebc_surf )
312      !
313      CASE ( 0 )             ! Dirichlet case
314         !
315         IF (ln_crban) THEN     ! Wave induced mixing case
316            !                      ! en(1) = q2(1) = 0.5 * (15.8 * Ccb)^(2/3) * u*^2
317            !                      ! balance between the production and the dissipation terms including the wave effect
318            en(:,:,1) = MAX( rsbc_tke1 * ustars2(:,:), rn_emin )
319            z_elem_a(:,:,1) = en(:,:,1)
320            z_elem_c(:,:,1) = 0._wp
321            z_elem_b(:,:,1) = 1._wp
322            !
323            ! one level below
324            en(:,:,2) = MAX( rsbc_tke1 * ustars2(:,:) * ( (zhsro(:,:)+fsdepw(:,:,2))/zhsro(:,:) )**ra_sf, rn_emin )
325            z_elem_a(:,:,2) = 0._wp
326            z_elem_c(:,:,2) = 0._wp
327            z_elem_b(:,:,2) = 1._wp
328            !
329         ELSE                   ! No wave induced mixing case
330            !                      ! en(1) = u*^2/C0^2  &  l(1)  = K*zs
331            !                      ! balance between the production and the dissipation terms
332            en(:,:,1) = MAX( rc02r * ustars2(:,:), rn_emin )
333            z_elem_a(:,:,1) = en(:,:,1) 
334            z_elem_c(:,:,1) = 0._wp
335            z_elem_b(:,:,1) = 1._wp
336            !
337            ! one level below
338            en(:,:,2) = MAX( rc02r * ustars2(:,:), rn_emin )
339            z_elem_a(:,:,2) = 0._wp
340            z_elem_c(:,:,2) = 0._wp
341            z_elem_b(:,:,2) = 1._wp
342            !
343         ENDIF
344         !
345      CASE ( 1 )             ! Neumann boundary condition on d(e)/dz
346         !
347         IF (ln_crban) THEN ! Shear free case: d(e)/dz= Fw
348            !
349            ! Dirichlet conditions at k=1 (Cosmetic)
350            en(:,:,1) = MAX( rsbc_tke1 * ustars2(:,:), rn_emin )
351            z_elem_a(:,:,1) = en(:,:,1)
352            z_elem_c(:,:,1) = 0._wp
353            z_elem_b(:,:,1) = 1._wp
354            ! at k=2, set de/dz=Fw
355            z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
356            z_elem_a(:,:,2) = 0._wp       
357            zflxs(:,:) = rsbc_tke3 * ustars2(:,:)**1.5_wp * ( (zhsro(:,:)+fsdept(:,:,1) ) / zhsro(:,:) )**(1.5*ra_sf)
358            en(:,:,2) = en(:,:,2) + zflxs(:,:) / fse3w(:,:,2)
359            !
360         ELSE                   ! No wave induced mixing case: d(e)/dz=0.
361            !
362            ! Dirichlet conditions at k=1 (Cosmetic)
363            en(:,:,1) = MAX( rc02r * ustars2(:,:), rn_emin )
364            z_elem_a(:,:,1) = en(:,:,1)
365            z_elem_c(:,:,1) = 0._wp
366            z_elem_b(:,:,1) = 1._wp
367            ! at k=2 set de/dz=0.:
368            z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2)  ! Remove z_elem_a from z_elem_b
369            z_elem_a(:,:,2) = 0._wp
370            !
371         ENDIF
372         !
373      END SELECT
374
375      ! Bottom boundary condition on tke
376      ! --------------------------------
377      !
378      SELECT CASE ( nn_tkebc_bot )
379      !
380      CASE ( 0 )             ! Dirichlet
381         !                      ! en(ibot) = u*^2 / Co2 and mxln(ibot) = rn_lmin
382         !                      ! Balance between the production and the dissipation terms
383!CDIR NOVERRCHK
384         DO jj = 2, jpjm1
385!CDIR NOVERRCHK
386            DO ji = fs_2, fs_jpim1   ! vector opt.
387               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
388               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
389               !
390               ! Bottom level Dirichlet condition:
391               z_elem_a(ji,jj,ibot  ) = 0._wp
392               z_elem_c(ji,jj,ibot  ) = 0._wp
393               z_elem_b(ji,jj,ibot  ) = 1._wp
394               en(ji,jj,ibot  ) = MAX( rc02r * ustarb2(ji,jj), rn_emin )
395               !
396               ! Just above last level, Dirichlet condition again
397               z_elem_a(ji,jj,ibotm1) = 0._wp
398               z_elem_c(ji,jj,ibotm1) = 0._wp
399               z_elem_b(ji,jj,ibotm1) = 1._wp
400               en(ji,jj,ibotm1) = MAX( rc02r * ustarb2(ji,jj), rn_emin ) 
401            END DO
402         END DO
403         !
404      CASE ( 1 )             ! Neumman boundary condition
405         !                     
406!CDIR NOVERRCHK
407         DO jj = 2, jpjm1
408!CDIR NOVERRCHK
409            DO ji = fs_2, fs_jpim1   ! vector opt.
410               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
411               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
412               !
413               ! Bottom level Dirichlet condition:
414               z_elem_a(ji,jj,ibot) = 0._wp
415               z_elem_c(ji,jj,ibot) = 0._wp
416               z_elem_b(ji,jj,ibot) = 1._wp
417               en(ji,jj,ibot) = MAX( rc02r * ustarb2(ji,jj), rn_emin )
418               !
419               ! Just above last level: Neumann condition
420               z_elem_b(ji,jj,ibotm1) = z_elem_b(ji,jj,ibotm1) + z_elem_c(ji,jj,ibotm1)   ! Remove z_elem_c from z_elem_b
421               z_elem_c(ji,jj,ibotm1) = 0._wp
422            END DO
423         END DO
424         !
425      END SELECT
426
427      ! Matrix inversion (en prescribed at surface and the bottom)
428      ! ----------------------------------------------------------
429      !
430      DO jk = 2, jpkm1                             ! First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1
431         DO jj = 2, jpjm1
432            DO ji = fs_2, fs_jpim1    ! vector opt.
433               z_elem_b(ji,jj,jk) = z_elem_b(ji,jj,jk) - z_elem_a(ji,jj,jk) * z_elem_c(ji,jj,jk-1) / z_elem_b(ji,jj,jk-1)
434            END DO
435         END DO
436      END DO
437      DO jk = 2, jpk                               ! Second recurrence : Lk = RHSk - Lk / Dk-1 * Lk-1
438         DO jj = 2, jpjm1
439            DO ji = fs_2, fs_jpim1    ! vector opt.
440               z_elem_a(ji,jj,jk) = en(ji,jj,jk) - z_elem_a(ji,jj,jk) / z_elem_b(ji,jj,jk-1) * z_elem_a(ji,jj,jk-1)
441            END DO
442         END DO
443      END DO
444      DO jk = jpk-1, 2, -1                         ! thrid recurrence : Ek = ( Lk - Uk * Ek+1 ) / Dk
445         DO jj = 2, jpjm1
446            DO ji = fs_2, fs_jpim1    ! vector opt.
447               en(ji,jj,jk) = ( z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk) * en(ji,jj,jk+1) ) / z_elem_b(ji,jj,jk)
448            END DO
449         END DO
450      END DO
451      !                                            ! set the minimum value of tke
452      en(:,:,:) = MAX( en(:,:,:), rn_emin )
453     
454      !!----------------------------------------!!
455      !!   Solve prognostic equation for psi    !!
456      !!----------------------------------------!!
457
458      ! Set psi to previous time step value
459      !
460      SELECT CASE ( nn_clos )
461      !
462      CASE( 0 )               ! k-kl  (Mellor-Yamada)
463         DO jk = 2, jpkm1
464            DO jj = 2, jpjm1
465               DO ji = fs_2, fs_jpim1   ! vector opt.
466                  psi(ji,jj,jk)  = en(ji,jj,jk) * mxln(ji,jj,jk)
467               END DO
468            END DO
469         END DO
470         !
471      CASE( 1 )               ! k-eps
472         DO jk = 2, jpkm1
473            DO jj = 2, jpjm1
474               DO ji = fs_2, fs_jpim1   ! vector opt.
475                  psi(ji,jj,jk)  = eps(ji,jj,jk)
476               END DO
477            END DO
478         END DO
479         !
480      CASE( 2 )               ! k-w
481         DO jk = 2, jpkm1
482            DO jj = 2, jpjm1
483               DO ji = fs_2, fs_jpim1   ! vector opt.
484                  psi(ji,jj,jk)  = SQRT( en(ji,jj,jk) ) / ( rc0 * mxln(ji,jj,jk) )
485               END DO
486            END DO
487         END DO
488         !
489      CASE( 3 )               ! generic
490         DO jk = 2, jpkm1
491            DO jj = 2, jpjm1
492               DO ji = fs_2, fs_jpim1   ! vector opt.
493                  psi(ji,jj,jk)  = rc02 * en(ji,jj,jk) * mxln(ji,jj,jk)**rnn 
494               END DO
495            END DO
496         END DO
497         !
498      END SELECT
499      !
500      ! Now gls (output in psi)
501      ! -------------------------------
502      ! Resolution of a tridiagonal linear system by a "methode de chasse"
503      ! computation from level 2 to jpkm1  (e(1) already computed and e(jpk)=0 ).
504      ! z_elem_b : diagonal z_elem_c : upper diagonal z_elem_a : lower diagonal
505      ! Warning : after this step, en : right hand side of the matrix
506
507      DO jk = 2, jpkm1
508         DO jj = 2, jpjm1
509            DO ji = fs_2, fs_jpim1   ! vector opt.
510               !
511               ! psi / k
512               zratio = psi(ji,jj,jk) / eb(ji,jj,jk) 
513               !
514               ! psi3+ : stable : B=-KhN²<0 => N²>0 if rn2>0 dir = 1 (stable) otherwise dir = 0 (unstable)
515               dir = 0.5_wp + SIGN( 0.5_wp, rn2(ji,jj,jk) )
516               !
517               rpsi3 = dir * rpsi3m + ( 1._wp - dir ) * rpsi3p
518               !
519               ! shear prod. - stratif. destruction
520               prod = rpsi1 * zratio * shear(ji,jj,jk)
521               !
522               ! stratif. destruction
523               buoy = rpsi3 * zratio * (- avt(ji,jj,jk) * rn2(ji,jj,jk) )
524               !
525               ! shear prod. - stratif. destruction
526               diss = rpsi2 * zratio * zwall(ji,jj,jk) * eps(ji,jj,jk)
527               !
528               dir = 0.5_wp + SIGN( 0.5_wp, prod + buoy )   ! dir =1(=0) if shear(ji,jj,jk)+buoy >0(<0)
529               !
530               zesh2 = dir * ( prod + buoy )          + (1._wp - dir ) * prod                        ! production term
531               zdiss = dir * ( diss / psi(ji,jj,jk) ) + (1._wp - dir ) * (diss-buoy) / psi(ji,jj,jk) ! dissipation term
532               !                                                       
533               ! building the matrix
534               zcof = rfact_psi * zwall_psi(ji,jj,jk) * tmask(ji,jj,jk)
535               ! lower diagonal
536               z_elem_a(ji,jj,jk) = zcof * ( avm  (ji,jj,jk  ) + avm  (ji,jj,jk-1) )   &
537                  &                      / ( fse3t(ji,jj,jk-1) * fse3w(ji,jj,jk  ) )
538               ! upper diagonal
539               z_elem_c(ji,jj,jk) = zcof * ( avm  (ji,jj,jk+1) + avm  (ji,jj,jk  ) )   &
540                  &                      / ( fse3t(ji,jj,jk  ) * fse3w(ji,jj,jk) )
541               ! diagonal
542               z_elem_b(ji,jj,jk) = 1._wp - z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk)  &
543                  &                       + rdt * zdiss * tmask(ji,jj,jk)
544               !
545               ! right hand side in psi
546               psi(ji,jj,jk) = psi(ji,jj,jk) + rdt * zesh2 * tmask(ji,jj,jk)
547            END DO
548         END DO
549      END DO
550      !
551      z_elem_b(:,:,jpk) = 1._wp
552
553      ! Surface boundary condition on psi
554      ! ---------------------------------
555      !
556      SELECT CASE ( nn_psibc_surf )
557      !
558      CASE ( 0 )             ! Dirichlet boundary conditions
559         !
560         IF( ln_crban ) THEN       ! Wave induced mixing case
561            !                      ! en(1) = q2(1) = 0.5 * (15.8 * Ccb)^(2/3) * u*^2
562            !                      ! balance between the production and the dissipation terms including the wave effect
563            zdep(:,:) = rl_sf * zhsro(:,:)
564            psi (:,:,1) = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
565            z_elem_a(:,:,1) = psi(:,:,1)
566            z_elem_c(:,:,1) = 0._wp
567            z_elem_b(:,:,1) = 1._wp
568            !
569            ! one level below
570            zex1 = (rmm*ra_sf+rnn)
571            zex2 = (rmm*ra_sf)
572            zdep(:,:) = ( (zhsro(:,:) + fsdepw(:,:,2))**zex1 ) / zhsro(:,:)**zex2
573            psi (:,:,2) = rsbc_psi1 * ustars2(:,:)**rmm * zdep(:,:) * tmask(:,:,1)
574            z_elem_a(:,:,2) = 0._wp
575            z_elem_c(:,:,2) = 0._wp
576            z_elem_b(:,:,2) = 1._wp
577            !
578         ELSE                   ! No wave induced mixing case
579            !                      ! en(1) = u*^2/C0^2  &  l(1)  = K*zs
580            !                      ! balance between the production and the dissipation terms
581            !
582            zdep(:,:) = vkarmn * zhsro(:,:)
583            psi (:,:,1) = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
584            z_elem_a(:,:,1) = psi(:,:,1)
585            z_elem_c(:,:,1) = 0._wp
586            z_elem_b(:,:,1) = 1._wp
587            !
588            ! one level below
589            zdep(:,:) = vkarmn * ( zhsro(:,:) + fsdepw(:,:,2) )
590            psi (:,:,2) = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
591            z_elem_a(:,:,2) = 0._wp
592            z_elem_c(:,:,2) = 0._wp
593            z_elem_b(:,:,2) = 1.
594            !
595         ENDIF
596         !
597      CASE ( 1 )             ! Neumann boundary condition on d(psi)/dz
598         !
599         IF( ln_crban ) THEN     ! Wave induced mixing case
600            !
601            zdep(:,:) = rl_sf * zhsro(:,:)
602            psi (:,:,1) = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
603            z_elem_a(:,:,1) = psi(:,:,1)
604            z_elem_c(:,:,1) = 0._wp
605            z_elem_b(:,:,1) = 1._wp
606            !
607            ! Neumann condition at k=2
608            z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
609            z_elem_a(:,:,2) = 0._wp
610            !
611            ! Set psi vertical flux at the surface:
612            zdep(:,:) = (zhsro(:,:) + fsdept(:,:,1))**(rmm*ra_sf+rnn-1._wp) / zhsro(:,:)**(rmm*ra_sf)
613            zflxs(:,:) = rsbc_psi3 * ( zwall_psi(:,:,1)*avm(:,:,1) + zwall_psi(:,:,2)*avm(:,:,2) ) & 
614               &                   * en(:,:,1)**rmm * zdep         
615            psi(:,:,2) = psi(:,:,2) + zflxs(:,:) / fse3w(:,:,2)
616            !
617      ELSE                   ! No wave induced mixing
618            !
619            zdep(:,:) = vkarmn * zhsro(:,:)
620            psi (:,:,1) = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
621            z_elem_a(:,:,1) = psi(:,:,1)
622            z_elem_c(:,:,1) = 0._wp
623            z_elem_b(:,:,1) = 1._wp
624            !
625            ! Neumann condition at k=2
626            z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
627            z_elem_a(ji,jj,2) = 0._wp
628            !
629            ! Set psi vertical flux at the surface:
630            zdep(:,:)  = zhsro(:,:) + fsdept(:,:,1)
631            zflxs(:,:) = rsbc_psi2 * ( avm(:,:,1) + avm(:,:,2) ) * en(:,:,1)**rmm * zdep**(rnn-1._wp)
632            psi(:,:,2) = psi(:,:,2) + zflxs(:,:) / fse3w(:,:,2)
633            !     
634         ENDIF
635         !
636      END SELECT
637
638      ! Bottom boundary condition on psi
639      ! --------------------------------
640      !
641      SELECT CASE ( nn_psibc_bot )
642      !
643      CASE ( 0 )             ! Dirichlet
644         !                      ! en(ibot) = u*^2 / Co2 and mxln(ibot) = vkarmn * hbro
645         !                      ! Balance between the production and the dissipation terms
646!CDIR NOVERRCHK
647         DO jj = 2, jpjm1
648!CDIR NOVERRCHK
649            DO ji = fs_2, fs_jpim1   ! vector opt.
650               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
651               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
652               zdep(ji,jj) = vkarmn * hbro
653               psi (ji,jj,ibot) = rc0**rpp * en(ji,jj,ibot)**rmm * zdep(ji,jj)**rnn
654               z_elem_a(ji,jj,ibot) = 0._wp
655               z_elem_c(ji,jj,ibot) = 0._wp
656               z_elem_b(ji,jj,ibot) = 1._wp
657               !
658               ! Just above last level, Dirichlet condition again (GOTM like)
659               zdep(ji,jj) = vkarmn * ( hbro + fse3t(ji,jj,ibotm1) )
660               psi (ji,jj,ibotm1) = rc0**rpp * en(ji,jj,ibot  )**rmm * zdep(ji,jj)**rnn
661               z_elem_a(ji,jj,ibotm1) = 0._wp
662               z_elem_c(ji,jj,ibotm1) = 0._wp
663               z_elem_b(ji,jj,ibotm1) = 1._wp
664            END DO
665         END DO
666         !
667      CASE ( 1 )             ! Neumman boundary condition
668         !                     
669!CDIR NOVERRCHK
670         DO jj = 2, jpjm1
671!CDIR NOVERRCHK
672            DO ji = fs_2, fs_jpim1   ! vector opt.
673               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
674               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
675               !
676               ! Bottom level Dirichlet condition:
677               zdep(ji,jj) = vkarmn * hbro
678               psi (ji,jj,ibot) = rc0**rpp * en(ji,jj,ibot)**rmm * zdep(ji,jj)**rnn
679               !
680               z_elem_a(ji,jj,ibot) = 0._wp
681               z_elem_c(ji,jj,ibot) = 0._wp
682               z_elem_b(ji,jj,ibot) = 1._wp
683               !
684               ! Just above last level: Neumann condition with flux injection
685               z_elem_b(ji,jj,ibotm1) = z_elem_b(ji,jj,ibotm1) + z_elem_c(ji,jj,ibotm1) ! Remove z_elem_c from z_elem_b
686               z_elem_c(ji,jj,ibotm1) = 0.
687               !
688               ! Set psi vertical flux at the bottom:
689               zdep(ji,jj) = hbro + 0.5_wp*fse3t(ji,jj,ibotm1)
690               zflxb = rsbc_psi2 * ( avm(ji,jj,ibot) + avm(ji,jj,ibotm1) )   &
691                  &  * (0.5_wp*(en(ji,jj,ibot)+en(ji,jj,ibotm1)))**rmm * zdep(ji,jj)**(rnn-1._wp)
692               psi(ji,jj,ibotm1) = psi(ji,jj,ibotm1) + zflxb / fse3w(ji,jj,ibotm1)
693            END DO
694         END DO
695         !
696      END SELECT
697
698      ! Matrix inversion
699      ! ----------------
700      !
701      DO jk = 2, jpkm1                             ! First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1
702         DO jj = 2, jpjm1
703            DO ji = fs_2, fs_jpim1    ! vector opt.
704               z_elem_b(ji,jj,jk) = z_elem_b(ji,jj,jk) - z_elem_a(ji,jj,jk) * z_elem_c(ji,jj,jk-1) / z_elem_b(ji,jj,jk-1)
705            END DO
706         END DO
707      END DO
708      DO jk = 2, jpk                               ! Second recurrence : Lk = RHSk - Lk / Dk-1 * Lk-1
709         DO jj = 2, jpjm1
710            DO ji = fs_2, fs_jpim1    ! vector opt.
711               z_elem_a(ji,jj,jk) = psi(ji,jj,jk) - z_elem_a(ji,jj,jk) / z_elem_b(ji,jj,jk-1) * z_elem_a(ji,jj,jk-1)
712            END DO
713         END DO
714      END DO
715      DO jk = jpk-1, 2, -1                         ! Third recurrence : Ek = ( Lk - Uk * Ek+1 ) / Dk
716         DO jj = 2, jpjm1
717            DO ji = fs_2, fs_jpim1    ! vector opt.
718               psi(ji,jj,jk) = ( z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk) * psi(ji,jj,jk+1) ) / z_elem_b(ji,jj,jk)
719            END DO
720         END DO
721      END DO
722
723      ! Set dissipation
724      !----------------
725
726      SELECT CASE ( nn_clos )
727      !
728      CASE( 0 )               ! k-kl  (Mellor-Yamada)
729         DO jk = 1, jpkm1
730            DO jj = 2, jpjm1
731               DO ji = fs_2, fs_jpim1   ! vector opt.
732                  eps(ji,jj,jk) = rc03 * en(ji,jj,jk) * en(ji,jj,jk) * SQRT( en(ji,jj,jk) ) / psi(ji,jj,jk)
733               END DO
734            END DO
735         END DO
736         !
737      CASE( 1 )               ! k-eps
738         DO jk = 1, jpkm1
739            DO jj = 2, jpjm1
740               DO ji = fs_2, fs_jpim1   ! vector opt.
741                  eps(ji,jj,jk) = psi(ji,jj,jk)
742               END DO
743            END DO
744         END DO
745         !
746      CASE( 2 )               ! k-w
747         DO jk = 1, jpkm1
748            DO jj = 2, jpjm1
749               DO ji = fs_2, fs_jpim1   ! vector opt.
750                  eps(ji,jj,jk) = rc04 * en(ji,jj,jk) * psi(ji,jj,jk) 
751               END DO
752            END DO
753         END DO
754         !
755      CASE( 3 )               ! generic
756         zcoef = rc0**( 3._wp  + rpp/rnn )
757         zex1  =      ( 1.5_wp + rmm/rnn )
758         zex2  = -1._wp / rnn
759         DO jk = 1, jpkm1
760            DO jj = 2, jpjm1
761               DO ji = fs_2, fs_jpim1   ! vector opt.
762                  eps(ji,jj,jk) = zcoef * en(ji,jj,jk)**zex1 * psi(ji,jj,jk)**zex2
763               END DO
764            END DO
765         END DO
766         !
767      END SELECT
768
769      ! Limit dissipation rate under stable stratification
770      ! --------------------------------------------------
771      DO jk = 1, jpkm1 ! Note that this set boundary conditions on mxln at the same time
772         DO jj = 2, jpjm1
773            DO ji = fs_2, fs_jpim1    ! vector opt.
774               ! limitation
775               eps(ji,jj,jk)  = MAX( eps(ji,jj,jk), rn_epsmin )
776               mxln(ji,jj,jk)  = rc03 * en(ji,jj,jk) * SQRT( en(ji,jj,jk) ) / eps(ji,jj,jk)
777               ! Galperin criterium (NOTE : Not required if the proper value of C3 in stable cases is calculated)
778               zrn2 = MAX( rn2(ji,jj,jk), rsmall )
779               mxln(ji,jj,jk) = MIN(  rn_clim_galp * SQRT( 2._wp * en(ji,jj,jk) / zrn2 ), mxln(ji,jj,jk)  )
780            END DO
781         END DO
782      END DO 
783
784      !
785      ! Stability function and vertical viscosity and diffusivity
786      ! ---------------------------------------------------------
787      !
788      SELECT CASE ( nn_stab_func )
789      !
790      CASE ( 0 , 1 )             ! Galperin or Kantha-Clayson stability functions
791         DO jk = 2, jpkm1
792            DO jj = 2, jpjm1
793               DO ji = fs_2, fs_jpim1   ! vector opt.
794                  ! zcof =  l²/q²
795                  zcof = mxlb(ji,jj,jk) * mxlb(ji,jj,jk) / ( 2._wp*eb(ji,jj,jk) )
796                  ! Gh = -N²l²/q²
797                  gh = - rn2(ji,jj,jk) * zcof
798                  gh = MIN( gh, rgh0   )
799                  gh = MAX( gh, rghmin )
800                  ! Stability functions from Kantha and Clayson (if C2=C3=0 => Galperin)
801                  sh = ra2*( 1._wp-6._wp*ra1/rb1 ) / ( 1.-3.*ra2*gh*(6.*ra1+rb2*( 1._wp-rc3 ) ) )
802                  sm = ( rb1**(-1._wp/3._wp) + ( 18._wp*ra1*ra1 + 9._wp*ra1*ra2*(1._wp-rc2) )*sh*gh ) / (1._wp-9._wp*ra1*ra2*gh)
803                  !
804                  ! Store stability function in avmu and avmv
805                  avmu(ji,jj,jk) = rc_diff * sh * tmask(ji,jj,jk)
806                  avmv(ji,jj,jk) = rc_diff * sm * tmask(ji,jj,jk)
807               END DO
808            END DO
809         END DO
810         !
811      CASE ( 2, 3 )               ! Canuto stability functions
812         DO jk = 2, jpkm1
813            DO jj = 2, jpjm1
814               DO ji = fs_2, fs_jpim1   ! vector opt.
815                  ! zcof =  l²/q²
816                  zcof = mxlb(ji,jj,jk)*mxlb(ji,jj,jk) / ( 2._wp * eb(ji,jj,jk) )
817                  ! Gh = -N²l²/q²
818                  gh = - rn2(ji,jj,jk) * zcof
819                  gh = MIN( gh, rgh0   )
820                  gh = MAX( gh, rghmin )
821                  gh = gh * rf6
822                  ! Gm =  M²l²/q² Shear number
823                  shr = shear(ji,jj,jk) / MAX( avm(ji,jj,jk), rsmall )
824                  gm = MAX( shr * zcof , 1.e-10 )
825                  gm = gm * rf6
826                  gm = MIN ( (rd0 - rd1*gh + rd3*gh*gh) / (rd2-rd4*gh) , gm )
827                  ! Stability functions from Canuto
828                  rcff = rd0 - rd1*gh +rd2*gm + rd3*gh*gh - rd4*gh*gm + rd5*gm*gm
829                  sm = (rs0 - rs1*gh + rs2*gm) / rcff
830                  sh = (rs4 - rs5*gh + rs6*gm) / rcff
831                  !
832                  ! Store stability function in avmu and avmv
833                  avmu(ji,jj,jk) = rc_diff * sh * tmask(ji,jj,jk)
834                  avmv(ji,jj,jk) = rc_diff * sm * tmask(ji,jj,jk)
835               END DO
836            END DO
837         END DO
838         !
839      END SELECT
840
841      ! Boundary conditions on stability functions for momentum (Neumann):
842      ! Lines below are useless if GOTM style Dirichlet conditions are used
843      zcoef = rcm_sf / SQRT( 2._wp )
844      DO jj = 2, jpjm1
845         DO ji = fs_2, fs_jpim1   ! vector opt.
846            avmv(ji,jj,1) = zcoef
847         END DO
848      END DO
849      zcoef = rc0 / SQRT( 2._wp )
850      DO jj = 2, jpjm1
851         DO ji = fs_2, fs_jpim1   ! vector opt.
852            avmv(ji,jj,mbkt(ji,jj)+1) = zcoef
853         END DO
854      END DO
855
856      ! Compute diffusivities/viscosities
857      ! The computation below could be restrained to jk=2 to jpkm1 if GOTM style Dirichlet conditions are used
858      DO jk = 1, jpk
859         DO jj = 2, jpjm1
860            DO ji = fs_2, fs_jpim1   ! vector opt.
861               zsqen         = SQRT( 2._wp * en(ji,jj,jk) ) * mxln(ji,jj,jk)
862               zav           = zsqen * avmu(ji,jj,jk)
863               avt(ji,jj,jk) = MAX( zav, avtb(jk) )*tmask(ji,jj,jk) ! apply mask for zdfmxl routine
864               zav           = zsqen * avmv(ji,jj,jk)
865               avm(ji,jj,jk) = MAX( zav, avmb(jk) ) ! Note that avm is not masked at the surface and the bottom
866            END DO
867         END DO
868      END DO
869      !
870      ! Lateral boundary conditions (sign unchanged)
871      avt(:,:,1)  = 0._wp
872      CALL lbc_lnk( avm, 'W', 1. )   ;   CALL lbc_lnk( avt, 'W', 1. )
873
874      DO jk = 2, jpkm1            !* vertical eddy viscosity at u- and v-points
875         DO jj = 2, jpjm1
876            DO ji = fs_2, fs_jpim1   ! vector opt.
877               avmu(ji,jj,jk) = 0.5 * ( avm(ji,jj,jk) + avm(ji+1,jj  ,jk) ) * umask(ji,jj,jk)
878               avmv(ji,jj,jk) = 0.5 * ( avm(ji,jj,jk) + avm(ji  ,jj+1,jk) ) * vmask(ji,jj,jk)
879            END DO
880         END DO
881      END DO
882      avmu(:,:,1) = 0._wp             ;   avmv(:,:,1) = 0._wp                 ! set surface to zero
883      CALL lbc_lnk( avmu, 'U', 1. )   ;   CALL lbc_lnk( avmv, 'V', 1. )       ! Lateral boundary conditions
884
885      IF(ln_ctl) THEN
886         CALL prt_ctl( tab3d_1=en  , clinfo1=' gls  - e: ', tab3d_2=avt, clinfo2=' t: ', ovlap=1, kdim=jpk)
887         CALL prt_ctl( tab3d_1=avmu, clinfo1=' gls  - u: ', mask1=umask,                   &
888            &          tab3d_2=avmv, clinfo2=       ' v: ', mask2=vmask, ovlap=1, kdim=jpk )
889      ENDIF
890      !
891      CALL wrk_dealloc( jpi,jpj, zdep, zflxs, zhsro )
892      CALL wrk_dealloc( jpi,jpj,jpk, eb, mxlb, shear, eps, zwall_psi )
893      !
894      IF( nn_timing == 1 )  CALL timing_stop('zdf_gls')
895      !
896      !
897   END SUBROUTINE zdf_gls
898
899
900   SUBROUTINE zdf_gls_init
901      !!----------------------------------------------------------------------
902      !!                  ***  ROUTINE zdf_gls_init  ***
903      !!                     
904      !! ** Purpose :   Initialization of the vertical eddy diffivity and
905      !!      viscosity when using a gls turbulent closure scheme
906      !!
907      !! ** Method  :   Read the namzdf_gls namelist and check the parameters
908      !!      called at the first timestep (nit000)
909      !!
910      !! ** input   :   Namlist namzdf_gls
911      !!
912      !! ** Action  :   Increase by 1 the nstop flag is setting problem encounter
913      !!
914      !!----------------------------------------------------------------------
915      USE dynzdf_exp
916      USE trazdf_exp
917      !
918      INTEGER ::   jk    ! dummy loop indices
919      REAL(wp)::   zcr   ! local scalar
920      !!
921      NAMELIST/namzdf_gls/rn_emin, rn_epsmin, ln_length_lim, &
922         &            rn_clim_galp, ln_crban, ln_sigpsi,     &
923         &            rn_crban, rn_charn,                    &
924         &            nn_tkebc_surf, nn_tkebc_bot,           &
925         &            nn_psibc_surf, nn_psibc_bot,           &
926         &            nn_stab_func, nn_clos
927      !!----------------------------------------------------------
928      !
929      IF( nn_timing == 1 )  CALL timing_start('zdf_gls_init')
930      !
931      REWIND( numnam )                 !* Read Namelist namzdf_gls
932      READ  ( numnam, namzdf_gls )
933
934      IF(lwp) THEN                     !* Control print
935         WRITE(numout,*)
936         WRITE(numout,*) 'zdf_gls_init : gls turbulent closure scheme'
937         WRITE(numout,*) '~~~~~~~~~~~~'
938         WRITE(numout,*) '   Namelist namzdf_gls : set gls mixing parameters'
939         WRITE(numout,*) '      minimum value of en                           rn_emin       = ', rn_emin
940         WRITE(numout,*) '      minimum value of eps                          rn_epsmin     = ', rn_epsmin
941         WRITE(numout,*) '      Limit dissipation rate under stable stratif.  ln_length_lim = ', ln_length_lim
942         WRITE(numout,*) '      Galperin limit (Standard: 0.53, Holt: 0.26)   rn_clim_galp  = ', rn_clim_galp
943         WRITE(numout,*) '      TKE Surface boundary condition                nn_tkebc_surf = ', nn_tkebc_surf
944         WRITE(numout,*) '      TKE Bottom boundary condition                 nn_tkebc_bot  = ', nn_tkebc_bot
945         WRITE(numout,*) '      PSI Surface boundary condition                nn_psibc_surf = ', nn_psibc_surf
946         WRITE(numout,*) '      PSI Bottom boundary condition                 nn_psibc_bot  = ', nn_psibc_bot
947         WRITE(numout,*) '      Craig and Banner scheme                       ln_crban      = ', ln_crban
948         WRITE(numout,*) '      Modify psi Schmidt number (wb case)           ln_sigpsi     = ', ln_sigpsi
949         WRITE(numout,*) '      Craig and Banner coefficient                  rn_crban       = ', rn_crban
950         WRITE(numout,*) '      Charnock coefficient                          rn_charn       = ', rn_charn
951         WRITE(numout,*) '      Stability functions                           nn_stab_func   = ', nn_stab_func
952         WRITE(numout,*) '      Type of closure                               nn_clos        = ', nn_clos
953         WRITE(numout,*) '   Hard coded parameters'
954         WRITE(numout,*) '      Surface roughness (m)                         hsro          = ', hsro
955         WRITE(numout,*) '      Bottom roughness (m)                          hbro          = ', hbro
956      ENDIF
957
958      !                                !* allocate gls arrays
959      IF( zdf_gls_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'zdf_gls_init : unable to allocate arrays' )
960
961      !                                !* Check of some namelist values
962      IF( nn_tkebc_surf < 0 .OR. nn_tkebc_surf > 1 ) CALL ctl_stop( 'bad flag: nn_tkebc_surf is 0 or 1' )
963      IF( nn_psibc_surf < 0 .OR. nn_psibc_surf > 1 ) CALL ctl_stop( 'bad flag: nn_psibc_surf is 0 or 1' )
964      IF( nn_tkebc_bot  < 0 .OR. nn_tkebc_bot  > 1 ) CALL ctl_stop( 'bad flag: nn_tkebc_bot is 0 or 1' )
965      IF( nn_psibc_bot  < 0 .OR. nn_psibc_bot  > 1 ) CALL ctl_stop( 'bad flag: nn_psibc_bot is 0 or 1' )
966      IF( nn_stab_func  < 0 .OR. nn_stab_func  > 3 ) CALL ctl_stop( 'bad flag: nn_stab_func is 0, 1, 2 and 3' )
967      IF( nn_clos       < 0 .OR. nn_clos       > 3 ) CALL ctl_stop( 'bad flag: nn_clos is 0, 1, 2 or 3' )
968
969      SELECT CASE ( nn_clos )          !* set the parameters for the chosen closure
970      !
971      CASE( 0 )                              ! k-kl  (Mellor-Yamada)
972         !
973         IF(lwp) WRITE(numout,*) 'The choosen closure is k-kl closed to the classical Mellor-Yamada'
974         rpp     = 0._wp
975         rmm     = 1._wp
976         rnn     = 1._wp
977         rsc_tke = 1.96_wp
978         rsc_psi = 1.96_wp
979         rpsi1   = 0.9_wp
980         rpsi3p  = 1._wp
981         rpsi2   = 0.5_wp
982         !
983         SELECT CASE ( nn_stab_func )
984         CASE( 0, 1 )   ;   rpsi3m = 2.53_wp       ! G88 or KC stability functions
985         CASE( 2 )      ;   rpsi3m = 2.38_wp       ! Canuto A stability functions
986         CASE( 3 )      ;   rpsi3m = 2.38          ! Canuto B stability functions (caution : constant not identified)
987         END SELECT
988         !
989      CASE( 1 )                              ! k-eps
990         !
991         IF(lwp) WRITE(numout,*) 'The choosen closure is k-eps'
992         rpp     =  3._wp
993         rmm     =  1.5_wp
994         rnn     = -1._wp
995         rsc_tke =  1._wp
996         rsc_psi =  1.3_wp  ! Schmidt number for psi
997         rpsi1   =  1.44_wp
998         rpsi3p  =  1._wp
999         rpsi2   =  1.92_wp
1000         !
1001         SELECT CASE ( nn_stab_func )
1002         CASE( 0, 1 )   ;   rpsi3m = -0.52_wp      ! G88 or KC stability functions
1003         CASE( 2 )      ;   rpsi3m = -0.629_wp     ! Canuto A stability functions
1004         CASE( 3 )      ;   rpsi3m = -0.566        ! Canuto B stability functions
1005         END SELECT
1006         !
1007      CASE( 2 )                              ! k-omega
1008         !
1009         IF(lwp) WRITE(numout,*) 'The choosen closure is k-omega'
1010         rpp     = -1._wp
1011         rmm     =  0.5_wp
1012         rnn     = -1._wp
1013         rsc_tke =  2._wp
1014         rsc_psi =  2._wp
1015         rpsi1   =  0.555_wp
1016         rpsi3p  =  1._wp
1017         rpsi2   =  0.833_wp
1018         !
1019         SELECT CASE ( nn_stab_func )
1020         CASE( 0, 1 )   ;   rpsi3m = -0.58_wp       ! G88 or KC stability functions
1021         CASE( 2 )      ;   rpsi3m = -0.64_wp       ! Canuto A stability functions
1022         CASE( 3 )      ;   rpsi3m = -0.64_wp       ! Canuto B stability functions caution : constant not identified)
1023         END SELECT
1024         !
1025      CASE( 3 )                              ! generic
1026         !
1027         IF(lwp) WRITE(numout,*) 'The choosen closure is generic'
1028         rpp     = 2._wp
1029         rmm     = 1._wp
1030         rnn     = -0.67_wp
1031         rsc_tke = 0.8_wp
1032         rsc_psi = 1.07_wp
1033         rpsi1   = 1._wp
1034         rpsi3p  = 1._wp
1035         rpsi2   = 1.22_wp
1036         !
1037         SELECT CASE ( nn_stab_func )
1038         CASE( 0, 1 )   ;   rpsi3m = 0.1_wp         ! G88 or KC stability functions
1039         CASE( 2 )      ;   rpsi3m = 0.05_wp        ! Canuto A stability functions
1040         CASE( 3 )      ;   rpsi3m = 0.05_wp        ! Canuto B stability functions caution : constant not identified)
1041         END SELECT
1042         !
1043      END SELECT
1044
1045      !
1046      SELECT CASE ( nn_stab_func )     !* set the parameters of the stability functions
1047      !
1048      CASE ( 0 )                             ! Galperin stability functions
1049         !
1050         IF(lwp) WRITE(numout,*) 'Stability functions from Galperin'
1051         rc2     =  0._wp
1052         rc3     =  0._wp
1053         rc_diff =  1._wp
1054         rc0     =  0.5544_wp
1055         rcm_sf  =  0.9884_wp
1056         rghmin  = -0.28_wp
1057         rgh0    =  0.0233_wp
1058         rghcri  =  0.02_wp
1059         !
1060      CASE ( 1 )                             ! Kantha-Clayson stability functions
1061         !
1062         IF(lwp) WRITE(numout,*) 'Stability functions from Kantha-Clayson'
1063         rc2     =  0.7_wp
1064         rc3     =  0.2_wp
1065         rc_diff =  1._wp
1066         rc0     =  0.5544_wp
1067         rcm_sf  =  0.9884_wp
1068         rghmin  = -0.28_wp
1069         rgh0    =  0.0233_wp
1070         rghcri  =  0.02_wp
1071         !
1072      CASE ( 2 )                             ! Canuto A stability functions
1073         !
1074         IF(lwp) WRITE(numout,*) 'Stability functions from Canuto A'
1075         rs0 = 1.5_wp * rl1 * rl5*rl5
1076         rs1 = -rl4*(rl6+rl7) + 2._wp*rl4*rl5*(rl1-(1._wp/3._wp)*rl2-rl3) + 1.5_wp*rl1*rl5*rl8
1077         rs2 = -(3._wp/8._wp) * rl1*(rl6*rl6-rl7*rl7)
1078         rs4 = 2._wp * rl5
1079         rs5 = 2._wp * rl4
1080         rs6 = (2._wp/3._wp) * rl5 * ( 3._wp*rl3*rl3 - rl2*rl2 ) - 0.5_wp * rl5*rl1 * (3._wp*rl3-rl2)   &
1081            &                                                    + 0.75_wp * rl1 * ( rl6 - rl7 )
1082         rd0 = 3._wp * rl5*rl5
1083         rd1 = rl5 * ( 7._wp*rl4 + 3._wp*rl8 )
1084         rd2 = rl5*rl5 * ( 3._wp*rl3*rl3 - rl2*rl2 ) - 0.75_wp*(rl6*rl6 - rl7*rl7 )
1085         rd3 = rl4 * ( 4._wp*rl4 + 3._wp*rl8)
1086         rd4 = rl4 * ( rl2 * rl6 - 3._wp*rl3*rl7 - rl5*(rl2*rl2 - rl3*rl3 ) ) + rl5*rl8 * ( 3._wp*rl3*rl3 - rl2*rl2 )
1087         rd5 = 0.25_wp * ( rl2*rl2 - 3._wp *rl3*rl3 ) * ( rl6*rl6 - rl7*rl7 )
1088         rc0 = 0.5268_wp
1089         rf6 = 8._wp / (rc0**6._wp)
1090         rc_diff = SQRT(2._wp) / (rc0**3._wp)
1091         rcm_sf  =  0.7310_wp
1092         rghmin  = -0.28_wp
1093         rgh0    =  0.0329_wp
1094         rghcri  =  0.03_wp
1095         !
1096      CASE ( 3 )                             ! Canuto B stability functions
1097         !
1098         IF(lwp) WRITE(numout,*) 'Stability functions from Canuto B'
1099         rs0 = 1.5_wp * rm1 * rm5*rm5
1100         rs1 = -rm4 * (rm6+rm7) + 2._wp * rm4*rm5*(rm1-(1._wp/3._wp)*rm2-rm3) + 1.5_wp * rm1*rm5*rm8
1101         rs2 = -(3._wp/8._wp) * rm1 * (rm6*rm6-rm7*rm7 )
1102         rs4 = 2._wp * rm5
1103         rs5 = 2._wp * rm4
1104         rs6 = (2._wp/3._wp) * rm5 * (3._wp*rm3*rm3-rm2*rm2) - 0.5_wp * rm5*rm1*(3._wp*rm3-rm2) + 0.75_wp * rm1*(rm6-rm7)
1105         rd0 = 3._wp * rm5*rm5
1106         rd1 = rm5 * (7._wp*rm4 + 3._wp*rm8)
1107         rd2 = rm5*rm5 * (3._wp*rm3*rm3 - rm2*rm2) - 0.75_wp * (rm6*rm6 - rm7*rm7)
1108         rd3 = rm4 * ( 4._wp*rm4 + 3._wp*rm8 )
1109         rd4 = rm4 * ( rm2*rm6 -3._wp*rm3*rm7 - rm5*(rm2*rm2 - rm3*rm3) ) + rm5 * rm8 * ( 3._wp*rm3*rm3 - rm2*rm2 )
1110         rd5 = 0.25_wp * ( rm2*rm2 - 3._wp*rm3*rm3 ) * ( rm6*rm6 - rm7*rm7 )
1111         rc0 = 0.5268_wp            !!       rc0 = 0.5540_wp (Warner ...) to verify !
1112         rf6 = 8._wp / ( rc0**6._wp )
1113         rc_diff = SQRT(2._wp)/(rc0**3.)
1114         rcm_sf  =  0.7470_wp
1115         rghmin  = -0.28_wp
1116         rgh0    =  0.0444_wp
1117         rghcri  =  0.0414_wp
1118         !
1119      END SELECT
1120   
1121      !                                !* Set Schmidt number for psi diffusion in the wave breaking case
1122      !                                     ! See Eq. (13) of Carniel et al, OM, 30, 225-239, 2009
1123      !                                     !  or Eq. (17) of Burchard, JPO, 31, 3133-3145, 2001
1124      IF( ln_sigpsi .AND. ln_crban ) THEN
1125         zcr = SQRT( 1.5_wp*rsc_tke ) * rcm_sf / vkarmn
1126         rsc_psi0 = vkarmn*vkarmn / ( rpsi2 * rcm_sf*rcm_sf )                       & 
1127        &         * ( rnn*rnn - 4._wp/3._wp * zcr*rnn*rmm - 1._wp/3._wp * zcr*rnn   &
1128        &           + 2._wp/9._wp * rmm * zcr*zcr + 4._wp/9._wp * zcr*zcr * rmm*rmm )                                 
1129      ELSE
1130         rsc_psi0 = rsc_psi
1131      ENDIF
1132 
1133      !                                !* Shear free turbulence parameters
1134      !
1135      ra_sf  = -4._wp * rnn * SQRT( rsc_tke ) / ( (1._wp+4._wp*rmm) * SQRT( rsc_tke )   &
1136         &                                      - SQRT(rsc_tke + 24._wp*rsc_psi0*rpsi2 ) )
1137      rl_sf  = rc0 * SQRT( rc0 / rcm_sf )                                                                   &
1138         &         * SQRT(  (  (1._wp + 4._wp*rmm + 8._wp*rmm*rmm) * rsc_tke                                &
1139         &                   + 12._wp * rsc_psi0 * rpsi2                                                    &
1140         &                   - (1._wp + 4._wp*rmm) * SQRT( rsc_tke*(rsc_tke+ 24._wp*rsc_psi0*rpsi2) )  )    &
1141         &                / ( 12._wp*rnn*rnn )                                                              )
1142
1143      !
1144      IF(lwp) THEN                     !* Control print
1145         WRITE(numout,*)
1146         WRITE(numout,*) 'Limit values'
1147         WRITE(numout,*) '~~~~~~~~~~~~'
1148         WRITE(numout,*) 'Parameter  m = ',rmm
1149         WRITE(numout,*) 'Parameter  n = ',rnn
1150         WRITE(numout,*) 'Parameter  p = ',rpp
1151         WRITE(numout,*) 'rpsi1   = ',rpsi1
1152         WRITE(numout,*) 'rpsi2   = ',rpsi2
1153         WRITE(numout,*) 'rpsi3m  = ',rpsi3m
1154         WRITE(numout,*) 'rpsi3p  = ',rpsi3p
1155         WRITE(numout,*) 'rsc_tke = ',rsc_tke
1156         WRITE(numout,*) 'rsc_psi = ',rsc_psi
1157         WRITE(numout,*) 'rsc_psi0 = ',rsc_psi0
1158         WRITE(numout,*) 'rc0     = ',rc0
1159         WRITE(numout,*)
1160         WRITE(numout,*) 'Shear free turbulence parameters:'
1161         WRITE(numout,*) 'rcm_sf  = ',rcm_sf
1162         WRITE(numout,*) 'ra_sf   = ',ra_sf
1163         WRITE(numout,*) 'rl_sf   = ',rl_sf
1164         WRITE(numout,*)
1165      ENDIF
1166
1167      !                                !* Constants initialization
1168      rc02  = rc0  * rc0   ;   rc02r = 1. / rc02
1169      rc03  = rc02 * rc0
1170      rc04  = rc03 * rc0
1171      rc03_sqrt2_galp = rc03 / SQRT(2._wp) / rn_clim_galp
1172      rsbc_mb   = 0.5_wp * (15.8_wp*rn_crban)**(2._wp/3._wp)               ! Surf. bound. cond. from Mellor and Blumberg
1173      rsbc_std  = 3.75_wp                                                  ! Surf. bound. cond. standard (prod=diss)
1174      rsbc_tke1 = (-rsc_tke*rn_crban/(rcm_sf*ra_sf*rl_sf))**(2._wp/3._wp)  ! k_eps = 53.  Dirichlet + Wave breaking
1175      rsbc_tke2 = 0.5_wp / rau0
1176      rsbc_tke3 = rdt * rn_crban                                                         ! Neumann + Wave breaking
1177      rsbc_zs   = rn_charn / grav                                                        ! Charnock formula
1178      rsbc_psi1 = rc0**rpp * rsbc_tke1**rmm * rl_sf**rnn                           ! Dirichlet + Wave breaking
1179      rsbc_psi2 = -0.5_wp * rdt * rc0**rpp * rnn * vkarmn**rnn / rsc_psi                   ! Neumann + NO Wave breaking
1180      rsbc_psi3 = -0.5_wp * rdt * rc0**rpp * rl_sf**rnn / rsc_psi  * (rnn + rmm*ra_sf) ! Neumann + Wave breaking
1181      rfact_tke = -0.5_wp / rsc_tke * rdt               ! Cst used for the Diffusion term of tke
1182      rfact_psi = -0.5_wp / rsc_psi * rdt               ! Cst used for the Diffusion term of tke
1183
1184      !                                !* Wall proximity function
1185      zwall (:,:,:) = 1._wp * tmask(:,:,:)
1186
1187      !                                !* set vertical eddy coef. to the background value
1188      DO jk = 1, jpk
1189         avt (:,:,jk) = avtb(jk) * tmask(:,:,jk)
1190         avm (:,:,jk) = avmb(jk) * tmask(:,:,jk)
1191         avmu(:,:,jk) = avmb(jk) * umask(:,:,jk)
1192         avmv(:,:,jk) = avmb(jk) * vmask(:,:,jk)
1193      END DO
1194      !                             
1195      CALL gls_rst( nit000, 'READ' )   !* read or initialize all required files
1196      !
1197      IF( nn_timing == 1 )  CALL timing_stop('zdf_gls_init')
1198      !
1199   END SUBROUTINE zdf_gls_init
1200
1201
1202   SUBROUTINE gls_rst( kt, cdrw )
1203      !!---------------------------------------------------------------------
1204      !!                   ***  ROUTINE ts_rst  ***
1205      !!                     
1206      !! ** Purpose :   Read or write TKE file (en) in restart file
1207      !!
1208      !! ** Method  :   use of IOM library
1209      !!                if the restart does not contain TKE, en is either
1210      !!                set to rn_emin or recomputed (nn_igls/=0)
1211      !!----------------------------------------------------------------------
1212      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
1213      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
1214      !
1215      INTEGER ::   jit, jk   ! dummy loop indices
1216      INTEGER ::   id1, id2, id3, id4, id5, id6
1217      INTEGER ::   ji, jj, ikbu, ikbv
1218      REAL(wp)::   cbx, cby
1219      !!----------------------------------------------------------------------
1220      !
1221      IF( TRIM(cdrw) == 'READ' ) THEN        ! Read/initialise
1222         !                                   ! ---------------
1223         IF( ln_rstart ) THEN                   !* Read the restart file
1224            id1 = iom_varid( numror, 'en'   , ldstop = .FALSE. )
1225            id2 = iom_varid( numror, 'avt'  , ldstop = .FALSE. )
1226            id3 = iom_varid( numror, 'avm'  , ldstop = .FALSE. )
1227            id4 = iom_varid( numror, 'avmu' , ldstop = .FALSE. )
1228            id5 = iom_varid( numror, 'avmv' , ldstop = .FALSE. )
1229            id6 = iom_varid( numror, 'mxln' , ldstop = .FALSE. )
1230            !
1231            IF( MIN( id1, id2, id3, id4, id5, id6 ) > 0 ) THEN        ! all required arrays exist
1232               CALL iom_get( numror, jpdom_autoglo, 'en'    , en     )
1233               CALL iom_get( numror, jpdom_autoglo, 'avt'   , avt    )
1234               CALL iom_get( numror, jpdom_autoglo, 'avm'   , avm    )
1235               CALL iom_get( numror, jpdom_autoglo, 'avmu'  , avmu   )
1236               CALL iom_get( numror, jpdom_autoglo, 'avmv'  , avmv   )
1237               CALL iom_get( numror, jpdom_autoglo, 'mxln'  , mxln   )
1238            ELSE                       
1239               IF(lwp) WRITE(numout,*) ' ===>>>> : previous run without gls scheme, en and mxln computed by iterative loop'
1240               en  (:,:,:) = rn_emin
1241               mxln(:,:,:) = 0.001       
1242               DO jit = nit000 + 1, nit000 + 10   ;   CALL zdf_gls( jit )   ;   END DO
1243            ENDIF
1244         ELSE                                   !* Start from rest
1245            IF(lwp) WRITE(numout,*) ' ===>>>> : Initialisation of en and mxln by background values'
1246            en  (:,:,:) = rn_emin
1247            mxln(:,:,:) = 0.001       
1248         ENDIF
1249         !
1250      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN   ! Create restart file
1251         !                                   ! -------------------
1252         IF(lwp) WRITE(numout,*) '---- gls-rst ----'
1253         CALL iom_rstput( kt, nitrst, numrow, 'en'   , en    )
1254         CALL iom_rstput( kt, nitrst, numrow, 'avt'  , avt   )
1255         CALL iom_rstput( kt, nitrst, numrow, 'avm'  , avm   )
1256         CALL iom_rstput( kt, nitrst, numrow, 'avmu' , avmu  )
1257         CALL iom_rstput( kt, nitrst, numrow, 'avmv' , avmv  )
1258         CALL iom_rstput( kt, nitrst, numrow, 'mxln' , mxln  )
1259         !
1260      ENDIF
1261      !
1262   END SUBROUTINE gls_rst
1263
1264#else
1265   !!----------------------------------------------------------------------
1266   !!   Dummy module :                                        NO TKE scheme
1267   !!----------------------------------------------------------------------
1268   LOGICAL, PUBLIC, PARAMETER ::   lk_zdfgls = .FALSE.   !: TKE flag
1269CONTAINS
1270   SUBROUTINE zdf_gls_init           ! Empty routine
1271      WRITE(*,*) 'zdf_gls_init: You should not have seen this print! error?'
1272   END SUBROUTINE zdf_gls_init
1273   SUBROUTINE zdf_gls( kt )          ! Empty routine
1274      WRITE(*,*) 'zdf_gls: You should not have seen this print! error?', kt
1275   END SUBROUTINE zdf_gls
1276   SUBROUTINE gls_rst( kt, cdrw )          ! Empty routine
1277      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
1278      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
1279      WRITE(*,*) 'gls_rst: You should not have seen this print! error?', kt, cdrw
1280   END SUBROUTINE gls_rst
1281#endif
1282
1283   !!======================================================================
1284END MODULE zdfgls
1285
Note: See TracBrowser for help on using the repository browser.