source: branches/2013/dev_LOCEAN_CMCC_INGV_2013/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zsbc.F90 @ 4230

Last change on this file since 4230 was 4230, checked in by cetlod, 8 years ago

dev_LOCEAN_CMCC_INGV_2013 : merge LOCEAN & CMCC_INGV branches, see ticket #1182

File size: 26.0 KB
Line 
1MODULE p4zsbc
2   !!======================================================================
3   !!                         ***  MODULE p4sbc  ***
4   !! TOP :   PISCES surface boundary conditions of external inputs of nutrients
5   !!======================================================================
6   !! History :   3.5  !  2012-07 (O. Aumont, C. Ethe) Original code
7   !!----------------------------------------------------------------------
8#if defined key_pisces
9   !!----------------------------------------------------------------------
10   !!   'key_pisces'                                       PISCES bio-model
11   !!----------------------------------------------------------------------
12   !!   p4z_sbc        :  Read and interpolate time-varying nutrients fluxes
13   !!   p4z_sbc_init   :  Initialization of p4z_sbc
14   !!----------------------------------------------------------------------
15   USE oce_trc         !  shared variables between ocean and passive tracers
16   USE trc             !  passive tracers common variables
17   USE sms_pisces      !  PISCES Source Minus Sink variables
18   USE iom             !  I/O manager
19   USE fldread         !  time interpolation
20
21   IMPLICIT NONE
22   PRIVATE
23
24   PUBLIC   p4z_sbc
25   PUBLIC   p4z_sbc_init   
26
27   !! * Shared module variables
28   LOGICAL , PUBLIC  :: ln_dust     !: boolean for dust input from the atmosphere
29   LOGICAL , PUBLIC  :: ln_solub    !: boolean for variable solubility of atmospheric iron
30   LOGICAL , PUBLIC  :: ln_river    !: boolean for river input of nutrients
31   LOGICAL , PUBLIC  :: ln_ndepo    !: boolean for atmospheric deposition of N
32   LOGICAL , PUBLIC  :: ln_ironsed  !: boolean for Fe input from sediments
33   LOGICAL , PUBLIC  :: ln_hydrofe  !: boolean for Fe input from hydrothermal vents
34   LOGICAL , PUBLIC  :: ln_ironice  !: boolean for Fe input from sea ice
35   REAL(wp), PUBLIC  :: sedfeinput  !: Coastal release of Iron
36   REAL(wp), PUBLIC  :: dustsolub   !: Solubility of the dust
37   REAL(wp), PUBLIC  :: icefeinput  !: Iron concentration in sea ice
38   REAL(wp), PUBLIC  :: wdust       !: Sinking speed of the dust
39   REAL(wp), PUBLIC  :: nitrfix     !: Nitrogen fixation rate   
40   REAL(wp), PUBLIC  :: diazolight  !: Nitrogen fixation sensitivty to light
41   REAL(wp), PUBLIC  :: concfediaz  !: Fe half-saturation Cste for diazotrophs
42   REAL(wp)          :: hratio      !: Fe:3He ratio assumed for vent iron supply
43
44   LOGICAL , PUBLIC  :: ll_sbc
45
46   !! * Module variables
47   LOGICAL  ::  ll_solub
48
49   INTEGER , PARAMETER  :: jpriv  = 7   !: Maximum number of river input fields
50   INTEGER , PARAMETER  :: jr_dic = 1   !: index of dissolved inorganic carbon
51   INTEGER , PARAMETER  :: jr_doc = 2   !: index of dissolved organic carbon
52   INTEGER , PARAMETER  :: jr_din = 3   !: index of dissolved inorganic nitrogen
53   INTEGER , PARAMETER  :: jr_don = 4   !: index of dissolved organic nitrogen
54   INTEGER , PARAMETER  :: jr_dip = 5   !: index of dissolved inorganic phosporus
55   INTEGER , PARAMETER  :: jr_dop = 6   !: index of dissolved organic phosphorus
56   INTEGER , PARAMETER  :: jr_dsi = 7   !: index of dissolved silicate
57
58
59   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_dust      ! structure of input dust
60   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_solub      ! structure of input dust
61   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_river  ! structure of input riverdic
62   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_ndepo     ! structure of input nitrogen deposition
63   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_ironsed   ! structure of input iron from sediment
64   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_hydrofe   ! structure of input iron from hydrothermal vents
65
66   INTEGER , PARAMETER :: nbtimes = 365  !: maximum number of times record in a file
67   INTEGER  :: ntimes_dust, ntimes_riv, ntimes_ndep       ! number of time steps in a file
68   INTEGER  :: ntimes_solub, ntimes_hydro                 ! number of time steps in a file
69
70   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:) :: dust, solub       !: dust fields
71   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:) :: rivdic, rivalk    !: river input fields
72   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:) :: rivdin, rivdip    !: river input fields
73   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:) :: rivdsi    !: river input fields
74   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:) :: nitdep    !: atmospheric N deposition
75   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: ironsed   !: Coastal supply of iron
76   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: hydrofe   !: Hydrothermal vent supply of iron
77
78   REAL(wp), PUBLIC :: sumdepsi, rivalkinput, rivdicinput, nitdepinput
79   REAL(wp), PUBLIC :: rivdininput, rivdipinput, rivdsiinput
80
81   REAL(wp) :: ryyss                    !: number of seconds per year
82
83   !!* Substitution
84#  include "top_substitute.h90"
85   !!----------------------------------------------------------------------
86   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
87   !! $Header:$
88   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
89   !!----------------------------------------------------------------------
90
91CONTAINS
92
93   SUBROUTINE p4z_sbc( kt )
94      !!----------------------------------------------------------------------
95      !!                  ***  routine p4z_sbc  ***
96      !!
97      !! ** purpose :   read and interpolate the external sources of nutrients
98      !!
99      !! ** method  :   read the files and interpolate the appropriate variables
100      !!
101      !! ** input   :   external netcdf files
102      !!
103      !!----------------------------------------------------------------------
104      !! * arguments
105      INTEGER, INTENT( in  ) ::   kt   ! ocean time step
106
107      !! * local declarations
108      INTEGER  :: ji,jj 
109      REAL(wp) :: zcoef, zyyss
110      !!---------------------------------------------------------------------
111      !
112      IF( nn_timing == 1 )  CALL timing_start('p4z_sbc')
113
114      !
115      ! Compute dust at nit000 or only if there is more than 1 time record in dust file
116      IF( ln_dust ) THEN
117         IF( kt == nit000 .OR. ( kt /= nit000 .AND. ntimes_dust > 1 ) ) THEN
118            CALL fld_read( kt, 1, sf_dust )
119            dust(:,:) = sf_dust(1)%fnow(:,:,1)
120         ENDIF
121      ENDIF
122
123      IF( ll_solub ) THEN
124         IF( kt == nit000 .OR. ( kt /= nit000 .AND. ntimes_solub > 1 ) ) THEN
125            CALL fld_read( kt, 1, sf_solub )
126            solub(:,:) = sf_solub(1)%fnow(:,:,1)
127         ENDIF
128      ENDIF
129
130      ! N/P and Si releases due to coastal rivers
131      ! Compute river at nit000 or only if there is more than 1 time record in river file
132      ! -----------------------------------------
133      IF( ln_river ) THEN
134         IF( kt == nit000 .OR. ( kt /= nit000 .AND. ntimes_riv > 1 ) ) THEN
135            CALL fld_read( kt, 1, sf_river )
136            DO jj = 1, jpj
137               DO ji = 1, jpi
138                  zcoef = ryyss * cvol(ji,jj,1) 
139                  rivalk(ji,jj) =   sf_river(jr_dic)%fnow(ji,jj,1)                                    &
140                     &              * 1.E3        / ( 12. * zcoef + rtrn )
141                  rivdic(ji,jj) = ( sf_river(jr_dic)%fnow(ji,jj,1) + sf_river(jr_doc)%fnow(ji,jj,1) ) &
142                     &              * 1.E3         / ( 12. * zcoef + rtrn )
143                  rivdin(ji,jj) = ( sf_river(jr_din)%fnow(ji,jj,1) + sf_river(jr_don)%fnow(ji,jj,1) ) &
144                     &              * 1.E3 / rno3 / ( 14. * zcoef + rtrn )
145                  rivdip(ji,jj) = ( sf_river(jr_dip)%fnow(ji,jj,1) + sf_river(jr_dop)%fnow(ji,jj,1) ) &
146                     &              * 1.E3 / po4r / ( 31. * zcoef + rtrn )
147                  rivdsi(ji,jj) =   sf_river(jr_dsi)%fnow(ji,jj,1)                                    &
148                     &              * 1.E3        / ( 28.1 * zcoef + rtrn )
149               END DO
150            END DO
151         ENDIF
152      ENDIF
153
154      ! Compute N deposition at nit000 or only if there is more than 1 time record in N deposition file
155      IF( ln_ndepo ) THEN
156         IF( kt == nit000 .OR. ( kt /= nit000 .AND. ntimes_ndep > 1 ) ) THEN
157            CALL fld_read( kt, 1, sf_ndepo )
158            DO jj = 1, jpj
159               DO ji = 1, jpi
160                  nitdep(ji,jj) = sf_ndepo(1)%fnow(ji,jj,1) / rno3 / ( 14E6 * ryyss * fse3t(ji,jj,1) + rtrn )
161               END DO
162            END DO
163         ENDIF
164      ENDIF
165      !
166      IF( nn_timing == 1 )  CALL timing_stop('p4z_sbc')
167      !
168   END SUBROUTINE p4z_sbc
169
170   SUBROUTINE p4z_sbc_init
171
172      !!----------------------------------------------------------------------
173      !!                  ***  routine p4z_sbc_init  ***
174      !!
175      !! ** purpose :   initialization of the external sources of nutrients
176      !!
177      !! ** method  :   read the files and compute the budget
178      !!                called at the first timestep (nittrc000)
179      !!
180      !! ** input   :   external netcdf files
181      !!
182      !!----------------------------------------------------------------------
183      !
184      INTEGER  :: ji, jj, jk, jm, ifpr
185      INTEGER  :: ii0, ii1, ij0, ij1
186      INTEGER  :: numdust, numsolub, numriv, numiron, numdepo, numhydro
187      INTEGER  :: ierr, ierr1, ierr2, ierr3
188      INTEGER  :: ios                 ! Local integer output status for namelist read
189      REAL(wp) :: zexpide, zdenitide, zmaskt
190      REAL(wp) :: ztimes_dust, ztimes_riv, ztimes_ndep 
191      REAL(wp), DIMENSION(nbtimes) :: zsteps                 ! times records
192      REAL(wp), DIMENSION(:), ALLOCATABLE :: rivinput
193      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: zdust, zndepo, zriver, zcmask
194      !
195      CHARACTER(len=100) ::  cn_dir          ! Root directory for location of ssr files
196      TYPE(FLD_N), DIMENSION(jpriv) ::  slf_river    ! array of namelist informations on the fields to read
197      TYPE(FLD_N) ::   sn_dust, sn_solub, sn_ndepo, sn_ironsed, sn_hydrofe   ! informations about the fields to be read
198      TYPE(FLD_N) ::   sn_riverdoc, sn_riverdic, sn_riverdsi   ! informations about the fields to be read
199      TYPE(FLD_N) ::   sn_riverdin, sn_riverdon, sn_riverdip, sn_riverdop
200      !
201      NAMELIST/nampissbc/cn_dir, sn_dust, sn_solub, sn_riverdic, sn_riverdoc, sn_riverdin, sn_riverdon,     &
202        &                sn_riverdip, sn_riverdop, sn_riverdsi, sn_ndepo, sn_ironsed, sn_hydrofe, &
203        &                ln_dust, ln_solub, ln_river, ln_ndepo, ln_ironsed, ln_ironice, ln_hydrofe,    &
204        &                sedfeinput, dustsolub, icefeinput, wdust, nitrfix, diazolight, concfediaz, hratio
205      !!----------------------------------------------------------------------
206      !
207      IF( nn_timing == 1 )  CALL timing_start('p4z_sbc_init')
208      !
209      ryyss   = nyear_len(1) * rday    ! number of seconds per year and per month
210      !
211      !                            !* set file information
212      REWIND( numnatp_ref )              ! Namelist nampissbc in reference namelist : Pisces external sources of nutrients
213      READ  ( numnatp_ref, nampissbc, IOSTAT = ios, ERR = 901)
214901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampissbc in reference namelist', lwp )
215
216      REWIND( numnatp_cfg )              ! Namelist nampissbc in configuration namelist : Pisces external sources of nutrients
217      READ  ( numnatp_cfg, nampissbc, IOSTAT = ios, ERR = 902 )
218902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampissbc in configuration namelist', lwp )
219      WRITE ( numonp, nampissbc )
220
221      IF(lwp) THEN
222         WRITE(numout,*) ' '
223         WRITE(numout,*) ' namelist : nampissbc '
224         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~ '
225         WRITE(numout,*) '    dust input from the atmosphere           ln_dust     = ', ln_dust
226         WRITE(numout,*) '    Variable solubility of iron input        ln_solub    = ', ln_solub
227         WRITE(numout,*) '    river input of nutrients                 ln_river    = ', ln_river
228         WRITE(numout,*) '    atmospheric deposition of n              ln_ndepo    = ', ln_ndepo
229         WRITE(numout,*) '    Fe input from sediments                  ln_ironsed  = ', ln_ironsed
230         WRITE(numout,*) '    Fe input from seaice                     ln_ironice  = ', ln_ironice
231         WRITE(numout,*) '    fe input from hydrothermal vents         ln_hydrofe  = ', ln_hydrofe
232         WRITE(numout,*) '    coastal release of iron                  sedfeinput  = ', sedfeinput
233         WRITE(numout,*) '    solubility of the dust                   dustsolub   = ', dustsolub
234         WRITE(numout,*) '    Iron concentration in sea ice            icefeinput  = ', icefeinput
235         WRITE(numout,*) '    sinking speed of the dust                wdust       = ', wdust
236         WRITE(numout,*) '    nitrogen fixation rate                   nitrfix     = ', nitrfix
237         WRITE(numout,*) '    nitrogen fixation sensitivty to light    diazolight  = ', diazolight
238         WRITE(numout,*) '    fe half-saturation cste for diazotrophs  concfediaz  = ', concfediaz
239         WRITE(numout,*) '    Fe to 3He ratio assumed for vent iron supply hratio  = ', hratio
240      END IF
241
242      IF( ln_dust .OR. ln_river .OR. ln_ndepo ) THEN  ;  ll_sbc = .TRUE.
243      ELSE                                            ;  ll_sbc = .FALSE.
244      ENDIF
245
246      IF( ln_dust .AND. ln_solub ) THEN               ;  ll_solub = .TRUE.
247      ELSE                                            ;  ll_solub = .FALSE.
248      ENDIF
249
250      ! dust input from the atmosphere
251      ! ------------------------------
252      IF( ln_dust ) THEN 
253         !
254         IF(lwp) WRITE(numout,*) '    initialize dust input from atmosphere '
255         IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ '
256         !
257         ALLOCATE( dust(jpi,jpj) )    ! allocation
258         !
259         ALLOCATE( sf_dust(1), STAT=ierr )           !* allocate and fill sf_sst (forcing structure) with sn_sst
260         IF( ierr > 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_init: unable to allocate sf_dust structure' )
261         !
262         CALL fld_fill( sf_dust, (/ sn_dust /), cn_dir, 'p4z_sed_init', 'Atmospheric dust deposition', 'nampissed' )
263                                   ALLOCATE( sf_dust(1)%fnow(jpi,jpj,1)   )
264         IF( sn_dust%ln_tint )     ALLOCATE( sf_dust(1)%fdta(jpi,jpj,1,2) )
265         !
266         IF( Agrif_Root() ) THEN   !  Only on the master grid
267            ! Get total input dust ; need to compute total atmospheric supply of Si in a year
268            CALL iom_open (  TRIM( sn_dust%clname ) , numdust )
269            CALL iom_gettime( numdust, zsteps, kntime=ntimes_dust)  ! get number of record in file
270            ALLOCATE( zdust(jpi,jpj,ntimes_dust) )
271            DO jm = 1, ntimes_dust
272               CALL iom_get( numdust, jpdom_data, TRIM( sn_dust%clvar ), zdust(:,:,jm), jm )
273            END DO
274            CALL iom_close( numdust )
275            ztimes_dust = 1._wp / FLOAT( ntimes_dust ) 
276            sumdepsi = 0.e0
277            DO jm = 1, ntimes_dust
278               sumdepsi = sumdepsi + glob_sum( zdust(:,:,jm) * e1e2t(:,:) * tmask(:,:,1) * ztimes_dust )
279            ENDDO
280            sumdepsi = sumdepsi / ( nyear_len(1) * rday ) * 12. * 8.8 * 0.075 / 28.1 
281            DEALLOCATE( zdust)
282         ENDIF
283      ELSE
284         sumdepsi  = 0._wp
285      END IF
286
287      ! Solubility of dust deposition of iron
288      ! Only if ln_dust and ln_solubility set to true (ll_solub = .true.)
289      ! -----------------------------------------------------------------
290      IF( ll_solub ) THEN
291         !
292         IF(lwp) WRITE(numout,*) '    initialize variable solubility of Fe '
293         IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ '
294         !
295         ALLOCATE( solub(jpi,jpj) )    ! allocation
296         !
297         ALLOCATE( sf_solub(1), STAT=ierr )           !* allocate and fill sf_sst (forcing structure) with sn_sst
298         IF( ierr > 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_init: unable to allocate sf_solub structure' )
299         !
300         CALL fld_fill( sf_solub, (/ sn_solub /), cn_dir, 'p4z_sed_init', 'Solubility of atm. iron ', 'nampissed' )
301                                   ALLOCATE( sf_solub(1)%fnow(jpi,jpj,1)   )
302         IF( sn_solub%ln_tint )    ALLOCATE( sf_solub(1)%fdta(jpi,jpj,1,2) )
303         ! get number of record in file
304         CALL iom_open (  TRIM( sn_solub%clname ) , numsolub )
305         CALL iom_gettime( numsolub, zsteps, kntime=ntimes_solub)  ! get number of record in file
306         CALL iom_close( numsolub )
307      ENDIF
308
309      ! nutrient input from rivers
310      ! --------------------------
311      IF( ln_river ) THEN
312         !
313         slf_river(jr_dic) = sn_riverdic  ;  slf_river(jr_doc) = sn_riverdoc  ;  slf_river(jr_din) = sn_riverdin 
314         slf_river(jr_don) = sn_riverdon  ;  slf_river(jr_dip) = sn_riverdip  ;  slf_river(jr_dop) = sn_riverdop
315         slf_river(jr_dsi) = sn_riverdsi 
316         !
317         ALLOCATE( rivdic(jpi,jpj), rivalk(jpi,jpj), rivdin(jpi,jpj), rivdip(jpi,jpj), rivdsi(jpi,jpj) ) 
318         !
319         ALLOCATE( sf_river(jpriv), rivinput(jpriv), STAT=ierr1 )           !* allocate and fill sf_river (forcing structure) with sn_river_
320         rivinput(:) = 0.0
321
322         IF( ierr1 > 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_init: unable to allocate sf_irver structure' )
323         !
324         CALL fld_fill( sf_river, slf_river, cn_dir, 'p4z_sed_init', 'Input from river ', 'nampissed' )
325         DO ifpr = 1, jpriv
326                                          ALLOCATE( sf_river(ifpr)%fnow(jpi,jpj,1  ) )
327            IF( slf_river(ifpr)%ln_tint ) ALLOCATE( sf_river(ifpr)%fdta(jpi,jpj,1,2) )
328         END DO
329         IF( Agrif_Root() ) THEN   !  Only on the master grid
330            ! Get total input rivers ; need to compute total river supply in a year
331            DO ifpr = 1, jpriv
332               CALL iom_open ( TRIM( slf_river(ifpr)%clname ), numriv )
333               CALL iom_gettime( numriv, zsteps, kntime=ntimes_riv)
334               ALLOCATE( zriver(jpi,jpj,ntimes_riv) )
335               DO jm = 1, ntimes_riv
336                  CALL iom_get( numriv, jpdom_data, TRIM( slf_river(ifpr)%clvar ), zriver(:,:,jm), jm )
337               END DO
338               CALL iom_close( numriv )
339               ztimes_riv = 1._wp / FLOAT(ntimes_riv) 
340               DO jm = 1, ntimes_riv
341                  rivinput(ifpr) = rivinput(ifpr) + glob_sum( zriver(:,:,jm) * tmask(:,:,1) * ztimes_riv ) 
342               END DO
343               DEALLOCATE( zriver)
344            END DO
345            ! N/P and Si releases due to coastal rivers
346            ! -----------------------------------------
347            rivdicinput = (rivinput(jr_dic) + rivinput(jr_doc) ) * 1E3 / 12._wp
348            rivdininput = (rivinput(jr_din) + rivinput(jr_don) ) * 1E3 / rno3 / 14._wp
349            rivdipinput = (rivinput(jr_dip) + rivinput(jr_dop) ) * 1E3 / po4r / 31._wp
350            rivdsiinput = rivinput(jr_dsi) * 1E3 / 28.1_wp
351            rivalkinput = rivinput(jr_dic) * 1E3 / 12._wp
352            !
353         ENDIF
354      ELSE
355         rivdicinput = 0._wp
356         rivdininput = 0._wp
357         rivdipinput = 0._wp
358         rivdsiinput = 0._wp
359         rivalkinput = 0._wp
360      END IF 
361
362      ! nutrient input from dust
363      ! ------------------------
364      IF( ln_ndepo ) THEN
365         !
366         IF(lwp) WRITE(numout,*) '    initialize the nutrient input by dust from ndeposition.orca.nc'
367         IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
368         !
369         ALLOCATE( nitdep(jpi,jpj) )    ! allocation
370         !
371         ALLOCATE( sf_ndepo(1), STAT=ierr3 )           !* allocate and fill sf_sst (forcing structure) with sn_sst
372         IF( ierr3 > 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_init: unable to allocate sf_ndepo structure' )
373         !
374         CALL fld_fill( sf_ndepo, (/ sn_ndepo /), cn_dir, 'p4z_sed_init', 'Nutrient atmospheric depositon ', 'nampissed' )
375                                   ALLOCATE( sf_ndepo(1)%fnow(jpi,jpj,1)   )
376         IF( sn_ndepo%ln_tint )    ALLOCATE( sf_ndepo(1)%fdta(jpi,jpj,1,2) )
377         !
378         IF( Agrif_Root() ) THEN   !  Only on the master grid
379            ! Get total input dust ; need to compute total atmospheric supply of N in a year
380            CALL iom_open ( TRIM( sn_ndepo%clname ), numdepo )
381            CALL iom_gettime( numdepo, zsteps, kntime=ntimes_ndep)
382            ALLOCATE( zndepo(jpi,jpj,ntimes_ndep) )
383            DO jm = 1, ntimes_ndep
384               CALL iom_get( numdepo, jpdom_data, TRIM( sn_ndepo%clvar ), zndepo(:,:,jm), jm )
385            END DO
386            CALL iom_close( numdepo )
387            ztimes_ndep = 1._wp / FLOAT( ntimes_ndep ) 
388            nitdepinput = 0._wp
389            DO jm = 1, ntimes_ndep
390              nitdepinput = nitdepinput + glob_sum( zndepo(:,:,jm) * e1e2t(:,:) * tmask(:,:,1) * ztimes_ndep )
391            ENDDO
392            nitdepinput = nitdepinput / rno3 / 14E6 
393            DEALLOCATE( zndepo)
394         ENDIF
395      ELSE
396         nitdepinput = 0._wp
397      ENDIF
398
399      ! coastal and island masks
400      ! ------------------------
401      IF( ln_ironsed ) THEN     
402         !
403         IF(lwp) WRITE(numout,*) '    computation of an island mask to enhance coastal supply of iron'
404         IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
405         !
406         ALLOCATE( ironsed(jpi,jpj,jpk) )    ! allocation
407         !
408         CALL iom_open ( TRIM( sn_ironsed%clname ), numiron )
409         ALLOCATE( zcmask(jpi,jpj,jpk) )
410         CALL iom_get  ( numiron, jpdom_data, TRIM( sn_ironsed%clvar ), zcmask(:,:,:), 1 )
411         CALL iom_close( numiron )
412         !
413         DO jk = 1, 5
414            DO jj = 2, jpjm1
415               DO ji = fs_2, fs_jpim1
416                  IF( tmask(ji,jj,jk) /= 0. ) THEN
417                     zmaskt = tmask(ji+1,jj,jk) * tmask(ji-1,jj,jk) * tmask(ji,jj+1,jk)    &
418                        &                       * tmask(ji,jj-1,jk) * tmask(ji,jj,jk+1)
419                     IF( zmaskt == 0. )   zcmask(ji,jj,jk ) = MAX( 0.1, zcmask(ji,jj,jk) ) 
420                  END IF
421               END DO
422            END DO
423         END DO
424         IF( cp_cfg == 'orca' .AND. jp_cfg == 2 ) THEN
425            ii0 = 176   ;   ii1 =  176        ! Southern Island : Kerguelen
426            ij0 =  37   ;   ij1 =   37  ;   zcmask( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1), 1:jpk ) =  0.3_wp 
427            !
428            ii0 = 119   ;   ii1 =  119        ! South Georgia
429            ij0 =  29   ;   ij1 =   29  ;   zcmask( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1), 1:jpk ) =  0.3_wp 
430            !
431            ii0 = 111   ;   ii1 =  111        ! Falklands
432            ij0 =  35   ;   ij1 =   35  ;   zcmask( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1), 1:jpk ) =  0.3_wp 
433            !
434            ii0 = 168   ;   ii1 =  168        ! Crozet
435            ij0 =  40   ;   ij1 =   40  ;   zcmask( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1), 1:jpk ) =  0.3_wp 
436            !
437            ii0 = 119   ;   ii1 =  119        ! South Orkney
438            ij0 =  28   ;   ij1 =   28  ;   zcmask( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1), 1:jpk ) =  0.3_wp 
439            !
440            ii0 = 140   ;   ii1 =  140        ! Bouvet Island
441            ij0 =  33   ;   ij1 =   33  ;   zcmask( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1), 1:jpk ) =  0.3_wp 
442            !
443            ii0 = 178   ;   ii1 =  178        ! Prince edwards
444            ij0 =  34   ;   ij1 =   34  ;   zcmask( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1), 1:jpk ) =  0.3_wp 
445            !
446            ii0 =  43   ;   ii1 =   43        ! Balleny islands
447            ij0 =  21   ;   ij1 =   21  ;   zcmask( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1), 1:jpk ) =  0.3_wp 
448         ENDIF
449         CALL lbc_lnk( zcmask , 'T', 1. )      ! lateral boundary conditions on cmask   (sign unchanged)
450         DO jk = 1, jpk
451            DO jj = 1, jpj
452               DO ji = 1, jpi
453                  zexpide   = MIN( 8.,( fsdept(ji,jj,jk) / 500. )**(-1.5) )
454                  zdenitide = -0.9543 + 0.7662 * LOG( zexpide ) - 0.235 * LOG( zexpide )**2
455                  zcmask(ji,jj,jk) = zcmask(ji,jj,jk) * MIN( 1., EXP( zdenitide ) / 0.5 )
456               END DO
457            END DO
458         END DO
459         ! Coastal supply of iron
460         ! -------------------------
461         ironsed(:,:,jpk) = 0._wp
462         DO jk = 1, jpkm1
463            ironsed(:,:,jk) = sedfeinput * zcmask(:,:,jk) / ( fse3t(:,:,jk) * rday )
464         END DO
465         DEALLOCATE( zcmask)
466      ENDIF
467      !
468      ! Iron from Hydrothermal vents
469      ! ------------------------
470      IF( ln_hydrofe ) THEN
471         !
472         IF(lwp) WRITE(numout,*) '    Input of iron from hydrothermal vents '
473         IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
474         !
475         ALLOCATE( hydrofe(jpi,jpj,jpk) )    ! allocation
476         !
477         CALL iom_open ( TRIM( sn_hydrofe%clname ), numhydro )
478         CALL iom_get  ( numhydro, jpdom_data, TRIM( sn_hydrofe%clvar ), hydrofe(:,:,:), 1 )
479         CALL iom_close( numhydro )
480         !
481         hydrofe(:,:,:) = ( hydrofe(:,:,:) * hratio ) / ( cvol(:,:,:) * ryyss + rtrn ) / fse3t(:,:,:)
482         !
483      ENDIF
484      !
485      IF( ll_sbc ) CALL p4z_sbc( nit000 ) 
486      !
487      IF(lwp) THEN
488         WRITE(numout,*)
489         WRITE(numout,*) '    Total input of elements from river supply'
490         WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
491         WRITE(numout,*) '    N Supply   : ', rivdininput*rno3*1E3/1E12*14.,' TgN/yr'
492         WRITE(numout,*) '    Si Supply  : ', rivdsiinput*1E3/1E12*28.1,' TgSi/yr'
493         WRITE(numout,*) '    P Supply   : ', rivdipinput*1E3*po4r/1E12*31.,' TgP/yr'
494         WRITE(numout,*) '    Alk Supply : ', rivalkinput*1E3/1E12,' Teq/yr'
495         WRITE(numout,*) '    DIC Supply : ', rivdicinput*1E3*12./1E12,'TgC/yr'
496         WRITE(numout,*) 
497         WRITE(numout,*) '    Total input of elements from atmospheric supply'
498         WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
499         WRITE(numout,*) '    N Supply   : ', nitdepinput*rno3*1E3/1E12*14.,' TgN/yr'
500         WRITE(numout,*) 
501      ENDIF
502      !
503      IF( nn_timing == 1 )  CALL timing_stop('p4z_sbc_init')
504      !
505   END SUBROUTINE p4z_sbc_init
506
507#else
508   !!======================================================================
509   !!  Dummy module :                                   No PISCES bio-model
510   !!======================================================================
511CONTAINS
512   SUBROUTINE p4z_sbc                         ! Empty routine
513   END SUBROUTINE p4z_sbc
514#endif 
515
516   !!======================================================================
517END MODULE  p4zsbc
Note: See TracBrowser for help on using the repository browser.