New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcsms_cfc.F90 in branches/2015/nemo_v3_6_STABLE/NEMOGCM/NEMO/TOP_SRC/CFC – NEMO

source: branches/2015/nemo_v3_6_STABLE/NEMOGCM/NEMO/TOP_SRC/CFC/trcsms_cfc.F90 @ 8396

Last change on this file since 8396 was 8396, checked in by lovato, 7 years ago

3.6_stable: fix bug in CFC fluxes indexing for output (#1925)

  • Property svn:keywords set to Id
File size: 14.4 KB
Line 
1MODULE trcsms_cfc
2   !!======================================================================
3   !!                      ***  MODULE trcsms_cfc  ***
4   !! TOP : CFC main model
5   !!======================================================================
6   !! History :  OPA  !  1999-10  (JC. Dutay)  original code
7   !!  NEMO      1.0  !  2004-03  (C. Ethe) free form + modularity
8   !!            2.0  !  2007-12  (C. Ethe, G. Madec)  reorganisation
9   !!----------------------------------------------------------------------
10#if defined key_cfc
11   !!----------------------------------------------------------------------
12   !!   'key_cfc'                                               CFC tracers
13   !!----------------------------------------------------------------------
14   !!   trc_sms_cfc  :  compute and add CFC suface forcing to CFC trends
15   !!   cfc_init     :  sets constants for CFC surface forcing computation
16   !!----------------------------------------------------------------------
17   USE oce_trc       ! Ocean variables
18   USE par_trc       ! TOP parameters
19   USE trc           ! TOP variables
20   USE trd_oce
21   USE trdtrc
22   USE iom           ! I/O library
23
24   IMPLICIT NONE
25   PRIVATE
26
27   PUBLIC   trc_sms_cfc         ! called in ???   
28   PUBLIC   trc_sms_cfc_alloc   ! called in trcini_cfc.F90
29
30   INTEGER , PUBLIC, PARAMETER ::   jphem  =   2   ! parameter for the 2 hemispheres
31   INTEGER , PUBLIC            ::   jpyear         ! Number of years read in input data file (in trcini_cfc)
32   INTEGER , PUBLIC            ::   ndate_beg      ! initial calendar date (aammjj) for CFC
33   INTEGER , PUBLIC            ::   nyear_res      ! restoring time constant (year)
34   INTEGER , PUBLIC            ::   nyear_beg      ! initial year (aa)
35   CHARACTER(len=200), PUBLIC  ::   clnamecfc      ! Input filename of CFCs atm. concentrations
36   
37   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   p_cfc    ! partial hemispheric pressure for CFC
38   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   xphem    ! spatial interpolation factor for patm
39   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   qtr_cfc  ! flux at surface
40   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   qint_cfc ! cumulative flux
41   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   atm_cfc  ! partial hemispheric pressure for used CFC
42   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   patm     ! atmospheric function
43
44   REAL(wp),         ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   soa      ! coefficient for solubility of CFC [mol/l/atm]
45   REAL(wp),         ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   sob      !    "               "
46   REAL(wp),         ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   sca      ! coefficients for schmidt number in degrees Celsius
47   !                          ! coefficients for conversion
48   REAL(wp) ::   xconv1 = 1.0          ! conversion from to
49   REAL(wp) ::   xconv2 = 0.01/3600.   ! conversion from cm/h to m/s:
50   REAL(wp) ::   xconv3 = 1.0e+3       ! conversion from mol/l/atm to mol/m3/atm
51   REAL(wp) ::   xconv4 = 1.0e-12      ! conversion from mol/m3/atm to mol/m3/pptv
52
53   !! * Substitutions
54#  include "top_substitute.h90"
55   !!----------------------------------------------------------------------
56   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
57   !! $Id$
58   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
59   !!----------------------------------------------------------------------
60CONTAINS
61
62   SUBROUTINE trc_sms_cfc( kt )
63      !!----------------------------------------------------------------------
64      !!                     ***  ROUTINE trc_sms_cfc  ***
65      !!
66      !! ** Purpose :   Compute the surface boundary contition on CFC 11
67      !!             passive tracer associated with air-mer fluxes and add it
68      !!             to the general trend of tracers equations.
69      !!
70      !! ** Method  : - get the atmospheric partial pressure - given in pico -
71      !!              - computation of solubility ( in 1.e-12 mol/l then in 1.e-9 mol/m3)
72      !!              - computation of transfert speed ( given in cm/hour ----> cm/s )
73      !!              - the input function is given by :
74      !!                speed * ( concentration at equilibrium - concentration at surface )
75      !!              - the input function is in pico-mol/m3/s and the
76      !!                CFC concentration in pico-mol/m3
77      !!----------------------------------------------------------------------
78      !
79      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
80      !
81      INTEGER  ::   ji, jj, jn, jl, jm, js
82      INTEGER  ::   iyear_beg, iyear_end
83      INTEGER  ::   im1, im2, ierr
84      REAL(wp) ::   ztap, zdtap       
85      REAL(wp) ::   zt1, zt2, zt3, zt4, zv2
86      REAL(wp) ::   zsol      ! solubility
87      REAL(wp) ::   zsch      ! schmidt number
88      REAL(wp) ::   zpp_cfc   ! atmospheric partial pressure of CFC
89      REAL(wp) ::   zca_cfc   ! concentration at equilibrium
90      REAL(wp) ::   zak_cfc   ! transfert coefficients
91      REAL(wp), ALLOCATABLE, DIMENSION(:,:)  ::   zpatm     ! atmospheric function
92      !!----------------------------------------------------------------------
93      !
94      !
95      IF( nn_timing == 1 )  CALL timing_start('trc_sms_cfc')
96
97      IF(lwp) WRITE(numout,*)
98      IF(lwp) WRITE(numout,*) ' trc_sms_cfc:  CFC model'
99      IF(lwp) WRITE(numout,*) ' ~~~~~~~~~~~~~~'
100      !
101      ALLOCATE( zpatm(jphem,jp_cfc), STAT=ierr )
102      IF( ierr > 0 ) THEN
103         CALL ctl_stop( 'trc_sms_cfc: unable to allocate zpatm array' )   ;   RETURN
104      ENDIF
105
106      IF( kt == nittrc000 )   CALL cfc_init
107
108      ! Temporal interpolation
109      ! ----------------------
110      iyear_beg = nyear - 1900
111      IF ( nmonth <= 6 ) THEN
112         iyear_beg = iyear_beg - 1
113         im1       =  6 - nmonth + 1
114         im2       =  6 + nmonth - 1
115      ELSE
116         im1       = 12 - nmonth + 7
117         im2       =      nmonth - 7
118      ENDIF
119      iyear_end = iyear_beg + 1
120
121      !                                                  !------------!
122      DO jl = 1, jp_cfc                                  !  CFC loop  !
123         !                                               !------------!
124         jn = jp_cfc0 + jl - 1
125         ! time interpolation at time kt
126         DO jm = 1, jphem
127            zpatm(jm,jl) = (  atm_cfc(iyear_beg, jm, jl) * REAL(im1, wp)  &
128               &           +  atm_cfc(iyear_end, jm, jl) * REAL(im2, wp) ) / 12.
129         END DO
130         
131         !                                                         !------------!
132         DO jj = 1, jpj                                            !  i-j loop  !
133            DO ji = 1, jpi                                         !------------!
134 
135               ! space interpolation
136               zpp_cfc  =       xphem(ji,jj)   * zpatm(1,jl)   &
137                  &     + ( 1.- xphem(ji,jj) ) * zpatm(2,jl)
138
139               ! Computation of concentration at equilibrium : in picomol/l
140               ! coefficient for solubility for CFC-11/12 in  mol/l/atm
141               IF( tmask(ji,jj,1) .GE. 0.5 ) THEN
142                  ztap  = ( tsn(ji,jj,1,jp_tem) + 273.16 ) * 0.01
143                  zdtap = sob(1,jl) + ztap * ( sob(2,jl) + ztap * sob(3,jl) ) 
144                  zsol  =  EXP( soa(1,jl) + soa(2,jl) / ztap + soa(3,jl) * LOG( ztap )   &
145                     &                    + soa(4,jl) * ztap * ztap + tsn(ji,jj,1,jp_sal) * zdtap ) 
146               ELSE
147                  zsol  = 0.e0
148               ENDIF
149               ! conversion from mol/l/atm to mol/m3/atm and from mol/m3/atm to mol/m3/pptv   
150               zsol = xconv4 * xconv3 * zsol * tmask(ji,jj,1) 
151               ! concentration at equilibrium
152               zca_cfc = xconv1 * zpp_cfc * zsol * tmask(ji,jj,1)             
153 
154               ! Computation of speed transfert
155               !    Schmidt number revised in Wanninkhof (2014)
156               zt1  = tsn(ji,jj,1,jp_tem)
157               zt2  = zt1 * zt1 
158               zt3  = zt1 * zt2
159               zt4  = zt2 * zt2
160               zsch = sca(1,jl) + sca(2,jl) * zt1 + sca(3,jl) * zt2 + sca(4,jl) * zt3 + sca(5,jl) * zt4
161
162               !    speed transfert : formulae revised in Wanninkhof (2014)
163               zv2     = wndm(ji,jj) * wndm(ji,jj)
164               zsch    = zsch / 660.
165               zak_cfc = ( 0.31 * xconv2 * zv2 / SQRT(zsch) ) * tmask(ji,jj,1)
166
167               ! Input function  : speed *( conc. at equil - concen at surface )
168               ! trn in pico-mol/l idem qtr; ak in en m/a
169               qtr_cfc(ji,jj,jl) = -zak_cfc * ( trb(ji,jj,1,jn) - zca_cfc )   &
170#if defined key_degrad
171                  &                         * facvol(ji,jj,1)                           &
172#endif
173                  &                         * tmask(ji,jj,1) * ( 1. - fr_i(ji,jj) )
174               ! Add the surface flux to the trend
175               tra(ji,jj,1,jn) = tra(ji,jj,1,jn) + qtr_cfc(ji,jj,jl) / fse3t(ji,jj,1) 
176
177               ! cumulation of surface flux at each time step
178               qint_cfc(ji,jj,jl) = qint_cfc(ji,jj,jl) + qtr_cfc(ji,jj,jl) * rdt
179               !                                               !----------------!
180            END DO                                             !  end i-j loop  !
181         END DO                                                !----------------!
182         !                                                  !----------------!
183      END DO                                                !  end CFC loop  !
184      !
185      IF( lrst_trc ) THEN
186         IF(lwp) WRITE(numout,*)
187         IF(lwp) WRITE(numout,*) 'trc_sms_cfc : cumulated input function fields written in ocean restart file ',   &
188            &                    'at it= ', kt,' date= ', ndastp
189         IF(lwp) WRITE(numout,*) '~~~~'
190         DO jn = jp_cfc0, jp_cfc1
191            CALL iom_rstput( kt, nitrst, numrtw, 'qint_'//ctrcnm(jn), qint_cfc(:,:,jn) )
192         END DO
193      ENDIF                                           
194      !
195      IF( lk_iomput ) THEN
196         jl = 0
197         DO jn = jp_cfc0, jp_cfc1
198            jl = jl + 1
199            CALL iom_put( 'qtr_'//TRIM(ctrcnm(jn)) , qtr_cfc (:,:,jl) )
200            CALL iom_put( 'qint_'//TRIM(ctrcnm(jn)), qint_cfc(:,:,jl) )
201         ENDDO
202      ELSE
203         IF( ln_diatrc ) THEN
204            jl = 0
205            DO jn = jp_cfc0_2d, jp_cfc1_2d, 2
206               jl = jl + 1
207               trc2d(:,:,jn    ) = qtr_cfc (:,:,jl)
208               trc2d(:,:,jn + 1) = qint_cfc(:,:,jl)
209            ENDDO
210         END IF
211      END IF
212      !
213      IF( l_trdtrc ) THEN
214          DO jn = jp_cfc0, jp_cfc1
215            CALL trd_trc( tra(:,:,:,jn), jn, jptra_sms, kt )   ! save trends
216          END DO
217      END IF
218      !
219      IF( nn_timing == 1 )  CALL timing_stop('trc_sms_cfc')
220      !
221   END SUBROUTINE trc_sms_cfc
222
223
224   SUBROUTINE cfc_init
225      !!---------------------------------------------------------------------
226      !!                     ***  cfc_init  *** 
227      !!
228      !! ** Purpose : sets constants for CFC model
229      !!---------------------------------------------------------------------
230      INTEGER :: jn
231      !!----------------------------------------------------------------------
232      !
233      jn = 0 
234      ! coefficient for CFC11
235      !----------------------
236      if ( lp_cfc11 ) then
237         jn = jn + 1
238         ! Solubility
239         soa(1,jn) = -229.9261 
240         soa(2,jn) =  319.6552
241         soa(3,jn) =  119.4471
242         soa(4,jn) =  -1.39165
243
244         sob(1,jn) =  -0.142382
245         sob(2,jn) =   0.091459
246         sob(3,jn) =  -0.0157274
247
248         ! Schmidt number
249         sca(1,jn) = 3579.2
250         sca(2,jn) = -222.63
251         sca(3,jn) = 7.5749
252         sca(4,jn) = -0.14595
253         sca(5,jn) = 0.0011874
254
255         ! atm. concentration
256         atm_cfc(:,:,jn) = p_cfc(:,:,1)
257      endif
258
259      ! coefficient for CFC12
260      !----------------------
261      if ( lp_cfc12 ) then
262         jn = jn + 1
263         ! Solubility
264         soa(1,jn) = -218.0971
265         soa(2,jn) =  298.9702
266         soa(3,jn) =  113.8049
267         soa(4,jn) =  -1.39165
268
269         sob(1,jn) =  -0.143566
270         sob(2,jn) =   0.091015
271         sob(3,jn) =  -0.0153924
272
273         ! schmidt number
274         sca(1,jn) = 3828.1
275         sca(2,jn) = -249.86
276         sca(3,jn) = 8.7603
277         sca(4,jn) = -0.1716
278         sca(5,jn) = 0.001408
279
280         ! atm. concentration
281         atm_cfc(:,:,jn) = p_cfc(:,:,2)
282      endif
283
284      ! coefficient for SF6
285      !----------------------
286      if ( lp_sf6 ) then
287         jn = jn + 1
288         ! Solubility
289         soa(1,jn) = -80.0343
290         soa(2,jn) = 117.232
291         soa(3,jn) =  29.5817
292         soa(4,jn) =   0.0
293
294         sob(1,jn) =  0.0335183 
295         sob(2,jn) = -0.0373942 
296         sob(3,jn) =  0.00774862
297
298         ! schmidt number
299         sca(1,jn) = 3177.5
300         sca(2,jn) = -200.57
301         sca(3,jn) = 6.8865
302         sca(4,jn) = -0.13335
303         sca(5,jn) = 0.0010877
304 
305         ! atm. concentration
306         atm_cfc(:,:,jn) = p_cfc(:,:,3)
307       endif
308
309      IF( ln_rsttr ) THEN
310         IF(lwp) WRITE(numout,*)
311         IF(lwp) WRITE(numout,*) ' Read specific variables from CFC model '
312         IF(lwp) WRITE(numout,*) ' ~~~~~~~~~~~~~~'
313         !
314         DO jn = jp_cfc0, jp_cfc1
315            CALL iom_get( numrtr, jpdom_autoglo, 'qint_'//ctrcnm(jn), qint_cfc(:,:,jn) ) 
316         END DO
317      ENDIF
318      IF(lwp) WRITE(numout,*)
319      !
320   END SUBROUTINE cfc_init
321
322
323   INTEGER FUNCTION trc_sms_cfc_alloc()
324      !!----------------------------------------------------------------------
325      !!                     ***  ROUTINE trc_sms_cfc_alloc  ***
326      !!----------------------------------------------------------------------
327      ALLOCATE( xphem   (jpi,jpj)        , atm_cfc(jpyear,jphem,jp_cfc)  ,    &
328         &      qtr_cfc (jpi,jpj,jp_cfc) , qint_cfc(jpi,jpj,jp_cfc)      ,    &
329         &      soa(4,jp_cfc)    ,  sob(3,jp_cfc)   ,  sca(5,jp_cfc)     ,    &
330         &      STAT=trc_sms_cfc_alloc )
331         !
332      IF( trc_sms_cfc_alloc /= 0 ) CALL ctl_warn('trc_sms_cfc_alloc : failed to allocate arrays.')
333      !
334   END FUNCTION trc_sms_cfc_alloc
335
336#else
337   !!----------------------------------------------------------------------
338   !!   Dummy module                                         No CFC tracers
339   !!----------------------------------------------------------------------
340CONTAINS
341   SUBROUTINE trc_sms_cfc( kt )       ! Empty routine
342      WRITE(*,*) 'trc_sms_cfc: You should not have seen this print! error?', kt
343   END SUBROUTINE trc_sms_cfc
344#endif
345
346   !!======================================================================
347END MODULE trcsms_cfc
Note: See TracBrowser for help on using the repository browser.