source: branches/2015/dev_r5204_CNRS_PISCES_dcy/NEMOGCM/NEMO/LIM_SRC_3/limthd.F90 @ 5207

Last change on this file since 5207 was 5207, checked in by cetlod, 7 years ago

dev_r5204_CNRS_PISCES_dcy:minor bugs corrections

  • Property svn:keywords set to Id
File size: 41.0 KB
Line 
1MODULE limthd
2   !!======================================================================
3   !!                  ***  MODULE limthd   ***
4   !!  LIM-3 :   ice thermodynamic
5   !!======================================================================
6   !! History :  LIM  ! 2000-01 (M.A. Morales Maqueda, H. Goosse, T. Fichefet) LIM-1
7   !!            2.0  ! 2002-07 (C. Ethe, G. Madec)  LIM-2 (F90 rewriting)
8   !!            3.0  ! 2005-11 (M. Vancoppenolle)  LIM-3 : Multi-layer thermodynamics + salinity variations
9   !!             -   ! 2007-04 (M. Vancoppenolle) add lim_thd_glohec, lim_thd_con_dh and lim_thd_con_dif
10   !!            3.2  ! 2009-07 (M. Vancoppenolle, Y. Aksenov, G. Madec) bug correction in wfx_snw
11   !!            3.3  ! 2010-11 (G. Madec) corrected snow melting heat (due to factor betas)
12   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
13   !!             -   ! 2012-05 (C. Rousset) add penetration solar flux
14   !!----------------------------------------------------------------------
15#if defined key_lim3
16   !!----------------------------------------------------------------------
17   !!   'key_lim3'                                      LIM3 sea-ice model
18   !!----------------------------------------------------------------------
19   !!   lim_thd       : thermodynamic of sea ice
20   !!   lim_thd_init  : initialisation of sea-ice thermodynamic
21   !!----------------------------------------------------------------------
22   USE phycst         ! physical constants
23   USE dom_oce        ! ocean space and time domain variables
24   USE oce     , ONLY : fraqsr_1lev 
25   USE ice            ! LIM: sea-ice variables
26   USE sbc_oce        ! Surface boundary condition: ocean fields
27   USE sbc_ice        ! Surface boundary condition: ice fields
28   USE thd_ice        ! LIM thermodynamic sea-ice variables
29   USE dom_ice        ! LIM sea-ice domain
30   USE domvvl         ! domain: variable volume level
31   USE limthd_dif     ! LIM: thermodynamics, vertical diffusion
32   USE limthd_dh      ! LIM: thermodynamics, ice and snow thickness variation
33   USE limthd_sal     ! LIM: thermodynamics, ice salinity
34   USE limthd_ent     ! LIM: thermodynamics, ice enthalpy redistribution
35   USE limthd_lac     ! LIM-3 lateral accretion
36   USE limitd_th      ! remapping thickness distribution
37   USE limtab         ! LIM: 1D <==> 2D transformation
38   USE limvar         ! LIM: sea-ice variables
39   USE lbclnk         ! lateral boundary condition - MPP links
40   USE lib_mpp        ! MPP library
41   USE wrk_nemo       ! work arrays
42   USE in_out_manager ! I/O manager
43   USE prtctl         ! Print control
44   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
45   USE timing         ! Timing
46   USE limcons        ! conservation tests
47   USE limctl
48
49   IMPLICIT NONE
50   PRIVATE
51
52   PUBLIC   lim_thd        ! called by limstp module
53   PUBLIC   lim_thd_init   ! called by sbc_lim_init
54
55   !! * Substitutions
56#  include "domzgr_substitute.h90"
57#  include "vectopt_loop_substitute.h90"
58   !!----------------------------------------------------------------------
59   !! NEMO/LIM3 3.3 , UCL - NEMO Consortium (2010)
60   !! $Id$
61   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
62   !!----------------------------------------------------------------------
63CONTAINS
64
65   SUBROUTINE lim_thd( kt )
66      !!-------------------------------------------------------------------
67      !!                ***  ROUTINE lim_thd  ***       
68      !! 
69      !! ** Purpose : This routine manages ice thermodynamics
70      !!         
71      !! ** Action : - Initialisation of some variables
72      !!             - Some preliminary computation (oceanic heat flux
73      !!               at the ice base, snow acc.,heat budget of the leads)
74      !!             - selection of the icy points and put them in an array
75      !!             - call lim_thd_dif  for vertical heat diffusion
76      !!             - call lim_thd_dh   for vertical ice growth and melt
77      !!             - call lim_thd_ent  for enthalpy remapping
78      !!             - call lim_thd_sal  for ice desalination
79      !!             - call lim_thd_temp to  retrieve temperature from ice enthalpy
80      !!             - back to the geographic grid
81      !!     
82      !! ** References :
83      !!---------------------------------------------------------------------
84      INTEGER, INTENT(in) :: kt    ! number of iteration
85      !!
86      INTEGER  :: ji, jj, jk, jl   ! dummy loop indices
87      INTEGER  :: nbpb             ! nb of icy pts for vertical thermo calculations
88      INTEGER  :: ii, ij           ! temporary dummy loop index
89      REAL(wp) :: zfric_u, zqld, zqfr
90      REAL(wp) :: zvi_b, zsmv_b, zei_b, zfs_b, zfw_b, zft_b 
91      REAL(wp), PARAMETER :: zfric_umin = 0._wp           ! lower bound for the friction velocity (cice value=5.e-04)
92      REAL(wp), PARAMETER :: zch        = 0.0057_wp       ! heat transfer coefficient
93      !
94      REAL(wp), POINTER, DIMENSION(:,:) ::  zqsr, zqns
95      !!-------------------------------------------------------------------
96      CALL wrk_alloc( jpi,jpj, zqsr, zqns )
97
98      IF( nn_timing == 1 )  CALL timing_start('limthd')
99
100      IF( kt == nit000 .AND. l_trcdm2dc )  ALLOCATE( ftr_ice_mean(jpi,jpj,jpl), ftr_ice_mean_1d(jpij), qsr_ice_mean_1d(jpij) )
101
102      ! conservation test
103      IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
104
105      CALL lim_var_glo2eqv
106      !------------------------------------------------------------------------!
107      ! 1) Initialization of some variables                                    !
108      !------------------------------------------------------------------------!
109      ftr_ice(:,:,:) = 0._wp  ! part of solar radiation transmitted through the ice
110      IF( l_trcdm2dc ) ftr_ice_mean(:,:,:) = 0._wp   ! part of daily mean solar radiation absorbing inside the ice
111
112
113      !--------------------
114      ! 1.2) Heat content   
115      !--------------------
116      ! Change the units of heat content; from J/m2 to J/m3
117      DO jl = 1, jpl
118         DO jk = 1, nlay_i
119            DO jj = 1, jpj
120               DO ji = 1, jpi
121                  !0 if no ice and 1 if yes
122                  rswitch = MAX(  0._wp , SIGN( 1._wp , v_i(ji,jj,jl) - epsi20 )  )
123                  !Energy of melting q(S,T) [J.m-3]
124                  e_i(ji,jj,jk,jl) = rswitch * e_i(ji,jj,jk,jl) / MAX( v_i(ji,jj,jl) , epsi20 ) * REAL( nlay_i )
125               END DO
126            END DO
127         END DO
128         DO jk = 1, nlay_s
129            DO jj = 1, jpj
130               DO ji = 1, jpi
131                  !0 if no ice and 1 if yes
132                  rswitch = MAX(  0._wp , SIGN( 1._wp , v_s(ji,jj,jl) - epsi20 )  )
133                  !Energy of melting q(S,T) [J.m-3]
134                  e_s(ji,jj,jk,jl) = rswitch * e_s(ji,jj,jk,jl) / MAX( v_s(ji,jj,jl) , epsi20 ) * REAL( nlay_s )
135               END DO
136            END DO
137         END DO
138      END DO
139
140      ! 2) Partial computation of forcing for the thermodynamic sea ice model.      !
141      !-----------------------------------------------------------------------------!
142
143      !--- Ocean solar and non solar fluxes to be used in zqld
144      IF ( .NOT. lk_cpl ) THEN   ! --- forced case, fluxes to the lead are the same as over the ocean
145         !
146         zqsr(:,:) = qsr(:,:)      ; zqns(:,:) = qns(:,:)
147         !
148      ELSE                       ! --- coupled case, fluxes to the lead are total - intercepted
149         !
150         zqsr(:,:) = qsr_tot(:,:)  ; zqns(:,:) = qns_tot(:,:)
151         !
152         DO jl = 1, jpl
153            DO jj = 1, jpj
154               DO ji = 1, jpi
155                  zqsr(ji,jj) = zqsr(ji,jj) - qsr_ice(ji,jj,jl) * a_i_b(ji,jj,jl)
156                  zqns(ji,jj) = zqns(ji,jj) - qns_ice(ji,jj,jl) * a_i_b(ji,jj,jl)
157               END DO
158            END DO
159         END DO
160         !
161      ENDIF
162
163      DO jj = 1, jpj
164         DO ji = 1, jpi
165            rswitch  = tmask(ji,jj,1) * MAX( 0._wp , SIGN( 1._wp , at_i(ji,jj) - epsi10 ) ) ! 0 if no ice
166            !
167            !           !  solar irradiance transmission at the mixed layer bottom and used in the lead heat budget
168            !           !  practically no "direct lateral ablation"
169            !           
170            !           !  net downward heat flux from the ice to the ocean, expressed as a function of ocean
171            !           !  temperature and turbulent mixing (McPhee, 1992)
172            !
173
174            ! --- Energy received in the lead, zqld is defined everywhere (J.m-2) --- !
175            ! REMARK valid at least in forced mode from clem
176            ! precip is included in qns but not in qns_ice
177            IF ( lk_cpl ) THEN
178               zqld =  tmask(ji,jj,1) * rdt_ice *  &
179                  &    (   zqsr(ji,jj) * fraqsr_1lev(ji,jj) + zqns(ji,jj)               &   ! pfrld already included in coupled mode
180                  &    + ( pfrld(ji,jj)**rn_betas - pfrld(ji,jj) ) * sprecip(ji,jj)  *     &   ! heat content of precip
181                  &      ( cpic * ( MIN( tatm_ice(ji,jj), rt0_snow ) - rt0 ) - lfus )   &
182                  &    + ( 1._wp - pfrld(ji,jj) ) * ( tprecip(ji,jj) - sprecip(ji,jj) ) * rcp * ( tatm_ice(ji,jj) - rt0 ) )
183            ELSE
184               zqld =  tmask(ji,jj,1) * rdt_ice *  &
185                  &      ( pfrld(ji,jj) * ( zqsr(ji,jj) * fraqsr_1lev(ji,jj) + zqns(ji,jj) )    &
186                  &    + ( pfrld(ji,jj)**rn_betas - pfrld(ji,jj) ) * sprecip(ji,jj)  *             &  ! heat content of precip
187                  &      ( cpic * ( MIN( tatm_ice(ji,jj), rt0_snow ) - rt0 ) - lfus )           &
188                  &    + ( 1._wp - pfrld(ji,jj) ) * ( tprecip(ji,jj) - sprecip(ji,jj) ) * rcp * ( tatm_ice(ji,jj) - rt0 ) )
189            ENDIF
190
191            ! --- Energy needed to bring ocean surface layer until its freezing (<0, J.m-2) --- !
192            zqfr = tmask(ji,jj,1) * rau0 * rcp * fse3t_m(ji,jj) * ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) )
193
194            ! --- Energy from the turbulent oceanic heat flux (W/m2) --- !
195            zfric_u      = MAX( SQRT( ust2s(ji,jj) ), zfric_umin ) 
196            fhtur(ji,jj) = MAX( 0._wp, rswitch * rau0 * rcp * zch  * zfric_u * ( ( sst_m(ji,jj) + rt0 ) - t_bo(ji,jj) ) ) ! W.m-2
197            fhtur(ji,jj) = rswitch * MIN( fhtur(ji,jj), - zqfr * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) )
198            ! upper bound for fhtur: the heat retrieved from the ocean must be smaller than the heat necessary to reach
199            !                        the freezing point, so that we do not have SST < T_freeze
200            !                        This implies: - ( fhtur(ji,jj) * at_i(ji,jj) * rtdice ) - zqfr >= 0
201
202            !-- Energy Budget of the leads (J.m-2). Must be < 0 to form ice
203            qlead(ji,jj) = MIN( 0._wp , zqld - ( fhtur(ji,jj) * at_i(ji,jj) * rdt_ice ) - zqfr )
204
205            ! If there is ice and leads are warming, then transfer energy from the lead budget and use it for bottom melting
206            IF( zqld > 0._wp ) THEN
207               fhld (ji,jj) = rswitch * zqld * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) ! divided by at_i since this is (re)multiplied by a_i in limthd_dh.F90
208               qlead(ji,jj) = 0._wp
209            ELSE
210               fhld (ji,jj) = 0._wp
211            ENDIF
212            !
213            ! -----------------------------------------
214            ! Net heat flux on top of ice-ocean [W.m-2]
215            ! -----------------------------------------
216            !     heat flux at the ocean surface + precip
217            !   + heat flux at the ice   surface
218            hfx_in(ji,jj) = hfx_in(ji,jj)                                                                                         & 
219               ! heat flux above the ocean
220               &    +             pfrld(ji,jj)   * ( zqns(ji,jj) + zqsr(ji,jj) )                                                  &
221               ! latent heat of precip (note that precip is included in qns but not in qns_ice)
222               &    +   ( 1._wp - pfrld(ji,jj) ) * sprecip(ji,jj) * ( cpic * ( MIN( tatm_ice(ji,jj), rt0_snow ) - rt0 ) - lfus )  &
223               &    +   ( 1._wp - pfrld(ji,jj) ) * ( tprecip(ji,jj) - sprecip(ji,jj) ) * rcp * ( tatm_ice(ji,jj) - rt0 )          &
224               ! heat flux above the ice
225               &    +   SUM(    a_i_b(ji,jj,:)   * ( qns_ice(ji,jj,:) + qsr_ice(ji,jj,:) ) )
226
227            ! -----------------------------------------------------------------------------
228            ! Net heat flux that is retroceded to the ocean or taken from the ocean [W.m-2]
229            ! -----------------------------------------------------------------------------
230            !     First  step here              :  non solar + precip - qlead - qturb
231            !     Second step in limthd_dh      :  heat remaining if total melt (zq_rema)
232            !     Third  step in limsbc         :  heat from ice-ocean mass exchange (zf_mass) + solar
233            hfx_out(ji,jj) = hfx_out(ji,jj)                                                                                       & 
234               ! Non solar heat flux received by the ocean
235               &    +        pfrld(ji,jj) * zqns(ji,jj)                                                                            &
236               ! latent heat of precip (note that precip is included in qns but not in qns_ice)
237               &    +      ( pfrld(ji,jj)**rn_betas - pfrld(ji,jj) ) * sprecip(ji,jj)       &
238               &         * ( cpic * ( MIN( tatm_ice(ji,jj), rt0_snow ) - rt0 ) - lfus )  &
239               &    +      ( 1._wp - pfrld(ji,jj) ) * ( tprecip(ji,jj) - sprecip(ji,jj) ) * rcp * ( tatm_ice(ji,jj) - rt0 )       &
240               ! heat flux taken from the ocean where there is open water ice formation
241               &    -      qlead(ji,jj) * r1_rdtice                                                                               &
242               ! heat flux taken from the ocean during bottom growth/melt (fhld should be 0 while bott growth)
243               &    -      at_i(ji,jj) * fhtur(ji,jj)                                                                             &
244               &    -      at_i(ji,jj) *  fhld(ji,jj)
245
246         END DO
247      END DO
248
249      !------------------------------------------------------------------------------!
250      ! 3) Select icy points and fulfill arrays for the vectorial grid.           
251      !------------------------------------------------------------------------------!
252
253      DO jl = 1, jpl      !loop over ice categories
254
255         IF( kt == nit000 .AND. lwp ) THEN
256            WRITE(numout,*) ' lim_thd : transfer to 1D vectors. Category no : ', jl 
257            WRITE(numout,*) ' ~~~~~~~~'
258         ENDIF
259
260         nbpb = 0
261         DO jj = 1, jpj
262            DO ji = 1, jpi
263               IF ( a_i(ji,jj,jl) > epsi10 ) THEN     
264                  nbpb      = nbpb  + 1
265                  npb(nbpb) = (jj - 1) * jpi + ji
266               ENDIF
267            END DO
268         END DO
269
270         ! debug point to follow
271         jiindex_1d = 0
272         IF( ln_icectl ) THEN
273            DO ji = mi0(iiceprt), mi1(iiceprt)
274               DO jj = mj0(jiceprt), mj1(jiceprt)
275                  jiindex_1d = (jj - 1) * jpi + ji
276                  WRITE(numout,*) ' lim_thd : Category no : ', jl 
277               END DO
278            END DO
279         ENDIF
280
281         !------------------------------------------------------------------------------!
282         ! 4) Thermodynamic computation
283         !------------------------------------------------------------------------------!
284
285         IF( lk_mpp )   CALL mpp_ini_ice( nbpb , numout )
286
287         IF( nbpb > 0 ) THEN  ! If there is no ice, do nothing.
288
289            !-------------------------!
290            ! --- Move to 1D arrays ---
291            !-------------------------!
292            CALL lim_thd_1d2d( nbpb, jl, 1 )
293
294            !--------------------------------------!
295            ! --- Ice/Snow Temperature profile --- !
296            !--------------------------------------!
297            CALL lim_thd_dif( 1, nbpb )
298
299            !---------------------------------!
300            ! --- Ice/Snow thickness ---      !
301            !---------------------------------!
302            CALL lim_thd_dh( 1, nbpb )   
303
304            ! --- Ice enthalpy remapping --- !
305            CALL lim_thd_ent( 1, nbpb, q_i_1d(1:nbpb,:) ) 
306                                           
307            !---------------------------------!
308            ! --- Ice salinity ---            !
309            !---------------------------------!
310            CALL lim_thd_sal( 1, nbpb )   
311
312            !---------------------------------!
313            ! --- temperature update ---      !
314            !---------------------------------!
315            CALL lim_thd_temp( 1, nbpb )
316
317            !------------------------------------!
318            ! --- lateral melting if monocat --- !
319            !------------------------------------!
320            IF ( ( nn_monocat == 1 .OR. nn_monocat == 4 ) .AND. jpl == 1 ) THEN
321               CALL lim_thd_lam( 1, nbpb )
322            END IF
323
324            !-------------------------!
325            ! --- Move to 2D arrays ---
326            !-------------------------!
327            CALL lim_thd_1d2d( nbpb, jl, 2 )
328
329            !
330            IF( lk_mpp )   CALL mpp_comm_free( ncomm_ice ) !RB necessary ??
331         ENDIF
332         !
333      END DO !jl
334
335      !------------------------------------------------------------------------------!
336      ! 5) Global variables, diagnostics
337      !------------------------------------------------------------------------------!
338
339      !------------------------
340      ! Ice heat content             
341      !------------------------
342      ! Enthalpies are global variables we have to readjust the units (heat content in J/m2)
343      DO jl = 1, jpl
344         DO jk = 1, nlay_i
345            e_i(:,:,jk,jl) = e_i(:,:,jk,jl) * a_i(:,:,jl) * ht_i(:,:,jl) * r1_nlay_i
346         END DO
347      END DO
348
349      !------------------------
350      ! Snow heat content             
351      !------------------------
352      ! Enthalpies are global variables we have to readjust the units (heat content in J/m2)
353      DO jl = 1, jpl
354         DO jk = 1, nlay_s
355            e_s(:,:,jk,jl) = e_s(:,:,jk,jl) * a_i(:,:,jl) * ht_s(:,:,jl) * r1_nlay_s
356         END DO
357      END DO
358 
359      !----------------------------------
360      ! Change thickness to volume
361      !----------------------------------
362      v_i(:,:,:)   = ht_i(:,:,:) * a_i(:,:,:)
363      v_s(:,:,:)   = ht_s(:,:,:) * a_i(:,:,:)
364      smv_i(:,:,:) = sm_i(:,:,:) * v_i(:,:,:)
365
366      ! update ice age (in case a_i changed, i.e. becomes 0 or lateral melting in monocat)
367      DO jl  = 1, jpl
368         DO jj = 1, jpj
369            DO ji = 1, jpi
370               rswitch = MAX( 0._wp , SIGN( 1._wp, a_i_b(ji,jj,jl) - epsi10 ) )
371               oa_i(ji,jj,jl) = rswitch * oa_i(ji,jj,jl) * a_i(ji,jj,jl) / MAX( a_i_b(ji,jj,jl), epsi10 )
372            END DO
373         END DO
374      END DO
375
376      CALL lim_var_zapsmall
377
378      !--------------------------------------------
379      ! Diagnostic thermodynamic growth rates
380      !--------------------------------------------
381      IF( ln_icectl )   CALL lim_prt( kt, iiceprt, jiceprt, 1, ' - ice thermodyn. - ' )   ! control print
382
383      IF(ln_ctl) THEN            ! Control print
384         CALL prt_ctl_info(' ')
385         CALL prt_ctl_info(' - Cell values : ')
386         CALL prt_ctl_info('   ~~~~~~~~~~~~~ ')
387         CALL prt_ctl(tab2d_1=e12t , clinfo1=' lim_thd  : cell area :')
388         CALL prt_ctl(tab2d_1=at_i , clinfo1=' lim_thd  : at_i      :')
389         CALL prt_ctl(tab2d_1=vt_i , clinfo1=' lim_thd  : vt_i      :')
390         CALL prt_ctl(tab2d_1=vt_s , clinfo1=' lim_thd  : vt_s      :')
391         DO jl = 1, jpl
392            CALL prt_ctl_info(' ')
393            CALL prt_ctl_info(' - Category : ', ivar1=jl)
394            CALL prt_ctl_info('   ~~~~~~~~~~')
395            CALL prt_ctl(tab2d_1=a_i   (:,:,jl)   , clinfo1= ' lim_thd  : a_i      : ')
396            CALL prt_ctl(tab2d_1=ht_i  (:,:,jl)   , clinfo1= ' lim_thd  : ht_i     : ')
397            CALL prt_ctl(tab2d_1=ht_s  (:,:,jl)   , clinfo1= ' lim_thd  : ht_s     : ')
398            CALL prt_ctl(tab2d_1=v_i   (:,:,jl)   , clinfo1= ' lim_thd  : v_i      : ')
399            CALL prt_ctl(tab2d_1=v_s   (:,:,jl)   , clinfo1= ' lim_thd  : v_s      : ')
400            CALL prt_ctl(tab2d_1=e_s   (:,:,1,jl) , clinfo1= ' lim_thd  : e_s      : ')
401            CALL prt_ctl(tab2d_1=t_su  (:,:,jl)   , clinfo1= ' lim_thd  : t_su     : ')
402            CALL prt_ctl(tab2d_1=t_s   (:,:,1,jl) , clinfo1= ' lim_thd  : t_snow   : ')
403            CALL prt_ctl(tab2d_1=sm_i  (:,:,jl)   , clinfo1= ' lim_thd  : sm_i     : ')
404            CALL prt_ctl(tab2d_1=smv_i (:,:,jl)   , clinfo1= ' lim_thd  : smv_i    : ')
405            DO jk = 1, nlay_i
406               CALL prt_ctl_info(' ')
407               CALL prt_ctl_info(' - Layer : ', ivar1=jk)
408               CALL prt_ctl_info('   ~~~~~~~')
409               CALL prt_ctl(tab2d_1=t_i(:,:,jk,jl) , clinfo1= ' lim_thd  : t_i      : ')
410               CALL prt_ctl(tab2d_1=e_i(:,:,jk,jl) , clinfo1= ' lim_thd  : e_i      : ')
411            END DO
412         END DO
413      ENDIF
414      !
415      !
416      IF( ln_limdiahsb ) CALL lim_cons_hsm(1, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
417
418      CALL wrk_dealloc( jpi,jpj, zqsr, zqns )
419
420      !------------------------------------------------------------------------------|
421      !  6) Transport of ice between thickness categories.                           |
422      !------------------------------------------------------------------------------|
423      ! Given thermodynamic growth rates, transport ice between thickness categories.
424      IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limitd_th_rem', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
425
426      IF( jpl > 1 )      CALL lim_itd_th_rem( 1, jpl, kt )
427
428      IF( ln_limdiahsb ) CALL lim_cons_hsm(1, 'limitd_th_rem', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
429
430      !------------------------------------------------------------------------------|
431      !  7) Add frazil ice growing in leads.
432      !------------------------------------------------------------------------------|
433      IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limthd_lac', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
434
435      CALL lim_thd_lac
436     
437      IF( ln_limdiahsb ) CALL lim_cons_hsm(1, 'limthd_lac', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
438
439      ! Control print
440      IF(ln_ctl) THEN
441         CALL lim_var_glo2eqv
442
443         CALL prt_ctl_info(' ')
444         CALL prt_ctl_info(' - Cell values : ')
445         CALL prt_ctl_info('   ~~~~~~~~~~~~~ ')
446         CALL prt_ctl(tab2d_1=e12t , clinfo1=' lim_itd_th  : cell area :')
447         CALL prt_ctl(tab2d_1=at_i , clinfo1=' lim_itd_th  : at_i      :')
448         CALL prt_ctl(tab2d_1=vt_i , clinfo1=' lim_itd_th  : vt_i      :')
449         CALL prt_ctl(tab2d_1=vt_s , clinfo1=' lim_itd_th  : vt_s      :')
450         DO jl = 1, jpl
451            CALL prt_ctl_info(' ')
452            CALL prt_ctl_info(' - Category : ', ivar1=jl)
453            CALL prt_ctl_info('   ~~~~~~~~~~')
454            CALL prt_ctl(tab2d_1=a_i   (:,:,jl)   , clinfo1= ' lim_itd_th  : a_i      : ')
455            CALL prt_ctl(tab2d_1=ht_i  (:,:,jl)   , clinfo1= ' lim_itd_th  : ht_i     : ')
456            CALL prt_ctl(tab2d_1=ht_s  (:,:,jl)   , clinfo1= ' lim_itd_th  : ht_s     : ')
457            CALL prt_ctl(tab2d_1=v_i   (:,:,jl)   , clinfo1= ' lim_itd_th  : v_i      : ')
458            CALL prt_ctl(tab2d_1=v_s   (:,:,jl)   , clinfo1= ' lim_itd_th  : v_s      : ')
459            CALL prt_ctl(tab2d_1=e_s   (:,:,1,jl) , clinfo1= ' lim_itd_th  : e_s      : ')
460            CALL prt_ctl(tab2d_1=t_su  (:,:,jl)   , clinfo1= ' lim_itd_th  : t_su     : ')
461            CALL prt_ctl(tab2d_1=t_s   (:,:,1,jl) , clinfo1= ' lim_itd_th  : t_snow   : ')
462            CALL prt_ctl(tab2d_1=sm_i  (:,:,jl)   , clinfo1= ' lim_itd_th  : sm_i     : ')
463            CALL prt_ctl(tab2d_1=smv_i (:,:,jl)   , clinfo1= ' lim_itd_th  : smv_i    : ')
464            DO jk = 1, nlay_i
465               CALL prt_ctl_info(' ')
466               CALL prt_ctl_info(' - Layer : ', ivar1=jk)
467               CALL prt_ctl_info('   ~~~~~~~')
468               CALL prt_ctl(tab2d_1=t_i(:,:,jk,jl) , clinfo1= ' lim_itd_th  : t_i      : ')
469               CALL prt_ctl(tab2d_1=e_i(:,:,jk,jl) , clinfo1= ' lim_itd_th  : e_i      : ')
470            END DO
471         END DO
472      ENDIF
473      !
474      IF( nn_timing == 1 )  CALL timing_stop('limthd')
475
476   END SUBROUTINE lim_thd 
477
478   SUBROUTINE lim_thd_temp( kideb, kiut )
479      !!-----------------------------------------------------------------------
480      !!                   ***  ROUTINE lim_thd_temp ***
481      !!                 
482      !! ** Purpose :   Computes sea ice temperature (Kelvin) from enthalpy
483      !!
484      !! ** Method  :   Formula (Bitz and Lipscomb, 1999)
485      !!-------------------------------------------------------------------
486      INTEGER, INTENT(in) ::   kideb, kiut   ! bounds for the spatial loop
487      !!
488      INTEGER  ::   ji, jk   ! dummy loop indices
489      REAL(wp) ::   ztmelts, zaaa, zbbb, zccc, zdiscrim  ! local scalar
490      !!-------------------------------------------------------------------
491      ! Recover ice temperature
492      DO jk = 1, nlay_i
493         DO ji = kideb, kiut
494            ztmelts       =  -tmut * s_i_1d(ji,jk) + rt0
495            ! Conversion q(S,T) -> T (second order equation)
496            zaaa          =  cpic
497            zbbb          =  ( rcp - cpic ) * ( ztmelts - rt0 ) + q_i_1d(ji,jk) * r1_rhoic - lfus
498            zccc          =  lfus * ( ztmelts - rt0 )
499            zdiscrim      =  SQRT( MAX( zbbb * zbbb - 4._wp * zaaa * zccc, 0._wp ) )
500            t_i_1d(ji,jk) =  rt0 - ( zbbb + zdiscrim ) / ( 2._wp * zaaa )
501           
502            ! mask temperature
503            rswitch       =  1._wp - MAX( 0._wp , SIGN( 1._wp , - ht_i_1d(ji) ) ) 
504            t_i_1d(ji,jk) =  rswitch * t_i_1d(ji,jk) + ( 1._wp - rswitch ) * rt0
505         END DO
506      END DO
507
508   END SUBROUTINE lim_thd_temp
509
510   SUBROUTINE lim_thd_lam( kideb, kiut )
511      !!-----------------------------------------------------------------------
512      !!                   ***  ROUTINE lim_thd_lam ***
513      !!                 
514      !! ** Purpose :   Lateral melting in case monocategory
515      !!                          ( dA = A/2h dh )
516      !!-----------------------------------------------------------------------
517      INTEGER, INTENT(in) ::   kideb, kiut        ! bounds for the spatial loop
518      INTEGER             ::   ji                 ! dummy loop indices
519      REAL(wp)            ::   zhi_bef            ! ice thickness before thermo
520      REAL(wp)            ::   zdh_mel, zda_mel   ! net melting
521      REAL(wp)            ::   zvi, zvs           ! ice/snow volumes
522
523      DO ji = kideb, kiut
524         zdh_mel = MIN( 0._wp, dh_i_surf(ji) + dh_i_bott(ji) + dh_snowice(ji) )
525         IF( zdh_mel < 0._wp .AND. a_i_1d(ji) > 0._wp )  THEN
526            zvi          = a_i_1d(ji) * ht_i_1d(ji)
527            zvs          = a_i_1d(ji) * ht_s_1d(ji)
528            ! lateral melting = concentration change
529            zhi_bef     = ht_i_1d(ji) - zdh_mel
530            rswitch     = MAX( 0._wp , SIGN( 1._wp , zhi_bef - epsi20 ) )
531            zda_mel     = rswitch * a_i_1d(ji) * zdh_mel / ( 2._wp * MAX( zhi_bef, epsi20 ) )
532            a_i_1d(ji)  = MAX( epsi20, a_i_1d(ji) + zda_mel ) 
533             ! adjust thickness
534            ht_i_1d(ji) = zvi / a_i_1d(ji)           
535            ht_s_1d(ji) = zvs / a_i_1d(ji)           
536            ! retrieve total concentration
537            at_i_1d(ji) = a_i_1d(ji)
538         END IF
539      END DO
540     
541   END SUBROUTINE lim_thd_lam
542
543   SUBROUTINE lim_thd_1d2d( nbpb, jl, kn )
544      !!-----------------------------------------------------------------------
545      !!                   ***  ROUTINE lim_thd_1d2d ***
546      !!                 
547      !! ** Purpose :   move arrays from 1d to 2d and the reverse
548      !!-----------------------------------------------------------------------
549      INTEGER, INTENT(in) ::   kn       ! 1= from 2D to 1D
550                                        ! 2= from 1D to 2D
551      INTEGER, INTENT(in) ::   nbpb     ! size of 1D arrays
552      INTEGER, INTENT(in) ::   jl       ! ice cat
553      INTEGER             ::   jk       ! dummy loop indices
554
555      SELECT CASE( kn )
556
557      CASE( 1 )
558
559         CALL tab_2d_1d( nbpb, at_i_1d     (1:nbpb), at_i            , jpi, jpj, npb(1:nbpb) )
560         CALL tab_2d_1d( nbpb, a_i_1d      (1:nbpb), a_i(:,:,jl)     , jpi, jpj, npb(1:nbpb) )
561         CALL tab_2d_1d( nbpb, ht_i_1d     (1:nbpb), ht_i(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
562         CALL tab_2d_1d( nbpb, ht_s_1d     (1:nbpb), ht_s(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
563         
564         CALL tab_2d_1d( nbpb, t_su_1d     (1:nbpb), t_su(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
565         CALL tab_2d_1d( nbpb, sm_i_1d     (1:nbpb), sm_i(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
566         DO jk = 1, nlay_s
567            CALL tab_2d_1d( nbpb, t_s_1d(1:nbpb,jk), t_s(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
568            CALL tab_2d_1d( nbpb, q_s_1d(1:nbpb,jk), e_s(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
569         END DO
570         DO jk = 1, nlay_i
571            CALL tab_2d_1d( nbpb, t_i_1d(1:nbpb,jk), t_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
572            CALL tab_2d_1d( nbpb, q_i_1d(1:nbpb,jk), e_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
573            CALL tab_2d_1d( nbpb, s_i_1d(1:nbpb,jk), s_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
574         END DO
575         
576         CALL tab_2d_1d( nbpb, tatm_ice_1d(1:nbpb), tatm_ice(:,:)   , jpi, jpj, npb(1:nbpb) )
577         CALL tab_2d_1d( nbpb, qsr_ice_1d (1:nbpb), qsr_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
578         CALL tab_2d_1d( nbpb, fr1_i0_1d  (1:nbpb), fr1_i0          , jpi, jpj, npb(1:nbpb) )
579         CALL tab_2d_1d( nbpb, fr2_i0_1d  (1:nbpb), fr2_i0          , jpi, jpj, npb(1:nbpb) )
580         CALL tab_2d_1d( nbpb, qns_ice_1d (1:nbpb), qns_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
581         CALL tab_2d_1d( nbpb, ftr_ice_1d (1:nbpb), ftr_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
582         IF( l_trcdm2dc )  THEN
583            CALL tab_2d_1d( nbpb, qsr_ice_mean_1d (1:nbpb), qsr_ice_mean(:,:,jl) , jpi, jpj, npb(1:nbpb) )
584            CALL tab_2d_1d( nbpb, ftr_ice_mean_1d (1:nbpb), ftr_ice_mean(:,:,jl) , jpi, jpj, npb(1:nbpb) )
585         ENDIF
586         IF( .NOT. lk_cpl ) THEN
587            CALL tab_2d_1d( nbpb, qla_ice_1d (1:nbpb), qla_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
588            CALL tab_2d_1d( nbpb, dqla_ice_1d(1:nbpb), dqla_ice(:,:,jl), jpi, jpj, npb(1:nbpb) )
589         ENDIF
590         CALL tab_2d_1d( nbpb, dqns_ice_1d(1:nbpb), dqns_ice(:,:,jl), jpi, jpj, npb(1:nbpb) )
591         CALL tab_2d_1d( nbpb, t_bo_1d     (1:nbpb), t_bo            , jpi, jpj, npb(1:nbpb) )
592         CALL tab_2d_1d( nbpb, sprecip_1d (1:nbpb), sprecip         , jpi, jpj, npb(1:nbpb) ) 
593         CALL tab_2d_1d( nbpb, fhtur_1d   (1:nbpb), fhtur           , jpi, jpj, npb(1:nbpb) )
594         CALL tab_2d_1d( nbpb, qlead_1d   (1:nbpb), qlead           , jpi, jpj, npb(1:nbpb) )
595         CALL tab_2d_1d( nbpb, fhld_1d    (1:nbpb), fhld            , jpi, jpj, npb(1:nbpb) )
596         
597         CALL tab_2d_1d( nbpb, wfx_snw_1d (1:nbpb), wfx_snw         , jpi, jpj, npb(1:nbpb) )
598         CALL tab_2d_1d( nbpb, wfx_sub_1d (1:nbpb), wfx_sub         , jpi, jpj, npb(1:nbpb) )
599         
600         CALL tab_2d_1d( nbpb, wfx_bog_1d (1:nbpb), wfx_bog         , jpi, jpj, npb(1:nbpb) )
601         CALL tab_2d_1d( nbpb, wfx_bom_1d (1:nbpb), wfx_bom         , jpi, jpj, npb(1:nbpb) )
602         CALL tab_2d_1d( nbpb, wfx_sum_1d (1:nbpb), wfx_sum         , jpi, jpj, npb(1:nbpb) )
603         CALL tab_2d_1d( nbpb, wfx_sni_1d (1:nbpb), wfx_sni         , jpi, jpj, npb(1:nbpb) )
604         CALL tab_2d_1d( nbpb, wfx_res_1d (1:nbpb), wfx_res         , jpi, jpj, npb(1:nbpb) )
605         CALL tab_2d_1d( nbpb, wfx_spr_1d (1:nbpb), wfx_spr         , jpi, jpj, npb(1:nbpb) )
606         
607         CALL tab_2d_1d( nbpb, sfx_bog_1d (1:nbpb), sfx_bog         , jpi, jpj, npb(1:nbpb) )
608         CALL tab_2d_1d( nbpb, sfx_bom_1d (1:nbpb), sfx_bom         , jpi, jpj, npb(1:nbpb) )
609         CALL tab_2d_1d( nbpb, sfx_sum_1d (1:nbpb), sfx_sum         , jpi, jpj, npb(1:nbpb) )
610         CALL tab_2d_1d( nbpb, sfx_sni_1d (1:nbpb), sfx_sni         , jpi, jpj, npb(1:nbpb) )
611         CALL tab_2d_1d( nbpb, sfx_bri_1d (1:nbpb), sfx_bri         , jpi, jpj, npb(1:nbpb) )
612         CALL tab_2d_1d( nbpb, sfx_res_1d (1:nbpb), sfx_res         , jpi, jpj, npb(1:nbpb) )
613         
614         CALL tab_2d_1d( nbpb, hfx_thd_1d (1:nbpb), hfx_thd         , jpi, jpj, npb(1:nbpb) )
615         CALL tab_2d_1d( nbpb, hfx_spr_1d (1:nbpb), hfx_spr         , jpi, jpj, npb(1:nbpb) )
616         CALL tab_2d_1d( nbpb, hfx_sum_1d (1:nbpb), hfx_sum         , jpi, jpj, npb(1:nbpb) )
617         CALL tab_2d_1d( nbpb, hfx_bom_1d (1:nbpb), hfx_bom         , jpi, jpj, npb(1:nbpb) )
618         CALL tab_2d_1d( nbpb, hfx_bog_1d (1:nbpb), hfx_bog         , jpi, jpj, npb(1:nbpb) )
619         CALL tab_2d_1d( nbpb, hfx_dif_1d (1:nbpb), hfx_dif         , jpi, jpj, npb(1:nbpb) )
620         CALL tab_2d_1d( nbpb, hfx_opw_1d (1:nbpb), hfx_opw         , jpi, jpj, npb(1:nbpb) )
621         CALL tab_2d_1d( nbpb, hfx_snw_1d (1:nbpb), hfx_snw         , jpi, jpj, npb(1:nbpb) )
622         CALL tab_2d_1d( nbpb, hfx_sub_1d (1:nbpb), hfx_sub         , jpi, jpj, npb(1:nbpb) )
623         CALL tab_2d_1d( nbpb, hfx_err_1d (1:nbpb), hfx_err         , jpi, jpj, npb(1:nbpb) )
624         CALL tab_2d_1d( nbpb, hfx_res_1d (1:nbpb), hfx_res         , jpi, jpj, npb(1:nbpb) )
625         CALL tab_2d_1d( nbpb, hfx_err_dif_1d (1:nbpb), hfx_err_dif , jpi, jpj, npb(1:nbpb) )
626         CALL tab_2d_1d( nbpb, hfx_err_rem_1d (1:nbpb), hfx_err_rem , jpi, jpj, npb(1:nbpb) )
627
628      CASE( 2 )
629
630         CALL tab_1d_2d( nbpb, at_i          , npb, at_i_1d    (1:nbpb)   , jpi, jpj )
631         CALL tab_1d_2d( nbpb, ht_i(:,:,jl)  , npb, ht_i_1d    (1:nbpb)   , jpi, jpj )
632         CALL tab_1d_2d( nbpb, ht_s(:,:,jl)  , npb, ht_s_1d    (1:nbpb)   , jpi, jpj )
633         CALL tab_1d_2d( nbpb, a_i (:,:,jl)  , npb, a_i_1d     (1:nbpb)   , jpi, jpj )
634         CALL tab_1d_2d( nbpb, t_su(:,:,jl)  , npb, t_su_1d    (1:nbpb)   , jpi, jpj )
635         CALL tab_1d_2d( nbpb, sm_i(:,:,jl)  , npb, sm_i_1d    (1:nbpb)   , jpi, jpj )
636         DO jk = 1, nlay_s
637            CALL tab_1d_2d( nbpb, t_s(:,:,jk,jl), npb, t_s_1d     (1:nbpb,jk), jpi, jpj)
638            CALL tab_1d_2d( nbpb, e_s(:,:,jk,jl), npb, q_s_1d     (1:nbpb,jk), jpi, jpj)
639         END DO
640         DO jk = 1, nlay_i
641            CALL tab_1d_2d( nbpb, t_i(:,:,jk,jl), npb, t_i_1d     (1:nbpb,jk), jpi, jpj)
642            CALL tab_1d_2d( nbpb, e_i(:,:,jk,jl), npb, q_i_1d     (1:nbpb,jk), jpi, jpj)
643            CALL tab_1d_2d( nbpb, s_i(:,:,jk,jl), npb, s_i_1d     (1:nbpb,jk), jpi, jpj)
644         END DO
645         CALL tab_1d_2d( nbpb, qlead         , npb, qlead_1d  (1:nbpb)   , jpi, jpj )
646         
647         CALL tab_1d_2d( nbpb, wfx_snw       , npb, wfx_snw_1d(1:nbpb)   , jpi, jpj )
648         CALL tab_1d_2d( nbpb, wfx_sub       , npb, wfx_sub_1d(1:nbpb)   , jpi, jpj )
649         
650         CALL tab_1d_2d( nbpb, wfx_bog       , npb, wfx_bog_1d(1:nbpb)   , jpi, jpj )
651         CALL tab_1d_2d( nbpb, wfx_bom       , npb, wfx_bom_1d(1:nbpb)   , jpi, jpj )
652         CALL tab_1d_2d( nbpb, wfx_sum       , npb, wfx_sum_1d(1:nbpb)   , jpi, jpj )
653         CALL tab_1d_2d( nbpb, wfx_sni       , npb, wfx_sni_1d(1:nbpb)   , jpi, jpj )
654         CALL tab_1d_2d( nbpb, wfx_res       , npb, wfx_res_1d(1:nbpb)   , jpi, jpj )
655         CALL tab_1d_2d( nbpb, wfx_spr       , npb, wfx_spr_1d(1:nbpb)   , jpi, jpj )
656         
657         CALL tab_1d_2d( nbpb, sfx_bog       , npb, sfx_bog_1d(1:nbpb)   , jpi, jpj )
658         CALL tab_1d_2d( nbpb, sfx_bom       , npb, sfx_bom_1d(1:nbpb)   , jpi, jpj )
659         CALL tab_1d_2d( nbpb, sfx_sum       , npb, sfx_sum_1d(1:nbpb)   , jpi, jpj )
660         CALL tab_1d_2d( nbpb, sfx_sni       , npb, sfx_sni_1d(1:nbpb)   , jpi, jpj )
661         CALL tab_1d_2d( nbpb, sfx_res       , npb, sfx_res_1d(1:nbpb)   , jpi, jpj )
662         CALL tab_1d_2d( nbpb, sfx_bri       , npb, sfx_bri_1d(1:nbpb)   , jpi, jpj )
663         
664         CALL tab_1d_2d( nbpb, hfx_thd       , npb, hfx_thd_1d(1:nbpb)   , jpi, jpj )
665         CALL tab_1d_2d( nbpb, hfx_spr       , npb, hfx_spr_1d(1:nbpb)   , jpi, jpj )
666         CALL tab_1d_2d( nbpb, hfx_sum       , npb, hfx_sum_1d(1:nbpb)   , jpi, jpj )
667         CALL tab_1d_2d( nbpb, hfx_bom       , npb, hfx_bom_1d(1:nbpb)   , jpi, jpj )
668         CALL tab_1d_2d( nbpb, hfx_bog       , npb, hfx_bog_1d(1:nbpb)   , jpi, jpj )
669         CALL tab_1d_2d( nbpb, hfx_dif       , npb, hfx_dif_1d(1:nbpb)   , jpi, jpj )
670         CALL tab_1d_2d( nbpb, hfx_opw       , npb, hfx_opw_1d(1:nbpb)   , jpi, jpj )
671         CALL tab_1d_2d( nbpb, hfx_snw       , npb, hfx_snw_1d(1:nbpb)   , jpi, jpj )
672         CALL tab_1d_2d( nbpb, hfx_sub       , npb, hfx_sub_1d(1:nbpb)   , jpi, jpj )
673         CALL tab_1d_2d( nbpb, hfx_err       , npb, hfx_err_1d(1:nbpb)   , jpi, jpj )
674         CALL tab_1d_2d( nbpb, hfx_res       , npb, hfx_res_1d(1:nbpb)   , jpi, jpj )
675         CALL tab_1d_2d( nbpb, hfx_err_rem   , npb, hfx_err_rem_1d(1:nbpb), jpi, jpj )
676         CALL tab_1d_2d( nbpb, hfx_err_dif   , npb, hfx_err_dif_1d(1:nbpb), jpi, jpj )
677         !
678         CALL tab_1d_2d( nbpb, qns_ice(:,:,jl), npb, qns_ice_1d(1:nbpb) , jpi, jpj)
679         CALL tab_1d_2d( nbpb, ftr_ice(:,:,jl), npb, ftr_ice_1d(1:nbpb) , jpi, jpj )
680         !         
681         IF( l_trcdm2dc )  THEN
682            CALL tab_1d_2d( nbpb, qsr_ice_mean(:,:,jl), npb, qsr_ice_mean_1d(1:nbpb) , jpi, jpj)
683            CALL tab_1d_2d( nbpb, ftr_ice_mean(:,:,jl), npb, ftr_ice_mean_1d(1:nbpb) , jpi, jpj )
684         ENDIF
685         !
686      END SELECT
687
688   END SUBROUTINE lim_thd_1d2d
689
690
691   SUBROUTINE lim_thd_init
692      !!-----------------------------------------------------------------------
693      !!                   ***  ROUTINE lim_thd_init ***
694      !!                 
695      !! ** Purpose :   Physical constants and parameters linked to the ice
696      !!              thermodynamics
697      !!
698      !! ** Method  :   Read the namicethd namelist and check the ice-thermo
699      !!              parameter values called at the first timestep (nit000)
700      !!
701      !! ** input   :   Namelist namicether
702      !!-------------------------------------------------------------------
703      INTEGER  ::   ios                 ! Local integer output status for namelist read
704      NAMELIST/namicethd/ rn_hnewice, ln_frazil, rn_maxfrazb, rn_vfrazb, rn_Cfrazb,                       &
705         &                rn_himin, rn_betas, rn_kappa_i, nn_conv_dif, rn_terr_dif, nn_ice_thcon, &
706         &                nn_monocat, ln_it_qnsice
707      !!-------------------------------------------------------------------
708      !
709      IF(lwp) THEN
710         WRITE(numout,*)
711         WRITE(numout,*) 'lim_thd : Ice Thermodynamics'
712         WRITE(numout,*) '~~~~~~~'
713      ENDIF
714      !
715      REWIND( numnam_ice_ref )              ! Namelist namicethd in reference namelist : Ice thermodynamics
716      READ  ( numnam_ice_ref, namicethd, IOSTAT = ios, ERR = 901)
717901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in reference namelist', lwp )
718
719      REWIND( numnam_ice_cfg )              ! Namelist namicethd in configuration namelist : Ice thermodynamics
720      READ  ( numnam_ice_cfg, namicethd, IOSTAT = ios, ERR = 902 )
721902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in configuration namelist', lwp )
722      IF(lwm) WRITE ( numoni, namicethd )
723      !
724      IF ( ( jpl > 1 ) .AND. ( nn_monocat == 1 ) ) THEN
725         nn_monocat = 0
726         IF(lwp) WRITE(numout, *) '   nn_monocat must be 0 in multi-category case '
727      ENDIF
728
729      !
730      IF(lwp) THEN                          ! control print
731         WRITE(numout,*)
732         WRITE(numout,*)'   Namelist of ice parameters for ice thermodynamic computation '
733         WRITE(numout,*)'      ice thick. for lateral accretion                        rn_hnewice   = ', rn_hnewice
734         WRITE(numout,*)'      Frazil ice thickness as a function of wind or not       ln_frazil    = ', ln_frazil
735         WRITE(numout,*)'      Maximum proportion of frazil ice collecting at bottom   rn_maxfrazb  = ', rn_maxfrazb
736         WRITE(numout,*)'      Thresold relative drift speed for collection of frazil  rn_vfrazb    = ', rn_vfrazb
737         WRITE(numout,*)'      Squeezing coefficient for collection of frazil          rn_Cfrazb    = ', rn_Cfrazb
738         WRITE(numout,*)'      minimum ice thickness                                   rn_himin     = ', rn_himin 
739         WRITE(numout,*)'      numerical carac. of the scheme for diffusion in ice '
740         WRITE(numout,*)'      coefficient for ice-lead partition of snowfall          rn_betas     = ', rn_betas
741         WRITE(numout,*)'      extinction radiation parameter in sea ice               rn_kappa_i   = ', rn_kappa_i
742         WRITE(numout,*)'      maximal n. of iter. for heat diffusion computation      nn_conv_dif  = ', nn_conv_dif
743         WRITE(numout,*)'      maximal err. on T for heat diffusion computation        rn_terr_dif  = ', rn_terr_dif
744         WRITE(numout,*)'      switch for comp. of thermal conductivity in the ice     nn_ice_thcon = ', nn_ice_thcon
745         WRITE(numout,*)'      check heat conservation in the ice/snow                 con_i        = ', con_i
746         WRITE(numout,*)'      virtual ITD mono-category parameterizations (1) or not  nn_monocat   = ', nn_monocat
747         WRITE(numout,*)'      iterate the surface non-solar flux (T) or not (F)       ln_it_qnsice = ', ln_it_qnsice
748      ENDIF
749      !
750   END SUBROUTINE lim_thd_init
751
752#else
753   !!----------------------------------------------------------------------
754   !!   Default option         Dummy module          NO  LIM3 sea-ice model
755   !!----------------------------------------------------------------------
756#endif
757
758   !!======================================================================
759END MODULE limthd
Note: See TracBrowser for help on using the repository browser.