New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zmeso.F90 in branches/2016/dev_r7012_ROBUST5_CNRS/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/2016/dev_r7012_ROBUST5_CNRS/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zmeso.F90 @ 7068

Last change on this file since 7068 was 7068, checked in by cetlod, 8 years ago

ROBUST5_CNRS : implementation of part I of new TOP interface - 1st step -, see ticket #1782
File size: 16.9 KB
Line 
1MODULE p4zmeso
2   !!======================================================================
3   !!                         ***  MODULE p4zmeso  ***
4   !! TOP :   PISCES Compute the sources/sinks for mesozooplankton
5   !!======================================================================
6   !! History :   1.0  !  2002     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!----------------------------------------------------------------------
10   !!   p4z_meso       :   Compute the sources/sinks for mesozooplankton
11   !!   p4z_meso_init  :   Initialization of the parameters for mesozooplankton
12   !!----------------------------------------------------------------------
13   USE oce_trc         !  shared variables between ocean and passive tracers
14   USE trc             !  passive tracers common variables
15   USE sms_pisces      !  PISCES Source Minus Sink variables
16   USE p4zsink         !  vertical flux of particulate matter due to sinking
17   USE p4zint          !  interpolation and computation of various fields
18   USE p4zprod         !  production
19   USE prtctl_trc      !  print control for debugging
20   USE iom             !  I/O manager
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC   p4z_meso              ! called in p4zbio.F90
26   PUBLIC   p4z_meso_init         ! called in trcsms_pisces.F90
27
28   !! * Shared module variables
29   REAL(wp), PUBLIC ::  part2        !: part of calcite not dissolved in mesozoo guts
30   REAL(wp), PUBLIC ::  xprefc       !: mesozoo preference for POC
31   REAL(wp), PUBLIC ::  xprefp       !: mesozoo preference for nanophyto
32   REAL(wp), PUBLIC ::  xprefz       !: mesozoo preference for diatoms
33   REAL(wp), PUBLIC ::  xprefpoc     !: mesozoo preference for POC
34   REAL(wp), PUBLIC ::  xthresh2zoo  !: zoo feeding threshold for mesozooplankton
35   REAL(wp), PUBLIC ::  xthresh2dia  !: diatoms feeding threshold for mesozooplankton
36   REAL(wp), PUBLIC ::  xthresh2phy  !: nanophyto feeding threshold for mesozooplankton
37   REAL(wp), PUBLIC ::  xthresh2poc  !: poc feeding threshold for mesozooplankton
38   REAL(wp), PUBLIC ::  xthresh2     !: feeding threshold for mesozooplankton
39   REAL(wp), PUBLIC ::  resrat2      !: exsudation rate of mesozooplankton
40   REAL(wp), PUBLIC ::  mzrat2       !: microzooplankton mortality rate
41   REAL(wp), PUBLIC ::  grazrat2     !: maximal mesozoo grazing rate
42   REAL(wp), PUBLIC ::  xkgraz2      !: non assimilated fraction of P by mesozoo
43   REAL(wp), PUBLIC ::  unass2       !: Efficicency of mesozoo growth
44   REAL(wp), PUBLIC ::  sigma2       !: Fraction of mesozoo excretion as DOM
45   REAL(wp), PUBLIC ::  epsher2      !: half sturation constant for grazing 2
46   REAL(wp), PUBLIC ::  grazflux     !: mesozoo flux feeding rate
47
48   !!----------------------------------------------------------------------
49   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
50   !! $Id: p4zmeso.F90 3160 2011-11-20 14:27:18Z cetlod $
51   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
52   !!----------------------------------------------------------------------
53
54CONTAINS
55
56   SUBROUTINE p4z_meso( kt, knt )
57      !!---------------------------------------------------------------------
58      !!                     ***  ROUTINE p4z_meso  ***
59      !!
60      !! ** Purpose :   Compute the sources/sinks for mesozooplankton
61      !!
62      !! ** Method  : - ???
63      !!---------------------------------------------------------------------
64      INTEGER, INTENT(in) ::   kt, knt ! ocean time step
65      INTEGER  :: ji, jj, jk
66      REAL(wp) :: zcompadi, zcompaph, zcompapoc, zcompaz, zcompam
67      REAL(wp) :: zgraze2 , zdenom, zdenom2
68      REAL(wp) :: zfact   , zfood, zfoodlim, zproport
69      REAL(wp) :: zmortzgoc, zfrac, zfracfe, zratio, zratio2
70      REAL(wp) :: zepshert, zepsherv, zgrarsig, zgraztot, zgraztotn, zgraztotf
71      REAL(wp) :: zgrarem2, zgrafer2, zgrapoc2, zprcaca, zmortz2, zgrasrat, zgrasratn
72      REAL(wp) :: zrespz2, ztortz2, zgrazd, zgrazz, zgrazpof
73      REAL(wp) :: zgrazn, zgrazpoc, zgraznf, zgrazf
74      REAL(wp) :: zgrazfffp, zgrazfffg, zgrazffep, zgrazffeg
75      CHARACTER (len=25) :: charout
76      REAL(wp), POINTER, DIMENSION(:,:,:) :: zgrazing, zw3d
77
78      !!---------------------------------------------------------------------
79      !
80      IF( nn_timing == 1 )  CALL timing_start('p4z_meso')
81      !
82      IF( lk_iomput ) THEN
83         CALL wrk_alloc( jpi, jpj, jpk, zgrazing )
84         zgrazing(:,:,:) = 0._wp
85      ENDIF
86
87      DO jk = 1, jpkm1
88         DO jj = 1, jpj
89            DO ji = 1, jpi
90               zcompam   = MAX( ( trb(ji,jj,jk,jpmes) - 1.e-9 ), 0.e0 )
91               zfact     = xstep * tgfunc2(ji,jj,jk) * zcompam
92
93               !  Respiration rates of both zooplankton
94               !  -------------------------------------
95               zrespz2   = resrat2 * zfact * trb(ji,jj,jk,jpmes) / ( xkmort + trb(ji,jj,jk,jpmes) )  &
96                  &      + resrat2 * zfact * 3. * nitrfac(ji,jj,jk)
97
98               !  Zooplankton mortality. A square function has been selected with
99               !  no real reason except that it seems to be more stable and may mimic predation
100               !  ---------------------------------------------------------------
101               ztortz2   = mzrat2 * 1.e6 * zfact * trb(ji,jj,jk,jpmes)
102               !
103               zcompadi  = MAX( ( trb(ji,jj,jk,jpdia) - xthresh2dia ), 0.e0 )
104               zcompaz   = MAX( ( trb(ji,jj,jk,jpzoo) - xthresh2zoo ), 0.e0 )
105               ! Size effect of nanophytoplankton on grazing : the smaller it is, the less prone
106               ! it is to predation by mesozooplankton
107               ! -------------------------------------------------------------------------------
108               zcompaph  = MAX( ( trb(ji,jj,jk,jpphy) - xthresh2phy ), 0.e0 ) &
109                  &      * MIN(1., MAX( 0., ( quotan(ji,jj,jk) - 0.2) / 0.3 ) )
110               zcompapoc = MAX( ( trb(ji,jj,jk,jppoc) - xthresh2poc ), 0.e0 )
111
112               zfood     = xprefc * zcompadi + xprefz * zcompaz + xprefp * zcompaph + xprefpoc * zcompapoc 
113               zfoodlim  = MAX( 0., zfood - MIN( 0.5 * zfood, xthresh2 ) )
114               zdenom    = zfoodlim / ( xkgraz2 + zfoodlim )
115               zdenom2   = zdenom / ( zfood + rtrn )
116               zgraze2   = grazrat2 * xstep * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jpmes) 
117
118               zgrazd    = zgraze2  * xprefc   * zcompadi  * zdenom2 
119               zgrazz    = zgraze2  * xprefz   * zcompaz   * zdenom2 
120               zgrazn    = zgraze2  * xprefp   * zcompaph  * zdenom2 
121               zgrazpoc  = zgraze2  * xprefpoc * zcompapoc * zdenom2 
122
123               zgraznf   = zgrazn   * trb(ji,jj,jk,jpnfe) / ( trb(ji,jj,jk,jpphy) + rtrn)
124               zgrazf    = zgrazd   * trb(ji,jj,jk,jpdfe) / ( trb(ji,jj,jk,jpdia) + rtrn)
125               zgrazpof  = zgrazpoc * trb(ji,jj,jk,jpsfe) / ( trb(ji,jj,jk,jppoc) + rtrn)
126
127               !  Mesozooplankton flux feeding on GOC
128               !  ----------------------------------
129               !  ----------------------------------
130               zgrazffeg = grazflux  * xstep * wsbio4(ji,jj,jk)      &
131               &           * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jpgoc) * trb(ji,jj,jk,jpmes)
132               zgrazfffg = zgrazffeg * trb(ji,jj,jk,jpbfe) / (trb(ji,jj,jk,jpgoc) + rtrn)
133               zgrazffep = grazflux  * xstep *  wsbio3(ji,jj,jk)     &
134               &           * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jppoc) * trb(ji,jj,jk,jpmes)
135               zgrazfffp = zgrazffep * trb(ji,jj,jk,jpsfe) / (trb(ji,jj,jk,jppoc) + rtrn)
136              !
137              zgraztot  = zgrazd + zgrazz + zgrazn + zgrazpoc + zgrazffep + zgrazffeg
138              ! Compute the proportion of filter feeders
139              zproport  = (zgrazffep + zgrazffeg)/(rtrn + zgraztot)
140              ! Compute fractionation of aggregates. It is assumed that
141              ! diatoms based aggregates are more prone to fractionation
142              ! since they are more porous (marine snow instead of fecal pellets)
143              zratio    = trb(ji,jj,jk,jpgsi) / ( trb(ji,jj,jk,jpgoc) + rtrn )
144              zratio2   = zratio * zratio
145              zfrac     = zproport * grazflux  * xstep * wsbio4(ji,jj,jk)      &
146               &          * trb(ji,jj,jk,jpgoc) * trb(ji,jj,jk,jpmes)          &
147               &          * ( 0.2 + 3.8 * zratio2 / ( 1.**2 + zratio2 ) )
148              zfracfe   = zfrac * trb(ji,jj,jk,jpbfe) / (trb(ji,jj,jk,jpgoc) + rtrn)
149
150              zgrazffep = zproport * zgrazffep
151              zgrazffeg = zproport * zgrazffeg
152              zgrazfffp = zproport * zgrazfffp
153              zgrazfffg = zproport * zgrazfffg
154              zgraztot  = zgrazd + zgrazz + zgrazn + zgrazpoc + zgrazffep + zgrazffeg
155              zgraztotn = zgrazd * quotad(ji,jj,jk) + zgrazz + zgrazn * quotan(ji,jj,jk)   &
156              &   + zgrazpoc + zgrazffep + zgrazffeg
157              zgraztotf = zgrazf + zgraznf + zgrazz * ferat3 + zgrazpof + zgrazfffp + zgrazfffg
158
159              ! Total grazing ( grazing by microzoo is already computed in p4zmicro )
160              IF( lk_iomput )  zgrazing(ji,jj,jk) = zgraztot
161
162              !    Mesozooplankton efficiency
163              !    --------------------------
164               zgrasrat  =  ( zgraztotf +rtrn )/ ( zgraztot + rtrn )
165               zgrasratn =  ( zgraztotn +rtrn )/ ( zgraztot + rtrn )
166               zepshert  = MIN( 1., zgrasratn, zgrasrat / ferat3)
167               zepsherv  = zepshert * MIN( epsher2, (1. - unass2) * zgrasrat / ferat3, (1. - unass2) * zgrasratn )
168               zgrarem2  = zgraztot * ( 1. - zepsherv - unass2 ) &
169                &       + ( 1. - epsher2 - unass2 ) / ( 1. - epsher2 ) * ztortz2
170               zgrafer2  = zgraztot * MAX( 0. , ( 1. - unass2 ) * zgrasrat - ferat3 * zepsherv )    &
171                &       + ferat3 * ( ( 1. - epsher2 - unass2 ) /( 1. - epsher2 ) * ztortz2 )
172               zgrapoc2  = zgraztot * unass2
173
174               !   Update the arrays TRA which contain the biological sources and sinks
175               zgrarsig  = zgrarem2 * sigma2
176               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zgrarsig
177               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zgrarsig
178               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zgrarem2 - zgrarsig
179               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2ut * zgrarsig
180               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zgrafer2
181               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrarsig
182               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * zgrarsig             
183
184               zmortz2 = ztortz2 + zrespz2
185               zmortzgoc = unass2 / ( 1. - epsher2 ) * ztortz2 + zrespz2
186               tra(ji,jj,jk,jpmes) = tra(ji,jj,jk,jpmes) - zmortz2 + zepsherv * zgraztot 
187               tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zgrazd
188               tra(ji,jj,jk,jpzoo) = tra(ji,jj,jk,jpzoo) - zgrazz
189               tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zgrazn
190               tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zgrazn * trb(ji,jj,jk,jpnch) / ( trb(ji,jj,jk,jpphy) + rtrn )
191               tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zgrazd * trb(ji,jj,jk,jpdch) / ( trb(ji,jj,jk,jpdia) + rtrn )
192               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) - zgrazd * trb(ji,jj,jk,jpdsi) / ( trb(ji,jj,jk,jpdia) + rtrn )
193               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) + zgrazd * trb(ji,jj,jk,jpdsi) / ( trb(ji,jj,jk,jpdia) + rtrn )
194               tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zgraznf
195               tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zgrazf
196
197               ! calcite production
198               zprcaca = xfracal(ji,jj,jk) * zgrazn
199               prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
200               !
201               zprcaca = part2 * zprcaca
202               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprcaca
203               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2. * zprcaca
204               tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) + zprcaca
205               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) - zgrazpoc - zgrazffep + zfrac
206               tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zmortzgoc - zgrazffeg + zgrapoc2 - zfrac
207               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) - zgrazpof - zgrazfffp + zfracfe
208               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + ferat3 * zmortzgoc - zgrazfffg     &
209                   &                + zgraztotf * unass2 - zfracfe
210            END DO
211         END DO
212      END DO
213      !
214      IF( lk_iomput .AND. knt == nrdttrc ) THEN
215         CALL wrk_alloc( jpi, jpj, jpk, zw3d )
216         IF( iom_use( "GRAZ2" ) ) THEN
217            zw3d(:,:,:) = zgrazing(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:)  !   Total grazing of phyto by zooplankton
218            CALL iom_put( "GRAZ2", zw3d )
219         ENDIF
220         IF( iom_use( "PCAL" ) ) THEN
221            zw3d(:,:,:) = prodcal(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:)   !  Calcite production
222            CALL iom_put( "PCAL", zw3d ) 
223         ENDIF
224         CALL wrk_dealloc( jpi, jpj, jpk, zw3d )
225      ENDIF
226      !
227      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
228        WRITE(charout, FMT="('meso')")
229        CALL prt_ctl_trc_info(charout)
230        CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
231      ENDIF
232      !
233      IF( lk_iomput )  CALL wrk_dealloc( jpi, jpj, jpk, zgrazing )
234      !
235      IF( nn_timing == 1 )  CALL timing_stop('p4z_meso')
236      !
237   END SUBROUTINE p4z_meso
238
239   SUBROUTINE p4z_meso_init
240
241      !!----------------------------------------------------------------------
242      !!                  ***  ROUTINE p4z_meso_init  ***
243      !!
244      !! ** Purpose :   Initialization of mesozooplankton parameters
245      !!
246      !! ** Method  :   Read the nampismes namelist and check the parameters
247      !!      called at the first timestep (nittrc000)
248      !!
249      !! ** input   :   Namelist nampismes
250      !!
251      !!----------------------------------------------------------------------
252
253      NAMELIST/nampismes/ part2, grazrat2, resrat2, mzrat2, xprefc, xprefp, xprefz,   &
254         &                xprefpoc, xthresh2dia, xthresh2phy, xthresh2zoo, xthresh2poc, &
255         &                xthresh2, xkgraz2, epsher2, sigma2, unass2, grazflux
256      INTEGER :: ios                 ! Local integer output status for namelist read
257
258      REWIND( numnatp_ref )              ! Namelist nampismes in reference namelist : Pisces mesozooplankton
259      READ  ( numnatp_ref, nampismes, IOSTAT = ios, ERR = 901)
260901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampismes in reference namelist', lwp )
261
262      REWIND( numnatp_cfg )              ! Namelist nampismes in configuration namelist : Pisces mesozooplankton
263      READ  ( numnatp_cfg, nampismes, IOSTAT = ios, ERR = 902 )
264902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampismes in configuration namelist', lwp )
265      IF(lwm) WRITE ( numonp, nampismes )
266
267
268      IF(lwp) THEN                         ! control print
269         WRITE(numout,*) ' ' 
270         WRITE(numout,*) ' Namelist parameters for mesozooplankton, nampismes'
271         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
272         WRITE(numout,*) '    part of calcite not dissolved in mesozoo guts  part2        =', part2
273         WRITE(numout,*) '    mesozoo preference for phyto                   xprefc       =', xprefc
274         WRITE(numout,*) '    mesozoo preference for POC                     xprefp       =', xprefp
275         WRITE(numout,*) '    mesozoo preference for zoo                     xprefz       =', xprefz
276         WRITE(numout,*) '    mesozoo preference for poc                     xprefpoc     =', xprefpoc
277         WRITE(numout,*) '    microzoo feeding threshold  for mesozoo        xthresh2zoo  =', xthresh2zoo
278         WRITE(numout,*) '    diatoms feeding threshold  for mesozoo         xthresh2dia  =', xthresh2dia
279         WRITE(numout,*) '    nanophyto feeding threshold for mesozoo        xthresh2phy  =', xthresh2phy
280         WRITE(numout,*) '    poc feeding threshold for mesozoo              xthresh2poc  =', xthresh2poc
281         WRITE(numout,*) '    feeding threshold for mesozooplankton          xthresh2     =', xthresh2
282         WRITE(numout,*) '    exsudation rate of mesozooplankton             resrat2      =', resrat2
283         WRITE(numout,*) '    mesozooplankton mortality rate                 mzrat2       =', mzrat2
284         WRITE(numout,*) '    maximal mesozoo grazing rate                   grazrat2     =', grazrat2
285         WRITE(numout,*) '    mesozoo flux feeding rate                      grazflux     =', grazflux
286         WRITE(numout,*) '    non assimilated fraction of P by mesozoo       unass2       =', unass2
287         WRITE(numout,*) '    Efficicency of Mesozoo growth                  epsher2      =', epsher2
288         WRITE(numout,*) '    Fraction of mesozoo excretion as DOM           sigma2       =', sigma2
289         WRITE(numout,*) '    half sturation constant for grazing 2          xkgraz2      =', xkgraz2
290      ENDIF
291
292
293   END SUBROUTINE p4z_meso_init
294
295   !!======================================================================
296END MODULE p4zmeso
Note: See TracBrowser for help on using the repository browser.