New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcrnf.F90 in branches/2015/dev_r5204_CNRS_PISCES_dcy/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/2015/dev_r5204_CNRS_PISCES_dcy/NEMOGCM/NEMO/OPA_SRC/SBC/sbcrnf.F90 @ 5327

Last change on this file since 5327 was 5327, checked in by cetlod, 10 years ago

NEMOGCM_dev_r5204_CNRS_PISCES_dcy : Add an option which gives the possibility to create a runoff depht file from runoff climatology
  • Property svn:keywords set to Id
File size: 30.9 KB
Line 
1MODULE sbcrnf
2   !!======================================================================
3   !!                       ***  MODULE  sbcrnf  ***
4   !! Ocean forcing:  river runoff
5   !!=====================================================================
6   !! History :  OPA  ! 2000-11  (R. Hordoir, E. Durand)  NetCDF FORMAT
7   !!   NEMO     1.0  ! 2002-09  (G. Madec)  F90: Free form and module
8   !!            3.0  ! 2006-07  (G. Madec)  Surface module
9   !!            3.2  ! 2009-04  (B. Lemaire)  Introduce iom_put
10   !!            3.3  ! 2010-10  (R. Furner, G. Madec) runoff distributed over ocean levels
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   sbc_rnf      : monthly runoffs read in a NetCDF file
15   !!   sbc_rnf_init : runoffs initialisation
16   !!   rnf_mouth    : set river mouth mask
17   !!----------------------------------------------------------------------
18   USE dom_oce         ! ocean space and time domain
19   USE phycst          ! physical constants
20   USE sbc_oce         ! surface boundary condition variables
21   USE sbcisf          ! PM we could remove it I think
22   USE closea          ! closed seas
23   USE fldread         ! read input field at current time step
24   USE in_out_manager  ! I/O manager
25   USE iom             ! I/O module
26   USE lib_mpp         ! MPP library
27   USE eosbn2
28   USE wrk_nemo        ! Memory allocation
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   sbc_rnf       ! routine call in sbcmod module
34   PUBLIC   sbc_rnf_div   ! routine called in sshwzv module
35   PUBLIC   sbc_rnf_alloc ! routine call in sbcmod module
36   PUBLIC   sbc_rnf_init  ! (PUBLIC for TAM)
37   !                                                     !!* namsbc_rnf namelist *
38   CHARACTER(len=100), PUBLIC ::   cn_dir          !: Root directory for location of ssr files
39   LOGICAL           , PUBLIC ::   ln_rnf_depth      !: depth       river runoffs attribute specified in a file
40   LOGICAL                    ::   ln_rnf_depth_ini  !: depth       river runoffs  computed at the initialisation
41   REAL(wp)                   ::   rn_rnf_max        !: maximum value of the runoff climatologie ( ln_rnf_depth_ini = .true )
42   REAL(wp)                   ::   rn_dep_max        !: depth over which runoffs is spread ( ln_rnf_depth_ini = .true )
43   INTEGER                    ::   nn_rnf_depth_file !: create (=1) a runoff depth file or not (=0)
44   LOGICAL           , PUBLIC ::   ln_rnf_tem      !: temperature river runoffs attribute specified in a file
45   LOGICAL           , PUBLIC ::   ln_rnf_sal      !: salinity    river runoffs attribute specified in a file
46   LOGICAL           , PUBLIC ::   ln_rnf_emp      !: runoffs into a file to be read or already into precipitation
47   TYPE(FLD_N)       , PUBLIC ::   sn_rnf          !: information about the runoff file to be read
48   TYPE(FLD_N)       , PUBLIC ::   sn_cnf          !: information about the runoff mouth file to be read
49   TYPE(FLD_N)                ::   sn_s_rnf        !: information about the salinities of runoff file to be read
50   TYPE(FLD_N)                ::   sn_t_rnf        !: information about the temperatures of runoff file to be read
51   TYPE(FLD_N)                ::   sn_dep_rnf      !: information about the depth which river inflow affects
52   LOGICAL           , PUBLIC ::   ln_rnf_mouth    !: specific treatment in mouths vicinity
53   REAL(wp)          , PUBLIC ::   rn_hrnf         !: runoffs, depth over which enhanced vertical mixing is used
54   REAL(wp)          , PUBLIC ::   rn_avt_rnf      !: runoffs, value of the additional vertical mixing coef. [m2/s]
55   REAL(wp)          , PUBLIC ::   rn_rfact        !: multiplicative factor for runoff
56
57   INTEGER , PUBLIC  ::   nkrnf = 0         !: nb of levels over which Kz is increased at river mouths
58   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   rnfmsk              !: river mouth mask (hori.)
59   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:)     ::   rnfmsk_z            !: river mouth mask (vert.)
60   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   h_rnf               !: depth of runoff in m
61   INTEGER,  PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   nk_rnf              !: depth of runoff in model levels
62   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   rnf_tsc_b, rnf_tsc  !: before and now T & S runoff contents   [K.m/s & PSU.m/s]   
63
64   TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:) ::   sf_rnf       ! structure: river runoff (file information, fields read)
65   TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:) ::   sf_s_rnf     ! structure: river runoff salinity (file information, fields read) 
66   TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:) ::   sf_t_rnf     ! structure: river runoff temperature (file information, fields read) 
67 
68   !! * Substitutions 
69#  include "domzgr_substitute.h90" 
70   !!----------------------------------------------------------------------
71   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
72   !! $Id$
73   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
74   !!----------------------------------------------------------------------
75CONTAINS
76
77   INTEGER FUNCTION sbc_rnf_alloc()
78      !!----------------------------------------------------------------------
79      !!                ***  ROUTINE sbc_rnf_alloc  ***
80      !!----------------------------------------------------------------------
81      ALLOCATE( rnfmsk(jpi,jpj)         , rnfmsk_z(jpk)          ,     &
82         &      h_rnf (jpi,jpj)         , nk_rnf  (jpi,jpj)      ,     &
83         &      rnf_tsc_b(jpi,jpj,jpts) , rnf_tsc (jpi,jpj,jpts) , STAT=sbc_rnf_alloc )
84         !
85      IF( lk_mpp            )   CALL mpp_sum ( sbc_rnf_alloc )
86      IF( sbc_rnf_alloc > 0 )   CALL ctl_warn('sbc_rnf_alloc: allocation of arrays failed')
87   END FUNCTION sbc_rnf_alloc
88
89
90   SUBROUTINE sbc_rnf( kt )
91      !!----------------------------------------------------------------------
92      !!                  ***  ROUTINE sbc_rnf  ***
93      !!
94      !! ** Purpose :   Introduce a climatological run off forcing
95      !!
96      !! ** Method  :   Set each river mouth with a monthly climatology
97      !!                provided from different data.
98      !!                CAUTION : upward water flux, runoff forced to be < 0
99      !!
100      !! ** Action  :   runoff updated runoff field at time-step kt
101      !!----------------------------------------------------------------------
102      INTEGER, INTENT(in) ::   kt          ! ocean time step
103      !
104      INTEGER  ::   ji, jj    ! dummy loop indices
105      INTEGER  ::   z_err = 0 ! dummy integer for error handling
106      !!----------------------------------------------------------------------
107      REAL(wp), DIMENSION(:,:), POINTER       ::   ztfrz   ! freezing point used for temperature correction
108      !
109      CALL wrk_alloc( jpi,jpj, ztfrz)
110
111      !
112      IF( kt == nit000 )   CALL sbc_rnf_init                           ! Read namelist and allocate structures
113
114      !                                            ! ---------------------------------------- !
115      IF( kt /= nit000 ) THEN                      !          Swap of forcing fields          !
116         !                                         ! ---------------------------------------- !
117         rnf_b    (:,:  ) = rnf    (:,:  )               ! Swap the ocean forcing fields except at nit000
118         rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)               ! where before fields are set at the end of the routine
119         !
120      ENDIF
121
122      !                                                   !-------------------!
123      IF( .NOT. ln_rnf_emp ) THEN                         !   Update runoff   !
124         !                                                !-------------------!
125         !
126                             CALL fld_read ( kt, nn_fsbc, sf_rnf   )    ! Read Runoffs data and provide it at kt
127         IF( ln_rnf_tem  )   CALL fld_read ( kt, nn_fsbc, sf_t_rnf )    ! idem for runoffs temperature if required
128         IF( ln_rnf_sal  )   CALL fld_read ( kt, nn_fsbc, sf_s_rnf )    ! idem for runoffs salinity    if required
129         !
130         ! Runoff reduction only associated to the ORCA2_LIM configuration
131         ! when reading the NetCDF file runoff_1m_nomask.nc
132         IF( cp_cfg == 'orca' .AND. jp_cfg == 2 )   THEN
133            WHERE( 40._wp < gphit(:,:) .AND. gphit(:,:) < 65._wp )
134               sf_rnf(1)%fnow(:,:,1) = 0.85 * sf_rnf(1)%fnow(:,:,1)
135            END WHERE
136         ENDIF
137         !
138         IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN
139            !
140            rnf(:,:) = rn_rfact * ( sf_rnf(1)%fnow(:,:,1) )       ! updated runoff value at time step kt
141            !
142            !                                                     ! set temperature & salinity content of runoffs
143            IF( ln_rnf_tem ) THEN                                       ! use runoffs temperature data
144               rnf_tsc(:,:,jp_tem) = ( sf_t_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0
145               WHERE( sf_t_rnf(1)%fnow(:,:,1) == -999._wp )             ! if missing data value use SST as runoffs temperature
146                   rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0
147               END WHERE
148               WHERE( sf_t_rnf(1)%fnow(:,:,1) == -222._wp )             ! where fwf comes from melting of ice shelves or iceberg
149                   ztfrz(:,:) = -1.9 !tfreez( sss_m(:,:) ) !PM to be discuss (trouble if sensitivity study)
150                   rnf_tsc(:,:,jp_tem) = ztfrz(:,:) * rnf(:,:) * r1_rau0 - rnf(:,:) * lfusisf * r1_rau0_rcp
151               END WHERE
152            ELSE                                                        ! use SST as runoffs temperature
153               rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0
154            ENDIF
155            !                                                           ! use runoffs salinity data
156            IF( ln_rnf_sal )   rnf_tsc(:,:,jp_sal) = ( sf_s_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0
157            !                                                           ! else use S=0 for runoffs (done one for all in the init)
158            IF ( ANY( rnf(:,:) < 0._wp ) ) z_err=1
159            IF(lk_mpp) CALL mpp_sum(z_err)
160            IF( z_err > 0 ) CALL ctl_stop( 'sbc_rnf : negative runnoff values exist' )
161            !
162            CALL iom_put( "runoffs", rnf )         ! output runoffs arrays
163         ENDIF
164         !
165      ENDIF
166      !
167      IF( kt == nit000 ) THEN                          !   set the forcing field at nit000 - 1    !
168         !                                             ! ---------------------------------------- !
169         IF( ln_rstart .AND.    &                               !* Restart: read in restart file
170            & iom_varid( numror, 'rnf_b', ldstop = .FALSE. ) > 0 ) THEN
171            IF(lwp) WRITE(numout,*) '          nit000-1 runoff forcing fields red in the restart file'
172            CALL iom_get( numror, jpdom_autoglo, 'rnf_b', rnf_b )     ! before runoff
173            CALL iom_get( numror, jpdom_autoglo, 'rnf_hc_b', rnf_tsc_b(:,:,jp_tem) )   ! before heat content of runoff
174            CALL iom_get( numror, jpdom_autoglo, 'rnf_sc_b', rnf_tsc_b(:,:,jp_sal) )   ! before salinity content of runoff
175         ELSE                                                   !* no restart: set from nit000 values
176            IF(lwp) WRITE(numout,*) '          nit000-1 runoff forcing fields set to nit000'
177             rnf_b    (:,:  ) = rnf    (:,:  )
178             rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
179         ENDIF
180      ENDIF
181      !                                                ! ---------------------------------------- !
182      IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
183         !                                             ! ---------------------------------------- !
184         IF(lwp) WRITE(numout,*)
185         IF(lwp) WRITE(numout,*) 'sbcrnf : runoff forcing fields written in ocean restart file ',   &
186            &                    'at it= ', kt,' date= ', ndastp
187         IF(lwp) WRITE(numout,*) '~~~~'
188         CALL iom_rstput( kt, nitrst, numrow, 'rnf_b' , rnf )
189         CALL iom_rstput( kt, nitrst, numrow, 'rnf_hc_b', rnf_tsc(:,:,jp_tem) )
190         CALL iom_rstput( kt, nitrst, numrow, 'rnf_sc_b', rnf_tsc(:,:,jp_sal) )
191      ENDIF
192      CALL wrk_dealloc( jpi,jpj, ztfrz)
193      !
194   END SUBROUTINE sbc_rnf
195
196
197   SUBROUTINE sbc_rnf_div( phdivn )
198      !!----------------------------------------------------------------------
199      !!                  ***  ROUTINE sbc_rnf  ***
200      !!
201      !! ** Purpose :   update the horizontal divergence with the runoff inflow
202      !!
203      !! ** Method  :
204      !!                CAUTION : rnf is positive (inflow) decreasing the
205      !!                          divergence and expressed in m/s
206      !!
207      !! ** Action  :   phdivn   decreased by the runoff inflow
208      !!----------------------------------------------------------------------
209      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   phdivn   ! horizontal divergence
210      !!
211      INTEGER  ::   ji, jj, jk   ! dummy loop indices
212      REAL(wp) ::   zfact     ! local scalar
213      !!----------------------------------------------------------------------
214      !
215      zfact = 0.5_wp
216      !
217      IF( ln_rnf_depth ) THEN      !==   runoff distributed over several levels   ==!
218         IF( lk_vvl ) THEN             ! variable volume case
219            DO jj = 1, jpj                   ! update the depth over which runoffs are distributed
220               DO ji = 1, jpi
221                  h_rnf(ji,jj) = 0._wp
222                  DO jk = 1, nk_rnf(ji,jj)                           ! recalculates h_rnf to be the depth in metres
223                     h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk)   ! to the bottom of the relevant grid box
224                  END DO
225                  !                          ! apply the runoff input flow
226                  DO jk = 1, nk_rnf(ji,jj)
227                     phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj)
228                  END DO
229               END DO
230            END DO
231         ELSE                          ! constant volume case : just apply the runoff input flow
232            DO jj = 1, jpj
233               DO ji = 1, jpi
234                  DO jk = 1, nk_rnf(ji,jj)
235                     phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj)
236                  END DO
237               END DO
238            END DO
239         ENDIF
240      ELSE                       !==   runoff put only at the surface   ==!
241         IF( lk_vvl ) THEN              ! variable volume case
242            h_rnf(:,:) = fse3t(:,:,1)   ! recalculate h_rnf to be depth of top box
243         ENDIF
244         phdivn(:,:,1) = phdivn(:,:,1) - ( rnf(:,:) + rnf_b(:,:) ) * zfact * r1_rau0 / fse3t(:,:,1)
245      ENDIF
246      !
247   END SUBROUTINE sbc_rnf_div
248
249
250   SUBROUTINE sbc_rnf_init
251      !!----------------------------------------------------------------------
252      !!                  ***  ROUTINE sbc_rnf_init  ***
253      !!
254      !! ** Purpose :   Initialisation of the runoffs if (ln_rnf=T)
255      !!
256      !! ** Method  : - read the runoff namsbc_rnf namelist
257      !!
258      !! ** Action  : - read parameters
259      !!----------------------------------------------------------------------
260      CHARACTER(len=32) ::   rn_dep_file   ! runoff file name
261      INTEGER           ::   ji, jj, jk, jm    ! dummy loop indices
262      INTEGER           ::   ierror, inum  ! temporary integer
263      INTEGER           ::   ios           ! Local integer output status for namelist read
264      INTEGER           ::   nbrec         ! temporary integer
265      REAL(wp)          ::   zacoef 
266      REAL(wp), DIMENSION(12)                 :: zrec             ! times records
267      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: zrnfcl   
268      REAL(wp), DIMENSION(:,:  ), ALLOCATABLE :: zrnf
269      !
270      NAMELIST/namsbc_rnf/ cn_dir, ln_rnf_emp, ln_rnf_depth, ln_rnf_tem, ln_rnf_sal,   &
271         &                 sn_rnf, sn_cnf    , sn_s_rnf    , sn_t_rnf  , sn_dep_rnf,   &
272         &                 ln_rnf_mouth      , rn_hrnf     , rn_avt_rnf, rn_rfact,     &
273         &                 ln_rnf_depth_ini  , rn_dep_max  , rn_rnf_max, nn_rnf_depth_file
274      !!----------------------------------------------------------------------
275      !
276      !                                   ! ============
277      !                                   !   Namelist
278      !                                   ! ============
279      !
280      REWIND( numnam_ref )              ! Namelist namsbc_rnf in reference namelist : Runoffs
281      READ  ( numnam_ref, namsbc_rnf, IOSTAT = ios, ERR = 901)
282901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_rnf in reference namelist', lwp )
283
284      REWIND( numnam_cfg )              ! Namelist namsbc_rnf in configuration namelist : Runoffs
285      READ  ( numnam_cfg, namsbc_rnf, IOSTAT = ios, ERR = 902 )
286902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_rnf in configuration namelist', lwp )
287      IF(lwm) WRITE ( numond, namsbc_rnf )
288      !
289      !                                         ! Control print
290      IF(lwp) THEN
291         WRITE(numout,*)
292         WRITE(numout,*) 'sbc_rnf : runoff '
293         WRITE(numout,*) '~~~~~~~ '
294         WRITE(numout,*) '   Namelist namsbc_rnf'
295         WRITE(numout,*) '      runoff in a file to be read                ln_rnf_emp   = ', ln_rnf_emp
296         WRITE(numout,*) '      specific river mouths treatment            ln_rnf_mouth = ', ln_rnf_mouth
297         WRITE(numout,*) '      river mouth additional Kz                  rn_avt_rnf   = ', rn_avt_rnf
298         WRITE(numout,*) '      depth of river mouth additional mixing     rn_hrnf      = ', rn_hrnf
299         WRITE(numout,*) '      multiplicative factor for runoff           rn_rfact     = ', rn_rfact
300      ENDIF
301      !
302      !                                   ! ==================
303      !                                   !   Type of runoff
304      !                                   ! ==================
305      !                                         !==  allocate runoff arrays
306      IF( sbc_rnf_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_rnf_alloc : unable to allocate arrays' )
307      !
308      IF( ln_rnf_emp ) THEN                     !==  runoffs directly provided in the precipitations  ==!
309         IF(lwp) WRITE(numout,*)
310         IF(lwp) WRITE(numout,*) '          runoffs directly provided in the precipitations'
311         IF( ln_rnf_depth .OR. ln_rnf_tem .OR. ln_rnf_sal .OR. ln_rnf_depth_ini ) THEN
312           CALL ctl_warn( 'runoffs already included in precipitations, so runoff (T,S, depth) attributes will not be used' )
313           ln_rnf_depth = .FALSE.   ;   ln_rnf_tem = .FALSE.   ;   ln_rnf_sal = .FALSE.  ;   ln_rnf_depth_ini = .FALSE.
314         ENDIF
315         !
316      ELSE                                      !==  runoffs read in a file : set sf_rnf structure  ==!
317         !
318         ALLOCATE( sf_rnf(1), STAT=ierror )         ! Create sf_rnf structure (runoff inflow)
319         IF(lwp) WRITE(numout,*)
320         IF(lwp) WRITE(numout,*) '          runoffs inflow read in a file'
321         IF( ierror > 0 ) THEN
322            CALL ctl_stop( 'sbc_rnf: unable to allocate sf_rnf structure' )   ;   RETURN
323         ENDIF
324         ALLOCATE( sf_rnf(1)%fnow(jpi,jpj,1)   )
325         IF( sn_rnf%ln_tint ) ALLOCATE( sf_rnf(1)%fdta(jpi,jpj,1,2) )
326         !                                          ! fill sf_rnf with the namelist (sn_rnf) and control print
327         CALL fld_fill( sf_rnf, (/ sn_rnf /), cn_dir, 'sbc_rnf_init', 'read runoffs data', 'namsbc_rnf' )
328         !
329         IF( ln_rnf_tem ) THEN                      ! Create (if required) sf_t_rnf structure
330            IF(lwp) WRITE(numout,*)
331            IF(lwp) WRITE(numout,*) '          runoffs temperatures read in a file'
332            ALLOCATE( sf_t_rnf(1), STAT=ierror  )
333            IF( ierror > 0 ) THEN
334               CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_t_rnf structure' )   ;   RETURN
335            ENDIF
336            ALLOCATE( sf_t_rnf(1)%fnow(jpi,jpj,1)   )
337            IF( sn_t_rnf%ln_tint ) ALLOCATE( sf_t_rnf(1)%fdta(jpi,jpj,1,2) )
338            CALL fld_fill (sf_t_rnf, (/ sn_t_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff temperature data', 'namsbc_rnf' )
339         ENDIF
340         !
341         IF( ln_rnf_sal  ) THEN                     ! Create (if required) sf_s_rnf and sf_t_rnf structures
342            IF(lwp) WRITE(numout,*)
343            IF(lwp) WRITE(numout,*) '          runoffs salinities read in a file'
344            ALLOCATE( sf_s_rnf(1), STAT=ierror  )
345            IF( ierror > 0 ) THEN
346               CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_s_rnf structure' )   ;   RETURN
347            ENDIF
348            ALLOCATE( sf_s_rnf(1)%fnow(jpi,jpj,1)   )
349            IF( sn_s_rnf%ln_tint ) ALLOCATE( sf_s_rnf(1)%fdta(jpi,jpj,1,2) )
350            CALL fld_fill (sf_s_rnf, (/ sn_s_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff salinity data', 'namsbc_rnf' )
351         ENDIF
352         !
353         IF( ln_rnf_depth ) THEN                    ! depth of runoffs set from a file
354            IF(lwp) WRITE(numout,*)
355            IF(lwp) WRITE(numout,*) '          runoffs depth read in a file'
356            rn_dep_file = TRIM( cn_dir )//TRIM( sn_dep_rnf%clname )
357            IF( .NOT. sn_dep_rnf%ln_clim ) THEN   ;   WRITE(rn_dep_file, '(a,"_y",i4)' ) TRIM( rn_dep_file ), nyear    ! add year
358               IF( sn_dep_rnf%cltype == 'monthly' )   WRITE(rn_dep_file, '(a,"m",i2)'  ) TRIM( rn_dep_file ), nmonth   ! add month
359            ENDIF
360            CALL iom_open ( rn_dep_file, inum )                           ! open file
361            CALL iom_get  ( inum, jpdom_data, sn_dep_rnf%clvar, h_rnf )   ! read the river mouth array
362            CALL iom_close( inum )                                        ! close file
363            !
364            nk_rnf(:,:) = 0                               ! set the number of level over which river runoffs are applied
365            DO jj = 1, jpj
366               DO ji = 1, jpi
367                  IF( h_rnf(ji,jj) > 0._wp ) THEN
368                     jk = 2
369                     DO WHILE ( jk /= mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ;  jk = jk + 1 ;  END DO
370                     nk_rnf(ji,jj) = jk
371                  ELSEIF( h_rnf(ji,jj) == -1._wp   ) THEN   ;  nk_rnf(ji,jj) = 1
372                  ELSEIF( h_rnf(ji,jj) == -999._wp ) THEN   ;  nk_rnf(ji,jj) = mbkt(ji,jj)
373                  ELSE
374                     CALL ctl_stop( 'sbc_rnf_init: runoff depth not positive, and not -999 or -1, rnf value in file fort.999'  )
375                     WRITE(999,*) 'ji, jj, h_rnf(ji,jj) :', ji, jj, h_rnf(ji,jj)
376                  ENDIF
377               END DO
378            END DO
379            DO jj = 1, jpj                                ! set the associated depth
380               DO ji = 1, jpi
381                  h_rnf(ji,jj) = 0._wp
382                  DO jk = 1, nk_rnf(ji,jj)
383                     h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk)
384                  END DO
385               END DO
386            END DO
387            !
388         ELSE IF( ln_rnf_depth_ini ) THEN           ! runoffs applied at the surface
389            !
390            IF(lwp) WRITE(numout,*)
391            IF(lwp) WRITE(numout,*) '    depth of runoff computed once from max value of runoff'
392            IF(lwp) WRITE(numout,*) '    max value of the runoff climatologie (over global domain) rn_rnf_max = ', rn_rnf_max
393            IF(lwp) WRITE(numout,*) '    depth over which runoffs is spread                        rn_dep_max = ', rn_dep_max
394            IF(lwp) WRITE(numout,*) '     create (=1) a runoff depth file or not (=0)      nn_rnf_depth_file  = ', nn_rnf_depth_file
395
396            CALL iom_open( TRIM( sn_rnf%clname ), inum )    !  open runoff file
397            CALL iom_gettime( inum, zrec, kntime=nbrec)
398            ALLOCATE( zrnfcl(jpi,jpj,nbrec) )     ;      ALLOCATE( zrnf(jpi,jpj) )
399            DO jm = 1, nbrec
400               CALL iom_get( inum, jpdom_data, TRIM( sn_rnf%clvar ), zrnfcl(:,:,jm), jm )
401            END DO
402            CALL iom_close( inum )
403            zrnf(:,:) = MAXVAL( zrnfcl(:,:,:), DIM=3 )   !  maximum value in time
404            DEALLOCATE( zrnfcl )
405            !
406            h_rnf(:,:) = 1.
407            !
408            zacoef = rn_dep_max / rn_rnf_max            ! coef of linear relation between runoff and its depth (150m for max of runoff)
409            !
410            WHERE( zrnf(:,:) > 0._wp )  h_rnf(:,:) = zacoef * zrnf(:,:)   ! compute depth for all runoffs
411            !
412            DO jj = 1, jpj                     ! take in account min depth of ocean rn_hmin
413               DO ji = 1, jpi
414                  IF( zrnf(ji,jj) > 0._wp ) THEN
415                     jk = mbkt(ji,jj)
416                     h_rnf(ji,jj) = MIN( h_rnf(ji,jj), gdept_0(ji,jj,jk ) )
417                  ENDIF
418               END DO
419            END DO
420            !
421            nk_rnf(:,:) = 0                       ! number of levels on which runoffs are distributed
422            DO jj = 1, jpj
423               DO ji = 1, jpi
424                   IF( zrnf(ji,jj) > 0._wp ) THEN
425                     jk = 2
426                     DO WHILE ( jk /= mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ;  jk = jk + 1 ;  END DO
427                     nk_rnf(ji,jj) = jk
428                   ELSE
429                     nk_rnf(ji,jj) = 1
430                   ENDIF
431                END DO
432            END DO
433            !
434            DEALLOCATE( zrnf )
435            !
436            DO jj = 1, jpj                                ! set the associated depth
437               DO ji = 1, jpi
438                  h_rnf(ji,jj) = 0._wp
439                  DO jk = 1, nk_rnf(ji,jj)
440                     h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk)
441                  END DO
442               END DO
443            END DO
444            !
445            IF( nn_rnf_depth_file == 1 ) THEN      !  save  output nb levels for runoff
446               IF(lwp) WRITE(numout,*) '              create runoff depht file'
447               CALL iom_open  ( TRIM( sn_dep_rnf%clname ), inum, ldwrt = .TRUE., kiolib = jprstlib )
448               CALL iom_rstput( 0, 0, inum, 'rodepth', h_rnf )
449               CALL iom_close ( inum )
450            ENDIF
451         ELSE                                       ! runoffs applied at the surface
452            nk_rnf(:,:) = 1
453            h_rnf (:,:) = fse3t(:,:,1)
454         ENDIF
455         !
456      ENDIF
457      !
458      rnf(:,:) =  0._wp                         ! runoff initialisation
459      rnf_tsc(:,:,:) = 0._wp                    ! runoffs temperature & salinty contents initilisation
460      !
461      !                                   ! ========================
462      !                                   !   River mouth vicinity
463      !                                   ! ========================
464      !
465      IF( ln_rnf_mouth ) THEN                   ! Specific treatment in vicinity of river mouths :
466         !                                      !    - Increase Kz in surface layers ( rn_hrnf > 0 )
467         !                                      !    - set to zero SSS damping (ln_ssr=T)
468         !                                      !    - mixed upstream-centered (ln_traadv_cen2=T)
469         !
470         IF ( ln_rnf_depth )   CALL ctl_warn( 'sbc_rnf_init: increased mixing turned on but effects may already',   &
471            &                                              'be spread through depth by ln_rnf_depth'               )
472         !
473         nkrnf = 0                                  ! Number of level over which Kz increase
474         IF( rn_hrnf > 0._wp ) THEN
475            nkrnf = 2
476            DO WHILE( nkrnf /= jpkm1 .AND. gdepw_1d(nkrnf+1) < rn_hrnf )   ;   nkrnf = nkrnf + 1   ;   END DO
477            IF( ln_sco )   CALL ctl_warn( 'sbc_rnf: number of levels over which Kz is increased is computed for zco...' )
478         ENDIF
479         IF(lwp) WRITE(numout,*)
480         IF(lwp) WRITE(numout,*) '          Specific treatment used in vicinity of river mouths :'
481         IF(lwp) WRITE(numout,*) '             - Increase Kz in surface layers (if rn_hrnf > 0 )'
482         IF(lwp) WRITE(numout,*) '               by ', rn_avt_rnf,' m2/s  over ', nkrnf, ' w-levels'
483         IF(lwp) WRITE(numout,*) '             - set to zero SSS damping       (if ln_ssr=T)'
484         IF(lwp) WRITE(numout,*) '             - mixed upstream-centered       (if ln_traadv_cen2=T)'
485         !
486         CALL rnf_mouth                             ! set river mouth mask
487         !
488      ELSE                                      ! No treatment at river mouths
489         IF(lwp) WRITE(numout,*)
490         IF(lwp) WRITE(numout,*) '          No specific treatment at river mouths'
491         rnfmsk  (:,:) = 0._wp
492         rnfmsk_z(:)   = 0._wp
493         nkrnf = 0
494      ENDIF
495      !
496   END SUBROUTINE sbc_rnf_init
497
498
499   SUBROUTINE rnf_mouth
500      !!----------------------------------------------------------------------
501      !!                  ***  ROUTINE rnf_mouth  ***
502      !!
503      !! ** Purpose :   define the river mouths mask
504      !!
505      !! ** Method  :   read the river mouth mask (=0/1) in the river runoff
506      !!                climatological file. Defined a given vertical structure.
507      !!                CAUTION, the vertical structure is hard coded on the
508      !!                first 5 levels.
509      !!                This fields can be used to:
510      !!                 - set an upstream advection scheme
511      !!                   (ln_rnf_mouth=T and ln_traadv_cen2=T)
512      !!                 - increase vertical on the top nn_krnf vertical levels
513      !!                   at river runoff input grid point (nn_krnf>=2, see step.F90)
514      !!                 - set to zero SSS restoring flux at river mouth grid points
515      !!
516      !! ** Action  :   rnfmsk   set to 1 at river runoff input, 0 elsewhere
517      !!                rnfmsk_z vertical structure
518      !!----------------------------------------------------------------------
519      INTEGER            ::   inum        ! temporary integers
520      CHARACTER(len=140) ::   cl_rnfile   ! runoff file name
521      !!----------------------------------------------------------------------
522      !
523      IF(lwp) WRITE(numout,*)
524      IF(lwp) WRITE(numout,*) 'rnf_mouth : river mouth mask'
525      IF(lwp) WRITE(numout,*) '~~~~~~~~~ '
526      !
527      cl_rnfile = TRIM( cn_dir )//TRIM( sn_cnf%clname )
528      IF( .NOT. sn_cnf%ln_clim ) THEN   ;   WRITE(cl_rnfile, '(a,"_y",i4)' ) TRIM( cl_rnfile ), nyear    ! add year
529         IF( sn_cnf%cltype == 'monthly' )   WRITE(cl_rnfile, '(a,"m",i2)'  ) TRIM( cl_rnfile ), nmonth   ! add month
530      ENDIF
531      !
532      ! horizontal mask (read in NetCDF file)
533      CALL iom_open ( cl_rnfile, inum )                           ! open file
534      CALL iom_get  ( inum, jpdom_data, sn_cnf%clvar, rnfmsk )    ! read the river mouth array
535      CALL iom_close( inum )                                      ! close file
536      !
537      IF( nn_closea == 1 )   CALL clo_rnf( rnfmsk )               ! closed sea inflow set as ruver mouth
538      !
539      rnfmsk_z(:)   = 0._wp                                       ! vertical structure
540      rnfmsk_z(1)   = 1.0
541      rnfmsk_z(2)   = 1.0                                         ! **********
542      rnfmsk_z(3)   = 0.5                                         ! HARD CODED on the 5 first levels
543      rnfmsk_z(4)   = 0.25                                        ! **********
544      rnfmsk_z(5)   = 0.125
545      !
546   END SUBROUTINE rnf_mouth
547
548   !!======================================================================
549END MODULE sbcrnf
Note: See TracBrowser for help on using the repository browser.