New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limsbc.F90 in branches/2013/dev_LOCEAN_2013/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/2013/dev_LOCEAN_2013/NEMOGCM/NEMO/LIM_SRC_3/limsbc.F90 @ 4161

Last change on this file since 4161 was 4161, checked in by cetlod, 11 years ago

dev_LOCEAN_2013 : merge in the 3rd dev branch dev_r4028_CNRS_LIM3, see ticket #1169

  • Property svn:keywords set to Id
File size: 26.9 KB
Line 
1MODULE limsbc
2   !!======================================================================
3   !!                       ***  MODULE limsbc   ***
4   !!           computation of the flux at the sea ice/ocean interface
5   !!======================================================================
6   !! History :   -   ! 2006-07 (M. Vancoppelle)  LIM3 original code
7   !!            3.0  ! 2008-03 (C. Tallandier)  surface module
8   !!             -   ! 2008-04 (C. Tallandier)  split in 2 + new ice-ocean coupling
9   !!            3.3  ! 2010-05 (G. Madec) decrease ocean & ice reference salinities in the Baltic sea
10   !!                 !                  + simplification of the ice-ocean stress calculation
11   !!            3.4  ! 2011-02 (G. Madec) dynamical allocation
12   !!             -   ! 2012    (D. Iovino) salt flux change
13   !!             -   ! 2012-05 (C. Rousset) add penetration solar flux
14   !!            3.5  ! 2012-10 (A. Coward, G. Madec) salt fluxes ; ice+snow mass
15   !!----------------------------------------------------------------------
16#if defined key_lim3
17   !!----------------------------------------------------------------------
18   !!   'key_lim3'                                    LIM 3.0 sea-ice model
19   !!----------------------------------------------------------------------
20   !!   lim_sbc_alloc : allocate the limsbc arrays
21   !!   lim_sbc_init  : initialisation
22   !!   lim_sbc_flx   : updates mass, heat and salt fluxes at the ocean surface
23   !!   lim_sbc_tau   : update i- and j-stresses, and its modulus at the ocean surface
24   !!----------------------------------------------------------------------
25   USE par_oce          ! ocean parameters
26   USE par_ice          ! ice parameters
27   USE dom_oce          ! ocean domain
28   USE sbc_ice          ! Surface boundary condition: sea-ice fields
29   USE sbc_oce          ! Surface boundary condition: ocean fields
30   USE phycst           ! physical constants
31   USE albedo           ! albedo parameters
32   USE ice              ! LIM sea-ice variables
33   USE lbclnk           ! ocean lateral boundary condition
34   USE in_out_manager   ! I/O manager
35   USE lib_mpp          ! MPP library
36   USE wrk_nemo         ! work arrays
37   USE prtctl           ! Print control
38   USE cpl_oasis3, ONLY : lk_cpl
39   USE traqsr           ! clem: add penetration of solar flux into the calculation of heat budget
40   USE oce,        ONLY : sshn, sshb, snwice_mass, snwice_mass_b, snwice_fmass, sshu_b, sshv_b, sshu_n, sshv_n, sshf_n
41   USE dom_ice,    ONLY : tms
42   USE lib_fortran      ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
43
44   IMPLICIT NONE
45   PRIVATE
46
47   PUBLIC   lim_sbc_init   ! called by ice_init
48   PUBLIC   lim_sbc_flx    ! called by sbc_ice_lim
49   PUBLIC   lim_sbc_tau    ! called by sbc_ice_lim
50
51   REAL(wp)  ::   epsi16 = 1.e-16_wp   ! constant values
52   REAL(wp)  ::   rzero  = 0._wp   
53   REAL(wp)  ::   rone   = 1._wp
54
55   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   utau_oce, vtau_oce   ! air-ocean surface i- & j-stress     [N/m2]
56   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   tmod_io              ! modulus of the ice-ocean velocity   [m/s]
57   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   soce_0  , sice_0     ! cst SSS and ice salinity (levitating sea-ice)
58
59   !! * Substitutions
60#  include "vectopt_loop_substitute.h90"
61   !!----------------------------------------------------------------------
62   !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011)
63   !! $Id$
64   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
65   !!----------------------------------------------------------------------
66CONTAINS
67
68   INTEGER FUNCTION lim_sbc_alloc()
69      !!-------------------------------------------------------------------
70      !!             ***  ROUTINE lim_sbc_alloc ***
71      !!-------------------------------------------------------------------
72      ALLOCATE( soce_0(jpi,jpj) , utau_oce(jpi,jpj) ,                       &
73         &      sice_0(jpi,jpj) , vtau_oce(jpi,jpj) , tmod_io(jpi,jpj), STAT=lim_sbc_alloc)
74         !
75      IF( lk_mpp             )   CALL mpp_sum( lim_sbc_alloc )
76      IF( lim_sbc_alloc /= 0 )   CALL ctl_warn('lim_sbc_alloc: failed to allocate arrays')
77   END FUNCTION lim_sbc_alloc
78
79
80   SUBROUTINE lim_sbc_flx( kt )
81      !!-------------------------------------------------------------------
82      !!                ***  ROUTINE lim_sbc_flx ***
83      !! 
84      !! ** Purpose :   Update the surface ocean boundary condition for heat
85      !!              salt and mass over areas where sea-ice is non-zero
86      !!         
87      !! ** Action  : - computes the heat and freshwater/salt fluxes
88      !!              at the ice-ocean interface.
89      !!              - Update the ocean sbc
90      !!     
91      !! ** Outputs : - qsr     : sea heat flux:     solar
92      !!              - qns     : sea heat flux: non solar
93      !!              - emp     : freshwater budget: volume flux
94      !!              - sfx     : salt flux
95      !!              - fr_i    : ice fraction
96      !!              - tn_ice  : sea-ice surface temperature
97      !!              - alb_ice : sea-ice alberdo (lk_cpl=T)
98      !!
99      !! References : Goosse, H. et al. 1996, Bul. Soc. Roy. Sc. Liege, 65, 87-90.
100      !!              Tartinville et al. 2001 Ocean Modelling, 3, 95-108.
101      !!---------------------------------------------------------------------
102      INTEGER, INTENT(in) ::   kt    ! number of iteration
103      !
104      INTEGER  ::   ji, jj, jl           ! dummy loop indices
105      INTEGER  ::   ierr, ifvt, i1mfr, idfr           ! local integer
106      INTEGER  ::   iflt, ial , iadv , ifral, ifrdv   !   -      -
107      REAL(wp) ::   zinda, zemp, zemp_snow, zfmm      ! local scalars
108      REAL(wp) ::   zemp_snw                          !   -      -
109      REAL(wp) ::   zfcm1 , zfcm2                     !   -      -
110      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zalb, zalbp     ! 2D/3D workspace
111      REAL(wp) ::   zzfcm1, zfscmbq ! clem: for light penetration
112      !!---------------------------------------------------------------------
113     
114      IF( lk_cpl )   CALL wrk_alloc( jpi, jpj, jpl, zalb, zalbp )
115
116      !------------------------------------------!
117      !      heat flux at the ocean surface      !
118      !------------------------------------------!
119      ! pfrld is the lead fraction at the previous time step (actually between TRP and THD)
120      ! changed to old_frld and old ht_i
121
122      DO jj = 1, jpj
123         DO ji = 1, jpi
124            zinda   = 1.0 - MAX( rzero , SIGN( rone , - ( 1.0 - pfrld(ji,jj) ) ) )
125            ifvt    = zinda  *  MAX( rzero , SIGN( rone, - phicif(ji,jj) ) )  !subscripts are bad here
126            i1mfr   = 1.0 - MAX( rzero , SIGN( rone ,  - at_i(ji,jj) ) )
127            idfr    = 1.0 - MAX( rzero , SIGN( rone , ( 1.0 - at_i(ji,jj) ) - pfrld(ji,jj) ) )
128            iflt    = zinda  * (1 - i1mfr) * (1 - ifvt )
129            ial     = ifvt   * i1mfr + ( 1 - ifvt ) * idfr
130            iadv    = ( 1  - i1mfr ) * zinda
131            ifral   = ( 1  - i1mfr * ( 1 - ial ) )   
132            ifrdv   = ( 1  - ifral * ( 1 - ial ) ) * iadv 
133
134            ! switch --- 1.0 ---------------- 0.0 --------------------
135            ! ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
136            ! zinda   | if pfrld = 1       | if pfrld < 1            |
137            !  -> ifvt| if pfrld old_ht_i
138            ! i1mfr   | if frld = 1        | if frld  < 1            |
139            ! idfr    | if frld <= pfrld    | if frld > pfrld        |
140            ! iflt    |
141            ! ial     |
142            ! iadv    |
143            ! ifral
144            ! ifrdv
145
146            !   computation the solar flux at ocean surface
147            IF (lk_cpl) THEN ! be carfeful: not being tested yet
148               ! original line
149               !zfcm1 = qsr_tot(ji,jj) + fstric(ji,jj) * at_i(ji,jj)
150               ! new line to include solar penetration (not tested)
151               zfcm1 = qsr_tot(ji,jj) + fstric(ji,jj) * at_i(ji,jj) / ( 1.0 - zinda + zinda * iatte(ji,jj) )
152               DO jl = 1, jpl
153                  zfcm1 = zfcm1 - qsr_ice(ji,jj,jl) * a_i(ji,jj,jl)
154               END DO
155            ELSE
156               zfcm1   = pfrld(ji,jj) * qsr(ji,jj)  + &
157                    &    ( 1._wp - pfrld(ji,jj) ) * fstric(ji,jj) / ( 1.0 - zinda + zinda * iatte(ji,jj) )
158            ENDIF
159            ! fstric     Solar flux transmitted trough the ice
160            ! qsr        Net short wave heat flux on free ocean
161            ! new line
162            fscmbq(ji,jj) = ( 1.0 - pfrld(ji,jj) ) * fstric(ji,jj) / ( 1.0 - zinda + zinda * iatte(ji,jj) )
163
164            ! solar flux and fscmbq with light penetration (clem)
165            zzfcm1  = pfrld(ji,jj) * qsr(ji,jj) * oatte(ji,jj) + ( 1. - pfrld(ji,jj) ) * fstric(ji,jj)
166            zfscmbq = ( 1.0 - pfrld(ji,jj) ) * fstric(ji,jj)
167
168            !  computation the non solar heat flux at ocean surface
169            zfcm2 = - zzfcm1                                                                    & !
170               &    + iflt    * zfscmbq                                                         & ! total ablation: heat given to the ocean
171               &    + ifral   * ( ial * qcmif(ji,jj) + (1 - ial) * qldif(ji,jj) ) * r1_rdtice   &
172               &    + ifrdv   * (       qfvbq(ji,jj) +             qdtcn(ji,jj) ) * r1_rdtice   &
173               &    + fhmec(ji,jj)                                                              & ! snow melt when ridging
174               &    + fheat_mec(ji,jj)                                                          & ! ridge formation
175               &    + fheat_res(ji,jj)                                                            ! residual heat flux
176            ! qcmif   Energy needed to bring the ocean surface layer until its freezing (ok)
177            ! qldif   heat balance of the lead (or of the open ocean)
178            ! qfvbq   latent heat uptake/release after accretion/ablation
179            ! qdtcn   Energy from the turbulent oceanic heat flux heat flux coming in the lead
180
181            IF( num_sal == 2 )   zfcm2 = zfcm2 + fhbri(ji,jj)    ! add contribution due to brine drainage
182
183            ! bottom radiative component is sent to the computation of the oceanic heat flux
184            fsbbq(ji,jj) = ( 1._wp - ( ifvt + iflt ) ) * fscmbq(ji,jj)     
185
186            ! used to compute the oceanic heat flux at the next time step
187            qsr(ji,jj) = zfcm1                                       ! solar heat flux
188            qns(ji,jj) = zfcm2 - fdtcn(ji,jj)                        ! non solar heat flux
189            !                           ! fdtcn : turbulent oceanic heat flux
190
191            !!gm   this IF prevents the vertorisation of the whole loop
192          !  IF ( ( ji == jiindx ) .AND. ( jj == jjindx) ) THEN
193          !     WRITE(numout,*) ' lim_sbc : heat fluxes '
194          !     WRITE(numout,*) ' qsr       : ', qsr(jiindx,jjindx)
195          !     WRITE(numout,*) ' pfrld     : ', pfrld(jiindx,jjindx)
196          !     WRITE(numout,*) ' fstric    : ', fstric (jiindx,jjindx)
197          !     WRITE(numout,*)
198          !     WRITE(numout,*) ' qns       : ', qns(jiindx,jjindx)
199          !     WRITE(numout,*) ' fdtcn     : ', fdtcn(jiindx,jjindx)
200          !     WRITE(numout,*) ' ifral     : ', ifral
201          !     WRITE(numout,*) ' ial       : ', ial 
202          !     WRITE(numout,*) ' qcmif     : ', qcmif(jiindx,jjindx)
203          !     WRITE(numout,*) ' qldif     : ', qldif(jiindx,jjindx)
204          !     !WRITE(numout,*) ' qcmif / dt: ', qcmif(jiindx,jjindx) * r1_rdtice
205          !     !WRITE(numout,*) ' qldif / dt: ', qldif(jiindx,jjindx) * r1_rdtice
206          !     WRITE(numout,*) ' ifrdv     : ', ifrdv
207          !     WRITE(numout,*) ' qfvbq     : ', qfvbq(jiindx,jjindx)
208          !     WRITE(numout,*) ' qdtcn     : ', qdtcn(jiindx,jjindx)
209          !     !WRITE(numout,*) ' qfvbq / dt: ', qfvbq(jiindx,jjindx) * r1_rdtice
210          !     !WRITE(numout,*) ' qdtcn / dt: ', qdtcn(jiindx,jjindx) * r1_rdtice
211          !     WRITE(numout,*) ' '
212          !     WRITE(numout,*) ' fdtcn     : ', fdtcn(jiindx,jjindx)
213          !     WRITE(numout,*) ' fhmec     : ', fhmec(jiindx,jjindx)
214          !     WRITE(numout,*) ' fheat_mec : ', fheat_mec(jiindx,jjindx)
215          !     WRITE(numout,*) ' fhbri     : ', fhbri(jiindx,jjindx)
216          !     WRITE(numout,*) ' fheat_res : ', fheat_res(jiindx,jjindx)
217          !  ENDIF
218            !!gm   end
219         END DO
220      END DO
221
222      !------------------------------------------!
223      !      mass flux at the ocean surface      !
224      !------------------------------------------!
225
226!!gm   optimisation: this loop have to be merged with the previous one
227      DO jj = 1, jpj
228         DO ji = 1, jpi
229            !  case of realistic freshwater flux (Tartinville et al., 2001) (presently ACTIVATED)
230            !  -------------------------------------------------------------------------------------
231            !  The idea of this approach is that the system that we consider is the ICE-OCEAN system
232            !  Thus  FW  flux  =  External ( E-P+snow melt)
233            !       Salt flux  =  Exchanges in the ice-ocean system then converted into FW
234            !                     Associated to Ice formation AND Ice melting
235            !                     Even if i see Ice melting as a FW and SALT flux
236            !       
237
238            !  computing freshwater exchanges at the ice/ocean interface
239            IF (lk_cpl) THEN
240               zemp = - emp_tot(ji,jj) + emp_ice(ji,jj) * ( 1. - pfrld(ji,jj) )    &   !
241                  &   - rdm_snw(ji,jj) / rdt_ice
242            ELSE
243               zemp =   emp(ji,jj)     * ( 1.0 - at_i(ji,jj)          )  &   ! evaporation over oceanic fraction
244                  &   - tprecip(ji,jj) *         at_i(ji,jj)             &   ! all precipitation reach the ocean
245                  &   + sprecip(ji,jj) * ( 1. - (pfrld(ji,jj)**betas) )  &   ! except solid precip intercepted by sea-ice
246                  &   - fmmec(ji,jj)                                         ! snow falling when ridging
247            ENDIF
248
249            ! mass flux at the ocean/ice interface (sea ice fraction)
250            zemp_snw = rdm_snw(ji,jj) * r1_rdtice                         ! snow melting = pure water that enters the ocean
251            zfmm     = rdm_ice(ji,jj) * r1_rdtice                         ! Freezing minus mesting 
252
253            fmmflx(ji,jj) = zfmm                                     ! F/M mass flux save at least for biogeochemical model
254
255            emp(ji,jj) = zemp + zemp_snw + zfmm  ! mass flux + F/M mass flux (always ice/ocean mass exchange)
256           
257            !  correcting brine salt fluxes   (zinda = 1  if pfrld=1 , =0 otherwise)
258            zinda        = 1.0 - MAX( rzero , SIGN( rone , - ( 1.0 - pfrld(ji,jj) ) ) )
259            sfx_bri(ji,jj) = zinda * sfx_bri(ji,jj)
260         END DO
261      END DO
262
263      !------------------------------------------!
264      !      salt flux at the ocean surface      !
265      !------------------------------------------!
266
267      IF( num_sal == 2 ) THEN      ! variable ice salinity: brine drainage included in the salt flux
268         sfx(:,:) = sfx_thd(:,:) + sfx_res(:,:) + sfx_mec(:,:) + sfx_bri(:,:)
269      ELSE                         ! constant ice salinity:
270         sfx(:,:) = sfx_thd(:,:) + sfx_res(:,:) + sfx_mec(:,:)
271      ENDIF
272      !-----------------------------------------------!
273      !   mass of snow and ice per unit area          !
274      !-----------------------------------------------!
275      IF( nn_ice_embd /= 0 ) THEN                               ! embedded sea-ice (mass required)
276         snwice_mass_b(:,:) = snwice_mass(:,:)                  ! save mass from the previous ice time step
277         !                                                      ! new mass per unit area
278         snwice_mass  (:,:) = tms(:,:) * ( rhosn * vt_s(:,:) + rhoic * vt_i(:,:)  ) 
279         !                                                      ! time evolution of snow+ice mass
280         snwice_fmass (:,:) = ( snwice_mass(:,:) - snwice_mass_b(:,:) ) * r1_rdtice
281      ENDIF
282
283      !-----------------------------------------------!
284      !   Storing the transmitted variables           !
285      !-----------------------------------------------!
286      fr_i  (:,:)   = at_i(:,:)             ! Sea-ice fraction           
287      tn_ice(:,:,:) = t_su(:,:,:)           ! Ice surface temperature                     
288
289      !------------------------------------------------!
290      !    Computation of snow/ice and ocean albedo    !
291      !------------------------------------------------!
292      IF( lk_cpl ) THEN          ! coupled case
293         CALL albedo_ice( t_su, ht_i, ht_s, zalbp, zalb )                  ! snow/ice albedo
294         !
295         alb_ice(:,:,:) =  0.5_wp * zalbp(:,:,:) + 0.5_wp * zalb (:,:,:)   ! Ice albedo (mean clear and overcast skys)
296      ENDIF
297
298      IF(ln_ctl) THEN
299         CALL prt_ctl( tab2d_1=qsr   , clinfo1=' lim_sbc: qsr    : ', tab2d_2=qns , clinfo2=' qns     : ' )
300         CALL prt_ctl( tab2d_1=emp   , clinfo1=' lim_sbc: emp    : ', tab2d_2=sfx , clinfo2=' sfx     : ' )
301         CALL prt_ctl( tab2d_1=fr_i  , clinfo1=' lim_sbc: fr_i   : ' )
302         CALL prt_ctl( tab3d_1=tn_ice, clinfo1=' lim_sbc: tn_ice : ', kdim=jpl )
303      ENDIF
304      !
305      IF( lk_cpl )   CALL wrk_dealloc( jpi, jpj, jpl, zalb, zalbp )
306      !
307   END SUBROUTINE lim_sbc_flx
308
309
310   SUBROUTINE lim_sbc_tau( kt , pu_oce, pv_oce )
311      !!-------------------------------------------------------------------
312      !!                ***  ROUTINE lim_sbc_tau ***
313      !! 
314      !! ** Purpose : Update the ocean surface stresses due to the ice
315      !!         
316      !! ** Action  : * at each ice time step (every nn_fsbc time step):
317      !!                - compute the modulus of ice-ocean relative velocity
318      !!                  (*rho*Cd) at T-point (C-grid) or I-point (B-grid)
319      !!                      tmod_io = rhoco * | U_ice-U_oce |
320      !!                - update the modulus of stress at ocean surface
321      !!                      taum = frld * taum + (1-frld) * tmod_io * | U_ice-U_oce |
322      !!              * at each ocean time step (every kt):
323      !!                  compute linearized ice-ocean stresses as
324      !!                      Utau = tmod_io * | U_ice - pU_oce |
325      !!                using instantaneous current ocean velocity (usually before)
326      !!
327      !!    NB: - ice-ocean rotation angle no more allowed
328      !!        - here we make an approximation: taum is only computed every ice time step
329      !!          This avoids mutiple average to pass from T -> U,V grids and next from U,V grids
330      !!          to T grid. taum is used in TKE and GLS, which should not be too sensitive to this approximaton...
331      !!
332      !! ** Outputs : - utau, vtau   : surface ocean i- and j-stress (u- & v-pts) updated with ice-ocean fluxes
333      !!              - taum         : modulus of the surface ocean stress (T-point) updated with ice-ocean fluxes
334      !!---------------------------------------------------------------------
335      INTEGER ,                     INTENT(in) ::   kt               ! ocean time-step index
336      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   pu_oce, pv_oce   ! surface ocean currents
337      !!
338      INTEGER  ::   ji, jj   ! dummy loop indices
339      REAL(wp) ::   zat_u, zutau_ice, zu_t, zmodt   ! local scalar
340      REAL(wp) ::   zat_v, zvtau_ice, zv_t          !   -      -
341      !!---------------------------------------------------------------------
342      !
343      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN     !==  Ice time-step only  ==!   (i.e. surface module time-step)
344!CDIR NOVERRCHK
345         DO jj = 2, jpjm1                             !* update the modulus of stress at ocean surface (T-point)
346!CDIR NOVERRCHK
347            DO ji = fs_2, fs_jpim1
348               !                                               ! 2*(U_ice-U_oce) at T-point
349               zu_t = u_ice(ji,jj) + u_ice(ji-1,jj) - u_oce(ji,jj) - u_oce(ji-1,jj)   
350               zv_t = v_ice(ji,jj) + v_ice(ji,jj-1) - v_oce(ji,jj) - v_oce(ji,jj-1) 
351               !                                              ! |U_ice-U_oce|^2
352               zmodt =  0.25_wp * (  zu_t * zu_t + zv_t * zv_t  )
353               !                                               ! update the ocean stress modulus
354               taum(ji,jj) = ( 1._wp - at_i(ji,jj) ) * taum(ji,jj) + at_i(ji,jj) * rhoco * zmodt
355               tmod_io(ji,jj) = rhoco * SQRT( zmodt )          ! rhoco * |U_ice-U_oce| at T-point
356            END DO
357         END DO
358         CALL lbc_lnk( taum, 'T', 1. )   ;   CALL lbc_lnk( tmod_io, 'T', 1. )
359         !
360         utau_oce(:,:) = utau(:,:)                    !* save the air-ocean stresses at ice time-step
361         vtau_oce(:,:) = vtau(:,:)
362         !
363      ENDIF
364      !
365      !                                      !==  every ocean time-step  ==!
366      !
367      DO jj = 2, jpjm1                                !* update the stress WITHOUT a ice-ocean rotation angle
368         DO ji = fs_2, fs_jpim1   ! Vect. Opt.
369            zat_u  = ( at_i(ji,jj) + at_i(ji+1,jj) ) * 0.5_wp   ! ice area at u and V-points
370            zat_v  = ( at_i(ji,jj) + at_i(ji,jj+1) ) * 0.5_wp
371            !                                                   ! linearized quadratic drag formulation
372            zutau_ice   = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji+1,jj) ) * ( u_ice(ji,jj) - pu_oce(ji,jj) )
373            zvtau_ice   = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji,jj+1) ) * ( v_ice(ji,jj) - pv_oce(ji,jj) )
374            !                                                   ! stresses at the ocean surface
375            utau(ji,jj) = ( 1._wp - zat_u ) * utau_oce(ji,jj) + zat_u * zutau_ice
376            vtau(ji,jj) = ( 1._wp - zat_v ) * vtau_oce(ji,jj) + zat_v * zvtau_ice
377         END DO
378      END DO
379      CALL lbc_lnk( utau, 'U', -1. )   ;   CALL lbc_lnk( vtau, 'V', -1. )   ! lateral boundary condition
380      !
381      IF(ln_ctl)   CALL prt_ctl( tab2d_1=utau, clinfo1=' lim_sbc: utau   : ', mask1=umask,   &
382         &                       tab2d_2=vtau, clinfo2=' vtau    : '        , mask2=vmask )
383     
384   END SUBROUTINE lim_sbc_tau
385
386
387   SUBROUTINE lim_sbc_init
388      !!-------------------------------------------------------------------
389      !!                  ***  ROUTINE lim_sbc_init  ***
390      !!             
391      !! ** Purpose : Preparation of the file ice_evolu for the output of
392      !!      the temporal evolution of key variables
393      !!
394      !! ** input   : Namelist namicedia
395      !!-------------------------------------------------------------------
396      REAL(wp) :: zsum, zarea
397      !
398      INTEGER  ::   ji, jj                          ! dummy loop indices
399      REAL(wp) ::   zcoefu, zcoefv, zcoeff          ! local scalar
400      IF(lwp) WRITE(numout,*)
401      IF(lwp) WRITE(numout,*) 'lim_sbc_init : LIM-3 sea-ice - surface boundary condition'
402      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~   '
403
404      !                                      ! allocate lim_sbc array
405      IF( lim_sbc_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'lim_sbc_init : unable to allocate standard arrays' )
406      !
407      soce_0(:,:) = soce                     ! constant SSS and ice salinity used in levitating sea-ice case
408      sice_0(:,:) = sice
409      !
410      IF( cp_cfg == "orca" ) THEN            ! decrease ocean & ice reference salinities in the Baltic sea
411         WHERE( 14._wp <= glamt(:,:) .AND. glamt(:,:) <= 32._wp .AND.   &
412            &   54._wp <= gphit(:,:) .AND. gphit(:,:) <= 66._wp         ) 
413            soce_0(:,:) = 4._wp
414            sice_0(:,:) = 2._wp
415         END WHERE
416      ENDIF
417      ! clem modif
418      iatte(:,:) = 1._wp
419      oatte(:,:) = 1._wp
420      !
421      !                                      ! embedded sea ice
422      IF( nn_ice_embd /= 0 ) THEN            ! mass exchanges between ice and ocean (case 1 or 2) set the snow+ice mass
423         snwice_mass  (:,:) = tms(:,:) * ( rhosn * vt_s(:,:) + rhoic * vt_i(:,:)  )
424         snwice_mass_b(:,:) = snwice_mass(:,:)
425      ELSE
426         snwice_mass  (:,:) = 0.0_wp         ! no mass exchanges
427         snwice_mass_b(:,:) = 0.0_wp         ! no mass exchanges
428      ENDIF
429      IF( nn_ice_embd == 2  .AND.         &  ! full embedment (case 2) & no restart
430         &  .NOT. ln_rstart ) THEN           ! deplete the initial ssh below sea-ice area
431         sshn(:,:) = sshn(:,:) - snwice_mass(:,:) * r1_rau0
432         sshb(:,:) = sshb(:,:) - snwice_mass(:,:) * r1_rau0
433         !
434         ! Note: Changed the initial values of sshb and sshn=>  need to recompute ssh[u,v,f]_[b,n]
435         !       which were previously set in domvvl
436         IF ( lk_vvl ) THEN            ! Is this necessary? embd 2 should be restricted to vvl only???
437            DO jj = 1, jpjm1
438               DO ji = 1, jpim1                    ! caution: use of Vector Opt. not possible
439                  zcoefu = 0.5  * umask(ji,jj,1) / ( e1u(ji,jj) * e2u(ji,jj) )
440                  zcoefv = 0.5  * vmask(ji,jj,1) / ( e1v(ji,jj) * e2v(ji,jj) )
441                  zcoeff = 0.25 * umask(ji,jj,1) * umask(ji,jj+1,1)
442                  sshu_b(ji,jj) = zcoefu * ( e1t(ji  ,jj) * e2t(ji  ,jj) * sshb(ji  ,jj)     &
443                     &                     + e1t(ji+1,jj) * e2t(ji+1,jj) * sshb(ji+1,jj) )
444                  sshv_b(ji,jj) = zcoefv * ( e1t(ji,jj  ) * e2t(ji,jj  ) * sshb(ji,jj  )     &
445                     &                     + e1t(ji,jj+1) * e2t(ji,jj+1) * sshb(ji,jj+1) )
446                  sshu_n(ji,jj) = zcoefu * ( e1t(ji  ,jj) * e2t(ji  ,jj) * sshn(ji  ,jj)     &
447                     &                     + e1t(ji+1,jj) * e2t(ji+1,jj) * sshn(ji+1,jj) )
448                  sshv_n(ji,jj) = zcoefv * ( e1t(ji,jj  ) * e2t(ji,jj  ) * sshn(ji,jj  )     &
449                     &                     + e1t(ji,jj+1) * e2t(ji,jj+1) * sshn(ji,jj+1) )
450               END DO
451            END DO
452            CALL lbc_lnk( sshu_b, 'U', 1. )   ;   CALL lbc_lnk( sshu_n, 'U', 1. )
453            CALL lbc_lnk( sshv_b, 'V', 1. )   ;   CALL lbc_lnk( sshv_n, 'V', 1. )
454            DO jj = 1, jpjm1
455               DO ji = 1, jpim1      ! NO Vector Opt.
456                  sshf_n(ji,jj) = 0.5  * umask(ji,jj,1) * umask(ji,jj+1,1)                   &
457                       &               / ( e1f(ji,jj  ) * e2f(ji,jj  ) )                     &
458                       &               * ( e1u(ji,jj  ) * e2u(ji,jj  ) * sshu_n(ji,jj  )     &
459                       &                 + e1u(ji,jj+1) * e2u(ji,jj+1) * sshu_n(ji,jj+1) )
460               END DO
461            END DO
462            CALL lbc_lnk( sshf_n, 'F', 1. )
463          ENDIF
464      ENDIF
465      !
466!!?      IF( .NOT. ln_rstart ) THEN           ! delete the initial ssh below sea-ice area
467!!?         !
468!!?         zarea     = glob_sum( e1e2t(:,:) )           ! interior global domain surface
469!!?         zsum      = glob_sum( e1e2t(:,:) * ( snwice_mass(:,:) ) ) / zarea * r1_rau0
470!!?         sshn(:,:) = sshn(:,:) - zsum
471!!?         sshb(:,:) = sshb(:,:) - zsum
472!!?      ENDIF
473      !
474
475   END SUBROUTINE lim_sbc_init
476
477#else
478   !!----------------------------------------------------------------------
479   !!   Default option :        Dummy module       NO LIM 3.0 sea-ice model
480   !!----------------------------------------------------------------------
481CONTAINS
482   SUBROUTINE lim_sbc           ! Dummy routine
483   END SUBROUTINE lim_sbc
484#endif 
485
486   !!======================================================================
487END MODULE limsbc
Note: See TracBrowser for help on using the repository browser.