source: branches/2013/dev_r3858_NOC_ZTC/NEMOGCM/NEMO/OPA_SRC/step.F90 @ 3953

Last change on this file since 3953 was 3953, checked in by gm, 8 years ago

dev_r3858_NOC_ZTC, #863 : activate tide potential in filtered ssh case + style in tide modules

  • Property svn:keywords set to Id
File size: 16.6 KB
Line 
1MODULE step
2   !!======================================================================
3   !!                       ***  MODULE step  ***
4   !! Time-stepping    : manager of the ocean, tracer and ice time stepping
5   !!======================================================================
6   !! History :  OPA  !  1991-03  (G. Madec)  Original code
7   !!             -   !  1991-11  (G. Madec)
8   !!             -   !  1992-06  (M. Imbard)  add a first output record
9   !!             -   !  1996-04  (G. Madec)  introduction of dynspg
10   !!             -   !  1996-04  (M.A. Foujols)  introduction of passive tracer
11   !!            8.0  !  1997-06  (G. Madec)  new architecture of call
12   !!            8.2  !  1997-06  (G. Madec, M. Imbard, G. Roullet)  free surface
13   !!             -   !  1999-02  (G. Madec, N. Grima)  hpg implicit
14   !!             -   !  2000-07  (J-M Molines, M. Imbard)  Open Bondary Conditions
15   !!   NEMO     1.0  !  2002-06  (G. Madec)  free form, suppress macro-tasking
16   !!             -   !  2004-08  (C. Talandier) New trends organization
17   !!             -   !  2005-01  (C. Ethe) Add the KPP closure scheme
18   !!             -   !  2005-11  (G. Madec)  Reorganisation of tra and dyn calls
19   !!             -   !  2006-01  (L. Debreu, C. Mazauric)  Agrif implementation
20   !!             -   !  2006-07  (S. Masson)  restart using iom
21   !!            3.2  !  2009-02  (G. Madec, R. Benshila)  reintroduicing z*-coordinate
22   !!             -   !  2009-06  (S. Masson, G. Madec)  TKE restart compatible with key_cpl
23   !!            3.3  !  2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
24   !!             -   !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase + merge TRC-TRA
25   !!            3.4  !  2011-04  (G. Madec, C. Ethe) Merge of dtatem and dtasal
26   !!----------------------------------------------------------------------
27
28   !!----------------------------------------------------------------------
29   !!   stp             : OPA system time-stepping
30   !!----------------------------------------------------------------------
31   USE step_oce         ! time stepping definition modules
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   stp   ! called by opa.F90
37
38   !! * Substitutions
39#  include "domzgr_substitute.h90"
40#  include "zdfddm_substitute.h90"
41   !!----------------------------------------------------------------------
42   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
43   !! $Id$
44   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48#if defined key_agrif
49   SUBROUTINE stp( )
50      INTEGER             ::   kstp   ! ocean time-step index
51#else
52   SUBROUTINE stp( kstp )
53      INTEGER, INTENT(in) ::   kstp   ! ocean time-step index
54#endif
55      !!----------------------------------------------------------------------
56      !!                     ***  ROUTINE stp  ***
57      !!
58      !! ** Purpose : - Time stepping of OPA (momentum and active tracer eqs.)
59      !!              - Time stepping of LIM (dynamic and thermodynamic eqs.)
60      !!              - Tme stepping  of TRC (passive tracer eqs.)
61      !!
62      !! ** Method  : -1- Update forcings and data
63      !!              -2- Update ocean physics
64      !!              -3- Compute the t and s trends
65      !!              -4- Update t and s
66      !!              -5- Compute the momentum trends
67      !!              -6- Update the horizontal velocity
68      !!              -7- Compute the diagnostics variables (rd,N2, div,cur,w)
69      !!              -8- Outputs and diagnostics
70      !!----------------------------------------------------------------------
71      INTEGER ::   jk       ! dummy loop indice
72      INTEGER ::   indic    ! error indicator if < 0
73      !! ---------------------------------------------------------------------
74
75#if defined key_agrif
76      kstp = nit000 + Agrif_Nb_Step()
77!      IF ( Agrif_Root() .and. lwp) Write(*,*) '---'
78!      IF (lwp) Write(*,*) 'Grid Number',Agrif_Fixed(),' time step ',kstp
79# if defined key_iomput
80      IF( Agrif_Nbstepint() == 0 )   CALL iom_swap
81# endif
82#endif
83                             indic = 0                ! reset to no error condition
84      IF( kstp == nit000 )   CALL iom_init            ! iom_put initialization (must be done after nemo_init for AGRIF+XIOS+OASIS)
85      IF( kstp /= nit000 )   CALL day( kstp )         ! Calendar (day was already called at nit000 in day_init)
86                             CALL iom_setkt( kstp - nit000 + 1 )   ! say to iom that we are at time step kstp
87
88      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
89      ! Update data, open boundaries, surface boundary condition (including sea-ice)
90      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
91                         CALL sbc     ( kstp )        ! Sea Boundary Condition (including sea-ice)
92      IF( lk_tide    )   CALL sbc_tide( kstp )
93      IF( lk_obc     )   CALL obc_dta ( kstp )        ! update dynamic and tracer data at open boundaries
94      IF( lk_obc     )   CALL obc_rad ( kstp )        ! compute phase velocities at open boundaries
95      IF( lk_bdy     )   CALL bdy_dta ( kstp, time_offset=+1 )   ! update dynamic & tracer data at open boundaries
96
97      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
98      !  Ocean dynamics : hdiv, rot, ssh, e3, wn
99      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
100                         CALL ssh_nxt       ( kstp )  ! after ssh
101      IF( lk_vvl     )   CALL dom_vvl_sf_nxt( kstp )  ! after vertical scale factors
102                         CALL wzv           ( kstp )  ! now cross-level velocity
103
104      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
105      ! Ocean physics update                (ua, va, tsa used as workspace)
106      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
107                         CALL bn2( tsb, rn2b )        ! before Brunt-Vaisala frequency
108                         CALL bn2( tsn, rn2  )        ! now    Brunt-Vaisala frequency
109      !
110      !  VERTICAL PHYSICS
111                         CALL zdf_bfr( kstp )         ! bottom friction
112
113      !                                               ! Vertical eddy viscosity and diffusivity coefficients
114      IF( lk_zdfric  )   CALL zdf_ric( kstp )            ! Richardson number dependent Kz
115      IF( lk_zdftke  )   CALL zdf_tke( kstp )            ! TKE closure scheme for Kz
116      IF( lk_zdfgls  )   CALL zdf_gls( kstp )            ! GLS closure scheme for Kz
117      IF( lk_zdfkpp  )   CALL zdf_kpp( kstp )            ! KPP closure scheme for Kz
118      IF( lk_zdfcst  ) THEN                              ! Constant Kz (reset avt, avm[uv] to the background value)
119         avt (:,:,:) = rn_avt0 * tmask(:,:,:)
120         avmu(:,:,:) = rn_avm0 * umask(:,:,:)
121         avmv(:,:,:) = rn_avm0 * vmask(:,:,:)
122      ENDIF
123      IF( ln_rnf_mouth ) THEN                         ! increase diffusivity at rivers mouths
124         DO jk = 2, nkrnf   ;   avt(:,:,jk) = avt(:,:,jk) + 2.e0 * rn_avt_rnf * rnfmsk(:,:) * tmask(:,:,jk)   ;   END DO
125      ENDIF
126      IF( ln_zdfevd  )   CALL zdf_evd( kstp )         ! enhanced vertical eddy diffusivity
127
128      IF( lk_zdftmx  )   CALL zdf_tmx( kstp )         ! tidal vertical mixing
129
130      IF( lk_zdfddm .AND. .NOT. lk_zdfkpp )   &
131         &               CALL zdf_ddm( kstp )         ! double diffusive mixing
132
133                         CALL zdf_mxl( kstp )         ! mixed layer depth
134
135                                                      ! write TKE or GLS information in the restart file
136      IF( lrst_oce .AND. lk_zdftke )   CALL tke_rst( kstp, 'WRITE' )
137      IF( lrst_oce .AND. lk_zdfgls )   CALL gls_rst( kstp, 'WRITE' )
138      !
139      !  LATERAL  PHYSICS
140      !
141      IF( lk_ldfslp ) THEN                            ! slope of lateral mixing
142                         CALL eos( tsb, rhd, gdept_0(:,:,:) )             ! before in situ density
143         IF( ln_zps )    CALL zps_hde( kstp, jpts, tsb, gtsu, gtsv,  &    ! Partial steps: before horizontal gradient
144            &                                      rhd, gru , grv  )      ! of t, s, rd at the last ocean level
145         IF( ln_traldf_grif ) THEN                           ! before slope for Griffies operator
146                         CALL ldf_slp_grif( kstp )
147         ELSE
148                         CALL ldf_slp( kstp, rhd, rn2b )     ! before slope for Madec operator
149         ENDIF
150      ENDIF
151#if defined key_traldf_c2d
152      IF( lk_traldf_eiv )   CALL ldf_eiv( kstp )      ! eddy induced velocity coefficient
153#endif
154#if defined key_traldf_c3d && key_traldf_smag
155                          CALL ldf_tra_smag( kstp )      ! eddy induced velocity coefficient
156#  endif
157#if defined key_dynldf_c3d && key_dynldf_smag
158                          CALL ldf_dyn_smag( kstp )      ! eddy induced velocity coefficient
159#  endif
160
161
162      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
163      ! diagnostics and outputs             (ua, va, tsa used as workspace)
164      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
165      IF( lk_floats  )   CALL flo_stp( kstp )         ! drifting Floats
166      IF( lk_diahth  )   CALL dia_hth( kstp )         ! Thermocline depth (20 degres isotherm depth)
167      IF( lk_diafwb  )   CALL dia_fwb( kstp )         ! Fresh water budget diagnostics
168      IF( ln_diaptr  )   CALL dia_ptr( kstp )         ! Poleward TRansports diagnostics
169      IF( lk_diadct  )   CALL dia_dct( kstp )         ! Transports
170      IF( lk_diaar5  )   CALL dia_ar5( kstp )         ! ar5 diag
171      IF( lk_diaharm )   CALL dia_harm( kstp )        ! Tidal harmonic analysis
172                         CALL dia_wri( kstp )         ! ocean model: outputs
173
174#if defined key_top
175      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
176      ! Passive Tracer Model
177      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
178                         CALL trc_stp( kstp )         ! time-stepping
179#endif
180
181      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
182      ! Active tracers                              (ua, va used as workspace)
183      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
184                             tsa(:,:,:,:) = 0.e0            ! set tracer trends to zero
185
186      IF(  ln_asmiau .AND. &
187         & ln_trainc     )   CALL tra_asm_inc( kstp )       ! apply tracer assimilation increment
188                             CALL tra_sbc    ( kstp )       ! surface boundary condition
189      IF( ln_traqsr      )   CALL tra_qsr    ( kstp )       ! penetrative solar radiation qsr
190      IF( ln_trabbc      )   CALL tra_bbc    ( kstp )       ! bottom heat flux
191      IF( lk_trabbl      )   CALL tra_bbl    ( kstp )       ! advective (and/or diffusive) bottom boundary layer scheme
192      IF( ln_tradmp      )   CALL tra_dmp    ( kstp )       ! internal damping trends
193      IF( lk_bdy         )   CALL bdy_tra_dmp( kstp )       ! bdy damping trends
194                             CALL tra_adv    ( kstp )       ! horizontal & vertical advection
195      IF( lk_zdfkpp      )   CALL tra_kpp    ( kstp )       ! KPP non-local tracer fluxes
196                             CALL tra_ldf    ( kstp )       ! lateral mixing
197#if defined key_agrif
198      IF(.NOT. Agrif_Root()) CALL Agrif_Sponge_tra          ! tracers sponge
199#endif
200                             CALL tra_zdf    ( kstp )       ! vertical mixing and after tracer fields
201
202      IF( ln_dynhpg_imp  ) THEN                             ! semi-implicit hpg (time stepping then eos)
203         IF( ln_zdfnpc   )   CALL tra_npc( kstp )                ! update after fields by non-penetrative convection
204                             CALL tra_nxt( kstp )                ! tracer fields at next time step
205                             CALL eos    ( tsa, rhd, rhop, fsdept_n(:,:,:) )  ! Time-filtered in situ density for hpg computation
206         IF( ln_zps      )   CALL zps_hde( kstp, jpts, tsa, gtsu, gtsv,  &    ! zps: time filtered hor. derivative
207            &                                          rhd, gru , grv  )      ! of t, s, rd at the last ocean level
208
209      ELSE                                                  ! centered hpg  (eos then time stepping)
210                             CALL eos    ( tsn, rhd, rhop, fsdept_n(:,:,:) )  ! now in situ density for hpg computation
211         IF( ln_zps      )   CALL zps_hde( kstp, jpts, tsn, gtsu, gtsv,  &    ! zps: now hor. derivative
212            &                                          rhd, gru , grv  )      ! of t, s, rd at the last ocean level
213         IF( ln_zdfnpc   )   CALL tra_npc( kstp )                ! update after fields by non-penetrative convection
214                             CALL tra_nxt( kstp )                ! tracer fields at next time step
215      ENDIF
216
217      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
218      ! Dynamics                                    (tsa used as workspace)
219      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
220                               ua(:,:,:) = 0.e0             ! set dynamics trends to zero
221                               va(:,:,:) = 0.e0
222
223      IF(  ln_asmiau .AND. &
224         & ln_dyninc       )   CALL dyn_asm_inc( kstp )     ! apply dynamics assimilation increment
225      IF( ln_bkgwri )          CALL asm_bkg_wri( kstp )     ! output background fields
226      IF( ln_neptsimp )        CALL dyn_nept_cor( kstp )    ! subtract Neptune velocities (simplified)
227      IF( lk_bdy           )   CALL bdy_dyn3d_dmp(kstp )    ! bdy damping trends
228                               CALL dyn_adv( kstp )         ! advection (vector or flux form)
229                               CALL dyn_vor( kstp )         ! vorticity term including Coriolis
230                               CALL dyn_ldf( kstp )         ! lateral mixing
231      IF( ln_neptsimp )        CALL dyn_nept_cor( kstp )    ! add Neptune velocities (simplified)
232#if defined key_agrif
233      IF(.NOT. Agrif_Root())   CALL Agrif_Sponge_dyn        ! momemtum sponge
234#endif
235                               CALL dyn_hpg( kstp )         ! horizontal gradient of Hydrostatic pressure
236                               CALL dyn_bfr( kstp )         ! bottom friction
237                               CALL dyn_zdf( kstp )         ! vertical diffusion
238                               CALL dyn_spg( kstp, indic )  ! surface pressure gradient
239                               CALL dyn_nxt( kstp )         ! lateral velocity at next time step
240
241                               CALL ssh_swp( kstp )         ! swap of sea surface height
242      IF( lk_vvl           )   CALL dom_vvl_sf_swp( kstp )  ! swap of vertical scale factors
243
244      IF( ln_diahsb        )   CALL dia_hsb( kstp )         ! - ML - global conservation diagnostics
245      IF( lk_diaobs  )         CALL dia_obs( kstp )         ! obs-minus-model (assimilation) diagnostics (call after dynamics update)
246
247      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
248      ! Control and restarts
249      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
250                               CALL stp_ctl( kstp, indic )
251      IF( indic < 0        )   THEN
252                               CALL ctl_stop( 'step: indic < 0' )
253                               CALL dia_wri_state( 'output.abort', kstp )
254      ENDIF
255      IF( kstp == nit000   )   CALL iom_close( numror )     ! close input  ocean restart file
256      IF( lrst_oce         )   CALL rst_write    ( kstp )   ! write output ocean restart file
257      IF( lk_obc           )   CALL obc_rst_write( kstp )   ! write open boundary restart file
258
259      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
260      ! Trends                              (ua, va, tsa used as workspace)
261      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
262      IF( nstop == 0 ) THEN
263         IF( lk_trddyn     )   CALL trd_dwr( kstp )         ! trends: dynamics
264         IF( lk_trdtra     )   CALL trd_twr( kstp )         ! trends: active tracers
265         IF( lk_trdmld     )   CALL trd_mld( kstp )         ! trends: Mixed-layer
266         IF( lk_trdvor     )   CALL trd_vor( kstp )         ! trends: vorticity budget
267      ENDIF
268
269      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
270      ! Coupled mode
271      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
272      IF( lk_cpl           )   CALL sbc_cpl_snd( kstp )     ! coupled mode : field exchanges
273      !
274#if defined key_iomput
275      IF( kstp == nitend   )   CALL xios_context_finalize() ! needed for XIOS+AGRIF
276#endif
277      !
278      IF( nn_timing == 1 .AND.  kstp == nit000  )   CALL timing_reset
279      !
280   END SUBROUTINE stp
281
282   !!======================================================================
283END MODULE step
Note: See TracBrowser for help on using the repository browser.