New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
nemogcm.F90 in branches/2014/dev_r4650_UKMO12_CFL_diagnostic/NEMOGCM/NEMO/OPA_SRC – NEMO

source: branches/2014/dev_r4650_UKMO12_CFL_diagnostic/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 4709

Last change on this file since 4709 was 4709, checked in by timgraham, 8 years ago

Removed cpp key and added a namelist option (nn_diacfl) to the namctl namelist

  • Property svn:keywords set to Id
File size: 39.4 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  LIM sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!            3.4  ! 2011-11  (C. Harris) decomposition changes for running with CICE
31   !!                 ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32   !!----------------------------------------------------------------------
33
34   !!----------------------------------------------------------------------
35   !!   nemo_gcm       : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
36   !!   nemo_init      : initialization of the NEMO system
37   !!   nemo_ctl       : initialisation of the contol print
38   !!   nemo_closefile : close remaining open files
39   !!   nemo_alloc     : dynamical allocation
40   !!   nemo_partition : calculate MPP domain decomposition
41   !!   factorise      : calculate the factors of the no. of MPI processes
42   !!----------------------------------------------------------------------
43   USE step_oce        ! module used in the ocean time stepping module
44   USE sbc_oce         ! surface boundary condition: ocean
45   USE cla             ! cross land advection               (tra_cla routine)
46   USE domcfg          ! domain configuration               (dom_cfg routine)
47   USE mppini          ! shared/distributed memory setting (mpp_init routine)
48   USE domain          ! domain initialization             (dom_init routine)
49#if defined key_nemocice_decomp
50   USE ice_domain_size, only: nx_global, ny_global
51#endif
52   USE tideini         ! tidal components initialization   (tide_ini routine)
53   USE bdyini          ! open boundary cond. initialization (bdy_init routine)
54   USE bdydta          ! open boundary cond. initialization (bdy_dta_init routine)
55   USE bdytides        ! open boundary cond. initialization (bdytide_init routine)
56   USE istate          ! initial state setting          (istate_init routine)
57   USE ldfdyn          ! lateral viscosity setting      (ldfdyn_init routine)
58   USE ldftra          ! lateral diffusivity setting    (ldftra_init routine)
59   USE zdfini          ! vertical physics setting          (zdf_init routine)
60   USE phycst          ! physical constant                  (par_cst routine)
61   USE trdmod          ! momentum/tracers trends       (trd_mod_init routine)
62   USE asminc          ! assimilation increments     
63   USE asmbkg          ! writing out state trajectory
64   USE diaptr          ! poleward transports           (dia_ptr_init routine)
65   USE diadct          ! sections transports           (dia_dct_init routine)
66   USE diaobs          ! Observation diagnostics       (dia_obs_init routine)
67   USE diacfl          ! CFL diagnostics               (dia_cfl_init routine)
68   USE lib_fortran     ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
69   USE step            ! NEMO time-stepping                 (stp     routine)
70   USE icbini          ! handle bergs, initialisation
71   USE icbstp          ! handle bergs, calving, themodynamics and transport
72#if defined key_oasis3
73   USE cpl_oasis3      ! OASIS3 coupling
74#elif defined key_oasis4
75   USE cpl_oasis4      ! OASIS4 coupling (not working)
76#endif
77   USE c1d             ! 1D configuration
78   USE step_c1d        ! Time stepping loop for the 1D configuration
79   USE dyndmp          ! Momentum damping
80#if defined key_top
81   USE trcini          ! passive tracer initialisation
82#endif
83   USE lib_mpp         ! distributed memory computing
84#if defined key_iomput
85   USE xios
86#endif
87   USE sbctide, ONLY: lk_tide
88   USE crsini          ! initialise grid coarsening utility
89   USE lbcnfd, ONLY: isendto, nsndto, nfsloop, nfeloop ! Setup of north fold exchanges
90
91   IMPLICIT NONE
92   PRIVATE
93
94   PUBLIC   nemo_gcm    ! called by model.F90
95   PUBLIC   nemo_init   ! needed by AGRIF
96   PUBLIC   nemo_alloc  ! needed by TAM
97
98   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
99
100   !!----------------------------------------------------------------------
101   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
102   !! $Id$
103   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
104   !!----------------------------------------------------------------------
105CONTAINS
106
107   SUBROUTINE nemo_gcm
108      !!----------------------------------------------------------------------
109      !!                     ***  ROUTINE nemo_gcm  ***
110      !!
111      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
112      !!              curvilinear mesh on the sphere.
113      !!
114      !! ** Method  : - model general initialization
115      !!              - launch the time-stepping (stp routine)
116      !!              - finalize the run by closing files and communications
117      !!
118      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
119      !!              Madec, 2008, internal report, IPSL.
120      !!----------------------------------------------------------------------
121      INTEGER ::   istp       ! time step index
122      !!----------------------------------------------------------------------
123      !
124
125#if defined key_agrif
126      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
127#endif
128
129      !                            !-----------------------!
130      CALL nemo_init               !==  Initialisations  ==!
131      !                            !-----------------------!
132#if defined key_agrif
133      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
134      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
135# if defined key_top
136      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
137# endif
138# if defined key_lim2
139      CALL Agrif_Declare_Var_lim2  !  "      "   "   "      "  LIM
140# endif
141#endif
142
143      ! check that all process are still there... If some process have an error,
144      ! they will never enter in step and other processes will wait until the end of the cpu time!
145      IF( lk_mpp )   CALL mpp_max( nstop )
146
147      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
148
149      !                            !-----------------------!
150      !                            !==   time stepping   ==!
151      !                            !-----------------------!
152      istp = nit000
153#if defined key_c1d
154         DO WHILE ( istp <= nitend .AND. nstop == 0 )
155            CALL stp_c1d( istp )
156            istp = istp + 1
157         END DO
158#else
159          IF( lk_asminc ) THEN
160             IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 )    ! Output background fields
161             IF( ln_asmdin ) THEN                        ! Direct initialization
162                IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 )    ! Tracers
163                IF( ln_dyninc ) CALL dyn_asm_inc( nit000 - 1 )    ! Dynamics
164                IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 )    ! SSH
165             ENDIF
166          ENDIF
167
168         DO WHILE ( istp <= nitend .AND. nstop == 0 )
169
170#if defined key_agrif
171            CALL Agrif_Step( stp )           ! AGRIF: time stepping
172#else
173            CALL stp( istp )                 ! standard time stepping
174#endif
175
176            istp = istp + 1
177            IF( lk_mpp )   CALL mpp_max( nstop )
178         END DO
179#endif
180
181      IF( lk_diaobs   )   CALL dia_obs_wri
182      !
183      IF( ln_icebergs )   CALL icb_end( nitend )
184
185      !                            !------------------------!
186      !                            !==  finalize the run  ==!
187      !                            !------------------------!
188      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
189      !
190      IF( nstop /= 0 .AND. lwp ) THEN   ! error print
191         WRITE(numout,cform_err)
192         WRITE(numout,*) nstop, ' error have been found'
193      ENDIF
194      !
195#if defined key_agrif
196      CALL Agrif_ParentGrid_To_ChildGrid()
197      IF( lk_diaobs ) CALL dia_obs_wri
198      IF( nn_timing == 1 )   CALL timing_finalize
199      CALL Agrif_ChildGrid_To_ParentGrid()
200#endif
201      IF( nn_timing == 1 )   CALL timing_finalize
202      !
203      CALL nemo_closefile
204#if defined key_iomput
205      CALL xios_finalize                ! end mpp communications with xios
206# if defined key_oasis3 || defined key_oasis4
207      CALL cpl_prism_finalize           ! end coupling and mpp communications with OASIS
208# endif
209#else
210# if defined key_oasis3 || defined key_oasis4
211      CALL cpl_prism_finalize           ! end coupling and mpp communications with OASIS
212# else
213      IF( lk_mpp )   CALL mppstop       ! end mpp communications
214# endif
215#endif
216      !
217   END SUBROUTINE nemo_gcm
218
219
220   SUBROUTINE nemo_init
221      !!----------------------------------------------------------------------
222      !!                     ***  ROUTINE nemo_init  ***
223      !!
224      !! ** Purpose :   initialization of the NEMO GCM
225      !!----------------------------------------------------------------------
226      INTEGER ::   ji            ! dummy loop indices
227      INTEGER ::   ilocal_comm   ! local integer
228      INTEGER ::   ios
229      CHARACTER(len=80), DIMENSION(16) ::   cltxt
230      !!
231      NAMELIST/namctl/ ln_ctl, nn_print, nn_ictls, nn_ictle,   &
232         &             nn_isplt, nn_jsplt, nn_jctls, nn_jctle,   &
233         &             nn_bench, nn_timing, nn_diacfl
234      NAMELIST/namcfg/ cp_cfg, cp_cfz, jp_cfg, jpidta, jpjdta, jpkdta, jpiglo, jpjglo, &
235         &             jpizoom, jpjzoom, jperio
236      !!----------------------------------------------------------------------
237      !
238      cltxt = ''
239      !
240      !                             ! Open reference namelist and configuration namelist files
241      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
242      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
243      !
244      REWIND( numnam_ref )              ! Namelist namctl in reference namelist : Control prints & Benchmark
245      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
246901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
247
248      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist : Control prints & Benchmark
249      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
250902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
251
252      !
253      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist : Control prints & Benchmark
254      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
255903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
256
257      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist : Control prints & Benchmark
258      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
259904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
260
261! Force values for AGRIF zoom (cf. agrif_user.F90)
262#if defined key_agrif
263   IF( .NOT. Agrif_Root() ) THEN
264      jpiglo  = nbcellsx + 2 + 2*nbghostcells
265      jpjglo  = nbcellsy + 2 + 2*nbghostcells
266      jpi     = ( jpiglo-2*jpreci + (jpni-1+0) ) / jpni + 2*jpreci
267      jpj     = ( jpjglo-2*jprecj + (jpnj-1+0) ) / jpnj + 2*jprecj
268      jpidta  = jpiglo
269      jpjdta  = jpjglo
270      jpizoom = 1
271      jpjzoom = 1
272      nperio  = 0
273      jperio  = 0
274   ENDIF
275#endif
276      !
277      !                             !--------------------------------------------!
278      !                             !  set communicator & select the local node  !
279      !                             !  NB: mynode also opens output.namelist.dyn !
280      !                             !      on unit number numond on first proc   !
281      !                             !--------------------------------------------!
282#if defined key_iomput
283      IF( Agrif_Root() ) THEN
284# if defined key_oasis3 || defined key_oasis4
285         CALL cpl_prism_init( ilocal_comm )      ! nemo local communicator given by oasis
286         CALL xios_initialize( "oceanx",local_comm=ilocal_comm )
287# else
288         CALL  xios_initialize( "nemo",return_comm=ilocal_comm )
289# endif
290      ENDIF
291      narea = mynode( cltxt, numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )   ! Nodes selection
292#else
293# if defined key_oasis3 || defined key_oasis4
294      IF( Agrif_Root() ) THEN
295         CALL cpl_prism_init( ilocal_comm )                 ! nemo local communicator given by oasis
296      ENDIF
297      narea = mynode( cltxt, numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )   ! Nodes selection (control print return in cltxt)
298# else
299      ilocal_comm = 0
300      narea = mynode( cltxt, numnam_ref, numnam_cfg, numond , nstop )                 ! Nodes selection (control print return in cltxt)
301# endif
302#endif
303      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
304
305      lwm = (narea == 1)                                    ! control of output namelists
306      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
307
308      IF(lwm) THEN
309         ! write merged namelists from earlier to output namelist now that the
310         ! file has been opened in call to mynode. nammpp has already been
311         ! written in mynode (if lk_mpp_mpi)
312         WRITE( numond, namctl )
313         WRITE( numond, namcfg )
314      ENDIF
315
316      ! If dimensions of processor grid weren't specified in the namelist file
317      ! then we calculate them here now that we have our communicator size
318      IF( (jpni < 1) .OR. (jpnj < 1) )THEN
319#if   defined key_mpp_mpi
320         IF( Agrif_Root() ) CALL nemo_partition(mppsize)
321#else
322         jpni  = 1
323         jpnj  = 1
324         jpnij = jpni*jpnj
325#endif
326      END IF
327
328      ! Calculate domain dimensions given calculated jpni and jpnj
329      ! This used to be done in par_oce.F90 when they were parameters rather
330      ! than variables
331      IF( Agrif_Root() ) THEN
332#if defined key_nemocice_decomp
333         jpi = ( nx_global+2-2*jpreci + (jpni-1) ) / jpni + 2*jpreci ! first  dim.
334         jpj = ( ny_global+2-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj ! second dim.
335#else
336         jpi = ( jpiglo-2*jpreci + (jpni-1) ) / jpni + 2*jpreci   ! first  dim.
337         jpj = ( jpjglo-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj   ! second dim.
338#endif
339      ENDIF
340         jpk = jpkdta                                             ! third dim
341         jpim1 = jpi-1                                            ! inner domain indices
342         jpjm1 = jpj-1                                            !   "           "
343         jpkm1 = jpk-1                                            !   "           "
344         jpij  = jpi*jpj                                          !  jpi x j
345
346      IF(lwp) THEN                            ! open listing units
347         !
348         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
349         !
350         WRITE(numout,*)
351         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
352         WRITE(numout,*) '                       NEMO team'
353         WRITE(numout,*) '            Ocean General Circulation Model'
354         WRITE(numout,*) '                  version 3.4  (2011) '
355         WRITE(numout,*)
356         WRITE(numout,*)
357         DO ji = 1, SIZE(cltxt)
358            IF( TRIM(cltxt(ji)) /= '' )   WRITE(numout,*) cltxt(ji)      ! control print of mynode
359         END DO
360         WRITE(numout,cform_aaa)                                         ! Flag AAAAAAA
361         !
362      ENDIF
363
364      ! Now we know the dimensions of the grid and numout has been set we can
365      ! allocate arrays
366      CALL nemo_alloc()
367
368      !                             !-------------------------------!
369      !                             !  NEMO general initialization  !
370      !                             !-------------------------------!
371
372      CALL nemo_ctl                          ! Control prints & Benchmark
373
374      !                                      ! Domain decomposition
375      IF( jpni*jpnj == jpnij ) THEN   ;   CALL mpp_init      ! standard cutting out
376      ELSE                            ;   CALL mpp_init2     ! eliminate land processors
377      ENDIF
378      !
379      IF( nn_timing == 1 )  CALL timing_init
380      !
381      !                                      ! General initialization
382                            CALL     phy_cst    ! Physical constants
383                            CALL     eos_init   ! Equation of state
384      IF( lk_c1d        )   CALL     c1d_init   ! 1D column configuration
385                            CALL     dom_cfg    ! Domain configuration
386                            CALL     dom_init   ! Domain
387
388      IF( ln_nnogather )    CALL nemo_northcomms   ! Initialise the northfold neighbour lists (must be done after the masks are defined)
389
390      IF( ln_ctl        )   CALL prt_ctl_init   ! Print control
391
392                            CALL  istate_init   ! ocean initial state (Dynamics and tracers)
393
394      IF( lk_tide       )   CALL    tide_init( nit000 )    ! Initialisation of the tidal harmonics
395
396      IF( lk_bdy        )   CALL      bdy_init  ! Open boundaries initialisation
397      IF( lk_bdy        )   CALL  bdy_dta_init  ! Open boundaries initialisation of external data arrays
398      IF( lk_bdy .AND. lk_tide )   &
399         &                  CALL  bdytide_init  ! Open boundaries initialisation of tidal harmonic forcing
400
401                            CALL dyn_nept_init  ! simplified form of Neptune effect
402
403      !     
404      IF( ln_crs        )   CALL     crs_init   ! Domain initialization of coarsened grid
405      !
406                                ! Ocean physics
407                            CALL     sbc_init   ! Forcings : surface module
408      !                                         ! Vertical physics
409
410                            CALL     zdf_init      ! namelist read
411
412                            CALL zdf_bfr_init      ! bottom friction
413
414      IF( lk_zdfric     )   CALL zdf_ric_init      ! Richardson number dependent Kz
415      IF( lk_zdftke     )   CALL zdf_tke_init      ! TKE closure scheme
416      IF( lk_zdfgls     )   CALL zdf_gls_init      ! GLS closure scheme
417      IF( lk_zdfkpp     )   CALL zdf_kpp_init      ! KPP closure scheme
418      IF( lk_zdftmx     )   CALL zdf_tmx_init      ! tidal vertical mixing
419      IF( lk_zdfddm .AND. .NOT. lk_zdfkpp )   &
420         &                  CALL zdf_ddm_init      ! double diffusive mixing
421      !                                         ! Lateral physics
422                            CALL ldf_tra_init      ! Lateral ocean tracer physics
423                            CALL ldf_dyn_init      ! Lateral ocean momentum physics
424      IF( lk_ldfslp     )   CALL ldf_slp_init      ! slope of lateral mixing
425
426      !                                     ! Active tracers
427                            CALL tra_qsr_init   ! penetrative solar radiation qsr
428                            CALL tra_bbc_init   ! bottom heat flux
429      IF( lk_trabbl     )   CALL tra_bbl_init   ! advective (and/or diffusive) bottom boundary layer scheme
430                            CALL tra_dmp_init   ! internal damping trends- tracers
431                            CALL tra_adv_init   ! horizontal & vertical advection
432                            CALL tra_ldf_init   ! lateral mixing
433                            CALL tra_zdf_init   ! vertical mixing and after tracer fields
434
435      !                                     ! Dynamics
436      IF( lk_c1d        )   CALL dyn_dmp_init   ! internal damping trends- momentum
437                            CALL dyn_adv_init   ! advection (vector or flux form)
438                            CALL dyn_vor_init   ! vorticity term including Coriolis
439                            CALL dyn_ldf_init   ! lateral mixing
440                            CALL dyn_hpg_init   ! horizontal gradient of Hydrostatic pressure
441                            CALL dyn_zdf_init   ! vertical diffusion
442                            CALL dyn_spg_init   ! surface pressure gradient
443
444      !                                     ! Misc. options
445      IF( nn_cla == 1 .AND. cp_cfg == 'orca' .AND. jp_cfg == 2 )   CALL cla_init       ! Cross Land Advection
446                            CALL icb_init( rdt, nit000)   ! initialise icebergs instance
447     
448#if defined key_top
449      !                                     ! Passive tracers
450                            CALL     trc_init
451#endif
452      !
453 
454                                            ! Diagnostics
455      IF( lk_floats     )   CALL     flo_init   ! drifting Floats
456                            CALL dia_cfl_init   ! Initialise CFL diagnostics
457      IF( lk_diaar5     )   CALL dia_ar5_init   ! ar5 diag
458                            CALL dia_ptr_init   ! Poleward TRansports initialization
459      IF( lk_diadct     )   CALL dia_dct_init   ! Sections tranports
460                            CALL dia_hsb_init   ! heat content, salt content and volume budgets
461                            CALL trd_mod_init   ! Mixed-layer/Vorticity/Integral constraints trends
462      IF( lk_diaobs     ) THEN                  ! Observation & model comparison
463                            CALL dia_obs_init            ! Initialize observational data
464                            CALL dia_obs( nit000 - 1 )   ! Observation operator for restart
465      ENDIF
466      !                                     ! Assimilation increments
467      IF( lk_asminc     )   CALL asm_inc_init   ! Initialize assimilation increments
468      IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
469      !
470   END SUBROUTINE nemo_init
471
472
473   SUBROUTINE nemo_ctl
474      !!----------------------------------------------------------------------
475      !!                     ***  ROUTINE nemo_ctl  ***
476      !!
477      !! ** Purpose :   control print setting
478      !!
479      !! ** Method  : - print namctl information and check some consistencies
480      !!----------------------------------------------------------------------
481      !
482      IF(lwp) THEN                  ! control print
483         WRITE(numout,*)
484         WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
485         WRITE(numout,*) '~~~~~~~ '
486         WRITE(numout,*) '   Namelist namctl'
487         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
488         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
489         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
490         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
491         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
492         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
493         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
494         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
495         WRITE(numout,*) '      benchmark parameter (0/1)       nn_bench   = ', nn_bench
496         WRITE(numout,*) '      timing activated    (0/1)       nn_timing  = ', nn_timing
497      ENDIF
498      !
499      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
500      nictls    = nn_ictls
501      nictle    = nn_ictle
502      njctls    = nn_jctls
503      njctle    = nn_jctle
504      isplt     = nn_isplt
505      jsplt     = nn_jsplt
506      nbench    = nn_bench
507
508      IF(lwp) THEN                  ! control print
509         WRITE(numout,*)
510         WRITE(numout,*) 'namcfg  : configuration initialization through namelist read'
511         WRITE(numout,*) '~~~~~~~ '
512         WRITE(numout,*) '   Namelist namcfg'
513         WRITE(numout,*) '      configuration name              cp_cfg      = ', TRIM(cp_cfg)
514         WRITE(numout,*) '      configuration zoom name         cp_cfz      = ', TRIM(cp_cfz)
515         WRITE(numout,*) '      configuration resolution        jp_cfg      = ', jp_cfg
516         WRITE(numout,*) '      1st lateral dimension ( >= jpi ) jpidta     = ', jpidta
517         WRITE(numout,*) '      2nd    "         "    ( >= jpj ) jpjdta     = ', jpjdta
518         WRITE(numout,*) '      3nd    "         "               jpkdta     = ', jpkdta
519         WRITE(numout,*) '      1st dimension of global domain in i jpiglo  = ', jpiglo
520         WRITE(numout,*) '      2nd    -                  -    in j jpjglo  = ', jpjglo
521         WRITE(numout,*) '      left bottom i index of the zoom (in data domain) jpizoom = ', jpizoom
522         WRITE(numout,*) '      left bottom j index of the zoom (in data domain) jpizoom = ', jpjzoom
523         WRITE(numout,*) '      lateral cond. type (between 0 and 6) jperio = ', jperio   
524      ENDIF
525      !                             ! Parameter control
526      !
527      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
528         IF( lk_mpp .AND. jpnij > 1 ) THEN
529            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
530         ELSE
531            IF( isplt == 1 .AND. jsplt == 1  ) THEN
532               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
533                  &           ' - the print control will be done over the whole domain' )
534            ENDIF
535            ijsplt = isplt * jsplt            ! total number of processors ijsplt
536         ENDIF
537         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
538         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
539         !
540         !                              ! indices used for the SUM control
541         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
542            lsp_area = .FALSE.
543         ELSE                                             ! print control done over a specific  area
544            lsp_area = .TRUE.
545            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
546               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
547               nictls = 1
548            ENDIF
549            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
550               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
551               nictle = jpiglo
552            ENDIF
553            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
554               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
555               njctls = 1
556            ENDIF
557            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
558               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
559               njctle = jpjglo
560            ENDIF
561         ENDIF
562      ENDIF
563      !
564      IF( nbench == 1 ) THEN              ! Benchmark
565         SELECT CASE ( cp_cfg )
566         CASE ( 'gyre' )   ;   CALL ctl_warn( ' The Benchmark is activated ' )
567         CASE DEFAULT      ;   CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:',   &
568            &                                 ' cp_cfg = "gyre" in namelist &namcfg or set nbench = 0' )
569         END SELECT
570      ENDIF
571      !
572      IF( lk_c1d .AND. .NOT.lk_iomput )   CALL ctl_stop( 'nemo_ctl: The 1D configuration must be used ',   &
573         &                                               'with the IOM Input/Output manager. '         ,   &
574         &                                               'Compile with key_iomput enabled' )
575      !
576      IF( 1_wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ',  &
577         &                                               'f2003 standard. '                              ,  &
578         &                                               'Compile with key_nosignedzero enabled' )
579      !
580   END SUBROUTINE nemo_ctl
581
582
583   SUBROUTINE nemo_closefile
584      !!----------------------------------------------------------------------
585      !!                     ***  ROUTINE nemo_closefile  ***
586      !!
587      !! ** Purpose :   Close the files
588      !!----------------------------------------------------------------------
589      !
590      IF( lk_mpp )   CALL mppsync
591      !
592      CALL iom_close                                 ! close all input/output files managed by iom_*
593      !
594      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
595      IF( numsol          /= -1 )   CLOSE( numsol          )   ! solver file
596      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
597      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
598      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
599      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
600      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
601      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
602      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
603      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
604      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
605      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
606      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
607
608      !
609      numout = 6                                     ! redefine numout in case it is used after this point...
610      !
611   END SUBROUTINE nemo_closefile
612
613
614   SUBROUTINE nemo_alloc
615      !!----------------------------------------------------------------------
616      !!                     ***  ROUTINE nemo_alloc  ***
617      !!
618      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
619      !!
620      !! ** Method  :
621      !!----------------------------------------------------------------------
622      USE diawri    , ONLY: dia_wri_alloc
623      USE dom_oce   , ONLY: dom_oce_alloc
624      USE ldfdyn_oce, ONLY: ldfdyn_oce_alloc
625      USE ldftra_oce, ONLY: ldftra_oce_alloc
626      USE trc_oce   , ONLY: trc_oce_alloc
627#if defined key_diadct 
628      USE diadct    , ONLY: diadct_alloc 
629#endif 
630#if defined key_bdy
631      USE bdy_oce   , ONLY: bdy_oce_alloc
632#endif
633      !
634      INTEGER :: ierr
635      !!----------------------------------------------------------------------
636      !
637      ierr =        oce_alloc       ()          ! ocean
638      ierr = ierr + dia_wri_alloc   ()
639      ierr = ierr + dom_oce_alloc   ()          ! ocean domain
640      ierr = ierr + ldfdyn_oce_alloc()          ! ocean lateral  physics : dynamics
641      ierr = ierr + ldftra_oce_alloc()          ! ocean lateral  physics : tracers
642      ierr = ierr + zdf_oce_alloc   ()          ! ocean vertical physics
643      !
644      ierr = ierr + trc_oce_alloc   ()          ! shared TRC / TRA arrays
645      !
646#if defined key_diadct 
647      ierr = ierr + diadct_alloc    ()          !
648#endif 
649#if defined key_bdy
650      ierr = ierr + bdy_oce_alloc   ()          ! bdy masks (incl. initialization)
651#endif
652      !
653      IF( lk_mpp    )   CALL mpp_sum( ierr )
654      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
655      !
656   END SUBROUTINE nemo_alloc
657
658
659   SUBROUTINE nemo_partition( num_pes )
660      !!----------------------------------------------------------------------
661      !!                 ***  ROUTINE nemo_partition  ***
662      !!
663      !! ** Purpose :
664      !!
665      !! ** Method  :
666      !!----------------------------------------------------------------------
667      INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have
668      !
669      INTEGER, PARAMETER :: nfactmax = 20
670      INTEGER :: nfact ! The no. of factors returned
671      INTEGER :: ierr  ! Error flag
672      INTEGER :: ji
673      INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
674      INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
675      !!----------------------------------------------------------------------
676
677      ierr = 0
678
679      CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
680
681      IF( nfact <= 1 ) THEN
682         WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
683         WRITE (numout, *) '       : using grid of ',num_pes,' x 1'
684         jpnj = 1
685         jpni = num_pes
686      ELSE
687         ! Search through factors for the pair that are closest in value
688         mindiff = 1000000
689         imin    = 1
690         DO ji = 1, nfact-1, 2
691            idiff = ABS( ifact(ji) - ifact(ji+1) )
692            IF( idiff < mindiff ) THEN
693               mindiff = idiff
694               imin = ji
695            ENDIF
696         END DO
697         jpnj = ifact(imin)
698         jpni = ifact(imin + 1)
699      ENDIF
700      !
701      jpnij = jpni*jpnj
702      !
703   END SUBROUTINE nemo_partition
704
705
706   SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
707      !!----------------------------------------------------------------------
708      !!                     ***  ROUTINE factorise  ***
709      !!
710      !! ** Purpose :   return the prime factors of n.
711      !!                knfax factors are returned in array kfax which is of
712      !!                maximum dimension kmaxfax.
713      !! ** Method  :
714      !!----------------------------------------------------------------------
715      INTEGER                    , INTENT(in   ) ::   kn, kmaxfax
716      INTEGER                    , INTENT(  out) ::   kerr, knfax
717      INTEGER, DIMENSION(kmaxfax), INTENT(  out) ::   kfax
718      !
719      INTEGER :: ifac, jl, inu
720      INTEGER, PARAMETER :: ntest = 14
721      INTEGER :: ilfax(ntest)
722
723      ! lfax contains the set of allowed factors.
724      data (ilfax(jl),jl=1,ntest) / 16384, 8192, 4096, 2048, 1024, 512, 256,  &
725         &                            128,   64,   32,   16,    8,   4,   2  /
726      !!----------------------------------------------------------------------
727
728      ! Clear the error flag and initialise output vars
729      kerr = 0
730      kfax = 1
731      knfax = 0
732
733      ! Find the factors of n.
734      IF( kn == 1 )   GOTO 20
735
736      ! nu holds the unfactorised part of the number.
737      ! knfax holds the number of factors found.
738      ! l points to the allowed factor list.
739      ! ifac holds the current factor.
740
741      inu   = kn
742      knfax = 0
743
744      DO jl = ntest, 1, -1
745         !
746         ifac = ilfax(jl)
747         IF( ifac > inu )   CYCLE
748
749         ! Test whether the factor will divide.
750
751         IF( MOD(inu,ifac) == 0 ) THEN
752            !
753            knfax = knfax + 1            ! Add the factor to the list
754            IF( knfax > kmaxfax ) THEN
755               kerr = 6
756               write (*,*) 'FACTOR: insufficient space in factor array ', knfax
757               return
758            ENDIF
759            kfax(knfax) = ifac
760            ! Store the other factor that goes with this one
761            knfax = knfax + 1
762            kfax(knfax) = inu / ifac
763            !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
764         ENDIF
765         !
766      END DO
767
768   20 CONTINUE      ! Label 20 is the exit point from the factor search loop.
769      !
770   END SUBROUTINE factorise
771
772#if defined key_mpp_mpi
773   SUBROUTINE nemo_northcomms
774      !!======================================================================
775      !!                     ***  ROUTINE  nemo_northcomms  ***
776      !! nemo_northcomms    :  Setup for north fold exchanges with explicit
777      !!                       point-to-point messaging
778      !!=====================================================================
779      !!----------------------------------------------------------------------
780      !!
781      !! ** Purpose :   Initialization of the northern neighbours lists.
782      !!----------------------------------------------------------------------
783      !!    1.0  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE)
784      !!    2.0  ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S. Mocavero, CMCC)
785      !!----------------------------------------------------------------------
786
787      INTEGER  ::   sxM, dxM, sxT, dxT, jn
788      INTEGER  ::   njmppmax
789
790      njmppmax = MAXVAL( njmppt )
791   
792      !initializes the north-fold communication variables
793      isendto(:) = 0
794      nsndto = 0
795
796      !if I am a process in the north
797      IF ( njmpp == njmppmax ) THEN
798          !sxM is the first point (in the global domain) needed to compute the
799          !north-fold for the current process
800          sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
801          !dxM is the last point (in the global domain) needed to compute the
802          !north-fold for the current process
803          dxM = jpiglo - nimppt(narea) + 2
804
805          !loop over the other north-fold processes to find the processes
806          !managing the points belonging to the sxT-dxT range
807 
808          DO jn = 1, jpni
809                !sxT is the first point (in the global domain) of the jn
810                !process
811                sxT = nfiimpp(jn, jpnj)
812                !dxT is the last point (in the global domain) of the jn
813                !process
814                dxT = nfiimpp(jn, jpnj) + nfilcit(jn, jpnj) - 1
815                IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
816                   nsndto = nsndto + 1
817                     isendto(nsndto) = jn
818                ELSEIF ((sxM .le. sxT) .AND. (dxM .ge. dxT)) THEN
819                   nsndto = nsndto + 1
820                     isendto(nsndto) = jn
821                ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
822                   nsndto = nsndto + 1
823                     isendto(nsndto) = jn
824                END IF
825          END DO
826          nfsloop = 1
827          nfeloop = nlci
828          DO jn = 2,jpni-1
829           IF(nfipproc(jn,jpnj) .eq. (narea - 1)) THEN
830              IF (nfipproc(jn - 1 ,jpnj) .eq. -1) THEN
831                 nfsloop = nldi
832              ENDIF
833              IF (nfipproc(jn + 1,jpnj) .eq. -1) THEN
834                 nfeloop = nlei
835              ENDIF
836           ENDIF
837        END DO
838
839      ENDIF
840      l_north_nogather = .TRUE.
841   END SUBROUTINE nemo_northcomms
842#else
843   SUBROUTINE nemo_northcomms      ! Dummy routine
844      WRITE(*,*) 'nemo_northcomms: You should not have seen this print! error?'
845   END SUBROUTINE nemo_northcomms
846#endif
847   !!======================================================================
848END MODULE nemogcm
849
850
Note: See TracBrowser for help on using the repository browser.