source: branches/2012/dev_r3385_NOCS04_HAMF/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 3488

Last change on this file since 3488 was 3488, checked in by acc, 9 years ago

Branch: dev_r3385_NOCS04_HAMF; #665. Stage 3 of 2012 development: Rationalisation of code. Added LIM3 changes, corrected coupled changes and highlighted areas of concern in CICE interface

  • Property svn:keywords set to Id
File size: 35.9 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  LIM sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!            3.4  ! 2011-11  (C. Harris) decomposition changes for running with CICE
31   !!----------------------------------------------------------------------
32
33   !!----------------------------------------------------------------------
34   !!   nemo_gcm       : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
35   !!   nemo_init      : initialization of the NEMO system
36   !!   nemo_ctl       : initialisation of the contol print
37   !!   nemo_closefile : close remaining open files
38   !!   nemo_alloc     : dynamical allocation
39   !!   nemo_partition : calculate MPP domain decomposition
40   !!   factorise      : calculate the factors of the no. of MPI processes
41   !!----------------------------------------------------------------------
42   USE step_oce        ! module used in the ocean time stepping module
43   USE sbc_oce         ! surface boundary condition: ocean
44   USE cla             ! cross land advection               (tra_cla routine)
45   USE domcfg          ! domain configuration               (dom_cfg routine)
46   USE mppini          ! shared/distributed memory setting (mpp_init routine)
47   USE domain          ! domain initialization             (dom_init routine)
48   USE obcini          ! open boundary cond. initialization (obc_ini routine)
49   USE bdyini          ! open boundary cond. initialization (bdy_init routine)
50   USE bdydta          ! open boundary cond. initialization (bdy_dta_init routine)
51   USE bdytides        ! open boundary cond. initialization (tide_init routine)
52   USE istate          ! initial state setting          (istate_init routine)
53   USE ldfdyn          ! lateral viscosity setting      (ldfdyn_init routine)
54   USE ldftra          ! lateral diffusivity setting    (ldftra_init routine)
55   USE zdfini          ! vertical physics setting          (zdf_init routine)
56   USE phycst          ! physical constant                  (par_cst routine)
57   USE trdmod          ! momentum/tracers trends       (trd_mod_init routine)
58   USE asmtrj          ! writing out state trajectory
59   USE diaptr          ! poleward transports           (dia_ptr_init routine)
60   USE diadct          ! sections transports           (dia_dct_init routine)
61   USE diaobs          ! Observation diagnostics       (dia_obs_init routine)
62   USE step            ! NEMO time-stepping                 (stp     routine)
63#if defined key_oasis3
64   USE cpl_oasis3      ! OASIS3 coupling
65#elif defined key_oasis4
66   USE cpl_oasis4      ! OASIS4 coupling (not working)
67#endif
68   USE c1d             ! 1D configuration
69   USE step_c1d        ! Time stepping loop for the 1D configuration
70#if defined key_top
71   USE trcini          ! passive tracer initialisation
72#endif
73   USE lib_mpp         ! distributed memory computing
74#if defined key_iomput
75   USE mod_ioclient
76#endif
77
78   IMPLICIT NONE
79   PRIVATE
80
81   PUBLIC   nemo_gcm    ! called by model.F90
82   PUBLIC   nemo_init   ! needed by AGRIF
83
84   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
85
86   !!----------------------------------------------------------------------
87   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
88   !! $Id$
89   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
90   !!----------------------------------------------------------------------
91CONTAINS
92
93   SUBROUTINE nemo_gcm
94      !!----------------------------------------------------------------------
95      !!                     ***  ROUTINE nemo_gcm  ***
96      !!
97      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
98      !!              curvilinear mesh on the sphere.
99      !!
100      !! ** Method  : - model general initialization
101      !!              - launch the time-stepping (stp routine)
102      !!              - finalize the run by closing files and communications
103      !!
104      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
105      !!              Madec, 2008, internal report, IPSL.
106      !!----------------------------------------------------------------------
107      INTEGER ::   istp       ! time step index
108      !!----------------------------------------------------------------------
109      !
110#if defined key_agrif
111      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
112#endif
113
114      !                            !-----------------------!
115      CALL nemo_init               !==  Initialisations  ==!
116      !                            !-----------------------!
117#if defined key_agrif
118      CALL Agrif_Declare_Var       ! AGRIF: set the meshes
119# if defined key_top
120      CALL Agrif_Declare_Var_Top   ! AGRIF: set the meshes
121# endif
122#endif
123      ! check that all process are still there... If some process have an error,
124      ! they will never enter in step and other processes will wait until the end of the cpu time!
125      IF( lk_mpp )   CALL mpp_max( nstop )
126
127      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
128
129      !                            !-----------------------!
130      !                            !==   time stepping   ==!
131      !                            !-----------------------!
132      istp = nit000
133#if defined key_c1d
134         DO WHILE ( istp <= nitend .AND. nstop == 0 )
135            CALL stp_c1d( istp )
136            istp = istp + 1
137         END DO
138#else
139          IF( lk_asminc ) THEN
140             IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 )    ! Output background fields
141             IF( ln_trjwri ) CALL asm_trj_wri( nit000 - 1 )    ! Output trajectory fields
142             IF( ln_asmdin ) THEN                        ! Direct initialization
143                IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 )    ! Tracers
144                IF( ln_dyninc ) THEN
145                   CALL dyn_asm_inc( nit000 - 1 )    ! Dynamics
146                   IF ( ln_asmdin ) CALL ssh_wzv ( nit000 - 1 )      ! update vertical velocity
147                ENDIF
148                IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 )    ! SSH
149             ENDIF
150          ENDIF
151       
152         DO WHILE ( istp <= nitend .AND. nstop == 0 )
153#if defined key_agrif
154            CALL Agrif_Step( stp )           ! AGRIF: time stepping
155#else
156            CALL stp( istp )                 ! standard time stepping
157#endif
158            istp = istp + 1
159            IF( lk_mpp )   CALL mpp_max( nstop )
160         END DO
161#endif
162
163      IF( lk_diaobs ) CALL dia_obs_wri
164       
165      !                            !------------------------!
166      !                            !==  finalize the run  ==!
167      !                            !------------------------!
168      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
169      !
170      IF( nstop /= 0 .AND. lwp ) THEN   ! error print
171         WRITE(numout,cform_err)
172         WRITE(numout,*) nstop, ' error have been found' 
173      ENDIF
174      !
175#if defined key_agrif
176      CALL Agrif_ParentGrid_To_ChildGrid()
177      IF( lk_diaobs ) CALL dia_obs_wri
178      IF( nn_timing == 1 )   CALL timing_finalize
179      CALL Agrif_ChildGrid_To_ParentGrid()
180#endif
181      IF( nn_timing == 1 )   CALL timing_finalize
182      !
183      CALL nemo_closefile
184#if defined key_oasis3 || defined key_oasis4
185      CALL cpl_prism_finalize           ! end coupling and mpp communications with OASIS
186#else
187      IF( lk_mpp )   CALL mppstop       ! end mpp communications
188#endif
189      !
190   END SUBROUTINE nemo_gcm
191
192
193   SUBROUTINE nemo_init
194      !!----------------------------------------------------------------------
195      !!                     ***  ROUTINE nemo_init  ***
196      !!
197      !! ** Purpose :   initialization of the NEMO GCM
198      !!----------------------------------------------------------------------
199      INTEGER ::   ji            ! dummy loop indices
200      INTEGER ::   ilocal_comm   ! local integer
201      CHARACTER(len=80), DIMENSION(16) ::   cltxt
202      !!
203      NAMELIST/namctl/ ln_ctl  , nn_print, nn_ictls, nn_ictle,   &
204         &             nn_isplt, nn_jsplt, nn_jctls, nn_jctle,   &
205         &             nn_bench, nn_timing
206      !!----------------------------------------------------------------------
207      !
208      cltxt = ''
209      !
210      !                             ! open Namelist file
211      CALL ctl_opn( numnam, 'namelist', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
212      !
213      READ( numnam, namctl )        ! Namelist namctl : Control prints & Benchmark
214      !
215      !                             !--------------------------------------------!
216      !                             !  set communicator & select the local node  !
217      !                             !--------------------------------------------!
218#if defined key_iomput
219      IF( Agrif_Root() ) THEN
220# if defined key_oasis3 || defined key_oasis4
221         CALL cpl_prism_init( ilocal_comm )                 ! nemo local communicator given by oasis
222# endif
223         CALL  init_ioclient( ilocal_comm )                 ! exchange io_server nemo local communicator with the io_server
224      ENDIF
225      narea = mynode( cltxt, numnam, nstop, ilocal_comm )   ! Nodes selection
226#else
227# if defined key_oasis3 || defined key_oasis4
228      IF( Agrif_Root() ) THEN
229         CALL cpl_prism_init( ilocal_comm )                 ! nemo local communicator given by oasis
230      ENDIF
231      narea = mynode( cltxt, numnam, nstop, ilocal_comm )   ! Nodes selection (control print return in cltxt)
232# else
233      ilocal_comm = 0
234      narea = mynode( cltxt, numnam, nstop )                 ! Nodes selection (control print return in cltxt)
235# endif
236#endif
237      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
238
239      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
240
241      ! If dimensions of processor grid weren't specified in the namelist file
242      ! then we calculate them here now that we have our communicator size
243      IF( (jpni < 1) .OR. (jpnj < 1) )THEN
244#if   defined key_mpp_mpi
245         IF( Agrif_Root() ) CALL nemo_partition(mppsize)
246#else
247         jpni  = 1
248         jpnj  = 1
249         jpnij = jpni*jpnj
250#endif
251      END IF
252
253      ! Calculate domain dimensions given calculated jpni and jpnj
254      ! This used to be done in par_oce.F90 when they were parameters rather
255      ! than variables
256      IF( Agrif_Root() ) THEN
257         jpi = ( jpiglo-2*jpreci + (jpni-1) ) / jpni + 2*jpreci   ! first  dim.
258#if defined key_nemocice_decomp
259         jpj = ( jpjglo+1-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj ! second dim.
260#else
261         jpj = ( jpjglo-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj   ! second dim.
262#endif
263         jpk = jpkdta                                             ! third dim
264         jpim1 = jpi-1                                            ! inner domain indices
265         jpjm1 = jpj-1                                            !   "           "
266         jpkm1 = jpk-1                                            !   "           "
267         jpij  = jpi*jpj                                          !  jpi x j
268      ENDIF
269
270      IF(lwp) THEN                            ! open listing units
271         !
272         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
273         !
274         WRITE(numout,*)
275         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
276         WRITE(numout,*) '                       NEMO team'
277         WRITE(numout,*) '            Ocean General Circulation Model'
278         WRITE(numout,*) '                  version 3.4  (2011) '
279         WRITE(numout,*)
280         WRITE(numout,*)
281         DO ji = 1, SIZE(cltxt) 
282            IF( TRIM(cltxt(ji)) /= '' )   WRITE(numout,*) cltxt(ji)      ! control print of mynode
283         END DO
284         WRITE(numout,cform_aaa)                                         ! Flag AAAAAAA
285         !
286      ENDIF
287
288      ! Now we know the dimensions of the grid and numout has been set we can
289      ! allocate arrays
290      CALL nemo_alloc()
291
292      !                             !-------------------------------!
293      !                             !  NEMO general initialization  !
294      !                             !-------------------------------!
295
296      CALL nemo_ctl                          ! Control prints & Benchmark
297
298      !                                      ! Domain decomposition
299      IF( jpni*jpnj == jpnij ) THEN   ;   CALL mpp_init      ! standard cutting out
300      ELSE                            ;   CALL mpp_init2     ! eliminate land processors
301      ENDIF
302      !
303      IF( nn_timing == 1 )  CALL timing_init
304      !
305      !                                      ! General initialization
306                            CALL     phy_cst    ! Physical constants
307                            CALL     eos_init   ! Equation of state
308                            CALL     dom_cfg    ! Domain configuration
309                            CALL     dom_init   ! Domain
310
311      IF( ln_nnogather )    CALL nemo_northcomms   ! Initialise the northfold neighbour lists (must be done after the masks are defined)
312
313      IF( ln_ctl        )   CALL prt_ctl_init   ! Print control
314
315      IF( lk_obc        )   CALL     obc_init   ! Open boundaries
316      IF( lk_bdy        )   CALL     bdy_init       ! Open boundaries initialisation
317      IF( lk_bdy        )   CALL     bdy_dta_init   ! Open boundaries initialisation of external data arrays
318      IF( lk_bdy        )   CALL     tide_init      ! Open boundaries initialisation of tidal harmonic forcing
319
320                            CALL dyn_nept_init  ! simplified form of Neptune effect
321
322                            CALL  istate_init   ! ocean initial state (Dynamics and tracers)
323
324      !                                     ! Ocean physics
325                            CALL     sbc_init   ! Forcings : surface module
326      !                                         ! Vertical physics
327                            CALL     zdf_init      ! namelist read
328                            CALL zdf_bfr_init      ! bottom friction
329      IF( lk_zdfric     )   CALL zdf_ric_init      ! Richardson number dependent Kz
330      IF( lk_zdftke     )   CALL zdf_tke_init      ! TKE closure scheme
331      IF( lk_zdfgls     )   CALL zdf_gls_init      ! GLS closure scheme
332      IF( lk_zdfkpp     )   CALL zdf_kpp_init      ! KPP closure scheme
333      IF( lk_zdftmx     )   CALL zdf_tmx_init      ! tidal vertical mixing
334      IF( lk_zdfddm .AND. .NOT. lk_zdfkpp )   & 
335         &                  CALL zdf_ddm_init      ! double diffusive mixing
336      !                                         ! Lateral physics
337                            CALL ldf_tra_init      ! Lateral ocean tracer physics
338                            CALL ldf_dyn_init      ! Lateral ocean momentum physics
339      IF( lk_ldfslp     )   CALL ldf_slp_init      ! slope of lateral mixing
340
341      !                                     ! Active tracers
342                            CALL tra_qsr_init   ! penetrative solar radiation qsr
343                            CALL tra_bbc_init   ! bottom heat flux
344      IF( lk_trabbl     )   CALL tra_bbl_init   ! advective (and/or diffusive) bottom boundary layer scheme
345      IF( ln_tradmp     )   CALL tra_dmp_init   ! internal damping trends
346                            CALL tra_adv_init   ! horizontal & vertical advection
347                            CALL tra_ldf_init   ! lateral mixing
348                            CALL tra_zdf_init   ! vertical mixing and after tracer fields
349
350      !                                     ! Dynamics
351                            CALL dyn_adv_init   ! advection (vector or flux form)
352                            CALL dyn_vor_init   ! vorticity term including Coriolis
353                            CALL dyn_ldf_init   ! lateral mixing
354                            CALL dyn_hpg_init   ! horizontal gradient of Hydrostatic pressure
355                            CALL dyn_zdf_init   ! vertical diffusion
356                            CALL dyn_spg_init   ! surface pressure gradient
357                           
358      !                                     ! Misc. options
359      IF( nn_cla == 1   )   CALL cla_init       ! Cross Land Advection
360     
361#if defined key_top
362      !                                     ! Passive tracers
363                            CALL     trc_init
364#endif
365      !                                     ! Diagnostics
366      IF( lk_floats     )   CALL     flo_init   ! drifting Floats
367                            CALL     iom_init   ! iom_put initialization
368      IF( lk_diaar5     )   CALL dia_ar5_init   ! ar5 diag
369                            CALL dia_ptr_init   ! Poleward TRansports initialization
370      IF( lk_diadct     )   CALL dia_dct_init   ! Sections tranports
371                            CALL dia_hsb_init   ! heat content, salt content and volume budgets
372                            CALL trd_mod_init   ! Mixed-layer/Vorticity/Integral constraints trends
373      IF( lk_diaobs     ) THEN                  ! Observation & model comparison
374                            CALL dia_obs_init            ! Initialize observational data
375                            CALL dia_obs( nit000 - 1 )   ! Observation operator for restart
376      ENDIF     
377      !                                     ! Assimilation increments
378      IF( lk_asminc     )   CALL asm_inc_init   ! Initialize assimilation increments
379      IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
380      !
381   END SUBROUTINE nemo_init
382
383
384   SUBROUTINE nemo_ctl
385      !!----------------------------------------------------------------------
386      !!                     ***  ROUTINE nemo_ctl  ***
387      !!
388      !! ** Purpose :   control print setting
389      !!
390      !! ** Method  : - print namctl information and check some consistencies
391      !!----------------------------------------------------------------------
392      !
393      IF(lwp) THEN                  ! control print
394         WRITE(numout,*)
395         WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
396         WRITE(numout,*) '~~~~~~~ '
397         WRITE(numout,*) '   Namelist namctl'
398         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
399         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
400         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
401         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
402         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
403         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
404         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
405         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
406         WRITE(numout,*) '      benchmark parameter (0/1)       nn_bench   = ', nn_bench
407         WRITE(numout,*) '      timing activated    (0/1)       nn_timing  = ', nn_timing
408      ENDIF
409      !
410      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
411      nictls    = nn_ictls
412      nictle    = nn_ictle
413      njctls    = nn_jctls
414      njctle    = nn_jctle
415      isplt     = nn_isplt
416      jsplt     = nn_jsplt
417      nbench    = nn_bench
418      !                             ! Parameter control
419      !
420      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
421         IF( lk_mpp .AND. jpnij > 1 ) THEN
422            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
423         ELSE
424            IF( isplt == 1 .AND. jsplt == 1  ) THEN
425               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
426                  &           ' - the print control will be done over the whole domain' )
427            ENDIF
428            ijsplt = isplt * jsplt            ! total number of processors ijsplt
429         ENDIF
430         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
431         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
432         !
433         !                              ! indices used for the SUM control
434         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
435            lsp_area = .FALSE.                       
436         ELSE                                             ! print control done over a specific  area
437            lsp_area = .TRUE.
438            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
439               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
440               nictls = 1
441            ENDIF
442            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
443               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
444               nictle = jpiglo
445            ENDIF
446            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
447               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
448               njctls = 1
449            ENDIF
450            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
451               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
452               njctle = jpjglo
453            ENDIF
454         ENDIF
455      ENDIF
456      !
457      IF( nbench == 1 ) THEN              ! Benchmark
458         SELECT CASE ( cp_cfg )
459         CASE ( 'gyre' )   ;   CALL ctl_warn( ' The Benchmark is activated ' )
460         CASE DEFAULT      ;   CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:',   &
461            &                                 ' key_gyre must be used or set nbench = 0' )
462         END SELECT
463      ENDIF
464      !
465      IF( lk_c1d .AND. .NOT.lk_iomput )   CALL ctl_stop( 'nemo_ctl: The 1D configuration must be used ',   &
466         &                                               'with the IOM Input/Output manager. '         ,   &
467         &                                               'Compile with key_iomput enabled' )
468      !
469   END SUBROUTINE nemo_ctl
470
471
472   SUBROUTINE nemo_closefile
473      !!----------------------------------------------------------------------
474      !!                     ***  ROUTINE nemo_closefile  ***
475      !!
476      !! ** Purpose :   Close the files
477      !!----------------------------------------------------------------------
478      !
479      IF( lk_mpp )   CALL mppsync
480      !
481      CALL iom_close                                 ! close all input/output files managed by iom_*
482      !
483      IF( numstp      /= -1 )   CLOSE( numstp      )   ! time-step file
484      IF( numsol      /= -1 )   CLOSE( numsol      )   ! solver file
485      IF( numnam      /= -1 )   CLOSE( numnam      )   ! oce namelist
486      IF( numnam_ice  /= -1 )   CLOSE( numnam_ice  )   ! ice namelist
487      IF( numevo_ice  /= -1 )   CLOSE( numevo_ice  )   ! ice variables (temp. evolution)
488      IF( numout      /=  6 )   CLOSE( numout      )   ! standard model output file
489      IF( numdct_vol  /= -1 )   CLOSE( numdct_vol  )   ! volume transports
490      IF( numdct_heat /= -1 )   CLOSE( numdct_heat )   ! heat transports
491      IF( numdct_salt /= -1 )   CLOSE( numdct_salt )   ! salt transports
492
493      !
494      numout = 6                                     ! redefine numout in case it is used after this point...
495      !
496   END SUBROUTINE nemo_closefile
497
498
499   SUBROUTINE nemo_alloc
500      !!----------------------------------------------------------------------
501      !!                     ***  ROUTINE nemo_alloc  ***
502      !!
503      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
504      !!
505      !! ** Method  :
506      !!----------------------------------------------------------------------
507      USE diawri    , ONLY: dia_wri_alloc
508      USE dom_oce   , ONLY: dom_oce_alloc
509      USE ldfdyn_oce, ONLY: ldfdyn_oce_alloc
510      USE ldftra_oce, ONLY: ldftra_oce_alloc
511      USE trc_oce   , ONLY: trc_oce_alloc
512      !
513      INTEGER :: ierr
514      !!----------------------------------------------------------------------
515      !
516      ierr =        oce_alloc       ()          ! ocean
517      ierr = ierr + dia_wri_alloc   ()
518      ierr = ierr + dom_oce_alloc   ()          ! ocean domain
519      ierr = ierr + ldfdyn_oce_alloc()          ! ocean lateral  physics : dynamics
520      ierr = ierr + ldftra_oce_alloc()          ! ocean lateral  physics : tracers
521      ierr = ierr + zdf_oce_alloc   ()          ! ocean vertical physics
522      !
523      ierr = ierr + lib_mpp_alloc   (numout)    ! mpp exchanges
524      ierr = ierr + trc_oce_alloc   ()          ! shared TRC / TRA arrays
525      !
526      IF( lk_mpp    )   CALL mpp_sum( ierr )
527      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
528      !
529   END SUBROUTINE nemo_alloc
530
531
532   SUBROUTINE nemo_partition( num_pes )
533      !!----------------------------------------------------------------------
534      !!                 ***  ROUTINE nemo_partition  ***
535      !!
536      !! ** Purpose :   
537      !!
538      !! ** Method  :
539      !!----------------------------------------------------------------------
540      INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have
541      !
542      INTEGER, PARAMETER :: nfactmax = 20
543      INTEGER :: nfact ! The no. of factors returned
544      INTEGER :: ierr  ! Error flag
545      INTEGER :: ji
546      INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
547      INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
548      !!----------------------------------------------------------------------
549
550      ierr = 0
551
552      CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
553
554      IF( nfact <= 1 ) THEN
555         WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
556         WRITE (numout, *) '       : using grid of ',num_pes,' x 1'
557         jpnj = 1
558         jpni = num_pes
559      ELSE
560         ! Search through factors for the pair that are closest in value
561         mindiff = 1000000
562         imin    = 1
563         DO ji = 1, nfact-1, 2
564            idiff = ABS( ifact(ji) - ifact(ji+1) )
565            IF( idiff < mindiff ) THEN
566               mindiff = idiff
567               imin = ji
568            ENDIF
569         END DO
570         jpnj = ifact(imin)
571         jpni = ifact(imin + 1)
572      ENDIF
573      !
574      jpnij = jpni*jpnj
575      !
576   END SUBROUTINE nemo_partition
577
578
579   SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
580      !!----------------------------------------------------------------------
581      !!                     ***  ROUTINE factorise  ***
582      !!
583      !! ** Purpose :   return the prime factors of n.
584      !!                knfax factors are returned in array kfax which is of
585      !!                maximum dimension kmaxfax.
586      !! ** Method  :
587      !!----------------------------------------------------------------------
588      INTEGER                    , INTENT(in   ) ::   kn, kmaxfax
589      INTEGER                    , INTENT(  out) ::   kerr, knfax
590      INTEGER, DIMENSION(kmaxfax), INTENT(  out) ::   kfax
591      !
592      INTEGER :: ifac, jl, inu
593      INTEGER, PARAMETER :: ntest = 14
594      INTEGER :: ilfax(ntest)
595
596      ! lfax contains the set of allowed factors.
597      data (ilfax(jl),jl=1,ntest) / 16384, 8192, 4096, 2048, 1024, 512, 256,  &
598         &                            128,   64,   32,   16,    8,   4,   2  /
599      !!----------------------------------------------------------------------
600
601      ! Clear the error flag and initialise output vars
602      kerr = 0
603      kfax = 1
604      knfax = 0
605
606      ! Find the factors of n.
607      IF( kn == 1 )   GOTO 20
608
609      ! nu holds the unfactorised part of the number.
610      ! knfax holds the number of factors found.
611      ! l points to the allowed factor list.
612      ! ifac holds the current factor.
613
614      inu   = kn
615      knfax = 0
616
617      DO jl = ntest, 1, -1
618         !
619         ifac = ilfax(jl)
620         IF( ifac > inu )   CYCLE
621
622         ! Test whether the factor will divide.
623
624         IF( MOD(inu,ifac) == 0 ) THEN
625            !
626            knfax = knfax + 1            ! Add the factor to the list
627            IF( knfax > kmaxfax ) THEN
628               kerr = 6
629               write (*,*) 'FACTOR: insufficient space in factor array ', knfax
630               return
631            ENDIF
632            kfax(knfax) = ifac
633            ! Store the other factor that goes with this one
634            knfax = knfax + 1
635            kfax(knfax) = inu / ifac
636            !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
637         ENDIF
638         !
639      END DO
640
641   20 CONTINUE      ! Label 20 is the exit point from the factor search loop.
642      !
643   END SUBROUTINE factorise
644
645#if defined key_mpp_mpi
646   SUBROUTINE nemo_northcomms
647      !!======================================================================
648      !!                     ***  ROUTINE  nemo_northcomms  ***
649      !! nemo_northcomms    :  Setup for north fold exchanges with explicit peer to peer messaging
650      !!=====================================================================
651      !!----------------------------------------------------------------------
652      !!
653      !! ** Purpose :   Initialization of the northern neighbours lists.
654      !!----------------------------------------------------------------------
655      !!    1.0  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE)
656      !!----------------------------------------------------------------------
657
658      INTEGER ::   ji, jj, jk, ij, jtyp    ! dummy loop indices
659      INTEGER ::   ijpj                    ! number of rows involved in north-fold exchange
660      INTEGER ::   northcomms_alloc        ! allocate return status
661      REAL(wp), ALLOCATABLE, DIMENSION ( :,: ) ::   znnbrs     ! workspace
662      LOGICAL,  ALLOCATABLE, DIMENSION ( : )   ::   lrankset   ! workspace
663
664      IF(lwp) WRITE(numout,*)
665      IF(lwp) WRITE(numout,*) 'nemo_northcomms : Initialization of the northern neighbours lists'
666      IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
667
668      !!----------------------------------------------------------------------
669      ALLOCATE( znnbrs(jpi,jpj), stat = northcomms_alloc )
670      ALLOCATE( lrankset(jpnij), stat = northcomms_alloc )
671      IF( northcomms_alloc /= 0 ) THEN
672         WRITE(numout,cform_war)
673         WRITE(numout,*) 'northcomms_alloc : failed to allocate arrays'
674         CALL ctl_stop( 'STOP', 'nemo_northcomms : unable to allocate temporary arrays' )
675      ENDIF
676      nsndto = 0
677      isendto = -1
678      ijpj   = 4
679      !
680      ! This routine has been called because ln_nnogather has been set true ( nammpp )
681      ! However, these first few exchanges have to use the mpi_allgather method to
682      ! establish the neighbour lists to use in subsequent peer to peer exchanges.
683      ! Consequently, set l_north_nogather to be false here and set it true only after
684      ! the lists have been established.
685      !
686      l_north_nogather = .FALSE.
687      !
688      ! Exchange and store ranks on northern rows
689
690      DO jtyp = 1,4
691
692         lrankset = .FALSE.
693         znnbrs = narea
694         SELECT CASE (jtyp)
695            CASE(1)
696               CALL lbc_lnk( znnbrs, 'T', 1. )      ! Type 1: T,W-points
697            CASE(2)
698               CALL lbc_lnk( znnbrs, 'U', 1. )      ! Type 2: U-point
699            CASE(3)
700               CALL lbc_lnk( znnbrs, 'V', 1. )      ! Type 3: V-point
701            CASE(4)
702               CALL lbc_lnk( znnbrs, 'F', 1. )      ! Type 4: F-point
703         END SELECT
704
705         IF ( njmppt(narea) .EQ. MAXVAL( njmppt ) ) THEN
706            DO jj = nlcj-ijpj+1, nlcj
707               ij = jj - nlcj + ijpj
708               DO ji = 1,jpi
709                  IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) &
710               &     lrankset(INT(znnbrs(ji,jj))) = .true.
711               END DO
712            END DO
713
714            DO jj = 1,jpnij
715               IF ( lrankset(jj) ) THEN
716                  nsndto(jtyp) = nsndto(jtyp) + 1
717                  IF ( nsndto(jtyp) .GT. jpmaxngh ) THEN
718                     CALL ctl_stop( ' Too many neighbours in nemo_northcomms ', &
719                  &                 ' jpmaxngh will need to be increased ')
720                  ENDIF
721                  isendto(nsndto(jtyp),jtyp) = jj-1   ! narea converted to MPI rank
722               ENDIF
723            END DO
724         ENDIF
725
726      END DO
727
728      !
729      ! Type 5: I-point
730      !
731      ! ICE point exchanges may involve some averaging. The neighbours list is
732      ! built up using two exchanges to ensure that the whole stencil is covered.
733      ! lrankset should not be reset between these 'J' and 'K' point exchanges
734
735      jtyp = 5
736      lrankset = .FALSE.
737      znnbrs = narea 
738      CALL lbc_lnk( znnbrs, 'J', 1. ) ! first ice U-V point
739
740      IF ( njmppt(narea) .EQ. MAXVAL( njmppt ) ) THEN
741         DO jj = nlcj-ijpj+1, nlcj
742            ij = jj - nlcj + ijpj
743            DO ji = 1,jpi
744               IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) &
745            &     lrankset(INT(znnbrs(ji,jj))) = .true.
746         END DO
747        END DO
748      ENDIF
749
750      znnbrs = narea 
751      CALL lbc_lnk( znnbrs, 'K', 1. ) ! second ice U-V point
752
753      IF ( njmppt(narea) .EQ. MAXVAL( njmppt )) THEN
754         DO jj = nlcj-ijpj+1, nlcj
755            ij = jj - nlcj + ijpj
756            DO ji = 1,jpi
757               IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND.  INT(znnbrs(ji,jj)) .NE. narea ) &
758            &       lrankset( INT(znnbrs(ji,jj))) = .true.
759            END DO
760         END DO
761
762         DO jj = 1,jpnij
763            IF ( lrankset(jj) ) THEN
764               nsndto(jtyp) = nsndto(jtyp) + 1
765               IF ( nsndto(jtyp) .GT. jpmaxngh ) THEN
766                  CALL ctl_stop( ' Too many neighbours in nemo_northcomms ', &
767               &                 ' jpmaxngh will need to be increased ')
768               ENDIF
769               isendto(nsndto(jtyp),jtyp) = jj-1   ! narea converted to MPI rank
770            ENDIF
771         END DO
772         !
773         ! For northern row areas, set l_north_nogather so that all subsequent exchanges
774         ! can use peer to peer communications at the north fold
775         !
776         l_north_nogather = .TRUE.
777         !
778      ENDIF
779      DEALLOCATE( znnbrs )
780      DEALLOCATE( lrankset )
781
782   END SUBROUTINE nemo_northcomms
783#else
784   SUBROUTINE nemo_northcomms      ! Dummy routine
785      WRITE(*,*) 'nemo_northcomms: You should not have seen this print! error?'
786   END SUBROUTINE nemo_northcomms
787#endif
788   !!======================================================================
789END MODULE nemogcm
Note: See TracBrowser for help on using the repository browser.