source: branches/2012/dev_r3385_NOCS04_HAMF/NEMOGCM/NEMO/OPA_SRC/SBC/sbcmod.F90 @ 3402

Last change on this file since 3402 was 3402, checked in by acc, 9 years ago

Branch: dev_r3385_NOCS04_HAMF; #665. Stage 2 of 2012 development: suppression of emps array and introduction of sfx (salt flux) array with associated code to setup the options for embedding the seaice into the ocean

  • Property svn:keywords set to Id
File size: 23.4 KB
Line 
1MODULE sbcmod
2   !!======================================================================
3   !!                       ***  MODULE  sbcmod  ***
4   !! Surface module :  provide to the ocean its surface boundary condition
5   !!======================================================================
6   !! History :  3.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.1  ! 2008-08  (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface
8   !!            3.3  ! 2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
9   !!            3.3  ! 2010-10  (S. Masson)  add diurnal cycle
10   !!            3.3  ! 2010-09  (D. Storkey) add ice boundary conditions (BDY)
11   !!             -   ! 2010-11  (G. Madec) ice-ocean stress always computed at each ocean time-step
12   !!             -   ! 2010-10  (J. Chanut, C. Bricaud, G. Madec)  add the surface pressure forcing
13   !!            3.4  ! 2011-11  (C. Harris) CICE added as an option
14   !!----------------------------------------------------------------------
15
16   !!----------------------------------------------------------------------
17   !!   sbc_init       : read namsbc namelist
18   !!   sbc            : surface ocean momentum, heat and freshwater boundary conditions
19   !!----------------------------------------------------------------------
20   USE oce              ! ocean dynamics and tracers
21   USE dom_oce          ! ocean space and time domain
22   USE phycst           ! physical constants
23   USE sbc_oce          ! Surface boundary condition: ocean fields
24   USE sbc_ice          ! Surface boundary condition: ice fields
25   USE sbcdcy           ! surface boundary condition: diurnal cycle
26   USE sbcssm           ! surface boundary condition: sea-surface mean variables
27   USE sbcapr           ! surface boundary condition: atmospheric pressure
28   USE sbcana           ! surface boundary condition: analytical formulation
29   USE sbcflx           ! surface boundary condition: flux formulation
30   USE sbcblk_clio      ! surface boundary condition: bulk formulation : CLIO
31   USE sbcblk_core      ! surface boundary condition: bulk formulation : CORE
32   USE sbcblk_mfs       ! surface boundary condition: bulk formulation : MFS
33   USE sbcice_if        ! surface boundary condition: ice-if sea-ice model
34   USE sbcice_lim       ! surface boundary condition: LIM 3.0 sea-ice model
35   USE sbcice_lim_2     ! surface boundary condition: LIM 2.0 sea-ice model
36   USE sbcice_cice      ! surface boundary condition: CICE    sea-ice model
37   USE sbccpl           ! surface boundary condition: coupled florulation
38   USE cpl_oasis3, ONLY:lk_cpl      ! are we in coupled mode?
39   USE sbcssr           ! surface boundary condition: sea surface restoring
40   USE sbcrnf           ! surface boundary condition: runoffs
41   USE sbcfwb           ! surface boundary condition: freshwater budget
42   USE closea           ! closed sea
43   USE bdy_par          ! for lk_bdy
44   USE bdyice_lim2      ! unstructured open boundary data  (bdy_ice_lim_2 routine)
45
46   USE prtctl           ! Print control                    (prt_ctl routine)
47   USE restart          ! ocean restart
48   USE iom              ! IOM library
49   USE in_out_manager   ! I/O manager
50   USE lib_mpp          ! MPP library
51   USE timing           ! Timing
52   USE sbcwave          ! Wave module
53
54   IMPLICIT NONE
55   PRIVATE
56
57   PUBLIC   sbc        ! routine called by step.F90
58   PUBLIC   sbc_init   ! routine called by opa.F90
59   
60   INTEGER ::   nsbc   ! type of surface boundary condition (deduced from namsbc informations)
61     
62   !! * Substitutions
63#  include "domzgr_substitute.h90"
64   !!----------------------------------------------------------------------
65   !! NEMO/OPA 4.0 , NEMO-consortium (2011)
66   !! $Id$
67   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
68   !!----------------------------------------------------------------------
69CONTAINS
70
71   SUBROUTINE sbc_init
72      !!---------------------------------------------------------------------
73      !!                    ***  ROUTINE sbc_init ***
74      !!
75      !! ** Purpose :   Initialisation of the ocean surface boundary computation
76      !!
77      !! ** Method  :   Read the namsbc namelist and set derived parameters
78      !!
79      !! ** Action  : - read namsbc parameters
80      !!              - nsbc: type of sbc
81      !!----------------------------------------------------------------------
82      INTEGER ::   icpt   ! local integer
83      !!
84      NAMELIST/namsbc/ nn_fsbc   , ln_ana    , ln_flx,  ln_blk_clio, ln_blk_core, ln_cpl,   &
85         &             ln_blk_mfs, ln_apr_dyn, nn_ice,  nn_ice_embd, ln_dm2dc   , ln_rnf,   &
86         &             ln_ssr    , nn_fwb    , ln_cdgw
87      !!----------------------------------------------------------------------
88
89      IF(lwp) THEN
90         WRITE(numout,*)
91         WRITE(numout,*) 'sbc_init : surface boundary condition setting'
92         WRITE(numout,*) '~~~~~~~~ '
93      ENDIF
94
95      REWIND( numnam )           ! Read Namelist namsbc
96      READ  ( numnam, namsbc )
97
98      !                          ! overwrite namelist parameter using CPP key information
99      IF( Agrif_Root() ) THEN                ! AGRIF zoom
100        IF( lk_lim2 )   nn_ice      = 2
101        IF( lk_lim3 )   nn_ice      = 3
102        IF( lk_cice )   nn_ice      = 4
103      ENDIF
104      IF( cp_cfg == 'gyre' ) THEN            ! GYRE configuration
105          ln_ana      = .TRUE.   
106          nn_ice      =   0
107      ENDIF
108     
109      IF(lwp) THEN               ! Control print
110         WRITE(numout,*) '        Namelist namsbc (partly overwritten with CPP key setting)'
111         WRITE(numout,*) '           frequency update of sbc (and ice)             nn_fsbc     = ', nn_fsbc
112         WRITE(numout,*) '           Type of sbc : '
113         WRITE(numout,*) '              analytical formulation                     ln_ana      = ', ln_ana
114         WRITE(numout,*) '              flux       formulation                     ln_flx      = ', ln_flx
115         WRITE(numout,*) '              CLIO bulk  formulation                     ln_blk_clio = ', ln_blk_clio
116         WRITE(numout,*) '              CORE bulk  formulation                     ln_blk_core = ', ln_blk_core
117         WRITE(numout,*) '              MFS  bulk  formulation                     ln_blk_mfs  = ', ln_blk_mfs
118         WRITE(numout,*) '              coupled    formulation (T if key_sbc_cpl)  ln_cpl      = ', ln_cpl
119         WRITE(numout,*) '           Misc. options of sbc : '
120         WRITE(numout,*) '              Patm gradient added in ocean & ice Eqs.    ln_apr_dyn  = ', ln_apr_dyn
121         WRITE(numout,*) '              ice management in the sbc (=0/1/2/3)       nn_ice      = ', nn_ice 
122         WRITE(numout,*) '              ice-ocean embedded/levitating (=0/1/2)     nn_ice_embd = ', nn_ice_embd
123         WRITE(numout,*) '              daily mean to diurnal cycle qsr            ln_dm2dc    = ', ln_dm2dc 
124         WRITE(numout,*) '              runoff / runoff mouths                     ln_rnf      = ', ln_rnf
125         WRITE(numout,*) '              Sea Surface Restoring on SST and/or SSS    ln_ssr      = ', ln_ssr
126         WRITE(numout,*) '              FreshWater Budget control  (=0/1/2)        nn_fwb      = ', nn_fwb
127         WRITE(numout,*) '              closed sea (=0/1) (set in namdom)          nn_closea   = ', nn_closea
128      ENDIF
129
130      !                              ! allocate sbc arrays
131      IF( sbc_oce_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_oce arrays' )
132
133      !                          ! Checks:
134      IF( .NOT. ln_rnf ) THEN                      ! no specific treatment in vicinity of river mouths
135         ln_rnf_mouth  = .false.                     
136         IF( sbc_rnf_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_rnf arrays' )
137         nkrnf         = 0
138         rnf     (:,:) = 0.0_wp
139         rnfmsk  (:,:) = 0.0_wp
140         rnfmsk_z(:)   = 0.0_wp
141      ENDIF
142      IF( nn_ice == 0  )   fr_i(:,:) = 0.e0        ! no ice in the domain, ice fraction is always zero
143
144      sfx(:,:) = 0.0_wp                            ! the salt flux due to freezing/melting will be computed (i.e. will be non-zero)
145                                                   ! only if sea-ice is present
146
147      !                                            ! restartability   
148      IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 .OR.   &
149          MOD( nstock             , nn_fsbc) /= 0 ) THEN
150         WRITE(ctmp1,*) 'experiment length (', nitend - nit000 + 1, ') or nstock (', nstock,   &
151            &           ' is NOT a multiple of nn_fsbc (', nn_fsbc, ')'
152         CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' )
153      ENDIF
154      !
155      IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 )   &
156         &  CALL ctl_warn( 'nn_fsbc is NOT a multiple of the number of time steps in a day' )
157      !
158      IF( ( nn_ice == 2 .OR. nn_ice ==3 ) .AND. .NOT.( ln_blk_clio .OR. ln_blk_core .OR. lk_cpl ) )   &
159         &   CALL ctl_stop( 'LIM sea-ice model requires a bulk formulation or coupled configuration' )
160      IF( nn_ice == 4 .AND. .NOT.( ln_blk_core .OR. lk_cpl ) )   &
161         &   CALL ctl_stop( 'CICE sea-ice model requires ln_blk_core or lk_cpl' )
162      IF( nn_ice == 4 .AND. ( .NOT. ( cp_cfg == 'orca' ) .OR. lk_agrif ) )   &
163         &   CALL ctl_stop( 'CICE sea-ice model currently only available in a global ORCA configuration without AGRIF' )
164     
165      IF( ln_dm2dc )   nday_qsr = -1   ! initialisation flag
166
167      IF( ln_dm2dc .AND. .NOT.( ln_flx .OR. ln_blk_core ) )   &
168         &   CALL ctl_stop( 'diurnal cycle into qsr field from daily values requires a flux or core-bulk formulation' )
169     
170      IF( ln_dm2dc .AND. ( ( NINT(rday) / ( nn_fsbc * NINT(rdt) ) )  < 8 ) )   &
171         &   CALL ctl_warn( 'diurnal cycle for qsr: the sampling of the diurnal cycle is too small...' )
172
173       !drag coefficient read from wave model definable only with mfs bulk formulae and core
174       IF(ln_cdgw .AND. .NOT.(ln_blk_mfs .OR. ln_blk_core) )              &
175          &   CALL ctl_stop( 'drag coefficient read from wave model definable only with mfs bulk formulae and core')
176     
177      !                          ! Choice of the Surface Boudary Condition (set nsbc)
178      icpt = 0
179      IF( ln_ana          ) THEN   ;   nsbc =  1   ; icpt = icpt + 1   ;   ENDIF       ! analytical      formulation
180      IF( ln_flx          ) THEN   ;   nsbc =  2   ; icpt = icpt + 1   ;   ENDIF       ! flux            formulation
181      IF( ln_blk_clio     ) THEN   ;   nsbc =  3   ; icpt = icpt + 1   ;   ENDIF       ! CLIO bulk       formulation
182      IF( ln_blk_core     ) THEN   ;   nsbc =  4   ; icpt = icpt + 1   ;   ENDIF       ! CORE bulk       formulation
183      IF( ln_blk_mfs      ) THEN   ;   nsbc =  6   ; icpt = icpt + 1   ;   ENDIF       ! MFS  bulk       formulation
184      IF( ln_cpl          ) THEN   ;   nsbc =  5   ; icpt = icpt + 1   ;   ENDIF       ! Coupled         formulation
185      IF( cp_cfg == 'gyre') THEN   ;   nsbc =  0                       ;   ENDIF       ! GYRE analytical formulation
186      IF( lk_esopa        )            nsbc = -1                                       ! esopa test, ALL formulations
187      !
188      IF( icpt /= 1 .AND. .NOT.lk_esopa ) THEN
189         WRITE(numout,*)
190         WRITE(numout,*) '           E R R O R in setting the sbc, one and only one namelist/CPP key option '
191         WRITE(numout,*) '                     must be choosen. You choose ', icpt, ' option(s)'
192         WRITE(numout,*) '                     We stop'
193         nstop = nstop + 1
194      ENDIF
195      IF(lwp) THEN
196         WRITE(numout,*)
197         IF( nsbc == -1 )   WRITE(numout,*) '              ESOPA test All surface boundary conditions'
198         IF( nsbc ==  0 )   WRITE(numout,*) '              GYRE analytical formulation'
199         IF( nsbc ==  1 )   WRITE(numout,*) '              analytical formulation'
200         IF( nsbc ==  2 )   WRITE(numout,*) '              flux formulation'
201         IF( nsbc ==  3 )   WRITE(numout,*) '              CLIO bulk formulation'
202         IF( nsbc ==  4 )   WRITE(numout,*) '              CORE bulk formulation'
203         IF( nsbc ==  5 )   WRITE(numout,*) '              coupled formulation'
204         IF( nsbc ==  6 )   WRITE(numout,*) '              MFS Bulk formulation'
205      ENDIF
206
207      IF( nn_ice == 4 )   CALL cice_sbc_init (nsbc)
208      !
209   END SUBROUTINE sbc_init
210
211
212   SUBROUTINE sbc( kt )
213      !!---------------------------------------------------------------------
214      !!                    ***  ROUTINE sbc  ***
215      !!             
216      !! ** Purpose :   provide at each time-step the ocean surface boundary
217      !!                condition (momentum, heat and freshwater fluxes)
218      !!
219      !! ** Method  :   blah blah  to be written ?????????
220      !!                CAUTION : never mask the surface stress field (tke sbc)
221      !!
222      !! ** Action  : - set the ocean surface boundary condition at before and now
223      !!                time step, i.e. 
224      !!                utau_b, vtau_b, qns_b, qsr_b, emp_n, emps_b, qrp_b, erp_b
225      !!                utau  , vtau  , qns  , qsr  , emp  , sfx   , qrp  , erp
226      !!              - updte the ice fraction : fr_i
227      !!----------------------------------------------------------------------
228      INTEGER, INTENT(in) ::   kt       ! ocean time step
229      !!---------------------------------------------------------------------
230      !
231      IF( nn_timing == 1 )  CALL timing_start('sbc')
232      !
233      !                                            ! ---------------------------------------- !
234      IF( kt /= nit000 ) THEN                      !          Swap of forcing fields          !
235         !                                         ! ---------------------------------------- !
236         utau_b(:,:) = utau(:,:)                         ! Swap the ocean forcing fields
237         vtau_b(:,:) = vtau(:,:)                         ! (except at nit000 where before fields
238         qns_b (:,:) = qns (:,:)                         !  are set at the end of the routine)
239         ! The 3D heat content due to qsr forcing is treated in traqsr
240         ! qsr_b (:,:) = qsr (:,:)
241         emp_b (:,:) = emp (:,:)
242         emps_b(:,:) = sfx(:,:)
243      ENDIF
244      !                                            ! ---------------------------------------- !
245      !                                            !        forcing field computation         !
246      !                                            ! ---------------------------------------- !
247
248      CALL iom_setkt( kt + nn_fsbc - 1 )                 ! in sbc, iom_put is called every nn_fsbc time step
249      !
250      IF( ln_apr_dyn ) CALL sbc_apr( kt )                ! atmospheric pressure provided at kt+0.5*nn_fsbc
251                                                         ! (caution called before sbc_ssm)
252      !
253      CALL sbc_ssm( kt )                                 ! ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m)
254      !                                                  ! averaged over nf_sbc time-step
255
256      IF (ln_cdgw) CALL sbc_wave( kt )
257                                                   !==  sbc formulation  ==!
258                                                           
259      SELECT CASE( nsbc )                                ! Compute ocean surface boundary condition
260      !                                                  ! (i.e. utau,vtau, qns, qsr, emp, sfx)
261      CASE(  0 )   ;   CALL sbc_gyre    ( kt )                    ! analytical formulation : GYRE configuration
262      CASE(  1 )   ;   CALL sbc_ana     ( kt )                    ! analytical formulation : uniform sbc
263      CASE(  2 )   ;   CALL sbc_flx     ( kt )                    ! flux formulation
264      CASE(  3 )   ;   CALL sbc_blk_clio( kt )                    ! bulk formulation : CLIO for the ocean
265      CASE(  4 )   ;   CALL sbc_blk_core( kt )                    ! bulk formulation : CORE for the ocean
266      CASE(  5 )   ;   CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   ! coupled formulation
267      CASE(  6 )   ;   CALL sbc_blk_mfs ( kt )                    ! bulk formulation : MFS for the ocean
268      CASE( -1 )                               
269                       CALL sbc_ana     ( kt )                    ! ESOPA, test ALL the formulations
270                       CALL sbc_gyre    ( kt )                    !
271                       CALL sbc_flx     ( kt )                    !
272                       CALL sbc_blk_clio( kt )                    !
273                       CALL sbc_blk_core( kt )                    !
274                       CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   !
275      END SELECT
276
277      !                                            !==  Misc. Options  ==!
278     
279      SELECT CASE( nn_ice )                                     ! Update heat and freshwater fluxes over sea-ice areas
280      CASE(  1 )   ;       CALL sbc_ice_if   ( kt )                  ! Ice-cover climatology ("Ice-if" model)
281         !                                                     
282      CASE(  2 )   ;       CALL sbc_ice_lim_2( kt, nsbc )            ! LIM-2 ice model
283         IF( lk_bdy )      CALL bdy_ice_lim_2( kt )                  ! BDY boundary condition
284         !                                                     
285      CASE(  3 )   ;       CALL sbc_ice_lim  ( kt, nsbc )            ! LIM-3 ice model
286         !
287      CASE(  4 )   ;       CALL sbc_ice_cice ( kt, nsbc )            ! CICE ice model
288      END SELECT                                             
289
290      IF( ln_rnf       )   CALL sbc_rnf( kt )                   ! add runoffs to fresh water fluxes
291 
292      IF( ln_ssr       )   CALL sbc_ssr( kt )                   ! add SST/SSS damping term
293
294      IF( nn_fwb  /= 0 )   CALL sbc_fwb( kt, nn_fwb, nn_fsbc )  ! control the freshwater budget
295
296      IF( nclosea == 1 )   CALL sbc_clo( kt )                   ! treatment of closed sea in the model domain
297      !                                                         ! (update freshwater fluxes)
298!RBbug do not understand why see ticket 667
299      CALL lbc_lnk( emp, 'T', 1. )
300      !
301      IF( kt == nit000 ) THEN                          !   set the forcing field at nit000 - 1    !
302         !                                             ! ---------------------------------------- !
303         IF( ln_rstart .AND.    &                               !* Restart: read in restart file
304            & iom_varid( numror, 'utau_b', ldstop = .FALSE. ) > 0 ) THEN
305            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields red in the restart file'
306            CALL iom_get( numror, jpdom_autoglo, 'utau_b', utau_b )   ! before i-stress  (U-point)
307            CALL iom_get( numror, jpdom_autoglo, 'vtau_b', vtau_b )   ! before j-stress  (V-point)
308            CALL iom_get( numror, jpdom_autoglo, 'qns_b' , qns_b  )   ! before non solar heat flux (T-point)
309            ! The 3D heat content due to qsr forcing is treated in traqsr
310            ! CALL iom_get( numror, jpdom_autoglo, 'qsr_b' , qsr_b  )   ! before     solar heat flux (T-point)
311            CALL iom_get( numror, jpdom_autoglo, 'emp_b' , emp_b  )   ! before     freshwater flux (T-point)
312            CALL iom_get( numror, jpdom_autoglo, 'emps_b', emps_b )   ! before C/D freshwater flux (T-point)
313         ELSE                                                   !* no restart: set from nit000 values
314            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields set to nit000'
315            utau_b(:,:) = utau(:,:) 
316            vtau_b(:,:) = vtau(:,:)
317            qns_b (:,:) = qns (:,:)
318            ! qsr_b (:,:) = qsr (:,:)
319            emp_b (:,:) = emp (:,:)
320            emps_b(:,:) = sfx(:,:)
321         ENDIF
322      ENDIF
323      !                                                ! ---------------------------------------- !
324      IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
325         !                                             ! ---------------------------------------- !
326         IF(lwp) WRITE(numout,*)
327         IF(lwp) WRITE(numout,*) 'sbc : ocean surface forcing fields written in ocean restart file ',   &
328            &                    'at it= ', kt,' date= ', ndastp
329         IF(lwp) WRITE(numout,*) '~~~~'
330         CALL iom_rstput( kt, nitrst, numrow, 'utau_b' , utau )
331         CALL iom_rstput( kt, nitrst, numrow, 'vtau_b' , vtau )
332         CALL iom_rstput( kt, nitrst, numrow, 'qns_b'  , qns  )
333         ! The 3D heat content due to qsr forcing is treated in traqsr
334         ! CALL iom_rstput( kt, nitrst, numrow, 'qsr_b'  , qsr  )
335         CALL iom_rstput( kt, nitrst, numrow, 'emp_b'  , emp  )
336         CALL iom_rstput( kt, nitrst, numrow, 'emps_b' , sfx )
337      ENDIF
338
339      !                                                ! ---------------------------------------- !
340      !                                                !        Outputs and control print         !
341      !                                                ! ---------------------------------------- !
342      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
343         CALL iom_put( "empmr" , emp  - rnf )                   ! upward water flux
344         CALL iom_put( "empsmr", sfx - rnf )                    ! c/d water flux
345         CALL iom_put( "qt"    , qns  + qsr )                   ! total heat flux
346         CALL iom_put( "qns"   , qns        )                   ! solar heat flux
347         CALL iom_put( "qsr"   ,       qsr  )                   ! solar heat flux
348         IF( nn_ice > 0 )   CALL iom_put( "ice_cover", fr_i )   ! ice fraction
349      ENDIF
350      !
351      CALL iom_setkt( kt )           ! iom_put outside of sbc is called at every time step
352      !
353      CALL iom_put( "utau", utau )   ! i-wind stress   (stress can be updated at
354      CALL iom_put( "vtau", vtau )   ! j-wind stress    each time step in sea-ice)
355      CALL iom_put( "taum", taum )   ! wind stress module
356      CALL iom_put( "wspd", wndm )   ! wind speed  module
357      !
358      IF(ln_ctl) THEN         ! print mean trends (used for debugging)
359         CALL prt_ctl(tab2d_1=fr_i             , clinfo1=' fr_i     - : ', mask1=tmask, ovlap=1 )
360         CALL prt_ctl(tab2d_1=(emp-rnf)        , clinfo1=' emp-rnf  - : ', mask1=tmask, ovlap=1 )
361         CALL prt_ctl(tab2d_1=(sfx-rnf)        , clinfo1=' sfx-rnf  - : ', mask1=tmask, ovlap=1 )
362         CALL prt_ctl(tab2d_1=qns              , clinfo1=' qns      - : ', mask1=tmask, ovlap=1 )
363         CALL prt_ctl(tab2d_1=qsr              , clinfo1=' qsr      - : ', mask1=tmask, ovlap=1 )
364         CALL prt_ctl(tab3d_1=tmask            , clinfo1=' tmask    - : ', mask1=tmask, ovlap=1, kdim=jpk )
365         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_tem), clinfo1=' sst      - : ', mask1=tmask, ovlap=1, kdim=1   )
366         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_sal), clinfo1=' sss      - : ', mask1=tmask, ovlap=1, kdim=1   )
367         CALL prt_ctl(tab2d_1=utau             , clinfo1=' utau     - : ', mask1=umask,                      &
368            &         tab2d_2=vtau             , clinfo2=' vtau     - : ', mask2=vmask, ovlap=1 )
369      ENDIF
370
371      IF( kt == nitend )   CALL sbc_final         ! Close down surface module if necessary
372      !
373      IF( nn_timing == 1 )  CALL timing_stop('sbc')
374      !
375   END SUBROUTINE sbc
376
377   SUBROUTINE sbc_final
378      !!---------------------------------------------------------------------
379      !!                    ***  ROUTINE sbc_final  ***
380      !!---------------------------------------------------------------------
381
382      !-----------------------------------------------------------------
383      ! Finalize CICE (if used)
384      !-----------------------------------------------------------------
385
386      IF( nn_ice == 4 )   CALL cice_sbc_final
387      !
388   END SUBROUTINE sbc_final
389
390   !!======================================================================
391END MODULE sbcmod
Note: See TracBrowser for help on using the repository browser.