source: branches/2013/dev_MERGE_2013/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zsed.F90 @ 4521

Last change on this file since 4521 was 4521, checked in by cetlod, 7 years ago

v3.6alpha : bugfixes in PISCES, see ticket #1251

File size: 20.0 KB
Line 
1MODULE p4zsed
2   !!======================================================================
3   !!                         ***  MODULE p4sed  ***
4   !! TOP :   PISCES Compute loss of organic matter in the sediments
5   !!======================================================================
6   !! History :   1.0  !  2004-03 (O. Aumont) Original code
7   !!             2.0  !  2007-12 (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06 (C. Ethe) USE of fldread
9   !!             3.5  !  2012-07 (O. Aumont) improvment of river input of nutrients
10   !!----------------------------------------------------------------------
11#if defined key_pisces
12   !!----------------------------------------------------------------------
13   !!   'key_pisces'                                       PISCES bio-model
14   !!----------------------------------------------------------------------
15   !!   p4z_sed        :  Compute loss of organic matter in the sediments
16   !!----------------------------------------------------------------------
17   USE oce_trc         !  shared variables between ocean and passive tracers
18   USE trc             !  passive tracers common variables
19   USE sms_pisces      !  PISCES Source Minus Sink variables
20   USE p4zsink         !  vertical flux of particulate matter due to sinking
21   USE p4zopt          !  optical model
22   USE p4zlim          !  Co-limitations of differents nutrients
23   USE p4zrem          !  Remineralisation of organic matter
24   USE p4zsbc          !  External source of nutrients
25   USE p4zint          !  interpolation and computation of various fields
26   USE iom             !  I/O manager
27   USE prtctl_trc      !  print control for debugging
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   p4z_sed   
33
34   !! * Module variables
35   REAL(wp) :: ryyss                    !: number of seconds per year
36   REAL(wp) :: r1_ryyss                 !: inverse of ryyss
37   REAL(wp) :: rmtss                    !: number of seconds per month
38   REAL(wp) :: r1_rday                  !: inverse of rday
39
40   INTEGER ::  numnit 
41
42
43   !!* Substitution
44#  include "top_substitute.h90"
45   !!----------------------------------------------------------------------
46   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
47   !! $Header:$
48   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
49   !!----------------------------------------------------------------------
50CONTAINS
51
52   SUBROUTINE p4z_sed( kt, jnt )
53      !!---------------------------------------------------------------------
54      !!                     ***  ROUTINE p4z_sed  ***
55      !!
56      !! ** Purpose :   Compute loss of organic matter in the sediments. This
57      !!              is by no way a sediment model. The loss is simply
58      !!              computed to balance the inout from rivers and dust
59      !!
60      !! ** Method  : - ???
61      !!---------------------------------------------------------------------
62      !
63      INTEGER, INTENT(in) ::   kt, jnt ! ocean time step
64      INTEGER  ::   ji, jj, jk, ikt
65#if ! defined key_sed
66      REAL(wp) ::   zsumsedsi, zsumsedpo4, zsumsedcal
67      REAL(wp) ::   zrivalk, zrivsil, zrivno3
68#endif
69      REAL(wp) ::  zwflux, zfminus, zfplus
70      REAL(wp) ::  zlim, zfact, zfactcal
71      REAL(wp) ::  zo2, zno3, zflx, zpdenit, z1pdenit, zdenitt, zolimit
72      REAL(wp) ::  zsiloss, zcaloss, zws3, zws4, zwsc, zdep, zwstpoc
73      REAL(wp) ::  ztrfer, ztrpo4, zwdust
74      REAL(wp) ::  zrdenittot, zsdenittot, znitrpottot
75      !
76      CHARACTER (len=25) :: charout
77      REAL(wp), POINTER, DIMENSION(:,:  ) :: zpdep, zsidep, zwork1, zwork2, zwork3, zwork4
78      REAL(wp), POINTER, DIMENSION(:,:  ) :: zdenit2d, zironice
79      REAL(wp), POINTER, DIMENSION(:,:  ) :: zwsbio3, zwsbio4, zwscal
80      REAL(wp), POINTER, DIMENSION(:,:,:) :: znitrpot, zirondep
81      !!---------------------------------------------------------------------
82      !
83      IF( nn_timing == 1 )  CALL timing_start('p4z_sed')
84      !
85      IF( kt == nittrc000 .AND. jnt == 1 )  THEN
86         ryyss    = nyear_len(1) * rday    ! number of seconds per year and per month
87         rmtss    = ryyss / raamo
88         r1_rday  = 1. / rday
89         r1_ryyss = 1. / ryyss
90         IF( ln_check_mass .AND. lwp)  &
91           &  CALL ctl_opn( numnit, 'nitrogen.budget', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
92      ENDIF
93      !
94      ! Allocate temporary workspace
95      CALL wrk_alloc( jpi, jpj, zdenit2d, zwork1, zwork2, zwork3, zwork4 )
96      CALL wrk_alloc( jpi, jpj, zwsbio3, zwsbio4, zwscal )
97      CALL wrk_alloc( jpi, jpj, jpk, znitrpot )
98
99      zdenit2d(:,:) = 0.e0
100
101      ! Iron input/uptake due to sea ice : Crude parameterization based on Lancelot et al.
102      ! ----------------------------------------------------
103      IF( ln_ironice ) THEN 
104         !                                             
105         CALL wrk_alloc( jpi, jpj, zironice )
106         !                                             
107         DO jj = 1, jpj
108            DO ji = 1, jpi
109               zdep    = rfact2 / fse3t(ji,jj,1)
110               zwflux  = fmmflx(ji,jj) / 1000._wp
111               zfminus = MIN( 0._wp, -zwflux ) * trn(ji,jj,1,jpfer) * zdep
112               zfplus  = MAX( 0._wp, -zwflux ) * icefeinput * zdep
113               zironice(ji,jj) =  zfplus + zfminus
114            END DO
115         END DO
116         !
117         trn(:,:,1,jpfer) = trn(:,:,1,jpfer) + zironice(:,:) 
118         !                                             
119         IF( ln_diatrc .AND. lk_iomput .AND. jnt == nrdttrc )   &
120            &   CALL iom_put( "Ironice", zironice(:,:) * 1.e+3 * rfact2r * fse3t(:,:,1) * tmask(:,:,1) ) ! iron flux from ice
121         CALL wrk_dealloc( jpi, jpj, zironice )
122         !                                             
123      ENDIF
124
125      ! Add the external input of nutrients from dust deposition
126      ! ----------------------------------------------------------
127      IF( ln_dust ) THEN
128         !                                             
129         CALL wrk_alloc( jpi, jpj,      zpdep, zsidep )
130         CALL wrk_alloc( jpi, jpj, jpk, zirondep      )
131         !                                              ! Iron and Si deposition at the surface
132         IF( ln_solub ) THEN
133            zirondep(:,:,1) = solub(:,:) * dust(:,:) * rfact2 / fse3t(:,:,1) / ( 55.85 * rmtss ) + 3.e-10 * r1_ryyss 
134         ELSE
135            zirondep(:,:,1) = dustsolub  * dust(:,:) * rfact2 / fse3t(:,:,1) / ( 55.85 * rmtss ) + 3.e-10 * r1_ryyss 
136         ENDIF
137         zsidep(:,:) = 8.8 * 0.075 * dust(:,:) * rfact2 / fse3t(:,:,1) / ( 28.1  * rmtss )
138         zpdep (:,:) = 0.1 * 0.021 * dust(:,:) * rfact2 / fse3t(:,:,1) / ( 31.   * rmtss ) / po4r 
139         !                                              ! Iron solubilization of particles in the water column
140         zwdust = 0.005 / ( wdust * 55.85 * 30.42 ) / ( 45. * rday ) 
141         DO jk = 2, jpkm1
142            zirondep(:,:,jk) = dust(:,:) * zwdust * rfact2 * EXP( -fsdept(:,:,jk) / 1000. )
143         END DO
144         !                                              ! Iron solubilization of particles in the water column
145         trn(:,:,1,jppo4) = trn(:,:,1,jppo4) + zpdep   (:,:)
146         trn(:,:,1,jpsil) = trn(:,:,1,jpsil) + zsidep  (:,:)
147         trn(:,:,:,jpfer) = trn(:,:,:,jpfer) + zirondep(:,:,:) 
148         !                                             
149         IF( ln_diatrc ) THEN
150            zfact = 1.e+3 * rfact2r
151            IF( lk_iomput ) THEN
152               IF( jnt == nrdttrc ) THEN
153                  CALL iom_put( "Irondep", zirondep(:,:,1) * zfact * fse3t(:,:,1) * tmask(:,:,1) ) ! surface downward dust depo of iron
154                  CALL iom_put( "pdust"  , dust(:,:) / ( wdust * 30.42 * 0.035 )  * tmask(:,:,1) ) ! dust concentration at surface
155               ENDIF
156            ELSE
157               trc2d(:,:,jp_pcs0_2d + 11) = zirondep(:,:,1) * zfact * fse3t(:,:,1) * tmask(:,:,1)
158            ENDIF
159         ENDIF
160         CALL wrk_dealloc( jpi, jpj,      zpdep, zsidep )
161         CALL wrk_dealloc( jpi, jpj, jpk, zirondep      )
162         !                                             
163      ENDIF
164     
165      ! Add the external input of nutrients from river
166      ! ----------------------------------------------------------
167      IF( ln_river ) THEN
168         trn(:,:,1,jppo4) = trn(:,:,1,jppo4) + rivdip(:,:) * rfact2
169         trn(:,:,1,jpno3) = trn(:,:,1,jpno3) + rivdin(:,:) * rfact2
170         trn(:,:,1,jpfer) = trn(:,:,1,jpfer) + rivdic(:,:) * 5.e-5 * rfact2
171         trn(:,:,1,jpsil) = trn(:,:,1,jpsil) + rivdsi(:,:) * rfact2
172         trn(:,:,1,jpdic) = trn(:,:,1,jpdic) + rivdic(:,:) * rfact2
173         trn(:,:,1,jptal) = trn(:,:,1,jptal) + ( rivalk(:,:) - rno3 * rivdin(:,:) ) * rfact2
174      ENDIF
175     
176      ! Add the external input of nutrients from nitrogen deposition
177      ! ----------------------------------------------------------
178      IF( ln_ndepo ) THEN
179         trn(:,:,1,jpno3) = trn(:,:,1,jpno3) + nitdep(:,:) * rfact2
180         trn(:,:,1,jptal) = trn(:,:,1,jptal) - rno3 * nitdep(:,:) * rfact2
181      ENDIF
182
183      ! Add the external input of iron from sediment mobilization
184      ! ------------------------------------------------------
185      IF( ln_ironsed ) THEN
186         trn(:,:,:,jpfer) = trn(:,:,:,jpfer) + ironsed(:,:,:) * rfact2
187         !
188         IF( ln_diatrc .AND. lk_iomput .AND. jnt == nrdttrc )   &
189            &   CALL iom_put( "Ironsed", ironsed(:,:,:) * 1.e+3 * tmask(:,:,:) ) ! iron inputs from sediments
190      ENDIF
191
192      ! Add the external input of iron from hydrothermal vents
193      ! ------------------------------------------------------
194      IF( ln_hydrofe ) THEN
195         trn(:,:,:,jpfer) = trn(:,:,:,jpfer) + hydrofe(:,:,:) * rfact2
196         !
197         IF( ln_diatrc .AND. lk_iomput .AND. jnt == nrdttrc )   &
198            &   CALL iom_put( "HYDR", hydrofe(:,:,:) * 1.e+3 * tmask(:,:,:) ) ! hydrothermal iron input
199      ENDIF
200
201
202      ! OA: Warning, the following part is necessary, especially with Kriest
203      ! to avoid CFL problems above the sediments
204      ! --------------------------------------------------------------------
205      DO jj = 1, jpj
206         DO ji = 1, jpi
207            ikt  = mbkt(ji,jj)
208            zdep = fse3t(ji,jj,ikt) / xstep
209            zwsbio4(ji,jj) = MIN( 0.99 * zdep, wsbio4(ji,jj,ikt) )
210            zwscal (ji,jj) = MIN( 0.99 * zdep, wscal (ji,jj,ikt) )
211            zwsbio3(ji,jj) = MIN( 0.99 * zdep, wsbio3(ji,jj,ikt) )
212         END DO
213      END DO
214
215#if ! defined key_sed
216      ! Computation of the sediment denitrification proportion: The metamodel from midlleburg (2006) is being used
217      ! -------------------------------------------------------
218      DO jj = 1, jpj
219         DO ji = 1, jpi
220           IF( tmask(ji,jj,1) == 1 ) THEN
221              ikt = mbkt(ji,jj)
222# if defined key_kriest
223              zflx =    trn(ji,jj,ikt,jppoc) * zwsbio3(ji,jj)    * 1E3 * 1E6 / 1E4
224# else
225              zflx = (  trn(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj)   &
226                &     + trn(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) )  * 1E3 * 1E6 / 1E4
227#endif
228              zflx  = LOG10( MAX( 1E-3, zflx ) )
229              zo2   = LOG10( MAX( 10. , trn(ji,jj,ikt,jpoxy) * 1E6 ) )
230              zno3  = LOG10( MAX( 1.  , trn(ji,jj,ikt,jpno3) * 1E6 * rno3 ) )
231              zdep  = LOG10( fsdepw(ji,jj,ikt+1) )
232              zdenit2d(ji,jj) = -2.2567 - 1.185 * zflx - 0.221 * zflx**2 - 0.3995 * zno3 * zo2 + 1.25 * zno3    &
233              &                + 0.4721 * zo2 - 0.0996 * zdep + 0.4256 * zflx * zo2
234              zdenit2d(ji,jj) = 10.0**( zdenit2d(ji,jj) )
235           ENDIF
236         END DO
237      END DO 
238      ! Loss of biogenic silicon, Caco3 organic carbon in the sediments.
239      ! First, the total loss is computed.
240      ! The factor for calcite comes from the alkalinity effect
241      ! -------------------------------------------------------------
242      DO jj = 1, jpj
243         DO ji = 1, jpi
244            ikt = mbkt(ji,jj) 
245# if defined key_kriest
246            zwork1(ji,jj) = trn(ji,jj,ikt,jpgsi) * zwscal (ji,jj)
247            zwork2(ji,jj) = trn(ji,jj,ikt,jppoc) * zwsbio3(ji,jj)
248# else
249            zwork1(ji,jj) = trn(ji,jj,ikt,jpgsi) * zwsbio4(ji,jj)
250            zwork2(ji,jj) = trn(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj) + trn(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) 
251# endif
252            ! For calcite, burial efficiency is made a function of saturation
253            zfactcal      = MIN( excess(ji,jj,ikt), 0.2 )
254            zfactcal      = MIN( 1., 1.3 * ( 0.2 - zfactcal ) / ( 0.4 - zfactcal ) )
255            zwork3(ji,jj) = trn(ji,jj,ikt,jpcal) * zwscal(ji,jj) * 2.e0 * zfactcal
256         END DO
257      END DO
258      zsumsedsi  = glob_sum( zwork1(:,:) * e1e2t(:,:) ) * r1_rday
259      zsumsedpo4 = glob_sum( zwork2(:,:) * e1e2t(:,:) ) * r1_rday
260      zsumsedcal = glob_sum( zwork3(:,:) * e1e2t(:,:) ) * r1_rday
261#endif
262
263      ! This loss is scaled at each bottom grid cell for equilibrating the total budget of silica in the ocean.
264      ! Thus, the amount of silica lost in the sediments equal the supply at the surface (dust+rivers)
265      ! ------------------------------------------------------
266#if ! defined key_sed
267      zrivsil =  1._wp - ( sumdepsi + rivdsiinput * r1_ryyss ) / zsumsedsi
268      zrivno3 =  1._wp - ( rivdininput * r1_ryyss ) / zsumsedpo4
269#endif
270
271      DO jj = 1, jpj
272         DO ji = 1, jpi
273            ikt  = mbkt(ji,jj)
274            zdep = xstep / fse3t(ji,jj,ikt)
275            zws4 = zwsbio4(ji,jj) * zdep
276            zwsc = zwscal (ji,jj) * zdep
277# if defined key_kriest
278            zsiloss = trn(ji,jj,ikt,jpgsi) * zws4
279# else
280            zsiloss = trn(ji,jj,ikt,jpgsi) * zwsc
281# endif
282            zcaloss = trn(ji,jj,ikt,jpcal) * zwsc
283            !
284            trn(ji,jj,ikt,jpgsi) = trn(ji,jj,ikt,jpgsi) - zsiloss
285            trn(ji,jj,ikt,jpcal) = trn(ji,jj,ikt,jpcal) - zcaloss
286#if ! defined key_sed
287            trn(ji,jj,ikt,jpsil) = trn(ji,jj,ikt,jpsil) + zsiloss * zrivsil 
288            zfactcal = MIN( excess(ji,jj,ikt), 0.2 )
289            zfactcal = MIN( 1., 1.3 * ( 0.2 - zfactcal ) / ( 0.4 - zfactcal ) )
290            zrivalk  =  1._wp - ( rivalkinput * r1_ryyss ) * zfactcal / zsumsedcal 
291            trn(ji,jj,ikt,jptal) =  trn(ji,jj,ikt,jptal) + zcaloss * zrivalk * 2.0
292            trn(ji,jj,ikt,jpdic) =  trn(ji,jj,ikt,jpdic) + zcaloss * zrivalk
293#endif
294         END DO
295      END DO
296
297      DO jj = 1, jpj
298         DO ji = 1, jpi
299            ikt     = mbkt(ji,jj)
300            zdep    = xstep / fse3t(ji,jj,ikt)
301            zws4 = zwsbio4(ji,jj) * zdep
302            zws3 = zwsbio3(ji,jj) * zdep
303# if ! defined key_kriest
304            trn(ji,jj,ikt,jpgoc) = trn(ji,jj,ikt,jpgoc) - trn(ji,jj,ikt,jpgoc) * zws4
305            trn(ji,jj,ikt,jppoc) = trn(ji,jj,ikt,jppoc) - trn(ji,jj,ikt,jppoc) * zws3
306            trn(ji,jj,ikt,jpbfe) = trn(ji,jj,ikt,jpbfe) - trn(ji,jj,ikt,jpbfe) * zws4
307            trn(ji,jj,ikt,jpsfe) = trn(ji,jj,ikt,jpsfe) - trn(ji,jj,ikt,jpsfe) * zws3
308            zwstpoc              =  trn(ji,jj,ikt,jpgoc) * zws4 + trn(ji,jj,ikt,jppoc) * zws3 
309# else
310            trn(ji,jj,ikt,jpnum) = trn(ji,jj,ikt,jpnum) - trn(ji,jj,ikt,jpnum) * zws4
311            trn(ji,jj,ikt,jppoc) = trn(ji,jj,ikt,jppoc) - trn(ji,jj,ikt,jppoc) * zws3
312            trn(ji,jj,ikt,jpsfe) = trn(ji,jj,ikt,jpsfe) - trn(ji,jj,ikt,jpsfe) * zws3
313            zwstpoc = trn(ji,jj,ikt,jppoc) * zws3 
314# endif
315
316#if ! defined key_sed
317            ! The 0.5 factor in zpdenit and zdenitt is to avoid negative NO3 concentration after both denitrification
318            ! in the sediments and just above the sediments. Not very clever, but simpliest option.
319            zpdenit  = MIN( 0.5 * ( trn(ji,jj,ikt,jpno3) - rtrn ) / rdenit, zdenit2d(ji,jj) * zwstpoc * zrivno3 )
320            z1pdenit = zwstpoc * zrivno3 - zpdenit
321            zolimit = MIN( ( trn(ji,jj,ikt,jpoxy) - rtrn ) / o2ut, z1pdenit * ( 1.- nitrfac(ji,jj,ikt) ) )
322            zdenitt = MIN(  0.5 * ( trn(ji,jj,ikt,jpno3) - rtrn ) / rdenit, z1pdenit * nitrfac(ji,jj,ikt) )
323            trn(ji,jj,ikt,jpdoc) = trn(ji,jj,ikt,jpdoc) + z1pdenit - zolimit - zdenitt
324            trn(ji,jj,ikt,jppo4) = trn(ji,jj,ikt,jppo4) + zpdenit + zolimit + zdenitt
325            trn(ji,jj,ikt,jpnh4) = trn(ji,jj,ikt,jpnh4) + zpdenit + zolimit + zdenitt
326            trn(ji,jj,ikt,jpno3) = trn(ji,jj,ikt,jpno3) - rdenit * (zpdenit + zdenitt)
327            trn(ji,jj,ikt,jpoxy) = trn(ji,jj,ikt,jpoxy) - zolimit * o2ut
328            trn(ji,jj,ikt,jptal) = trn(ji,jj,ikt,jptal) + rno3 * (zolimit + (1.+rdenit) * (zpdenit + zdenitt) )
329            trn(ji,jj,ikt,jpdic) = trn(ji,jj,ikt,jpdic) + zpdenit + zolimit + zdenitt
330            zwork4(ji,jj) = rdenit * zpdenit * fse3t(ji,jj,ikt)
331#endif
332         END DO
333      END DO
334
335      ! Nitrogen fixation process
336      !-----------------------------------
337      DO jk = 1, jpkm1
338         DO jj = 1, jpj
339            DO ji = 1, jpi
340               !                                       ! Potential nitrogen fixation dependant on temperature and iron
341               zlim = ( 1.- xnanono3(ji,jj,jk) - xnanonh4(ji,jj,jk) )
342               IF( zlim <= 0.2 )   zlim = 0.01
343#if defined key_degrad
344               zfact = zlim * rfact2 * facvol(ji,jj,jk)
345#else
346               zfact = zlim * rfact2
347#endif
348               ztrfer = biron(ji,jj,jk)       / ( concfediaz + biron(ji,jj,jk)       )
349               ztrpo4 = trn  (ji,jj,jk,jppo4) / ( concnnh4   + trn  (ji,jj,jk,jppo4) ) 
350               znitrpot(ji,jj,jk) =  MAX( 0.e0, ( 0.6 * tgfunc(ji,jj,jk) - 2.15 ) * r1_rday )   &
351                 &         *  zfact * MIN( ztrfer, ztrpo4 ) * ( 1.- EXP( -etot(ji,jj,jk) / diazolight ) )
352            END DO
353         END DO
354      END DO
355 
356      IF( ln_check_mass ) THEN
357         ! The total gain from nitrogen fixation is scaled to balance the loss by denitrification
358         ! -------------------------------------------------------------
359         zrdenittot   = glob_sum ( denitr(:,:,:) * rdenit * xnegtr(:,:,:) * cvol(:,:,:) )
360         zsdenittot   = glob_sum ( zwork4(:,:)   * e1e2t(:,:) )
361         znitrpottot  = glob_sum ( znitrpot(:,:,:)                        * cvol(:,:,:) )
362         IF( kt == nitend .AND. jnt == nrdttrc ) THEN
363            zfact = 1.e+3 * rfact2r * rno3 * 365. * 86400. * 14. / 1e12
364            IF(lwp) WRITE(numnit,9100) ndastp, znitrpottot * nitrfix * zfact, zrdenittot * zfact , zsdenittot * zfact
365         ENDIF
366       ENDIF
367
368      ! Nitrogen change due to nitrogen fixation
369      ! ----------------------------------------
370      DO jk = 1, jpkm1
371         DO jj = 1, jpj
372            DO ji = 1, jpi
373               ! zfact = znitrpot(ji,jj,jk) * ( zrdenittot + zsdenittot ) / znitrpottot
374               zfact = znitrpot(ji,jj,jk) * nitrfix
375               trn(ji,jj,jk,jpnh4) = trn(ji,jj,jk,jpnh4) +             zfact
376               trn(ji,jj,jk,jptal) = trn(ji,jj,jk,jptal) + rno3      * zfact
377               trn(ji,jj,jk,jpoxy) = trn(ji,jj,jk,jpoxy) + o2nit     * zfact 
378               trn(ji,jj,jk,jppo4) = trn(ji,jj,jk,jppo4) + 30. / 46. * zfact
379           END DO
380         END DO
381      END DO
382      !
383      IF( ln_diatrc ) THEN
384         zfact = 1.e+3 * rfact2r
385         IF( lk_iomput ) THEN
386            IF( jnt == nrdttrc ) THEN
387               CALL iom_put( "Nfix"  , znitrpot(:,:,:) * nitrfix * rno3 * zfact * tmask(:,:,:) )  ! nitrogen fixation
388               CALL iom_put( "Sdenit", zwork4(:,:)               * rno3 * zfact * tmask(:,:,1) )  ! Nitrate reduction in the sediments
389            ENDIF
390         ELSE
391            trc2d(:,:,jp_pcs0_2d + 12) = znitrpot(:,:,1) * nitrfix * zfact * fse3t(:,:,1) * tmask(:,:,1)
392         ENDIF
393      ENDIF
394      !
395      IF(ln_ctl) THEN  ! print mean trends (USEd for debugging)
396         WRITE(charout, fmt="('sed ')")
397         CALL prt_ctl_trc_info(charout)
398         CALL prt_ctl_trc(tab4d=trn, mask=tmask, clinfo=ctrcnm)
399      ENDIF
400      !
401      CALL wrk_dealloc( jpi, jpj, zdenit2d, zwork1, zwork2, zwork3, zwork4 )
402      CALL wrk_dealloc( jpi, jpj, zwsbio3, zwsbio4, zwscal )
403      CALL wrk_dealloc( jpi, jpj, jpk, znitrpot )
404      !
405      IF( nn_timing == 1 )  CALL timing_stop('p4z_sed')
406      !
407 9100  FORMAT(i8,3f10.5)
408      !
409   END SUBROUTINE p4z_sed
410
411#else
412   !!======================================================================
413   !!  Dummy module :                                   No PISCES bio-model
414   !!======================================================================
415CONTAINS
416   SUBROUTINE p4z_sed                         ! Empty routine
417   END SUBROUTINE p4z_sed
418#endif 
419
420   !!======================================================================
421END MODULE  p4zsed
Note: See TracBrowser for help on using the repository browser.