New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_muscl.F90 in branches/2012/dev_LOCEAN_UKMO_CMCC_INGV_2012/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2012/dev_LOCEAN_UKMO_CMCC_INGV_2012/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_muscl.F90 @ 3666

Last change on this file since 3666 was 3666, checked in by cetlod, 12 years ago

commit the changes resulting for the merged branches, see ticket #1025
  • Property svn:keywords set to Id
File size: 16.0 KB
Line 
1MODULE traadv_muscl
2   !!======================================================================
3   !!                       ***  MODULE  traadv_muscl  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!======================================================================
6   !! History :       !  2000-06  (A.Estublier)  for passive tracers
7   !!                 !  2001-08  (E.Durand, G.Madec)  adapted for T & S
8   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            3.2  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
10   !!            3.4  !  2012-06  (P. Oddo) include the upstream where needed
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   tra_adv_muscl : update the tracer trend with the horizontal
15   !!                   and vertical advection trends using MUSCL scheme
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean dynamics and active tracers
18   USE dom_oce         ! ocean space and time domain
19   USE trdmod_oce      ! tracers trends
20   USE trdtra      ! tracers trends
21   USE eosbn2          ! equation of state
22   USE in_out_manager  ! I/O manager
23   USE dynspg_oce      ! choice/control of key cpp for surface pressure gradient
24   USE trabbl          ! tracers: bottom boundary layer
25   USE sbcrnf          ! river runoffs
26   USE lib_mpp         ! distribued memory computing
27   USE lbclnk          ! ocean lateral boundary condition (or mpp link)
28   USE diaptr          ! poleward transport diagnostics
29   USE trc_oce         ! share passive tracers/Ocean variables
30   USE wrk_nemo        ! Memory Allocation
31   USE timing          ! Timing
32   USE eosbn2          ! equation of state
33   USE sbcrnf          ! river runoffs
34
35   IMPLICIT NONE
36   PRIVATE
37
38   PUBLIC   tra_adv_muscl  ! routine called by step.F90
39
40   LOGICAL  :: l_trd       ! flag to compute trends
41
42   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: upsmsk !: mixed upstream/centered scheme near some straits
43   !                                                             !  and in closed seas (orca 2 and 4 configurations)
44   !! * Substitutions
45#  include "domzgr_substitute.h90"
46#  include "vectopt_loop_substitute.h90"
47   !!----------------------------------------------------------------------
48   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
49   !! $Id$
50   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
51   !!----------------------------------------------------------------------
52CONTAINS
53
54   SUBROUTINE tra_adv_muscl( kt, kit000, cdtype, p2dt, pun, pvn, pwn, &
55      &                                        ptb, pta, kjpt )
56      !!----------------------------------------------------------------------
57      !!                    ***  ROUTINE tra_adv_muscl  ***
58      !!
59      !! ** Purpose :   Compute the now trend due to total advection of T and
60      !!      S using a MUSCL scheme (Monotone Upstream-centered Scheme for
61      !!      Conservation Laws) and add it to the general tracer trend.
62      !!
63      !! ** Method  : MUSCL scheme plus centered scheme at ocean boundaries
64      !!
65      !! ** Action  : - update (ta,sa) with the now advective tracer trends
66      !!              - save trends
67      !!
68      !! References : Estubier, A., and M. Levy, Notes Techn. Pole de Modelisation
69      !!              IPSL, Sept. 2000 (http://www.lodyc.jussieu.fr/opa)
70      !!----------------------------------------------------------------------
71      USE oce     , ONLY:   zwx   => ua    , zwy   => va          ! (ua,va) used as workspace
72      !
73      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
74      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
75      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
76      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
77      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
78      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
79      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb             ! before tracer field
80      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
81      !
82      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
83      REAL(wp) ::   zu, z0u, zzwx, zw         ! local scalars
84      REAL(wp) ::   zv, z0v, zzwy, z0w        !   -      -
85      REAL(wp) ::   ztra, zbtr, zdt, zalpha   !   -      -
86      REAL(wp), POINTER, DIMENSION(:,:,:) :: zslpx, zslpy
87      INTEGER  ::   ierr
88      REAL(wp) ::   zice                             ! temporary scalars
89      REAL(wp), POINTER, DIMENSION(:,:  ) :: ztfreez
90      REAL(wp), POINTER, DIMENSION(:,:,:) :: zind
91      !!----------------------------------------------------------------------
92      !
93      IF( nn_timing == 1 )  CALL timing_start('tra_adv_muscl')
94      !
95      CALL wrk_alloc( jpi, jpj, jpk, zslpx, zslpy )
96      CALL wrk_alloc( jpi, jpj, ztfreez )
97      CALL wrk_alloc( jpi, jpj, jpk, zind )
98      !
99
100      IF( kt == kit000 )  THEN
101         IF(lwp) WRITE(numout,*)
102         IF(lwp) WRITE(numout,*) 'tra_adv : MUSCL advection scheme on ', cdtype
103         IF(lwp) WRITE(numout,*) '~~~~~~~'
104         IF(lwp) WRITE(numout,*)
105         !
106         !
107         IF (.not. ALLOCATED(upsmsk))THEN
108             ALLOCATE( upsmsk(jpi,jpj), STAT=ierr )
109             IF( ierr /= 0 )   CALL ctl_stop('STOP', 'tra_adv_muscl: unable to allocate array')
110         ENDIF
111         !
112         upsmsk(:,:) = 0._wp                             ! not upstream by default
113         !
114         l_trd = .FALSE.
115         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
116      ENDIF
117
118      !
119      ! Upstream / centered scheme indicator
120      ! ------------------------------------
121      ztfreez(:,:) = tfreez( tsn(:,:,1,jp_sal) )
122      DO jk = 1, jpk
123         DO jj = 1, jpj
124            DO ji = 1, jpi
125               !                                        ! below ice covered area (if tn < "freezing"+0.1 )
126               IF( tsn(ji,jj,jk,jp_tem) <= ztfreez(ji,jj) + 0.1_wp ) THEN   ;   zice = 1.e0
127               ELSE                                                         ;   zice = 0.e0
128               ENDIF
129               zind(ji,jj,jk) = MAX (   &
130                  rnfmsk(ji,jj) * rnfmsk_z(jk),      &  ! near runoff mouths (& closed sea outflows)
131                  upsmsk(ji,jj)               ,      &  ! some of some straits
132                  zice                               &  ! below ice covered area (if tn < "freezing"+0.1 )
133                  &                  ) * tmask(ji,jj,jk)
134               zind(ji,jj,jk) = 1 - zind(ji,jj,jk)
135            END DO
136         END DO
137      END DO
138      !                                                     ! ===========
139      DO jn = 1, kjpt                                       ! tracer loop
140         !                                                  ! ===========
141         ! I. Horizontal advective fluxes
142         ! ------------------------------
143         ! first guess of the slopes
144         zwx(:,:,jpk) = 0.e0   ;   zwy(:,:,jpk) = 0.e0        ! bottom values
145         ! interior values
146         DO jk = 1, jpkm1
147            DO jj = 1, jpjm1     
148               DO ji = 1, fs_jpim1   ! vector opt.
149                  zwx(ji,jj,jk) = umask(ji,jj,jk) * ( ptb(ji+1,jj,jk,jn) - ptb(ji,jj,jk,jn) )
150                  zwy(ji,jj,jk) = vmask(ji,jj,jk) * ( ptb(ji,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
151               END DO
152           END DO
153         END DO
154         !
155         CALL lbc_lnk( zwx, 'U', -1. )                        ! lateral boundary conditions on zwx, zwy   (changed sign)
156         CALL lbc_lnk( zwy, 'V', -1. )
157         !                                             !-- Slopes of tracer
158         zslpx(:,:,jpk) = 0.e0   ;   zslpy(:,:,jpk) = 0.e0    ! bottom values
159         DO jk = 1, jpkm1                                     ! interior values
160            DO jj = 2, jpj
161               DO ji = fs_2, jpi   ! vector opt.
162                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji-1,jj  ,jk) )   &
163                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji-1,jj  ,jk) ) )
164                  zslpy(ji,jj,jk) =                    ( zwy(ji,jj,jk) + zwy(ji  ,jj-1,jk) )   &
165                     &            * ( 0.25 + SIGN( 0.25, zwy(ji,jj,jk) * zwy(ji  ,jj-1,jk) ) )
166               END DO
167            END DO
168         END DO
169         !
170         DO jk = 1, jpkm1                                     ! Slopes limitation
171            DO jj = 2, jpj
172               DO ji = fs_2, jpi   ! vector opt.
173                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji  ,jj,jk) ),   &
174                     &                                                 2.*ABS( zwx  (ji-1,jj,jk) ),   &
175                     &                                                 2.*ABS( zwx  (ji  ,jj,jk) ) )
176                  zslpy(ji,jj,jk) = SIGN( 1., zslpy(ji,jj,jk) ) * MIN(    ABS( zslpy(ji,jj  ,jk) ),   &
177                     &                                                 2.*ABS( zwy  (ji,jj-1,jk) ),   &
178                     &                                                 2.*ABS( zwy  (ji,jj  ,jk) ) )
179               END DO
180           END DO
181         END DO             ! interior values
182
183         !                                             !-- MUSCL horizontal advective fluxes
184         DO jk = 1, jpkm1                                     ! interior values
185            zdt  = p2dt(jk)
186            DO jj = 2, jpjm1
187               DO ji = fs_2, fs_jpim1   ! vector opt.
188                  ! MUSCL fluxes
189                  z0u = SIGN( 0.5, pun(ji,jj,jk) )
190                  zalpha = 0.5 - z0u
191                  zu  = z0u - 0.5 * pun(ji,jj,jk) * zdt / ( e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk) )
192                  zzwx = ptb(ji+1,jj,jk,jn) + zind(ji,jj,jk) * (zu * zslpx(ji+1,jj,jk))
193                  zzwy = ptb(ji  ,jj,jk,jn) + zind(ji,jj,jk) * (zu * zslpx(ji  ,jj,jk))
194                  zwx(ji,jj,jk) = pun(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
195                  !
196                  z0v = SIGN( 0.5, pvn(ji,jj,jk) )
197                  zalpha = 0.5 - z0v
198                  zv  = z0v - 0.5 * pvn(ji,jj,jk) * zdt / ( e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk) )
199                  zzwx = ptb(ji,jj+1,jk,jn) + zind(ji,jj,jk) * (zv * zslpy(ji,jj+1,jk))
200                  zzwy = ptb(ji,jj  ,jk,jn) + zind(ji,jj,jk) * (zv * zslpy(ji,jj  ,jk))
201                  zwy(ji,jj,jk) = pvn(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
202               END DO
203            END DO
204         END DO
205         !                                                    ! lateral boundary conditions on zwx, zwy   (changed sign)
206         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )
207         !
208         ! Tracer flux divergence at t-point added to the general trend
209         DO jk = 1, jpkm1
210            DO jj = 2, jpjm1     
211               DO ji = fs_2, fs_jpim1   ! vector opt.
212                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
213                  ! horizontal advective trends
214                  ztra = - zbtr * ( zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
215                  &               + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  ) )
216                  ! add it to the general tracer trends
217                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
218               END DO
219           END DO
220         END DO       
221         !                                 ! trend diagnostics (contribution of upstream fluxes)
222         IF( l_trd )  THEN
223            CALL trd_tra( kt, cdtype, jn, jptra_trd_xad, zwx, pun, ptb(:,:,:,jn) )
224            CALL trd_tra( kt, cdtype, jn, jptra_trd_yad, zwy, pvn, ptb(:,:,:,jn) )
225         END IF
226         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
227         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN 
228            IF( jn == jp_tem )  htr_adv(:) = ptr_vj( zwy(:,:,:) )
229            IF( jn == jp_sal )  str_adv(:) = ptr_vj( zwy(:,:,:) )
230         ENDIF
231
232         ! II. Vertical advective fluxes
233         ! -----------------------------
234         !                                             !-- first guess of the slopes
235         zwx (:,:, 1 ) = 0.e0    ;    zwx (:,:,jpk) = 0.e0    ! surface & bottom boundary conditions
236         DO jk = 2, jpkm1                                     ! interior values
237            zwx(:,:,jk) = tmask(:,:,jk) * ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) )
238         END DO
239
240         !                                             !-- Slopes of tracer
241         zslpx(:,:,1) = 0.e0                                  ! surface values
242         DO jk = 2, jpkm1                                     ! interior value
243            DO jj = 1, jpj
244               DO ji = 1, jpi
245                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji,jj,jk+1) )   &
246                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji,jj,jk+1) ) )
247               END DO
248            END DO
249         END DO
250         !                                             !-- Slopes limitation
251         DO jk = 2, jpkm1                                     ! interior values
252            DO jj = 1, jpj
253               DO ji = 1, jpi
254                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji,jj,jk  ) ),   &
255                     &                                                 2.*ABS( zwx  (ji,jj,jk+1) ),   &
256                     &                                                 2.*ABS( zwx  (ji,jj,jk  ) )  )
257               END DO
258            END DO
259         END DO
260         !                                             !-- vertical advective flux
261         !                                                    ! surface values  (bottom already set to zero)
262         IF( lk_vvl ) THEN    ;   zwx(:,:, 1 ) = 0.e0                      !  variable volume
263         ELSE                 ;   zwx(:,:, 1 ) = pwn(:,:,1) * ptb(:,:,1,jn)   ! linear free surface
264         ENDIF 
265         !
266         DO jk = 1, jpkm1                                     ! interior values
267            zdt  = p2dt(jk)
268            DO jj = 2, jpjm1     
269               DO ji = fs_2, fs_jpim1   ! vector opt.
270                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3w(ji,jj,jk+1) )
271                  z0w = SIGN( 0.5, pwn(ji,jj,jk+1) )
272                  zalpha = 0.5 + z0w
273                  zw  = z0w - 0.5 * pwn(ji,jj,jk+1) * zdt * zbtr 
274                  zzwx = ptb(ji,jj,jk+1,jn) + zind(ji,jj,jk) * (zw * zslpx(ji,jj,jk+1))
275                  zzwy = ptb(ji,jj,jk  ,jn) + zind(ji,jj,jk) * (zw * zslpx(ji,jj,jk  ))
276                  zwx(ji,jj,jk+1) = pwn(ji,jj,jk+1) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
277               END DO
278            END DO
279         END DO
280
281         ! Compute & add the vertical advective trend
282         DO jk = 1, jpkm1
283            DO jj = 2, jpjm1     
284               DO ji = fs_2, fs_jpim1   ! vector opt.
285                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
286                  ! vertical advective trends
287                  ztra = - zbtr * ( zwx(ji,jj,jk) - zwx(ji,jj,jk+1) )
288                  ! add it to the general tracer trends
289                  pta(ji,jj,jk,jn) =  pta(ji,jj,jk,jn) + ztra
290               END DO
291            END DO
292         END DO
293         !                                 ! Save the vertical advective trends for diagnostic
294         IF( l_trd ) CALL trd_tra( kt, cdtype, jn, jptra_trd_zad, zwx, pwn, ptb(:,:,:,jn) )
295         !
296      ENDDO
297      !
298      CALL wrk_dealloc( jpi, jpj, jpk, zslpx, zslpy )
299      CALL wrk_dealloc( jpi, jpj, ztfreez )
300      CALL wrk_dealloc( jpi, jpj, jpk, zind )
301      !
302      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_muscl')
303      !
304   END SUBROUTINE tra_adv_muscl
305
306   !!======================================================================
307END MODULE traadv_muscl
Note: See TracBrowser for help on using the repository browser.