source: branches/2013/dev_r3858_NOC_ZTC/NEMOGCM/NEMO/OPA_SRC/DIA/diaharm.F90 @ 3953

Last change on this file since 3953 was 3953, checked in by gm, 8 years ago

dev_r3858_NOC_ZTC, #863 : activate tide potential in filtered ssh case + style in tide modules

File size: 19.1 KB
Line 
1MODULE diaharm 
2   !!======================================================================
3   !!                       ***  MODULE  diaharm  ***
4   !! Harmonic analysis of tidal constituents
5   !!======================================================================
6   !! History :  3.1  !  2007  (O. Le Galloudec, J. Chanut)  Original code
7   !!----------------------------------------------------------------------
8#if defined key_diaharm && defined key_tide
9   !!----------------------------------------------------------------------
10   !!   'key_diaharm'
11   !!   'key_tide'
12   !!----------------------------------------------------------------------
13   USE oce             ! ocean dynamics and tracers variables
14   USE dom_oce         ! ocean space and time domain
15   USE phycst
16   USE dynspg_oce
17   USE dynspg_ts
18   USE daymod
19   USE tide_mod
20   USE in_out_manager  ! I/O units
21   USE iom             ! I/0 library
22   USE ioipsl          ! NetCDF IPSL library
23   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
24   USE diadimg         ! To write dimg
25   USE timing          ! preformance summary
26   USE wrk_nemo        ! working arrays
27
28   IMPLICIT NONE
29   PRIVATE
30
31   LOGICAL, PUBLIC, PARAMETER :: lk_diaharm  = .TRUE.
32   
33   INTEGER, PARAMETER :: jpincomax    = 2.*jpmax_harmo
34   INTEGER, PARAMETER :: jpdimsparse  = jpincomax*300*24
35
36   !                            !!!namelist variables
37   INTEGER ::   nit000_han = 1   ! First time step used for harmonic analysis
38   INTEGER ::   nitend_han = 1   ! Last time step used for harmonic analysis
39   INTEGER ::   nstep_han  = 1   ! Time step frequency for harmonic analysis
40   INTEGER ::   nb_ana           ! Number of harmonics to analyse
41
42   INTEGER , ALLOCATABLE, DIMENSION(:)       ::   name
43   REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:) ::   ana_temp
44   REAL(wp), ALLOCATABLE, DIMENSION(:)       ::   ana_freq, ut   , vt   , ft
45   REAL(wp), ALLOCATABLE, DIMENSION(:,:,:)   ::   out_eta , out_u, out_v
46
47   INTEGER ::   ninco, nsparse
48   INTEGER ,       DIMENSION(jpdimsparse)         ::   njsparse, nisparse
49   INTEGER , SAVE, DIMENSION(jpincomax)           ::   ipos1
50   REAL(wp),       DIMENSION(jpdimsparse)         ::   valuesparse
51   REAL(wp),       DIMENSION(jpincomax)           ::   ztmp4 , ztmp7
52   REAL(wp), SAVE, DIMENSION(jpincomax,jpincomax) ::   ztmp3 , zpilier
53   REAL(wp), SAVE, DIMENSION(jpincomax)           ::   zpivot
54
55   CHARACTER (LEN=4), DIMENSION(jpmax_harmo) ::   tname   ! Names of tidal constituents ('M2', 'K1',...)
56
57   PUBLIC   dia_harm   ! routine called by step.F90
58
59   !!----------------------------------------------------------------------
60   !! NEMO/OPA 3.5 , NEMO Consortium (2013)
61   !! $Id:$
62   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
63   !!----------------------------------------------------------------------
64CONTAINS
65
66   SUBROUTINE dia_harm_init 
67      !!----------------------------------------------------------------------
68      !!                 ***  ROUTINE dia_harm_init  ***
69      !!         
70      !! ** Purpose :   Initialization of tidal harmonic analysis
71      !!
72      !! ** Method  :   Initialize frequency array and  nodal factor for nit000_han
73      !!
74      !!--------------------------------------------------------------------
75      INTEGER :: jh, nhan, jk, ji
76      !
77      NAMELIST/nam_diaharm/ nit000_han, nitend_han, nstep_han, tname
78      !!----------------------------------------------------------------------
79
80      IF(lwp) THEN
81         WRITE(numout,*)
82         WRITE(numout,*) 'dia_harm_init: Tidal harmonic analysis initialization'
83         WRITE(numout,*) '~~~~~~~ '
84      ENDIF
85      !
86      CALL tide_init_Wave
87      !
88      tname(:)=''
89      !
90      REWIND( numnam )                   ! Read Namelist nam_diaharm
91      READ  ( numnam, nam_diaharm )
92      !
93      IF(lwp) THEN
94         WRITE(numout,*) 'First time step used for analysis:  nit000_han= ', nit000_han
95         WRITE(numout,*) 'Last  time step used for analysis:  nitend_han= ', nitend_han
96         WRITE(numout,*) 'Time step frequency for harmonic analysis:  nstep_han= ', nstep_han
97      ENDIF
98
99      ! Basic checks on harmonic analysis time window:
100      ! ----------------------------------------------
101      IF( nit000 > nit000_han )   CALL ctl_stop( 'dia_harm_init : nit000_han must be greater than nit000',   &
102         &                                       ' restart capability not implemented' )
103      IF( nitend < nitend_han )   CALL ctl_stop( 'dia_harm_init : nitend_han must be lower than nitend',   &
104         &                                       'restart capability not implemented' )
105
106      IF( MOD( nitend_han-nit000_han+1 , nstep_han ) /= 0 )   &
107         &                        CALL ctl_stop( 'dia_harm_init : analysis time span must be a multiple of nstep_han' )
108
109      nb_ana = 0
110      DO jk=1,jpmax_harmo
111         DO ji=1,jpmax_harmo
112            IF(TRIM(tname(jk)) == Wave(ji)%cname_tide) THEN
113               nb_ana=nb_ana+1
114            ENDIF
115         END DO
116      ENDDO
117      !
118      IF(lwp) THEN
119         WRITE(numout,*) '        Namelist nam_diaharm'
120         WRITE(numout,*) '        nb_ana    = ', nb_ana
121         CALL flush(numout)
122      ENDIF
123      !
124      IF (nb_ana > jpmax_harmo) THEN
125        IF(lwp) WRITE(numout,*) ' E R R O R dia_harm_init : nb_ana must be lower than jpmax_harmo, stop'
126        IF(lwp) WRITE(numout,*) ' jpmax_harmo= ', jpmax_harmo
127        nstop = nstop + 1
128      ENDIF
129
130      ALLOCATE(name    (nb_ana))
131      DO jk=1,nb_ana
132       DO ji=1,jpmax_harmo
133          IF (TRIM(tname(jk)) .eq. Wave(ji)%cname_tide) THEN
134             name(jk) = ji
135             EXIT
136          END IF
137       END DO
138      END DO
139
140      ! Initialize frequency array:
141      ! ---------------------------
142      ALLOCATE( ana_freq(nb_ana), ut(nb_ana), vt(nb_ana), ft(nb_ana) )
143
144      CALL tide_harmo( ana_freq, vt, ut, ft, name, nb_ana )
145
146      IF(lwp) WRITE(numout,*) 'Analysed frequency  : ',nb_ana ,'Frequency '
147
148      DO jh = 1, nb_ana
149        IF(lwp) WRITE(numout,*) '                    : ',tname(jh),' ',ana_freq(jh)
150      END DO
151
152      ! Initialize temporary arrays:
153      ! ----------------------------
154      ALLOCATE( ana_temp(jpi,jpj,2*nb_ana,3) )
155      ana_temp(:,:,:,:) = 0.e0
156
157   END SUBROUTINE dia_harm_init
158
159
160   SUBROUTINE dia_harm ( kt )
161      !!----------------------------------------------------------------------
162      !!                 ***  ROUTINE dia_harm  ***
163      !!         
164      !! ** Purpose :   Tidal harmonic analysis main routine
165      !!
166      !! ** Action  :   Sums ssh/u/v over time analysis [nit000_han,nitend_han]
167      !!
168      !!--------------------------------------------------------------------
169      INTEGER, INTENT( IN ) :: kt
170      !
171      INTEGER  :: ji, jj, jh, jc, nhc
172      REAL(wp) :: ztime, ztemp
173      !!--------------------------------------------------------------------
174      IF( nn_timing == 1 )   CALL timing_start('dia_harm')
175
176      IF ( kt == nit000 ) CALL dia_harm_init
177
178      IF ( ((kt.GE.nit000_han).AND.(kt.LE.nitend_han)).AND. &
179           (MOD(kt,nstep_han).EQ.0) ) THEN
180
181        ztime = (kt-nit000+1)*rdt 
182       
183        nhc = 0
184        DO jh = 1,nb_ana
185          DO jc = 1,2
186            nhc = nhc+1
187            ztemp =(     MOD(jc,2) * ft(jh) *COS(ana_freq(jh)*ztime + vt(jh) + ut(jh))  &
188                    +(1.-MOD(jc,2))* ft(jh) *SIN(ana_freq(jh)*ztime + vt(jh) + ut(jh)))
189
190            DO jj = 1,jpj
191              DO ji = 1,jpi
192                ! Elevation
193                ana_temp(ji,jj,nhc,1) = ana_temp(ji,jj,nhc,1) + ztemp*sshn(ji,jj)           *tmask(ji,jj,1)       
194#if defined key_dynspg_ts
195                ana_temp(ji,jj,nhc,2) = ana_temp(ji,jj,nhc,2) + ztemp*un_b(ji,jj)*hur(ji,jj)*umask(ji,jj,1)
196                ana_temp(ji,jj,nhc,3) = ana_temp(ji,jj,nhc,3) + ztemp*vn_b(ji,jj)*hvr(ji,jj)*vmask(ji,jj,1)
197#endif
198              END DO
199            END DO
200
201          END DO
202        END DO
203       
204      END IF
205
206      IF ( kt == nitend_han )   CALL dia_harm_end
207
208      IF( nn_timing == 1 )   CALL timing_stop('dia_harm')
209 
210   END SUBROUTINE dia_harm
211
212
213   SUBROUTINE dia_harm_end
214      !!----------------------------------------------------------------------
215      !!                 ***  ROUTINE diaharm_end  ***
216      !!         
217      !! ** Purpose :  Compute the Real and Imaginary part of tidal constituents
218      !!
219      !! ** Action  :  Decompose the signal on the harmonic constituents
220      !!
221      !!--------------------------------------------------------------------
222      INTEGER :: ji, jj, jh, jc, jn, nhan, jl
223      INTEGER :: ksp, kun, keq
224      REAL(wp) :: ztime, ztime_ini, ztime_end
225      REAL(wp) :: X1,X2
226      REAL(wp), POINTER, DIMENSION(:,:,:,:) :: ana_amp
227      !!--------------------------------------------------------------------
228      CALL wrk_alloc( jpi , jpj , jpmax_harmo , 2 , ana_amp )
229
230      IF(lwp) WRITE(numout,*)
231      IF(lwp) WRITE(numout,*) 'anharmo_end: kt=nitend_han: Perform harmonic analysis'
232      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~'
233
234      ztime_ini = nit000_han*rdt                 ! Initial time in seconds at the beginning of analysis
235      ztime_end = nitend_han*rdt                 ! Final time in seconds at the end of analysis
236      nhan = (nitend_han-nit000_han+1)/nstep_han ! Number of dumps used for analysis
237
238      ninco = 2*nb_ana
239
240      ksp = 0
241      keq = 0       
242      DO jn = 1, nhan
243         ztime=( (nhan-jn)*ztime_ini + (jn-1)*ztime_end )/FLOAT(nhan-1)
244         keq = keq + 1
245         kun = 0
246         DO jh = 1,nb_ana
247            DO jc = 1,2
248               kun = kun + 1
249               ksp = ksp + 1
250               nisparse(ksp) = keq
251               njsparse(ksp) = kun
252               valuesparse(ksp) = (   MOD(jc,2) * ft(jh) * COS(ana_freq(jh)*ztime + vt(jh) + ut(jh))   &
253                  &             + (1.-MOD(jc,2))* ft(jh) * SIN(ana_freq(jh)*ztime + vt(jh) + ut(jh)) )
254            END DO
255         END DO
256      END DO
257
258      nsparse = ksp
259
260      ! Elevation:
261      DO jj = 1, jpj
262         DO ji = 1, jpi
263            ! Fill input array
264            kun = 0
265            DO jh = 1, nb_ana
266               DO jc = 1, 2
267                  kun = kun + 1
268                  ztmp4(kun)=ana_temp(ji,jj,kun,1)
269               END DO
270            END DO
271
272            CALL SUR_DETERMINE(jj)
273
274            ! Fill output array
275            DO jh = 1, nb_ana
276               ana_amp(ji,jj,jh,1)=ztmp7((jh-1)*2+1)
277               ana_amp(ji,jj,jh,2)=ztmp7((jh-1)*2+2)
278            END DO
279         END DO
280      END DO
281
282      ALLOCATE( out_eta(jpi,jpj,2*nb_ana),   & 
283         &      out_u  (jpi,jpj,2*nb_ana),   &
284         &      out_v  (jpi,jpj,2*nb_ana)  )
285
286      DO jj = 1, jpj
287         DO ji = 1, jpi
288            DO jh = 1, nb_ana 
289               X1 = ana_amp(ji,jj,jh,1)
290               X2 =-ana_amp(ji,jj,jh,2)
291               out_eta(ji,jj,jh       ) = X1 * tmask(ji,jj,1)
292               out_eta(ji,jj,jh+nb_ana) = X2 * tmask(ji,jj,1)
293            ENDDO
294         ENDDO
295      ENDDO
296
297      ! ubar:
298      DO jj = 1, jpj
299         DO ji = 1, jpi
300            ! Fill input array
301            kun=0
302            DO jh = 1,nb_ana
303               DO jc = 1,2
304                  kun = kun + 1
305                  ztmp4(kun)=ana_temp(ji,jj,kun,2)
306               ENDDO
307            ENDDO
308
309            CALL SUR_DETERMINE(jj+1)
310
311            ! Fill output array
312            DO jh = 1, nb_ana
313               ana_amp(ji,jj,jh,1)=ztmp7((jh-1)*2+1)
314               ana_amp(ji,jj,jh,2)=ztmp7((jh-1)*2+2)
315            END DO
316
317         END DO
318      END DO
319
320      DO jj = 1, jpj
321         DO ji = 1, jpi
322            DO jh = 1, nb_ana 
323               X1=ana_amp(ji,jj,jh,1)
324               X2=-ana_amp(ji,jj,jh,2)
325               out_u(ji,jj,jh) = X1 * umask(ji,jj,1)
326               out_u (ji,jj,nb_ana+jh) = X2 * umask(ji,jj,1)
327            ENDDO
328         ENDDO
329      ENDDO
330
331      ! vbar:
332      DO jj = 1, jpj
333         DO ji = 1, jpi
334            ! Fill input array
335            kun=0
336            DO jh = 1,nb_ana
337               DO jc = 1,2
338                  kun = kun + 1
339                  ztmp4(kun)=ana_temp(ji,jj,kun,3)
340               ENDDO
341            ENDDO
342
343            CALL SUR_DETERMINE(jj+1)
344
345            ! Fill output array
346            DO jh = 1, nb_ana
347               ana_amp(ji,jj,jh,1)=ztmp7((jh-1)*2+1)
348               ana_amp(ji,jj,jh,2)=ztmp7((jh-1)*2+2)
349            END DO
350
351         END DO
352      END DO
353
354      DO jj = 1, jpj
355         DO ji = 1, jpi
356            DO jh = 1, nb_ana 
357               X1=ana_amp(ji,jj,jh,1)
358               X2=-ana_amp(ji,jj,jh,2)
359               out_v(ji,jj,jh)=X1 * vmask(ji,jj,1)
360               out_v(ji,jj,nb_ana+jh)=X2 * vmask(ji,jj,1)
361            ENDDO
362         ENDDO
363      ENDDO
364
365      CALL dia_wri_harm ! Write results in files
366      CALL wrk_dealloc( jpi , jpj , jpmax_harmo , 2 , ana_amp )
367      !
368   END SUBROUTINE dia_harm_end
369
370
371   SUBROUTINE dia_wri_harm
372      !!--------------------------------------------------------------------
373      !!                 ***  ROUTINE dia_wri_harm  ***
374      !!         
375      !! ** Purpose : Write tidal harmonic analysis results in a netcdf file
376      !!--------------------------------------------------------------------
377      CHARACTER(LEN=lc) :: cltext
378      CHARACTER(LEN=lc) ::   &
379         cdfile_name_T   ,   & ! name of the file created (T-points)
380         cdfile_name_U   ,   & ! name of the file created (U-points)
381         cdfile_name_V         ! name of the file created (V-points)
382      INTEGER  ::   jh
383      !!----------------------------------------------------------------------
384
385#if defined key_dimgout
386      cdfile_name_T = TRIM(cexper)//'_Tidal_harmonics_gridT.dimgproc'
387      cdfile_name_U = TRIM(cexper)//'_Tidal_harmonics_gridU.dimgproc'
388      cdfile_name_V = TRIM(cexper)//'_Tidal_harmonics_gridV.dimgproc'
389#endif
390
391      IF(lwp) WRITE(numout,*) '  '
392      IF(lwp) WRITE(numout,*) 'dia_wri_harm : Write harmonic analysis results'
393#if defined key_dimgout
394      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~  Output files: ', TRIM(cdfile_name_T)
395      IF(lwp) WRITE(numout,*) '                             ', TRIM(cdfile_name_U)
396      IF(lwp) WRITE(numout,*) '                             ', TRIM(cdfile_name_V)
397#endif
398      IF(lwp) WRITE(numout,*) '  '
399
400      ! A) Elevation
401      !/////////////
402      !
403#if defined key_dimgout
404      cltext='Elevation amplitude and phase'
405      CALL dia_wri_dimg(TRIM(cdfile_name_T), TRIM(cltext), out_eta, 2*nb_ana, '2')
406#else
407      DO jh = 1, nb_ana
408      CALL iom_put( TRIM(tname(jh))//'x', out_eta(:,:,jh) )
409      CALL iom_put( TRIM(tname(jh))//'y', out_eta(:,:,nb_ana+jh) )
410      END DO
411#endif
412
413      ! B) ubar
414      !/////////
415      !
416#if defined key_dimgout
417      cltext='ubar amplitude and phase'
418      CALL dia_wri_dimg(TRIM(cdfile_name_U), TRIM(cltext), out_u, 2*nb_ana, '2')
419#else
420      DO jh = 1, nb_ana
421      CALL iom_put( TRIM(tname(jh))//'x_u', out_u(:,:,jh) )
422      CALL iom_put( TRIM(tname(jh))//'y_u', out_u(:,:,nb_ana+jh) )
423      END DO
424#endif
425
426      ! C) vbar
427      !/////////
428      !
429#if defined key_dimgout
430      cltext='vbar amplitude and phase'
431      CALL dia_wri_dimg(TRIM(cdfile_name_V), TRIM(cltext), out_v, 2*nb_ana, '2')
432#else
433      DO jh = 1, nb_ana
434         CALL iom_put( TRIM(tname(jh))//'x_v', out_u(:,:,jh       ) )
435         CALL iom_put( TRIM(tname(jh))//'y_v', out_u(:,:,jh+nb_ana) )
436      END DO
437#endif
438
439   END SUBROUTINE dia_wri_harm
440
441
442   SUBROUTINE SUR_DETERMINE(init)
443   !!---------------------------------------------------------------------------------
444   !!                      *** ROUTINE SUR_DETERMINE ***
445   !!   
446   !!   
447   !!       
448   !!---------------------------------------------------------------------------------
449   INTEGER, INTENT(in) ::   init 
450   !
451   INTEGER                         :: ji_sd, jj_sd, ji1_sd, ji2_sd, jk1_sd, jk2_sd
452   REAL(wp)                        :: zval1, zval2, zx1
453   REAL(wp), POINTER, DIMENSION(:) :: ztmpx, zcol1, zcol2
454   INTEGER , POINTER, DIMENSION(:) :: ipos2, ipivot
455   !---------------------------------------------------------------------------------
456   CALL wrk_alloc( jpincomax , ztmpx , zcol1 , zcol2 )
457   CALL wrk_alloc( jpincomax , ipos2 , ipivot        )
458           
459   IF( init == 1 ) THEN
460      IF( nsparse > jpdimsparse )   CALL ctl_stop( 'STOP', 'SUR_DETERMINE : nsparse .GT. jpdimsparse')
461      IF( ninco   > jpincomax   )   CALL ctl_stop( 'STOP', 'SUR_DETERMINE : ninco .GT. jpincomax')
462      !
463      ztmp3(:,:) = 0._wp
464      !
465      DO jk1_sd = 1, nsparse
466         DO jk2_sd = 1, nsparse
467            nisparse(jk2_sd) = nisparse(jk2_sd)
468            njsparse(jk2_sd) = njsparse(jk2_sd)
469            IF( nisparse(jk2_sd) == nisparse(jk1_sd) ) THEN
470               ztmp3(njsparse(jk1_sd),njsparse(jk2_sd)) = ztmp3(njsparse(jk1_sd),njsparse(jk2_sd))  &
471                                                        + valuesparse(jk1_sd)*valuesparse(jk2_sd)
472            ENDIF
473         END DO
474      END DO
475
476      DO jj_sd = 1 ,ninco
477          ipos1(jj_sd) = jj_sd
478          ipos2(jj_sd) = jj_sd
479      ENDDO
480
481      DO ji_sd = 1 , ninco
482
483         !find greatest non-zero pivot:
484         zval1 = ABS(ztmp3(ji_sd,ji_sd))
485
486         ipivot(ji_sd) = ji_sd
487         DO jj_sd = ji_sd, ninco
488            zval2 = ABS(ztmp3(ji_sd,jj_sd))
489            IF( zval2.GE.zval1 )THEN
490               ipivot(ji_sd) = jj_sd
491               zval1         = zval2
492            ENDIF
493         ENDDO
494
495         DO ji1_sd = 1, ninco
496            zcol1(ji1_sd)               = ztmp3(ji1_sd,ji_sd)
497            zcol2(ji1_sd)               = ztmp3(ji1_sd,ipivot(ji_sd))
498            ztmp3(ji1_sd,ji_sd)         = zcol2(ji1_sd)
499            ztmp3(ji1_sd,ipivot(ji_sd)) = zcol1(ji1_sd)
500         ENDDO
501
502         ipos2(ji_sd)         = ipos1(ipivot(ji_sd))
503         ipos2(ipivot(ji_sd)) = ipos1(ji_sd)
504         ipos1(ji_sd)         = ipos2(ji_sd)
505         ipos1(ipivot(ji_sd)) = ipos2(ipivot(ji_sd))
506         zpivot(ji_sd)        = ztmp3(ji_sd,ji_sd)
507         DO jj_sd = 1, ninco
508            ztmp3(ji_sd,jj_sd) = ztmp3(ji_sd,jj_sd) / zpivot(ji_sd)
509         ENDDO
510
511         DO ji2_sd = ji_sd+1, ninco
512            zpilier(ji2_sd,ji_sd)=ztmp3(ji2_sd,ji_sd)
513            DO jj_sd=1,ninco
514               ztmp3(ji2_sd,jj_sd)=  ztmp3(ji2_sd,jj_sd) - ztmp3(ji_sd,jj_sd) * zpilier(ji2_sd,ji_sd)
515            ENDDO
516         ENDDO
517
518      ENDDO
519
520   ENDIF ! End init==1
521
522   DO ji_sd = 1, ninco
523      ztmp4(ji_sd) = ztmp4(ji_sd) / zpivot(ji_sd)
524      DO ji2_sd = ji_sd+1, ninco
525         ztmp4(ji2_sd) = ztmp4(ji2_sd) - ztmp4(ji_sd) * zpilier(ji2_sd,ji_sd)
526      ENDDO
527   ENDDO
528
529   !system solving:
530   ztmpx(ninco) = ztmp4(ninco) / ztmp3(ninco,ninco)
531   ji_sd = ninco
532   DO ji_sd = ninco-1, 1, -1
533      zx1=0.
534      DO jj_sd = ji_sd+1, ninco
535         zx1 = zx1 + ztmpx(jj_sd) * ztmp3(ji_sd,jj_sd)
536      ENDDO
537      ztmpx(ji_sd) = ztmp4(ji_sd)-zx1
538   ENDDO
539
540   DO jj_sd =1, ninco
541      ztmp7(ipos1(jj_sd))=ztmpx(jj_sd)
542   ENDDO
543
544   CALL wrk_dealloc( jpincomax , ztmpx , zcol1 , zcol2 )
545   CALL wrk_dealloc( jpincomax , ipos2 , ipivot        )
546
547  END SUBROUTINE SUR_DETERMINE
548
549#else
550   !!----------------------------------------------------------------------
551   !!   Default case :   Empty module
552   !!----------------------------------------------------------------------
553   LOGICAL, PUBLIC, PARAMETER ::   lk_diaharm = .FALSE.
554CONTAINS
555   SUBROUTINE dia_harm ( kt )     ! Empty routine
556      INTEGER, INTENT( IN ) :: kt 
557      WRITE(*,*) 'dia_harm: you should not have seen this print'
558   END SUBROUTINE dia_harm
559#endif
560
561   !!======================================================================
562END MODULE diaharm
Note: See TracBrowser for help on using the repository browser.