New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
step.F90 in branches/2012/dev_LOCEAN_2012/NEMOGCM/NEMO/OPA_SRC – NEMO

source: branches/2012/dev_LOCEAN_2012/NEMOGCM/NEMO/OPA_SRC/step.F90 @ 3655

Last change on this file since 3655 was 3655, checked in by cetlod, 10 years ago

branch LOCEAN 2012 : update branch according to Sebastien Masson sunday modifications, see ticket #1019

  • Property svn:keywords set to Id
File size: 15.9 KB
Line 
1MODULE step
2   !!======================================================================
3   !!                       ***  MODULE step  ***
4   !! Time-stepping    : manager of the ocean, tracer and ice time stepping
5   !!======================================================================
6   !! History :  OPA  !  1991-03  (G. Madec)  Original code
7   !!             -   !  1991-11  (G. Madec)
8   !!             -   !  1992-06  (M. Imbard)  add a first output record
9   !!             -   !  1996-04  (G. Madec)  introduction of dynspg
10   !!             -   !  1996-04  (M.A. Foujols)  introduction of passive tracer
11   !!            8.0  !  1997-06  (G. Madec)  new architecture of call
12   !!            8.2  !  1997-06  (G. Madec, M. Imbard, G. Roullet)  free surface
13   !!             -   !  1999-02  (G. Madec, N. Grima)  hpg implicit
14   !!             -   !  2000-07  (J-M Molines, M. Imbard)  Open Bondary Conditions
15   !!   NEMO     1.0  !  2002-06  (G. Madec)  free form, suppress macro-tasking
16   !!             -   !  2004-08  (C. Talandier) New trends organization
17   !!             -   !  2005-01  (C. Ethe) Add the KPP closure scheme
18   !!             -   !  2005-11  (G. Madec)  Reorganisation of tra and dyn calls
19   !!             -   !  2006-01  (L. Debreu, C. Mazauric)  Agrif implementation
20   !!             -   !  2006-07  (S. Masson)  restart using iom
21   !!            3.2  !  2009-02  (G. Madec, R. Benshila)  reintroduicing z*-coordinate
22   !!             -   !  2009-06  (S. Masson, G. Madec)  TKE restart compatible with key_cpl
23   !!            3.3  !  2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
24   !!             -   !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase + merge TRC-TRA
25   !!            3.4  !  2011-04  (G. Madec, C. Ethe) Merge of dtatem and dtasal
26   !!----------------------------------------------------------------------
27
28   !!----------------------------------------------------------------------
29   !!   stp             : OPA system time-stepping
30   !!----------------------------------------------------------------------
31   USE step_oce         ! time stepping definition modules
32#if defined key_top
33   USE trcstp           ! passive tracer time-stepping      (trc_stp routine)
34#endif
35#if defined key_agrif
36   USE agrif_opa_sponge ! Momemtum and tracers sponges
37#endif
38   USE restart          ! restart
39
40   IMPLICIT NONE
41   PRIVATE
42
43   PUBLIC   stp   ! called by opa.F90
44
45   !! * Substitutions
46#  include "domzgr_substitute.h90"
47#  include "zdfddm_substitute.h90"
48   !!----------------------------------------------------------------------
49   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
50   !! $Id$
51   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
52   !!----------------------------------------------------------------------
53CONTAINS
54
55#if defined key_agrif
56   SUBROUTINE stp( )
57      INTEGER             ::   kstp   ! ocean time-step index
58#else
59   SUBROUTINE stp( kstp )
60      INTEGER, INTENT(in) ::   kstp   ! ocean time-step index
61#endif
62      !!----------------------------------------------------------------------
63      !!                     ***  ROUTINE stp  ***
64      !!                     
65      !! ** Purpose : - Time stepping of OPA (momentum and active tracer eqs.)
66      !!              - Time stepping of LIM (dynamic and thermodynamic eqs.)
67      !!              - Tme stepping  of TRC (passive tracer eqs.)
68      !!
69      !! ** Method  : -1- Update forcings and data 
70      !!              -2- Update ocean physics
71      !!              -3- Compute the t and s trends
72      !!              -4- Update t and s
73      !!              -5- Compute the momentum trends
74      !!              -6- Update the horizontal velocity
75      !!              -7- Compute the diagnostics variables (rd,N2, div,cur,w)
76      !!              -8- Outputs and diagnostics
77      !!----------------------------------------------------------------------
78      INTEGER ::   jk       ! dummy loop indice
79      INTEGER ::   indic    ! error indicator if < 0
80      !! ---------------------------------------------------------------------
81
82#if defined key_agrif
83      kstp = nit000 + Agrif_Nb_Step()
84!      IF ( Agrif_Root() .and. lwp) Write(*,*) '---'
85!      IF (lwp) Write(*,*) 'Grid Number',Agrif_Fixed(),' time step ',kstp
86# if defined key_iomput
87      IF( Agrif_Nbstepint() == 0 )   CALL iom_swap
88# endif   
89#endif   
90                             indic = 0                ! reset to no error condition
91      IF( kstp /= nit000 )   CALL day( kstp )         ! Calendar (day was already called at nit000 in day_init)
92                             CALL iom_setkt( kstp )   ! say to iom that we are at time step kstp
93
94      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
95      ! Update data, open boundaries, surface boundary condition (including sea-ice)
96      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
97                         CALL sbc    ( kstp )         ! Sea Boundary Condition (including sea-ice)
98      IF( lk_tide    )   CALL sbc_tide( kstp )
99      IF( lk_obc     )   CALL obc_dta( kstp )         ! update dynamic and tracer data at open boundaries
100      IF( lk_obc     )   CALL obc_rad( kstp )         ! compute phase velocities at open boundaries
101      IF( lk_bdy     )   CALL bdy_dta( kstp, time_offset=+1 ) ! update dynamic and tracer data at open boundaries
102
103      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
104      !  Ocean dynamics : ssh, wn, hdiv, rot                                 !
105      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
106                         CALL ssh_wzv( kstp )         ! after ssh & vertical velocity
107
108      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
109      ! Ocean physics update                (ua, va, tsa used as workspace)
110      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
111                         CALL bn2( tsb, rn2b )        ! before Brunt-Vaisala frequency
112                         CALL bn2( tsn, rn2  )        ! now    Brunt-Vaisala frequency
113      !
114      !  VERTICAL PHYSICS   
115                         CALL zdf_bfr( kstp )         ! bottom friction
116                         
117      !                                               ! Vertical eddy viscosity and diffusivity coefficients
118      IF( lk_zdfric  )   CALL zdf_ric( kstp )            ! Richardson number dependent Kz
119      IF( lk_zdftke  )   CALL zdf_tke( kstp )            ! TKE closure scheme for Kz
120      IF( lk_zdfgls  )   CALL zdf_gls( kstp )            ! GLS closure scheme for Kz
121      IF( lk_zdfkpp  )   CALL zdf_kpp( kstp )            ! KPP closure scheme for Kz
122      IF( lk_zdfcst  )   THEN                            ! Constant Kz (reset avt, avm[uv] to the background value)
123         avt (:,:,:) = rn_avt0 * tmask(:,:,:)
124         avmu(:,:,:) = rn_avm0 * umask(:,:,:)
125         avmv(:,:,:) = rn_avm0 * vmask(:,:,:)
126      ENDIF
127      IF( ln_rnf_mouth ) THEN                         ! increase diffusivity at rivers mouths
128         DO jk = 2, nkrnf   ;   avt(:,:,jk) = avt(:,:,jk) + 2.e0 * rn_avt_rnf * rnfmsk(:,:) * tmask(:,:,jk)   ;   END DO
129      ENDIF
130      IF( ln_zdfevd  )   CALL zdf_evd( kstp )         ! enhanced vertical eddy diffusivity
131
132      IF( lk_zdftmx  )   CALL zdf_tmx( kstp )         ! tidal vertical mixing
133
134      IF( lk_zdfddm .AND. .NOT. lk_zdfkpp )   &
135         &               CALL zdf_ddm( kstp )         ! double diffusive mixing
136         
137                         CALL zdf_mxl( kstp )         ! mixed layer depth
138
139                                                      ! write TKE or GLS information in the restart file
140      IF( lrst_oce .AND. lk_zdftke )   CALL tke_rst( kstp, 'WRITE' )
141      IF( lrst_oce .AND. lk_zdfgls )   CALL gls_rst( kstp, 'WRITE' )
142      !
143      !  LATERAL  PHYSICS
144      !
145      IF( lk_ldfslp ) THEN                            ! slope of lateral mixing
146                         CALL eos( tsb, rhd )                ! before in situ density
147         IF( ln_zps )    CALL zps_hde( kstp, jpts, tsb, gtsu, gtsv,  &    ! Partial steps: before horizontal gradient
148            &                                      rhd, gru , grv  )      ! of t, s, rd at the last ocean level
149         IF( ln_traldf_grif ) THEN                           ! before slope for Griffies operator
150                         CALL ldf_slp_grif( kstp )
151         ELSE
152                         CALL ldf_slp( kstp, rhd, rn2b )     ! before slope for Madec operator
153         ENDIF
154      ENDIF
155#if defined key_traldf_c2d
156      IF( lk_traldf_eiv )   CALL ldf_eiv( kstp )      ! eddy induced velocity coefficient
157#endif
158
159      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
160      ! diagnostics and outputs             (ua, va, tsa used as workspace)
161      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
162      IF( lk_floats  )   CALL flo_stp( kstp )         ! drifting Floats
163      IF( lk_diahth  )   CALL dia_hth( kstp )         ! Thermocline depth (20 degres isotherm depth)
164      IF( lk_diafwb  )   CALL dia_fwb( kstp )         ! Fresh water budget diagnostics
165      IF( ln_diaptr  )   CALL dia_ptr( kstp )         ! Poleward TRansports diagnostics
166      IF( lk_diadct  )   CALL dia_dct( kstp )         ! Transports
167      IF( lk_diaar5  )   CALL dia_ar5( kstp )         ! ar5 diag
168      IF( lk_diaharm )   CALL dia_harm( kstp )        ! Tidal harmonic analysis
169                         CALL dia_wri( kstp )         ! ocean model: outputs
170
171#if defined key_top
172      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
173      ! Passive Tracer Model
174      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
175                         CALL trc_stp( kstp )         ! time-stepping
176#endif
177
178      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
179      ! Active tracers                              (ua, va used as workspace)
180      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
181                             tsa(:,:,:,:) = 0.e0            ! set tracer trends to zero
182
183      IF(  ln_asmiau .AND. &
184         & ln_trainc     )   CALL tra_asm_inc( kstp )       ! apply tracer assimilation increment
185                             CALL tra_sbc    ( kstp )       ! surface boundary condition
186      IF( ln_traqsr      )   CALL tra_qsr    ( kstp )       ! penetrative solar radiation qsr
187      IF( ln_trabbc      )   CALL tra_bbc    ( kstp )       ! bottom heat flux
188      IF( lk_trabbl      )   CALL tra_bbl    ( kstp )       ! advective (and/or diffusive) bottom boundary layer scheme
189      IF( ln_tradmp      )   CALL tra_dmp    ( kstp )       ! internal damping trends
190                             CALL tra_adv    ( kstp )       ! horizontal & vertical advection
191      IF( lk_zdfkpp      )   CALL tra_kpp    ( kstp )       ! KPP non-local tracer fluxes
192                             CALL tra_ldf    ( kstp )       ! lateral mixing
193#if defined key_agrif
194      IF(.NOT. Agrif_Root()) CALL Agrif_Sponge_tra          ! tracers sponge
195#endif
196                             CALL tra_zdf    ( kstp )       ! vertical mixing and after tracer fields
197
198      IF( ln_dynhpg_imp  ) THEN                             ! semi-implicit hpg (time stepping then eos)
199         IF( ln_zdfnpc   )   CALL tra_npc( kstp )                ! update after fields by non-penetrative convection
200                             CALL tra_nxt( kstp )                ! tracer fields at next time step
201                             CALL eos    ( tsa, rhd, rhop )      ! Time-filtered in situ density for hpg computation
202         IF( ln_zps      )   CALL zps_hde( kstp, jpts, tsa, gtsu, gtsv,  &    ! zps: time filtered hor. derivative
203            &                                          rhd, gru , grv  )      ! of t, s, rd at the last ocean level
204         
205      ELSE                                                  ! centered hpg  (eos then time stepping)
206                             CALL eos    ( tsn, rhd, rhop )      ! now in situ density for hpg computation
207         IF( ln_zps      )   CALL zps_hde( kstp, jpts, tsn, gtsu, gtsv,  &    ! zps: now hor. derivative
208            &                                          rhd, gru , grv  )      ! of t, s, rd at the last ocean level
209         IF( ln_zdfnpc   )   CALL tra_npc( kstp )                ! update after fields by non-penetrative convection
210                             CALL tra_nxt( kstp )                ! tracer fields at next time step
211      ENDIF 
212
213      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
214      ! Dynamics                                    (tsa used as workspace)
215      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
216                               ua(:,:,:) = 0.e0             ! set dynamics trends to zero
217                               va(:,:,:) = 0.e0
218
219      IF(  ln_asmiau .AND. &
220         & ln_dyninc       )   CALL dyn_asm_inc( kstp )     ! apply dynamics assimilation increment
221      IF( ln_neptsimp )        CALL dyn_nept_cor( kstp )    ! subtract Neptune velocities (simplified)
222                               CALL dyn_adv( kstp )         ! advection (vector or flux form)
223                               CALL dyn_vor( kstp )         ! vorticity term including Coriolis
224                               CALL dyn_ldf( kstp )         ! lateral mixing
225      IF( ln_neptsimp )        CALL dyn_nept_cor( kstp )    ! add Neptune velocities (simplified)
226#if defined key_agrif
227      IF(.NOT. Agrif_Root())   CALL Agrif_Sponge_dyn        ! momemtum sponge
228#endif
229                               CALL dyn_hpg( kstp )         ! horizontal gradient of Hydrostatic pressure
230                               CALL dyn_bfr( kstp )         ! bottom friction   
231                               CALL dyn_zdf( kstp )         ! vertical diffusion
232                               CALL dyn_spg( kstp, indic )  ! surface pressure gradient
233                               CALL dyn_nxt( kstp )         ! lateral velocity at next time step
234
235                               CALL ssh_nxt( kstp )         ! sea surface height at next time step
236
237      IF( ln_diahsb        )   CALL dia_hsb( kstp )         ! - ML - global conservation diagnostics
238      IF( lk_diaobs  )         CALL dia_obs( kstp )         ! obs-minus-model (assimilation) diagnostics (call after dynamics update)
239
240      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
241      ! Control and restarts
242      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
243                               CALL stp_ctl( kstp, indic )
244      IF( indic < 0        )   THEN
245                               CALL ctl_stop( 'step: indic < 0' )
246                               CALL dia_wri_state( 'output.abort', kstp )
247      ENDIF
248      IF( kstp == nit000   )   CALL iom_close( numror )     ! close input  ocean restart file
249      IF( lrst_oce         )   CALL rst_write    ( kstp )   ! write output ocean restart file
250      IF( lk_obc           )   CALL obc_rst_write( kstp )   ! write open boundary restart file
251
252      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
253      ! Trends                              (ua, va, tsa used as workspace)
254      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
255      IF( nstop == 0 ) THEN                         
256         IF( lk_trddyn     )   CALL trd_dwr( kstp )         ! trends: dynamics
257         IF( lk_trdtra     )   CALL trd_twr( kstp )         ! trends: active tracers
258         IF( lk_trdmld     )   CALL trd_mld( kstp )         ! trends: Mixed-layer
259         IF( lk_trdvor     )   CALL trd_vor( kstp )         ! trends: vorticity budget
260      ENDIF
261
262      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
263      ! Coupled mode
264      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
265      IF( lk_cpl           )   CALL sbc_cpl_snd( kstp )     ! coupled mode : field exchanges
266      !
267      IF( nn_timing == 1 .AND.  kstp == nit000  )   CALL timing_reset
268      !
269   END SUBROUTINE stp
270
271   !!======================================================================
272END MODULE step
Note: See TracBrowser for help on using the repository browser.