source: branches/2015/dev_r5044_CNRS_LIM3CLEAN/NEMOGCM/NEMO/LIM_SRC_3/limthd_lac.F90 @ 5047

Last change on this file since 5047 was 5047, checked in by clem, 7 years ago

LIM3 cleaning (1): namelist

  • Property svn:keywords set to Id
File size: 26.1 KB
Line 
1MODULE limthd_lac
2   !!======================================================================
3   !!                       ***  MODULE limthd_lac   ***
4   !!                lateral thermodynamic growth of the ice
5   !!======================================================================
6   !! History :  LIM  ! 2005-12 (M. Vancoppenolle)  Original code
7   !!             -   ! 2006-01 (M. Vancoppenolle)  add ITD
8   !!            3.0  ! 2007-07 (M. Vancoppenolle)  Mass and energy conservation tested
9   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
10   !!----------------------------------------------------------------------
11#if defined key_lim3
12   !!----------------------------------------------------------------------
13   !!   'key_lim3'                                      LIM3 sea-ice model
14   !!----------------------------------------------------------------------
15   !!   lim_lat_acr   : lateral accretion of ice
16   !!----------------------------------------------------------------------
17   USE par_oce        ! ocean parameters
18   USE dom_oce        ! domain variables
19   USE phycst         ! physical constants
20   USE sbc_oce        ! Surface boundary condition: ocean fields
21   USE sbc_ice        ! Surface boundary condition: ice fields
22   USE thd_ice        ! LIM thermodynamics
23   USE dom_ice        ! LIM domain
24   USE par_ice        ! LIM parameters
25   USE ice            ! LIM variables
26   USE limtab         ! LIM 2D <==> 1D
27   USE limcons        ! LIM conservation
28   USE in_out_manager ! I/O manager
29   USE lib_mpp        ! MPP library
30   USE wrk_nemo       ! work arrays
31   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
32   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
33   USE limthd_ent
34
35   IMPLICIT NONE
36   PRIVATE
37
38   PUBLIC lim_thd_lac     ! called by lim_thd
39
40   !!----------------------------------------------------------------------
41   !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011)
42   !! $Id$
43   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE lim_thd_lac
48      !!-------------------------------------------------------------------
49      !!               ***   ROUTINE lim_thd_lac  ***
50      !! 
51      !! ** Purpose : Computation of the evolution of the ice thickness and
52      !!      concentration as a function of the heat balance in the leads.
53      !!      It is only used for lateral accretion
54      !!       
55      !! ** Method  : Ice is formed in the open water when ocean lose heat
56      !!      (heat budget of open water Bl is negative) .
57      !!      Computation of the increase of 1-A (ice concentration) fol-
58      !!      lowing the law :
59      !!      (dA/dt)acc = F[ (1-A)/(1-a) ] * [ Bl / (Li*h0) ]
60      !!       where - h0 is the thickness of ice created in the lead
61      !!             - a is a minimum fraction for leads
62      !!             - F is a monotonic non-increasing function defined as:
63      !!                  F(X)=( 1 - X**exld )**(1.0/exld)
64      !!             - exld is the exponent closure rate (=2 default val.)
65      !!
66      !! ** Action : - Adjustment of snow and ice thicknesses and heat
67      !!                content in brine pockets
68      !!             - Updating ice internal temperature
69      !!             - Computation of variation of ice volume and mass
70      !!             - Computation of frldb after lateral accretion and
71      !!               update ht_s_1d, ht_i_1d and tbif_1d(:,:)     
72      !!------------------------------------------------------------------------
73      INTEGER ::   ji,jj,jk,jl      ! dummy loop indices
74      INTEGER ::   nbpac            ! local integers
75      INTEGER ::   ii, ij, iter     !   -       -
76      REAL(wp)  ::   ztmelts, zdv, zfrazb, zweight, zde                         ! local scalars
77      REAL(wp) ::   zgamafr, zvfrx, zvgx, ztaux, ztwogp, zf , zhicol_new        !   -      -
78      REAL(wp) ::   ztenagm, zvfry, zvgy, ztauy, zvrel2, zfp, zsqcd , zhicrit   !   -      -
79      LOGICAL  ::   iterate_frazil   ! iterate frazil ice collection thickness
80      CHARACTER (len = 15) :: fieldid
81
82      REAL(wp) ::   zQm          ! enthalpy exchanged with the ocean (J/m2, >0 towards ocean)
83      REAL(wp) ::   zEi          ! sea ice specific enthalpy (J/kg)
84      REAL(wp) ::   zEw          ! seawater specific enthalpy (J/kg)
85      REAL(wp) ::   zfmdt        ! mass flux x time step (kg/m2, >0 towards ocean)
86     
87      REAL(wp) ::   zv_newfra
88 
89      INTEGER , POINTER, DIMENSION(:) ::   jcat        ! indexes of categories where new ice grows
90      REAL(wp), POINTER, DIMENSION(:) ::   zswinew     ! switch for new ice or not
91
92      REAL(wp), POINTER, DIMENSION(:) ::   zv_newice   ! volume of accreted ice
93      REAL(wp), POINTER, DIMENSION(:) ::   za_newice   ! fractional area of accreted ice
94      REAL(wp), POINTER, DIMENSION(:) ::   zh_newice   ! thickness of accreted ice
95      REAL(wp), POINTER, DIMENSION(:) ::   ze_newice   ! heat content of accreted ice
96      REAL(wp), POINTER, DIMENSION(:) ::   zs_newice   ! salinity of accreted ice
97      REAL(wp), POINTER, DIMENSION(:) ::   zo_newice   ! age of accreted ice
98      REAL(wp), POINTER, DIMENSION(:) ::   zdv_res     ! residual volume in case of excessive heat budget
99      REAL(wp), POINTER, DIMENSION(:) ::   zda_res     ! residual area in case of excessive heat budget
100      REAL(wp), POINTER, DIMENSION(:) ::   zat_i_1d    ! total ice fraction   
101      REAL(wp), POINTER, DIMENSION(:) ::   zv_frazb    ! accretion of frazil ice at the ice bottom
102      REAL(wp), POINTER, DIMENSION(:) ::   zvrel_1d    ! relative ice / frazil velocity (1D vector)
103
104      REAL(wp), POINTER, DIMENSION(:,:) ::   zv_b      ! old volume of ice in category jl
105      REAL(wp), POINTER, DIMENSION(:,:) ::   za_b      ! old area of ice in category jl
106      REAL(wp), POINTER, DIMENSION(:,:) ::   za_i_1d   ! 1-D version of a_i
107      REAL(wp), POINTER, DIMENSION(:,:) ::   zv_i_1d   ! 1-D version of v_i
108      REAL(wp), POINTER, DIMENSION(:,:) ::   zoa_i_1d  ! 1-D version of oa_i
109      REAL(wp), POINTER, DIMENSION(:,:) ::   zsmv_i_1d ! 1-D version of smv_i
110
111      REAL(wp), POINTER, DIMENSION(:,:,:) ::   ze_i_1d   !: 1-D version of e_i
112
113      REAL(wp), POINTER, DIMENSION(:,:) ::   zvrel                   ! relative ice / frazil velocity
114
115      REAL(wp) :: zcai = 1.4e-3_wp
116      !!-----------------------------------------------------------------------!
117
118      CALL wrk_alloc( jpij, jcat )   ! integer
119      CALL wrk_alloc( jpij, zswinew, zv_newice, za_newice, zh_newice, ze_newice, zs_newice, zo_newice )
120      CALL wrk_alloc( jpij, zdv_res, zda_res, zat_i_1d, zv_frazb, zvrel_1d )
121      CALL wrk_alloc( jpij,jpl, zv_b, za_b, za_i_1d, zv_i_1d, zoa_i_1d, zsmv_i_1d )
122      CALL wrk_alloc( jpij,nlay_i+1,jpl, ze_i_1d )
123      CALL wrk_alloc( jpi,jpj, zvrel )
124
125      !------------------------------------------------------------------------------|
126      ! 2) Convert units for ice internal energy
127      !------------------------------------------------------------------------------|
128      DO jl = 1, jpl
129         DO jk = 1, nlay_i
130            DO jj = 1, jpj
131               DO ji = 1, jpi
132                  !Energy of melting q(S,T) [J.m-3]
133                  rswitch          = 1._wp - MAX(  0._wp , SIGN( 1._wp , -v_i(ji,jj,jl) + epsi10 )  )   !0 if no ice and 1 if yes
134                  e_i(ji,jj,jk,jl) = rswitch * e_i(ji,jj,jk,jl) &
135                      &   / ( area(ji,jj) * MAX( v_i(ji,jj,jl) ,  epsi10 ) ) * REAL( nlay_i, wp )
136                  e_i(ji,jj,jk,jl) = e_i(ji,jj,jk,jl) * unit_fac
137               END DO
138            END DO
139         END DO
140      END DO
141
142      !------------------------------------------------------------------------------!
143      ! 3) Collection thickness of ice formed in leads and polynyas
144      !------------------------------------------------------------------------------!   
145      ! hicol is the thickness of new ice formed in open water
146      ! hicol can be either prescribed (frazswi = 0)
147      ! or computed (frazswi = 1)
148      ! Frazil ice forms in open water, is transported by wind
149      ! accumulates at the edge of the consolidated ice edge
150      ! where it forms aggregates of a specific thickness called
151      ! collection thickness.
152
153      ! Note : the following algorithm currently breaks vectorization
154      !
155
156      zvrel(:,:) = 0._wp
157
158      ! Default new ice thickness
159      hicol(:,:) = hiccrit
160
161      IF( fraz_swi == 1 ) THEN
162
163         !--------------------
164         ! Physical constants
165         !--------------------
166         hicol(:,:) = 0._wp
167
168         zhicrit = 0.04 ! frazil ice thickness
169         ztwogp  = 2. * rau0 / ( grav * 0.3 * ( rau0 - rhoic ) ) ! reduced grav
170         zsqcd   = 1.0 / SQRT( 1.3 * zcai ) ! 1/SQRT(airdensity*drag)
171         zgamafr = 0.03
172
173         DO jj = 2, jpj
174            DO ji = 2, jpi
175               IF ( qlead(ji,jj) < 0._wp ) THEN
176                  !-------------
177                  ! Wind stress
178                  !-------------
179                  ! C-grid wind stress components
180                  ztaux         = ( utau_ice(ji-1,jj  ) * tmu(ji-1,jj  )   &
181                     &          +   utau_ice(ji  ,jj  ) * tmu(ji  ,jj  ) ) * 0.5_wp
182                  ztauy         = ( vtau_ice(ji  ,jj-1) * tmv(ji  ,jj-1)   &
183                     &          +   vtau_ice(ji  ,jj  ) * tmv(ji  ,jj  ) ) * 0.5_wp
184                  ! Square root of wind stress
185                  ztenagm       =  SQRT( SQRT( ztaux**2 + ztauy**2 ) )
186
187                  !---------------------
188                  ! Frazil ice velocity
189                  !---------------------
190                  rswitch = MAX( 0._wp, SIGN( 1._wp , ztenagm - epsi10 ) )
191                  zvfrx   = rswitch * zgamafr * zsqcd * ztaux / MAX( ztenagm, epsi10 )
192                  zvfry   = rswitch * zgamafr * zsqcd * ztauy / MAX( ztenagm, epsi10 )
193
194                  !-------------------
195                  ! Pack ice velocity
196                  !-------------------
197                  ! C-grid ice velocity
198                  rswitch = MAX(  0._wp, SIGN( 1._wp , at_i(ji,jj) )  )
199                  zvgx    = rswitch * ( u_ice(ji-1,jj  ) * tmu(ji-1,jj  )  + u_ice(ji,jj) * tmu(ji,jj) ) * 0.5_wp
200                  zvgy    = rswitch * ( v_ice(ji  ,jj-1) * tmv(ji  ,jj-1)  + v_ice(ji,jj) * tmv(ji,jj) ) * 0.5_wp
201
202                  !-----------------------------------
203                  ! Relative frazil/pack ice velocity
204                  !-----------------------------------
205                  ! absolute relative velocity
206                  zvrel2 = MAX(  ( zvfrx - zvgx ) * ( zvfrx - zvgx )   &
207                     &         + ( zvfry - zvgy ) * ( zvfry - zvgy ) , 0.15 * 0.15 )
208                  zvrel(ji,jj)  = SQRT( zvrel2 )
209
210                  !---------------------
211                  ! Iterative procedure
212                  !---------------------
213                  hicol(ji,jj) = zhicrit + 0.1 
214                  hicol(ji,jj) = zhicrit +   hicol(ji,jj)    &
215                     &                   / ( hicol(ji,jj) * hicol(ji,jj) -  zhicrit * zhicrit ) * ztwogp * zvrel2
216
217!!gm better coding: above: hicol(ji,jj) * hicol(ji,jj) = (zhicrit + 0.1)*(zhicrit + 0.1)
218!!gm                                                   = zhicrit**2 + 0.2*zhicrit +0.01
219!!gm                therefore the 2 lines with hicol can be replaced by 1 line:
220!!gm              hicol(ji,jj) = zhicrit + (zhicrit + 0.1) / ( 0.2 * zhicrit + 0.01 ) * ztwogp * zvrel2
221!!gm further more (zhicrit + 0.1)/(0.2 * zhicrit + 0.01 )*ztwogp can be computed one for all outside the DO loop
222
223                  iter = 1
224                  iterate_frazil = .true.
225
226                  DO WHILE ( iter .LT. 100 .AND. iterate_frazil ) 
227                     zf = ( hicol(ji,jj) - zhicrit ) * ( hicol(ji,jj)**2 - zhicrit**2 ) &
228                        - hicol(ji,jj) * zhicrit * ztwogp * zvrel2
229                     zfp = ( hicol(ji,jj) - zhicrit ) * ( 3.0*hicol(ji,jj) + zhicrit ) &
230                        - zhicrit * ztwogp * zvrel2
231                     zhicol_new = hicol(ji,jj) - zf/zfp
232                     hicol(ji,jj)   = zhicol_new
233
234                     iter = iter + 1
235
236                  END DO ! do while
237
238               ENDIF ! end of selection of pixels where ice forms
239
240            END DO ! loop on ji ends
241         END DO ! loop on jj ends
242      !
243      CALL lbc_lnk( zvrel(:,:), 'T', 1. )
244      CALL lbc_lnk( hicol(:,:), 'T', 1. )
245
246      ENDIF ! End of computation of frazil ice collection thickness
247
248      !------------------------------------------------------------------------------!
249      ! 4) Identify grid points where new ice forms
250      !------------------------------------------------------------------------------!
251
252      !-------------------------------------
253      ! Select points for new ice formation
254      !-------------------------------------
255      ! This occurs if open water energy budget is negative
256      nbpac = 0
257      npac(:) = 0
258      !
259      DO jj = 1, jpj
260         DO ji = 1, jpi
261            IF ( qlead(ji,jj)  <  0._wp ) THEN
262               nbpac = nbpac + 1
263               npac( nbpac ) = (jj - 1) * jpi + ji
264            ENDIF
265         END DO
266      END DO
267
268      ! debug point to follow
269      jiindex_1d = 0
270      IF( ln_nicep ) THEN
271         DO ji = mi0(jiindx), mi1(jiindx)
272            DO jj = mj0(jjindx), mj1(jjindx)
273               IF ( qlead(ji,jj)  <  0._wp ) THEN
274                  jiindex_1d = (jj - 1) * jpi + ji
275               ENDIF
276            END DO
277         END DO
278      ENDIF
279   
280      IF( ln_nicep ) WRITE(numout,*) 'lim_thd_lac : nbpac = ', nbpac
281
282      !------------------------------
283      ! Move from 2-D to 1-D vectors
284      !------------------------------
285      ! If ocean gains heat do nothing
286      ! 0therwise compute new ice formation
287
288      IF ( nbpac > 0 ) THEN
289
290         CALL tab_2d_1d( nbpac, zat_i_1d  (1:nbpac)     , at_i         , jpi, jpj, npac(1:nbpac) )
291         DO jl = 1, jpl
292            CALL tab_2d_1d( nbpac, za_i_1d  (1:nbpac,jl), a_i  (:,:,jl), jpi, jpj, npac(1:nbpac) )
293            CALL tab_2d_1d( nbpac, zv_i_1d  (1:nbpac,jl), v_i  (:,:,jl), jpi, jpj, npac(1:nbpac) )
294            CALL tab_2d_1d( nbpac, zoa_i_1d (1:nbpac,jl), oa_i (:,:,jl), jpi, jpj, npac(1:nbpac) )
295            CALL tab_2d_1d( nbpac, zsmv_i_1d(1:nbpac,jl), smv_i(:,:,jl), jpi, jpj, npac(1:nbpac) )
296            DO jk = 1, nlay_i
297               CALL tab_2d_1d( nbpac, ze_i_1d(1:nbpac,jk,jl), e_i(:,:,jk,jl) , jpi, jpj, npac(1:nbpac) )
298            END DO ! jk
299         END DO ! jl
300
301         CALL tab_2d_1d( nbpac, qlead_1d  (1:nbpac)     , qlead  , jpi, jpj, npac(1:nbpac) )
302         CALL tab_2d_1d( nbpac, t_bo_1d   (1:nbpac)     , t_bo   , jpi, jpj, npac(1:nbpac) )
303         CALL tab_2d_1d( nbpac, sfx_opw_1d(1:nbpac)     , sfx_opw, jpi, jpj, npac(1:nbpac) )
304         CALL tab_2d_1d( nbpac, wfx_opw_1d(1:nbpac)     , wfx_opw, jpi, jpj, npac(1:nbpac) )
305         CALL tab_2d_1d( nbpac, hicol_1d  (1:nbpac)     , hicol  , jpi, jpj, npac(1:nbpac) )
306         CALL tab_2d_1d( nbpac, zvrel_1d  (1:nbpac)     , zvrel  , jpi, jpj, npac(1:nbpac) )
307
308         CALL tab_2d_1d( nbpac, hfx_thd_1d(1:nbpac)     , hfx_thd, jpi, jpj, npac(1:nbpac) )
309         CALL tab_2d_1d( nbpac, hfx_opw_1d(1:nbpac)     , hfx_opw, jpi, jpj, npac(1:nbpac) )
310
311         !------------------------------------------------------------------------------!
312         ! 5) Compute thickness, salinity, enthalpy, age, area and volume of new ice
313         !------------------------------------------------------------------------------!
314
315         !-----------------------------------------
316         ! Keep old ice areas and volume in memory
317         !-----------------------------------------
318         zv_b(1:nbpac,:) = zv_i_1d(1:nbpac,:) 
319         za_b(1:nbpac,:) = za_i_1d(1:nbpac,:)
320         !----------------------
321         ! Thickness of new ice
322         !----------------------
323         DO ji = 1, nbpac
324            zh_newice(ji) = hiccrit
325         END DO
326         IF( fraz_swi == 1 ) zh_newice(1:nbpac) = hicol_1d(1:nbpac)
327
328         !----------------------
329         ! Salinity of new ice
330         !----------------------
331         SELECT CASE ( num_sal )
332         CASE ( 1 )                    ! Sice = constant
333            zs_newice(1:nbpac) = bulk_sal
334         CASE ( 2 )                    ! Sice = F(z,t) [Vancoppenolle et al (2005)]
335            DO ji = 1, nbpac
336               ii =   MOD( npac(ji) - 1 , jpi ) + 1
337               ij =      ( npac(ji) - 1 ) / jpi + 1
338               zs_newice(ji) = MIN(  4.606 + 0.91 / zh_newice(ji) , s_i_max , 0.5 * sss_m(ii,ij)  )
339            END DO
340         CASE ( 3 )                    ! Sice = F(z) [multiyear ice]
341            zs_newice(1:nbpac) =   2.3
342         END SELECT
343
344         !-------------------------
345         ! Heat content of new ice
346         !-------------------------
347         ! We assume that new ice is formed at the seawater freezing point
348         DO ji = 1, nbpac
349            ztmelts       = - tmut * zs_newice(ji) + rtt                  ! Melting point (K)
350            ze_newice(ji) =   rhoic * (  cpic * ( ztmelts - t_bo_1d(ji) )                             &
351               &                       + lfus * ( 1.0 - ( ztmelts - rtt ) / MIN( t_bo_1d(ji) - rtt, -epsi10 ) )   &
352               &                       - rcp  *         ( ztmelts - rtt )  )
353         END DO ! ji
354
355         !----------------
356         ! Age of new ice
357         !----------------
358         DO ji = 1, nbpac
359            zo_newice(ji) = 0._wp
360         END DO ! ji
361
362         !-------------------
363         ! Volume of new ice
364         !-------------------
365         DO ji = 1, nbpac
366
367            zEi           = - ze_newice(ji) / rhoic                ! specific enthalpy of forming ice [J/kg]
368
369            zEw           = rcp * ( t_bo_1d(ji) - rt0 )             ! specific enthalpy of seawater at t_bo_1d [J/kg]
370                                                                   ! clem: we suppose we are already at the freezing point (condition qlead<0 is satisfyied)
371                                                                   
372            zdE           = zEi - zEw                              ! specific enthalpy difference [J/kg]
373                                             
374            zfmdt         = - qlead_1d(ji) / zdE                   ! Fm.dt [kg/m2] (<0)
375                                                                   ! clem: we use qlead instead of zqld (limthd) because we suppose we are at the freezing point   
376            zv_newice(ji) = - zfmdt / rhoic
377
378            zQm           = zfmdt * zEw                            ! heat to the ocean >0 associated with mass flux 
379
380            ! Contribution to heat flux to the ocean [W.m-2], >0 
381            hfx_thd_1d(ji) = hfx_thd_1d(ji) + zfmdt * zEw * r1_rdtice
382            ! Total heat flux used in this process [W.m-2] 
383            hfx_opw_1d(ji) = hfx_opw_1d(ji) - zfmdt * zdE * r1_rdtice
384            ! mass flux
385            wfx_opw_1d(ji) = wfx_opw_1d(ji) - zv_newice(ji) * rhoic * r1_rdtice
386            ! salt flux
387            sfx_opw_1d(ji) = sfx_opw_1d(ji) - zv_newice(ji) * rhoic * zs_newice(ji) * r1_rdtice
388
389            ! A fraction zfrazb of frazil ice is accreted at the ice bottom
390            rswitch       = 1._wp - MAX( 0._wp, SIGN( 1._wp , - zat_i_1d(ji) ) )
391            zfrazb        = rswitch * ( TANH ( Cfrazb * ( zvrel_1d(ji) - vfrazb ) ) + 1.0 ) * 0.5 * maxfrazb
392            zv_frazb(ji)  =         zfrazb   * zv_newice(ji)
393            zv_newice(ji) = ( 1.0 - zfrazb ) * zv_newice(ji)
394         END DO
395
396         !-----------------
397         ! Area of new ice
398         !-----------------
399         DO ji = 1, nbpac
400            za_newice(ji) = zv_newice(ji) / zh_newice(ji)
401         END DO
402
403         !------------------------------------------------------------------------------!
404         ! 6) Redistribute new ice area and volume into ice categories                  !
405         !------------------------------------------------------------------------------!
406
407         !------------------------
408         ! 6.1) lateral ice growth
409         !------------------------
410         ! If lateral ice growth gives an ice concentration gt 1, then
411         ! we keep the excessive volume in memory and attribute it later to bottom accretion
412         DO ji = 1, nbpac
413            IF ( za_newice(ji) >  ( amax - zat_i_1d(ji) ) ) THEN
414               zda_res(ji)   = za_newice(ji) - ( amax - zat_i_1d(ji) )
415               zdv_res(ji)   = zda_res  (ji) * zh_newice(ji) 
416               za_newice(ji) = za_newice(ji) - zda_res  (ji)
417               zv_newice(ji) = zv_newice(ji) - zdv_res  (ji)
418            ELSE
419               zda_res(ji) = 0._wp
420               zdv_res(ji) = 0._wp
421            ENDIF
422         END DO
423
424         ! find which category to fill
425         zat_i_1d(:) = 0._wp
426         DO jl = 1, jpl
427            DO ji = 1, nbpac
428               IF( zh_newice(ji) > hi_max(jl-1) .AND. zh_newice(ji) <= hi_max(jl) ) THEN
429                  za_i_1d (ji,jl) = za_i_1d (ji,jl) + za_newice(ji)
430                  zv_i_1d (ji,jl) = zv_i_1d (ji,jl) + zv_newice(ji)
431                  jcat    (ji)    = jl
432               ENDIF
433               zat_i_1d(ji) = zat_i_1d(ji) + za_i_1d  (ji,jl)
434            END DO
435         END DO
436
437         ! Heat content
438         DO ji = 1, nbpac
439            jl = jcat(ji)                                                    ! categroy in which new ice is put
440            zswinew  (ji) = MAX( 0._wp , SIGN( 1._wp , - za_b(ji,jl) ) )   ! 0 if old ice
441         END DO
442
443         DO jk = 1, nlay_i
444            DO ji = 1, nbpac
445               jl = jcat(ji)
446               rswitch = MAX( 0._wp, SIGN( 1._wp , zv_i_1d(ji,jl) - epsi20 ) )
447               ze_i_1d(ji,jk,jl) = zswinew(ji)   *   ze_newice(ji) +                                                      &
448                  &        ( 1.0 - zswinew(ji) ) * ( ze_newice(ji) * zv_newice(ji) + ze_i_1d(ji,jk,jl) * zv_b(ji,jl) )  &
449                  &        * rswitch / MAX( zv_i_1d(ji,jl), epsi20 )
450            END DO
451         END DO
452
453         !------------------------------------------------
454         ! 6.2) bottom ice growth + ice enthalpy remapping
455         !------------------------------------------------
456         DO jl = 1, jpl
457
458            ! for remapping
459            h_i_old (1:nbpac,0:nlay_i+1) = 0._wp
460            qh_i_old(1:nbpac,0:nlay_i+1) = 0._wp
461            DO jk = 1, nlay_i
462               DO ji = 1, nbpac
463                  h_i_old (ji,jk) = zv_i_1d(ji,jl) / REAL( nlay_i )
464                  qh_i_old(ji,jk) = ze_i_1d(ji,jk,jl) * h_i_old(ji,jk)
465               END DO
466            END DO
467
468            ! new volumes including lateral/bottom accretion + residual
469            DO ji = 1, nbpac
470               rswitch        = MAX( 0._wp, SIGN( 1._wp , zat_i_1d(ji) - epsi20 ) )
471               zv_newfra      = rswitch * ( zdv_res(ji) + zv_frazb(ji) ) * za_i_1d(ji,jl) / MAX( zat_i_1d(ji) , epsi20 )
472               za_i_1d(ji,jl) = rswitch * za_i_1d(ji,jl)               
473               zv_i_1d(ji,jl) = zv_i_1d(ji,jl) + zv_newfra
474               ! for remapping
475               h_i_old (ji,nlay_i+1) = zv_newfra
476               qh_i_old(ji,nlay_i+1) = ze_newice(ji) * zv_newfra
477            ENDDO
478            ! --- Ice enthalpy remapping --- !
479            CALL lim_thd_ent( 1, nbpac, ze_i_1d(1:nbpac,:,jl) ) 
480         ENDDO
481
482         !------------
483         ! Update age
484         !------------
485         DO jl = 1, jpl
486            DO ji = 1, nbpac
487               rswitch          = 1._wp - MAX( 0._wp , SIGN( 1._wp , - za_i_1d(ji,jl) + epsi20 ) )  ! 0 if no ice and 1 if yes
488               zoa_i_1d(ji,jl)  = za_b(ji,jl) * zoa_i_1d(ji,jl) / MAX( za_i_1d(ji,jl) , epsi20 ) * rswitch   
489            END DO
490         END DO   
491
492         !-----------------
493         ! Update salinity
494         !-----------------
495         DO jl = 1, jpl
496            DO ji = 1, nbpac
497               zdv   = zv_i_1d(ji,jl) - zv_b(ji,jl)
498               zsmv_i_1d(ji,jl) = zsmv_i_1d(ji,jl) + zdv * zs_newice(ji)
499            END DO
500         END DO
501
502         !------------------------------------------------------------------------------!
503         ! 7) Change 2D vectors to 1D vectors
504         !------------------------------------------------------------------------------!
505         DO jl = 1, jpl
506            CALL tab_1d_2d( nbpac, a_i (:,:,jl), npac(1:nbpac), za_i_1d (1:nbpac,jl), jpi, jpj )
507            CALL tab_1d_2d( nbpac, v_i (:,:,jl), npac(1:nbpac), zv_i_1d (1:nbpac,jl), jpi, jpj )
508            CALL tab_1d_2d( nbpac, oa_i(:,:,jl), npac(1:nbpac), zoa_i_1d(1:nbpac,jl), jpi, jpj )
509            CALL tab_1d_2d( nbpac, smv_i (:,:,jl), npac(1:nbpac), zsmv_i_1d(1:nbpac,jl) , jpi, jpj )
510            DO jk = 1, nlay_i
511               CALL tab_1d_2d( nbpac, e_i(:,:,jk,jl), npac(1:nbpac), ze_i_1d(1:nbpac,jk,jl), jpi, jpj )
512            END DO
513         END DO
514         CALL tab_1d_2d( nbpac, sfx_opw, npac(1:nbpac), sfx_opw_1d(1:nbpac), jpi, jpj )
515         CALL tab_1d_2d( nbpac, wfx_opw, npac(1:nbpac), wfx_opw_1d(1:nbpac), jpi, jpj )
516
517         CALL tab_1d_2d( nbpac, hfx_thd, npac(1:nbpac), hfx_thd_1d(1:nbpac), jpi, jpj )
518         CALL tab_1d_2d( nbpac, hfx_opw, npac(1:nbpac), hfx_opw_1d(1:nbpac), jpi, jpj )
519         !
520      ENDIF ! nbpac > 0
521
522      !------------------------------------------------------------------------------!
523      ! 8) Change units for e_i
524      !------------------------------------------------------------------------------!   
525      DO jl = 1, jpl
526         DO jk = 1, nlay_i
527            DO jj = 1, jpj
528               DO ji = 1, jpi
529                  ! heat content in Joules
530                  e_i(ji,jj,jk,jl) = e_i(ji,jj,jk,jl) * area(ji,jj) * v_i(ji,jj,jl) / ( REAL( nlay_i ,wp ) * unit_fac ) 
531               END DO
532            END DO
533         END DO
534      END DO
535
536      !
537      CALL wrk_dealloc( jpij, jcat )   ! integer
538      CALL wrk_dealloc( jpij, zswinew, zv_newice, za_newice, zh_newice, ze_newice, zs_newice, zo_newice )
539      CALL wrk_dealloc( jpij, zdv_res, zda_res, zat_i_1d, zv_frazb, zvrel_1d )
540      CALL wrk_dealloc( jpij,jpl, zv_b, za_b, za_i_1d, zv_i_1d, zoa_i_1d, zsmv_i_1d )
541      CALL wrk_dealloc( jpij,nlay_i+1,jpl, ze_i_1d )
542      CALL wrk_dealloc( jpi,jpj, zvrel )
543      !
544   END SUBROUTINE lim_thd_lac
545
546#else
547   !!----------------------------------------------------------------------
548   !!   Default option                               NO  LIM3 sea-ice model
549   !!----------------------------------------------------------------------
550CONTAINS
551   SUBROUTINE lim_thd_lac           ! Empty routine
552   END SUBROUTINE lim_thd_lac
553#endif
554
555   !!======================================================================
556END MODULE limthd_lac
Note: See TracBrowser for help on using the repository browser.