source: branches/2013/dev_LOCEAN_CMCC_INGV_MERC_UKMO_2013/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 4245

Last change on this file since 4245 was 4245, checked in by cetlod, 7 years ago

dev_locean_cmcc_ingv_ukmo_merc : merge in the MERC_UKMO dev branch with trunk rev 4119

  • Property svn:keywords set to Id
File size: 38.4 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  LIM sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!            3.4  ! 2011-11  (C. Harris) decomposition changes for running with CICE
31   !!                 ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32   !!----------------------------------------------------------------------
33
34   !!----------------------------------------------------------------------
35   !!   nemo_gcm       : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
36   !!   nemo_init      : initialization of the NEMO system
37   !!   nemo_ctl       : initialisation of the contol print
38   !!   nemo_closefile : close remaining open files
39   !!   nemo_alloc     : dynamical allocation
40   !!   nemo_partition : calculate MPP domain decomposition
41   !!   factorise      : calculate the factors of the no. of MPI processes
42   !!----------------------------------------------------------------------
43   USE step_oce        ! module used in the ocean time stepping module
44   USE sbc_oce         ! surface boundary condition: ocean
45   USE cla             ! cross land advection               (tra_cla routine)
46   USE domcfg          ! domain configuration               (dom_cfg routine)
47   USE mppini          ! shared/distributed memory setting (mpp_init routine)
48   USE domain          ! domain initialization             (dom_init routine)
49#if defined key_nemocice_decomp
50   USE ice_domain_size, only: nx_global, ny_global
51#endif
52   USE tideini         ! tidal components initialization   (tide_ini routine)
53   USE obcini          ! open boundary cond. initialization (obc_ini routine)
54   USE bdyini          ! open boundary cond. initialization (bdy_init routine)
55   USE bdydta          ! open boundary cond. initialization (bdy_dta_init routine)
56   USE bdytides        ! open boundary cond. initialization (bdytide_init routine)
57   USE istate          ! initial state setting          (istate_init routine)
58   USE ldfdyn          ! lateral viscosity setting      (ldfdyn_init routine)
59   USE ldftra          ! lateral diffusivity setting    (ldftra_init routine)
60   USE zdfini          ! vertical physics setting          (zdf_init routine)
61   USE phycst          ! physical constant                  (par_cst routine)
62   USE trdmod          ! momentum/tracers trends       (trd_mod_init routine)
63   USE asminc          ! assimilation increments     
64   USE asmbkg          ! writing out state trajectory
65   USE diaptr          ! poleward transports           (dia_ptr_init routine)
66   USE diadct          ! sections transports           (dia_dct_init routine)
67   USE diaobs          ! Observation diagnostics       (dia_obs_init routine)
68   USE lib_fortran     ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
69   USE step            ! NEMO time-stepping                 (stp     routine)
70   USE icbini          ! handle bergs, initialisation
71   USE icbstp          ! handle bergs, calving, themodynamics and transport
72#if defined key_oasis3
73   USE cpl_oasis3      ! OASIS3 coupling
74#elif defined key_oasis4
75   USE cpl_oasis4      ! OASIS4 coupling (not working)
76#endif
77   USE c1d             ! 1D configuration
78   USE step_c1d        ! Time stepping loop for the 1D configuration
79   USE dyndmp          ! Momentum damping
80#if defined key_top
81   USE trcini          ! passive tracer initialisation
82#endif
83   USE lib_mpp         ! distributed memory computing
84#if defined key_iomput
85   USE xios
86#endif
87   USE sbctide, ONLY: lk_tide
88   USE crsini          ! initialise grid coarsening utility
89   USE lbcnfd, ONLY: isendto, nsndto ! Setup of north fold exchanges
90
91   IMPLICIT NONE
92   PRIVATE
93
94   PUBLIC   nemo_gcm    ! called by model.F90
95   PUBLIC   nemo_init   ! needed by AGRIF
96   PUBLIC   nemo_alloc  ! needed by TAM
97
98   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
99
100   !!----------------------------------------------------------------------
101   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
102   !! $Id$
103   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
104   !!----------------------------------------------------------------------
105CONTAINS
106
107   SUBROUTINE nemo_gcm
108      !!----------------------------------------------------------------------
109      !!                     ***  ROUTINE nemo_gcm  ***
110      !!
111      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
112      !!              curvilinear mesh on the sphere.
113      !!
114      !! ** Method  : - model general initialization
115      !!              - launch the time-stepping (stp routine)
116      !!              - finalize the run by closing files and communications
117      !!
118      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
119      !!              Madec, 2008, internal report, IPSL.
120      !!----------------------------------------------------------------------
121      INTEGER ::   istp       ! time step index
122      !!----------------------------------------------------------------------
123      !
124
125#if defined key_agrif
126      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
127#endif
128
129      !                            !-----------------------!
130      CALL nemo_init               !==  Initialisations  ==!
131      !                            !-----------------------!
132#if defined key_agrif
133      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
134      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
135# if defined key_top
136      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
137# endif
138# if defined key_lim2
139      CALL Agrif_Declare_Var_lim2  !  "      "   "   "      "  LIM
140# endif
141#endif
142
143      ! check that all process are still there... If some process have an error,
144      ! they will never enter in step and other processes will wait until the end of the cpu time!
145      IF( lk_mpp )   CALL mpp_max( nstop )
146
147      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
148
149      !                            !-----------------------!
150      !                            !==   time stepping   ==!
151      !                            !-----------------------!
152      istp = nit000
153#if defined key_c1d
154         DO WHILE ( istp <= nitend .AND. nstop == 0 )
155            CALL stp_c1d( istp )
156            istp = istp + 1
157         END DO
158#else
159          IF( lk_asminc ) THEN
160             IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 )    ! Output background fields
161             IF( ln_asmdin ) THEN                        ! Direct initialization
162                IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 )    ! Tracers
163                IF( ln_dyninc ) CALL dyn_asm_inc( nit000 - 1 )    ! Dynamics
164                IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 )    ! SSH
165             ENDIF
166          ENDIF
167
168         DO WHILE ( istp <= nitend .AND. nstop == 0 )
169
170#if defined key_agrif
171            CALL Agrif_Step( stp )           ! AGRIF: time stepping
172#else
173            CALL stp( istp )                 ! standard time stepping
174#endif
175
176            istp = istp + 1
177            IF( lk_mpp )   CALL mpp_max( nstop )
178         END DO
179#endif
180
181      IF( lk_diaobs   )   CALL dia_obs_wri
182      !
183      IF( ln_icebergs )   CALL icb_end( nitend )
184
185      !                            !------------------------!
186      !                            !==  finalize the run  ==!
187      !                            !------------------------!
188      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
189      !
190      IF( nstop /= 0 .AND. lwp ) THEN   ! error print
191         WRITE(numout,cform_err)
192         WRITE(numout,*) nstop, ' error have been found'
193      ENDIF
194      !
195#if defined key_agrif
196      CALL Agrif_ParentGrid_To_ChildGrid()
197      IF( lk_diaobs ) CALL dia_obs_wri
198      IF( nn_timing == 1 )   CALL timing_finalize
199      CALL Agrif_ChildGrid_To_ParentGrid()
200#endif
201      IF( nn_timing == 1 )   CALL timing_finalize
202      !
203      CALL nemo_closefile
204#if defined key_iomput
205      CALL xios_finalize                ! end mpp communications with xios
206# if defined key_oasis3 || defined key_oasis4
207      CALL cpl_prism_finalize           ! end coupling and mpp communications with OASIS
208# endif
209#else
210# if defined key_oasis3 || defined key_oasis4
211      CALL cpl_prism_finalize           ! end coupling and mpp communications with OASIS
212# else
213      IF( lk_mpp )   CALL mppstop       ! end mpp communications
214# endif
215#endif
216      !
217   END SUBROUTINE nemo_gcm
218
219
220   SUBROUTINE nemo_init
221      !!----------------------------------------------------------------------
222      !!                     ***  ROUTINE nemo_init  ***
223      !!
224      !! ** Purpose :   initialization of the NEMO GCM
225      !!----------------------------------------------------------------------
226      INTEGER ::   ji            ! dummy loop indices
227      INTEGER ::   ilocal_comm   ! local integer
228      INTEGER ::   ios
229      CHARACTER(len=80), DIMENSION(16) ::   cltxt
230      !!
231      NAMELIST/namctl/ ln_ctl, nn_print, nn_ictls, nn_ictle,   &
232         &             nn_isplt, nn_jsplt, nn_jctls, nn_jctle,   &
233         &             nn_bench, nn_timing
234      NAMELIST/namcfg/ cp_cfg, cp_cfz, jp_cfg, jpidta, jpjdta, jpkdta, jpiglo, jpjglo, &
235         &             jpizoom, jpjzoom, jperio
236      !!----------------------------------------------------------------------
237      !
238      cltxt = ''
239      !
240      !                             ! Open reference namelist and configuration namelist files
241      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
242      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
243      CALL ctl_opn( numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
244      !
245      REWIND( numnam_ref )              ! Namelist namctl in reference namelist : Control prints & Benchmark
246      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
247901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', lwp )
248
249      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist : Control prints & Benchmark
250      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
251902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', lwp )
252      WRITE( numond, namctl )
253
254      !
255      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist : Control prints & Benchmark
256      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
257903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', lwp )
258
259      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist : Control prints & Benchmark
260      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
261904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', lwp )   
262      WRITE( numond, namcfg )
263! Force values for AGRIF zoom (cf. agrif_user.F90)
264#if defined key_agrif
265   IF( .NOT. Agrif_Root() ) THEN
266      jpiglo  = nbcellsx + 2 + 2*nbghostcells
267      jpjglo  = nbcellsy + 2 + 2*nbghostcells
268      jpi     = ( jpiglo-2*jpreci + (jpni-1+0) ) / jpni + 2*jpreci
269      jpj     = ( jpjglo-2*jprecj + (jpnj-1+0) ) / jpnj + 2*jprecj
270      jpidta  = jpiglo
271      jpjdta  = jpjglo
272      jpizoom = 1
273      jpjzoom = 1
274      nperio  = 0
275      jperio  = 0
276   ENDIF
277#endif
278      !
279      !                             !--------------------------------------------!
280      !                             !  set communicator & select the local node  !
281      !                             !--------------------------------------------!
282#if defined key_iomput
283      IF( Agrif_Root() ) THEN
284# if defined key_oasis3 || defined key_oasis4
285         CALL cpl_prism_init( ilocal_comm )      ! nemo local communicator given by oasis
286         CALL xios_initialize( "oceanx",local_comm=ilocal_comm )
287# else
288         CALL  xios_initialize( "nemo",return_comm=ilocal_comm )
289# endif
290      ENDIF
291      narea = mynode( cltxt, numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )   ! Nodes selection
292#else
293# if defined key_oasis3 || defined key_oasis4
294      IF( Agrif_Root() ) THEN
295         CALL cpl_prism_init( ilocal_comm )                 ! nemo local communicator given by oasis
296      ENDIF
297      narea = mynode( cltxt, numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )   ! Nodes selection (control print return in cltxt)
298# else
299      ilocal_comm = 0
300      narea = mynode( cltxt, numnam_ref, numnam_cfg, numond , nstop )                 ! Nodes selection (control print return in cltxt)
301# endif
302#endif
303      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
304
305      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
306
307      ! If dimensions of processor grid weren't specified in the namelist file
308      ! then we calculate them here now that we have our communicator size
309      IF( (jpni < 1) .OR. (jpnj < 1) )THEN
310#if   defined key_mpp_mpi
311         IF( Agrif_Root() ) CALL nemo_partition(mppsize)
312#else
313         jpni  = 1
314         jpnj  = 1
315         jpnij = jpni*jpnj
316#endif
317      END IF
318
319      ! Calculate domain dimensions given calculated jpni and jpnj
320      ! This used to be done in par_oce.F90 when they were parameters rather
321      ! than variables
322      IF( Agrif_Root() ) THEN
323#if defined key_nemocice_decomp
324         jpi = ( nx_global+2-2*jpreci + (jpni-1) ) / jpni + 2*jpreci ! first  dim.
325         jpj = ( ny_global+2-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj ! second dim.
326#else
327         jpi = ( jpiglo-2*jpreci + (jpni-1) ) / jpni + 2*jpreci   ! first  dim.
328         jpj = ( jpjglo-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj   ! second dim.
329#endif
330      ENDIF
331         jpk = jpkdta                                             ! third dim
332         jpim1 = jpi-1                                            ! inner domain indices
333         jpjm1 = jpj-1                                            !   "           "
334         jpkm1 = jpk-1                                            !   "           "
335         jpij  = jpi*jpj                                          !  jpi x j
336
337      IF(lwp) THEN                            ! open listing units
338         !
339         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
340         !
341         WRITE(numout,*)
342         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
343         WRITE(numout,*) '                       NEMO team'
344         WRITE(numout,*) '            Ocean General Circulation Model'
345         WRITE(numout,*) '                  version 3.4  (2011) '
346         WRITE(numout,*)
347         WRITE(numout,*)
348         DO ji = 1, SIZE(cltxt)
349            IF( TRIM(cltxt(ji)) /= '' )   WRITE(numout,*) cltxt(ji)      ! control print of mynode
350         END DO
351         WRITE(numout,cform_aaa)                                         ! Flag AAAAAAA
352         !
353      ENDIF
354
355      ! Now we know the dimensions of the grid and numout has been set we can
356      ! allocate arrays
357      CALL nemo_alloc()
358
359      !                             !-------------------------------!
360      !                             !  NEMO general initialization  !
361      !                             !-------------------------------!
362
363      CALL nemo_ctl                          ! Control prints & Benchmark
364
365      !                                      ! Domain decomposition
366      IF( jpni*jpnj == jpnij ) THEN   ;   CALL mpp_init      ! standard cutting out
367      ELSE                            ;   CALL mpp_init2     ! eliminate land processors
368      ENDIF
369      !
370      IF( nn_timing == 1 )  CALL timing_init
371      !
372      !                                      ! General initialization
373                            CALL     phy_cst    ! Physical constants
374                            CALL     eos_init   ! Equation of state
375      IF( lk_c1d        )   CALL     c1d_init   ! 1D column configuration
376                            CALL     dom_cfg    ! Domain configuration
377                            CALL     dom_init   ! Domain
378
379      IF( ln_nnogather )    CALL nemo_northcomms   ! Initialise the northfold neighbour lists (must be done after the masks are defined)
380
381      IF( ln_ctl        )   CALL prt_ctl_init   ! Print control
382
383      IF( lk_obc        )   CALL     obc_init   ! Open boundaries
384
385                            CALL  istate_init   ! ocean initial state (Dynamics and tracers)
386
387      IF( lk_tide       )   CALL tide_init( nit000 )    ! Initialisation of the tidal harmonics
388
389      IF( lk_bdy        )   CALL     bdy_init       ! Open boundaries initialisation
390      IF( lk_bdy        )   CALL     bdy_dta_init   ! Open boundaries initialisation of external data arrays
391      IF( lk_bdy        )   CALL     bdytide_init   ! Open boundaries initialisation of tidal harmonic forcing
392
393                            CALL dyn_nept_init  ! simplified form of Neptune effect
394
395      !     
396      IF( ln_crs        )   CALL     crs_init   ! Domain initialization of coarsened grid
397      !
398                                ! Ocean physics
399                            CALL     sbc_init   ! Forcings : surface module
400      !                                         ! Vertical physics
401
402                            CALL     zdf_init      ! namelist read
403
404                            CALL zdf_bfr_init      ! bottom friction
405
406      IF( lk_zdfric     )   CALL zdf_ric_init      ! Richardson number dependent Kz
407      IF( lk_zdftke     )   CALL zdf_tke_init      ! TKE closure scheme
408      IF( lk_zdfgls     )   CALL zdf_gls_init      ! GLS closure scheme
409      IF( lk_zdfkpp     )   CALL zdf_kpp_init      ! KPP closure scheme
410      IF( lk_zdftmx     )   CALL zdf_tmx_init      ! tidal vertical mixing
411      IF( lk_zdfddm .AND. .NOT. lk_zdfkpp )   &
412         &                  CALL zdf_ddm_init      ! double diffusive mixing
413      !                                         ! Lateral physics
414                            CALL ldf_tra_init      ! Lateral ocean tracer physics
415                            CALL ldf_dyn_init      ! Lateral ocean momentum physics
416      IF( lk_ldfslp     )   CALL ldf_slp_init      ! slope of lateral mixing
417
418      !                                     ! Active tracers
419                            CALL tra_qsr_init   ! penetrative solar radiation qsr
420                            CALL tra_bbc_init   ! bottom heat flux
421      IF( lk_trabbl     )   CALL tra_bbl_init   ! advective (and/or diffusive) bottom boundary layer scheme
422                            CALL tra_dmp_init   ! internal damping trends- tracers
423                            CALL tra_adv_init   ! horizontal & vertical advection
424                            CALL tra_ldf_init   ! lateral mixing
425                            CALL tra_zdf_init   ! vertical mixing and after tracer fields
426
427      !                                     ! Dynamics
428      IF( lk_c1d        )   CALL dyn_dmp_init   ! internal damping trends- momentum
429                            CALL dyn_adv_init   ! advection (vector or flux form)
430                            CALL dyn_vor_init   ! vorticity term including Coriolis
431                            CALL dyn_ldf_init   ! lateral mixing
432                            CALL dyn_hpg_init   ! horizontal gradient of Hydrostatic pressure
433                            CALL dyn_zdf_init   ! vertical diffusion
434                            CALL dyn_spg_init   ! surface pressure gradient
435
436      !                                     ! Misc. options
437      IF( nn_cla == 1 .AND. cp_cfg == 'orca' .AND. jp_cfg == 2 )   CALL cla_init       ! Cross Land Advection
438                            CALL icb_init( rdt, nit000)   ! initialise icebergs instance
439     
440#if defined key_top
441      !                                     ! Passive tracers
442                            CALL     trc_init
443#endif
444      !
445 
446                                            ! Diagnostics
447      IF( lk_floats     )   CALL     flo_init   ! drifting Floats
448      IF( lk_diaar5     )   CALL dia_ar5_init   ! ar5 diag
449                            CALL dia_ptr_init   ! Poleward TRansports initialization
450      IF( lk_diadct     )   CALL dia_dct_init   ! Sections tranports
451                            CALL dia_hsb_init   ! heat content, salt content and volume budgets
452                            CALL trd_mod_init   ! Mixed-layer/Vorticity/Integral constraints trends
453      IF( lk_diaobs     ) THEN                  ! Observation & model comparison
454                            CALL dia_obs_init            ! Initialize observational data
455                            CALL dia_obs( nit000 - 1 )   ! Observation operator for restart
456      ENDIF
457      !                                     ! Assimilation increments
458      IF( lk_asminc     )   CALL asm_inc_init   ! Initialize assimilation increments
459      IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
460      !
461   END SUBROUTINE nemo_init
462
463
464   SUBROUTINE nemo_ctl
465      !!----------------------------------------------------------------------
466      !!                     ***  ROUTINE nemo_ctl  ***
467      !!
468      !! ** Purpose :   control print setting
469      !!
470      !! ** Method  : - print namctl information and check some consistencies
471      !!----------------------------------------------------------------------
472      !
473      IF(lwp) THEN                  ! control print
474         WRITE(numout,*)
475         WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
476         WRITE(numout,*) '~~~~~~~ '
477         WRITE(numout,*) '   Namelist namctl'
478         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
479         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
480         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
481         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
482         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
483         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
484         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
485         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
486         WRITE(numout,*) '      benchmark parameter (0/1)       nn_bench   = ', nn_bench
487         WRITE(numout,*) '      timing activated    (0/1)       nn_timing  = ', nn_timing
488      ENDIF
489      !
490      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
491      nictls    = nn_ictls
492      nictle    = nn_ictle
493      njctls    = nn_jctls
494      njctle    = nn_jctle
495      isplt     = nn_isplt
496      jsplt     = nn_jsplt
497      nbench    = nn_bench
498
499      IF(lwp) THEN                  ! control print
500         WRITE(numout,*)
501         WRITE(numout,*) 'namcfg  : configuration initialization through namelist read'
502         WRITE(numout,*) '~~~~~~~ '
503         WRITE(numout,*) '   Namelist namcfg'
504         WRITE(numout,*) '      configuration name              cp_cfg      = ', TRIM(cp_cfg)
505         WRITE(numout,*) '      configuration zoom name         cp_cfz      = ', TRIM(cp_cfz)
506         WRITE(numout,*) '      configuration resolution        jp_cfg      = ', jp_cfg
507         WRITE(numout,*) '      1st lateral dimension ( >= jpi ) jpidta     = ', jpidta
508         WRITE(numout,*) '      2nd    "         "    ( >= jpj ) jpjdta     = ', jpjdta
509         WRITE(numout,*) '      3nd    "         "               jpkdta     = ', jpkdta
510         WRITE(numout,*) '      1st dimension of global domain in i jpiglo  = ', jpiglo
511         WRITE(numout,*) '      2nd    -                  -    in j jpjglo  = ', jpjglo
512         WRITE(numout,*) '      left bottom i index of the zoom (in data domain) jpizoom = ', jpizoom
513         WRITE(numout,*) '      left bottom j index of the zoom (in data domain) jpizoom = ', jpjzoom
514         WRITE(numout,*) '      lateral cond. type (between 0 and 6) jperio = ', jperio   
515      ENDIF
516      !                             ! Parameter control
517      !
518      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
519         IF( lk_mpp .AND. jpnij > 1 ) THEN
520            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
521         ELSE
522            IF( isplt == 1 .AND. jsplt == 1  ) THEN
523               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
524                  &           ' - the print control will be done over the whole domain' )
525            ENDIF
526            ijsplt = isplt * jsplt            ! total number of processors ijsplt
527         ENDIF
528         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
529         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
530         !
531         !                              ! indices used for the SUM control
532         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
533            lsp_area = .FALSE.
534         ELSE                                             ! print control done over a specific  area
535            lsp_area = .TRUE.
536            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
537               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
538               nictls = 1
539            ENDIF
540            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
541               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
542               nictle = jpiglo
543            ENDIF
544            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
545               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
546               njctls = 1
547            ENDIF
548            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
549               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
550               njctle = jpjglo
551            ENDIF
552         ENDIF
553      ENDIF
554      !
555      IF( nbench == 1 ) THEN              ! Benchmark
556         SELECT CASE ( cp_cfg )
557         CASE ( 'gyre' )   ;   CALL ctl_warn( ' The Benchmark is activated ' )
558         CASE DEFAULT      ;   CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:',   &
559            &                                 ' cp_cfg = "gyre" in namelist &namcfg or set nbench = 0' )
560         END SELECT
561      ENDIF
562      !
563      IF( lk_c1d .AND. .NOT.lk_iomput )   CALL ctl_stop( 'nemo_ctl: The 1D configuration must be used ',   &
564         &                                               'with the IOM Input/Output manager. '         ,   &
565         &                                               'Compile with key_iomput enabled' )
566      !
567      IF( 1_wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ',  &
568         &                                               'f2003 standard. '                              ,  &
569         &                                               'Compile with key_nosignedzero enabled' )
570      !
571   END SUBROUTINE nemo_ctl
572
573
574   SUBROUTINE nemo_closefile
575      !!----------------------------------------------------------------------
576      !!                     ***  ROUTINE nemo_closefile  ***
577      !!
578      !! ** Purpose :   Close the files
579      !!----------------------------------------------------------------------
580      !
581      IF( lk_mpp )   CALL mppsync
582      !
583      CALL iom_close                                 ! close all input/output files managed by iom_*
584      !
585      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
586      IF( numsol          /= -1 )   CLOSE( numsol          )   ! solver file
587      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
588      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
589      IF( numond          /= -1 )   CLOSE( numond          )   ! oce output namelist
590      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
591      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
592      IF( numoni          /= -1 )   CLOSE( numoni          )   ! ice output namelist
593      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
594      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
595      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
596      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
597      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
598
599      !
600      numout = 6                                     ! redefine numout in case it is used after this point...
601      !
602   END SUBROUTINE nemo_closefile
603
604
605   SUBROUTINE nemo_alloc
606      !!----------------------------------------------------------------------
607      !!                     ***  ROUTINE nemo_alloc  ***
608      !!
609      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
610      !!
611      !! ** Method  :
612      !!----------------------------------------------------------------------
613      USE diawri    , ONLY: dia_wri_alloc
614      USE dom_oce   , ONLY: dom_oce_alloc
615      USE ldfdyn_oce, ONLY: ldfdyn_oce_alloc
616      USE ldftra_oce, ONLY: ldftra_oce_alloc
617      USE trc_oce   , ONLY: trc_oce_alloc
618#if defined key_diadct 
619      USE diadct    , ONLY: diadct_alloc 
620#endif 
621      !
622      INTEGER :: ierr
623      !!----------------------------------------------------------------------
624      !
625      ierr =        oce_alloc       ()          ! ocean
626      ierr = ierr + dia_wri_alloc   ()
627      ierr = ierr + dom_oce_alloc   ()          ! ocean domain
628      ierr = ierr + ldfdyn_oce_alloc()          ! ocean lateral  physics : dynamics
629      ierr = ierr + ldftra_oce_alloc()          ! ocean lateral  physics : tracers
630      ierr = ierr + zdf_oce_alloc   ()          ! ocean vertical physics
631      !
632      ierr = ierr + trc_oce_alloc   ()          ! shared TRC / TRA arrays
633      !
634#if defined key_diadct 
635      ierr = ierr + diadct_alloc    ()          !
636#endif 
637      !
638      IF( lk_mpp    )   CALL mpp_sum( ierr )
639      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
640      !
641   END SUBROUTINE nemo_alloc
642
643
644   SUBROUTINE nemo_partition( num_pes )
645      !!----------------------------------------------------------------------
646      !!                 ***  ROUTINE nemo_partition  ***
647      !!
648      !! ** Purpose :
649      !!
650      !! ** Method  :
651      !!----------------------------------------------------------------------
652      INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have
653      !
654      INTEGER, PARAMETER :: nfactmax = 20
655      INTEGER :: nfact ! The no. of factors returned
656      INTEGER :: ierr  ! Error flag
657      INTEGER :: ji
658      INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
659      INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
660      !!----------------------------------------------------------------------
661
662      ierr = 0
663
664      CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
665
666      IF( nfact <= 1 ) THEN
667         WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
668         WRITE (numout, *) '       : using grid of ',num_pes,' x 1'
669         jpnj = 1
670         jpni = num_pes
671      ELSE
672         ! Search through factors for the pair that are closest in value
673         mindiff = 1000000
674         imin    = 1
675         DO ji = 1, nfact-1, 2
676            idiff = ABS( ifact(ji) - ifact(ji+1) )
677            IF( idiff < mindiff ) THEN
678               mindiff = idiff
679               imin = ji
680            ENDIF
681         END DO
682         jpnj = ifact(imin)
683         jpni = ifact(imin + 1)
684      ENDIF
685      !
686      jpnij = jpni*jpnj
687      !
688   END SUBROUTINE nemo_partition
689
690
691   SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
692      !!----------------------------------------------------------------------
693      !!                     ***  ROUTINE factorise  ***
694      !!
695      !! ** Purpose :   return the prime factors of n.
696      !!                knfax factors are returned in array kfax which is of
697      !!                maximum dimension kmaxfax.
698      !! ** Method  :
699      !!----------------------------------------------------------------------
700      INTEGER                    , INTENT(in   ) ::   kn, kmaxfax
701      INTEGER                    , INTENT(  out) ::   kerr, knfax
702      INTEGER, DIMENSION(kmaxfax), INTENT(  out) ::   kfax
703      !
704      INTEGER :: ifac, jl, inu
705      INTEGER, PARAMETER :: ntest = 14
706      INTEGER :: ilfax(ntest)
707
708      ! lfax contains the set of allowed factors.
709      data (ilfax(jl),jl=1,ntest) / 16384, 8192, 4096, 2048, 1024, 512, 256,  &
710         &                            128,   64,   32,   16,    8,   4,   2  /
711      !!----------------------------------------------------------------------
712
713      ! Clear the error flag and initialise output vars
714      kerr = 0
715      kfax = 1
716      knfax = 0
717
718      ! Find the factors of n.
719      IF( kn == 1 )   GOTO 20
720
721      ! nu holds the unfactorised part of the number.
722      ! knfax holds the number of factors found.
723      ! l points to the allowed factor list.
724      ! ifac holds the current factor.
725
726      inu   = kn
727      knfax = 0
728
729      DO jl = ntest, 1, -1
730         !
731         ifac = ilfax(jl)
732         IF( ifac > inu )   CYCLE
733
734         ! Test whether the factor will divide.
735
736         IF( MOD(inu,ifac) == 0 ) THEN
737            !
738            knfax = knfax + 1            ! Add the factor to the list
739            IF( knfax > kmaxfax ) THEN
740               kerr = 6
741               write (*,*) 'FACTOR: insufficient space in factor array ', knfax
742               return
743            ENDIF
744            kfax(knfax) = ifac
745            ! Store the other factor that goes with this one
746            knfax = knfax + 1
747            kfax(knfax) = inu / ifac
748            !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
749         ENDIF
750         !
751      END DO
752
753   20 CONTINUE      ! Label 20 is the exit point from the factor search loop.
754      !
755   END SUBROUTINE factorise
756
757#if defined key_mpp_mpi
758   SUBROUTINE nemo_northcomms
759      !!======================================================================
760      !!                     ***  ROUTINE  nemo_northcomms  ***
761      !! nemo_northcomms    :  Setup for north fold exchanges with explicit
762      !!                       point-to-point messaging
763      !!=====================================================================
764      !!----------------------------------------------------------------------
765      !!
766      !! ** Purpose :   Initialization of the northern neighbours lists.
767      !!----------------------------------------------------------------------
768      !!    1.0  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE)
769      !!    2.0  ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S. Mocavero, CMCC)
770      !!----------------------------------------------------------------------
771
772      INTEGER  ::   sxM, dxM, sxT, dxT, jn
773      INTEGER  ::   njmppmax
774
775      njmppmax = MAXVAL( njmppt )
776   
777      !initializes the north-fold communication variables
778      isendto(:) = 0
779      nsndto = 0
780
781      !if I am a process in the north
782      IF ( njmpp == njmppmax ) THEN
783          !sxM is the first point (in the global domain) needed to compute the
784          !north-fold for the current process
785          sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
786          !dxM is the last point (in the global domain) needed to compute the
787          !north-fold for the current process
788          dxM = jpiglo - nimppt(narea) + 2
789
790          !loop over the other north-fold processes to find the processes
791          !managing the points belonging to the sxT-dxT range
792          DO jn = jpnij - jpni +1, jpnij
793             IF ( njmppt(jn) == njmppmax ) THEN
794                !sxT is the first point (in the global domain) of the jn
795                !process
796                sxT = nimppt(jn)
797                !dxT is the last point (in the global domain) of the jn
798                !process
799                dxT = nimppt(jn) + nlcit(jn) - 1
800                IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
801                   nsndto = nsndto + 1
802                   isendto(nsndto) = jn
803                ELSEIF ((sxM .le. sxT) .AND. (dxM .gt. dxT)) THEN
804                   nsndto = nsndto + 1
805                   isendto(nsndto) = jn
806                ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
807                   nsndto = nsndto + 1
808                   isendto(nsndto) = jn
809                END IF
810             END IF
811          END DO
812      ENDIF
813      l_north_nogather = .TRUE.
814   END SUBROUTINE nemo_northcomms
815#else
816   SUBROUTINE nemo_northcomms      ! Dummy routine
817      WRITE(*,*) 'nemo_northcomms: You should not have seen this print! error?'
818   END SUBROUTINE nemo_northcomms
819#endif
820   !!======================================================================
821END MODULE nemogcm
Note: See TracBrowser for help on using the repository browser.