source: branches/2013/dev_r3858_CNRS3_Ediag/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_muscl.F90 @ 3876

Last change on this file since 3876 was 3876, checked in by gm, 8 years ago

dev_r3858_CNRS3_Ediag: #927 phasing with 2011/dev_r3309_LOCEAN12_Ediag branche + mxl diag update

  • Property svn:keywords set to Id
File size: 15.9 KB
Line 
1MODULE traadv_muscl
2   !!======================================================================
3   !!                       ***  MODULE  traadv_muscl  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!======================================================================
6   !! History :       !  2000-06  (A.Estublier)  for passive tracers
7   !!                 !  2001-08  (E.Durand, G.Madec)  adapted for T & S
8   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            3.2  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
10   !!            3.4  !  2012-06  (P. Oddo, M. Vichi) include the upstream where needed
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   tra_adv_muscl : update the tracer trend with the horizontal
15   !!                   and vertical advection trends using MUSCL scheme
16   !!----------------------------------------------------------------------
17   USE oce            ! ocean dynamics and active tracers
18   USE trc_oce        ! share passive tracers/Ocean variables
19   USE dom_oce        ! ocean space and time domain
20   USE trd_oce        ! trends: ocean variables
21   USE trdtra         ! tracers trends manager
22   USE dynspg_oce     ! choice/control of key cpp for surface pressure gradient
23   USE sbcrnf          ! river runoffs
24   USE diaptr         ! poleward transport diagnostics
25   !
26   USE wrk_nemo       ! Memory Allocation
27   USE timing         ! Timing
28   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
29   USE in_out_manager ! I/O manager
30   USE lib_mpp        ! distribued memory computing
31   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
32!!gm   USE trabbl         ! tracers: bottom boundary layer
33!!gm   USE eosbn2          ! equation of state
34
35   IMPLICIT NONE
36   PRIVATE
37
38   PUBLIC   tra_adv_muscl  ! routine called by step.F90
39
40   LOGICAL  :: l_trd                        ! flag to compute trends
41   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: upsmsk !: mixed upstream/centered scheme near some straits
42   !                                                             !  and in closed seas (orca 2 and 4 configurations)
43   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: xind         !: mixed upstream/centered index
44   !! * Substitutions
45#  include "domzgr_substitute.h90"
46#  include "vectopt_loop_substitute.h90"
47   !!----------------------------------------------------------------------
48   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
49   !! $Id$
50   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
51   !!----------------------------------------------------------------------
52CONTAINS
53
54   SUBROUTINE tra_adv_muscl( kt, kit000, cdtype, p2dt, pun, pvn, pwn, &
55      &                                        ptb, pta, kjpt, ld_msc_ups )
56      !!----------------------------------------------------------------------
57      !!                    ***  ROUTINE tra_adv_muscl  ***
58      !!
59      !! ** Purpose :   Compute the now trend due to total advection of T and
60      !!      S using a MUSCL scheme (Monotone Upstream-centered Scheme for
61      !!      Conservation Laws) and add it to the general tracer trend.
62      !!
63      !! ** Method  : MUSCL scheme plus centered scheme at ocean boundaries
64      !!
65      !! ** Action  : - update (ta,sa) with the now advective tracer trends
66      !!              - save trends
67      !!
68      !! References : Estubier, A., and M. Levy, Notes Techn. Pole de Modelisation
69      !!              IPSL, Sept. 2000 (http://www.lodyc.jussieu.fr/opa)
70      !!----------------------------------------------------------------------
71      USE oce     , ONLY:   zwx   => ua    , zwy   => va          ! (ua,va) used as workspace
72      !
73      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
74      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
75      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
76      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
77      LOGICAL                              , INTENT(in   ) ::   ld_msc_ups      ! use upstream scheme within muscl
78      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
79      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
80      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb             ! before tracer field
81      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
82
83      !
84      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
85      REAL(wp) ::   zu, z0u, zzwx, zw         ! local scalars
86      REAL(wp) ::   zv, z0v, zzwy, z0w        !   -      -
87      REAL(wp) ::   ztra, zbtr, zdt, zalpha   !   -      -
88      REAL(wp), POINTER, DIMENSION(:,:,:) :: zslpx, zslpy
89      INTEGER  ::   ierr
90      !!----------------------------------------------------------------------
91      !
92      IF( nn_timing == 1 )  CALL timing_start('tra_adv_muscl')
93      !
94      CALL wrk_alloc( jpi, jpj, jpk, zslpx, zslpy )
95      !
96
97      IF( kt == kit000 )  THEN
98         IF(lwp) WRITE(numout,*)
99         IF(lwp) WRITE(numout,*) 'tra_adv : MUSCL advection scheme on ', cdtype
100         IF(lwp) WRITE(numout,*) '        : mixed up-stream           ', ld_msc_ups
101         IF(lwp) WRITE(numout,*) '~~~~~~~'
102         IF(lwp) WRITE(numout,*)
103         !
104         !
105         IF( ld_msc_ups ) THEN
106            IF( .NOT. ALLOCATED( upsmsk ) )  THEN
107                ALLOCATE( upsmsk(jpi,jpj), STAT=ierr )
108                IF( ierr /= 0 )   CALL ctl_stop('STOP', 'tra_adv_muscl: unable to allocate upsmsk array')
109            ENDIF
110            upsmsk(:,:) = 0._wp                             ! not upstream by default
111         ENDIF
112
113         IF( .NOT. ALLOCATED( xind ) ) THEN
114             ALLOCATE( xind(jpi,jpj,jpk), STAT=ierr )
115             IF( ierr /= 0 )   CALL ctl_stop('STOP', 'tra_adv_muscl: unable to allocate zind array')
116         ENDIF
117         !
118         !
119         l_trd = .FALSE.
120         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
121
122         !
123         ! Upstream / centered scheme indicator
124         ! ------------------------------------
125         xind(:,:,:) = 1._wp                             ! set equal to 1 where up-stream is not needed
126         !
127         IF( ld_msc_ups )  THEN
128            DO jk = 1, jpk
129               DO jj = 1, jpj
130                  DO ji = 1, jpi
131                     xind(ji,jj,jk) = 1  - MAX (           &
132                        rnfmsk(ji,jj) * rnfmsk_z(jk),      &  ! near runoff mouths (& closed sea outflows)
133                        upsmsk(ji,jj) ) * tmask(ji,jj,jk)     ! some of some straits
134                  END DO
135               END DO
136            END DO
137         ENDIF 
138         !
139      ENDIF 
140      !                                                     ! ===========
141      DO jn = 1, kjpt                                       ! tracer loop
142         !                                                  ! ===========
143         ! I. Horizontal advective fluxes
144         ! ------------------------------
145         ! first guess of the slopes
146         zwx(:,:,jpk) = 0.e0   ;   zwy(:,:,jpk) = 0.e0        ! bottom values
147         ! interior values
148         DO jk = 1, jpkm1
149            DO jj = 1, jpjm1     
150               DO ji = 1, fs_jpim1   ! vector opt.
151                  zwx(ji,jj,jk) = umask(ji,jj,jk) * ( ptb(ji+1,jj,jk,jn) - ptb(ji,jj,jk,jn) )
152                  zwy(ji,jj,jk) = vmask(ji,jj,jk) * ( ptb(ji,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
153               END DO
154           END DO
155         END DO
156         !
157         CALL lbc_lnk( zwx, 'U', -1. )                        ! lateral boundary conditions on zwx, zwy   (changed sign)
158         CALL lbc_lnk( zwy, 'V', -1. )
159         !                                             !-- Slopes of tracer
160         zslpx(:,:,jpk) = 0.e0   ;   zslpy(:,:,jpk) = 0.e0    ! bottom values
161         DO jk = 1, jpkm1                                     ! interior values
162            DO jj = 2, jpj
163               DO ji = fs_2, jpi   ! vector opt.
164                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji-1,jj  ,jk) )   &
165                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji-1,jj  ,jk) ) )
166                  zslpy(ji,jj,jk) =                    ( zwy(ji,jj,jk) + zwy(ji  ,jj-1,jk) )   &
167                     &            * ( 0.25 + SIGN( 0.25, zwy(ji,jj,jk) * zwy(ji  ,jj-1,jk) ) )
168               END DO
169            END DO
170         END DO
171         !
172         DO jk = 1, jpkm1                                     ! Slopes limitation
173            DO jj = 2, jpj
174               DO ji = fs_2, jpi   ! vector opt.
175                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji  ,jj,jk) ),   &
176                     &                                                 2.*ABS( zwx  (ji-1,jj,jk) ),   &
177                     &                                                 2.*ABS( zwx  (ji  ,jj,jk) ) )
178                  zslpy(ji,jj,jk) = SIGN( 1., zslpy(ji,jj,jk) ) * MIN(    ABS( zslpy(ji,jj  ,jk) ),   &
179                     &                                                 2.*ABS( zwy  (ji,jj-1,jk) ),   &
180                     &                                                 2.*ABS( zwy  (ji,jj  ,jk) ) )
181               END DO
182           END DO
183         END DO             ! interior values
184
185         !                                             !-- MUSCL horizontal advective fluxes
186         DO jk = 1, jpkm1                                     ! interior values
187            zdt  = p2dt(jk)
188            DO jj = 2, jpjm1
189               DO ji = fs_2, fs_jpim1   ! vector opt.
190                  ! MUSCL fluxes
191                  z0u = SIGN( 0.5, pun(ji,jj,jk) )
192                  zalpha = 0.5 - z0u
193                  zu  = z0u - 0.5 * pun(ji,jj,jk) * zdt / ( e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk) )
194                  zzwx = ptb(ji+1,jj,jk,jn) + xind(ji,jj,jk) * zu * zslpx(ji+1,jj,jk)
195                  zzwy = ptb(ji  ,jj,jk,jn) + xind(ji,jj,jk) * zu * zslpx(ji  ,jj,jk)
196                  zwx(ji,jj,jk) = pun(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
197                  !
198                  z0v = SIGN( 0.5, pvn(ji,jj,jk) )
199                  zalpha = 0.5 - z0v
200                  zv  = z0v - 0.5 * pvn(ji,jj,jk) * zdt / ( e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk) )
201                  zzwx = ptb(ji,jj+1,jk,jn) + xind(ji,jj,jk) * zv * zslpy(ji,jj+1,jk)
202                  zzwy = ptb(ji,jj  ,jk,jn) + xind(ji,jj,jk) * zv * zslpy(ji,jj  ,jk)
203                  zwy(ji,jj,jk) = pvn(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
204               END DO
205            END DO
206         END DO
207         !                                                    ! lateral boundary conditions on zwx, zwy   (changed sign)
208         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )
209         !
210         ! Tracer flux divergence at t-point added to the general trend
211         DO jk = 1, jpkm1
212            DO jj = 2, jpjm1     
213               DO ji = fs_2, fs_jpim1   ! vector opt.
214                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
215                  ! horizontal advective trends
216                  ztra = - zbtr * ( zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
217                  &               + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  ) )
218                  ! add it to the general tracer trends
219                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
220               END DO
221           END DO
222         END DO       
223         !                                 ! trend diagnostics (contribution of upstream fluxes)
224         IF( l_trd )  THEN
225            CALL trd_tra( kt, cdtype, jn, jptra_xad, zwx, pun, ptb(:,:,:,jn) )
226            CALL trd_tra( kt, cdtype, jn, jptra_yad, zwy, pvn, ptb(:,:,:,jn) )
227         END IF
228         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
229         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN 
230            IF( jn == jp_tem )  htr_adv(:) = ptr_vj( zwy(:,:,:) )
231            IF( jn == jp_sal )  str_adv(:) = ptr_vj( zwy(:,:,:) )
232         ENDIF
233
234         ! II. Vertical advective fluxes
235         ! -----------------------------
236         !                                             !-- first guess of the slopes
237         zwx (:,:, 1 ) = 0.e0    ;    zwx (:,:,jpk) = 0.e0    ! surface & bottom boundary conditions
238         DO jk = 2, jpkm1                                     ! interior values
239            zwx(:,:,jk) = tmask(:,:,jk) * ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) )
240         END DO
241
242         !                                             !-- Slopes of tracer
243         zslpx(:,:,1) = 0.e0                                  ! surface values
244         DO jk = 2, jpkm1                                     ! interior value
245            DO jj = 1, jpj
246               DO ji = 1, jpi
247                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji,jj,jk+1) )   &
248                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji,jj,jk+1) ) )
249               END DO
250            END DO
251         END DO
252         !                                             !-- Slopes limitation
253         DO jk = 2, jpkm1                                     ! interior values
254            DO jj = 1, jpj
255               DO ji = 1, jpi
256                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji,jj,jk  ) ),   &
257                     &                                                 2.*ABS( zwx  (ji,jj,jk+1) ),   &
258                     &                                                 2.*ABS( zwx  (ji,jj,jk  ) )  )
259               END DO
260            END DO
261         END DO
262         !                                             !-- vertical advective flux
263         !                                                    ! surface values  (bottom already set to zero)
264         IF( lk_vvl ) THEN    ;   zwx(:,:, 1 ) = 0.e0                      !  variable volume
265         ELSE                 ;   zwx(:,:, 1 ) = pwn(:,:,1) * ptb(:,:,1,jn)   ! linear free surface
266         ENDIF 
267         !
268         DO jk = 1, jpkm1                                     ! interior values
269            zdt  = p2dt(jk)
270            DO jj = 2, jpjm1     
271               DO ji = fs_2, fs_jpim1   ! vector opt.
272                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3w(ji,jj,jk+1) )
273                  z0w = SIGN( 0.5, pwn(ji,jj,jk+1) )
274                  zalpha = 0.5 + z0w
275                  zw  = z0w - 0.5 * pwn(ji,jj,jk+1) * zdt * zbtr 
276                  zzwx = ptb(ji,jj,jk+1,jn) + xind(ji,jj,jk) * zw * zslpx(ji,jj,jk+1)
277                  zzwy = ptb(ji,jj,jk  ,jn) + xind(ji,jj,jk) * zw * zslpx(ji,jj,jk  )
278                  zwx(ji,jj,jk+1) = pwn(ji,jj,jk+1) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
279               END DO
280            END DO
281         END DO
282
283         ! Compute & add the vertical advective trend
284         DO jk = 1, jpkm1
285            DO jj = 2, jpjm1     
286               DO ji = fs_2, fs_jpim1   ! vector opt.
287                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
288                  ! vertical advective trends
289                  ztra = - zbtr * ( zwx(ji,jj,jk) - zwx(ji,jj,jk+1) )
290                  ! add it to the general tracer trends
291                  pta(ji,jj,jk,jn) =  pta(ji,jj,jk,jn) + ztra
292               END DO
293            END DO
294         END DO
295         !                                 ! Save the vertical advective trends for diagnostic
296         IF( l_trd ) CALL trd_tra( kt, cdtype, jn, jptra_zad, zwx, pwn, ptb(:,:,:,jn) )
297         !
298      ENDDO
299      !
300      CALL wrk_dealloc( jpi, jpj, jpk, zslpx, zslpy )
301      !
302      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_muscl')
303      !
304   END SUBROUTINE tra_adv_muscl
305
306   !!======================================================================
307END MODULE traadv_muscl
Note: See TracBrowser for help on using the repository browser.