source: branches/2013/dev_r3858_CNRS3_Ediag/NEMOGCM/NEMO/OPA_SRC/DYN/dynldf.F90 @ 3876

Last change on this file since 3876 was 3876, checked in by gm, 8 years ago

dev_r3858_CNRS3_Ediag: #927 phasing with 2011/dev_r3309_LOCEAN12_Ediag branche + mxl diag update

  • Property svn:keywords set to Id
File size: 12.2 KB
Line 
1MODULE dynldf
2   !!======================================================================
3   !!                       ***  MODULE  dynldf  ***
4   !! Ocean physics:  lateral diffusivity trends
5   !!=====================================================================
6   !! History :  9.0  !  05-11  (G. Madec)  Original code (new step architecture)
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!   dyn_ldf      : update the dynamics trend with the lateral diffusion
11   !!   dyn_ldf_init : initialization, namelist read, and parameters control
12   !!----------------------------------------------------------------------
13   USE oce            ! ocean dynamics and tracers
14   USE dom_oce        ! ocean space and time domain
15   USE phycst         ! physical constants
16   USE ldfdyn_oce     ! ocean dynamics lateral physics
17   USE ldfslp         ! lateral mixing: slopes of mixing orientation
18   USE dynldf_bilapg  ! lateral mixing            (dyn_ldf_bilapg routine)
19   USE dynldf_bilap   ! lateral mixing            (dyn_ldf_bilap  routine)
20   USE dynldf_iso     ! lateral mixing            (dyn_ldf_iso    routine)
21   USE dynldf_lap     ! lateral mixing            (dyn_ldf_lap    routine)
22   USE trd_oce        ! trends: ocean variables
23   USE trddyn         ! trend manager: dynamics
24   USE prtctl         ! Print control
25   USE in_out_manager ! I/O manager
26   USE lib_mpp        ! distribued memory computing library
27   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
28   USE wrk_nemo        ! Memory Allocation
29   USE timing          ! Timing
30
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   dyn_ldf       ! called by step module
36   PUBLIC   dyn_ldf_init  ! called by opa  module
37
38   INTEGER ::   nldf = -2   ! type of lateral diffusion used defined from ln_dynldf_... namlist logicals)
39
40   !! * Substitutions
41#  include "domzgr_substitute.h90"
42#  include "vectopt_loop_substitute.h90"
43   !!----------------------------------------------------------------------
44   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
45   !! $Id$
46   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
47   !!----------------------------------------------------------------------
48CONTAINS
49
50   SUBROUTINE dyn_ldf( kt )
51      !!----------------------------------------------------------------------
52      !!                  ***  ROUTINE dyn_ldf  ***
53      !!
54      !! ** Purpose :   compute the lateral ocean dynamics physics.
55      !!----------------------------------------------------------------------
56      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
57      !
58      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdu, ztrdv
59      !!----------------------------------------------------------------------
60      !
61      IF( nn_timing == 1 )  CALL timing_start('dyn_ldf')
62      !
63      IF( l_trddyn )   THEN                      ! temporary save of ta and sa trends
64         CALL wrk_alloc( jpi, jpj, jpk, ztrdu, ztrdv )
65         ztrdu(:,:,:) = ua(:,:,:) 
66         ztrdv(:,:,:) = va(:,:,:) 
67      ENDIF
68
69      SELECT CASE ( nldf )                       ! compute lateral mixing trend and add it to the general trend
70      !
71      CASE ( 0 )    ;   CALL dyn_ldf_lap    ( kt )      ! iso-level laplacian
72      CASE ( 1 )    ;   CALL dyn_ldf_iso    ( kt )      ! rotated laplacian (except dk[ dk[.] ] part)
73      CASE ( 2 )    ;   CALL dyn_ldf_bilap  ( kt )      ! iso-level bilaplacian
74      CASE ( 3 )    ;   CALL dyn_ldf_bilapg ( kt )      ! s-coord. horizontal bilaplacian
75      CASE ( 4 )                                        ! iso-level laplacian + bilaplacian
76         CALL dyn_ldf_lap    ( kt )
77         CALL dyn_ldf_bilap  ( kt )
78      CASE ( 5 )                                        ! rotated laplacian + bilaplacian (s-coord)
79         CALL dyn_ldf_iso    ( kt )
80         CALL dyn_ldf_bilapg ( kt )
81      !
82      CASE ( -1 )                                       ! esopa: test all possibility with control print
83                        CALL dyn_ldf_lap    ( kt )
84                        CALL prt_ctl( tab3d_1=ua, clinfo1=' ldf0 - Ua: ', mask1=umask,   &
85            &                         tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
86                        CALL dyn_ldf_iso    ( kt )
87                        CALL prt_ctl( tab3d_1=ua, clinfo1=' ldf1 - Ua: ', mask1=umask,   &
88            &                         tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
89                        CALL dyn_ldf_bilap  ( kt )
90                        CALL prt_ctl( tab3d_1=ua, clinfo1=' ldf2 - Ua: ', mask1=umask,   &
91            &                         tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
92                        CALL dyn_ldf_bilapg ( kt )
93                        CALL prt_ctl( tab3d_1=ua, clinfo1=' ldf3 - Ua: ', mask1=umask,   &
94            &                         tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
95      !
96      CASE ( -2 )                                       ! neither laplacian nor bilaplacian schemes used
97         IF( kt == nit000 ) THEN
98            IF(lwp) WRITE(numout,*)
99            IF(lwp) WRITE(numout,*) 'dyn_ldf : no lateral diffusion on momentum setup'
100            IF(lwp) WRITE(numout,*) '~~~~~~~ '
101         ENDIF
102      END SELECT
103
104      IF( l_trddyn ) THEN                        ! save the horizontal diffusive trends for further diagnostics
105         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
106         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
107         CALL trd_dyn( ztrdu, ztrdv, jpdyn_ldf, kt )
108         CALL wrk_dealloc( jpi, jpj, jpk, ztrdu, ztrdv )
109      ENDIF
110      !                                          ! print sum trends (used for debugging)
111      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' ldf  - Ua: ', mask1=umask,   &
112         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
113      !
114      IF( nn_timing == 1 )  CALL timing_stop('dyn_ldf')
115      !
116   END SUBROUTINE dyn_ldf
117
118
119   SUBROUTINE dyn_ldf_init
120      !!----------------------------------------------------------------------
121      !!                  ***  ROUTINE dyn_ldf_init  ***
122      !!
123      !! ** Purpose :   initializations of the horizontal ocean dynamics physics
124      !!----------------------------------------------------------------------
125      INTEGER ::   ioptio, ierr         ! temporary integers
126      !!----------------------------------------------------------------------
127   
128      !                                   ! Namelist nam_dynldf: already read in ldfdyn module
129
130      IF(lwp) THEN                        ! Namelist print
131         WRITE(numout,*)
132         WRITE(numout,*) 'dyn_ldf_init : Choice of the lateral diffusive operator on dynamics'
133         WRITE(numout,*) '~~~~~~~~~~~'
134         WRITE(numout,*) '       Namelist nam_dynldf : set lateral mixing parameters (type, direction, coefficients)'
135         WRITE(numout,*) '          laplacian operator          ln_dynldf_lap   = ', ln_dynldf_lap
136         WRITE(numout,*) '          bilaplacian operator        ln_dynldf_bilap = ', ln_dynldf_bilap
137         WRITE(numout,*) '          iso-level                   ln_dynldf_level = ', ln_dynldf_level
138         WRITE(numout,*) '          horizontal (geopotential)   ln_dynldf_hor   = ', ln_dynldf_hor
139         WRITE(numout,*) '          iso-neutral                 ln_dynldf_iso   = ', ln_dynldf_iso
140      ENDIF
141
142      !                                   ! control the consistency
143      ioptio = 0
144      IF( ln_dynldf_lap   )   ioptio = ioptio + 1
145      IF( ln_dynldf_bilap )   ioptio = ioptio + 1
146      IF( ioptio <  1 ) CALL ctl_warn( '          neither laplacian nor bilaplacian operator set for dynamics' )
147      ioptio = 0
148      IF( ln_dynldf_level )   ioptio = ioptio + 1
149      IF( ln_dynldf_hor   )   ioptio = ioptio + 1
150      IF( ln_dynldf_iso   )   ioptio = ioptio + 1
151      IF( ioptio >  1 ) CALL ctl_stop( '          use only ONE direction (level/hor/iso)' )
152
153      !                                   ! Set nldf, the type of lateral diffusion, from ln_dynldf_... logicals
154      ierr = 0
155      IF ( ln_dynldf_lap ) THEN      ! laplacian operator
156         IF ( ln_zco ) THEN                ! z-coordinate
157            IF ( ln_dynldf_level )   nldf = 0      ! iso-level  (no rotation)
158            IF ( ln_dynldf_hor   )   nldf = 0      ! horizontal (no rotation)
159            IF ( ln_dynldf_iso   )   nldf = 1      ! isoneutral (   rotation)
160         ENDIF
161         IF ( ln_zps ) THEN             ! z-coordinate
162            IF ( ln_dynldf_level )   ierr = 1      ! iso-level not allowed
163            IF ( ln_dynldf_hor   )   nldf = 0      ! horizontal (no rotation)
164            IF ( ln_dynldf_iso   )   nldf = 1      ! isoneutral (   rotation)
165         ENDIF
166         IF ( ln_sco ) THEN             ! s-coordinate
167            IF ( ln_dynldf_level )   nldf = 0      ! iso-level  (no rotation)
168            IF ( ln_dynldf_hor   )   nldf = 1      ! horizontal (   rotation)
169            IF ( ln_dynldf_iso   )   nldf = 1      ! isoneutral (   rotation)
170         ENDIF
171      ENDIF
172
173      IF( ln_dynldf_bilap ) THEN      ! bilaplacian operator
174         IF ( ln_zco ) THEN                ! z-coordinate
175            IF ( ln_dynldf_level )   nldf = 2      ! iso-level  (no rotation)
176            IF ( ln_dynldf_hor   )   nldf = 2      ! horizontal (no rotation)
177            IF ( ln_dynldf_iso   )   ierr = 2      ! isoneutral (   rotation)
178         ENDIF
179         IF ( ln_zps ) THEN             ! z-coordinate
180            IF ( ln_dynldf_level )   ierr = 1      ! iso-level not allowed
181            IF ( ln_dynldf_hor   )   nldf = 2      ! horizontal (no rotation)
182            IF ( ln_dynldf_iso   )   ierr = 2      ! isoneutral (   rotation)
183         ENDIF
184         IF ( ln_sco ) THEN             ! s-coordinate
185            IF ( ln_dynldf_level )   nldf = 2      ! iso-level  (no rotation)
186            IF ( ln_dynldf_hor   )   nldf = 3      ! horizontal (   rotation)
187            IF ( ln_dynldf_iso   )   ierr = 2      ! isoneutral (   rotation)
188         ENDIF
189      ENDIF
190     
191      IF( ln_dynldf_lap .AND. ln_dynldf_bilap ) THEN  ! mixed laplacian and bilaplacian operators
192         IF ( ln_zco ) THEN                ! z-coordinate
193            IF ( ln_dynldf_level )   nldf = 4      ! iso-level  (no rotation)
194            IF ( ln_dynldf_hor   )   nldf = 4      ! horizontal (no rotation)
195            IF ( ln_dynldf_iso   )   ierr = 2      ! isoneutral (   rotation)
196         ENDIF
197         IF ( ln_zps ) THEN             ! z-coordinate
198            IF ( ln_dynldf_level )   ierr = 1      ! iso-level not allowed
199            IF ( ln_dynldf_hor   )   nldf = 4      ! horizontal (no rotation)
200            IF ( ln_dynldf_iso   )   ierr = 2      ! isoneutral (   rotation)
201         ENDIF
202         IF ( ln_sco ) THEN             ! s-coordinate
203            IF ( ln_dynldf_level )   nldf = 4      ! iso-level  (no rotation)
204            IF ( ln_dynldf_hor   )   nldf = 5      ! horizontal (   rotation)
205            IF ( ln_dynldf_iso   )   ierr = 2      ! isoneutral (   rotation)
206         ENDIF
207      ENDIF
208
209      IF( lk_esopa )                 nldf = -1     ! esopa test
210
211      IF( ierr == 1 )   CALL ctl_stop( 'iso-level in z-coordinate - partial step, not allowed' )
212      IF( ierr == 2 )   CALL ctl_stop( 'isoneutral bilaplacian operator does not exist' )
213      IF( nldf == 1 .OR. nldf == 3 ) THEN      ! rotation
214         IF( .NOT.lk_ldfslp )   CALL ctl_stop( 'the rotation of the diffusive tensor require key_ldfslp' )
215      ENDIF
216
217      IF(lwp) THEN
218         WRITE(numout,*)
219         IF( nldf == -2 )   WRITE(numout,*) '              neither laplacian nor bilaplacian schemes used'
220         IF( nldf == -1 )   WRITE(numout,*) '              ESOPA test All scheme used'
221         IF( nldf ==  0 )   WRITE(numout,*) '              laplacian operator'
222         IF( nldf ==  1 )   WRITE(numout,*) '              rotated laplacian operator'
223         IF( nldf ==  2 )   WRITE(numout,*) '              bilaplacian operator'
224         IF( nldf ==  3 )   WRITE(numout,*) '              rotated bilaplacian'
225         IF( nldf ==  4 )   WRITE(numout,*) '              laplacian and bilaplacian operators'
226         IF( nldf ==  5 )   WRITE(numout,*) '              rotated laplacian and bilaplacian operators'
227      ENDIF
228      !
229   END SUBROUTINE dyn_ldf_init
230
231   !!======================================================================
232END MODULE dynldf
Note: See TracBrowser for help on using the repository browser.