source: branches/2013/dev_r3858_NOC_ZTC/NEMOGCM/NEMO/OPA_SRC/BDY/bdydta.F90 @ 4254

Last change on this file since 4254 was 4254, checked in by acc, 8 years ago

Branch 2013/dev_r3858_NOC_ZTC, #863. Merge in final changes from the dev_r3867_MERCATOR1_DYN branch; mainly AGRIF and BDY compatibility

  • Property svn:keywords set to Id
File size: 35.7 KB
Line 
1MODULE bdydta
2   !!======================================================================
3   !!                       ***  MODULE bdydta  ***
4   !! Open boundary data : read the data for the unstructured open boundaries.
5   !!======================================================================
6   !! History :  1.0  !  2005-01  (J. Chanut, A. Sellar)  Original code
7   !!             -   !  2007-01  (D. Storkey) Update to use IOM module
8   !!             -   !  2007-07  (D. Storkey) add bdy_dta_fla
9   !!            3.0  !  2008-04  (NEMO team)  add in the reference version
10   !!            3.3  !  2010-09  (E.O'Dea) modifications for Shelf configurations
11   !!            3.3  !  2010-09  (D.Storkey) add ice boundary conditions
12   !!            3.4  !  2011     (D. Storkey) rewrite in preparation for OBC-BDY merge
13   !!----------------------------------------------------------------------
14#if defined key_bdy
15   !!----------------------------------------------------------------------
16   !!   'key_bdy'                     Open Boundary Conditions
17   !!----------------------------------------------------------------------
18   !!    bdy_dta        : read external data along open boundaries from file
19   !!    bdy_dta_init   : initialise arrays etc for reading of external data
20   !!----------------------------------------------------------------------
21   USE wrk_nemo        ! Memory Allocation
22   USE timing          ! Timing
23   USE oce             ! ocean dynamics and tracers
24   USE dom_oce         ! ocean space and time domain
25   USE phycst          ! physical constants
26   USE bdy_oce         ! ocean open boundary conditions 
27   USE bdytides        ! tidal forcing at boundaries
28   USE fldread         ! read input fields
29   USE iom             ! IOM library
30   USE in_out_manager  ! I/O logical units
31   USE dynspg_oce, ONLY: lk_dynspg_ts ! Split-explicit free surface flag
32#if defined key_lim2
33   USE ice_2
34#endif
35   USE sbcapr
36
37   IMPLICIT NONE
38   PRIVATE
39
40   PUBLIC   bdy_dta          ! routine called by step.F90 and dynspg_ts.F90
41   PUBLIC   bdy_dta_init     ! routine called by nemogcm.F90
42
43   INTEGER, ALLOCATABLE, DIMENSION(:)   ::   nb_bdy_fld        ! Number of fields to update for each boundary set.
44   INTEGER                              ::   nb_bdy_fld_sum    ! Total number of fields to update for all boundary sets.
45
46   LOGICAL,           DIMENSION(jp_bdy) ::   ln_full_vel_array ! =T => full velocities in 3D boundary conditions
47                                                               ! =F => baroclinic velocities in 3D boundary conditions
48
49   TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:), TARGET ::   bf        ! structure of input fields (file informations, fields read)
50
51   TYPE(MAP_POINTER), ALLOCATABLE, DIMENSION(:) :: nbmap_ptr   ! array of pointers to nbmap
52
53#  include "domzgr_substitute.h90"
54   !!----------------------------------------------------------------------
55   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
56   !! $Id$
57   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
58   !!----------------------------------------------------------------------
59CONTAINS
60
61      SUBROUTINE bdy_dta( kt, jit, time_offset )
62      !!----------------------------------------------------------------------
63      !!                   ***  SUBROUTINE bdy_dta  ***
64      !!                   
65      !! ** Purpose :   Update external data for open boundary conditions
66      !!
67      !! ** Method  :   Use fldread.F90
68      !!               
69      !!----------------------------------------------------------------------
70      !!
71      INTEGER, INTENT( in )           ::   kt    ! ocean time-step index
72      INTEGER, INTENT( in ), OPTIONAL ::   jit   ! subcycle time-step index (for timesplitting option)
73      INTEGER, INTENT( in ), OPTIONAL ::   time_offset  ! time offset in units of timesteps. NB. if jit
74                                                        ! is present then units = subcycle timesteps.
75                                                        ! time_offset = 0 => get data at "now" time level
76                                                        ! time_offset = -1 => get data at "before" time level
77                                                        ! time_offset = +1 => get data at "after" time level
78                                                        ! etc.
79      !!
80      INTEGER     ::  ib_bdy, jfld, jstart, jend, ib, ii, ij, ik, igrd  ! local indices
81      INTEGER,          DIMENSION(jpbgrd) ::   ilen1 
82      INTEGER, POINTER, DIMENSION(:)      ::   nblen, nblenrim  ! short cuts
83      TYPE(OBC_DATA), POINTER             ::   dta              ! short cut
84      !!
85      !!---------------------------------------------------------------------------
86      !!
87      IF( nn_timing == 1 ) CALL timing_start('bdy_dta')
88
89      ! Initialise data arrays once for all from initial conditions where required
90      !---------------------------------------------------------------------------
91      IF( kt .eq. nit000 .and. .not. PRESENT(jit) ) THEN
92
93         ! Calculate depth-mean currents
94         !-----------------------------
95         CALL wrk_alloc(jpi,jpj,pun2d,pvn2d) 
96
97         pun2d(:,:) = 0.e0
98         pvn2d(:,:) = 0.e0
99         DO ik = 1, jpkm1   !! Vertically integrated momentum trends
100             pun2d(:,:) = pun2d(:,:) + fse3u(:,:,ik) * umask(:,:,ik) * un(:,:,ik)
101             pvn2d(:,:) = pvn2d(:,:) + fse3v(:,:,ik) * vmask(:,:,ik) * vn(:,:,ik)
102         END DO
103         pun2d(:,:) = pun2d(:,:) * hur(:,:)
104         pvn2d(:,:) = pvn2d(:,:) * hvr(:,:)
105         
106         DO ib_bdy = 1, nb_bdy
107
108            nblen => idx_bdy(ib_bdy)%nblen
109            nblenrim => idx_bdy(ib_bdy)%nblenrim
110            dta => dta_bdy(ib_bdy)
111
112            IF( nn_dyn2d_dta(ib_bdy) .eq. 0 ) THEN
113               ilen1(:) = nblen(:)
114               IF( dta%ll_ssh ) THEN
115                  igrd = 1
116                  DO ib = 1, ilen1(igrd)
117                     ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
118                     ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
119                     dta_bdy(ib_bdy)%ssh(ib) = sshn(ii,ij) * tmask(ii,ij,1)         
120                  END DO
121               END IF
122               IF( dta%ll_u2d ) THEN
123                  igrd = 2
124                  DO ib = 1, ilen1(igrd)
125                     ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
126                     ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
127                     dta_bdy(ib_bdy)%u2d(ib) = pun2d(ii,ij) * umask(ii,ij,1)         
128                  END DO
129               END IF
130               IF( dta%ll_v2d ) THEN
131                  igrd = 3
132                  DO ib = 1, ilen1(igrd)
133                     ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
134                     ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
135                     dta_bdy(ib_bdy)%v2d(ib) = pvn2d(ii,ij) * vmask(ii,ij,1)         
136                  END DO
137               END IF
138            ENDIF
139
140            IF( nn_dyn3d_dta(ib_bdy) .eq. 0 ) THEN
141               ilen1(:) = nblen(:)
142               IF( dta%ll_u3d ) THEN
143                  igrd = 2 
144                  DO ib = 1, ilen1(igrd)
145                     DO ik = 1, jpkm1
146                        ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
147                        ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
148                        dta_bdy(ib_bdy)%u3d(ib,ik) =  ( un(ii,ij,ik) - pun2d(ii,ij) ) * umask(ii,ij,ik)         
149                     END DO
150                  END DO
151               END IF
152               IF( dta%ll_v3d ) THEN
153                  igrd = 3 
154                  DO ib = 1, ilen1(igrd)
155                     DO ik = 1, jpkm1
156                        ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
157                        ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
158                        dta_bdy(ib_bdy)%v3d(ib,ik) =  ( vn(ii,ij,ik) - pvn2d(ii,ij) ) * vmask(ii,ij,ik)         
159                        END DO
160                  END DO
161               END IF
162            ENDIF
163
164            IF( nn_tra_dta(ib_bdy) .eq. 0 ) THEN
165               ilen1(:) = nblen(:)
166               IF( dta%ll_tem ) THEN
167                  igrd = 1 
168                  DO ib = 1, ilen1(igrd)
169                     DO ik = 1, jpkm1
170                        ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
171                        ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
172                        dta_bdy(ib_bdy)%tem(ib,ik) = tsn(ii,ij,ik,jp_tem) * tmask(ii,ij,ik)         
173                     END DO
174                  END DO
175               END IF
176               IF( dta%ll_sal ) THEN
177                  igrd = 1 
178                  DO ib = 1, ilen1(igrd)
179                     DO ik = 1, jpkm1
180                        ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
181                        ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
182                        dta_bdy(ib_bdy)%sal(ib,ik) = tsn(ii,ij,ik,jp_sal) * tmask(ii,ij,ik)         
183                     END DO
184                  END DO
185               END IF
186            ENDIF
187
188#if defined key_lim2
189            IF( nn_ice_lim2_dta(ib_bdy) .eq. 0 ) THEN
190               ilen1(:) = nblen(:)
191               IF( dta%ll_frld ) THEN
192                  igrd = 1 
193                  DO ib = 1, ilen1(igrd)
194                     ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
195                     ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
196                     dta_bdy(ib_bdy)%frld(ib) = frld(ii,ij) * tmask(ii,ij,1)         
197                  END DO
198               END IF
199               IF( dta%ll_hicif ) THEN
200                  igrd = 1 
201                  DO ib = 1, ilen1(igrd)
202                     ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
203                     ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
204                     dta_bdy(ib_bdy)%hicif(ib) = hicif(ii,ij) * tmask(ii,ij,1)         
205                  END DO
206               END IF
207               IF( dta%ll_hsnif ) THEN
208                  igrd = 1 
209                  DO ib = 1, ilen1(igrd)
210                     ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
211                     ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
212                     dta_bdy(ib_bdy)%hsnif(ib) = hsnif(ii,ij) * tmask(ii,ij,1)         
213                  END DO
214               END IF
215            ENDIF
216#endif
217
218         ENDDO ! ib_bdy
219
220         CALL wrk_dealloc(jpi,jpj,pun2d,pvn2d) 
221
222      ENDIF ! kt .eq. nit000
223
224      ! update external data from files
225      !--------------------------------
226     
227      jstart = 1
228      DO ib_bdy = 1, nb_bdy   
229         dta => dta_bdy(ib_bdy)
230         IF( nn_dta(ib_bdy) .eq. 1 ) THEN ! skip this bit if no external data required
231     
232            IF( PRESENT(jit) ) THEN
233               ! Update barotropic boundary conditions only
234               ! jit is optional argument for fld_read and bdytide_update
235               IF( cn_dyn2d(ib_bdy) /= 'none' ) THEN
236                  IF( nn_dyn2d_dta(ib_bdy) .eq. 2 ) THEN ! tidal harmonic forcing ONLY: initialise arrays
237                     IF( dta%ll_ssh ) dta%ssh(:) = 0.0
238                     IF( dta%ll_u2d ) dta%u2d(:) = 0.0
239                     IF( dta%ll_u3d ) dta%v2d(:) = 0.0
240                  ENDIF
241                  IF (cn_tra(ib_bdy) /= 'runoff') THEN
242                     IF( nn_dyn2d_dta(ib_bdy) .EQ. 1 .OR. nn_dyn2d_dta(ib_bdy) .EQ. 3 ) THEN
243
244                        jend = jstart + dta%nread(2) - 1
245                        CALL fld_read( kt=kt, kn_fsbc=1, sd=bf(jstart:jend), map=nbmap_ptr(jstart:jend),  &
246                                     & kit=jit, kt_offset=time_offset )
247
248                        ! If full velocities in boundary data then extract barotropic velocities from 3D fields
249                        IF( ln_full_vel_array(ib_bdy) .AND.                                             &
250                          &    ( nn_dyn2d_dta(ib_bdy) .EQ. 1 .OR. nn_dyn2d_dta(ib_bdy) .EQ. 3 .OR.  &
251                          &      nn_dyn3d_dta(ib_bdy) .EQ. 1 ) )THEN
252
253                           igrd = 2                      ! zonal velocity
254                           dta%u2d(:) = 0.0
255                           DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
256                              ii   = idx_bdy(ib_bdy)%nbi(ib,igrd)
257                              ij   = idx_bdy(ib_bdy)%nbj(ib,igrd)
258                              DO ik = 1, jpkm1
259                                 dta%u2d(ib) = dta%u2d(ib) &
260                       &                          + fse3u(ii,ij,ik) * umask(ii,ij,ik) * dta%u3d(ib,ik)
261                              END DO
262                              dta%u2d(ib) =  dta%u2d(ib) * hur(ii,ij)
263                           END DO
264                           igrd = 3                      ! meridional velocity
265                           dta%v2d(:) = 0.0
266                           DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
267                              ii   = idx_bdy(ib_bdy)%nbi(ib,igrd)
268                              ij   = idx_bdy(ib_bdy)%nbj(ib,igrd)
269                              DO ik = 1, jpkm1
270                                 dta%v2d(ib) = dta%v2d(ib) &
271                       &                       + fse3v(ii,ij,ik) * vmask(ii,ij,ik) * dta%v3d(ib,ik)
272                              END DO
273                              dta%v2d(ib) =  dta%v2d(ib) * hvr(ii,ij)
274                           END DO
275                        ENDIF                   
276                     ENDIF
277                     IF( nn_dyn2d_dta(ib_bdy) .ge. 2 ) THEN ! update tidal harmonic forcing
278                        CALL bdytide_update( kt=kt, idx=idx_bdy(ib_bdy), dta=dta, td=tides(ib_bdy),   & 
279                          &                 jit=jit, time_offset=time_offset )
280                     ENDIF
281                  ENDIF
282               ENDIF
283            ELSE
284               IF (cn_tra(ib_bdy) == 'runoff') then      ! runoff condition
285                  jend = nb_bdy_fld(ib_bdy)
286                  CALL fld_read( kt=kt, kn_fsbc=1, sd=bf(jstart:jend),  &
287                               & map=nbmap_ptr(jstart:jend), kt_offset=time_offset )
288                  !
289                  igrd = 2                      ! zonal velocity
290                  DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
291                     ii   = idx_bdy(ib_bdy)%nbi(ib,igrd)
292                     ij   = idx_bdy(ib_bdy)%nbj(ib,igrd)
293                     dta%u2d(ib) = dta%u2d(ib) / ( e2u(ii,ij) * hu_0(ii,ij) )
294                  END DO
295                  !
296                  igrd = 3                      ! meridional velocity
297                  DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
298                     ii   = idx_bdy(ib_bdy)%nbi(ib,igrd)
299                     ij   = idx_bdy(ib_bdy)%nbj(ib,igrd)
300                     dta%v2d(ib) = dta%v2d(ib) / ( e1v(ii,ij) * hv_0(ii,ij) )
301                  END DO
302               ELSE
303                  IF( nn_dyn2d_dta(ib_bdy) .eq. 2 ) THEN ! tidal harmonic forcing ONLY: initialise arrays
304                     IF( dta%ll_ssh ) dta%ssh(:) = 0.0
305                     IF( dta%ll_u2d ) dta%u2d(:) = 0.0
306                     IF( dta%ll_v2d ) dta%v2d(:) = 0.0
307                  ENDIF
308                  IF( dta%nread(1) .gt. 0 ) THEN ! update external data
309                     jend = jstart + dta%nread(1) - 1
310                     CALL fld_read( kt=kt, kn_fsbc=1, sd=bf(jstart:jend), &
311                                  & map=nbmap_ptr(jstart:jend), kt_offset=time_offset )
312                  ENDIF
313                  ! If full velocities in boundary data then split into barotropic and baroclinic data
314                  IF( ln_full_vel_array(ib_bdy) .and.                                             &
315                    & ( nn_dyn2d_dta(ib_bdy) .EQ. 1 .OR. nn_dyn2d_dta(ib_bdy) .EQ. 3 .OR. &
316                    &   nn_dyn3d_dta(ib_bdy) .EQ. 1 ) ) THEN
317                     igrd = 2                      ! zonal velocity
318                     dta%u2d(:) = 0.0
319                     DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
320                        ii   = idx_bdy(ib_bdy)%nbi(ib,igrd)
321                        ij   = idx_bdy(ib_bdy)%nbj(ib,igrd)
322                        DO ik = 1, jpkm1
323                           dta%u2d(ib) = dta%u2d(ib) &
324                 &                       + fse3u(ii,ij,ik) * umask(ii,ij,ik) * dta%u3d(ib,ik)
325                        END DO
326                        dta%u2d(ib) =  dta%u2d(ib) * hur(ii,ij)
327                        DO ik = 1, jpkm1
328                           dta%u3d(ib,ik) = dta%u3d(ib,ik) - dta%u2d(ib)
329                        END DO
330                     END DO
331                     igrd = 3                      ! meridional velocity
332                     dta%v2d(:) = 0.0
333                     DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
334                        ii   = idx_bdy(ib_bdy)%nbi(ib,igrd)
335                        ij   = idx_bdy(ib_bdy)%nbj(ib,igrd)
336                        DO ik = 1, jpkm1
337                           dta%v2d(ib) = dta%v2d(ib) &
338                 &                       + fse3v(ii,ij,ik) * vmask(ii,ij,ik) * dta%v3d(ib,ik)
339                        END DO
340                        dta%v2d(ib) =  dta%v2d(ib) * hvr(ii,ij)
341                        DO ik = 1, jpkm1
342                           dta%v3d(ib,ik) = dta%v3d(ib,ik) - dta%v2d(ib)
343                        END DO
344                     END DO
345                  ENDIF
346
347               ENDIF
348            ENDIF
349            jstart = jstart + dta%nread(1)
350         END IF ! nn_dta(ib_bdy) = 1
351      END DO  ! ib_bdy
352
353      ! bg jchanut tschanges
354#if defined key_tide
355      ! Add tides if not split-explicit free surface else this is done in ts loop
356      IF (.NOT.lk_dynspg_ts) CALL bdy_dta_tides( kt=kt, time_offset=time_offset )
357#endif
358      ! end jchanut tschanges
359
360      IF ( ln_apr_obc ) THEN
361         DO ib_bdy = 1, nb_bdy
362            IF (cn_tra(ib_bdy) /= 'runoff')THEN
363               igrd = 1                      ! meridional velocity
364               DO ib = 1, idx_bdy(ib_bdy)%nblenrim(igrd)
365                  ii   = idx_bdy(ib_bdy)%nbi(ib,igrd)
366                  ij   = idx_bdy(ib_bdy)%nbj(ib,igrd)
367                  dta_bdy(ib_bdy)%ssh(ib) = dta_bdy(ib_bdy)%ssh(ib) + ssh_ib(ii,ij)
368               ENDDO
369            ENDIF
370         ENDDO
371      ENDIF
372
373      IF( nn_timing == 1 ) CALL timing_stop('bdy_dta')
374
375      END SUBROUTINE bdy_dta
376
377
378      SUBROUTINE bdy_dta_init
379      !!----------------------------------------------------------------------
380      !!                   ***  SUBROUTINE bdy_dta_init  ***
381      !!                   
382      !! ** Purpose :   Initialise arrays for reading of external data
383      !!                for open boundary conditions
384      !!
385      !! ** Method  :   
386      !!               
387      !!----------------------------------------------------------------------
388      USE dynspg_oce, ONLY: lk_dynspg_ts
389      !!
390      INTEGER     ::  ib_bdy, jfld, jstart, jend, ierror  ! local indices
391      !!
392      CHARACTER(len=100)                     ::   cn_dir        ! Root directory for location of data files
393      CHARACTER(len=100), DIMENSION(nb_bdy)  ::   cn_dir_array  ! Root directory for location of data files
394      LOGICAL                                ::   ln_full_vel   ! =T => full velocities in 3D boundary data
395                                                                ! =F => baroclinic velocities in 3D boundary data
396      INTEGER                                ::   ilen_global   ! Max length required for global bdy dta arrays
397      INTEGER, ALLOCATABLE, DIMENSION(:)     ::   ilen1, ilen3  ! size of 1st and 3rd dimensions of local arrays
398      INTEGER, ALLOCATABLE, DIMENSION(:)     ::   ibdy           ! bdy set for a particular jfld
399      INTEGER, ALLOCATABLE, DIMENSION(:)     ::   igrid         ! index for grid type (1,2,3 = T,U,V)
400      INTEGER, POINTER, DIMENSION(:)         ::   nblen, nblenrim  ! short cuts
401      TYPE(OBC_DATA), POINTER                ::   dta           ! short cut
402      TYPE(FLD_N), ALLOCATABLE, DIMENSION(:) ::   blf_i         !  array of namelist information structures
403      TYPE(FLD_N) ::   bn_tem, bn_sal, bn_u3d, bn_v3d   !
404      TYPE(FLD_N) ::   bn_ssh, bn_u2d, bn_v2d           ! informations about the fields to be read
405#if defined key_lim2
406      TYPE(FLD_N) ::   bn_frld, bn_hicif, bn_hsnif      !
407#endif
408      NAMELIST/nambdy_dta/ cn_dir, bn_tem, bn_sal, bn_u3d, bn_v3d, bn_ssh, bn_u2d, bn_v2d 
409#if defined key_lim2
410      NAMELIST/nambdy_dta/ bn_frld, bn_hicif, bn_hsnif
411#endif
412      NAMELIST/nambdy_dta/ ln_full_vel
413      !!---------------------------------------------------------------------------
414
415      IF( nn_timing == 1 ) CALL timing_start('bdy_dta_init')
416
417      IF(lwp) WRITE(numout,*)
418      IF(lwp) WRITE(numout,*) 'bdy_dta_ini : initialization of data at the open boundaries'
419      IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
420      IF(lwp) WRITE(numout,*) ''
421
422      ! Set nn_dta
423      DO ib_bdy = 1, nb_bdy
424         nn_dta(ib_bdy) = MAX(  nn_dyn2d_dta(ib_bdy)       &
425                               ,nn_dyn3d_dta(ib_bdy)       &
426                               ,nn_tra_dta(ib_bdy)         &
427#if defined key_lim2
428                               ,nn_ice_lim2_dta(ib_bdy)    &
429#endif
430                              )
431         IF(nn_dta(ib_bdy) .gt. 1) nn_dta(ib_bdy) = 1
432      END DO
433
434      ! Work out upper bound of how many fields there are to read in and allocate arrays
435      ! ---------------------------------------------------------------------------
436      ALLOCATE( nb_bdy_fld(nb_bdy) )
437      nb_bdy_fld(:) = 0
438      DO ib_bdy = 1, nb_bdy         
439         IF( cn_dyn2d(ib_bdy) /= 'none' .and. ( nn_dyn2d_dta(ib_bdy) .eq. 1 .or. nn_dyn2d_dta(ib_bdy) .eq. 3 ) ) THEN
440            nb_bdy_fld(ib_bdy) = nb_bdy_fld(ib_bdy) + 3
441         ENDIF
442         IF( cn_dyn3d(ib_bdy) /= 'none' .and. nn_dyn3d_dta(ib_bdy) .eq. 1 ) THEN
443            nb_bdy_fld(ib_bdy) = nb_bdy_fld(ib_bdy) + 2
444         ENDIF
445         IF( cn_tra(ib_bdy) /= 'none' .and. nn_tra_dta(ib_bdy) .eq. 1  ) THEN
446            nb_bdy_fld(ib_bdy) = nb_bdy_fld(ib_bdy) + 2
447         ENDIF
448#if defined key_lim2
449         IF( cn_ice_lim2(ib_bdy) /= 'none' .and. nn_ice_lim2_dta(ib_bdy) .eq. 1  ) THEN
450            nb_bdy_fld(ib_bdy) = nb_bdy_fld(ib_bdy) + 3
451         ENDIF
452#endif               
453         IF(lwp) WRITE(numout,*) 'Maximum number of files to open =',nb_bdy_fld(ib_bdy)
454      ENDDO           
455
456      nb_bdy_fld_sum = SUM( nb_bdy_fld )
457
458      ALLOCATE( bf(nb_bdy_fld_sum), STAT=ierror )
459      IF( ierror > 0 ) THEN   
460         CALL ctl_stop( 'bdy_dta: unable to allocate bf structure' )   ;   RETURN 
461      ENDIF
462      ALLOCATE( blf_i(nb_bdy_fld_sum), STAT=ierror )
463      IF( ierror > 0 ) THEN   
464         CALL ctl_stop( 'bdy_dta: unable to allocate blf_i structure' )   ;   RETURN 
465      ENDIF
466      ALLOCATE( nbmap_ptr(nb_bdy_fld_sum), STAT=ierror )
467      IF( ierror > 0 ) THEN   
468         CALL ctl_stop( 'bdy_dta: unable to allocate nbmap_ptr structure' )   ;   RETURN 
469      ENDIF
470      ALLOCATE( ilen1(nb_bdy_fld_sum), ilen3(nb_bdy_fld_sum) ) 
471      ALLOCATE( ibdy(nb_bdy_fld_sum) ) 
472      ALLOCATE( igrid(nb_bdy_fld_sum) ) 
473
474      ! Read namelists
475      ! --------------
476      REWIND(numnam)
477      jfld = 0 
478      DO ib_bdy = 1, nb_bdy         
479         IF( nn_dta(ib_bdy) .eq. 1 ) THEN
480            ! set file information
481            cn_dir = './'        ! directory in which the model is executed
482            ln_full_vel = .false.
483            ! ... default values (NB: frequency positive => hours, negative => months)
484            !                    !  file       ! frequency !  variable   ! time intep !  clim   ! 'yearly' or ! weights  ! rotation  !
485            !                    !  name       ! hours !   name     !  (T/F)  !  (T/F)  !  'monthly'  ! filename ! pairs     !
486            bn_ssh     = FLD_N(  'bdy_ssh'     ,  24   , 'sossheig' , .false. , .false. ,   'yearly'  , ''       , ''        )
487            bn_u2d     = FLD_N(  'bdy_vel2d_u' ,  24   , 'vobtcrtx' , .false. , .false. ,   'yearly'  , ''       , ''        )
488            bn_v2d     = FLD_N(  'bdy_vel2d_v' ,  24   , 'vobtcrty' , .false. , .false. ,   'yearly'  , ''       , ''        )
489            bn_u3d     = FLD_N(  'bdy_vel3d_u' ,  24   , 'vozocrtx' , .false. , .false. ,   'yearly'  , ''       , ''        )
490            bn_v3d     = FLD_N(  'bdy_vel3d_v' ,  24   , 'vomecrty' , .false. , .false. ,   'yearly'  , ''       , ''        )
491            bn_tem     = FLD_N(  'bdy_tem'     ,  24   , 'votemper' , .false. , .false. ,   'yearly'  , ''       , ''        )
492            bn_sal     = FLD_N(  'bdy_sal'     ,  24   , 'vosaline' , .false. , .false. ,   'yearly'  , ''       , ''        )
493#if defined key_lim2
494            bn_frld    = FLD_N(  'bdy_frld'    ,  24   , 'ildsconc' , .false. , .false. ,   'yearly'  , ''       , ''        )
495            bn_hicif   = FLD_N(  'bdy_hicif'   ,  24   , 'iicethic' , .false. , .false. ,   'yearly'  , ''       , ''        )
496            bn_hsnif   = FLD_N(  'bdy_hsnif'   ,  24   , 'isnothic' , .false. , .false. ,   'yearly'  , ''       , ''        )
497#endif
498
499            ! Important NOT to rewind here.
500            READ( numnam, nambdy_dta )
501
502            cn_dir_array(ib_bdy) = cn_dir
503            ln_full_vel_array(ib_bdy) = ln_full_vel
504
505            nblen => idx_bdy(ib_bdy)%nblen
506            nblenrim => idx_bdy(ib_bdy)%nblenrim
507            dta => dta_bdy(ib_bdy)
508            dta%nread(2) = 0
509
510            ! Only read in necessary fields for this set.
511            ! Important that barotropic variables come first.
512            IF( nn_dyn2d_dta(ib_bdy) .eq. 1 .or. nn_dyn2d_dta(ib_bdy) .eq. 3 ) THEN
513
514               IF( dta%ll_ssh ) THEN
515                  if(lwp) write(numout,*) '++++++ reading in ssh field'
516                  jfld = jfld + 1
517                  blf_i(jfld) = bn_ssh
518                  ibdy(jfld) = ib_bdy
519                  igrid(jfld) = 1
520                  ilen1(jfld) = nblen(igrid(jfld))
521                  ilen3(jfld) = 1
522                  dta%nread(2) = dta%nread(2) + 1
523               ENDIF
524
525               IF( dta%ll_u2d .and. .not. ln_full_vel_array(ib_bdy) ) THEN
526                  if(lwp) write(numout,*) '++++++ reading in u2d field'
527                  jfld = jfld + 1
528                  blf_i(jfld) = bn_u2d
529                  ibdy(jfld) = ib_bdy
530                  igrid(jfld) = 2
531                  ilen1(jfld) = nblen(igrid(jfld))
532                  ilen3(jfld) = 1
533                  dta%nread(2) = dta%nread(2) + 1
534               ENDIF
535
536               IF( dta%ll_v2d .and. .not. ln_full_vel_array(ib_bdy) ) THEN
537                  if(lwp) write(numout,*) '++++++ reading in v2d field'
538                  jfld = jfld + 1
539                  blf_i(jfld) = bn_v2d
540                  ibdy(jfld) = ib_bdy
541                  igrid(jfld) = 3
542                  ilen1(jfld) = nblen(igrid(jfld))
543                  ilen3(jfld) = 1
544                  dta%nread(2) = dta%nread(2) + 1
545               ENDIF
546
547            ENDIF
548
549            ! read 3D velocities if baroclinic velocities require OR if
550            ! barotropic velocities required and ln_full_vel set to .true.
551            IF( nn_dyn3d_dta(ib_bdy) .eq. 1 .or. &
552           &  ( ln_full_vel_array(ib_bdy) .and. ( nn_dyn2d_dta(ib_bdy) .eq. 1 .or. nn_dyn2d_dta(ib_bdy) .eq. 3 ) ) ) THEN
553
554               IF( dta%ll_u3d .or. ( ln_full_vel_array(ib_bdy) .and. dta%ll_u2d ) ) THEN
555                  if(lwp) write(numout,*) '++++++ reading in u3d field'
556                  jfld = jfld + 1
557                  blf_i(jfld) = bn_u3d
558                  ibdy(jfld) = ib_bdy
559                  igrid(jfld) = 2
560                  ilen1(jfld) = nblen(igrid(jfld))
561                  ilen3(jfld) = jpk
562                  IF( ln_full_vel_array(ib_bdy) .and. dta%ll_u2d ) dta%nread(2) = dta%nread(2) + 1
563               ENDIF
564
565               IF( dta%ll_v3d .or. ( ln_full_vel_array(ib_bdy) .and. dta%ll_v2d ) ) THEN
566                  if(lwp) write(numout,*) '++++++ reading in v3d field'
567                  jfld = jfld + 1
568                  blf_i(jfld) = bn_v3d
569                  ibdy(jfld) = ib_bdy
570                  igrid(jfld) = 3
571                  ilen1(jfld) = nblen(igrid(jfld))
572                  ilen3(jfld) = jpk
573                  IF( ln_full_vel_array(ib_bdy) .and. dta%ll_v2d ) dta%nread(2) = dta%nread(2) + 1
574               ENDIF
575
576            ENDIF
577
578            ! temperature and salinity
579            IF( nn_tra_dta(ib_bdy) .eq. 1 ) THEN
580
581               IF( dta%ll_tem ) THEN
582                  if(lwp) write(numout,*) '++++++ reading in tem field'
583                  jfld = jfld + 1
584                  blf_i(jfld) = bn_tem
585                  ibdy(jfld) = ib_bdy
586                  igrid(jfld) = 1
587                  ilen1(jfld) = nblen(igrid(jfld))
588                  ilen3(jfld) = jpk
589               ENDIF
590
591               IF( dta%ll_sal ) THEN
592                  if(lwp) write(numout,*) '++++++ reading in sal field'
593                  jfld = jfld + 1
594                  blf_i(jfld) = bn_sal
595                  ibdy(jfld) = ib_bdy
596                  igrid(jfld) = 1
597                  ilen1(jfld) = nblen(igrid(jfld))
598                  ilen3(jfld) = jpk
599               ENDIF
600
601            ENDIF
602
603#if defined key_lim2
604            ! sea ice
605            IF( nn_ice_lim2_dta(ib_bdy) .eq. 1 ) THEN
606
607               IF( dta%ll_frld ) THEN
608                  jfld = jfld + 1
609                  blf_i(jfld) = bn_frld
610                  ibdy(jfld) = ib_bdy
611                  igrid(jfld) = 1
612                  ilen1(jfld) = nblen(igrid(jfld))
613                  ilen3(jfld) = 1
614               ENDIF
615
616               IF( dta%ll_hicif ) THEN
617                  jfld = jfld + 1
618                  blf_i(jfld) = bn_hicif
619                  ibdy(jfld) = ib_bdy
620                  igrid(jfld) = 1
621                  ilen1(jfld) = nblen(igrid(jfld))
622                  ilen3(jfld) = 1
623               ENDIF
624
625               IF( dta%ll_hsnif ) THEN
626                  jfld = jfld + 1
627                  blf_i(jfld) = bn_hsnif
628                  ibdy(jfld) = ib_bdy
629                  igrid(jfld) = 1
630                  ilen1(jfld) = nblen(igrid(jfld))
631                  ilen3(jfld) = 1
632               ENDIF
633
634            ENDIF
635#endif
636            ! Recalculate field counts
637            !-------------------------
638            IF( ib_bdy .eq. 1 ) THEN
639               nb_bdy_fld_sum = 0
640               nb_bdy_fld(ib_bdy) = jfld
641               nb_bdy_fld_sum     = jfld             
642            ELSE
643               nb_bdy_fld(ib_bdy) = jfld - nb_bdy_fld_sum
644               nb_bdy_fld_sum = nb_bdy_fld_sum + nb_bdy_fld(ib_bdy)
645            ENDIF
646
647            dta%nread(1) = nb_bdy_fld(ib_bdy)
648
649         ENDIF ! nn_dta .eq. 1
650      ENDDO ! ib_bdy
651
652      DO jfld = 1, nb_bdy_fld_sum
653         ALLOCATE( bf(jfld)%fnow(ilen1(jfld),1,ilen3(jfld)) )
654         IF( blf_i(jfld)%ln_tint ) ALLOCATE( bf(jfld)%fdta(ilen1(jfld),1,ilen3(jfld),2) )
655         nbmap_ptr(jfld)%ptr => idx_bdy(ibdy(jfld))%nbmap(:,igrid(jfld))
656      ENDDO
657
658      ! fill bf with blf_i and control print
659      !-------------------------------------
660      jstart = 1
661      DO ib_bdy = 1, nb_bdy
662         jend = nb_bdy_fld(ib_bdy) 
663         CALL fld_fill( bf(jstart:jend), blf_i(jstart:jend), cn_dir_array(ib_bdy), 'bdy_dta',   &
664         &              'open boundary conditions', 'nambdy_dta' )
665         jstart = jend + 1
666      ENDDO
667
668      ! Initialise local boundary data arrays
669      ! nn_xxx_dta=0 : allocate space - will be filled from initial conditions later
670      ! nn_xxx_dta=1 : point to "fnow" arrays
671      !-------------------------------------
672
673      jfld = 0
674      DO ib_bdy=1, nb_bdy
675
676         nblen => idx_bdy(ib_bdy)%nblen
677         dta => dta_bdy(ib_bdy)
678
679         if(lwp) then
680            write(numout,*) '++++++ dta%ll_ssh = ',dta%ll_ssh
681            write(numout,*) '++++++ dta%ll_u2d = ',dta%ll_u2d
682            write(numout,*) '++++++ dta%ll_v2d = ',dta%ll_v2d
683            write(numout,*) '++++++ dta%ll_u3d = ',dta%ll_u3d
684            write(numout,*) '++++++ dta%ll_v3d = ',dta%ll_v3d
685            write(numout,*) '++++++ dta%ll_tem = ',dta%ll_tem
686            write(numout,*) '++++++ dta%ll_sal = ',dta%ll_sal
687         endif
688
689         IF ( nn_dyn2d_dta(ib_bdy) .eq. 0 .or. nn_dyn2d_dta(ib_bdy) .eq. 2 ) THEN
690            if(lwp) write(numout,*) '++++++ dta%ssh/u2d/u3d allocated space'
691            IF( dta%ll_ssh ) ALLOCATE( dta%ssh(nblen(1)) )
692            IF( dta%ll_u2d ) ALLOCATE( dta%u2d(nblen(2)) )
693            IF( dta%ll_v2d ) ALLOCATE( dta%v2d(nblen(3)) )
694         ENDIF
695         IF ( nn_dyn2d_dta(ib_bdy) .eq. 1 .or. nn_dyn2d_dta(ib_bdy) .eq. 3 ) THEN
696            IF( dta%ll_ssh ) THEN
697               if(lwp) write(numout,*) '++++++ dta%ssh pointing to fnow'
698               jfld = jfld + 1
699               dta%ssh => bf(jfld)%fnow(:,1,1)
700            ENDIF
701            IF ( dta%ll_u2d ) THEN
702               IF ( ln_full_vel_array(ib_bdy) ) THEN
703                  if(lwp) write(numout,*) '++++++ dta%u2d allocated space'
704                  ALLOCATE( dta%u2d(nblen(2)) )
705               ELSE
706                  if(lwp) write(numout,*) '++++++ dta%u2d pointing to fnow'
707                  jfld = jfld + 1
708                  dta%u2d => bf(jfld)%fnow(:,1,1)
709               ENDIF
710            ENDIF
711            IF ( dta%ll_v2d ) THEN
712               IF ( ln_full_vel_array(ib_bdy) ) THEN
713                  if(lwp) write(numout,*) '++++++ dta%v2d allocated space'
714                  ALLOCATE( dta%v2d(nblen(3)) )
715               ELSE
716                  if(lwp) write(numout,*) '++++++ dta%v2d pointing to fnow'
717                  jfld = jfld + 1
718                  dta%v2d => bf(jfld)%fnow(:,1,1)
719               ENDIF
720            ENDIF
721         ENDIF
722
723         IF ( nn_dyn3d_dta(ib_bdy) .eq. 0 ) THEN
724            if(lwp) write(numout,*) '++++++ dta%u3d/v3d allocated space'
725            IF( dta%ll_u3d ) ALLOCATE( dta_bdy(ib_bdy)%u3d(nblen(2),jpk) )
726            IF( dta%ll_v3d ) ALLOCATE( dta_bdy(ib_bdy)%v3d(nblen(3),jpk) )
727         ENDIF
728         IF ( nn_dyn3d_dta(ib_bdy) .eq. 1 .or. &
729           &  ( ln_full_vel_array(ib_bdy) .and. ( nn_dyn2d_dta(ib_bdy) .eq. 1 .or. nn_dyn2d_dta(ib_bdy) .eq. 3 ) ) ) THEN
730            IF ( dta%ll_u3d .or. ( ln_full_vel_array(ib_bdy) .and. dta%ll_u2d ) ) THEN
731               if(lwp) write(numout,*) '++++++ dta%u3d pointing to fnow'
732               jfld = jfld + 1
733               dta_bdy(ib_bdy)%u3d => bf(jfld)%fnow(:,1,:)
734            ENDIF
735            IF ( dta%ll_v3d .or. ( ln_full_vel_array(ib_bdy) .and. dta%ll_v2d ) ) THEN
736               if(lwp) write(numout,*) '++++++ dta%v3d pointing to fnow'
737               jfld = jfld + 1
738               dta_bdy(ib_bdy)%v3d => bf(jfld)%fnow(:,1,:)
739            ENDIF
740         ENDIF
741
742         IF( nn_tra_dta(ib_bdy) .eq. 0 ) THEN
743            if(lwp) write(numout,*) '++++++ dta%tem/sal allocated space'
744            IF( dta%ll_tem ) ALLOCATE( dta_bdy(ib_bdy)%tem(nblen(1),jpk) )
745            IF( dta%ll_sal ) ALLOCATE( dta_bdy(ib_bdy)%sal(nblen(1),jpk) )
746         ELSE
747            IF( dta%ll_tem ) THEN
748               if(lwp) write(numout,*) '++++++ dta%tem pointing to fnow'
749               jfld = jfld + 1
750               dta_bdy(ib_bdy)%tem => bf(jfld)%fnow(:,1,:)
751            ENDIF
752            IF( dta%ll_sal ) THEN
753               if(lwp) write(numout,*) '++++++ dta%sal pointing to fnow'
754               jfld = jfld + 1
755               dta_bdy(ib_bdy)%sal => bf(jfld)%fnow(:,1,:)
756            ENDIF
757         ENDIF
758
759#if defined key_lim2
760         IF (nn_ice_lim2(ib_bdy) .gt. 0) THEN
761            IF( nn_ice_lim2_dta(ib_bdy) .eq. 0 ) THEN
762               ALLOCATE( dta_bdy(ib_bdy)%frld(nblen(1)) )
763               ALLOCATE( dta_bdy(ib_bdy)%hicif(nblen(1)) )
764               ALLOCATE( dta_bdy(ib_bdy)%hsnif(nblen(1)) )
765            ELSE
766               jfld = jfld + 1
767               dta_bdy(ib_bdy)%frld  => bf(jfld)%fnow(:,1,1)
768               jfld = jfld + 1
769               dta_bdy(ib_bdy)%hicif => bf(jfld)%fnow(:,1,1)
770               jfld = jfld + 1
771               dta_bdy(ib_bdy)%hsnif => bf(jfld)%fnow(:,1,1)
772            ENDIF
773         ENDIF
774#endif
775
776      ENDDO ! ib_bdy
777
778      IF( nn_timing == 1 ) CALL timing_stop('bdy_dta_init')
779
780      END SUBROUTINE bdy_dta_init
781
782#else
783   !!----------------------------------------------------------------------
784   !!   Dummy module                   NO Open Boundary Conditions
785   !!----------------------------------------------------------------------
786CONTAINS
787   SUBROUTINE bdy_dta( kt, jit, time_offset ) ! Empty routine
788      INTEGER, INTENT( in )           ::   kt   
789      INTEGER, INTENT( in ), OPTIONAL ::   jit   
790      INTEGER, INTENT( in ), OPTIONAL ::   time_offset
791      WRITE(*,*) 'bdy_dta: You should not have seen this print! error?', kt
792   END SUBROUTINE bdy_dta
793   SUBROUTINE bdy_dta_init()                  ! Empty routine
794      WRITE(*,*) 'bdy_dta_init: You should not have seen this print! error?'
795   END SUBROUTINE bdy_dta_init
796#endif
797
798   !!==============================================================================
799END MODULE bdydta
Note: See TracBrowser for help on using the repository browser.