source: branches/2016/dev_r6409_SIMPLIF_2_usrdef/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 7200

Last change on this file since 7200 was 7200, checked in by gm, 5 years ago

#1692 - branch SIMPLIF_2_usrdef: add depth_e3 module + management of ORCA family + domain_cfg filename (in&out) given in namelist

  • Property svn:keywords set to Id
File size: 41.3 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  LIM sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!            3.4  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE) add nemo_northcomms
31   !!             -   ! 2011-11  (C. Harris) decomposition changes for running with CICE
32   !!            3.6  ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
33   !!             -   ! 2013-06  (I. Epicoco, S. Mocavero, CMCC) nemo_northcomms: setup avoiding MPI communication
34   !!             -   ! 2014-12  (G. Madec) remove KPP scheme and cross-land advection (cla)
35   !!            4.0  ! 2016-10  (G. Madec, S. Flavoni)  domain configuration / user defined interface
36   !!----------------------------------------------------------------------
37
38   !!----------------------------------------------------------------------
39   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
40   !!   nemo_init     : initialization of the NEMO system
41   !!   nemo_ctl      : initialisation of the contol print
42   !!   nemo_closefile: close remaining open files
43   !!   nemo_alloc    : dynamical allocation
44   !!   nemo_partition: calculate MPP domain decomposition
45   !!   factorise     : calculate the factors of the no. of MPI processes
46   !!----------------------------------------------------------------------
47   USE step_oce       ! module used in the ocean time stepping module (step.F90)
48   USE phycst         ! physical constant                  (par_cst routine)
49   USE domain         ! domain initialization   (dom_init & dom_cfg routines)
50   USE usrdef_nam     ! user defined configuration
51   USE tideini        ! tidal components initialization   (tide_ini routine)
52   USE bdyini         ! open boundary cond. setting       (bdy_init routine)
53   USE bdydta         ! open boundary cond. setting   (bdy_dta_init routine)
54   USE bdytides       ! open boundary cond. setting   (bdytide_init routine)
55   USE sbctide, ONLY  : lk_tide
56   USE istate         ! initial state setting          (istate_init routine)
57   USE ldfdyn         ! lateral viscosity setting      (ldfdyn_init routine)
58   USE ldftra         ! lateral diffusivity setting    (ldftra_init routine)
59   USE zdfini         ! vertical physics setting          (zdf_init routine)
60   USE trdini         ! dyn/tra trends initialization     (trd_init routine)
61   USE asminc         ! assimilation increments     
62   USE asmbkg         ! writing out state trajectory
63   USE diaptr         ! poleward transports           (dia_ptr_init routine)
64   USE diadct         ! sections transports           (dia_dct_init routine)
65   USE diaobs         ! Observation diagnostics       (dia_obs_init routine)
66   USE diacfl         ! CFL diagnostics               (dia_cfl_init routine)
67   USE step           ! NEMO time-stepping                 (stp     routine)
68   USE icbini         ! handle bergs, initialisation
69   USE icbstp         ! handle bergs, calving, themodynamics and transport
70   USE cpl_oasis3     ! OASIS3 coupling
71   USE c1d            ! 1D configuration
72   USE step_c1d       ! Time stepping loop for the 1D configuration
73   USE dyndmp         ! Momentum damping
74   USE stopar         ! Stochastic param.: ???
75   USE stopts         ! Stochastic param.: ???
76   USE diurnal_bulk   ! diurnal bulk SST
77   USE step_diu       ! diurnal bulk SST timestepping (called from here if run offline)
78   USE crsini         ! initialise grid coarsening utility
79   USE diatmb         ! Top,middle,bottom output
80   USE dia25h         ! 25h mean output
81   USE sbc_oce , ONLY : lk_oasis
82   USE wet_dry        ! Wetting and drying setting   (wad_init routine)
83#if defined key_top
84   USE trcini         ! passive tracer initialisation
85#endif
86#if defined key_nemocice_decomp
87   USE ice_domain_size, only: nx_global, ny_global
88#endif
89   !
90   USE lib_mpp        ! distributed memory computing
91   USE mppini         ! shared/distributed memory setting (mpp_init routine)
92   USE lbcnfd , ONLY  : isendto, nsndto, nfsloop, nfeloop   ! Setup of north fold exchanges
93   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
94#if defined key_iomput
95   USE xios           ! xIOserver
96#endif
97
98   IMPLICIT NONE
99   PRIVATE
100
101   PUBLIC   nemo_gcm    ! called by model.F90
102   PUBLIC   nemo_init   ! needed by AGRIF
103   PUBLIC   nemo_alloc  ! needed by TAM
104
105   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
106
107   !!----------------------------------------------------------------------
108   !! NEMO/OPA 4.0 , NEMO Consortium (2016)
109   !! $Id$
110   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
111   !!----------------------------------------------------------------------
112CONTAINS
113
114   SUBROUTINE nemo_gcm
115      !!----------------------------------------------------------------------
116      !!                     ***  ROUTINE nemo_gcm  ***
117      !!
118      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
119      !!              curvilinear mesh on the sphere.
120      !!
121      !! ** Method  : - model general initialization
122      !!              - launch the time-stepping (stp routine)
123      !!              - finalize the run by closing files and communications
124      !!
125      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
126      !!              Madec, 2008, internal report, IPSL.
127      !!----------------------------------------------------------------------
128      INTEGER ::   istp   ! time step index
129      !!----------------------------------------------------------------------
130      !
131#if defined key_agrif
132      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
133#endif
134      !
135      !                            !-----------------------!
136      CALL nemo_init               !==  Initialisations  ==!
137      !                            !-----------------------!
138#if defined key_agrif
139      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
140      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
141# if defined key_top
142      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
143# endif
144# if defined key_lim2
145      CALL Agrif_Declare_Var_lim2  !  "      "   "   "      "  LIM
146# endif
147#endif
148      ! check that all process are still there... If some process have an error,
149      ! they will never enter in step and other processes will wait until the end of the cpu time!
150      IF( lk_mpp )   CALL mpp_max( nstop )
151
152      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
153
154      !                            !-----------------------!
155      !                            !==   time stepping   ==!
156      !                            !-----------------------!
157      istp = nit000
158#if defined key_c1d
159         DO WHILE ( istp <= nitend .AND. nstop == 0 )
160            CALL stp_c1d( istp )
161            istp = istp + 1
162         END DO
163#else
164          IF( lk_asminc ) THEN
165             IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 )    ! Output background fields
166             IF( ln_asmdin ) THEN                        ! Direct initialization
167                IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 )    ! Tracers
168                IF( ln_dyninc ) CALL dyn_asm_inc( nit000 - 1 )    ! Dynamics
169                IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 )    ! SSH
170             ENDIF
171          ENDIF
172
173#if defined key_agrif
174          CALL Agrif_Regrid()
175#endif
176
177         DO WHILE ( istp <= nitend .AND. nstop == 0 )
178#if defined key_agrif
179            CALL stp                         ! AGRIF: time stepping
180#else
181            IF ( .NOT. ln_diurnal_only ) THEN
182               CALL stp( istp )                 ! standard time stepping
183            ELSE
184               CALL stp_diurnal( istp )        ! time step only the diurnal SST
185            ENDIF 
186#endif
187            istp = istp + 1
188            IF( lk_mpp )   CALL mpp_max( nstop )
189         END DO
190#endif
191
192      IF( ln_diaobs   )   CALL dia_obs_wri
193      !
194      IF( ln_icebergs )   CALL icb_end( nitend )
195
196      !                            !------------------------!
197      !                            !==  finalize the run  ==!
198      !                            !------------------------!
199      IF(lwp) WRITE(numout,cform_aaa)        ! Flag AAAAAAA
200      !
201      IF( nstop /= 0 .AND. lwp ) THEN        ! error print
202         WRITE(numout,cform_err)
203         WRITE(numout,*) nstop, ' error have been found'
204      ENDIF
205      !
206#if defined key_agrif
207      IF( .NOT. Agrif_Root() ) THEN
208                         CALL Agrif_ParentGrid_To_ChildGrid()
209         IF( ln_diaobs ) CALL dia_obs_wri
210         IF( nn_timing == 1 )   CALL timing_finalize
211                                CALL Agrif_ChildGrid_To_ParentGrid()
212      ENDIF
213#endif
214      IF( nn_timing == 1 )   CALL timing_finalize
215      !
216      CALL nemo_closefile
217      !
218#if defined key_iomput
219      CALL xios_finalize                     ! end mpp communications with xios
220      IF( lk_oasis )   CALL cpl_finalize     ! end coupling and mpp communications with OASIS
221#else
222      IF( lk_oasis ) THEN
223         CALL cpl_finalize                   ! end coupling and mpp communications with OASIS
224      ELSE
225         IF( lk_mpp )   CALL mppstop         ! end mpp communications
226      ENDIF
227#endif
228      !
229   END SUBROUTINE nemo_gcm
230
231
232   SUBROUTINE nemo_init
233      !!----------------------------------------------------------------------
234      !!                     ***  ROUTINE nemo_init  ***
235      !!
236      !! ** Purpose :   initialization of the NEMO GCM
237      !!----------------------------------------------------------------------
238      INTEGER  ::   ji                 ! dummy loop indices
239      INTEGER  ::   ios, ilocal_comm   ! local integer
240      CHARACTER(len=120), DIMENSION(30) ::   cltxt, cltxt2, clnam
241      !
242      NAMELIST/namctl/ ln_ctl   , nn_print, nn_ictls, nn_ictle,   &
243         &             nn_isplt , nn_jsplt, nn_jctls, nn_jctle,   &
244         &             nn_timing, nn_diacfl
245      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_write_cfg, cn_domcfg_out, ln_use_jattr
246      !!----------------------------------------------------------------------
247      !
248      cltxt  = ''
249      cltxt2 = ''
250      clnam  = '' 
251      cxios_context = 'nemo'
252      !
253      !                             ! Open reference namelist and configuration namelist files
254      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
255      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
256      !
257      REWIND( numnam_ref )              ! Namelist namctl in reference namelist : Control prints
258      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
259901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
260      !
261      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist
262      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
263902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
264      !
265      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist : Control prints
266      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
267903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
268
269      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist : Control prints & Benchmark
270      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
271904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
272
273      !                             !--------------------------!
274      !                             !  Set global domain size  !   (control print return in cltxt2)
275      !                             !--------------------------!
276      IF( ln_read_cfg ) THEN              ! Read sizes in domain configuration file
277         CALL domain_cfg ( cltxt2, clnam, cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
278         !
279      ELSE                                ! user-defined namelist
280         CALL usr_def_nam( cltxt2, clnam, cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
281      ENDIF
282      !
283      jpk = jpkglo
284      !
285#if defined key_agrif
286      IF( .NOT. Agrif_Root() ) THEN       ! AGRIF children: specific setting (cf. agrif_user.F90)
287         jpiglo  = nbcellsx + 2 + 2*nbghostcells
288         jpjglo  = nbcellsy + 2 + 2*nbghostcells
289         jpi     = ( jpiglo-2*jpreci + (jpni-1+0) ) / jpni + 2*jpreci
290         jpj     = ( jpjglo-2*jprecj + (jpnj-1+0) ) / jpnj + 2*jprecj
291         nperio  = 0
292         jperio  = 0
293         ln_use_jattr = .false.
294      ENDIF
295#endif
296      !
297      !                             !--------------------------------------------!
298      !                             !  set communicator & select the local node  !
299      !                             !  NB: mynode also opens output.namelist.dyn !
300      !                             !      on unit number numond on first proc   !
301      !                             !--------------------------------------------!
302#if defined key_iomput
303      IF( Agrif_Root() ) THEN
304         IF( lk_oasis ) THEN
305            CALL cpl_init( "oceanx", ilocal_comm )                               ! nemo local communicator given by oasis
306            CALL xios_initialize( "not used"       ,local_comm= ilocal_comm )    ! send nemo communicator to xios
307         ELSE
308            CALL xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )    ! nemo local communicator given by xios
309         ENDIF
310      ENDIF
311      ! Nodes selection (control print return in cltxt)
312      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
313#else
314      IF( lk_oasis ) THEN
315         IF( Agrif_Root() ) THEN
316            CALL cpl_init( "oceanx", ilocal_comm )          ! nemo local communicator given by oasis
317         ENDIF
318         ! Nodes selection (control print return in cltxt)
319         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
320      ELSE
321         ilocal_comm = 0                                    ! Nodes selection (control print return in cltxt)
322         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )
323      ENDIF
324#endif
325
326      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
327
328      lwm = (narea == 1)                                    ! control of output namelists
329      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
330
331      IF(lwm) THEN               ! write merged namelists from earlier to output namelist
332         !                       ! now that the file has been opened in call to mynode.
333         !                       ! NB: nammpp has already been written in mynode (if lk_mpp_mpi)
334         WRITE( numond, namctl )
335         WRITE( numond, namcfg )
336         IF( .NOT.ln_read_cfg ) THEN
337            DO ji = 1, SIZE(clnam)
338               IF( TRIM(clnam(ji)) /= '' )   WRITE(numond, * ) clnam(ji)     ! namusr_def print
339            END DO
340         ENDIF
341      ENDIF
342
343      ! If dimensions of processor grid weren't specified in the namelist file
344      ! then we calculate them here now that we have our communicator size
345      IF( jpni < 1 .OR. jpnj < 1 ) THEN
346#if   defined key_mpp_mpi
347         IF( Agrif_Root() )   CALL nemo_partition( mppsize )
348#else
349         jpni  = 1
350         jpnj  = 1
351         jpnij = jpni*jpnj
352#endif
353      ENDIF
354
355      IF( Agrif_Root() ) THEN       ! AGRIF mother: specific setting from jpni and jpnj
356#if defined key_nemocice_decomp
357         jpi = ( nx_global+2-2*jpreci + (jpni-1) ) / jpni + 2*jpreci    ! first  dim.
358         jpj = ( ny_global+2-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj    ! second dim.
359#else
360         jpi = ( jpiglo     -2*jpreci + (jpni-1) ) / jpni + 2*jpreci    ! first  dim.
361         jpj = ( jpjglo     -2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj    ! second dim.
362#endif
363      ENDIF
364
365!!gm ???    why here  it has already been done in line 301 !
366      jpk = jpkglo                                             ! third dim
367!!gm end
368
369#if defined key_agrif
370      ! simple trick to use same vertical grid as parent but different number of levels:
371      ! Save maximum number of levels in jpkglo, then define all vertical grids with this number.
372      ! Suppress once vertical online interpolation is ok
373      IF(.NOT.Agrif_Root())   jpkglo = Agrif_Parent( jpkglo )
374#endif
375      jpim1 = jpi-1                                            ! inner domain indices
376      jpjm1 = jpj-1                                            !   "           "
377      jpkm1 = jpk-1                                            !   "           "
378      jpij  = jpi*jpj                                          !  jpi x j
379
380      IF(lwp) THEN                            ! open listing units
381         !
382         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
383         !
384         WRITE(numout,*)
385         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
386         WRITE(numout,*) '                       NEMO team'
387         WRITE(numout,*) '            Ocean General Circulation Model'
388         WRITE(numout,*) '                NEMO version 3.7  (2016) '
389         WRITE(numout,*)
390         WRITE(numout,*)
391         DO ji = 1, SIZE(cltxt)
392            IF( TRIM(cltxt (ji)) /= '' )   WRITE(numout,*) cltxt(ji)    ! control print of mynode
393         END DO
394         WRITE(numout,*)
395         WRITE(numout,*)
396         DO ji = 1, SIZE(cltxt2)
397            IF( TRIM(cltxt2(ji)) /= '' )   WRITE(numout,*) cltxt2(ji)   ! control print of domain size
398         END DO
399         !
400         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
401         !
402      ENDIF
403
404      ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
405      CALL nemo_alloc()
406
407      !                             !-------------------------------!
408      !                             !  NEMO general initialization  !
409      !                             !-------------------------------!
410
411      CALL nemo_ctl                          ! Control prints
412
413      !                                      ! Domain decomposition
414      IF( jpni*jpnj == jpnij ) THEN   ;   CALL mpp_init      ! standard cutting out
415      ELSE                            ;   CALL mpp_init2     ! eliminate land processors
416      ENDIF
417      !
418      IF( nn_timing == 1 )  CALL timing_init
419      !
420      !                                      ! General initialization
421                            CALL     phy_cst    ! Physical constants
422                            CALL     eos_init   ! Equation of state
423      IF( lk_c1d        )   CALL     c1d_init   ! 1D column configuration
424                            CALL     wad_init   ! Wetting and drying options
425                            CALL     dom_init   ! Domain
426      IF( ln_crs        )   CALL     crs_init   ! coarsened grid: domain initialization
427      IF( ln_nnogather )    CALL nemo_northcomms! northfold neighbour lists (must be done after the masks are defined)
428      IF( ln_ctl        )   CALL prt_ctl_init   ! Print control
429     
430      CALL diurnal_sst_bulk_init            ! diurnal sst
431      IF ( ln_diurnal ) CALL diurnal_sst_coolskin_init   ! cool skin   
432     
433      ! IF ln_diurnal_only, then we only want a subset of the initialisation routines
434      IF ( ln_diurnal_only ) THEN
435         CALL  istate_init   ! ocean initial state (Dynamics and tracers)
436         CALL     sbc_init   ! Forcings : surface module
437         CALL tra_qsr_init   ! penetrative solar radiation qsr
438         IF( ln_diaobs     ) THEN                  ! Observation & model comparison
439            CALL dia_obs_init            ! Initialize observational data
440            CALL dia_obs( nit000 - 1 )   ! Observation operator for restart
441         ENDIF     
442         !                                     ! Assimilation increments
443         IF( lk_asminc     )   CALL asm_inc_init   ! Initialize assimilation increments
444                 
445         IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
446         RETURN
447      ENDIF
448     
449                            CALL  istate_init   ! ocean initial state (Dynamics and tracers)
450
451      !                                      ! external forcing
452!!gm to be added : creation and call of sbc_apr_init
453      IF( lk_tide       )   CALL    tide_init   ! tidal harmonics
454                            CALL     sbc_init   ! surface boundary conditions (including sea-ice)
455!!gm ==>> bdy_init should call bdy_dta_init and bdytide_init  NOT in nemogcm !!!
456      IF( lk_bdy        )   CALL     bdy_init   ! Open boundaries initialisation
457      IF( lk_bdy        )   CALL bdy_dta_init   ! Open boundaries initialisation of external data arrays
458      IF( lk_bdy .AND. lk_tide )   &
459         &                  CALL bdytide_init   ! Open boundaries initialisation of tidal harmonic forcing
460         
461      !                                      ! Ocean physics
462      !                                         ! Vertical physics
463                            CALL     zdf_init      ! namelist read
464                            CALL zdf_bfr_init      ! bottom friction
465      IF( lk_zdfric     )   CALL zdf_ric_init      ! Richardson number dependent Kz
466      IF( lk_zdftke     )   CALL zdf_tke_init      ! TKE closure scheme
467      IF( lk_zdfgls     )   CALL zdf_gls_init      ! GLS closure scheme
468      IF( lk_zdftmx     )   CALL zdf_tmx_init      ! tidal vertical mixing
469      IF( lk_zdfddm     )   CALL zdf_ddm_init      ! double diffusive mixing
470         
471      !                                         ! Lateral physics
472                            CALL ldf_tra_init      ! Lateral ocean tracer physics
473                            CALL ldf_eiv_init      ! eddy induced velocity param.
474                            CALL ldf_dyn_init      ! Lateral ocean momentum physics
475
476      !                                         ! Active tracers
477                            CALL tra_qsr_init      ! penetrative solar radiation qsr
478                            CALL tra_bbc_init      ! bottom heat flux
479      IF( lk_trabbl     )   CALL tra_bbl_init      ! advective (and/or diffusive) bottom boundary layer scheme
480                            CALL tra_dmp_init      ! internal tracer damping
481                            CALL tra_adv_init      ! horizontal & vertical advection
482                            CALL tra_ldf_init      ! lateral mixing
483                            CALL tra_zdf_init      ! vertical mixing and after tracer fields
484
485      !                                         ! Dynamics
486      IF( lk_c1d        )   CALL dyn_dmp_init      ! internal momentum damping
487                            CALL dyn_adv_init      ! advection (vector or flux form)
488                            CALL dyn_vor_init      ! vorticity term including Coriolis
489                            CALL dyn_ldf_init      ! lateral mixing
490                            CALL dyn_hpg_init      ! horizontal gradient of Hydrostatic pressure
491                            CALL dyn_zdf_init      ! vertical diffusion
492                            CALL dyn_spg_init      ! surface pressure gradient
493
494#if defined key_top
495      !                                      ! Passive tracers
496                            CALL     trc_init
497#endif
498      IF( l_ldfslp      )   CALL ldf_slp_init   ! slope of lateral mixing
499
500      !                                      ! Icebergs
501                            CALL icb_init( rdt, nit000)   ! initialise icebergs instance
502
503      !                                      ! Misc. options
504                            CALL sto_par_init   ! Stochastic parametrization
505      IF( ln_sto_eos     )  CALL sto_pts_init   ! RRandom T/S fluctuations
506     
507      !                                      ! Diagnostics
508      IF( lk_floats     )   CALL     flo_init   ! drifting Floats
509                            CALL dia_cfl_init   ! Initialise CFL diagnostics
510      IF( lk_diaar5     )   CALL dia_ar5_init   ! ar5 diag
511                            CALL dia_ptr_init   ! Poleward TRansports initialization
512      IF( lk_diadct     )   CALL dia_dct_init   ! Sections tranports
513                            CALL dia_hsb_init   ! heat content, salt content and volume budgets
514                            CALL     trd_init   ! Mixed-layer/Vorticity/Integral constraints trends
515                            CALL dia_obs_init            ! Initialize observational data
516      IF( ln_diaobs     )   CALL dia_obs( nit000 - 1 )   ! Observation operator for restart
517
518      !                                         ! Assimilation increments
519      IF( lk_asminc     )   CALL asm_inc_init   ! Initialize assimilation increments
520      IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
521                            CALL dia_tmb_init  ! TMB outputs
522                            CALL dia_25h_init  ! 25h mean  outputs
523      !
524   END SUBROUTINE nemo_init
525
526
527   SUBROUTINE nemo_ctl
528      !!----------------------------------------------------------------------
529      !!                     ***  ROUTINE nemo_ctl  ***
530      !!
531      !! ** Purpose :   control print setting
532      !!
533      !! ** Method  : - print namctl information and check some consistencies
534      !!----------------------------------------------------------------------
535      !
536      IF(lwp) THEN                  ! control print
537         WRITE(numout,*)
538         WRITE(numout,*) 'nemo_ctl: Control prints'
539         WRITE(numout,*) '~~~~~~~ '
540         WRITE(numout,*) '   Namelist namctl'
541         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
542         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
543         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
544         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
545         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
546         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
547         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
548         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
549         WRITE(numout,*) '      timing activated    (0/1)       nn_timing  = ', nn_timing
550      ENDIF
551      !
552      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
553      nictls    = nn_ictls
554      nictle    = nn_ictle
555      njctls    = nn_jctls
556      njctle    = nn_jctle
557      isplt     = nn_isplt
558      jsplt     = nn_jsplt
559
560      IF(lwp) THEN                  ! control print
561         WRITE(numout,*)
562         WRITE(numout,*) 'namcfg  : configuration initialization through namelist read'
563         WRITE(numout,*) '~~~~~~~ '
564         WRITE(numout,*) '   Namelist namcfg'
565         WRITE(numout,*) '      read domain configuration file                ln_read_cfg      = ', ln_read_cfg
566         WRITE(numout,*) '         filename to be read                           cn_domcfg     = ', TRIM(cn_domcfg)
567         WRITE(numout,*) '      write configuration definition file           ln_write_cfg     = ', ln_write_cfg
568         WRITE(numout,*) '         filename to be written                        cn_domcfg_out = ', TRIM(cn_domcfg_out)
569         WRITE(numout,*) '      use file attribute if exists as i/p j-start   ln_use_jattr     = ', ln_use_jattr
570      ENDIF
571      !                             ! Parameter control
572      !
573      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
574         IF( lk_mpp .AND. jpnij > 1 ) THEN
575            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
576         ELSE
577            IF( isplt == 1 .AND. jsplt == 1  ) THEN
578               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
579                  &           ' - the print control will be done over the whole domain' )
580            ENDIF
581            ijsplt = isplt * jsplt            ! total number of processors ijsplt
582         ENDIF
583         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
584         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
585         !
586         !                              ! indices used for the SUM control
587         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
588            lsp_area = .FALSE.
589         ELSE                                             ! print control done over a specific  area
590            lsp_area = .TRUE.
591            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
592               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
593               nictls = 1
594            ENDIF
595            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
596               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
597               nictle = jpiglo
598            ENDIF
599            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
600               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
601               njctls = 1
602            ENDIF
603            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
604               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
605               njctle = jpjglo
606            ENDIF
607         ENDIF
608      ENDIF
609      !
610      IF( 1_wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ',  &
611         &                                               'f2003 standard. '                              ,  &
612         &                                               'Compile with key_nosignedzero enabled' )
613      !
614   END SUBROUTINE nemo_ctl
615
616
617   SUBROUTINE nemo_closefile
618      !!----------------------------------------------------------------------
619      !!                     ***  ROUTINE nemo_closefile  ***
620      !!
621      !! ** Purpose :   Close the files
622      !!----------------------------------------------------------------------
623      !
624      IF( lk_mpp )   CALL mppsync
625      !
626      CALL iom_close                                 ! close all input/output files managed by iom_*
627      !
628      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
629      IF( numsol          /= -1 )   CLOSE( numsol          )   ! solver file
630      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
631      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
632      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
633      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
634      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
635      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
636      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
637      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
638      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
639      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
640      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
641      !
642      numout = 6                                     ! redefine numout in case it is used after this point...
643      !
644   END SUBROUTINE nemo_closefile
645
646
647   SUBROUTINE nemo_alloc
648      !!----------------------------------------------------------------------
649      !!                     ***  ROUTINE nemo_alloc  ***
650      !!
651      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
652      !!
653      !! ** Method  :
654      !!----------------------------------------------------------------------
655      USE diawri    , ONLY: dia_wri_alloc
656      USE dom_oce   , ONLY: dom_oce_alloc
657      USE trc_oce   , ONLY: trc_oce_alloc
658#if defined key_diadct 
659      USE diadct    , ONLY: diadct_alloc 
660#endif 
661#if defined key_bdy
662      USE bdy_oce   , ONLY: bdy_oce_alloc
663#endif
664      !
665      INTEGER :: ierr
666      !!----------------------------------------------------------------------
667      !
668      ierr =        oce_alloc       ()          ! ocean
669      ierr = ierr + dia_wri_alloc   ()
670      ierr = ierr + dom_oce_alloc   ()          ! ocean domain
671      ierr = ierr + zdf_oce_alloc   ()          ! ocean vertical physics
672      !
673      ierr = ierr + trc_oce_alloc   ()          ! shared TRC / TRA arrays
674      !
675#if defined key_diadct 
676      ierr = ierr + diadct_alloc    ()          !
677#endif 
678#if defined key_bdy
679      ierr = ierr + bdy_oce_alloc   ()          ! bdy masks (incl. initialization)
680#endif
681      !
682      IF( lk_mpp    )   CALL mpp_sum( ierr )
683      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
684      !
685   END SUBROUTINE nemo_alloc
686
687
688   SUBROUTINE nemo_partition( num_pes )
689      !!----------------------------------------------------------------------
690      !!                 ***  ROUTINE nemo_partition  ***
691      !!
692      !! ** Purpose :
693      !!
694      !! ** Method  :
695      !!----------------------------------------------------------------------
696      INTEGER, INTENT(in) ::   num_pes   ! The number of MPI processes we have
697      !
698      INTEGER, PARAMETER :: nfactmax = 20
699      INTEGER :: nfact ! The no. of factors returned
700      INTEGER :: ierr  ! Error flag
701      INTEGER :: ji
702      INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
703      INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
704      !!----------------------------------------------------------------------
705      !
706      ierr = 0
707      !
708      CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
709      !
710      IF( nfact <= 1 ) THEN
711         WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
712         WRITE (numout, *) '       : using grid of ',num_pes,' x 1'
713         jpnj = 1
714         jpni = num_pes
715      ELSE
716         ! Search through factors for the pair that are closest in value
717         mindiff = 1000000
718         imin    = 1
719         DO ji = 1, nfact-1, 2
720            idiff = ABS( ifact(ji) - ifact(ji+1) )
721            IF( idiff < mindiff ) THEN
722               mindiff = idiff
723               imin = ji
724            ENDIF
725         END DO
726         jpnj = ifact(imin)
727         jpni = ifact(imin + 1)
728      ENDIF
729      !
730      jpnij = jpni*jpnj
731      !
732   END SUBROUTINE nemo_partition
733
734
735   SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
736      !!----------------------------------------------------------------------
737      !!                     ***  ROUTINE factorise  ***
738      !!
739      !! ** Purpose :   return the prime factors of n.
740      !!                knfax factors are returned in array kfax which is of
741      !!                maximum dimension kmaxfax.
742      !! ** Method  :
743      !!----------------------------------------------------------------------
744      INTEGER                    , INTENT(in   ) ::   kn, kmaxfax
745      INTEGER                    , INTENT(  out) ::   kerr, knfax
746      INTEGER, DIMENSION(kmaxfax), INTENT(  out) ::   kfax
747      !
748      INTEGER :: ifac, jl, inu
749      INTEGER, PARAMETER :: ntest = 14
750      INTEGER, DIMENSION(ntest) ::   ilfax
751      !!----------------------------------------------------------------------
752      !
753      ! lfax contains the set of allowed factors.
754      ilfax(:) = (/(2**jl,jl=ntest,1,-1)/)
755      !
756      ! Clear the error flag and initialise output vars
757      kerr  = 0
758      kfax  = 1
759      knfax = 0
760      !
761      ! Find the factors of n.
762      IF( kn == 1 )   GOTO 20
763
764      ! nu holds the unfactorised part of the number.
765      ! knfax holds the number of factors found.
766      ! l points to the allowed factor list.
767      ! ifac holds the current factor.
768      !
769      inu   = kn
770      knfax = 0
771      !
772      DO jl = ntest, 1, -1
773         !
774         ifac = ilfax(jl)
775         IF( ifac > inu )   CYCLE
776
777         ! Test whether the factor will divide.
778
779         IF( MOD(inu,ifac) == 0 ) THEN
780            !
781            knfax = knfax + 1            ! Add the factor to the list
782            IF( knfax > kmaxfax ) THEN
783               kerr = 6
784               write (*,*) 'FACTOR: insufficient space in factor array ', knfax
785               return
786            ENDIF
787            kfax(knfax) = ifac
788            ! Store the other factor that goes with this one
789            knfax = knfax + 1
790            kfax(knfax) = inu / ifac
791            !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
792         ENDIF
793         !
794      END DO
795      !
796   20 CONTINUE      ! Label 20 is the exit point from the factor search loop.
797      !
798   END SUBROUTINE factorise
799
800#if defined key_mpp_mpi
801
802   SUBROUTINE nemo_northcomms
803      !!----------------------------------------------------------------------
804      !!                     ***  ROUTINE  nemo_northcomms  ***
805      !! ** Purpose :   Setup for north fold exchanges with explicit
806      !!                point-to-point messaging
807      !!
808      !! ** Method :   Initialization of the northern neighbours lists.
809      !!----------------------------------------------------------------------
810      !!    1.0  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE)
811      !!    2.0  ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S. Mocavero, CMCC)
812      !!----------------------------------------------------------------------
813      INTEGER  ::   sxM, dxM, sxT, dxT, jn
814      INTEGER  ::   njmppmax
815      !!----------------------------------------------------------------------
816      !
817      njmppmax = MAXVAL( njmppt )
818      !
819      !initializes the north-fold communication variables
820      isendto(:) = 0
821      nsndto     = 0
822      !
823      !if I am a process in the north
824      IF ( njmpp == njmppmax ) THEN
825          !sxM is the first point (in the global domain) needed to compute the
826          !north-fold for the current process
827          sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
828          !dxM is the last point (in the global domain) needed to compute the
829          !north-fold for the current process
830          dxM = jpiglo - nimppt(narea) + 2
831
832          !loop over the other north-fold processes to find the processes
833          !managing the points belonging to the sxT-dxT range
834 
835          DO jn = 1, jpni
836                !sxT is the first point (in the global domain) of the jn
837                !process
838                sxT = nfiimpp(jn, jpnj)
839                !dxT is the last point (in the global domain) of the jn
840                !process
841                dxT = nfiimpp(jn, jpnj) + nfilcit(jn, jpnj) - 1
842                IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
843                   nsndto = nsndto + 1
844                   isendto(nsndto) = jn
845                ELSEIF ((sxM .le. sxT) .AND. (dxM .ge. dxT)) THEN
846                   nsndto = nsndto + 1
847                   isendto(nsndto) = jn
848                ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
849                   nsndto = nsndto + 1
850                   isendto(nsndto) = jn
851                ENDIF
852          END DO
853          nfsloop = 1
854          nfeloop = nlci
855          DO jn = 2,jpni-1
856           IF(nfipproc(jn,jpnj) .eq. (narea - 1)) THEN
857              IF (nfipproc(jn - 1 ,jpnj) .eq. -1) THEN
858                 nfsloop = nldi
859              ENDIF
860              IF (nfipproc(jn + 1,jpnj) .eq. -1) THEN
861                 nfeloop = nlei
862              ENDIF
863           ENDIF
864        END DO
865
866      ENDIF
867      l_north_nogather = .TRUE.
868   END SUBROUTINE nemo_northcomms
869
870#else
871   SUBROUTINE nemo_northcomms      ! Dummy routine
872      WRITE(*,*) 'nemo_northcomms: You should not have seen this print! error?'
873   END SUBROUTINE nemo_northcomms
874#endif
875
876   !!======================================================================
877END MODULE nemogcm
878
Note: See TracBrowser for help on using the repository browser.