New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limthd.F90 in branches/2015/dev_r5204_CNRS_PISCES_dcy/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/2015/dev_r5204_CNRS_PISCES_dcy/NEMOGCM/NEMO/LIM_SRC_3/limthd.F90 @ 5236

Last change on this file since 5236 was 5236, checked in by cetlod, 9 years ago

NEMOGCM_dev_r5204_CNRS_PISCES_dcy : update routines according to the new strategy, see ticket #1484

  • Property svn:keywords set to Id
File size: 40.3 KB
Line 
1MODULE limthd
2   !!======================================================================
3   !!                  ***  MODULE limthd   ***
4   !!  LIM-3 :   ice thermodynamic
5   !!======================================================================
6   !! History :  LIM  ! 2000-01 (M.A. Morales Maqueda, H. Goosse, T. Fichefet) LIM-1
7   !!            2.0  ! 2002-07 (C. Ethe, G. Madec)  LIM-2 (F90 rewriting)
8   !!            3.0  ! 2005-11 (M. Vancoppenolle)  LIM-3 : Multi-layer thermodynamics + salinity variations
9   !!             -   ! 2007-04 (M. Vancoppenolle) add lim_thd_glohec, lim_thd_con_dh and lim_thd_con_dif
10   !!            3.2  ! 2009-07 (M. Vancoppenolle, Y. Aksenov, G. Madec) bug correction in wfx_snw
11   !!            3.3  ! 2010-11 (G. Madec) corrected snow melting heat (due to factor betas)
12   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
13   !!             -   ! 2012-05 (C. Rousset) add penetration solar flux
14   !!----------------------------------------------------------------------
15#if defined key_lim3
16   !!----------------------------------------------------------------------
17   !!   'key_lim3'                                      LIM3 sea-ice model
18   !!----------------------------------------------------------------------
19   !!   lim_thd       : thermodynamic of sea ice
20   !!   lim_thd_init  : initialisation of sea-ice thermodynamic
21   !!----------------------------------------------------------------------
22   USE phycst         ! physical constants
23   USE dom_oce        ! ocean space and time domain variables
24   USE oce     , ONLY : fraqsr_1lev 
25   USE ice            ! LIM: sea-ice variables
26   USE sbc_oce        ! Surface boundary condition: ocean fields
27   USE sbc_ice        ! Surface boundary condition: ice fields
28   USE thd_ice        ! LIM thermodynamic sea-ice variables
29   USE dom_ice        ! LIM sea-ice domain
30   USE domvvl         ! domain: variable volume level
31   USE limthd_dif     ! LIM: thermodynamics, vertical diffusion
32   USE limthd_dh      ! LIM: thermodynamics, ice and snow thickness variation
33   USE limthd_sal     ! LIM: thermodynamics, ice salinity
34   USE limthd_ent     ! LIM: thermodynamics, ice enthalpy redistribution
35   USE limthd_lac     ! LIM-3 lateral accretion
36   USE limitd_th      ! remapping thickness distribution
37   USE limtab         ! LIM: 1D <==> 2D transformation
38   USE limvar         ! LIM: sea-ice variables
39   USE lbclnk         ! lateral boundary condition - MPP links
40   USE lib_mpp        ! MPP library
41   USE wrk_nemo       ! work arrays
42   USE in_out_manager ! I/O manager
43   USE prtctl         ! Print control
44   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
45   USE timing         ! Timing
46   USE limcons        ! conservation tests
47   USE limctl
48
49   IMPLICIT NONE
50   PRIVATE
51
52   PUBLIC   lim_thd        ! called by limstp module
53   PUBLIC   lim_thd_init   ! called by sbc_lim_init
54
55   !! * Substitutions
56#  include "domzgr_substitute.h90"
57#  include "vectopt_loop_substitute.h90"
58   !!----------------------------------------------------------------------
59   !! NEMO/LIM3 3.3 , UCL - NEMO Consortium (2010)
60   !! $Id$
61   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
62   !!----------------------------------------------------------------------
63CONTAINS
64
65   SUBROUTINE lim_thd( kt )
66      !!-------------------------------------------------------------------
67      !!                ***  ROUTINE lim_thd  ***       
68      !! 
69      !! ** Purpose : This routine manages ice thermodynamics
70      !!         
71      !! ** Action : - Initialisation of some variables
72      !!             - Some preliminary computation (oceanic heat flux
73      !!               at the ice base, snow acc.,heat budget of the leads)
74      !!             - selection of the icy points and put them in an array
75      !!             - call lim_thd_dif  for vertical heat diffusion
76      !!             - call lim_thd_dh   for vertical ice growth and melt
77      !!             - call lim_thd_ent  for enthalpy remapping
78      !!             - call lim_thd_sal  for ice desalination
79      !!             - call lim_thd_temp to  retrieve temperature from ice enthalpy
80      !!             - back to the geographic grid
81      !!     
82      !! ** References :
83      !!---------------------------------------------------------------------
84      INTEGER, INTENT(in) :: kt    ! number of iteration
85      !!
86      INTEGER  :: ji, jj, jk, jl   ! dummy loop indices
87      INTEGER  :: nbpb             ! nb of icy pts for vertical thermo calculations
88      INTEGER  :: ii, ij           ! temporary dummy loop index
89      REAL(wp) :: zfric_u, zqld, zqfr
90      REAL(wp) :: zvi_b, zsmv_b, zei_b, zfs_b, zfw_b, zft_b 
91      REAL(wp), PARAMETER :: zfric_umin = 0._wp           ! lower bound for the friction velocity (cice value=5.e-04)
92      REAL(wp), PARAMETER :: zch        = 0.0057_wp       ! heat transfer coefficient
93      !
94      REAL(wp), POINTER, DIMENSION(:,:) ::  zqsr, zqns
95      !!-------------------------------------------------------------------
96      CALL wrk_alloc( jpi,jpj, zqsr, zqns )
97
98      IF( nn_timing == 1 )  CALL timing_start('limthd')
99
100      ! conservation test
101      IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
102
103      CALL lim_var_glo2eqv
104      !------------------------------------------------------------------------!
105      ! 1) Initialization of some variables                                    !
106      !------------------------------------------------------------------------!
107      ftr_ice(:,:,:) = 0._wp  ! part of solar radiation transmitted through the ice
108      IF( l_trcdm2dc ) ftr_ice_mean(:,:,:) = 0._wp   ! part of daily mean solar radiation absorbing inside the ice
109
110
111      !--------------------
112      ! 1.2) Heat content   
113      !--------------------
114      ! Change the units of heat content; from J/m2 to J/m3
115      DO jl = 1, jpl
116         DO jk = 1, nlay_i
117            DO jj = 1, jpj
118               DO ji = 1, jpi
119                  !0 if no ice and 1 if yes
120                  rswitch = MAX(  0._wp , SIGN( 1._wp , v_i(ji,jj,jl) - epsi20 )  )
121                  !Energy of melting q(S,T) [J.m-3]
122                  e_i(ji,jj,jk,jl) = rswitch * e_i(ji,jj,jk,jl) / MAX( v_i(ji,jj,jl) , epsi20 ) * REAL( nlay_i )
123               END DO
124            END DO
125         END DO
126         DO jk = 1, nlay_s
127            DO jj = 1, jpj
128               DO ji = 1, jpi
129                  !0 if no ice and 1 if yes
130                  rswitch = MAX(  0._wp , SIGN( 1._wp , v_s(ji,jj,jl) - epsi20 )  )
131                  !Energy of melting q(S,T) [J.m-3]
132                  e_s(ji,jj,jk,jl) = rswitch * e_s(ji,jj,jk,jl) / MAX( v_s(ji,jj,jl) , epsi20 ) * REAL( nlay_s )
133               END DO
134            END DO
135         END DO
136      END DO
137
138      ! 2) Partial computation of forcing for the thermodynamic sea ice model.      !
139      !-----------------------------------------------------------------------------!
140
141      !--- Ocean solar and non solar fluxes to be used in zqld
142      IF ( .NOT. lk_cpl ) THEN   ! --- forced case, fluxes to the lead are the same as over the ocean
143         !
144         zqsr(:,:) = qsr(:,:)      ; zqns(:,:) = qns(:,:)
145         !
146      ELSE                       ! --- coupled case, fluxes to the lead are total - intercepted
147         !
148         zqsr(:,:) = qsr_tot(:,:)  ; zqns(:,:) = qns_tot(:,:)
149         !
150         DO jl = 1, jpl
151            DO jj = 1, jpj
152               DO ji = 1, jpi
153                  zqsr(ji,jj) = zqsr(ji,jj) - qsr_ice(ji,jj,jl) * a_i_b(ji,jj,jl)
154                  zqns(ji,jj) = zqns(ji,jj) - qns_ice(ji,jj,jl) * a_i_b(ji,jj,jl)
155               END DO
156            END DO
157         END DO
158         !
159      ENDIF
160
161      DO jj = 1, jpj
162         DO ji = 1, jpi
163            rswitch  = tmask(ji,jj,1) * MAX( 0._wp , SIGN( 1._wp , at_i(ji,jj) - epsi10 ) ) ! 0 if no ice
164            !
165            !           !  solar irradiance transmission at the mixed layer bottom and used in the lead heat budget
166            !           !  practically no "direct lateral ablation"
167            !           
168            !           !  net downward heat flux from the ice to the ocean, expressed as a function of ocean
169            !           !  temperature and turbulent mixing (McPhee, 1992)
170            !
171
172            ! --- Energy received in the lead, zqld is defined everywhere (J.m-2) --- !
173            ! REMARK valid at least in forced mode from clem
174            ! precip is included in qns but not in qns_ice
175            IF ( lk_cpl ) THEN
176               zqld =  tmask(ji,jj,1) * rdt_ice *  &
177                  &    (   zqsr(ji,jj) * fraqsr_1lev(ji,jj) + zqns(ji,jj)               &   ! pfrld already included in coupled mode
178                  &    + ( pfrld(ji,jj)**rn_betas - pfrld(ji,jj) ) * sprecip(ji,jj)  *     &   ! heat content of precip
179                  &      ( cpic * ( MIN( tatm_ice(ji,jj), rt0_snow ) - rt0 ) - lfus )   &
180                  &    + ( 1._wp - pfrld(ji,jj) ) * ( tprecip(ji,jj) - sprecip(ji,jj) ) * rcp * ( tatm_ice(ji,jj) - rt0 ) )
181            ELSE
182               zqld =  tmask(ji,jj,1) * rdt_ice *  &
183                  &      ( pfrld(ji,jj) * ( zqsr(ji,jj) * fraqsr_1lev(ji,jj) + zqns(ji,jj) )    &
184                  &    + ( pfrld(ji,jj)**rn_betas - pfrld(ji,jj) ) * sprecip(ji,jj)  *             &  ! heat content of precip
185                  &      ( cpic * ( MIN( tatm_ice(ji,jj), rt0_snow ) - rt0 ) - lfus )           &
186                  &    + ( 1._wp - pfrld(ji,jj) ) * ( tprecip(ji,jj) - sprecip(ji,jj) ) * rcp * ( tatm_ice(ji,jj) - rt0 ) )
187            ENDIF
188
189            ! --- Energy needed to bring ocean surface layer until its freezing (<0, J.m-2) --- !
190            zqfr = tmask(ji,jj,1) * rau0 * rcp * fse3t_m(ji,jj) * ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) )
191
192            ! --- Energy from the turbulent oceanic heat flux (W/m2) --- !
193            zfric_u      = MAX( SQRT( ust2s(ji,jj) ), zfric_umin ) 
194            fhtur(ji,jj) = MAX( 0._wp, rswitch * rau0 * rcp * zch  * zfric_u * ( ( sst_m(ji,jj) + rt0 ) - t_bo(ji,jj) ) ) ! W.m-2
195            fhtur(ji,jj) = rswitch * MIN( fhtur(ji,jj), - zqfr * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) )
196            ! upper bound for fhtur: the heat retrieved from the ocean must be smaller than the heat necessary to reach
197            !                        the freezing point, so that we do not have SST < T_freeze
198            !                        This implies: - ( fhtur(ji,jj) * at_i(ji,jj) * rtdice ) - zqfr >= 0
199
200            !-- Energy Budget of the leads (J.m-2). Must be < 0 to form ice
201            qlead(ji,jj) = MIN( 0._wp , zqld - ( fhtur(ji,jj) * at_i(ji,jj) * rdt_ice ) - zqfr )
202
203            ! If there is ice and leads are warming, then transfer energy from the lead budget and use it for bottom melting
204            IF( zqld > 0._wp ) THEN
205               fhld (ji,jj) = rswitch * zqld * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) ! divided by at_i since this is (re)multiplied by a_i in limthd_dh.F90
206               qlead(ji,jj) = 0._wp
207            ELSE
208               fhld (ji,jj) = 0._wp
209            ENDIF
210            !
211            ! -----------------------------------------
212            ! Net heat flux on top of ice-ocean [W.m-2]
213            ! -----------------------------------------
214            !     heat flux at the ocean surface + precip
215            !   + heat flux at the ice   surface
216            hfx_in(ji,jj) = hfx_in(ji,jj)                                                                                         & 
217               ! heat flux above the ocean
218               &    +             pfrld(ji,jj)   * ( zqns(ji,jj) + zqsr(ji,jj) )                                                  &
219               ! latent heat of precip (note that precip is included in qns but not in qns_ice)
220               &    +   ( 1._wp - pfrld(ji,jj) ) * sprecip(ji,jj) * ( cpic * ( MIN( tatm_ice(ji,jj), rt0_snow ) - rt0 ) - lfus )  &
221               &    +   ( 1._wp - pfrld(ji,jj) ) * ( tprecip(ji,jj) - sprecip(ji,jj) ) * rcp * ( tatm_ice(ji,jj) - rt0 )          &
222               ! heat flux above the ice
223               &    +   SUM(    a_i_b(ji,jj,:)   * ( qns_ice(ji,jj,:) + qsr_ice(ji,jj,:) ) )
224
225            ! -----------------------------------------------------------------------------
226            ! Net heat flux that is retroceded to the ocean or taken from the ocean [W.m-2]
227            ! -----------------------------------------------------------------------------
228            !     First  step here              :  non solar + precip - qlead - qturb
229            !     Second step in limthd_dh      :  heat remaining if total melt (zq_rema)
230            !     Third  step in limsbc         :  heat from ice-ocean mass exchange (zf_mass) + solar
231            hfx_out(ji,jj) = hfx_out(ji,jj)                                                                                       & 
232               ! Non solar heat flux received by the ocean
233               &    +        pfrld(ji,jj) * zqns(ji,jj)                                                                            &
234               ! latent heat of precip (note that precip is included in qns but not in qns_ice)
235               &    +      ( pfrld(ji,jj)**rn_betas - pfrld(ji,jj) ) * sprecip(ji,jj)       &
236               &         * ( cpic * ( MIN( tatm_ice(ji,jj), rt0_snow ) - rt0 ) - lfus )  &
237               &    +      ( 1._wp - pfrld(ji,jj) ) * ( tprecip(ji,jj) - sprecip(ji,jj) ) * rcp * ( tatm_ice(ji,jj) - rt0 )       &
238               ! heat flux taken from the ocean where there is open water ice formation
239               &    -      qlead(ji,jj) * r1_rdtice                                                                               &
240               ! heat flux taken from the ocean during bottom growth/melt (fhld should be 0 while bott growth)
241               &    -      at_i(ji,jj) * fhtur(ji,jj)                                                                             &
242               &    -      at_i(ji,jj) *  fhld(ji,jj)
243
244         END DO
245      END DO
246
247      !------------------------------------------------------------------------------!
248      ! 3) Select icy points and fulfill arrays for the vectorial grid.           
249      !------------------------------------------------------------------------------!
250
251      DO jl = 1, jpl      !loop over ice categories
252
253         IF( kt == nit000 .AND. lwp ) THEN
254            WRITE(numout,*) ' lim_thd : transfer to 1D vectors. Category no : ', jl 
255            WRITE(numout,*) ' ~~~~~~~~'
256         ENDIF
257
258         nbpb = 0
259         DO jj = 1, jpj
260            DO ji = 1, jpi
261               IF ( a_i(ji,jj,jl) > epsi10 ) THEN     
262                  nbpb      = nbpb  + 1
263                  npb(nbpb) = (jj - 1) * jpi + ji
264               ENDIF
265            END DO
266         END DO
267
268         ! debug point to follow
269         jiindex_1d = 0
270         IF( ln_icectl ) THEN
271            DO ji = mi0(iiceprt), mi1(iiceprt)
272               DO jj = mj0(jiceprt), mj1(jiceprt)
273                  jiindex_1d = (jj - 1) * jpi + ji
274                  WRITE(numout,*) ' lim_thd : Category no : ', jl 
275               END DO
276            END DO
277         ENDIF
278
279         !------------------------------------------------------------------------------!
280         ! 4) Thermodynamic computation
281         !------------------------------------------------------------------------------!
282
283         IF( lk_mpp )   CALL mpp_ini_ice( nbpb , numout )
284
285         IF( nbpb > 0 ) THEN  ! If there is no ice, do nothing.
286
287            !-------------------------!
288            ! --- Move to 1D arrays ---
289            !-------------------------!
290            CALL lim_thd_1d2d( nbpb, jl, 1 )
291
292            !--------------------------------------!
293            ! --- Ice/Snow Temperature profile --- !
294            !--------------------------------------!
295            CALL lim_thd_dif( 1, nbpb )
296
297            !---------------------------------!
298            ! --- Ice/Snow thickness ---      !
299            !---------------------------------!
300            CALL lim_thd_dh( 1, nbpb )   
301
302            ! --- Ice enthalpy remapping --- !
303            CALL lim_thd_ent( 1, nbpb, q_i_1d(1:nbpb,:) ) 
304                                           
305            !---------------------------------!
306            ! --- Ice salinity ---            !
307            !---------------------------------!
308            CALL lim_thd_sal( 1, nbpb )   
309
310            !---------------------------------!
311            ! --- temperature update ---      !
312            !---------------------------------!
313            CALL lim_thd_temp( 1, nbpb )
314
315            !------------------------------------!
316            ! --- lateral melting if monocat --- !
317            !------------------------------------!
318            IF ( ( nn_monocat == 1 .OR. nn_monocat == 4 ) .AND. jpl == 1 ) THEN
319               CALL lim_thd_lam( 1, nbpb )
320            END IF
321
322            !-------------------------!
323            ! --- Move to 2D arrays ---
324            !-------------------------!
325            CALL lim_thd_1d2d( nbpb, jl, 2 )
326
327            !
328            IF( lk_mpp )   CALL mpp_comm_free( ncomm_ice ) !RB necessary ??
329         ENDIF
330         !
331      END DO !jl
332
333      !------------------------------------------------------------------------------!
334      ! 5) Global variables, diagnostics
335      !------------------------------------------------------------------------------!
336
337      !------------------------
338      ! Ice heat content             
339      !------------------------
340      ! Enthalpies are global variables we have to readjust the units (heat content in J/m2)
341      DO jl = 1, jpl
342         DO jk = 1, nlay_i
343            e_i(:,:,jk,jl) = e_i(:,:,jk,jl) * a_i(:,:,jl) * ht_i(:,:,jl) * r1_nlay_i
344         END DO
345      END DO
346
347      !------------------------
348      ! Snow heat content             
349      !------------------------
350      ! Enthalpies are global variables we have to readjust the units (heat content in J/m2)
351      DO jl = 1, jpl
352         DO jk = 1, nlay_s
353            e_s(:,:,jk,jl) = e_s(:,:,jk,jl) * a_i(:,:,jl) * ht_s(:,:,jl) * r1_nlay_s
354         END DO
355      END DO
356 
357      !----------------------------------
358      ! Change thickness to volume
359      !----------------------------------
360      v_i(:,:,:)   = ht_i(:,:,:) * a_i(:,:,:)
361      v_s(:,:,:)   = ht_s(:,:,:) * a_i(:,:,:)
362      smv_i(:,:,:) = sm_i(:,:,:) * v_i(:,:,:)
363
364      ! update ice age (in case a_i changed, i.e. becomes 0 or lateral melting in monocat)
365      DO jl  = 1, jpl
366         DO jj = 1, jpj
367            DO ji = 1, jpi
368               rswitch = MAX( 0._wp , SIGN( 1._wp, a_i_b(ji,jj,jl) - epsi10 ) )
369               oa_i(ji,jj,jl) = rswitch * oa_i(ji,jj,jl) * a_i(ji,jj,jl) / MAX( a_i_b(ji,jj,jl), epsi10 )
370            END DO
371         END DO
372      END DO
373
374      CALL lim_var_zapsmall
375
376      !--------------------------------------------
377      ! Diagnostic thermodynamic growth rates
378      !--------------------------------------------
379      IF( ln_icectl )   CALL lim_prt( kt, iiceprt, jiceprt, 1, ' - ice thermodyn. - ' )   ! control print
380
381      IF(ln_ctl) THEN            ! Control print
382         CALL prt_ctl_info(' ')
383         CALL prt_ctl_info(' - Cell values : ')
384         CALL prt_ctl_info('   ~~~~~~~~~~~~~ ')
385         CALL prt_ctl(tab2d_1=e12t , clinfo1=' lim_thd  : cell area :')
386         CALL prt_ctl(tab2d_1=at_i , clinfo1=' lim_thd  : at_i      :')
387         CALL prt_ctl(tab2d_1=vt_i , clinfo1=' lim_thd  : vt_i      :')
388         CALL prt_ctl(tab2d_1=vt_s , clinfo1=' lim_thd  : vt_s      :')
389         DO jl = 1, jpl
390            CALL prt_ctl_info(' ')
391            CALL prt_ctl_info(' - Category : ', ivar1=jl)
392            CALL prt_ctl_info('   ~~~~~~~~~~')
393            CALL prt_ctl(tab2d_1=a_i   (:,:,jl)   , clinfo1= ' lim_thd  : a_i      : ')
394            CALL prt_ctl(tab2d_1=ht_i  (:,:,jl)   , clinfo1= ' lim_thd  : ht_i     : ')
395            CALL prt_ctl(tab2d_1=ht_s  (:,:,jl)   , clinfo1= ' lim_thd  : ht_s     : ')
396            CALL prt_ctl(tab2d_1=v_i   (:,:,jl)   , clinfo1= ' lim_thd  : v_i      : ')
397            CALL prt_ctl(tab2d_1=v_s   (:,:,jl)   , clinfo1= ' lim_thd  : v_s      : ')
398            CALL prt_ctl(tab2d_1=e_s   (:,:,1,jl) , clinfo1= ' lim_thd  : e_s      : ')
399            CALL prt_ctl(tab2d_1=t_su  (:,:,jl)   , clinfo1= ' lim_thd  : t_su     : ')
400            CALL prt_ctl(tab2d_1=t_s   (:,:,1,jl) , clinfo1= ' lim_thd  : t_snow   : ')
401            CALL prt_ctl(tab2d_1=sm_i  (:,:,jl)   , clinfo1= ' lim_thd  : sm_i     : ')
402            CALL prt_ctl(tab2d_1=smv_i (:,:,jl)   , clinfo1= ' lim_thd  : smv_i    : ')
403            DO jk = 1, nlay_i
404               CALL prt_ctl_info(' ')
405               CALL prt_ctl_info(' - Layer : ', ivar1=jk)
406               CALL prt_ctl_info('   ~~~~~~~')
407               CALL prt_ctl(tab2d_1=t_i(:,:,jk,jl) , clinfo1= ' lim_thd  : t_i      : ')
408               CALL prt_ctl(tab2d_1=e_i(:,:,jk,jl) , clinfo1= ' lim_thd  : e_i      : ')
409            END DO
410         END DO
411      ENDIF
412      !
413      !
414      IF( ln_limdiahsb ) CALL lim_cons_hsm(1, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
415
416      CALL wrk_dealloc( jpi,jpj, zqsr, zqns )
417
418      !------------------------------------------------------------------------------|
419      !  6) Transport of ice between thickness categories.                           |
420      !------------------------------------------------------------------------------|
421      ! Given thermodynamic growth rates, transport ice between thickness categories.
422      IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limitd_th_rem', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
423
424      IF( jpl > 1 )      CALL lim_itd_th_rem( 1, jpl, kt )
425
426      IF( ln_limdiahsb ) CALL lim_cons_hsm(1, 'limitd_th_rem', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
427
428      !------------------------------------------------------------------------------|
429      !  7) Add frazil ice growing in leads.
430      !------------------------------------------------------------------------------|
431      IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limthd_lac', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
432
433      CALL lim_thd_lac
434     
435      IF( ln_limdiahsb ) CALL lim_cons_hsm(1, 'limthd_lac', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
436
437      ! Control print
438      IF(ln_ctl) THEN
439         CALL lim_var_glo2eqv
440
441         CALL prt_ctl_info(' ')
442         CALL prt_ctl_info(' - Cell values : ')
443         CALL prt_ctl_info('   ~~~~~~~~~~~~~ ')
444         CALL prt_ctl(tab2d_1=e12t , clinfo1=' lim_itd_th  : cell area :')
445         CALL prt_ctl(tab2d_1=at_i , clinfo1=' lim_itd_th  : at_i      :')
446         CALL prt_ctl(tab2d_1=vt_i , clinfo1=' lim_itd_th  : vt_i      :')
447         CALL prt_ctl(tab2d_1=vt_s , clinfo1=' lim_itd_th  : vt_s      :')
448         DO jl = 1, jpl
449            CALL prt_ctl_info(' ')
450            CALL prt_ctl_info(' - Category : ', ivar1=jl)
451            CALL prt_ctl_info('   ~~~~~~~~~~')
452            CALL prt_ctl(tab2d_1=a_i   (:,:,jl)   , clinfo1= ' lim_itd_th  : a_i      : ')
453            CALL prt_ctl(tab2d_1=ht_i  (:,:,jl)   , clinfo1= ' lim_itd_th  : ht_i     : ')
454            CALL prt_ctl(tab2d_1=ht_s  (:,:,jl)   , clinfo1= ' lim_itd_th  : ht_s     : ')
455            CALL prt_ctl(tab2d_1=v_i   (:,:,jl)   , clinfo1= ' lim_itd_th  : v_i      : ')
456            CALL prt_ctl(tab2d_1=v_s   (:,:,jl)   , clinfo1= ' lim_itd_th  : v_s      : ')
457            CALL prt_ctl(tab2d_1=e_s   (:,:,1,jl) , clinfo1= ' lim_itd_th  : e_s      : ')
458            CALL prt_ctl(tab2d_1=t_su  (:,:,jl)   , clinfo1= ' lim_itd_th  : t_su     : ')
459            CALL prt_ctl(tab2d_1=t_s   (:,:,1,jl) , clinfo1= ' lim_itd_th  : t_snow   : ')
460            CALL prt_ctl(tab2d_1=sm_i  (:,:,jl)   , clinfo1= ' lim_itd_th  : sm_i     : ')
461            CALL prt_ctl(tab2d_1=smv_i (:,:,jl)   , clinfo1= ' lim_itd_th  : smv_i    : ')
462            DO jk = 1, nlay_i
463               CALL prt_ctl_info(' ')
464               CALL prt_ctl_info(' - Layer : ', ivar1=jk)
465               CALL prt_ctl_info('   ~~~~~~~')
466               CALL prt_ctl(tab2d_1=t_i(:,:,jk,jl) , clinfo1= ' lim_itd_th  : t_i      : ')
467               CALL prt_ctl(tab2d_1=e_i(:,:,jk,jl) , clinfo1= ' lim_itd_th  : e_i      : ')
468            END DO
469         END DO
470      ENDIF
471      !
472      IF( nn_timing == 1 )  CALL timing_stop('limthd')
473
474   END SUBROUTINE lim_thd 
475
476   SUBROUTINE lim_thd_temp( kideb, kiut )
477      !!-----------------------------------------------------------------------
478      !!                   ***  ROUTINE lim_thd_temp ***
479      !!                 
480      !! ** Purpose :   Computes sea ice temperature (Kelvin) from enthalpy
481      !!
482      !! ** Method  :   Formula (Bitz and Lipscomb, 1999)
483      !!-------------------------------------------------------------------
484      INTEGER, INTENT(in) ::   kideb, kiut   ! bounds for the spatial loop
485      !!
486      INTEGER  ::   ji, jk   ! dummy loop indices
487      REAL(wp) ::   ztmelts, zaaa, zbbb, zccc, zdiscrim  ! local scalar
488      !!-------------------------------------------------------------------
489      ! Recover ice temperature
490      DO jk = 1, nlay_i
491         DO ji = kideb, kiut
492            ztmelts       =  -tmut * s_i_1d(ji,jk) + rt0
493            ! Conversion q(S,T) -> T (second order equation)
494            zaaa          =  cpic
495            zbbb          =  ( rcp - cpic ) * ( ztmelts - rt0 ) + q_i_1d(ji,jk) * r1_rhoic - lfus
496            zccc          =  lfus * ( ztmelts - rt0 )
497            zdiscrim      =  SQRT( MAX( zbbb * zbbb - 4._wp * zaaa * zccc, 0._wp ) )
498            t_i_1d(ji,jk) =  rt0 - ( zbbb + zdiscrim ) / ( 2._wp * zaaa )
499           
500            ! mask temperature
501            rswitch       =  1._wp - MAX( 0._wp , SIGN( 1._wp , - ht_i_1d(ji) ) ) 
502            t_i_1d(ji,jk) =  rswitch * t_i_1d(ji,jk) + ( 1._wp - rswitch ) * rt0
503         END DO
504      END DO
505
506   END SUBROUTINE lim_thd_temp
507
508   SUBROUTINE lim_thd_lam( kideb, kiut )
509      !!-----------------------------------------------------------------------
510      !!                   ***  ROUTINE lim_thd_lam ***
511      !!                 
512      !! ** Purpose :   Lateral melting in case monocategory
513      !!                          ( dA = A/2h dh )
514      !!-----------------------------------------------------------------------
515      INTEGER, INTENT(in) ::   kideb, kiut        ! bounds for the spatial loop
516      INTEGER             ::   ji                 ! dummy loop indices
517      REAL(wp)            ::   zhi_bef            ! ice thickness before thermo
518      REAL(wp)            ::   zdh_mel, zda_mel   ! net melting
519      REAL(wp)            ::   zvi, zvs           ! ice/snow volumes
520
521      DO ji = kideb, kiut
522         zdh_mel = MIN( 0._wp, dh_i_surf(ji) + dh_i_bott(ji) + dh_snowice(ji) )
523         IF( zdh_mel < 0._wp .AND. a_i_1d(ji) > 0._wp )  THEN
524            zvi          = a_i_1d(ji) * ht_i_1d(ji)
525            zvs          = a_i_1d(ji) * ht_s_1d(ji)
526            ! lateral melting = concentration change
527            zhi_bef     = ht_i_1d(ji) - zdh_mel
528            rswitch     = MAX( 0._wp , SIGN( 1._wp , zhi_bef - epsi20 ) )
529            zda_mel     = rswitch * a_i_1d(ji) * zdh_mel / ( 2._wp * MAX( zhi_bef, epsi20 ) )
530            a_i_1d(ji)  = MAX( epsi20, a_i_1d(ji) + zda_mel ) 
531             ! adjust thickness
532            ht_i_1d(ji) = zvi / a_i_1d(ji)           
533            ht_s_1d(ji) = zvs / a_i_1d(ji)           
534            ! retrieve total concentration
535            at_i_1d(ji) = a_i_1d(ji)
536         END IF
537      END DO
538     
539   END SUBROUTINE lim_thd_lam
540
541   SUBROUTINE lim_thd_1d2d( nbpb, jl, kn )
542      !!-----------------------------------------------------------------------
543      !!                   ***  ROUTINE lim_thd_1d2d ***
544      !!                 
545      !! ** Purpose :   move arrays from 1d to 2d and the reverse
546      !!-----------------------------------------------------------------------
547      INTEGER, INTENT(in) ::   kn       ! 1= from 2D to 1D
548                                        ! 2= from 1D to 2D
549      INTEGER, INTENT(in) ::   nbpb     ! size of 1D arrays
550      INTEGER, INTENT(in) ::   jl       ! ice cat
551      INTEGER             ::   jk       ! dummy loop indices
552
553      SELECT CASE( kn )
554
555      CASE( 1 )
556
557         CALL tab_2d_1d( nbpb, at_i_1d     (1:nbpb), at_i            , jpi, jpj, npb(1:nbpb) )
558         CALL tab_2d_1d( nbpb, a_i_1d      (1:nbpb), a_i(:,:,jl)     , jpi, jpj, npb(1:nbpb) )
559         CALL tab_2d_1d( nbpb, ht_i_1d     (1:nbpb), ht_i(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
560         CALL tab_2d_1d( nbpb, ht_s_1d     (1:nbpb), ht_s(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
561         
562         CALL tab_2d_1d( nbpb, t_su_1d     (1:nbpb), t_su(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
563         CALL tab_2d_1d( nbpb, sm_i_1d     (1:nbpb), sm_i(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
564         DO jk = 1, nlay_s
565            CALL tab_2d_1d( nbpb, t_s_1d(1:nbpb,jk), t_s(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
566            CALL tab_2d_1d( nbpb, q_s_1d(1:nbpb,jk), e_s(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
567         END DO
568         DO jk = 1, nlay_i
569            CALL tab_2d_1d( nbpb, t_i_1d(1:nbpb,jk), t_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
570            CALL tab_2d_1d( nbpb, q_i_1d(1:nbpb,jk), e_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
571            CALL tab_2d_1d( nbpb, s_i_1d(1:nbpb,jk), s_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
572         END DO
573         
574         CALL tab_2d_1d( nbpb, tatm_ice_1d(1:nbpb), tatm_ice(:,:)   , jpi, jpj, npb(1:nbpb) )
575         CALL tab_2d_1d( nbpb, qsr_ice_1d (1:nbpb), qsr_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
576         CALL tab_2d_1d( nbpb, fr1_i0_1d  (1:nbpb), fr1_i0          , jpi, jpj, npb(1:nbpb) )
577         CALL tab_2d_1d( nbpb, fr2_i0_1d  (1:nbpb), fr2_i0          , jpi, jpj, npb(1:nbpb) )
578         CALL tab_2d_1d( nbpb, qns_ice_1d (1:nbpb), qns_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
579         CALL tab_2d_1d( nbpb, ftr_ice_1d (1:nbpb), ftr_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
580         IF( .NOT. lk_cpl ) THEN
581            CALL tab_2d_1d( nbpb, qla_ice_1d (1:nbpb), qla_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
582            CALL tab_2d_1d( nbpb, dqla_ice_1d(1:nbpb), dqla_ice(:,:,jl), jpi, jpj, npb(1:nbpb) )
583         ENDIF
584         CALL tab_2d_1d( nbpb, dqns_ice_1d(1:nbpb), dqns_ice(:,:,jl), jpi, jpj, npb(1:nbpb) )
585         CALL tab_2d_1d( nbpb, t_bo_1d     (1:nbpb), t_bo            , jpi, jpj, npb(1:nbpb) )
586         CALL tab_2d_1d( nbpb, sprecip_1d (1:nbpb), sprecip         , jpi, jpj, npb(1:nbpb) ) 
587         CALL tab_2d_1d( nbpb, fhtur_1d   (1:nbpb), fhtur           , jpi, jpj, npb(1:nbpb) )
588         CALL tab_2d_1d( nbpb, qlead_1d   (1:nbpb), qlead           , jpi, jpj, npb(1:nbpb) )
589         CALL tab_2d_1d( nbpb, fhld_1d    (1:nbpb), fhld            , jpi, jpj, npb(1:nbpb) )
590         
591         CALL tab_2d_1d( nbpb, wfx_snw_1d (1:nbpb), wfx_snw         , jpi, jpj, npb(1:nbpb) )
592         CALL tab_2d_1d( nbpb, wfx_sub_1d (1:nbpb), wfx_sub         , jpi, jpj, npb(1:nbpb) )
593         
594         CALL tab_2d_1d( nbpb, wfx_bog_1d (1:nbpb), wfx_bog         , jpi, jpj, npb(1:nbpb) )
595         CALL tab_2d_1d( nbpb, wfx_bom_1d (1:nbpb), wfx_bom         , jpi, jpj, npb(1:nbpb) )
596         CALL tab_2d_1d( nbpb, wfx_sum_1d (1:nbpb), wfx_sum         , jpi, jpj, npb(1:nbpb) )
597         CALL tab_2d_1d( nbpb, wfx_sni_1d (1:nbpb), wfx_sni         , jpi, jpj, npb(1:nbpb) )
598         CALL tab_2d_1d( nbpb, wfx_res_1d (1:nbpb), wfx_res         , jpi, jpj, npb(1:nbpb) )
599         CALL tab_2d_1d( nbpb, wfx_spr_1d (1:nbpb), wfx_spr         , jpi, jpj, npb(1:nbpb) )
600         
601         CALL tab_2d_1d( nbpb, sfx_bog_1d (1:nbpb), sfx_bog         , jpi, jpj, npb(1:nbpb) )
602         CALL tab_2d_1d( nbpb, sfx_bom_1d (1:nbpb), sfx_bom         , jpi, jpj, npb(1:nbpb) )
603         CALL tab_2d_1d( nbpb, sfx_sum_1d (1:nbpb), sfx_sum         , jpi, jpj, npb(1:nbpb) )
604         CALL tab_2d_1d( nbpb, sfx_sni_1d (1:nbpb), sfx_sni         , jpi, jpj, npb(1:nbpb) )
605         CALL tab_2d_1d( nbpb, sfx_bri_1d (1:nbpb), sfx_bri         , jpi, jpj, npb(1:nbpb) )
606         CALL tab_2d_1d( nbpb, sfx_res_1d (1:nbpb), sfx_res         , jpi, jpj, npb(1:nbpb) )
607         
608         CALL tab_2d_1d( nbpb, hfx_thd_1d (1:nbpb), hfx_thd         , jpi, jpj, npb(1:nbpb) )
609         CALL tab_2d_1d( nbpb, hfx_spr_1d (1:nbpb), hfx_spr         , jpi, jpj, npb(1:nbpb) )
610         CALL tab_2d_1d( nbpb, hfx_sum_1d (1:nbpb), hfx_sum         , jpi, jpj, npb(1:nbpb) )
611         CALL tab_2d_1d( nbpb, hfx_bom_1d (1:nbpb), hfx_bom         , jpi, jpj, npb(1:nbpb) )
612         CALL tab_2d_1d( nbpb, hfx_bog_1d (1:nbpb), hfx_bog         , jpi, jpj, npb(1:nbpb) )
613         CALL tab_2d_1d( nbpb, hfx_dif_1d (1:nbpb), hfx_dif         , jpi, jpj, npb(1:nbpb) )
614         CALL tab_2d_1d( nbpb, hfx_opw_1d (1:nbpb), hfx_opw         , jpi, jpj, npb(1:nbpb) )
615         CALL tab_2d_1d( nbpb, hfx_snw_1d (1:nbpb), hfx_snw         , jpi, jpj, npb(1:nbpb) )
616         CALL tab_2d_1d( nbpb, hfx_sub_1d (1:nbpb), hfx_sub         , jpi, jpj, npb(1:nbpb) )
617         CALL tab_2d_1d( nbpb, hfx_err_1d (1:nbpb), hfx_err         , jpi, jpj, npb(1:nbpb) )
618         CALL tab_2d_1d( nbpb, hfx_res_1d (1:nbpb), hfx_res         , jpi, jpj, npb(1:nbpb) )
619         CALL tab_2d_1d( nbpb, hfx_err_dif_1d (1:nbpb), hfx_err_dif , jpi, jpj, npb(1:nbpb) )
620         CALL tab_2d_1d( nbpb, hfx_err_rem_1d (1:nbpb), hfx_err_rem , jpi, jpj, npb(1:nbpb) )
621
622      CASE( 2 )
623
624         CALL tab_1d_2d( nbpb, at_i          , npb, at_i_1d    (1:nbpb)   , jpi, jpj )
625         CALL tab_1d_2d( nbpb, ht_i(:,:,jl)  , npb, ht_i_1d    (1:nbpb)   , jpi, jpj )
626         CALL tab_1d_2d( nbpb, ht_s(:,:,jl)  , npb, ht_s_1d    (1:nbpb)   , jpi, jpj )
627         CALL tab_1d_2d( nbpb, a_i (:,:,jl)  , npb, a_i_1d     (1:nbpb)   , jpi, jpj )
628         CALL tab_1d_2d( nbpb, t_su(:,:,jl)  , npb, t_su_1d    (1:nbpb)   , jpi, jpj )
629         CALL tab_1d_2d( nbpb, sm_i(:,:,jl)  , npb, sm_i_1d    (1:nbpb)   , jpi, jpj )
630         DO jk = 1, nlay_s
631            CALL tab_1d_2d( nbpb, t_s(:,:,jk,jl), npb, t_s_1d     (1:nbpb,jk), jpi, jpj)
632            CALL tab_1d_2d( nbpb, e_s(:,:,jk,jl), npb, q_s_1d     (1:nbpb,jk), jpi, jpj)
633         END DO
634         DO jk = 1, nlay_i
635            CALL tab_1d_2d( nbpb, t_i(:,:,jk,jl), npb, t_i_1d     (1:nbpb,jk), jpi, jpj)
636            CALL tab_1d_2d( nbpb, e_i(:,:,jk,jl), npb, q_i_1d     (1:nbpb,jk), jpi, jpj)
637            CALL tab_1d_2d( nbpb, s_i(:,:,jk,jl), npb, s_i_1d     (1:nbpb,jk), jpi, jpj)
638         END DO
639         CALL tab_1d_2d( nbpb, qlead         , npb, qlead_1d  (1:nbpb)   , jpi, jpj )
640         
641         CALL tab_1d_2d( nbpb, wfx_snw       , npb, wfx_snw_1d(1:nbpb)   , jpi, jpj )
642         CALL tab_1d_2d( nbpb, wfx_sub       , npb, wfx_sub_1d(1:nbpb)   , jpi, jpj )
643         
644         CALL tab_1d_2d( nbpb, wfx_bog       , npb, wfx_bog_1d(1:nbpb)   , jpi, jpj )
645         CALL tab_1d_2d( nbpb, wfx_bom       , npb, wfx_bom_1d(1:nbpb)   , jpi, jpj )
646         CALL tab_1d_2d( nbpb, wfx_sum       , npb, wfx_sum_1d(1:nbpb)   , jpi, jpj )
647         CALL tab_1d_2d( nbpb, wfx_sni       , npb, wfx_sni_1d(1:nbpb)   , jpi, jpj )
648         CALL tab_1d_2d( nbpb, wfx_res       , npb, wfx_res_1d(1:nbpb)   , jpi, jpj )
649         CALL tab_1d_2d( nbpb, wfx_spr       , npb, wfx_spr_1d(1:nbpb)   , jpi, jpj )
650         
651         CALL tab_1d_2d( nbpb, sfx_bog       , npb, sfx_bog_1d(1:nbpb)   , jpi, jpj )
652         CALL tab_1d_2d( nbpb, sfx_bom       , npb, sfx_bom_1d(1:nbpb)   , jpi, jpj )
653         CALL tab_1d_2d( nbpb, sfx_sum       , npb, sfx_sum_1d(1:nbpb)   , jpi, jpj )
654         CALL tab_1d_2d( nbpb, sfx_sni       , npb, sfx_sni_1d(1:nbpb)   , jpi, jpj )
655         CALL tab_1d_2d( nbpb, sfx_res       , npb, sfx_res_1d(1:nbpb)   , jpi, jpj )
656         CALL tab_1d_2d( nbpb, sfx_bri       , npb, sfx_bri_1d(1:nbpb)   , jpi, jpj )
657         
658         CALL tab_1d_2d( nbpb, hfx_thd       , npb, hfx_thd_1d(1:nbpb)   , jpi, jpj )
659         CALL tab_1d_2d( nbpb, hfx_spr       , npb, hfx_spr_1d(1:nbpb)   , jpi, jpj )
660         CALL tab_1d_2d( nbpb, hfx_sum       , npb, hfx_sum_1d(1:nbpb)   , jpi, jpj )
661         CALL tab_1d_2d( nbpb, hfx_bom       , npb, hfx_bom_1d(1:nbpb)   , jpi, jpj )
662         CALL tab_1d_2d( nbpb, hfx_bog       , npb, hfx_bog_1d(1:nbpb)   , jpi, jpj )
663         CALL tab_1d_2d( nbpb, hfx_dif       , npb, hfx_dif_1d(1:nbpb)   , jpi, jpj )
664         CALL tab_1d_2d( nbpb, hfx_opw       , npb, hfx_opw_1d(1:nbpb)   , jpi, jpj )
665         CALL tab_1d_2d( nbpb, hfx_snw       , npb, hfx_snw_1d(1:nbpb)   , jpi, jpj )
666         CALL tab_1d_2d( nbpb, hfx_sub       , npb, hfx_sub_1d(1:nbpb)   , jpi, jpj )
667         CALL tab_1d_2d( nbpb, hfx_err       , npb, hfx_err_1d(1:nbpb)   , jpi, jpj )
668         CALL tab_1d_2d( nbpb, hfx_res       , npb, hfx_res_1d(1:nbpb)   , jpi, jpj )
669         CALL tab_1d_2d( nbpb, hfx_err_rem   , npb, hfx_err_rem_1d(1:nbpb), jpi, jpj )
670         CALL tab_1d_2d( nbpb, hfx_err_dif   , npb, hfx_err_dif_1d(1:nbpb), jpi, jpj )
671         !
672         CALL tab_1d_2d( nbpb, qns_ice(:,:,jl), npb, qns_ice_1d(1:nbpb) , jpi, jpj)
673         CALL tab_1d_2d( nbpb, ftr_ice(:,:,jl), npb, ftr_ice_1d(1:nbpb) , jpi, jpj )
674         !         
675      END SELECT
676
677   END SUBROUTINE lim_thd_1d2d
678
679
680   SUBROUTINE lim_thd_init
681      !!-----------------------------------------------------------------------
682      !!                   ***  ROUTINE lim_thd_init ***
683      !!                 
684      !! ** Purpose :   Physical constants and parameters linked to the ice
685      !!              thermodynamics
686      !!
687      !! ** Method  :   Read the namicethd namelist and check the ice-thermo
688      !!              parameter values called at the first timestep (nit000)
689      !!
690      !! ** input   :   Namelist namicether
691      !!-------------------------------------------------------------------
692      INTEGER  ::   ios                 ! Local integer output status for namelist read
693      NAMELIST/namicethd/ rn_hnewice, ln_frazil, rn_maxfrazb, rn_vfrazb, rn_Cfrazb,                       &
694         &                rn_himin, rn_betas, rn_kappa_i, nn_conv_dif, rn_terr_dif, nn_ice_thcon, &
695         &                nn_monocat, ln_it_qnsice
696      !!-------------------------------------------------------------------
697      !
698      IF(lwp) THEN
699         WRITE(numout,*)
700         WRITE(numout,*) 'lim_thd : Ice Thermodynamics'
701         WRITE(numout,*) '~~~~~~~'
702      ENDIF
703      !
704      REWIND( numnam_ice_ref )              ! Namelist namicethd in reference namelist : Ice thermodynamics
705      READ  ( numnam_ice_ref, namicethd, IOSTAT = ios, ERR = 901)
706901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in reference namelist', lwp )
707
708      REWIND( numnam_ice_cfg )              ! Namelist namicethd in configuration namelist : Ice thermodynamics
709      READ  ( numnam_ice_cfg, namicethd, IOSTAT = ios, ERR = 902 )
710902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in configuration namelist', lwp )
711      IF(lwm) WRITE ( numoni, namicethd )
712      !
713      IF ( ( jpl > 1 ) .AND. ( nn_monocat == 1 ) ) THEN
714         nn_monocat = 0
715         IF(lwp) WRITE(numout, *) '   nn_monocat must be 0 in multi-category case '
716      ENDIF
717
718      !
719      IF(lwp) THEN                          ! control print
720         WRITE(numout,*)
721         WRITE(numout,*)'   Namelist of ice parameters for ice thermodynamic computation '
722         WRITE(numout,*)'      ice thick. for lateral accretion                        rn_hnewice   = ', rn_hnewice
723         WRITE(numout,*)'      Frazil ice thickness as a function of wind or not       ln_frazil    = ', ln_frazil
724         WRITE(numout,*)'      Maximum proportion of frazil ice collecting at bottom   rn_maxfrazb  = ', rn_maxfrazb
725         WRITE(numout,*)'      Thresold relative drift speed for collection of frazil  rn_vfrazb    = ', rn_vfrazb
726         WRITE(numout,*)'      Squeezing coefficient for collection of frazil          rn_Cfrazb    = ', rn_Cfrazb
727         WRITE(numout,*)'      minimum ice thickness                                   rn_himin     = ', rn_himin 
728         WRITE(numout,*)'      numerical carac. of the scheme for diffusion in ice '
729         WRITE(numout,*)'      coefficient for ice-lead partition of snowfall          rn_betas     = ', rn_betas
730         WRITE(numout,*)'      extinction radiation parameter in sea ice               rn_kappa_i   = ', rn_kappa_i
731         WRITE(numout,*)'      maximal n. of iter. for heat diffusion computation      nn_conv_dif  = ', nn_conv_dif
732         WRITE(numout,*)'      maximal err. on T for heat diffusion computation        rn_terr_dif  = ', rn_terr_dif
733         WRITE(numout,*)'      switch for comp. of thermal conductivity in the ice     nn_ice_thcon = ', nn_ice_thcon
734         WRITE(numout,*)'      check heat conservation in the ice/snow                 con_i        = ', con_i
735         WRITE(numout,*)'      virtual ITD mono-category parameterizations (1) or not  nn_monocat   = ', nn_monocat
736         WRITE(numout,*)'      iterate the surface non-solar flux (T) or not (F)       ln_it_qnsice = ', ln_it_qnsice
737      ENDIF
738      !
739   END SUBROUTINE lim_thd_init
740
741#else
742   !!----------------------------------------------------------------------
743   !!   Default option         Dummy module          NO  LIM3 sea-ice model
744   !!----------------------------------------------------------------------
745#endif
746
747   !!======================================================================
748END MODULE limthd
Note: See TracBrowser for help on using the repository browser.