source: branches/2012/dev_r3385_NOCS04_HAMF/NEMOGCM/NEMO/OPA_SRC/SBC/sbcmod.F90 @ 3488

Last change on this file since 3488 was 3488, checked in by acc, 9 years ago

Branch: dev_r3385_NOCS04_HAMF; #665. Stage 3 of 2012 development: Rationalisation of code. Added LIM3 changes, corrected coupled changes and highlighted areas of concern in CICE interface

  • Property svn:keywords set to Id
File size: 24.0 KB
Line 
1MODULE sbcmod
2   !!======================================================================
3   !!                       ***  MODULE  sbcmod  ***
4   !! Surface module :  provide to the ocean its surface boundary condition
5   !!======================================================================
6   !! History :  3.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.1  ! 2008-08  (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface
8   !!            3.3  ! 2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
9   !!            3.3  ! 2010-10  (S. Masson)  add diurnal cycle
10   !!            3.3  ! 2010-09  (D. Storkey) add ice boundary conditions (BDY)
11   !!             -   ! 2010-11  (G. Madec) ice-ocean stress always computed at each ocean time-step
12   !!             -   ! 2010-10  (J. Chanut, C. Bricaud, G. Madec)  add the surface pressure forcing
13   !!            3.4  ! 2011-11  (C. Harris) CICE added as an option
14   !!            3.5  ! 2012-11  (A. Coward, G. Madec) Rethink of heat, mass and salt surface fluxes
15   !!----------------------------------------------------------------------
16
17   !!----------------------------------------------------------------------
18   !!   sbc_init       : read namsbc namelist
19   !!   sbc            : surface ocean momentum, heat and freshwater boundary conditions
20   !!----------------------------------------------------------------------
21   USE oce              ! ocean dynamics and tracers
22   USE dom_oce          ! ocean space and time domain
23   USE phycst           ! physical constants
24   USE sbc_oce          ! Surface boundary condition: ocean fields
25   USE sbc_ice          ! Surface boundary condition: ice fields
26   USE sbcdcy           ! surface boundary condition: diurnal cycle
27   USE sbcssm           ! surface boundary condition: sea-surface mean variables
28   USE sbcapr           ! surface boundary condition: atmospheric pressure
29   USE sbcana           ! surface boundary condition: analytical formulation
30   USE sbcflx           ! surface boundary condition: flux formulation
31   USE sbcblk_clio      ! surface boundary condition: bulk formulation : CLIO
32   USE sbcblk_core      ! surface boundary condition: bulk formulation : CORE
33   USE sbcblk_mfs       ! surface boundary condition: bulk formulation : MFS
34   USE sbcice_if        ! surface boundary condition: ice-if sea-ice model
35   USE sbcice_lim       ! surface boundary condition: LIM 3.0 sea-ice model
36   USE sbcice_lim_2     ! surface boundary condition: LIM 2.0 sea-ice model
37   USE sbcice_cice      ! surface boundary condition: CICE    sea-ice model
38   USE sbccpl           ! surface boundary condition: coupled florulation
39   USE cpl_oasis3, ONLY:lk_cpl      ! are we in coupled mode?
40   USE sbcssr           ! surface boundary condition: sea surface restoring
41   USE sbcrnf           ! surface boundary condition: runoffs
42   USE sbcfwb           ! surface boundary condition: freshwater budget
43   USE closea           ! closed sea
44   USE bdy_par          ! for lk_bdy
45   USE bdyice_lim2      ! unstructured open boundary data  (bdy_ice_lim_2 routine)
46
47   USE prtctl           ! Print control                    (prt_ctl routine)
48   USE restart          ! ocean restart
49   USE iom              ! IOM library
50   USE in_out_manager   ! I/O manager
51   USE lib_mpp          ! MPP library
52   USE timing           ! Timing
53   USE sbcwave          ! Wave module
54
55   IMPLICIT NONE
56   PRIVATE
57
58   PUBLIC   sbc        ! routine called by step.F90
59   PUBLIC   sbc_init   ! routine called by opa.F90
60   
61   INTEGER ::   nsbc   ! type of surface boundary condition (deduced from namsbc informations)
62     
63   !! * Substitutions
64#  include "domzgr_substitute.h90"
65   !!----------------------------------------------------------------------
66   !! NEMO/OPA 4.0 , NEMO-consortium (2011)
67   !! $Id$
68   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
69   !!----------------------------------------------------------------------
70CONTAINS
71
72   SUBROUTINE sbc_init
73      !!---------------------------------------------------------------------
74      !!                    ***  ROUTINE sbc_init ***
75      !!
76      !! ** Purpose :   Initialisation of the ocean surface boundary computation
77      !!
78      !! ** Method  :   Read the namsbc namelist and set derived parameters
79      !!
80      !! ** Action  : - read namsbc parameters
81      !!              - nsbc: type of sbc
82      !!----------------------------------------------------------------------
83      INTEGER ::   icpt   ! local integer
84      !!
85      NAMELIST/namsbc/ nn_fsbc   , ln_ana    , ln_flx,  ln_blk_clio, ln_blk_core, ln_cpl,   &
86         &             ln_blk_mfs, ln_apr_dyn, nn_ice,  nn_ice_embd, ln_dm2dc   , ln_rnf,   &
87         &             ln_ssr    , nn_fwb    , ln_cdgw
88      !!----------------------------------------------------------------------
89
90      IF(lwp) THEN
91         WRITE(numout,*)
92         WRITE(numout,*) 'sbc_init : surface boundary condition setting'
93         WRITE(numout,*) '~~~~~~~~ '
94      ENDIF
95
96      REWIND( numnam )           ! Read Namelist namsbc
97      READ  ( numnam, namsbc )
98
99      !                          ! overwrite namelist parameter using CPP key information
100      IF( Agrif_Root() ) THEN                ! AGRIF zoom
101        IF( lk_lim2 )   nn_ice      = 2
102        IF( lk_lim3 )   nn_ice      = 3
103        IF( lk_cice )   nn_ice      = 4
104      ENDIF
105      IF( cp_cfg == 'gyre' ) THEN            ! GYRE configuration
106          ln_ana      = .TRUE.   
107          nn_ice      =   0
108      ENDIF
109     
110      IF(lwp) THEN               ! Control print
111         WRITE(numout,*) '        Namelist namsbc (partly overwritten with CPP key setting)'
112         WRITE(numout,*) '           frequency update of sbc (and ice)             nn_fsbc     = ', nn_fsbc
113         WRITE(numout,*) '           Type of sbc : '
114         WRITE(numout,*) '              analytical formulation                     ln_ana      = ', ln_ana
115         WRITE(numout,*) '              flux       formulation                     ln_flx      = ', ln_flx
116         WRITE(numout,*) '              CLIO bulk  formulation                     ln_blk_clio = ', ln_blk_clio
117         WRITE(numout,*) '              CORE bulk  formulation                     ln_blk_core = ', ln_blk_core
118         WRITE(numout,*) '              MFS  bulk  formulation                     ln_blk_mfs  = ', ln_blk_mfs
119         WRITE(numout,*) '              coupled    formulation (T if key_sbc_cpl)  ln_cpl      = ', ln_cpl
120         WRITE(numout,*) '           Misc. options of sbc : '
121         WRITE(numout,*) '              Patm gradient added in ocean & ice Eqs.    ln_apr_dyn  = ', ln_apr_dyn
122         WRITE(numout,*) '              ice management in the sbc (=0/1/2/3)       nn_ice      = ', nn_ice 
123         WRITE(numout,*) '              ice-ocean embedded/levitating (=0/1/2)     nn_ice_embd = ', nn_ice_embd
124         WRITE(numout,*) '              daily mean to diurnal cycle qsr            ln_dm2dc    = ', ln_dm2dc 
125         WRITE(numout,*) '              runoff / runoff mouths                     ln_rnf      = ', ln_rnf
126         WRITE(numout,*) '              Sea Surface Restoring on SST and/or SSS    ln_ssr      = ', ln_ssr
127         WRITE(numout,*) '              FreshWater Budget control  (=0/1/2)        nn_fwb      = ', nn_fwb
128         WRITE(numout,*) '              closed sea (=0/1) (set in namdom)          nn_closea   = ', nn_closea
129      ENDIF
130
131      !                              ! allocate sbc arrays
132      IF( sbc_oce_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_oce arrays' )
133
134      !                          ! Checks:
135      IF( .NOT. ln_rnf ) THEN                      ! no specific treatment in vicinity of river mouths
136         ln_rnf_mouth  = .false.                     
137         IF( sbc_rnf_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_rnf arrays' )
138         nkrnf         = 0
139         rnf     (:,:) = 0.0_wp
140         rnfmsk  (:,:) = 0.0_wp
141         rnfmsk_z(:)   = 0.0_wp
142      ENDIF
143      IF( nn_ice == 0  )   fr_i(:,:) = 0.e0        ! no ice in the domain, ice fraction is always zero
144
145      sfx(:,:) = 0.0_wp                            ! the salt flux due to freezing/melting will be computed (i.e. will be non-zero)
146                                                   ! only if sea-ice is present
147
148      !                                            ! restartability   
149      IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 .OR.   &
150          MOD( nstock             , nn_fsbc) /= 0 ) THEN
151         WRITE(ctmp1,*) 'experiment length (', nitend - nit000 + 1, ') or nstock (', nstock,   &
152            &           ' is NOT a multiple of nn_fsbc (', nn_fsbc, ')'
153         CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' )
154      ENDIF
155      !
156      IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 )   &
157         &  CALL ctl_warn( 'nn_fsbc is NOT a multiple of the number of time steps in a day' )
158      !
159      IF( ( nn_ice == 2 .OR. nn_ice ==3 ) .AND. .NOT.( ln_blk_clio .OR. ln_blk_core .OR. lk_cpl ) )   &
160         &   CALL ctl_stop( 'LIM sea-ice model requires a bulk formulation or coupled configuration' )
161      IF( nn_ice == 4 .AND. .NOT.( ln_blk_core .OR. lk_cpl ) )   &
162         &   CALL ctl_stop( 'CICE sea-ice model requires ln_blk_core or lk_cpl' )
163      IF( nn_ice == 4 .AND. ( .NOT. ( cp_cfg == 'orca' ) .OR. lk_agrif ) )   &
164         &   CALL ctl_stop( 'CICE sea-ice model currently only available in a global ORCA configuration without AGRIF' )
165      IF( nn_ice == 3 .AND. nn_ice_embd == 0 )   &
166         &   CALL ctl_stop( 'LIM3 sea-ice model requires nn_ice_embd = 2 or 3' )
167     
168      IF( ln_dm2dc )   nday_qsr = -1   ! initialisation flag
169
170      IF( ln_dm2dc .AND. .NOT.( ln_flx .OR. ln_blk_core ) )   &
171         &   CALL ctl_stop( 'diurnal cycle into qsr field from daily values requires a flux or core-bulk formulation' )
172     
173      IF( ln_dm2dc .AND. ( ( NINT(rday) / ( nn_fsbc * NINT(rdt) ) )  < 8 ) )   &
174         &   CALL ctl_warn( 'diurnal cycle for qsr: the sampling of the diurnal cycle is too small...' )
175
176       !drag coefficient read from wave model definable only with mfs bulk formulae and core
177       IF(ln_cdgw .AND. .NOT.(ln_blk_mfs .OR. ln_blk_core) )              &
178          &   CALL ctl_stop( 'drag coefficient read from wave model definable only with mfs bulk formulae and core')
179     
180      !                          ! Choice of the Surface Boudary Condition (set nsbc)
181      icpt = 0
182      IF( ln_ana          ) THEN   ;   nsbc =  1   ; icpt = icpt + 1   ;   ENDIF       ! analytical      formulation
183      IF( ln_flx          ) THEN   ;   nsbc =  2   ; icpt = icpt + 1   ;   ENDIF       ! flux            formulation
184      IF( ln_blk_clio     ) THEN   ;   nsbc =  3   ; icpt = icpt + 1   ;   ENDIF       ! CLIO bulk       formulation
185      IF( ln_blk_core     ) THEN   ;   nsbc =  4   ; icpt = icpt + 1   ;   ENDIF       ! CORE bulk       formulation
186      IF( ln_blk_mfs      ) THEN   ;   nsbc =  6   ; icpt = icpt + 1   ;   ENDIF       ! MFS  bulk       formulation
187      IF( ln_cpl          ) THEN   ;   nsbc =  5   ; icpt = icpt + 1   ;   ENDIF       ! Coupled         formulation
188      IF( cp_cfg == 'gyre') THEN   ;   nsbc =  0                       ;   ENDIF       ! GYRE analytical formulation
189      IF( lk_esopa        )            nsbc = -1                                       ! esopa test, ALL formulations
190      !
191      IF( icpt /= 1 .AND. .NOT.lk_esopa ) THEN
192         WRITE(numout,*)
193         WRITE(numout,*) '           E R R O R in setting the sbc, one and only one namelist/CPP key option '
194         WRITE(numout,*) '                     must be choosen. You choose ', icpt, ' option(s)'
195         WRITE(numout,*) '                     We stop'
196         nstop = nstop + 1
197      ENDIF
198      IF(lwp) THEN
199         WRITE(numout,*)
200         IF( nsbc == -1 )   WRITE(numout,*) '              ESOPA test All surface boundary conditions'
201         IF( nsbc ==  0 )   WRITE(numout,*) '              GYRE analytical formulation'
202         IF( nsbc ==  1 )   WRITE(numout,*) '              analytical formulation'
203         IF( nsbc ==  2 )   WRITE(numout,*) '              flux formulation'
204         IF( nsbc ==  3 )   WRITE(numout,*) '              CLIO bulk formulation'
205         IF( nsbc ==  4 )   WRITE(numout,*) '              CORE bulk formulation'
206         IF( nsbc ==  5 )   WRITE(numout,*) '              coupled formulation'
207         IF( nsbc ==  6 )   WRITE(numout,*) '              MFS Bulk formulation'
208      ENDIF
209
210      IF( nn_ice == 4 )   CALL cice_sbc_init (nsbc)
211      !
212   END SUBROUTINE sbc_init
213
214
215   SUBROUTINE sbc( kt )
216      !!---------------------------------------------------------------------
217      !!                    ***  ROUTINE sbc  ***
218      !!             
219      !! ** Purpose :   provide at each time-step the ocean surface boundary
220      !!                condition (momentum, heat and freshwater fluxes)
221      !!
222      !! ** Method  :   blah blah  to be written ?????????
223      !!                CAUTION : never mask the surface stress field (tke sbc)
224      !!
225      !! ** Action  : - set the ocean surface boundary condition at before and now
226      !!                time step, i.e. 
227      !!                utau_b, vtau_b, qns_b, qsr_b, emp_n, sfx_b, qrp_b, erp_b
228      !!                utau  , vtau  , qns  , qsr  , emp  , sfx  , qrp  , erp
229      !!              - updte the ice fraction : fr_i
230      !!----------------------------------------------------------------------
231      INTEGER, INTENT(in) ::   kt       ! ocean time step
232      !!---------------------------------------------------------------------
233      !
234      IF( nn_timing == 1 )  CALL timing_start('sbc')
235      !
236      !                                            ! ---------------------------------------- !
237      IF( kt /= nit000 ) THEN                      !          Swap of forcing fields          !
238         !                                         ! ---------------------------------------- !
239         utau_b(:,:) = utau(:,:)                         ! Swap the ocean forcing fields
240         vtau_b(:,:) = vtau(:,:)                         ! (except at nit000 where before fields
241         qns_b (:,:) = qns (:,:)                         !  are set at the end of the routine)
242         ! The 3D heat content due to qsr forcing is treated in traqsr
243         ! qsr_b (:,:) = qsr (:,:)
244         emp_b(:,:) = emp(:,:)
245         sfx_b(:,:) = sfx(:,:)
246      ENDIF
247      !                                            ! ---------------------------------------- !
248      !                                            !        forcing field computation         !
249      !                                            ! ---------------------------------------- !
250
251      CALL iom_setkt( kt + nn_fsbc - 1 )                 ! in sbc, iom_put is called every nn_fsbc time step
252      !
253      IF( ln_apr_dyn ) CALL sbc_apr( kt )                ! atmospheric pressure provided at kt+0.5*nn_fsbc
254                                                         ! (caution called before sbc_ssm)
255      !
256      CALL sbc_ssm( kt )                                 ! ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m)
257      !                                                  ! averaged over nf_sbc time-step
258
259      IF (ln_cdgw) CALL sbc_wave( kt )
260                                                   !==  sbc formulation  ==!
261                                                           
262      SELECT CASE( nsbc )                                ! Compute ocean surface boundary condition
263      !                                                  ! (i.e. utau,vtau, qns, qsr, emp, sfx)
264      CASE(  0 )   ;   CALL sbc_gyre    ( kt )                    ! analytical formulation : GYRE configuration
265      CASE(  1 )   ;   CALL sbc_ana     ( kt )                    ! analytical formulation : uniform sbc
266      CASE(  2 )   ;   CALL sbc_flx     ( kt )                    ! flux formulation
267      CASE(  3 )   ;   CALL sbc_blk_clio( kt )                    ! bulk formulation : CLIO for the ocean
268      CASE(  4 )   ;   CALL sbc_blk_core( kt )                    ! bulk formulation : CORE for the ocean
269      CASE(  5 )   ;   CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   ! coupled formulation
270      CASE(  6 )   ;   CALL sbc_blk_mfs ( kt )                    ! bulk formulation : MFS for the ocean
271      CASE( -1 )                               
272                       CALL sbc_ana     ( kt )                    ! ESOPA, test ALL the formulations
273                       CALL sbc_gyre    ( kt )                    !
274                       CALL sbc_flx     ( kt )                    !
275                       CALL sbc_blk_clio( kt )                    !
276                       CALL sbc_blk_core( kt )                    !
277                       CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   !
278      END SELECT
279
280      !                                            !==  Misc. Options  ==!
281     
282      SELECT CASE( nn_ice )                                     ! Update heat and freshwater fluxes over sea-ice areas
283      CASE(  1 )   ;       CALL sbc_ice_if   ( kt )                  ! Ice-cover climatology ("Ice-if" model)
284         !                                                     
285      CASE(  2 )   ;       CALL sbc_ice_lim_2( kt, nsbc )            ! LIM-2 ice model
286         IF( lk_bdy )      CALL bdy_ice_lim_2( kt )                  ! BDY boundary condition
287         !                                                     
288      CASE(  3 )   ;       CALL sbc_ice_lim  ( kt, nsbc )            ! LIM-3 ice model
289         !
290      CASE(  4 )   ;       CALL sbc_ice_cice ( kt, nsbc )            ! CICE ice model
291      END SELECT                                             
292
293      IF( ln_rnf       )   CALL sbc_rnf( kt )                   ! add runoffs to fresh water fluxes
294 
295      IF( ln_ssr       )   CALL sbc_ssr( kt )                   ! add SST/SSS damping term
296
297      IF( nn_fwb  /= 0 )   CALL sbc_fwb( kt, nn_fwb, nn_fsbc )  ! control the freshwater budget
298
299      IF( nclosea == 1 )   CALL sbc_clo( kt )                   ! treatment of closed sea in the model domain
300      !                                                         ! (update freshwater fluxes)
301!RBbug do not understand why see ticket 667
302      CALL lbc_lnk( emp, 'T', 1. )
303      !
304      IF( kt == nit000 ) THEN                          !   set the forcing field at nit000 - 1    !
305         !                                             ! ---------------------------------------- !
306         IF( ln_rstart .AND.    &                               !* Restart: read in restart file
307            & iom_varid( numror, 'utau_b', ldstop = .FALSE. ) > 0 ) THEN
308            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields red in the restart file'
309            CALL iom_get( numror, jpdom_autoglo, 'utau_b', utau_b )   ! before i-stress  (U-point)
310            CALL iom_get( numror, jpdom_autoglo, 'vtau_b', vtau_b )   ! before j-stress  (V-point)
311            CALL iom_get( numror, jpdom_autoglo, 'qns_b' , qns_b  )   ! before non solar heat flux (T-point)
312            ! The 3D heat content due to qsr forcing is treated in traqsr
313            ! CALL iom_get( numror, jpdom_autoglo, 'qsr_b' , qsr_b  ) ! before     solar heat flux (T-point)
314            CALL iom_get( numror, jpdom_autoglo, 'emp_b', emp_b  )    ! before     freshwater flux (T-point)
315            ! To ensure restart capability with 3.3x/3.4 restart files    !! to be removed in v3.6
316            IF( iom_varid( numror, 'sfx_b', ldstop = .FALSE. ) > 0 ) THEN
317               CALL iom_get( numror, jpdom_autoglo, 'sfx_b', sfx_b )  ! before salt flux (T-point)
318            ELSE
319               sfx_b (:,:) = sfx(:,:)
320            ENDIF
321         ELSE                                                   !* no restart: set from nit000 values
322            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields set to nit000'
323            utau_b(:,:) = utau(:,:) 
324            vtau_b(:,:) = vtau(:,:)
325            qns_b (:,:) = qns (:,:)
326            emp_b (:,:) = emp(:,:)
327            sfx_b (:,:) = sfx(:,:)
328         ENDIF
329      ENDIF
330      !                                                ! ---------------------------------------- !
331      IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
332         !                                             ! ---------------------------------------- !
333         IF(lwp) WRITE(numout,*)
334         IF(lwp) WRITE(numout,*) 'sbc : ocean surface forcing fields written in ocean restart file ',   &
335            &                    'at it= ', kt,' date= ', ndastp
336         IF(lwp) WRITE(numout,*) '~~~~'
337         CALL iom_rstput( kt, nitrst, numrow, 'utau_b' , utau )
338         CALL iom_rstput( kt, nitrst, numrow, 'vtau_b' , vtau )
339         CALL iom_rstput( kt, nitrst, numrow, 'qns_b'  , qns  )
340         ! The 3D heat content due to qsr forcing is treated in traqsr
341         ! CALL iom_rstput( kt, nitrst, numrow, 'qsr_b'  , qsr  )
342         CALL iom_rstput( kt, nitrst, numrow, 'emp_b'  , emp  )
343         CALL iom_rstput( kt, nitrst, numrow, 'sfx_b' , sfx )
344      ENDIF
345
346      !                                                ! ---------------------------------------- !
347      !                                                !        Outputs and control print         !
348      !                                                ! ---------------------------------------- !
349      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
350         CALL iom_put( "empmr" , emp  - rnf )                   ! upward water flux
351         CALL iom_put( "saltflx", sfx  )                        ! downward salt flux 
352                                                                ! (includes virtual salt flux beneath ice
353                                                                ! in linear free surface case)
354         CALL iom_put( "qt"    , qns  + qsr )                   ! total heat flux
355         CALL iom_put( "qns"   , qns        )                   ! solar heat flux
356         CALL iom_put( "qsr"   ,       qsr  )                   ! solar heat flux
357         IF( nn_ice > 0 )   CALL iom_put( "ice_cover", fr_i )   ! ice fraction
358      ENDIF
359      !
360      CALL iom_setkt( kt )           ! iom_put outside of sbc is called at every time step
361      !
362      CALL iom_put( "utau", utau )   ! i-wind stress   (stress can be updated at
363      CALL iom_put( "vtau", vtau )   ! j-wind stress    each time step in sea-ice)
364      CALL iom_put( "taum", taum )   ! wind stress module
365      CALL iom_put( "wspd", wndm )   ! wind speed  module
366      !
367      IF(ln_ctl) THEN         ! print mean trends (used for debugging)
368         CALL prt_ctl(tab2d_1=fr_i             , clinfo1=' fr_i     - : ', mask1=tmask, ovlap=1 )
369         CALL prt_ctl(tab2d_1=(emp-rnf)        , clinfo1=' emp-rnf  - : ', mask1=tmask, ovlap=1 )
370         CALL prt_ctl(tab2d_1=(sfx-rnf)        , clinfo1=' sfx-rnf  - : ', mask1=tmask, ovlap=1 )
371         CALL prt_ctl(tab2d_1=qns              , clinfo1=' qns      - : ', mask1=tmask, ovlap=1 )
372         CALL prt_ctl(tab2d_1=qsr              , clinfo1=' qsr      - : ', mask1=tmask, ovlap=1 )
373         CALL prt_ctl(tab3d_1=tmask            , clinfo1=' tmask    - : ', mask1=tmask, ovlap=1, kdim=jpk )
374         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_tem), clinfo1=' sst      - : ', mask1=tmask, ovlap=1, kdim=1   )
375         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_sal), clinfo1=' sss      - : ', mask1=tmask, ovlap=1, kdim=1   )
376         CALL prt_ctl(tab2d_1=utau             , clinfo1=' utau     - : ', mask1=umask,                      &
377            &         tab2d_2=vtau             , clinfo2=' vtau     - : ', mask2=vmask, ovlap=1 )
378      ENDIF
379
380      IF( kt == nitend )   CALL sbc_final         ! Close down surface module if necessary
381      !
382      IF( nn_timing == 1 )  CALL timing_stop('sbc')
383      !
384   END SUBROUTINE sbc
385
386   SUBROUTINE sbc_final
387      !!---------------------------------------------------------------------
388      !!                    ***  ROUTINE sbc_final  ***
389      !!---------------------------------------------------------------------
390
391      !-----------------------------------------------------------------
392      ! Finalize CICE (if used)
393      !-----------------------------------------------------------------
394
395      IF( nn_ice == 4 )   CALL cice_sbc_final
396      !
397   END SUBROUTINE sbc_final
398
399   !!======================================================================
400END MODULE sbcmod
Note: See TracBrowser for help on using the repository browser.