source: branches/2013/dev_LOCEAN_2013/NEMOGCM/NEMO/LIM_SRC_2/limhdf_2.F90 @ 4146

Last change on this file since 4146 was 3625, checked in by acc, 9 years ago

Branch dev_NOC_2012_r3555. #1006. Step 7. Check in code now merged with dev_r3385_NOCS04_HAMF

  • Property svn:keywords set to Id
File size: 7.3 KB
Line 
1MODULE limhdf_2
2   !!======================================================================
3   !!                    ***  MODULE limhdf_2   ***
4   !! LIM 2.0 ice model : horizontal diffusion of sea-ice quantities
5   !!======================================================================
6   !! History :  LIM  !  2000-01 (LIM) Original code
7   !!             -   !  2001-05 (G. Madec, R. Hordoir) opa norm
8   !!            1.0  !  2002-08 (C. Ethe)  F90, free form
9   !!----------------------------------------------------------------------
10#if defined key_lim2
11   !!----------------------------------------------------------------------
12   !!   'key_lim2'                                    LIM 2.0 sea-ice model
13   !!----------------------------------------------------------------------
14   !!   lim_hdf_2  : diffusion trend on sea-ice variable
15   !!----------------------------------------------------------------------
16   USE dom_oce          ! ocean domain
17   USE ice_2            ! LIM-2: ice variables
18   USE lbclnk           ! lateral boundary condition - MPP exchanges
19   USE lib_mpp          ! MPP library
20   USE wrk_nemo         ! work arrays
21   USE prtctl           ! Print control
22   USE in_out_manager   ! I/O manager
23   USE lib_fortran      ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   lim_hdf_2         ! called by limtrp_2.F90
29
30   LOGICAL  ::   linit = .TRUE.   ! ! initialization flag (set to flase after the 1st call)
31   REAL(wp) ::   epsi04 = 1e-04   ! constant
32   
33   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   efact   ! metric coefficient
34
35   !! * Substitution
36#  include "vectopt_loop_substitute.h90"
37   !!----------------------------------------------------------------------
38   !! NEMO/LIM2 4.0 , UCL - NEMO Consortium (2010)
39   !! $Id$
40   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
41   !!----------------------------------------------------------------------
42CONTAINS
43
44   SUBROUTINE lim_hdf_2( ptab )
45      !!-------------------------------------------------------------------
46      !!                  ***  ROUTINE lim_hdf_2  ***
47      !!
48      !! ** purpose :   Compute and add the diffusive trend on sea-ice variables
49      !!
50      !! ** method  :   Second order diffusive operator evaluated using a
51      !!              Cranck-Nicholson time Scheme.
52      !!
53      !! ** Action  :    update ptab with the diffusive contribution
54      !!-------------------------------------------------------------------
55      REAL(wp), DIMENSION(jpi,jpj), INTENT( inout ) ::   ptab   ! Field on which the diffusion is applied 
56      !
57      INTEGER  ::   ji, jj            ! dummy loop indices
58      INTEGER  ::   its, iter, ierr   ! local integers
59      REAL(wp) ::   zalfa, zrlxint, zconv, zeps   ! local scalars
60      REAL(wp), DIMENSION(:,:), POINTER :: zrlx, zflu, zflv, zdiv0, zdiv, ztab0 
61      CHARACTER (len=55) :: charout
62      !!-------------------------------------------------------------------
63
64      CALL wrk_alloc( jpi, jpj, zrlx, zflu, zflv, zdiv0, zdiv, ztab0 )
65
66      !                       !==  Initialisation  ==!
67      !
68      IF( linit ) THEN              ! Metric coefficient (compute at the first call and saved in efact)
69         ALLOCATE( efact(jpi,jpj) , STAT=ierr )
70         IF( lk_mpp    )   CALL mpp_sum( ierr )
71         IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'lim_hdf_2 : unable to allocate standard arrays' )
72         DO jj = 2, jpjm1 
73            DO ji = fs_2 , fs_jpim1   ! vector opt.
74               efact(ji,jj) = ( e2u(ji,jj) + e2u(ji-1,jj) + e1v(ji,jj) + e1v(ji,jj-1) ) / ( e1t(ji,jj) * e2t(ji,jj) )
75            END DO
76         END DO
77         linit = .FALSE.
78      ENDIF
79      !
80      !                             ! Time integration parameters
81      zalfa = 0.5_wp                      ! =1.0/0.5/0.0 = implicit/Cranck-Nicholson/explicit
82      its   = 100                         ! Maximum number of iteration
83      zeps  =  2._wp * epsi04
84      !
85      ztab0(:, : ) = ptab(:,:)      ! Arrays initialization
86      zdiv0(:, 1 ) = 0._wp
87      zdiv0(:,jpj) = 0._wp
88      IF( .NOT.lk_vopt_loop ) THEN
89         zflu (jpi,:) = 0._wp   
90         zflv (jpi,:) = 0._wp
91         zdiv0(1,  :) = 0._wp
92         zdiv0(jpi,:) = 0._wp
93      ENDIF
94
95      zconv = 1._wp           !==  horizontal diffusion using a Crant-Nicholson scheme  ==!
96      iter  = 0
97      !
98      DO WHILE (  zconv > zeps  .AND.  iter <= its  )    ! Sub-time step loop
99         !
100         iter = iter + 1                                       ! incrementation of the sub-time step number
101         !
102         DO jj = 1, jpjm1                                      ! diffusive fluxes in U- and V- direction
103            DO ji = 1 , fs_jpim1   ! vector opt.
104               zflu(ji,jj) = pahu(ji,jj) * e2u(ji,jj) / e1u(ji,jj) * ( ptab(ji+1,jj) - ptab(ji,jj) )
105               zflv(ji,jj) = pahv(ji,jj) * e1v(ji,jj) / e2v(ji,jj) * ( ptab(ji,jj+1) - ptab(ji,jj) )
106            END DO
107         END DO
108         !
109         DO jj= 2, jpjm1                                       ! diffusive trend : divergence of the fluxes
110            DO ji = fs_2 , fs_jpim1   ! vector opt.
111               zdiv (ji,jj) = (  zflu(ji,jj) - zflu(ji-1,jj  )   &
112                  &            + zflv(ji,jj) - zflv(ji  ,jj-1)  ) / ( e1t (ji,jj) * e2t (ji,jj) )
113            END DO
114         END DO
115         !
116         IF( iter == 1 )   zdiv0(:,:) = zdiv(:,:)              ! save the 1st evaluation of the diffusive trend in zdiv0
117         !
118         DO jj = 2, jpjm1                                      ! iterative evaluation
119            DO ji = fs_2 , fs_jpim1   ! vector opt.
120               zrlxint = (   ztab0(ji,jj)    &
121                  &       +  rdt_ice * (           zalfa   * ( zdiv(ji,jj) + efact(ji,jj) * ptab(ji,jj) )   &
122                  &                      + ( 1.0 - zalfa ) *   zdiv0(ji,jj) )  )                             & 
123                  &    / ( 1.0 + zalfa * rdt_ice * efact(ji,jj) )
124               zrlx(ji,jj) = ptab(ji,jj) + om * ( zrlxint - ptab(ji,jj) )
125            END DO
126         END DO
127         CALL lbc_lnk( zrlx, 'T', 1. )                         ! lateral boundary condition
128
129         zconv = 0._wp                                         ! convergence test
130
131         DO jj = 2, jpjm1
132            DO ji = 2, jpim1
133               zconv = MAX( zconv, ABS( zrlx(ji,jj) - ptab(ji,jj) )  )
134            END DO
135         END DO
136         IF( lk_mpp )   CALL mpp_max( zconv )                  ! max over the global domain
137
138         ptab(:,:) = zrlx(:,:)
139         !
140      END DO                                             ! end of sub-time step loop
141
142      IF(ln_ctl)   THEN
143         zrlx(:,:) = ptab(:,:) - ztab0(:,:)
144         WRITE(charout,FMT="(' lim_hdf  : zconv =',D23.16, ' iter =',I4,2X)") zconv, iter
145         CALL prt_ctl( tab2d_1=zrlx, clinfo1=charout )
146      ENDIF
147      !
148      CALL wrk_dealloc( jpi, jpj, zrlx, zflu, zflv, zdiv0, zdiv, ztab0 )
149      !
150   END SUBROUTINE lim_hdf_2
151
152#else
153   !!----------------------------------------------------------------------
154   !!   Default option          Dummy module       NO LIM 2.0 sea-ice model
155   !!----------------------------------------------------------------------
156CONTAINS
157   SUBROUTINE lim_hdf_2       ! Empty routine
158   END SUBROUTINE lim_hdf_2
159#endif
160
161   !!======================================================================
162END MODULE limhdf_2
Note: See TracBrowser for help on using the repository browser.