New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zprod.F90 in branches/2016/dev_r7012_ROBUST5_CNRS/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/2016/dev_r7012_ROBUST5_CNRS/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zprod.F90 @ 7068

Last change on this file since 7068 was 7068, checked in by cetlod, 8 years ago

ROBUST5_CNRS : implementation of part I of new TOP interface - 1st step -, see ticket #1782
File size: 28.7 KB
Line 
1MODULE p4zprod
2   !!======================================================================
3   !!                         ***  MODULE p4zprod  ***
4   !! TOP :  Growth Rate of the two phytoplanktons groups
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-05  (O. Aumont, C. Ethe) New parameterization of light limitation
9   !!----------------------------------------------------------------------
10   !!   p4z_prod       :   Compute the growth Rate of the two phytoplanktons groups
11   !!   p4z_prod_init  :   Initialization of the parameters for growth
12   !!   p4z_prod_alloc :   Allocate variables for growth
13   !!----------------------------------------------------------------------
14   USE oce_trc         !  shared variables between ocean and passive tracers
15   USE trc             !  passive tracers common variables
16   USE sms_pisces      !  PISCES Source Minus Sink variables
17   USE p4zopt          !  optical model
18   USE p4zlim          !  Co-limitations of differents nutrients
19   USE prtctl_trc      !  print control for debugging
20   USE iom             !  I/O manager
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC   p4z_prod         ! called in p4zbio.F90
26   PUBLIC   p4z_prod_init    ! called in trcsms_pisces.F90
27   PUBLIC   p4z_prod_alloc
28
29   !! * Shared module variables
30   LOGICAL , PUBLIC ::  ln_newprod      !:
31   REAL(wp), PUBLIC ::  pislope         !:
32   REAL(wp), PUBLIC ::  pislope2        !:
33   REAL(wp), PUBLIC ::  xadap           !:
34   REAL(wp), PUBLIC ::  excret          !:
35   REAL(wp), PUBLIC ::  excret2         !:
36   REAL(wp), PUBLIC ::  bresp           !:
37   REAL(wp), PUBLIC ::  chlcnm          !:
38   REAL(wp), PUBLIC ::  chlcdm          !:
39   REAL(wp), PUBLIC ::  chlcmin         !:
40   REAL(wp), PUBLIC ::  fecnm           !:
41   REAL(wp), PUBLIC ::  fecdm           !:
42   REAL(wp), PUBLIC ::  grosip          !:
43
44   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   prmax    !: optimal production = f(temperature)
45   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   quotan   !: proxy of N quota in Nanophyto
46   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   quotad   !: proxy of N quota in diatomee
47   
48   REAL(wp) :: r1_rday                !: 1 / rday
49   REAL(wp) :: texcret                !: 1 - excret
50   REAL(wp) :: texcret2               !: 1 - excret2       
51
52   !!----------------------------------------------------------------------
53   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
54   !! $Id: p4zprod.F90 3160 2011-11-20 14:27:18Z cetlod $
55   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
56   !!----------------------------------------------------------------------
57CONTAINS
58
59   SUBROUTINE p4z_prod( kt , knt )
60      !!---------------------------------------------------------------------
61      !!                     ***  ROUTINE p4z_prod  ***
62      !!
63      !! ** Purpose :   Compute the phytoplankton production depending on
64      !!              light, temperature and nutrient availability
65      !!
66      !! ** Method  : - ???
67      !!---------------------------------------------------------------------
68      !
69      INTEGER, INTENT(in) :: kt, knt
70      !
71      INTEGER  ::   ji, jj, jk
72      REAL(wp) ::   zsilfac, znanotot, zdiattot, zconctemp, zconctemp2
73      REAL(wp) ::   zratio, zmax, zsilim, ztn, zadap
74      REAL(wp) ::   zlim, zsilfac2, zsiborn, zprod, zproreg, zproreg2
75      REAL(wp) ::   zmxltst, zmxlday, zmaxday
76      REAL(wp) ::   zpislopen  , zpislope2n
77      REAL(wp) ::   zrum, zcodel, zargu, zval
78      REAL(wp) ::   zfact
79      CHARACTER (len=25) :: charout
80      REAL(wp), POINTER, DIMENSION(:,:  ) :: zmixnano, zmixdiat, zstrn, zw2d
81      REAL(wp), POINTER, DIMENSION(:,:,:) :: zpislopead, zpislopead2, zprdia, zprbio, zprdch, zprnch, zysopt, zw3d   
82      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprorca, zprorcad, zprofed, zprofen, zprochln, zprochld, zpronew, zpronewd
83      !!---------------------------------------------------------------------
84      !
85      IF( nn_timing == 1 )  CALL timing_start('p4z_prod')
86      !
87      !  Allocate temporary workspace
88      CALL wrk_alloc( jpi, jpj,      zmixnano, zmixdiat, zstrn                                                  )
89      CALL wrk_alloc( jpi, jpj, jpk, zpislopead, zpislopead2, zprdia, zprbio, zprdch, zprnch, zysopt            ) 
90      CALL wrk_alloc( jpi, jpj, jpk, zprorca, zprorcad, zprofed, zprofen, zprochln, zprochld, zpronew, zpronewd )
91      !
92      zprorca (:,:,:) = 0._wp
93      zprorcad(:,:,:) = 0._wp
94      zprofed (:,:,:) = 0._wp
95      zprofen (:,:,:) = 0._wp
96      zprochln(:,:,:) = 0._wp
97      zprochld(:,:,:) = 0._wp
98      zpronew (:,:,:) = 0._wp
99      zpronewd(:,:,:) = 0._wp
100      zprdia  (:,:,:) = 0._wp
101      zprbio  (:,:,:) = 0._wp
102      zprdch  (:,:,:) = 0._wp
103      zprnch  (:,:,:) = 0._wp
104      zysopt  (:,:,:) = 0._wp
105
106      ! Computation of the optimal production
107      prmax(:,:,:) = 0.6_wp * r1_rday * tgfunc(:,:,:) 
108
109      ! compute the day length depending on latitude and the day
110      zrum = REAL( nday_year - 80, wp ) / REAL( nyear_len(1), wp )
111      zcodel = ASIN(  SIN( zrum * rpi * 2._wp ) * SIN( rad * 23.5_wp )  )
112
113      ! day length in hours
114      zstrn(:,:) = 0.
115      DO jj = 1, jpj
116         DO ji = 1, jpi
117            zargu = TAN( zcodel ) * TAN( gphit(ji,jj) * rad )
118            zargu = MAX( -1., MIN(  1., zargu ) )
119            zstrn(ji,jj) = MAX( 0.0, 24. - 2. * ACOS( zargu ) / rad / 15. )
120         END DO
121      END DO
122
123      ! Impact of the day duration on phytoplankton growth
124      DO jk = 1, jpkm1
125         DO jj = 1 ,jpj
126            DO ji = 1, jpi
127               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
128                  zval = MAX( 1., zstrn(ji,jj) )
129                  zval = 1.5 * zval / ( 12. + zval )
130                  zprbio(ji,jj,jk) = prmax(ji,jj,jk) * zval * ( 1. - fr_i(ji,jj) )
131                  zprdia(ji,jj,jk) = zprbio(ji,jj,jk)
132               ENDIF
133            END DO
134         END DO
135      END DO
136
137      ! Maximum light intensity
138      WHERE( zstrn(:,:) < 1.e0 ) zstrn(:,:) = 24.
139      zstrn(:,:) = 24. / zstrn(:,:)
140
141      IF( ln_newprod ) THEN
142         DO jk = 1, jpkm1
143            DO jj = 1, jpj
144               DO ji = 1, jpi
145                  ! Computation of the P-I slope for nanos and diatoms
146                  IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
147                      ztn         = MAX( 0., tsn(ji,jj,jk,jp_tem) - 15. )
148                      zadap       = xadap * ztn / ( 2.+ ztn )
149                      zconctemp   = MAX( 0.e0 , trb(ji,jj,jk,jpdia) - xsizedia )
150                      zconctemp2  = trb(ji,jj,jk,jpdia) - zconctemp
151                      znanotot    = enano(ji,jj,jk) * zstrn(ji,jj)
152                      zdiattot    = ediat(ji,jj,jk) * zstrn(ji,jj)
153                      !
154                      zpislopead (ji,jj,jk) = pislope * ( 1.+ zadap  * EXP( -znanotot ) )  &
155                         &                   * trb(ji,jj,jk,jpnch) /( trb(ji,jj,jk,jpphy) * 12. + rtrn)
156                      !
157                      zpislopead2(ji,jj,jk) = (pislope * zconctemp2 + pislope2 * zconctemp) / ( trb(ji,jj,jk,jpdia) + rtrn )   &
158                         &                   * trb(ji,jj,jk,jpdch) /( trb(ji,jj,jk,jpdia) * 12. + rtrn)
159
160                      ! Computation of production function for Carbon
161                      !  ---------------------------------------------
162                      zpislopen  = zpislopead (ji,jj,jk) / ( ( r1_rday + bresp * r1_rday ) * rday + rtrn)
163                      zpislope2n = zpislopead2(ji,jj,jk) / ( ( r1_rday + bresp * r1_rday ) * rday + rtrn)
164                      zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1.- EXP( -zpislopen  * znanotot )  )
165                      zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1.- EXP( -zpislope2n * zdiattot )  )
166
167                      !  Computation of production function for Chlorophyll
168                      !--------------------------------------------------
169                      zmaxday  = 1._wp / ( prmax(ji,jj,jk) * rday + rtrn )
170                      zprnch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislopead (ji,jj,jk) * zmaxday * znanotot ) )
171                      zprdch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislopead2(ji,jj,jk) * zmaxday * zdiattot ) )
172                  ENDIF
173               END DO
174            END DO
175         END DO
176      ELSE
177         DO jk = 1, jpkm1
178            DO jj = 1, jpj
179               DO ji = 1, jpi
180
181                  ! Computation of the P-I slope for nanos and diatoms
182                  IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
183                      ztn         = MAX( 0., tsn(ji,jj,jk,jp_tem) - 15. )
184                      zadap       = ztn / ( 2.+ ztn )
185                      zconctemp   = MAX( 0.e0 , trb(ji,jj,jk,jpdia) - xsizedia )
186                      zconctemp2  = trb(ji,jj,jk,jpdia) - zconctemp
187                      znanotot    = enano(ji,jj,jk) * zstrn(ji,jj)
188                      zdiattot    = ediat(ji,jj,jk) * zstrn(ji,jj)
189                      !
190                      zpislopead (ji,jj,jk) = pislope  * ( 1.+ zadap  * EXP( -znanotot ) )
191                      zpislopead2(ji,jj,jk) = (pislope * zconctemp2 + pislope2 * zconctemp)  / ( trb(ji,jj,jk,jpdia) + rtrn )
192
193                      zpislopen =  zpislopead(ji,jj,jk) * trb(ji,jj,jk,jpnch)                &
194                        &          / ( trb(ji,jj,jk,jpphy) * 12.                  + rtrn )   &
195                        &          / ( prmax(ji,jj,jk) * rday * xlimphy(ji,jj,jk) + rtrn )
196
197                      zpislope2n = zpislopead2(ji,jj,jk) * trb(ji,jj,jk,jpdch)                &
198                        &          / ( trb(ji,jj,jk,jpdia) * 12.                  + rtrn )   &
199                        &          / ( prmax(ji,jj,jk) * rday * xlimdia(ji,jj,jk) + rtrn )
200
201                      ! Computation of production function for Carbon
202                      !  ---------------------------------------------
203                      zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1.- EXP( -zpislopen  * znanotot ) )
204                      zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1.- EXP( -zpislope2n * zdiattot ) )
205
206                      !  Computation of production function for Chlorophyll
207                      !--------------------------------------------------
208                      zprnch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislopen  * enano(ji,jj,jk) ) )
209                      zprdch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislope2n * ediat(ji,jj,jk) ) )
210                  ENDIF
211               END DO
212            END DO
213         END DO
214      ENDIF
215
216
217      !  Computation of a proxy of the N/C ratio
218      !  ---------------------------------------
219      DO jk = 1, jpkm1
220         DO jj = 1, jpj
221            DO ji = 1, jpi
222                zval = MIN( xnanopo4(ji,jj,jk), ( xnanonh4(ji,jj,jk) + xnanono3(ji,jj,jk) ) )   &
223                &      * prmax(ji,jj,jk) / ( zprbio(ji,jj,jk) + rtrn )
224                quotan(ji,jj,jk) = MIN( 1., 0.2 + 0.8 * zval )
225                zval = MIN( xdiatpo4(ji,jj,jk), ( xdiatnh4(ji,jj,jk) + xdiatno3(ji,jj,jk) ) )   &
226                &      * prmax(ji,jj,jk) / ( zprdia(ji,jj,jk) + rtrn )
227                quotad(ji,jj,jk) = MIN( 1., 0.2 + 0.8 * zval )
228            END DO
229         END DO
230      END DO
231
232
233      DO jk = 1, jpkm1
234         DO jj = 1, jpj
235            DO ji = 1, jpi
236
237                IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
238                   !    Si/C of diatoms
239                   !    ------------------------
240                   !    Si/C increases with iron stress and silicate availability
241                   !    Si/C is arbitrariliy increased for very high Si concentrations
242                   !    to mimic the very high ratios observed in the Southern Ocean (silpot2)
243                  zlim  = trb(ji,jj,jk,jpsil) / ( trb(ji,jj,jk,jpsil) + xksi1 )
244                  zsilim = MIN( zprdia(ji,jj,jk) / ( prmax(ji,jj,jk) + rtrn ), xlimsi(ji,jj,jk) )
245                  zsilfac = 4.4 * EXP( -4.23 * zsilim ) * MAX( 0.e0, MIN( 1., 2.2 * ( zlim - 0.5 ) )  ) + 1.e0
246                  zsiborn = trb(ji,jj,jk,jpsil) * trb(ji,jj,jk,jpsil) * trb(ji,jj,jk,jpsil)
247                  IF (gphit(ji,jj) < -30 ) THEN
248                    zsilfac2 = 1. + 2. * zsiborn / ( zsiborn + xksi2**3 )
249                  ELSE
250                    zsilfac2 = 1. +      zsiborn / ( zsiborn + xksi2**3 )
251                  ENDIF
252                  zysopt(ji,jj,jk) = grosip * zlim * zsilfac * zsilfac2
253              ENDIF
254            END DO
255         END DO
256      END DO
257
258      !  Computation of the limitation term due to a mixed layer deeper than the euphotic depth
259      DO jj = 1, jpj
260         DO ji = 1, jpi
261            zmxltst = MAX( 0.e0, hmld(ji,jj) - heup(ji,jj) )
262            zmxlday = zmxltst * zmxltst * r1_rday
263            zmixnano(ji,jj) = 1. - zmxlday / ( 2. + zmxlday )
264            zmixdiat(ji,jj) = 1. - zmxlday / ( 4. + zmxlday )
265         END DO
266      END DO
267 
268      !  Mixed-layer effect on production                                                                               
269      DO jk = 1, jpkm1
270         DO jj = 1, jpj
271            DO ji = 1, jpi
272               IF( gdepw_n(ji,jj,jk+1) <= hmld(ji,jj) ) THEN
273                  zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * zmixnano(ji,jj)
274                  zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * zmixdiat(ji,jj)
275               ENDIF
276               zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
277               zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
278            END DO
279         END DO
280      END DO
281
282      ! Computation of the various production terms
283      DO jk = 1, jpkm1
284         DO jj = 1, jpj
285            DO ji = 1, jpi
286               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
287                  !  production terms for nanophyto.
288                  zprorca(ji,jj,jk) = zprbio(ji,jj,jk)  * xlimphy(ji,jj,jk) * trb(ji,jj,jk,jpphy) * rfact2
289                  zpronew(ji,jj,jk) = zprorca(ji,jj,jk) * xnanono3(ji,jj,jk) / ( xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk) + rtrn )
290                  !
291                  zratio = trb(ji,jj,jk,jpnfe) / ( trb(ji,jj,jk,jpphy) + rtrn )
292                  zratio = zratio / fecnm 
293                  zmax   = MAX( 0., ( 1. - zratio ) / ABS( 1.05 - zratio ) ) 
294                  zprofen(ji,jj,jk) = fecnm * prmax(ji,jj,jk)  &
295                  &             * ( 4. - 4.5 * xlimnfe(ji,jj,jk) / ( xlimnfe(ji,jj,jk) + 0.5 ) )    &
296                  &             * biron(ji,jj,jk) / ( biron(ji,jj,jk) + concnfe(ji,jj,jk) )  &
297                  &             * zmax * trb(ji,jj,jk,jpphy) * rfact2
298                  !  production terms for diatomees
299                  zprorcad(ji,jj,jk) = zprdia(ji,jj,jk) * xlimdia(ji,jj,jk) * trb(ji,jj,jk,jpdia) * rfact2
300                  zpronewd(ji,jj,jk) = zprorcad(ji,jj,jk) * xdiatno3(ji,jj,jk) / ( xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk) + rtrn )
301                  !
302                  zratio = trb(ji,jj,jk,jpdfe) / ( trb(ji,jj,jk,jpdia) + rtrn )
303                  zratio = zratio / fecdm 
304                  zmax   = MAX( 0., ( 1. - zratio ) / ABS( 1.05 - zratio ) ) 
305                  zprofed(ji,jj,jk) = fecdm * prmax(ji,jj,jk)  &
306                  &             * ( 4. - 4.5 * xlimdfe(ji,jj,jk) / ( xlimdfe(ji,jj,jk) + 0.5 ) )    &
307                  &             * biron(ji,jj,jk) / ( biron(ji,jj,jk) + concdfe(ji,jj,jk) )  &
308                  &             * zmax * trb(ji,jj,jk,jpdia) * rfact2
309               ENDIF
310            END DO
311         END DO
312      END DO
313
314      DO jk = 1, jpkm1
315         DO jj = 1, jpj
316            DO ji = 1, jpi
317               IF( gdepw_n(ji,jj,jk+1) <= hmld(ji,jj) ) THEN
318                  zprnch(ji,jj,jk) = zprnch(ji,jj,jk) * zmixnano(ji,jj)
319                  zprdch(ji,jj,jk) = zprdch(ji,jj,jk) * zmixdiat(ji,jj)
320               ENDIF
321               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
322                  !  production terms for nanophyto. ( chlorophyll )
323                  znanotot = enano(ji,jj,jk) * zstrn(ji,jj)
324                  zprod    = rday * zprorca(ji,jj,jk) * zprnch(ji,jj,jk) * xlimphy(ji,jj,jk)
325                  zprochln(ji,jj,jk) = chlcmin * 12. * zprorca (ji,jj,jk)
326                  zprochln(ji,jj,jk) = zprochln(ji,jj,jk) + (chlcnm-chlcmin) * 12. * zprod / &
327                                     & (  zpislopead(ji,jj,jk) * znanotot +rtrn)
328                  !  production terms for diatomees ( chlorophyll )
329                  zdiattot = ediat(ji,jj,jk) * zstrn(ji,jj)
330                  zprod = rday * zprorcad(ji,jj,jk) * zprdch(ji,jj,jk) * xlimdia(ji,jj,jk)
331                  zprochld(ji,jj,jk) = chlcmin * 12. * zprorcad(ji,jj,jk)
332                  zprochld(ji,jj,jk) = zprochld(ji,jj,jk) + (chlcdm-chlcmin) * 12. * zprod / &
333                                     & ( zpislopead2(ji,jj,jk) * zdiattot +rtrn )
334               ENDIF
335            END DO
336         END DO
337      END DO
338
339      !   Update the arrays TRA which contain the biological sources and sinks
340      DO jk = 1, jpkm1
341         DO jj = 1, jpj
342           DO ji =1 ,jpi
343              zproreg  = zprorca(ji,jj,jk) - zpronew(ji,jj,jk)
344              zproreg2 = zprorcad(ji,jj,jk) - zpronewd(ji,jj,jk)
345              tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) - zprorca(ji,jj,jk) - zprorcad(ji,jj,jk)
346              tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - zpronew(ji,jj,jk) - zpronewd(ji,jj,jk)
347              tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zproreg - zproreg2
348              tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) + zprorca(ji,jj,jk) * texcret
349              tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) + zprochln(ji,jj,jk) * texcret
350              tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) + zprofen(ji,jj,jk) * texcret
351              tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) + zprorcad(ji,jj,jk) * texcret2
352              tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) + zprochld(ji,jj,jk) * texcret2
353              tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) + zprofed(ji,jj,jk) * texcret2
354              tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) + zprorcad(ji,jj,jk) * zysopt(ji,jj,jk) * texcret2
355              tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + excret2 * zprorcad(ji,jj,jk) + excret * zprorca(ji,jj,jk)
356              tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) + o2ut * ( zproreg + zproreg2) &
357                 &                + ( o2ut + o2nit ) * ( zpronew(ji,jj,jk) + zpronewd(ji,jj,jk) )
358              tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - texcret * zprofen(ji,jj,jk) - texcret2 * zprofed(ji,jj,jk)
359              tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) - texcret2 * zprorcad(ji,jj,jk) * zysopt(ji,jj,jk)
360              tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprorca(ji,jj,jk) - zprorcad(ji,jj,jk)
361              tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zpronew(ji,jj,jk) + zpronewd(ji,jj,jk) ) &
362                 &                                      - rno3 * ( zproreg + zproreg2 )
363          END DO
364        END DO
365     END DO
366
367
368    ! Total primary production per year
369    IF( iom_use( "tintpp" ) .OR. ( ln_check_mass .AND. kt == nitend .AND. knt == nrdttrc )  )  &
370         & tpp = glob_sum( ( zprorca(:,:,:) + zprorcad(:,:,:) ) * cvol(:,:,:) )
371
372    IF( lk_iomput ) THEN
373       IF( knt == nrdttrc ) THEN
374          CALL wrk_alloc( jpi, jpj,      zw2d )
375          CALL wrk_alloc( jpi, jpj, jpk, zw3d )
376          zfact = 1.e+3 * rfact2r  !  conversion from mol/l/kt to  mol/m3/s
377          !
378          IF( iom_use( "PPPHY" ) .OR. iom_use( "PPPHY2" ) )  THEN
379              zw3d(:,:,:) = zprorca (:,:,:) * zfact * tmask(:,:,:)  ! primary production by nanophyto
380              CALL iom_put( "PPPHY"  , zw3d )
381              !
382              zw3d(:,:,:) = zprorcad(:,:,:) * zfact * tmask(:,:,:)  ! primary production by diatomes
383              CALL iom_put( "PPPHY2"  , zw3d )
384          ENDIF
385          IF( iom_use( "PPNEWN" ) .OR. iom_use( "PPNEWD" ) )  THEN
386              zw3d(:,:,:) = zpronew (:,:,:) * zfact * tmask(:,:,:)  ! new primary production by nanophyto
387              CALL iom_put( "PPNEWN"  , zw3d )
388              !
389              zw3d(:,:,:) = zpronewd(:,:,:) * zfact * tmask(:,:,:)  ! new primary production by diatomes
390              CALL iom_put( "PPNEWD"  , zw3d )
391          ENDIF
392          IF( iom_use( "PBSi" ) )  THEN
393              zw3d(:,:,:) = zprorcad(:,:,:) * zfact * tmask(:,:,:) * zysopt(:,:,:) ! biogenic silica production
394              CALL iom_put( "PBSi"  , zw3d )
395          ENDIF
396          IF( iom_use( "PFeN" ) .OR. iom_use( "PFeD" ) )  THEN
397              zw3d(:,:,:) = zprofen(:,:,:) * zfact * tmask(:,:,:)  ! biogenic iron production by nanophyto
398              CALL iom_put( "PFeN"  , zw3d )
399              !
400              zw3d(:,:,:) = zprofed(:,:,:) * zfact * tmask(:,:,:)  ! biogenic iron production by  diatomes
401              CALL iom_put( "PFeD"  , zw3d )
402          ENDIF
403          IF( iom_use( "Mumax" ) )  THEN
404              zw3d(:,:,:) = prmax(:,:,:) * tmask(:,:,:)   ! Maximum growth rate
405              CALL iom_put( "Mumax"  , zw3d )
406          ENDIF
407          IF( iom_use( "MuN" ) .OR. iom_use( "MuD" ) )  THEN
408              zw3d(:,:,:) = zprbio(:,:,:) * xlimphy(:,:,:) * tmask(:,:,:)  ! Realized growth rate for nanophyto
409              CALL iom_put( "MuN"  , zw3d )
410              !
411              zw3d(:,:,:) =  zprdia(:,:,:) * xlimdia(:,:,:) * tmask(:,:,:)  ! Realized growth rate for diatoms
412              CALL iom_put( "MuD"  , zw3d )
413          ENDIF
414          IF( iom_use( "LNlight" ) .OR. iom_use( "LDlight" ) )  THEN
415              zw3d(:,:,:) = zprbio (:,:,:) / (prmax(:,:,:) + rtrn) * tmask(:,:,:) ! light limitation term
416              CALL iom_put( "LNlight"  , zw3d )
417              !
418              zw3d(:,:,:) =  zprdia (:,:,:) / (prmax(:,:,:) + rtrn) * tmask(:,:,:)  ! light limitation term
419              CALL iom_put( "LDlight"  , zw3d )
420          ENDIF
421          IF( iom_use( "TPP" ) )  THEN
422              zw3d(:,:,:) = ( zprorca(:,:,:) + zprorcad(:,:,:) ) * zfact * tmask(:,:,:)  ! total primary production
423              CALL iom_put( "TPP"  , zw3d )
424          ENDIF
425          IF( iom_use( "TPNEW" ) )  THEN
426              zw3d(:,:,:) = ( zpronew(:,:,:) + zpronewd(:,:,:) ) * zfact * tmask(:,:,:)  ! total new production
427              CALL iom_put( "TPNEW"  , zw3d )
428          ENDIF
429          IF( iom_use( "TPBFE" ) )  THEN
430              zw3d(:,:,:) = ( zprofen(:,:,:) + zprofed(:,:,:) ) * zfact * tmask(:,:,:)  ! total biogenic iron production
431              CALL iom_put( "TPBFE"  , zw3d )
432          ENDIF
433          IF( iom_use( "INTPPPHY" ) .OR. iom_use( "INTPPPHY2" ) ) THEN 
434             zw2d(:,:) = 0.
435             DO jk = 1, jpkm1
436               zw2d(:,:) = zw2d(:,:) + zprorca (:,:,jk) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk)  ! vert. integrated  primary produc. by nano
437             ENDDO
438             CALL iom_put( "INTPPPHY" , zw2d )
439             !
440             zw2d(:,:) = 0.
441             DO jk = 1, jpkm1
442                zw2d(:,:) = zw2d(:,:) + zprorcad(:,:,jk) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk) ! vert. integrated  primary produc. by diatom
443             ENDDO
444             CALL iom_put( "INTPPPHY2" , zw2d )
445          ENDIF
446          IF( iom_use( "INTPP" ) ) THEN   
447             zw2d(:,:) = 0.
448             DO jk = 1, jpkm1
449                zw2d(:,:) = zw2d(:,:) + ( zprorca(:,:,jk) + zprorcad(:,:,jk) ) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk) ! vert. integrated pp
450             ENDDO
451             CALL iom_put( "INTPP" , zw2d )
452          ENDIF
453          IF( iom_use( "INTPNEW" ) ) THEN   
454             zw2d(:,:) = 0.
455             DO jk = 1, jpkm1
456                zw2d(:,:) = zw2d(:,:) + ( zpronew(:,:,jk) + zpronewd(:,:,jk) ) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk)  ! vert. integrated new prod
457             ENDDO
458             CALL iom_put( "INTPNEW" , zw2d )
459          ENDIF
460          IF( iom_use( "INTPBFE" ) ) THEN           !   total biogenic iron production  ( vertically integrated )
461             zw2d(:,:) = 0.
462             DO jk = 1, jpkm1
463                zw2d(:,:) = zw2d(:,:) + ( zprofen(:,:,jk) + zprofed(:,:,jk) ) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk) ! vert integr. bfe prod
464             ENDDO
465            CALL iom_put( "INTPBFE" , zw2d )
466          ENDIF
467          IF( iom_use( "INTPBSI" ) ) THEN           !   total biogenic silica production  ( vertically integrated )
468             zw2d(:,:) = 0.
469             DO jk = 1, jpkm1
470                zw2d(:,:) = zw2d(:,:) + zprorcad(:,:,jk) * zysopt(:,:,jk) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk)  ! vert integr. bsi prod
471             ENDDO
472             CALL iom_put( "INTPBSI" , zw2d )
473          ENDIF
474          IF( iom_use( "tintpp" ) )  CALL iom_put( "tintpp" , tpp * zfact )  !  global total integrated primary production molC/s
475          !
476          CALL wrk_dealloc( jpi, jpj,      zw2d )
477          CALL wrk_dealloc( jpi, jpj, jpk, zw3d )
478       ENDIF
479     ENDIF
480
481     IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
482         WRITE(charout, FMT="('prod')")
483         CALL prt_ctl_trc_info(charout)
484         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
485     ENDIF
486     !
487     CALL wrk_dealloc( jpi, jpj,      zmixnano, zmixdiat, zstrn                                                  )
488     CALL wrk_dealloc( jpi, jpj, jpk, zpislopead, zpislopead2, zprdia, zprbio, zprdch, zprnch, zysopt            ) 
489     CALL wrk_dealloc( jpi, jpj, jpk, zprorca, zprorcad, zprofed, zprofen, zprochln, zprochld, zpronew, zpronewd )
490     !
491     IF( nn_timing == 1 )  CALL timing_stop('p4z_prod')
492     !
493   END SUBROUTINE p4z_prod
494
495
496   SUBROUTINE p4z_prod_init
497      !!----------------------------------------------------------------------
498      !!                  ***  ROUTINE p4z_prod_init  ***
499      !!
500      !! ** Purpose :   Initialization of phytoplankton production parameters
501      !!
502      !! ** Method  :   Read the nampisprod namelist and check the parameters
503      !!      called at the first timestep (nittrc000)
504      !!
505      !! ** input   :   Namelist nampisprod
506      !!----------------------------------------------------------------------
507      !
508      NAMELIST/nampisprod/ pislope, pislope2, xadap, ln_newprod, bresp, excret, excret2,  &
509         &                 chlcnm, chlcdm, chlcmin, fecnm, fecdm, grosip
510      INTEGER :: ios                 ! Local integer output status for namelist read
511      !!----------------------------------------------------------------------
512
513      REWIND( numnatp_ref )              ! Namelist nampisprod in reference namelist : Pisces phytoplankton production
514      READ  ( numnatp_ref, nampisprod, IOSTAT = ios, ERR = 901)
515901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisprod in reference namelist', lwp )
516
517      REWIND( numnatp_cfg )              ! Namelist nampisprod in configuration namelist : Pisces phytoplankton production
518      READ  ( numnatp_cfg, nampisprod, IOSTAT = ios, ERR = 902 )
519902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisprod in configuration namelist', lwp )
520      IF(lwm) WRITE ( numonp, nampisprod )
521
522      IF(lwp) THEN                         ! control print
523         WRITE(numout,*) ' '
524         WRITE(numout,*) ' Namelist parameters for phytoplankton growth, nampisprod'
525         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
526         WRITE(numout,*) '    Enable new parame. of production (T/F)   ln_newprod   =', ln_newprod
527         WRITE(numout,*) '    mean Si/C ratio                           grosip       =', grosip
528         WRITE(numout,*) '    P-I slope                                 pislope      =', pislope
529         WRITE(numout,*) '    Acclimation factor to low light           xadap       =', xadap
530         WRITE(numout,*) '    excretion ratio of nanophytoplankton      excret       =', excret
531         WRITE(numout,*) '    excretion ratio of diatoms                excret2      =', excret2
532         IF( ln_newprod )  THEN
533            WRITE(numout,*) '    basal respiration in phytoplankton        bresp        =', bresp
534            WRITE(numout,*) '    Maximum Chl/C in phytoplankton            chlcmin      =', chlcmin
535         ENDIF
536         WRITE(numout,*) '    P-I slope  for diatoms                    pislope2     =', pislope2
537         WRITE(numout,*) '    Minimum Chl/C in nanophytoplankton        chlcnm       =', chlcnm
538         WRITE(numout,*) '    Minimum Chl/C in diatoms                  chlcdm       =', chlcdm
539         WRITE(numout,*) '    Maximum Fe/C in nanophytoplankton         fecnm        =', fecnm
540         WRITE(numout,*) '    Minimum Fe/C in diatoms                   fecdm        =', fecdm
541      ENDIF
542      !
543      r1_rday   = 1._wp / rday 
544      texcret   = 1._wp - excret
545      texcret2  = 1._wp - excret2
546      tpp       = 0._wp
547      !
548   END SUBROUTINE p4z_prod_init
549
550
551   INTEGER FUNCTION p4z_prod_alloc()
552      !!----------------------------------------------------------------------
553      !!                     ***  ROUTINE p4z_prod_alloc  ***
554      !!----------------------------------------------------------------------
555      ALLOCATE( prmax(jpi,jpj,jpk), quotan(jpi,jpj,jpk), quotad(jpi,jpj,jpk), STAT = p4z_prod_alloc )
556      !
557      IF( p4z_prod_alloc /= 0 ) CALL ctl_warn('p4z_prod_alloc : failed to allocate arrays.')
558      !
559   END FUNCTION p4z_prod_alloc
560
561   !!======================================================================
562END MODULE p4zprod
Note: See TracBrowser for help on using the repository browser.