source: branches/2013/dev_LOCEAN_2013/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zmeso.F90 @ 4147

Last change on this file since 4147 was 4147, checked in by cetlod, 8 years ago

merge in dev_LOCEAN_2013, the 1st development branch dev_r3853_CNRS9_Confsetting, from its starting point ( r3853 ) on the trunk: see ticket #1169

File size: 16.8 KB
Line 
1MODULE p4zmeso
2   !!======================================================================
3   !!                         ***  MODULE p4zmeso  ***
4   !! TOP :   PISCES Compute the sources/sinks for mesozooplankton
5   !!======================================================================
6   !! History :   1.0  !  2002     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!----------------------------------------------------------------------
10#if defined key_pisces
11   !!----------------------------------------------------------------------
12   !!   'key_pisces'                                       PISCES bio-model
13   !!----------------------------------------------------------------------
14   !!   p4z_meso       :   Compute the sources/sinks for mesozooplankton
15   !!   p4z_meso_init  :   Initialization of the parameters for mesozooplankton
16   !!----------------------------------------------------------------------
17   USE oce_trc         !  shared variables between ocean and passive tracers
18   USE trc             !  passive tracers common variables
19   USE sms_pisces      !  PISCES Source Minus Sink variables
20   USE p4zsink         !  vertical flux of particulate matter due to sinking
21   USE p4zint          !  interpolation and computation of various fields
22   USE p4zprod         !  production
23   USE prtctl_trc      !  print control for debugging
24   USE iom             !  I/O manager
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   p4z_meso              ! called in p4zbio.F90
30   PUBLIC   p4z_meso_init         ! called in trcsms_pisces.F90
31
32   !! * Shared module variables
33   REAL(wp), PUBLIC ::  part2        !: part of calcite not dissolved in mesozoo guts
34   REAL(wp), PUBLIC ::  xprefc       !: mesozoo preference for POC
35   REAL(wp), PUBLIC ::  xprefp       !: mesozoo preference for nanophyto
36   REAL(wp), PUBLIC ::  xprefz       !: mesozoo preference for diatoms
37   REAL(wp), PUBLIC ::  xprefpoc     !: mesozoo preference for POC
38   REAL(wp), PUBLIC ::  xthresh2zoo  !: zoo feeding threshold for mesozooplankton
39   REAL(wp), PUBLIC ::  xthresh2dia  !: diatoms feeding threshold for mesozooplankton
40   REAL(wp), PUBLIC ::  xthresh2phy  !: nanophyto feeding threshold for mesozooplankton
41   REAL(wp), PUBLIC ::  xthresh2poc  !: poc feeding threshold for mesozooplankton
42   REAL(wp), PUBLIC ::  xthresh2     !: feeding threshold for mesozooplankton
43   REAL(wp), PUBLIC ::  resrat2      !: exsudation rate of mesozooplankton
44   REAL(wp), PUBLIC ::  mzrat2       !: microzooplankton mortality rate
45   REAL(wp), PUBLIC ::  grazrat2     !: maximal mesozoo grazing rate
46   REAL(wp), PUBLIC ::  xkgraz2      !: non assimilated fraction of P by mesozoo
47   REAL(wp), PUBLIC ::  unass2       !: Efficicency of mesozoo growth
48   REAL(wp), PUBLIC ::  sigma2       !: Fraction of mesozoo excretion as DOM
49   REAL(wp), PUBLIC ::  epsher2      !: half sturation constant for grazing 2
50   REAL(wp), PUBLIC ::  grazflux     !: mesozoo flux feeding rate
51
52   !!* Substitution
53#  include "top_substitute.h90"
54   !!----------------------------------------------------------------------
55   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
56   !! $Id: p4zmeso.F90 3295 2012-01-30 15:49:07Z cetlod $
57   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
58   !!----------------------------------------------------------------------
59
60CONTAINS
61
62   SUBROUTINE p4z_meso( kt, jnt )
63      !!---------------------------------------------------------------------
64      !!                     ***  ROUTINE p4z_meso  ***
65      !!
66      !! ** Purpose :   Compute the sources/sinks for mesozooplankton
67      !!
68      !! ** Method  : - ???
69      !!---------------------------------------------------------------------
70      INTEGER, INTENT(in) ::   kt, jnt ! ocean time step
71      INTEGER  :: ji, jj, jk
72      REAL(wp) :: zcompadi, zcompaph, zcompapoc, zcompaz, zcompam
73      REAL(wp) :: zgraze2 , zdenom, zdenom2, zncratio
74      REAL(wp) :: zfact   , zstep, zfood, zfoodlim
75      REAL(wp) :: zepshert, zepsherv, zgrarsig, zgraztot, zgraztotf
76      REAL(wp) :: zgrarem2, zgrafer2, zgrapoc2, zprcaca, zmortz2, zmortzgoc, zgrasrat
77#if defined key_kriest
78      REAL znumpoc
79#endif
80      REAL(wp) :: zrespz2, ztortz2, zgrazd, zgrazz, zgrazpof
81      REAL(wp) :: zgrazn, zgrazpoc, zgraznf, zgrazf
82      REAL(wp) :: zgrazfff, zgrazffe
83      REAL(wp) :: zrfact2
84      REAL(wp), POINTER, DIMENSION(:,:,:) :: zgrazing
85      CHARACTER (len=25) :: charout
86      !!---------------------------------------------------------------------
87      !
88      IF( nn_timing == 1 )  CALL timing_start('p4z_meso')
89      !
90      IF( ln_diatrc .AND. lk_iomput )  CALL wrk_alloc( jpi, jpj, jpk, zgrazing )
91      !
92      DO jk = 1, jpkm1
93         DO jj = 1, jpj
94            DO ji = 1, jpi
95               zcompam   = MAX( ( trn(ji,jj,jk,jpmes) - 1.e-8 ), 0.e0 )
96# if defined key_degrad
97               zstep     = xstep * facvol(ji,jj,jk)
98# else
99               zstep     = xstep
100# endif
101               zfact     = zstep * tgfunc2(ji,jj,jk) * zcompam
102
103               !  Respiration rates of both zooplankton
104               !  -------------------------------------
105               zrespz2   = resrat2 * zfact * trn(ji,jj,jk,jpmes) / ( xkmort + trn(ji,jj,jk,jpmes) )  &
106                  &      + resrat2 * zfact * 3. * nitrfac(ji,jj,jk)
107
108               !  Zooplankton mortality. A square function has been selected with
109               !  no real reason except that it seems to be more stable and may mimic predation
110               !  ---------------------------------------------------------------
111               ztortz2   = mzrat2 * 1.e6 * zfact * trn(ji,jj,jk,jpmes)
112               !
113
114               zcompadi  = MAX( ( trn(ji,jj,jk,jpdia) - xthresh2dia ), 0.e0 )
115               zcompaz   = MAX( ( trn(ji,jj,jk,jpzoo) - xthresh2zoo ), 0.e0 )
116               zcompaph  = MAX( ( trn(ji,jj,jk,jpphy) - xthresh2phy ), 0.e0 )
117               zcompapoc = MAX( ( trn(ji,jj,jk,jppoc) - xthresh2poc ), 0.e0 )
118
119               zfood     = xprefc * zcompadi + xprefz * zcompaz + xprefp * zcompaph + xprefpoc * zcompapoc 
120               zfoodlim  = MAX( 0., zfood - MIN( 0.5 * zfood , xthresh2 ) )
121               zdenom    = zfoodlim / ( xkgraz2 + zfoodlim )
122               zdenom2   = zdenom / ( zfood + rtrn )
123               zgraze2   = grazrat2 * zstep * tgfunc2(ji,jj,jk) * trn(ji,jj,jk,jpmes) 
124
125               zgrazd    = zgraze2  * xprefc   * zcompadi  * zdenom2 
126               zgrazz    = zgraze2  * xprefz   * zcompaz   * zdenom2 
127               zgrazn    = zgraze2  * xprefp   * zcompaph  * zdenom2 
128               zgrazpoc  = zgraze2  * xprefpoc * zcompapoc * zdenom2 
129
130               zgraznf   = zgrazn   * trn(ji,jj,jk,jpnfe) / ( trn(ji,jj,jk,jpphy) + rtrn)
131               zgrazf    = zgrazd   * trn(ji,jj,jk,jpdfe) / ( trn(ji,jj,jk,jpdia) + rtrn)
132               zgrazpof  = zgrazpoc * trn(ji,jj,jk,jpsfe) / ( trn(ji,jj,jk,jppoc) + rtrn)
133
134               !  Mesozooplankton flux feeding on GOC
135               !  ----------------------------------
136# if ! defined key_kriest
137               zgrazffe  = grazflux * zstep * wsbio4(ji,jj,jk)          &
138                 &                 * tgfunc2(ji,jj,jk) * trn(ji,jj,jk,jpgoc) * trn(ji,jj,jk,jpmes)
139               zgrazfff  = zgrazffe * trn(ji,jj,jk,jpbfe) / (trn(ji,jj,jk,jpgoc) + rtrn)
140# else
141               zgrazffe = grazflux * zstep * wsbio3(ji,jj,jk)     &
142                 &                 * tgfunc2(ji,jj,jk) * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jpmes)
143               zgrazfff   = zgrazffe * trn(ji,jj,jk,jpsfe) / (trn(ji,jj,jk,jppoc) + rtrn)
144# endif
145              !
146              zgraztot   = zgrazd + zgrazz + zgrazn + zgrazpoc + zgrazffe
147              zgraztotf  = zgrazf + zgraznf + zgrazz * ferat3 + zgrazpof + zgrazfff 
148
149              ! Total grazing ( grazing by microzoo is already computed in p4zmicro )
150              IF( ln_diatrc .AND. lk_iomput )  zgrazing(ji,jj,jk) = zgraztot
151
152              !    Mesozooplankton efficiency
153              !    --------------------------
154              zgrasrat   =  zgraztotf / ( zgraztot + rtrn )
155              zncratio   = (  xprefc   * zcompadi * quotad(ji,jj,jk)  &
156                  &         + xprefp   * zcompaph * quotan(ji,jj,jk)  &
157                  &         + xprefz   * zcompaz                      &
158                  &         + xprefpoc * zcompapoc   ) / ( zfood + rtrn )
159               zepshert  = epsher2 * MIN( 1., zncratio )
160               zepsherv  = zepshert * MIN( 1., zgrasrat / ferat3 )
161               zgrarem2  = zgraztot * ( 1. - zepsherv - unass2 ) + zrespz2  &
162               &    + ( 1. - zepsherv - unass2 ) /( 1. - zepsherv + rtrn) * ztortz2
163               zgrafer2  = zgraztot * MAX( 0. , ( 1. - unass2 ) * zgrasrat - ferat3 * zepsherv )    &
164               &    + ferat3 * ( zrespz2 + ( 1. - zepsherv - unass2 ) /( 1. - zepsherv + rtrn) * ztortz2 )
165               zgrapoc2  = zgraztot * unass2
166
167               !   Update the arrays TRA which contain the biological sources and sinks
168               zgrarsig  = zgrarem2 * sigma2
169               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zgrarsig
170               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zgrarsig
171               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zgrarem2 - zgrarsig
172               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2ut * zgrarsig
173               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zgrafer2
174               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrarsig
175               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * zgrarsig             
176#if defined key_kriest
177               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zgrapoc2
178               tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) + zgrapoc2 * xkr_dmeso
179               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zgraztotf * unass2
180#else
181               tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zgrapoc2
182               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zgraztotf * unass2
183#endif
184               zmortz2 = ztortz2 + zrespz2
185               zmortzgoc = unass2 / ( 1. - zepsherv + rtrn ) * ztortz2
186               tra(ji,jj,jk,jpmes) = tra(ji,jj,jk,jpmes) - zmortz2 + zepsherv * zgraztot 
187               tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zgrazd
188               tra(ji,jj,jk,jpzoo) = tra(ji,jj,jk,jpzoo) - zgrazz
189               tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zgrazn
190               tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zgrazn * trn(ji,jj,jk,jpnch) / ( trn(ji,jj,jk,jpphy) + rtrn )
191               tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zgrazd * trn(ji,jj,jk,jpdch) / ( trn(ji,jj,jk,jpdia) + rtrn )
192               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) - zgrazd * trn(ji,jj,jk,jpdsi) / ( trn(ji,jj,jk,jpdia) + rtrn )
193               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) + zgrazd * trn(ji,jj,jk,jpdsi) / ( trn(ji,jj,jk,jpdia) + rtrn )
194               tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zgraznf
195               tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zgrazf
196
197               zprcaca = xfracal(ji,jj,jk) * zgrazn
198               ! calcite production
199               prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
200               !
201               zprcaca = part2 * zprcaca
202               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprcaca
203               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2. * zprcaca
204               tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) + zprcaca
205#if defined key_kriest
206               znumpoc = trn(ji,jj,jk,jpnum) / ( trn(ji,jj,jk,jppoc) + rtrn )
207               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zmortzgoc - zgrazpoc - zgrazffe
208               tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) - zgrazpoc * znumpoc &
209                  &    + zmortzgoc  * xkr_dmeso - zgrazffe * znumpoc * wsbio4(ji,jj,jk) / ( wsbio3(ji,jj,jk) + rtrn )
210               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + ferat3 * zmortz2 - zgrazfff - zgrazpof
211#else
212               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) - zgrazpoc
213               tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zmortzgoc - zgrazffe
214               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) - zgrazpof
215               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + ferat3 * zmortzgoc - zgrazfff
216#endif
217
218            END DO
219         END DO
220      END DO
221      !
222      IF( ln_diatrc .AND. lk_iomput .AND. jnt == nrdttrc ) THEN
223         zrfact2 = 1.e3 * rfact2r
224         CALL iom_put( "GRAZ2", zgrazing(:,:,:) * zrfact2 * tmask(:,:,:) )  ! Total grazing of phyto by zooplankton
225         CALL iom_put( "PCAL" , prodcal(:,:,:)  * zrfact2 * tmask(:,:,:) )  ! Calcite production
226      ENDIF
227      !
228      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
229        WRITE(charout, FMT="('meso')")
230        CALL prt_ctl_trc_info(charout)
231        CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
232      ENDIF
233      !
234      IF( ln_diatrc .AND. lk_iomput )  CALL wrk_dealloc( jpi, jpj, jpk, zgrazing )
235      !
236      IF( nn_timing == 1 )  CALL timing_stop('p4z_meso')
237      !
238   END SUBROUTINE p4z_meso
239
240   SUBROUTINE p4z_meso_init
241
242      !!----------------------------------------------------------------------
243      !!                  ***  ROUTINE p4z_meso_init  ***
244      !!
245      !! ** Purpose :   Initialization of mesozooplankton parameters
246      !!
247      !! ** Method  :   Read the nampismes namelist and check the parameters
248      !!      called at the first timestep (nittrc000)
249      !!
250      !! ** input   :   Namelist nampismes
251      !!
252      !!----------------------------------------------------------------------
253
254      NAMELIST/nampismes/ part2, grazrat2, resrat2, mzrat2, xprefc, xprefp, xprefz,   &
255         &                xprefpoc, xthresh2dia, xthresh2phy, xthresh2zoo, xthresh2poc, &
256         &                xthresh2, xkgraz2, epsher2, sigma2, unass2, grazflux
257      INTEGER :: ios                 ! Local integer output status for namelist read
258
259      REWIND( numnatp_ref )              ! Namelist nampismes in reference namelist : Pisces mesozooplankton
260      READ  ( numnatp_ref, nampismes, IOSTAT = ios, ERR = 901)
261901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampismes in reference namelist', lwp )
262
263      REWIND( numnatp_cfg )              ! Namelist nampismes in configuration namelist : Pisces mesozooplankton
264      READ  ( numnatp_cfg, nampismes, IOSTAT = ios, ERR = 902 )
265902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampismes in configuration namelist', lwp )
266      WRITE ( numonp, nampismes )
267
268
269      IF(lwp) THEN                         ! control print
270         WRITE(numout,*) ' ' 
271         WRITE(numout,*) ' Namelist parameters for mesozooplankton, nampismes'
272         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
273         WRITE(numout,*) '    part of calcite not dissolved in mesozoo guts  part2        =', part2
274         WRITE(numout,*) '    mesozoo preference for phyto                   xprefc       =', xprefc
275         WRITE(numout,*) '    mesozoo preference for POC                     xprefp       =', xprefp
276         WRITE(numout,*) '    mesozoo preference for zoo                     xprefz       =', xprefz
277         WRITE(numout,*) '    mesozoo preference for poc                     xprefpoc     =', xprefpoc
278         WRITE(numout,*) '    microzoo feeding threshold  for mesozoo        xthresh2zoo  =', xthresh2zoo
279         WRITE(numout,*) '    diatoms feeding threshold  for mesozoo         xthresh2dia  =', xthresh2dia
280         WRITE(numout,*) '    nanophyto feeding threshold for mesozoo        xthresh2phy  =', xthresh2phy
281         WRITE(numout,*) '    poc feeding threshold for mesozoo              xthresh2poc  =', xthresh2poc
282         WRITE(numout,*) '    feeding threshold for mesozooplankton          xthresh2     =', xthresh2
283         WRITE(numout,*) '    exsudation rate of mesozooplankton             resrat2      =', resrat2
284         WRITE(numout,*) '    mesozooplankton mortality rate                 mzrat2       =', mzrat2
285         WRITE(numout,*) '    maximal mesozoo grazing rate                   grazrat2     =', grazrat2
286         WRITE(numout,*) '    mesozoo flux feeding rate                      grazflux     =', grazflux
287         WRITE(numout,*) '    non assimilated fraction of P by mesozoo       unass2       =', unass2
288         WRITE(numout,*) '    Efficicency of Mesozoo growth                  epsher2      =', epsher2
289         WRITE(numout,*) '    Fraction of mesozoo excretion as DOM           sigma2       =', sigma2
290         WRITE(numout,*) '    half sturation constant for grazing 2          xkgraz2      =', xkgraz2
291      ENDIF
292
293
294   END SUBROUTINE p4z_meso_init
295
296
297#else
298   !!======================================================================
299   !!  Dummy module :                                   No PISCES bio-model
300   !!======================================================================
301CONTAINS
302   SUBROUTINE p4z_meso                    ! Empty routine
303   END SUBROUTINE p4z_meso
304#endif 
305
306   !!======================================================================
307END MODULE  p4zmeso
Note: See TracBrowser for help on using the repository browser.