source: branches/2013/dev_r3858_CNRS3_Ediag/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_tvd.F90 @ 3876

Last change on this file since 3876 was 3876, checked in by gm, 8 years ago

dev_r3858_CNRS3_Ediag: #927 phasing with 2011/dev_r3309_LOCEAN12_Ediag branche + mxl diag update

  • Property svn:keywords set to Id
File size: 17.9 KB
Line 
1MODULE traadv_tvd
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_tvd  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!==============================================================================
6   !! History :  OPA  !  1995-12  (L. Mortier)  Original code
7   !!                 !  2000-01  (H. Loukos)  adapted to ORCA
8   !!                 !  2000-10  (MA Foujols E.Kestenare)  include file not routine
9   !!                 !  2000-12  (E. Kestenare M. Levy)  fix bug in trtrd indexes
10   !!                 !  2001-07  (E. Durand G. Madec)  adaptation to ORCA config
11   !!            8.5  !  2002-06  (G. Madec)  F90: Free form and module
12   !!    NEMO    1.0  !  2004-01  (A. de Miranda, G. Madec, J.M. Molines ): advective bbl
13   !!            2.0  !  2008-04  (S. Cravatte) add the i-, j- & k- trends computation
14   !!             -   !  2009-11  (V. Garnier) Surface pressure gradient organization
15   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
16   !!----------------------------------------------------------------------
17
18   !!----------------------------------------------------------------------
19   !!   tra_adv_tvd   : update the tracer trend with the 3D advection trends using a TVD scheme
20   !!   nonosc        : compute monotonic tracer fluxes by a non-oscillatory algorithm
21   !!----------------------------------------------------------------------
22   USE oce            ! ocean dynamics and active tracers
23   USE dom_oce        ! ocean space and time domain
24   USE trc_oce        ! share passive tracers/Ocean variables
25   USE trd_oce        ! trends: ocean variables
26   USE trdtra         ! tracers trends
27   USE dynspg_oce     ! choice/control of key cpp for surface pressure gradient
28   USE diaptr         ! poleward transport diagnostics
29   !
30   USE lib_mpp        ! MPP library
31   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
32   USE in_out_manager ! I/O manager
33   USE wrk_nemo       ! Memory Allocation
34   USE timing         ! Timing
35   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
36
37   IMPLICIT NONE
38   PRIVATE
39
40   PUBLIC   tra_adv_tvd    ! routine called by step.F90
41
42   LOGICAL ::   l_trd   ! flag to compute trends
43
44   !! * Substitutions
45#  include "domzgr_substitute.h90"
46#  include "vectopt_loop_substitute.h90"
47   !!----------------------------------------------------------------------
48   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
49   !! $Id$
50   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
51   !!----------------------------------------------------------------------
52CONTAINS
53
54   SUBROUTINE tra_adv_tvd ( kt, kit000, cdtype, p2dt, pun, pvn, pwn,      &
55      &                                       ptb, ptn, pta, kjpt )
56      !!----------------------------------------------------------------------
57      !!                  ***  ROUTINE tra_adv_tvd  ***
58      !!
59      !! **  Purpose :   Compute the now trend due to total advection of
60      !!       tracers and add it to the general trend of tracer equations
61      !!
62      !! **  Method  :   TVD scheme, i.e. 2nd order centered scheme with
63      !!       corrected flux (monotonic correction)
64      !!       note: - this advection scheme needs a leap-frog time scheme
65      !!
66      !! ** Action : - update (pta) with the now advective tracer trends
67      !!             - save the trends
68      !!----------------------------------------------------------------------
69      USE oce     , ONLY:   zwx => ua        , zwy => va          ! (ua,va) used as workspace
70      !
71      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
72      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
73      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
74      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
75      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
76      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
77      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
78      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
79      !
80      INTEGER  ::   ji, jj, jk, jn           ! dummy loop indices 
81      REAL(wp) ::   z2dtt, zbtr, ztra        ! local scalar
82      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk   !   -      -
83      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk   !   -      -
84      REAL(wp), POINTER, DIMENSION(:,:,:) :: zwi, zwz
85      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdx, ztrdy, ztrdz
86      !!----------------------------------------------------------------------
87      !
88      IF( nn_timing == 1 )  CALL timing_start('tra_adv_tvd')
89      !
90      CALL wrk_alloc( jpi, jpj, jpk, zwi, zwz )
91      !
92      IF( kt == kit000 )  THEN
93         IF(lwp) WRITE(numout,*)
94         IF(lwp) WRITE(numout,*) 'tra_adv_tvd : TVD advection scheme on ', cdtype
95         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
96         !
97         l_trd = .FALSE.
98         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
99      ENDIF
100      !
101      IF( l_trd )  THEN
102         CALL wrk_alloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
103         ztrdx(:,:,:) = 0.e0   ;    ztrdy(:,:,:) = 0.e0   ;   ztrdz(:,:,:) = 0.e0
104      ENDIF
105      !
106      zwi(:,:,:) = 0.e0
107      !
108      !                                                          ! ===========
109      DO jn = 1, kjpt                                            ! tracer loop
110         !                                                       ! ===========
111         ! 1. Bottom value : flux set to zero
112         ! ----------------------------------
113         zwx(:,:,jpk) = 0.e0    ;    zwz(:,:,jpk) = 0.e0
114         zwy(:,:,jpk) = 0.e0    ;    zwi(:,:,jpk) = 0.e0
115
116         ! 2. upstream advection with initial mass fluxes & intermediate update
117         ! --------------------------------------------------------------------
118         ! upstream tracer flux in the i and j direction
119         DO jk = 1, jpkm1
120            DO jj = 1, jpjm1
121               DO ji = 1, fs_jpim1   ! vector opt.
122                  ! upstream scheme
123                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
124                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
125                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
126                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
127                  zwx(ji,jj,jk) = 0.5 * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
128                  zwy(ji,jj,jk) = 0.5 * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
129               END DO
130            END DO
131         END DO
132
133         ! upstream tracer flux in the k direction
134         ! Surface value
135         IF( lk_vvl ) THEN   ;   zwz(:,:, 1 ) = 0.e0                         ! volume variable
136         ELSE                ;   zwz(:,:, 1 ) = pwn(:,:,1) * ptb(:,:,1,jn)   ! linear free surface
137         ENDIF
138         ! Interior value
139         DO jk = 2, jpkm1
140            DO jj = 1, jpj
141               DO ji = 1, jpi
142                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
143                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
144                  zwz(ji,jj,jk) = 0.5 * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) )
145               END DO
146            END DO
147         END DO
148
149         ! total advective trend
150         DO jk = 1, jpkm1
151            z2dtt = p2dt(jk)
152            DO jj = 2, jpjm1
153               DO ji = fs_2, fs_jpim1   ! vector opt.
154                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
155                  ! total intermediate advective trends
156                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
157                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
158                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
159                  ! update and guess with monotonic sheme
160                  pta(ji,jj,jk,jn) =   pta(ji,jj,jk,jn)         + ztra
161                  zwi(ji,jj,jk)    = ( ptb(ji,jj,jk,jn) + z2dtt * ztra ) * tmask(ji,jj,jk)
162               END DO
163            END DO
164         END DO
165         !                             ! Lateral boundary conditions on zwi  (unchanged sign)
166         CALL lbc_lnk( zwi, 'T', 1. ) 
167
168         !                                 ! trend diagnostics (contribution of upstream fluxes)
169         IF( l_trd )  THEN 
170            ! store intermediate advective trends
171            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
172         END IF
173         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
174         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN 
175           IF( jn == jp_tem )  htr_adv(:) = ptr_vj( zwy(:,:,:) )
176           IF( jn == jp_sal )  str_adv(:) = ptr_vj( zwy(:,:,:) )
177         ENDIF
178
179         ! 3. antidiffusive flux : high order minus low order
180         ! --------------------------------------------------
181         ! antidiffusive flux on i and j
182         DO jk = 1, jpkm1
183            DO jj = 1, jpjm1
184               DO ji = 1, fs_jpim1   ! vector opt.
185                  zwx(ji,jj,jk) = 0.5 * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) ) - zwx(ji,jj,jk)
186                  zwy(ji,jj,jk) = 0.5 * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) ) - zwy(ji,jj,jk)
187               END DO
188            END DO
189         END DO
190     
191         ! antidiffusive flux on k
192         zwz(:,:,1) = 0.e0         ! Surface value
193         !
194         DO jk = 2, jpkm1          ! Interior value
195            DO jj = 1, jpj
196               DO ji = 1, jpi
197                  zwz(ji,jj,jk) = 0.5 * pwn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj,jk-1,jn) ) - zwz(ji,jj,jk)
198               END DO
199            END DO
200         END DO
201         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
202         CALL lbc_lnk( zwz, 'W',  1. )
203
204         ! 4. monotonicity algorithm
205         ! -------------------------
206         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
207
208
209         ! 5. final trend with corrected fluxes
210         ! ------------------------------------
211         DO jk = 1, jpkm1
212            DO jj = 2, jpjm1
213               DO ji = fs_2, fs_jpim1   ! vector opt. 
214                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
215                  ! total advective trends
216                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
217                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
218                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
219                  ! add them to the general tracer trends
220                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
221               END DO
222            END DO
223         END DO
224
225         !                                 ! trend diagnostics (contribution of upstream fluxes)
226         IF( l_trd )  THEN
227            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
228            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
229            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
230           
231            CALL trd_tra( kt, cdtype, jn, jptra_xad, ztrdx, pun, ptn(:,:,:,jn) )   
232            CALL trd_tra( kt, cdtype, jn, jptra_yad, ztrdy, pvn, ptn(:,:,:,jn) ) 
233            CALL trd_tra( kt, cdtype, jn, jptra_zad, ztrdz, pwn, ptn(:,:,:,jn) ) 
234         END IF
235         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
236         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN 
237           IF( jn == jp_tem )  htr_adv(:) = ptr_vj( zwy(:,:,:) ) + htr_adv(:)
238           IF( jn == jp_sal )  str_adv(:) = ptr_vj( zwy(:,:,:) ) + str_adv(:)
239         ENDIF
240         !
241      END DO
242      !
243                   CALL wrk_dealloc( jpi, jpj, jpk, zwi, zwz )
244      IF( l_trd )  CALL wrk_dealloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
245      !
246      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_tvd')
247      !
248   END SUBROUTINE tra_adv_tvd
249
250
251   SUBROUTINE nonosc( pbef, paa, pbb, pcc, paft, p2dt )
252      !!---------------------------------------------------------------------
253      !!                    ***  ROUTINE nonosc  ***
254      !!     
255      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
256      !!       scheme and the before field by a nonoscillatory algorithm
257      !!
258      !! **  Method  :   ... ???
259      !!       warning : pbef and paft must be masked, but the boundaries
260      !!       conditions on the fluxes are not necessary zalezak (1979)
261      !!       drange (1995) multi-dimensional forward-in-time and upstream-
262      !!       in-space based differencing for fluid
263      !!----------------------------------------------------------------------
264      !
265      !!----------------------------------------------------------------------
266      REAL(wp), DIMENSION(jpk)         , INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
267      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(in   ) ::   pbef, paft      ! before & after field
268      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
269      !
270      INTEGER ::   ji, jj, jk   ! dummy loop indices
271      INTEGER ::   ikm1         ! local integer
272      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn, z2dtt   ! local scalars
273      REAL(wp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
274      REAL(wp), POINTER, DIMENSION(:,:,:) :: zbetup, zbetdo, zbup, zbdo
275      !!----------------------------------------------------------------------
276      !
277      IF( nn_timing == 1 )  CALL timing_start('nonosc')
278      !
279      CALL wrk_alloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
280      !
281
282      zbig  = 1.e+40_wp
283      zrtrn = 1.e-15_wp
284      zbetup(:,:,jpk) = 0._wp   ;   zbetdo(:,:,jpk) = 0._wp
285
286
287      ! Search local extrema
288      ! --------------------
289      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
290      zbup = MAX( pbef * tmask - zbig * ( 1.e0 - tmask ),   &
291         &        paft * tmask - zbig * ( 1.e0 - tmask )  )
292      zbdo = MIN( pbef * tmask + zbig * ( 1.e0 - tmask ),   &
293         &        paft * tmask + zbig * ( 1.e0 - tmask )  )
294
295      DO jk = 1, jpkm1
296         ikm1 = MAX(jk-1,1)
297         z2dtt = p2dt(jk)
298         DO jj = 2, jpjm1
299            DO ji = fs_2, fs_jpim1   ! vector opt.
300
301               ! search maximum in neighbourhood
302               zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
303                  &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
304                  &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
305                  &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
306
307               ! search minimum in neighbourhood
308               zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
309                  &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
310                  &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
311                  &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
312
313               ! positive part of the flux
314               zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
315                  & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
316                  & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
317
318               ! negative part of the flux
319               zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
320                  & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
321                  & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
322
323               ! up & down beta terms
324               zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) / z2dtt
325               zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
326               zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
327            END DO
328         END DO
329      END DO
330      CALL lbc_lnk( zbetup, 'T', 1. )   ;   CALL lbc_lnk( zbetdo, 'T', 1. )   ! lateral boundary cond. (unchanged sign)
331
332      ! 3. monotonic flux in the i & j direction (paa & pbb)
333      ! ----------------------------------------
334      DO jk = 1, jpkm1
335         DO jj = 2, jpjm1
336            DO ji = fs_2, fs_jpim1   ! vector opt.
337               zau = MIN( 1.e0, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
338               zbu = MIN( 1.e0, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
339               zcu =       ( 0.5  + SIGN( 0.5 , paa(ji,jj,jk) ) )
340               paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1.e0 - zcu) * zbu )
341
342               zav = MIN( 1.e0, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
343               zbv = MIN( 1.e0, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
344               zcv =       ( 0.5  + SIGN( 0.5 , pbb(ji,jj,jk) ) )
345               pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1.e0 - zcv) * zbv )
346
347      ! monotonic flux in the k direction, i.e. pcc
348      ! -------------------------------------------
349               za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
350               zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
351               zc =       ( 0.5  + SIGN( 0.5 , pcc(ji,jj,jk+1) ) )
352               pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1.e0 - zc) * zb )
353            END DO
354         END DO
355      END DO
356      CALL lbc_lnk( paa, 'U', -1. )   ;   CALL lbc_lnk( pbb, 'V', -1. )   ! lateral boundary condition (changed sign)
357      !
358      CALL wrk_dealloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
359      !
360      IF( nn_timing == 1 )  CALL timing_stop('nonosc')
361      !
362   END SUBROUTINE nonosc
363
364   !!======================================================================
365END MODULE traadv_tvd
Note: See TracBrowser for help on using the repository browser.