source: branches/2012/dev_r3385_NOCS04_HAMF/NEMOGCM/NEMO/OPA_SRC/SBC/sbcfwb.F90 @ 3488

Last change on this file since 3488 was 3488, checked in by acc, 9 years ago

Branch: dev_r3385_NOCS04_HAMF; #665. Stage 3 of 2012 development: Rationalisation of code. Added LIM3 changes, corrected coupled changes and highlighted areas of concern in CICE interface

  • Property svn:keywords set to Id
File size: 11.4 KB
Line 
1MODULE sbcfwb
2   !!======================================================================
3   !!                       ***  MODULE  sbcfwb  ***
4   !! Ocean fluxes   : domain averaged freshwater budget
5   !!======================================================================
6   !! History :  OPA  ! 2001-02  (E. Durand)  Original code
7   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
8   !!            3.0  ! 2006-08  (G. Madec)  Surface module
9   !!            3.2  ! 2009-07  (C. Talandier) emp mean s spread over erp area
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   sbc_fwb      : freshwater budget for global ocean configurations
14   !!                  in free surface and forced mode
15   !!----------------------------------------------------------------------
16   USE oce             ! ocean dynamics and tracers
17   USE dom_oce         ! ocean space and time domain
18   USE sbc_oce         ! surface ocean boundary condition
19   USE phycst          ! physical constants
20   USE sbcrnf          ! ocean runoffs
21   USE sbcssr          ! SS damping terms
22   USE in_out_manager  ! I/O manager
23   USE lib_mpp         ! distribued memory computing library
24   USE wrk_nemo        ! work arrays
25   USE timing          ! Timing
26   USE lbclnk          ! ocean lateral boundary conditions
27   USE lib_fortran
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   sbc_fwb    ! routine called by step
33
34   REAL(wp) ::   a_fwb_b   ! annual domain averaged freshwater budget
35   REAL(wp) ::   a_fwb     ! for 2 year before (_b) and before year.
36   REAL(wp) ::   fwfold    ! fwfold to be suppressed
37   REAL(wp) ::   area      ! global mean ocean surface (interior domain)
38
39   !! * Substitutions
40#  include "domzgr_substitute.h90"
41#  include "vectopt_loop_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
44   !! $Id$
45   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   SUBROUTINE sbc_fwb( kt, kn_fwb, kn_fsbc )
50      !!---------------------------------------------------------------------
51      !!                  ***  ROUTINE sbc_fwb  ***
52      !!
53      !! ** Purpose :   Control the mean sea surface drift
54      !!
55      !! ** Method  :   several ways  depending on kn_fwb
56      !!                =0 no control
57      !!                =1 global mean of emp set to zero at each nn_fsbc time step
58      !!                =2 annual global mean corrected from previous year
59      !!                =3 global mean of emp set to zero at each nn_fsbc time step
60      !!                   & spread out over erp area depending its sign
61      !! Note: if sea ice is embedded it is taken into account when computing the budget
62      !!----------------------------------------------------------------------
63      INTEGER, INTENT( in ) ::   kt       ! ocean time-step index
64      INTEGER, INTENT( in ) ::   kn_fsbc  !
65      INTEGER, INTENT( in ) ::   kn_fwb   ! ocean time-step index
66      !
67      INTEGER  ::   inum, ikty, iyear     ! local integers
68      REAL(wp) ::   z_fwf, z_fwf_nsrf, zsum_fwf, zsum_erp                ! local scalars
69      REAL(wp) ::   zsurf_neg, zsurf_pos, zsurf_tospread, zcoef          !   -      -
70      REAL(wp), POINTER, DIMENSION(:,:) ::   ztmsk_neg, ztmsk_pos, z_wgt ! 2D workspaces
71      REAL(wp), POINTER, DIMENSION(:,:) ::   ztmsk_tospread, zerp_cor    !   -      -
72      !!----------------------------------------------------------------------
73      !
74      IF( nn_timing == 1 )  CALL timing_start('sbc_fwb')
75      !
76      CALL wrk_alloc( jpi,jpj, ztmsk_neg, ztmsk_pos, ztmsk_tospread, z_wgt, zerp_cor )
77      !
78      IF( kt == nit000 ) THEN
79         IF(lwp) THEN
80            WRITE(numout,*)
81            WRITE(numout,*) 'sbc_fwb : FreshWater Budget correction'
82            WRITE(numout,*) '~~~~~~~'
83            IF( kn_fwb == 1 )   WRITE(numout,*) '          instantaneously set to zero'
84            IF( kn_fwb == 2 )   WRITE(numout,*) '          adjusted from previous year budget'
85            IF( kn_fwb == 3 )   WRITE(numout,*) '          fwf set to zero and spread out over erp area'
86         ENDIF
87         !
88         IF( kn_fwb == 3 .AND. nn_sssr /= 2 )   CALL ctl_stop( 'sbc_fwb: nn_fwb = 3 requires nn_sssr = 2, we stop ' )
89         !
90         area = glob_sum( e1e2t(:,:) )           ! interior global domain surface
91         !
92#if ! defined key_lim2 &&  ! defined key_lim3 && ! defined key_cice
93         snwice_mass_b(:,:) = 0.e0               ! no sea-ice model is being used : no snow+ice mass
94         snwice_mass  (:,:) = 0.e0
95#endif
96         !
97      ENDIF
98     
99
100      SELECT CASE ( kn_fwb )
101      !
102      CASE ( 1 )                             !==  global mean fwf set to zero  ==!
103         !
104         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
105            z_fwf = glob_sum( e1e2t(:,:) * ( emp(:,:) - rnf(:,:) -  snwice_fmass(:,:) ) ) / area   ! sum over the global domain
106            zcoef = z_fwf * rcp
107            emp(:,:) = emp(:,:) - z_fwf 
108            qns(:,:) = qns(:,:) + zcoef * sst_m(:,:)  ! account for change to the heat budget due to fw correction
109         ENDIF
110         !
111      CASE ( 2 )                             !==  fwf budget adjusted from the previous year  ==!
112         !
113         IF( kt == nit000 ) THEN                      ! initialisation
114            !                                         ! Read the corrective factor on precipitations (fwfold)
115            CALL ctl_opn( inum, 'EMPave_old.dat', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE. )
116            READ ( inum, "(24X,I8,2ES24.16)" ) iyear, a_fwb_b, a_fwb
117            CLOSE( inum )
118            fwfold = a_fwb                            ! current year freshwater budget correction
119            !                                         ! estimate from the previous year budget
120            IF(lwp)WRITE(numout,*)
121            IF(lwp)WRITE(numout,*)'sbc_fwb : year = ',iyear  , ' freshwater budget correction = ', fwfold
122            IF(lwp)WRITE(numout,*)'          year = ',iyear-1, ' freshwater budget read       = ', a_fwb
123            IF(lwp)WRITE(numout,*)'          year = ',iyear-2, ' freshwater budget read       = ', a_fwb_b
124         ENDIF   
125         !                                         ! Update fwfold if new year start
126         ikty = 365 * 86400 / rdttra(1)    !!bug  use of 365 days leap year or 360d year !!!!!!!
127         IF( MOD( kt, ikty ) == 0 ) THEN
128            a_fwb_b = a_fwb                           ! mean sea level taking into account the ice+snow
129                                                      ! sum over the global domain
130            a_fwb   = glob_sum( e1e2t(:,:) * ( sshn(:,:) + snwice_mass(:,:) * r1_rau0 ) )
131            a_fwb   = a_fwb * 1.e+3 / ( area * 86400. * 365. )     ! convert in Kg/m3/s = mm/s
132!!gm        !                                                      !!bug 365d year
133            fwfold =  a_fwb                           ! current year freshwater budget correction
134            !                                         ! estimate from the previous year budget
135         ENDIF
136         !
137         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN         ! correct the freshwater fluxes
138            zcoef = fwfold * rcp
139            emp(:,:) = emp(:,:) + fwfold
140            qns(:,:) = qns(:,:) - zcoef * sst_m(:,:)  ! account for change to the heat budget due to fw correction
141         ENDIF
142         !
143         IF( kt == nitend .AND. lwp ) THEN            ! save fwfold value in a file
144            CALL ctl_opn( inum, 'EMPave.dat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE., narea )
145            WRITE( inum, "(24X,I8,2ES24.16)" ) nyear, a_fwb_b, a_fwb
146            CLOSE( inum )
147         ENDIF
148         !
149      CASE ( 3 )                             !==  global fwf set to zero and spread out over erp area  ==!
150         !
151         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
152            ztmsk_pos(:,:) = tmask_i(:,:)                      ! Select <0 and >0 area of erp
153            WHERE( erp < 0._wp )   ztmsk_pos = 0._wp
154            ztmsk_neg(:,:) = tmask_i(:,:) - ztmsk_pos(:,:)
155            !
156            zsurf_neg = glob_sum( e1e2t(:,:)*ztmsk_neg(:,:) )  ! Area filled by <0 and >0 erp
157            zsurf_pos = glob_sum( e1e2t(:,:)*ztmsk_pos(:,:) )
158            !                                                  ! fwf global mean (excluding ocean to ice/snow exchanges)
159            z_fwf     = glob_sum( e1e2t(:,:) * ( emp(:,:) - rnf(:,:) - snwice_fmass(:,:) ) ) / area
160            !           
161            IF( z_fwf < 0._wp ) THEN         ! spread out over >0 erp area to increase evaporation
162                zsurf_tospread      = zsurf_pos
163                ztmsk_tospread(:,:) = ztmsk_pos(:,:)
164            ELSE                             ! spread out over <0 erp area to increase precipitation
165                zsurf_tospread      = zsurf_neg
166                ztmsk_tospread(:,:) = ztmsk_neg(:,:)
167            ENDIF
168            !
169            zsum_fwf   = glob_sum( e1e2t(:,:) * z_fwf )         ! fwf global mean over <0 or >0 erp area
170!!gm :  zsum_fwf   = z_fwf * area   ???  it is right?  I think so....
171            z_fwf_nsrf =  zsum_fwf / ( zsurf_tospread + rsmall )
172            !                                                  ! weight to respect erp field 2D structure
173            zsum_erp   = glob_sum( ztmsk_tospread(:,:) * erp(:,:) * e1e2t(:,:) )
174            z_wgt(:,:) = ztmsk_tospread(:,:) * erp(:,:) / ( zsum_erp + rsmall )
175            !                                                  ! final correction term to apply
176            zerp_cor(:,:) = -1. * z_fwf_nsrf * zsurf_tospread * z_wgt(:,:)
177            !
178!!gm   ===>>>>  lbc_lnk should be useless as all the computation is done over the whole domain !
179            CALL lbc_lnk( zerp_cor, 'T', 1. )
180            !
181            emp(:,:) = emp(:,:) + zerp_cor(:,:)
182            qns(:,:) = qns(:,:) - zerp_cor(:,:) * rcp * sst_m(:,:)  ! account for change to the heat budget due to fw correction
183            erp(:,:) = erp(:,:) + zerp_cor(:,:)
184            !
185            IF( nprint == 1 .AND. lwp ) THEN                   ! control print
186               IF( z_fwf < 0._wp ) THEN
187                  WRITE(numout,*)'   z_fwf < 0'
188                  WRITE(numout,*)'   SUM(erp+)     = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv'
189               ELSE
190                  WRITE(numout,*)'   z_fwf >= 0'
191                  WRITE(numout,*)'   SUM(erp-)     = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv'
192               ENDIF
193               WRITE(numout,*)'   SUM(empG)     = ', SUM( z_fwf*e1e2t(:,:) )*1.e-9,' Sv'
194               WRITE(numout,*)'   z_fwf         = ', z_fwf      ,' Kg/m2/s'
195               WRITE(numout,*)'   z_fwf_nsrf    = ', z_fwf_nsrf ,' Kg/m2/s'
196               WRITE(numout,*)'   MIN(zerp_cor) = ', MINVAL(zerp_cor) 
197               WRITE(numout,*)'   MAX(zerp_cor) = ', MAXVAL(zerp_cor) 
198            ENDIF
199         ENDIF
200         !
201      CASE DEFAULT                           !==  you should never be there  ==!
202         CALL ctl_stop( 'sbc_fwb : wrong nn_fwb value for the FreshWater Budget correction, choose either 1, 2 or 3' )
203         !
204      END SELECT
205      !
206      CALL wrk_dealloc( jpi,jpj, ztmsk_neg, ztmsk_pos, ztmsk_tospread, z_wgt, zerp_cor )
207      !
208      IF( nn_timing == 1 )  CALL timing_stop('sbc_fwb')
209      !
210   END SUBROUTINE sbc_fwb
211
212   !!======================================================================
213END MODULE sbcfwb
Note: See TracBrowser for help on using the repository browser.